qcsrc/common/weapons/weapon/seeker.qc

   1 #ifndef IMPLEMENTATION
   2 REGISTER_WEAPON(
   3 /* WEP_##id  */ SEEKER,
   4 /* function  */ W_Seeker,
   5 /* ammotype  */ ammo_rockets,
   6 /* impulse   */ 8,
   7 /* flags     */ WEP_FLAG_MUTATORBLOCKED | WEP_FLAG_RELOADABLE | WEP_TYPE_SPLASH,
   8 /* rating    */ BOT_PICKUP_RATING_MID,
   9 /* color     */ '0.5 1 0',
  10 /* modelname */ "seeker",
  11 /* model     */ MDL_SEEKER_ITEM,
  12 /* simplemdl */ "foobar",
  13 /* crosshair */ "gfx/crosshairseeker 0.8",
  14 /* wepimg    */ "weaponseeker",
  15 /* refname   */ "seeker",
  16 /* wepname   */ _("T.A.G. Seeker")
  17 );
  18
  19 #define SEEKER_SETTINGS(w_cvar,w_prop) SEEKER_SETTINGS_LIST(w_cvar, w_prop, SEEKER, seeker)
  20 #define SEEKER_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  21         w_cvar(id, sn, NONE, type) \
  22         w_cvar(id, sn, NONE, flac_ammo) \
  23         w_cvar(id, sn, NONE, flac_animtime) \
  24         w_cvar(id, sn, NONE, flac_damage) \
  25         w_cvar(id, sn, NONE, flac_edgedamage) \
  26         w_cvar(id, sn, NONE, flac_force) \
  27         w_cvar(id, sn, NONE, flac_lifetime) \
  28         w_cvar(id, sn, NONE, flac_lifetime_rand) \
  29         w_cvar(id, sn, NONE, flac_radius) \
  30         w_cvar(id, sn, NONE, flac_refire) \
  31         w_cvar(id, sn, NONE, flac_speed) \
  32         w_cvar(id, sn, NONE, flac_speed_up) \
  33         w_cvar(id, sn, NONE, flac_speed_z) \
  34         w_cvar(id, sn, NONE, flac_spread) \
  35         w_cvar(id, sn, NONE, missile_accel) \
  36         w_cvar(id, sn, NONE, missile_ammo) \
  37         w_cvar(id, sn, NONE, missile_animtime) \
  38         w_cvar(id, sn, NONE, missile_count) \
  39         w_cvar(id, sn, NONE, missile_damage) \
  40         w_cvar(id, sn, NONE, missile_damageforcescale) \
  41         w_cvar(id, sn, NONE, missile_decel) \
  42         w_cvar(id, sn, NONE, missile_delay) \
  43         w_cvar(id, sn, NONE, missile_edgedamage) \
  44         w_cvar(id, sn, NONE, missile_force) \
  45         w_cvar(id, sn, NONE, missile_health) \
  46         w_cvar(id, sn, NONE, missile_lifetime) \
  47         w_cvar(id, sn, NONE, missile_proxy) \
  48         w_cvar(id, sn, NONE, missile_proxy_delay) \
  49         w_cvar(id, sn, NONE, missile_proxy_maxrange) \
  50         w_cvar(id, sn, NONE, missile_radius) \
  51         w_cvar(id, sn, NONE, missile_refire) \
  52         w_cvar(id, sn, NONE, missile_smart) \
  53         w_cvar(id, sn, NONE, missile_smart_mindist) \
  54         w_cvar(id, sn, NONE, missile_smart_trace_max) \
  55         w_cvar(id, sn, NONE, missile_smart_trace_min) \
  56         w_cvar(id, sn, NONE, missile_speed) \
  57         w_cvar(id, sn, NONE, missile_speed_max) \
  58         w_cvar(id, sn, NONE, missile_speed_up) \
  59         w_cvar(id, sn, NONE, missile_speed_z) \
  60         w_cvar(id, sn, NONE, missile_spread) \
  61         w_cvar(id, sn, NONE, missile_turnrate) \
  62         w_cvar(id, sn, NONE, tag_ammo) \
  63         w_cvar(id, sn, NONE, tag_animtime) \
  64         w_cvar(id, sn, NONE, tag_damageforcescale) \
  65         w_cvar(id, sn, NONE, tag_health) \
  66         w_cvar(id, sn, NONE, tag_lifetime) \
  67         w_cvar(id, sn, NONE, tag_refire) \
  68         w_cvar(id, sn, NONE, tag_speed) \
  69         w_cvar(id, sn, NONE, tag_spread) \
  70         w_cvar(id, sn, NONE, tag_tracker_lifetime) \
  71         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  72         w_prop(id, sn, float,  reloading_time, reload_time) \
  73         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  74         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  75         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  76         w_prop(id, sn, float,  weaponstart, weaponstart) \
  77         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  78         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  79
  80 #ifdef SVQC
  81 SEEKER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  82 .entity tag_target, wps_tag_tracker;
  83 .float tag_time;
  84 #endif
  85 #endif
  86 #ifdef IMPLEMENTATION
  87 #ifdef SVQC
  88 void spawnfunc_weapon_seeker(void) { weapon_defaultspawnfunc(WEP_SEEKER.m_id); }
  89
  90 // ============================
  91 // Begin: Missile functions, these are general functions to be manipulated by other code
  92 // ============================
  93 void W_Seeker_Missile_Explode(void)
  94 {SELFPARAM();
  95         self.event_damage = func_null;
  96         RadiusDamage(self, self.realowner, WEP_CVAR(seeker, missile_damage), WEP_CVAR(seeker, missile_edgedamage), WEP_CVAR(seeker, missile_radius), world, world, WEP_CVAR(seeker, missile_force), self.projectiledeathtype, other);
  97
  98         remove(self);
  99 }
 100
 101 void W_Seeker_Missile_Touch(void)
 102 {
 103         PROJECTILE_TOUCH;
 104
 105         W_Seeker_Missile_Explode();
 106 }
 107
 108 void W_Seeker_Missile_Think(void)
 109 {SELFPARAM();
 110         entity e;
 111         vector desireddir, olddir, newdir, eorg;
 112         float turnrate;
 113         float dist;
 114         float spd;
 115
 116         if(time > self.cnt)
 117         {
 118                 self.projectiledeathtype |= HITTYPE_SPLASH;
 119                 W_Seeker_Missile_Explode();
 120         }
 121
 122         spd = vlen(self.velocity);
 123         spd = bound(
 124                 spd - WEP_CVAR(seeker, missile_decel) * frametime,
 125                 WEP_CVAR(seeker, missile_speed_max),
 126                 spd + WEP_CVAR(seeker, missile_accel) * frametime
 127         );
 128
 129         if(self.enemy != world)
 130                 if(self.enemy.takedamage != DAMAGE_AIM || self.enemy.deadflag != DEAD_NO)
 131                         self.enemy = world;
 132
 133         if(self.enemy != world)
 134         {
 135                 e               = self.enemy;
 136                 eorg            = 0.5 * (e.absmin + e.absmax);
 137                 turnrate        = WEP_CVAR(seeker, missile_turnrate); // how fast to turn
 138                 desireddir      = normalize(eorg - self.origin);
 139                 olddir          = normalize(self.velocity); // get my current direction
 140                 dist            = vlen(eorg - self.origin);
 141
 142                 // Do evasive maneuvers for world objects? ( this should be a cpu hog. :P )
 143                 if(WEP_CVAR(seeker, missile_smart) && (dist > WEP_CVAR(seeker, missile_smart_mindist)))
 144                 {
 145                         // Is it a better idea (shorter distance) to trace to the target itself?
 146                         if( vlen(self.origin + olddir * self.wait) < dist)
 147                                 traceline(self.origin, self.origin + olddir * self.wait, false, self);
 148                         else
 149                                 traceline(self.origin, eorg, false, self);
 150
 151                         // Setup adaptive tracelength
 152                         self.wait = bound(WEP_CVAR(seeker, missile_smart_trace_min), vlen(self.origin - trace_endpos), self.wait = WEP_CVAR(seeker, missile_smart_trace_max));
 153
 154                         // Calc how important it is that we turn and add this to the desierd (enemy) dir.
 155                         desireddir  = normalize(((trace_plane_normal * (1 - trace_fraction)) + (desireddir * trace_fraction)) * 0.5);
 156                 }
 157
 158                 newdir = normalize(olddir + desireddir * turnrate); // take the average of the 2 directions; not the best method but simple & easy
 159                 self.velocity = newdir * spd; // make me fly in the new direction at my flight speed
 160         }
 161         else
 162                 dist = 0;
 163
 164         // Proxy
 165         if(WEP_CVAR(seeker, missile_proxy))
 166         {
 167                 if(dist <= WEP_CVAR(seeker, missile_proxy_maxrange))
 168                 {
 169                         if(self.autoswitch == 0)
 170                         {
 171                                 self.autoswitch = time + WEP_CVAR(seeker, missile_proxy_delay);
 172                         }
 173                         else
 174                         {
 175                                 if(self.autoswitch <= time)
 176                                 {
 177                                         W_Seeker_Missile_Explode();
 178                                         self.autoswitch = 0;
 179                                 }
 180                         }
 181                 }
 182                 else
 183                 {
 184                         if(self.autoswitch != 0)
 185                                 self.autoswitch = 0;
 186                 }
 187         }
 188         ///////////////
 189
 190         if(self.enemy.deadflag != DEAD_NO)
 191         {
 192                 self.enemy = world;
 193                 self.cnt = time + 1 + (random() * 4);
 194                 self.nextthink = self.cnt;
 195                 return;
 196         }
 197
 198         //self.angles = vectoangles(self.velocity);                     // turn model in the new flight direction
 199         self.nextthink = time;// + 0.05; // csqc projectiles
 200         UpdateCSQCProjectile(self);
 201 }
 202
 203
 204
 205 void W_Seeker_Missile_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 206 {SELFPARAM();
 207         if(self.health <= 0)
 208                 return;
 209
 210         if(!W_CheckProjectileDamage(inflictor.realowner, self.realowner, deathtype, -1)) // no exceptions
 211                 return; // g_projectiles_damage says to halt
 212
 213         if(self.realowner == attacker)
 214                 self.health = self.health - (damage * 0.25);
 215         else
 216                 self.health = self.health - damage;
 217
 218         if(self.health <= 0)
 219                 W_PrepareExplosionByDamage(attacker, W_Seeker_Missile_Explode);
 220 }
 221
 222 /*
 223 void W_Seeker_Missile_Animate(void)
 224 {
 225         self.frame = self.frame +1;
 226         self.nextthink = time + 0.05;
 227
 228         if(self.enemy != world)
 229                 if(self.enemy.takedamage != DAMAGE_AIM || self.enemy.deadflag != DEAD_NO)
 230                         self.enemy = world;
 231
 232         if(self.frame == 5)
 233         {
 234                 self.think           = W_Seeker_Missile_Think;
 235                 self.nextthink       = time;// + cvar("g_balance_seeker_missile_activate_delay"); // cant dealy with csqc projectiles
 236
 237                 if(autocvar_g_balance_seeker_missile_proxy)
 238                         self.movetype    = MOVETYPE_BOUNCEMISSILE;
 239                 else
 240                         self.movetype    = MOVETYPE_FLYMISSILE;
 241         }
 242
 243         UpdateCSQCProjectile(self);
 244 }
 245 */
 246
 247 void W_Seeker_Fire_Missile(vector f_diff, entity m_target)
 248 {SELFPARAM();
 249         entity missile;
 250
 251         W_DecreaseAmmo(WEP_CVAR(seeker, missile_ammo));
 252
 253         makevectors(self.v_angle);
 254         W_SetupShot_ProjectileSize(self, '-2 -2 -2', '2 2 2', false, 2, SND(SEEKER_FIRE), CH_WEAPON_A, 0);
 255         w_shotorg += f_diff;
 256         Send_Effect(EFFECT_SEEKER_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 257
 258         //self.detornator         = false;
 259
 260         missile                 = spawn();
 261         missile.owner           = missile.realowner = self;
 262         missile.classname       = "seeker_missile";
 263         missile.bot_dodge       = true;
 264         missile.bot_dodgerating = WEP_CVAR(seeker, missile_damage);
 265
 266         missile.think           = W_Seeker_Missile_Think;
 267         missile.touch           = W_Seeker_Missile_Touch;
 268         missile.event_damage    = W_Seeker_Missile_Damage;
 269         missile.nextthink       = time;// + 0.2;// + cvar("g_balance_seeker_missile_activate_delay");
 270         missile.cnt             = time + WEP_CVAR(seeker, missile_lifetime);
 271         missile.enemy           = m_target;
 272         missile.solid           = SOLID_BBOX;
 273         missile.scale           = 2;
 274         missile.takedamage      = DAMAGE_YES;
 275         missile.health          = WEP_CVAR(seeker, missile_health);
 276         missile.damageforcescale = WEP_CVAR(seeker, missile_damageforcescale);
 277         missile.damagedbycontents = true;
 278         //missile.think           = W_Seeker_Missile_Animate; // csqc projectiles.
 279
 280         if(missile.enemy != world)
 281                 missile.projectiledeathtype = WEP_SEEKER.m_id | HITTYPE_SECONDARY;
 282         else
 283                 missile.projectiledeathtype = WEP_SEEKER.m_id;
 284
 285
 286         setorigin(missile, w_shotorg);
 287         setsize(missile, '-4 -4 -4', '4 4 4');
 288         missile.movetype    = MOVETYPE_FLYMISSILE;
 289         missile.flags       = FL_PROJECTILE;
 290         missile.missile_flags = MIF_SPLASH | MIF_GUIDED_TAG;
 291
 292         W_SetupProjVelocity_UP_PRE(missile, seeker, missile_);
 293
 294         missile.angles = vectoangles(missile.velocity);
 295
 296         CSQCProjectile(missile, false, PROJECTILE_SEEKER, true);
 297
 298         MUTATOR_CALLHOOK(EditProjectile, self, missile);
 299 }
 300
 301 // ============================
 302 // Begin: FLAC, close range attack meant for defeating rockets which are coming at you.
 303 // ============================
 304 void W_Seeker_Flac_Explode(void)
 305 {SELFPARAM();
 306         self.event_damage = func_null;
 307
 308         RadiusDamage(self, self.realowner, WEP_CVAR(seeker, flac_damage), WEP_CVAR(seeker, flac_edgedamage), WEP_CVAR(seeker, flac_radius), world, world, WEP_CVAR(seeker, flac_force), self.projectiledeathtype, other);
 309
 310         remove(self);
 311 }
 312
 313 void W_Seeker_Flac_Touch(void)
 314 {
 315         PROJECTILE_TOUCH;
 316
 317         W_Seeker_Flac_Explode();
 318 }
 319
 320 void W_Seeker_Fire_Flac(void)
 321 {SELFPARAM();
 322         entity missile;
 323         vector f_diff;
 324         float c;
 325
 326         W_DecreaseAmmo(WEP_CVAR(seeker, flac_ammo));
 327
 328         c = self.bulletcounter % 4;
 329         switch(c)
 330         {
 331                 case 0:
 332                         f_diff = '-1.25 -3.75 0';
 333                         break;
 334                 case 1:
 335                         f_diff = '+1.25 -3.75 0';
 336                         break;
 337                 case 2:
 338                         f_diff = '-1.25 +3.75 0';
 339                         break;
 340                 case 3:
 341                 default:
 342                         f_diff = '+1.25 +3.75 0';
 343                         break;
 344         }
 345         W_SetupShot_ProjectileSize(self, '-2 -2 -2', '2 2 2', false, 2, SND(FLAC_FIRE), CH_WEAPON_A, WEP_CVAR(seeker, flac_damage));
 346         w_shotorg += f_diff;
 347
 348         Send_Effect(EFFECT_HAGAR_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 349
 350         missile                                 = spawn();
 351         missile.owner                   = missile.realowner = self;
 352         missile.classname               = "missile";
 353         missile.bot_dodge               = true;
 354         missile.bot_dodgerating = WEP_CVAR(seeker, flac_damage);
 355         missile.touch                   = W_Seeker_Flac_Explode;
 356         missile.use                     = W_Seeker_Flac_Explode;
 357         missile.think                   = adaptor_think2use_hittype_splash;
 358         missile.nextthink               = time + WEP_CVAR(seeker, flac_lifetime) + WEP_CVAR(seeker, flac_lifetime_rand);
 359         missile.solid                   = SOLID_BBOX;
 360         missile.movetype                = MOVETYPE_FLY;
 361         missile.projectiledeathtype = WEP_SEEKER.m_id;
 362         missile.projectiledeathtype = WEP_SEEKER.m_id | HITTYPE_SECONDARY;
 363         missile.flags                           = FL_PROJECTILE;
 364         missile.missile_flags       = MIF_SPLASH;
 365
 366         // csqc projectiles
 367         //missile.angles                                = vectoangles(missile.velocity);
 368         //missile.scale = 0.4; // BUG: the model is too big
 369
 370         setorigin(missile, w_shotorg);
 371         setsize(missile, '-2 -2 -2', '2 2 2');
 372
 373         W_SetupProjVelocity_UP_PRE(missile, seeker, flac_);
 374         CSQCProjectile(missile, true, PROJECTILE_FLAC, true);
 375
 376         MUTATOR_CALLHOOK(EditProjectile, self, missile);
 377 }
 378
 379 // ============================
 380 // Begin: Tag and rocket controllers
 381 // ============================
 382 entity W_Seeker_Tagged_Info(entity isowner, entity istarget)
 383 {
 384         entity tag;
 385         for(tag = world; (tag = find(tag, classname, "tag_tracker")); )
 386                 if((tag.realowner == isowner) && (tag.tag_target == istarget))
 387                         return tag;
 388
 389         return world;
 390 }
 391
 392 void W_Seeker_Attack(void)
 393 {SELFPARAM();
 394         entity tracker, closest_target;
 395
 396         closest_target = world;
 397         for(tracker = world; (tracker = find(tracker, classname, "tag_tracker")); ) if (tracker.realowner == self)
 398         {
 399                 if(closest_target)
 400                 {
 401                         if(vlen(self.origin - tracker.tag_target.origin) < vlen(self.origin - closest_target.origin))
 402                                 closest_target = tracker.tag_target;
 403                 }
 404                 else
 405                         closest_target = tracker.tag_target;
 406         }
 407
 408         traceline(self.origin + self.view_ofs, closest_target.origin, MOVE_NOMONSTERS, self);
 409         if((!closest_target) || ((trace_fraction < 1) && (trace_ent != closest_target)))
 410                 closest_target = world;
 411
 412         W_Seeker_Fire_Missile('0 0 0', closest_target);
 413 }
 414
 415 void W_Seeker_Vollycontroller_Think(void) // TODO: Merge this with W_Seeker_Attack
 416 {SELFPARAM();
 417         float c;
 418         entity oldenemy;
 419         self.cnt = self.cnt - 1;
 420
 421         if((!(self.realowner.items & IT_UNLIMITED_AMMO) && self.realowner.WEP_AMMO(SEEKER) < WEP_CVAR(seeker, missile_ammo)) || (self.cnt <= -1) || (self.realowner.deadflag != DEAD_NO) || (self.realowner.switchweapon != WEP_SEEKER.m_id))
 422         {
 423                 remove(self);
 424                 return;
 425         }
 426
 427         self.nextthink = time + WEP_CVAR(seeker, missile_delay) * W_WeaponRateFactor();
 428
 429         setself(self.realowner);
 430
 431         oldenemy = self.enemy;
 432         self.enemy = this.enemy;
 433
 434         c = self.cnt % 4;
 435         switch(c)
 436         {
 437                 case 0:
 438                         W_Seeker_Fire_Missile('-1.25 -3.75 0', self.enemy);
 439                         break;
 440                 case 1:
 441                         W_Seeker_Fire_Missile('+1.25 -3.75 0', self.enemy);
 442                         break;
 443                 case 2:
 444                         W_Seeker_Fire_Missile('-1.25 +3.75 0', self.enemy);
 445                         break;
 446                 case 3:
 447                 default:
 448                         W_Seeker_Fire_Missile('+1.25 +3.75 0', self.enemy);
 449                         break;
 450         }
 451
 452         self.enemy = oldenemy;
 453         setself(this);
 454 }
 455
 456 void W_Seeker_Tracker_Think(void)
 457 {SELFPARAM();
 458         // commit suicide if: You die OR target dies OR you switch away from the seeker OR commit suicide if lifetime is up
 459         if((self.realowner.deadflag != DEAD_NO) || (self.tag_target.deadflag != DEAD_NO) || (self.realowner.switchweapon != WEP_SEEKER.m_id)
 460         || (time > self.tag_time + WEP_CVAR(seeker, tag_tracker_lifetime)))
 461         {
 462                 if(self)
 463                 {
 464                         WaypointSprite_Kill(self.tag_target.wps_tag_tracker);
 465                         remove(self);
 466                 }
 467                 return;
 468         }
 469
 470         // Update the think method information
 471         self.nextthink = time;
 472 }
 473
 474 // ============================
 475 // Begin: Tag projectile
 476 // ============================
 477 void W_Seeker_Tag_Explode(void)
 478 {SELFPARAM();
 479         //if(other==self.realowner)
 480         //    return;
 481         Damage_DamageInfo(self.origin, 0, 0, 0, self.velocity, WEP_SEEKER.m_id | HITTYPE_BOUNCE, other.species, self);
 482
 483         remove(self);
 484 }
 485
 486 void W_Seeker_Tag_Damage(entity inflictor, entity attacker, float damage, int deathtype, vector hitloc, vector force)
 487 {SELFPARAM();
 488         if(self.health <= 0)
 489                 return;
 490         self.health = self.health - damage;
 491         if(self.health <= 0)
 492                 W_Seeker_Tag_Explode();
 493 }
 494
 495 void W_Seeker_Tag_Touch(void)
 496 {SELFPARAM();
 497         vector dir;
 498         vector org2;
 499         entity e;
 500
 501         PROJECTILE_TOUCH;
 502
 503         dir     = normalize(self.realowner.origin - self.origin);
 504         org2    = findbetterlocation(self.origin, 8);
 505
 506         te_knightspike(org2);
 507
 508         self.event_damage = func_null;
 509         Damage_DamageInfo(self.origin, 0, 0, 0, self.velocity, WEP_SEEKER.m_id | HITTYPE_BOUNCE | HITTYPE_SECONDARY, other.species, self);
 510
 511         if(other.takedamage == DAMAGE_AIM && other.deadflag == DEAD_NO)
 512         {
 513                 // check to see if this person is already tagged by me
 514                 entity tag = W_Seeker_Tagged_Info(self.realowner, other);
 515
 516                 if(tag != world)
 517                 {
 518                         if(other.wps_tag_tracker && (WEP_CVAR(seeker, type) == 1)) // don't attach another waypointsprite without killing the old one first
 519                                 WaypointSprite_Kill(other.wps_tag_tracker);
 520
 521                         tag.tag_time = time;
 522                 }
 523                 else
 524                 {
 525                         //sprint(self.realowner, strcat("You just tagged ^2", other.netname, "^7 with a tracking device!\n"));
 526                         e             = spawn();
 527                         e.cnt         = WEP_CVAR(seeker, missile_count);
 528                         e.classname   = "tag_tracker";
 529                         e.owner       = self.owner;
 530                         e.realowner   = self.realowner;
 531
 532                         if(WEP_CVAR(seeker, type) == 1)
 533                         {
 534                                 e.tag_target  = other;
 535                                 e.tag_time    = time;
 536                                 e.think       = W_Seeker_Tracker_Think;
 537                         }
 538                         else
 539                         {
 540                                 e.enemy     = other;
 541                                 e.think     = W_Seeker_Vollycontroller_Think;
 542                         }
 543
 544                         e.nextthink   = time;
 545                 }
 546
 547                 if(WEP_CVAR(seeker, type) == 1)
 548                 {
 549                         WaypointSprite_Spawn(WP_Seeker, WEP_CVAR(seeker, tag_tracker_lifetime), 0, other, '0 0 64', self.realowner, 0, other, wps_tag_tracker, true, RADARICON_TAGGED);
 550                         WaypointSprite_UpdateRule(other.wps_tag_tracker, 0, SPRITERULE_DEFAULT);
 551                 }
 552         }
 553
 554         remove(self);
 555         return;
 556 }
 557
 558 void W_Seeker_Fire_Tag(void)
 559 {SELFPARAM();
 560         entity missile;
 561         W_DecreaseAmmo(WEP_CVAR(seeker, tag_ammo));
 562
 563         W_SetupShot_ProjectileSize(self, '-2 -2 -2', '2 2 2', false, 2, SND(TAG_FIRE), CH_WEAPON_A, WEP_CVAR(seeker, missile_damage) * WEP_CVAR(seeker, missile_count));
 564
 565         missile                 = spawn();
 566         missile.owner           = missile.realowner = self;
 567         missile.classname       = "seeker_tag";
 568         missile.bot_dodge       = true;
 569         missile.bot_dodgerating = 50;
 570         missile.touch           = W_Seeker_Tag_Touch;
 571         missile.think           = SUB_Remove;
 572         missile.nextthink       = time + WEP_CVAR(seeker, tag_lifetime);
 573         missile.movetype        = MOVETYPE_FLY;
 574         missile.solid           = SOLID_BBOX;
 575
 576         missile.takedamage       = DAMAGE_YES;
 577         missile.event_damage     = W_Seeker_Tag_Damage;
 578         missile.health           = WEP_CVAR(seeker, tag_health);
 579         missile.damageforcescale = WEP_CVAR(seeker, tag_damageforcescale);
 580
 581         setorigin(missile, w_shotorg);
 582         setsize(missile, '-2 -2 -2', '2 2 2');
 583
 584         missile.flags       = FL_PROJECTILE;
 585         //missile.missile_flags = MIF_..?;
 586
 587         missile.movetype    = MOVETYPE_FLY;
 588         W_SetupProjVelocity_PRE(missile, seeker, tag_);
 589         missile.angles = vectoangles(missile.velocity);
 590
 591         CSQCProjectile(missile, true, PROJECTILE_TAG, false); // has sound
 592
 593         MUTATOR_CALLHOOK(EditProjectile, self, missile);
 594 }
 595
 596 // ============================
 597 // Begin: Genereal weapon functions
 598 // ============================
 599
 600 bool W_Seeker(entity thiswep, int req)
 601 {SELFPARAM();
 602         float ammo_amount;
 603
 604         switch(req)
 605         {
 606                 case WR_AIM:
 607                 {
 608                         if(WEP_CVAR(seeker, type) == 1)
 609                                 if(W_Seeker_Tagged_Info(self, self.enemy) != world)
 610                                         self.BUTTON_ATCK = bot_aim(WEP_CVAR(seeker, missile_speed_max), 0, WEP_CVAR(seeker, missile_lifetime), false);
 611                                 else
 612                                         self.BUTTON_ATCK2 = bot_aim(WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), false);
 613                         else
 614                                 self.BUTTON_ATCK = bot_aim(WEP_CVAR(seeker, tag_speed), 0, WEP_CVAR(seeker, tag_lifetime), false);
 615                         return true;
 616                 }
 617                 case WR_THINK:
 618                 {
 619                         if(autocvar_g_balance_seeker_reload_ammo && self.clip_load < min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo))) // forced reload
 620                                 _WEP_ACTION(self.weapon, WR_RELOAD);
 621
 622                         else if(self.BUTTON_ATCK)
 623                         {
 624                                 if(WEP_CVAR(seeker, type) == 1)
 625                                 {
 626                                         if(weapon_prepareattack(0, WEP_CVAR(seeker, missile_refire)))
 627                                         {
 628                                                 W_Seeker_Attack();
 629                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, missile_animtime), w_ready);
 630                                         }
 631                                 }
 632                                 else
 633                                 {
 634                                         if(weapon_prepareattack(0, WEP_CVAR(seeker, tag_refire)))
 635                                         {
 636                                                 W_Seeker_Fire_Tag();
 637                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 638                                         }
 639                                 }
 640                         }
 641
 642                         else if(self.BUTTON_ATCK2)
 643                         {
 644                                 if(WEP_CVAR(seeker, type) == 1)
 645                                 {
 646                                         if(weapon_prepareattack(0, WEP_CVAR(seeker, tag_refire)))
 647                                         {
 648                                                 W_Seeker_Fire_Tag();
 649                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, tag_animtime), w_ready);
 650                                         }
 651                                 }
 652                                 else
 653                                 {
 654                                         if(weapon_prepareattack(0, WEP_CVAR(seeker, flac_refire)))
 655                                         {
 656                                                 W_Seeker_Fire_Flac();
 657                                                 weapon_thinkf(WFRAME_FIRE2, WEP_CVAR(seeker, flac_animtime), w_ready);
 658                                         }
 659                                 }
 660                         }
 661
 662                         return true;
 663                 }
 664                 case WR_INIT:
 665                 {
 666                         SEEKER_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
 667                         return true;
 668                 }
 669                 case WR_CHECKAMMO1:
 670                 {
 671                         if(WEP_CVAR(seeker, type) == 1)
 672                         {
 673                                 ammo_amount = self.WEP_AMMO(SEEKER) >= WEP_CVAR(seeker, missile_ammo);
 674                                 ammo_amount += self.(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, missile_ammo);
 675                         }
 676                         else
 677                         {
 678                                 ammo_amount = self.WEP_AMMO(SEEKER) >= WEP_CVAR(seeker, tag_ammo);
 679                                 ammo_amount += self.(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, tag_ammo);
 680                         }
 681                         return ammo_amount;
 682                 }
 683                 case WR_CHECKAMMO2:
 684                 {
 685                         if(WEP_CVAR(seeker, type) == 1)
 686                         {
 687                                 ammo_amount = self.WEP_AMMO(SEEKER) >= WEP_CVAR(seeker, tag_ammo);
 688                                 ammo_amount += self.(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, tag_ammo);
 689                         }
 690                         else
 691                         {
 692                                 ammo_amount = self.WEP_AMMO(SEEKER) >= WEP_CVAR(seeker, flac_ammo);
 693                                 ammo_amount += self.(weapon_load[WEP_SEEKER.m_id]) >= WEP_CVAR(seeker, flac_ammo);
 694                         }
 695                         return ammo_amount;
 696                 }
 697                 case WR_CONFIG:
 698                 {
 699                         SEEKER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
 700                         return true;
 701                 }
 702                 case WR_RELOAD:
 703                 {
 704                         W_Reload(min(WEP_CVAR(seeker, missile_ammo), WEP_CVAR(seeker, tag_ammo)), SND(RELOAD));
 705                         return true;
 706                 }
 707                 case WR_SUICIDEMESSAGE:
 708                 {
 709                         return WEAPON_SEEKER_SUICIDE;
 710                 }
 711                 case WR_KILLMESSAGE:
 712                 {
 713                         if(w_deathtype & HITTYPE_SECONDARY)
 714                                 return WEAPON_SEEKER_MURDER_TAG;
 715                         else
 716                                 return WEAPON_SEEKER_MURDER_SPRAY;
 717                 }
 718         }
 719         return false;
 720 }
 721 #endif
 722 #ifdef CSQC
 723 bool W_Seeker(entity thiswep, int req)
 724 {SELFPARAM();
 725         switch(req)
 726         {
 727                 case WR_IMPACTEFFECT:
 728                 {
 729                         vector org2;
 730                         org2 = w_org + w_backoff * 6;
 731                         if(w_deathtype & HITTYPE_BOUNCE)
 732                         {
 733                                 if(w_deathtype & HITTYPE_SECONDARY)
 734                                 {
 735                                         if(!w_issilent)
 736                                                 sound(self, CH_SHOTS, SND_TAG_IMPACT, 1, ATTEN_NORM);
 737                                 }
 738                                 else
 739                                 {
 740                                         pointparticles(particleeffectnum(EFFECT_HAGAR_EXPLODE), org2, '0 0 0', 1);
 741                                         if(!w_issilent)
 742                                         {
 743                                                 if(w_random<0.15)
 744                                                         sound(self, CH_SHOTS, SND_TAGEXP1, 1, ATTEN_NORM);
 745                                                 else if(w_random<0.7)
 746                                                         sound(self, CH_SHOTS, SND_TAGEXP2, 1, ATTEN_NORM);
 747                                                 else
 748                                                         sound(self, CH_SHOTS, SND_TAGEXP3, 1, ATTEN_NORM);
 749                                         }
 750                                 }
 751                         }
 752                         else
 753                         {
 754                                 pointparticles(particleeffectnum(EFFECT_HAGAR_EXPLODE), org2, '0 0 0', 1);
 755                                 if(!w_issilent)
 756                                 {
 757                                         if(w_random<0.15)
 758                                                 sound(self, CH_SHOTS, SND_SEEKEREXP1, 1, ATTEN_NORM);
 759                                         else if(w_random<0.7)
 760                                                 sound(self, CH_SHOTS, SND_SEEKEREXP2, 1, ATTEN_NORM);
 761                                         else
 762                                                 sound(self, CH_SHOTS, SND_SEEKEREXP3, 1, ATTEN_NORM);
 763                                 }
 764                         }
 765                         return true;
 766                 }
 767                 case WR_INIT:
 768                 {
 769                         return true;
 770                 }
 771                 case WR_ZOOMRETICLE:
 772                 {
 773                         // no weapon specific image for this weapon
 774                         return false;
 775                 }
 776         }
 777         return false;
 778 }
 779 #endif
 780 #endif