]> de.git.xonotic.org Git - xonotic/xonotic-data.pk3dir.git/blob - qcsrc/common/weapons/weapon/shockwave.qc
Port ping, ping_packetloss and ping_movementloss to ClientState
[xonotic/xonotic-data.pk3dir.git] / qcsrc / common / weapons / weapon / shockwave.qc
1 #include "shockwave.qh"
2 #ifndef IMPLEMENTATION
3 CLASS(Shockwave, Weapon)
4 /* ammotype  */ //ATTRIB(Shockwave, ammo_field, .int, ammo_none);
5 /* impulse   */ ATTRIB(Shockwave, impulse, int, 2);
6 /* flags     */ ATTRIB(Shockwave, spawnflags, int, WEP_TYPE_HITSCAN | WEP_FLAG_CANCLIMB | WEP_TYPE_MELEE_SEC);
7 /* rating    */ ATTRIB(Shockwave, bot_pickupbasevalue, float, 3000);
8 /* color     */ ATTRIB(Shockwave, wpcolor, vector, '0.5 0.25 0');
9 /* modelname */ ATTRIB(Shockwave, mdl, string, "shotgun");
10 #ifdef GAMEQC
11 /* model     */ ATTRIB(Shockwave, m_model, Model, MDL_SHOCKWAVE_ITEM);
12 #endif
13 /* crosshair */ ATTRIB(Shockwave, w_crosshair, string, "gfx/crosshairshotgun");
14 /* crosshair */ ATTRIB(Shockwave, w_crosshair_size, float, 0.7);
15 /* wepimg    */ ATTRIB(Shockwave, model2, string, "weaponshockwave");
16 /* refname   */ ATTRIB(Shockwave, netname, string, "shockwave");
17 /* wepname   */ ATTRIB(Shockwave, m_name, string, _("Shockwave"));
18
19 #define X(BEGIN, P, END, class, prefix) \
20         BEGIN(class) \
21                 P(class, prefix, blast_animtime, float, NONE) \
22                 P(class, prefix, blast_damage, float, NONE) \
23                 P(class, prefix, blast_distance, float, NONE) \
24                 P(class, prefix, blast_edgedamage, float, NONE) \
25                 P(class, prefix, blast_force, float, NONE) \
26                 P(class, prefix, blast_force_forwardbias, float, NONE) \
27                 P(class, prefix, blast_force_zscale, float, NONE) \
28                 P(class, prefix, blast_jump_damage, float, NONE) \
29                 P(class, prefix, blast_jump_edgedamage, float, NONE) \
30                 P(class, prefix, blast_jump_force, float, NONE) \
31                 P(class, prefix, blast_jump_force_velocitybias, float, NONE) \
32                 P(class, prefix, blast_jump_force_zscale, float, NONE) \
33                 P(class, prefix, blast_jump_multiplier_accuracy, float, NONE) \
34                 P(class, prefix, blast_jump_multiplier_distance, float, NONE) \
35                 P(class, prefix, blast_jump_multiplier_min, float, NONE) \
36                 P(class, prefix, blast_jump_radius, float, NONE) \
37                 P(class, prefix, blast_multiplier_accuracy, float, NONE) \
38                 P(class, prefix, blast_multiplier_distance, float, NONE) \
39                 P(class, prefix, blast_multiplier_min, float, NONE) \
40                 P(class, prefix, blast_refire, float, NONE) \
41                 P(class, prefix, blast_splash_damage, float, NONE) \
42                 P(class, prefix, blast_splash_edgedamage, float, NONE) \
43                 P(class, prefix, blast_splash_force, float, NONE) \
44                 P(class, prefix, blast_splash_force_forwardbias, float, NONE) \
45                 P(class, prefix, blast_splash_multiplier_accuracy, float, NONE) \
46                 P(class, prefix, blast_splash_multiplier_distance, float, NONE) \
47                 P(class, prefix, blast_splash_multiplier_min, float, NONE) \
48                 P(class, prefix, blast_splash_radius, float, NONE) \
49                 P(class, prefix, blast_spread_max, float, NONE) \
50                 P(class, prefix, blast_spread_min, float, NONE) \
51                 P(class, prefix, melee_animtime, float, NONE) \
52                 P(class, prefix, melee_damage, float, NONE) \
53                 P(class, prefix, melee_delay, float, NONE) \
54                 P(class, prefix, melee_force, float, NONE) \
55                 P(class, prefix, melee_multihit, float, NONE) \
56                 P(class, prefix, melee_no_doubleslap, float, NONE) \
57                 P(class, prefix, melee_nonplayerdamage, float, NONE) \
58                 P(class, prefix, melee_range, float, NONE) \
59                 P(class, prefix, melee_refire, float, NONE) \
60                 P(class, prefix, melee_swing_side, float, NONE) \
61                 P(class, prefix, melee_swing_up, float, NONE) \
62                 P(class, prefix, melee_time, float, NONE) \
63                 P(class, prefix, melee_traces, float, NONE) \
64                 P(class, prefix, switchdelay_raise, float, NONE) \
65         P(class, prefix, switchdelay_drop, float, NONE) \
66         P(class, prefix, weaponreplace, string, NONE) \
67         P(class, prefix, weaponstart, float, NONE) \
68         P(class, prefix, weaponstartoverride, float, NONE) \
69         P(class, prefix, weaponthrowable, float, NONE) \
70         END()
71     W_PROPS(X, Shockwave, shockwave)
72 #undef X
73
74 ENDCLASS(Shockwave)
75 REGISTER_WEAPON(SHOCKWAVE, shockwave, NEW(Shockwave));
76
77
78 #ifdef CSQC
79 void Net_ReadShockwaveParticle();
80 .vector sw_shotorg;
81 .vector sw_shotdir;
82 .float sw_distance;
83 .float sw_spread_max;
84 .float sw_spread_min;
85 .float sw_time;
86 #endif
87 #endif
88 #ifdef IMPLEMENTATION
89
90 REGISTER_NET_TEMP(TE_CSQC_SHOCKWAVEPARTICLE)
91
92 #ifdef SVQC
93 spawnfunc(weapon_shockwave)
94 {
95         //if(autocvar_sv_q3acompat_machineshockwaveswap) // WEAPONTODO
96         if(autocvar_sv_q3acompat_machineshotgunswap)
97         if(this.classname != "droppedweapon")
98         {
99                 weapon_defaultspawnfunc(this, WEP_MACHINEGUN);
100                 return;
101         }
102         weapon_defaultspawnfunc(this, WEP_SHOCKWAVE);
103 }
104
105 const float MAX_SHOCKWAVE_HITS = 10;
106 //#define DEBUG_SHOCKWAVE
107
108 .float swing_prev;
109 .entity swing_alreadyhit;
110 .float shockwave_blasttime;
111 entity shockwave_hit[MAX_SHOCKWAVE_HITS];
112 float shockwave_hit_damage[MAX_SHOCKWAVE_HITS];
113 vector shockwave_hit_force[MAX_SHOCKWAVE_HITS];
114
115 // MELEE ATTACK MODE
116 void W_Shockwave_Melee_Think(entity this)
117 {
118         // declarations
119         float i, f, swing, swing_factor, swing_damage, meleetime, is_player;
120         entity target_victim;
121         vector targpos;
122
123         // check to see if we can still continue, otherwise give up now
124         if(IS_DEAD(this.realowner) && WEP_CVAR(shockwave, melee_no_doubleslap))
125         {
126                 delete(this);
127                 return;
128         }
129
130         // set start time of melee
131         if(!this.cnt)
132         {
133                 this.cnt = time;
134                 W_PlayStrengthSound(this.realowner);
135         }
136
137         // update values for v_* vectors
138         makevectors(this.realowner.v_angle);
139
140         // calculate swing percentage based on time
141         meleetime = WEP_CVAR(shockwave, melee_time) * W_WeaponRateFactor(this.realowner);
142         swing = bound(0, (this.cnt + meleetime - time) / meleetime, 10);
143         f = ((1 - swing) * WEP_CVAR(shockwave, melee_traces));
144
145         // perform the traces needed for this frame
146         for(i=this.swing_prev; i < f; ++i)
147         {
148                 swing_factor = ((1 - (i / WEP_CVAR(shockwave, melee_traces))) * 2 - 1);
149
150                 targpos = (this.realowner.origin + this.realowner.view_ofs
151                         + (v_forward * WEP_CVAR(shockwave, melee_range))
152                         + (v_up * swing_factor * WEP_CVAR(shockwave, melee_swing_up))
153                         + (v_right * swing_factor * WEP_CVAR(shockwave, melee_swing_side)));
154
155                 WarpZone_traceline_antilag(
156                         this.realowner,
157                         (this.realowner.origin + this.realowner.view_ofs),
158                         targpos,
159                         false,
160                         this.realowner,
161                         ANTILAG_LATENCY(this.realowner)
162                 );
163
164                 // draw lightning beams for debugging
165 #ifdef DEBUG_SHOCKWAVE
166                 te_lightning2(NULL, targpos, this.realowner.origin + this.realowner.view_ofs + v_forward * 5 - v_up * 5);
167                 te_customflash(targpos, 40,  2, '1 1 1');
168 #endif
169
170                 is_player = (IS_PLAYER(trace_ent) || trace_ent.classname == "body" || IS_MONSTER(trace_ent));
171
172                 if((trace_fraction < 1) // if trace is good, apply the damage and remove this if necessary
173                         && (trace_ent.takedamage == DAMAGE_AIM)
174                         && (trace_ent != this.swing_alreadyhit)
175                         && (is_player || WEP_CVAR(shockwave, melee_nonplayerdamage)))
176                 {
177                         target_victim = trace_ent; // so it persists through other calls
178
179                         if(is_player) // this allows us to be able to nerf the non-player damage done in e.g. assault or onslaught
180                                 swing_damage = (WEP_CVAR(shockwave, melee_damage) * min(1, swing_factor + 1));
181                         else
182                                 swing_damage = (WEP_CVAR(shockwave, melee_nonplayerdamage) * min(1, swing_factor + 1));
183
184                         // trigger damage with this calculated info
185                         Damage(
186                                 target_victim,
187                                 this.realowner,
188                                 this.realowner,
189                                 swing_damage,
190                                 (WEP_SHOCKWAVE.m_id | HITTYPE_SECONDARY),
191                                 (this.realowner.origin + this.realowner.view_ofs),
192                                 (v_forward * WEP_CVAR(shockwave, melee_force))
193                         );
194
195                         // handle accuracy
196                         if(accuracy_isgooddamage(this.realowner, target_victim))
197                                 { accuracy_add(this.realowner, WEP_SHOCKWAVE.m_id, 0, swing_damage); }
198
199                         #ifdef DEBUG_SHOCKWAVE
200                         LOG_INFO(sprintf(
201                                 "MELEE: %s hitting %s with %f damage (factor: %f) at %f time.\n",
202                                 this.realowner.netname,
203                                 target_victim.netname,
204                                 swing_damage,
205                                 swing_factor,
206                                 time
207                         ));
208                         #endif
209
210                         // allow multiple hits with one swing, but not against the same player twice
211                         if(WEP_CVAR(shockwave, melee_multihit))
212                         {
213                                 this.swing_alreadyhit = target_victim;
214                                 continue; // move along to next trace
215                         }
216                         else
217                         {
218                                 delete(this);
219                                 return;
220                         }
221                 }
222         }
223
224         if(time >= this.cnt + meleetime)
225         {
226                 // melee is finished
227                 delete(this);
228                 return;
229         }
230         else
231         {
232                 // set up next frame
233                 this.swing_prev = i;
234                 this.nextthink = time;
235         }
236 }
237
238 void W_Shockwave_Melee(Weapon thiswep, entity actor, .entity weaponentity, int fire)
239 {
240         sound(actor, CH_WEAPON_A, SND_SHOTGUN_MELEE, VOL_BASE, ATTN_NORM);
241         weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR(shockwave, melee_animtime), w_ready);
242
243         entity meleetemp = new_pure(meleetemp);
244         meleetemp.owner = meleetemp.realowner = actor;
245         setthink(meleetemp, W_Shockwave_Melee_Think);
246         meleetemp.nextthink = time + WEP_CVAR(shockwave, melee_delay) * W_WeaponRateFactor(actor);
247         W_SetupShot_Range(actor, weaponentity, true, 0, SND_Null, 0, WEP_CVAR(shockwave, melee_damage), WEP_CVAR(shockwave, melee_range));
248 }
249
250 // SHOCKWAVE ATTACK MODE
251 float W_Shockwave_Attack_CheckSpread(
252         vector targetorg,
253         vector nearest_on_line,
254         vector sw_shotorg,
255         vector attack_endpos)
256 {
257         float spreadlimit;
258         float distance_of_attack = vlen(sw_shotorg - attack_endpos);
259         float distance_from_line = vlen(targetorg - nearest_on_line);
260
261         spreadlimit = (distance_of_attack ? min(1, (vlen(sw_shotorg - nearest_on_line) / distance_of_attack)) : 1);
262         spreadlimit =
263                 (
264                         (WEP_CVAR(shockwave, blast_spread_min) * (1 - spreadlimit))
265                         +
266                         (WEP_CVAR(shockwave, blast_spread_max) * spreadlimit)
267                 );
268
269         if(
270                 (spreadlimit && (distance_from_line <= spreadlimit))
271                 &&
272                 ((vlen(normalize(targetorg - sw_shotorg) - normalize(attack_endpos - sw_shotorg)) * RAD2DEG) <= 90)
273         )
274                 { return bound(0, (distance_from_line / spreadlimit), 1); }
275         else
276                 { return false; }
277 }
278
279 float W_Shockwave_Attack_IsVisible(
280         entity actor,
281         entity head,
282         vector nearest_on_line,
283         vector sw_shotorg,
284         vector attack_endpos)
285 {
286         vector nearest_to_attacker = head.WarpZone_findradius_nearest;
287         vector center = (head.origin + (head.mins + head.maxs) * 0.5);
288         vector corner;
289         float i;
290
291         // STEP ONE: Check if the nearest point is clear
292         if(W_Shockwave_Attack_CheckSpread(nearest_to_attacker, nearest_on_line, sw_shotorg, attack_endpos))
293         {
294                 WarpZone_TraceLine(sw_shotorg, nearest_to_attacker, MOVE_NOMONSTERS, actor);
295                 if(trace_fraction == 1) { return true; } // yes, the nearest point is clear and we can allow the damage
296         }
297
298         // STEP TWO: Check if shotorg to center point is clear
299         if(W_Shockwave_Attack_CheckSpread(center, nearest_on_line, sw_shotorg, attack_endpos))
300         {
301                 WarpZone_TraceLine(sw_shotorg, center, MOVE_NOMONSTERS, actor);
302                 if(trace_fraction == 1) { return true; } // yes, the center point is clear and we can allow the damage
303         }
304
305         // STEP THREE: Check each corner to see if they are clear
306         for(i=1; i<=8; ++i)
307         {
308                 corner = get_corner_position(head, i);
309                 if(W_Shockwave_Attack_CheckSpread(corner, nearest_on_line, sw_shotorg, attack_endpos))
310                 {
311                         WarpZone_TraceLine(sw_shotorg, corner, MOVE_NOMONSTERS, actor);
312                         if(trace_fraction == 1) { return true; } // yes, this corner is clear and we can allow the damage
313                 }
314         }
315
316         return false;
317 }
318
319 float W_Shockwave_Attack_CheckHit(
320         float queue,
321         entity head,
322         vector final_force,
323         float final_damage)
324 {
325         if(!head) { return false; }
326         float i;
327
328         for(i = 0; i <= queue; ++i)
329         {
330                 if(shockwave_hit[i] == head)
331                 {
332                         if(vlen2(final_force) > vlen2(shockwave_hit_force[i])) { shockwave_hit_force[i] = final_force; }
333                         if(final_damage > shockwave_hit_damage[i]) { shockwave_hit_damage[i] = final_damage; }
334                         return false;
335                 }
336         }
337
338         shockwave_hit[queue] = head;
339         shockwave_hit_force[queue] = final_force;
340         shockwave_hit_damage[queue] = final_damage;
341         return true;
342 }
343
344 void W_Shockwave_Send(entity actor)
345 {
346         WriteHeader(MSG_BROADCAST, TE_CSQC_SHOCKWAVEPARTICLE);
347         WriteCoord(MSG_BROADCAST, w_shotorg.x);
348         WriteCoord(MSG_BROADCAST, w_shotorg.y);
349         WriteCoord(MSG_BROADCAST, w_shotorg.z);
350         WriteCoord(MSG_BROADCAST, w_shotdir.x);
351         WriteCoord(MSG_BROADCAST, w_shotdir.y);
352         WriteCoord(MSG_BROADCAST, w_shotdir.z);
353         WriteShort(MSG_BROADCAST, WEP_CVAR(shockwave, blast_distance));
354         WriteByte(MSG_BROADCAST, bound(0, WEP_CVAR(shockwave, blast_spread_max), 255));
355         WriteByte(MSG_BROADCAST, bound(0, WEP_CVAR(shockwave, blast_spread_min), 255));
356         WriteByte(MSG_BROADCAST, etof(actor));
357 }
358
359 void W_Shockwave_Attack(entity actor, .entity weaponentity)
360 {
361         // declarations
362         float multiplier, multiplier_from_accuracy, multiplier_from_distance;
363         float final_damage;
364         vector final_force, center, vel;
365         entity head;
366
367         float i, queue = 0;
368
369         // set up the shot direction
370         W_SetupShot(actor, weaponentity, true, 3, SND_LASERGUN_FIRE, CH_WEAPON_B, WEP_CVAR(shockwave, blast_damage));
371         vector attack_endpos = (w_shotorg + (w_shotdir * WEP_CVAR(shockwave, blast_distance)));
372         WarpZone_TraceLine(w_shotorg, attack_endpos, MOVE_NOMONSTERS, actor);
373         vector attack_hitpos = trace_endpos;
374         float distance_to_end = vlen(w_shotorg - attack_endpos);
375         float distance_to_hit = vlen(w_shotorg - attack_hitpos);
376         //entity transform = WarpZone_trace_transform;
377
378         // do the firing effect now
379         W_Shockwave_Send(actor);
380         Damage_DamageInfo(
381                 attack_hitpos,
382                 WEP_CVAR(shockwave, blast_splash_damage),
383                 WEP_CVAR(shockwave, blast_splash_edgedamage),
384                 WEP_CVAR(shockwave, blast_splash_radius),
385                 w_shotdir * WEP_CVAR(shockwave, blast_splash_force),
386                 WEP_SHOCKWAVE.m_id,
387                 0,
388                 actor
389         );
390
391         // splash damage/jumping trace
392         head = WarpZone_FindRadius(
393                 attack_hitpos,
394                 max(
395                         WEP_CVAR(shockwave, blast_splash_radius),
396                         WEP_CVAR(shockwave, blast_jump_radius)
397                 ),
398                 false
399         );
400
401         float lag = ((IS_REAL_CLIENT(actor)) ? ANTILAG_LATENCY(actor) : 0);
402         if(lag < 0.001)
403                 lag = 0;
404         if(autocvar_g_antilag == 0 || actor.cvar_cl_noantilag)
405                 lag = 0; // only do hitscan, but no antilag
406         if(lag)
407         {
408                 FOREACH_CLIENT(IS_PLAYER(it) && it != actor, antilag_takeback(it, CS(it), time - lag));
409                 IL_EACH(g_monsters, it != actor,
410                 {
411                         antilag_takeback(it, it, time - lag);
412                 });
413         }
414
415         while(head)
416         {
417                 if(head.takedamage)
418                 {
419                         float distance_to_head = vlen(attack_hitpos - head.WarpZone_findradius_nearest);
420
421                         if((head == actor) && (distance_to_head <= WEP_CVAR(shockwave, blast_jump_radius)))
422                         {
423                                 // ========================
424                                 //  BLAST JUMP CALCULATION
425                                 // ========================
426
427                                 // calculate importance of distance and accuracy for this attack
428                                 multiplier_from_accuracy = (1 -
429                                         (distance_to_head ?
430                                                 min(1, (distance_to_head / WEP_CVAR(shockwave, blast_jump_radius)))
431                                                 :
432                                                 0
433                                         )
434                                 );
435                                 multiplier_from_distance = (1 -
436                                         (distance_to_hit ?
437                                                 min(1, (distance_to_hit / distance_to_end))
438                                                 :
439                                                 0
440                                         )
441                                 );
442                                 multiplier =
443                                         max(
444                                                 WEP_CVAR(shockwave, blast_jump_multiplier_min),
445                                                 (
446                                                         (multiplier_from_accuracy * WEP_CVAR(shockwave, blast_jump_multiplier_accuracy))
447                                                         +
448                                                         (multiplier_from_distance * WEP_CVAR(shockwave, blast_jump_multiplier_distance))
449                                                 )
450                                         );
451
452                                 // calculate damage from multiplier: 1 = "highest" damage, 0 = "lowest" edgedamage
453                                 final_damage =
454                                         (
455                                                 (WEP_CVAR(shockwave, blast_jump_damage) * multiplier)
456                                                 +
457                                                 (WEP_CVAR(shockwave, blast_jump_edgedamage) * (1 - multiplier))
458                                         );
459
460                                 // figure out the direction of force
461                                 vel = normalize(vec2(head.velocity));
462                                 vel *=
463                                         (
464                                                 bound(0, (vlen(vel) / autocvar_sv_maxspeed), 1)
465                                                 *
466                                                 WEP_CVAR(shockwave, blast_jump_force_velocitybias)
467                                         );
468                                 final_force = normalize((CENTER_OR_VIEWOFS(head) - attack_hitpos) + vel);
469
470                                 // now multiply the direction by force units
471                                 final_force *= (WEP_CVAR(shockwave, blast_jump_force) * multiplier);
472                                 final_force.z *= WEP_CVAR(shockwave, blast_jump_force_zscale);
473
474                                 // trigger damage with this calculated info
475                                 Damage(
476                                         head,
477                                         actor,
478                                         actor,
479                                         final_damage,
480                                         WEP_SHOCKWAVE.m_id,
481                                         head.origin,
482                                         final_force
483                                 );
484
485                                 #ifdef DEBUG_SHOCKWAVE
486                                 LOG_INFO(sprintf(
487                                         "SELF HIT: multiplier = %f, damage = %f, force = %f... "
488                                         "multiplier_from_accuracy = %f, multiplier_from_distance = %f.\n",
489                                         multiplier,
490                                         final_damage,
491                                         vlen(final_force),
492                                         multiplier_from_accuracy,
493                                         multiplier_from_distance
494                                 ));
495                                 #endif
496                         }
497                         else if(distance_to_head <= WEP_CVAR(shockwave, blast_splash_radius))
498                         {
499                                 // ==========================
500                                 //  BLAST SPLASH CALCULATION
501                                 // ==========================
502
503                                 // calculate importance of distance and accuracy for this attack
504                                 multiplier_from_accuracy = (1 -
505                                         (distance_to_head ?
506                                                 min(1, (distance_to_head / WEP_CVAR(shockwave, blast_splash_radius)))
507                                                 :
508                                                 0
509                                         )
510                                 );
511                                 multiplier_from_distance = (1 -
512                                         (distance_to_hit ?
513                                                 min(1, (distance_to_hit / distance_to_end))
514                                                 :
515                                                 0
516                                         )
517                                 );
518                                 multiplier =
519                                         max(
520                                                 WEP_CVAR(shockwave, blast_splash_multiplier_min),
521                                                 (
522                                                         (multiplier_from_accuracy * WEP_CVAR(shockwave, blast_splash_multiplier_accuracy))
523                                                         +
524                                                         (multiplier_from_distance * WEP_CVAR(shockwave, blast_splash_multiplier_distance))
525                                                 )
526                                         );
527
528                                 // calculate damage from multiplier: 1 = "highest" damage, 0 = "lowest" edgedamage
529                                 final_damage =
530                                         (
531                                                 (WEP_CVAR(shockwave, blast_splash_damage) * multiplier)
532                                                 +
533                                                 (WEP_CVAR(shockwave, blast_splash_edgedamage) * (1 - multiplier))
534                                         );
535
536                                 // figure out the direction of force
537                                 final_force = (w_shotdir * WEP_CVAR(shockwave, blast_splash_force_forwardbias));
538                                 final_force = normalize(CENTER_OR_VIEWOFS(head) - (attack_hitpos - final_force));
539                                 //te_lightning2(NULL, attack_hitpos, (attack_hitpos + (final_force * 200)));
540
541                                 // now multiply the direction by force units
542                                 final_force *= (WEP_CVAR(shockwave, blast_splash_force) * multiplier);
543                                 final_force.z *= WEP_CVAR(shockwave, blast_force_zscale);
544
545                                 // queue damage with this calculated info
546                                 if(W_Shockwave_Attack_CheckHit(queue, head, final_force, final_damage)) { queue = min(queue + 1, MAX_SHOCKWAVE_HITS); }
547
548                                 #ifdef DEBUG_SHOCKWAVE
549                                 LOG_INFO(sprintf(
550                                         "SPLASH HIT: multiplier = %f, damage = %f, force = %f... "
551                                         "multiplier_from_accuracy = %f, multiplier_from_distance = %f.\n",
552                                         multiplier,
553                                         final_damage,
554                                         vlen(final_force),
555                                         multiplier_from_accuracy,
556                                         multiplier_from_distance
557                                 ));
558                                 #endif
559                         }
560                 }
561                 head = head.chain;
562         }
563
564         // cone damage trace
565         head = WarpZone_FindRadius(w_shotorg, WEP_CVAR(shockwave, blast_distance), false);
566         while(head)
567         {
568                 if((head != actor) && head.takedamage)
569                 {
570                         // ========================
571                         //  BLAST CONE CALCULATION
572                         // ========================
573
574                         // if it's a player, use the view origin as reference (stolen from RadiusDamage functions in g_damage.qc)
575                         center = CENTER_OR_VIEWOFS(head);
576
577                         // find the closest point on the enemy to the center of the attack
578                         float h; // hypotenuse, which is the distance between attacker to head
579                         float a; // adjacent side, which is the distance between attacker and the point on w_shotdir that is closest to head.origin
580
581                         h = vlen(center - actor.origin);
582                         a = h * (normalize(center - actor.origin) * w_shotdir);
583                         // WEAPONTODO: replace with simpler method
584
585                         vector nearest_on_line = (w_shotorg + a * w_shotdir);
586                         vector nearest_to_attacker = WarpZoneLib_NearestPointOnBox(center + head.mins, center + head.maxs, nearest_on_line);
587
588                         if((vdist(head.WarpZone_findradius_dist, <=, WEP_CVAR(shockwave, blast_distance)))
589                                 && (W_Shockwave_Attack_IsVisible(actor, head, nearest_on_line, w_shotorg, attack_endpos)))
590                         {
591                                 // calculate importance of distance and accuracy for this attack
592                                 multiplier_from_accuracy = (1 -
593                                         W_Shockwave_Attack_CheckSpread(
594                                                 nearest_to_attacker,
595                                                 nearest_on_line,
596                                                 w_shotorg,
597                                                 attack_endpos
598                                         )
599                                 );
600                                 multiplier_from_distance = (1 -
601                                         (distance_to_hit ?
602                                                 min(1, (vlen(head.WarpZone_findradius_dist) / distance_to_end))
603                                                 :
604                                                 0
605                                         )
606                                 );
607                                 multiplier =
608                                         max(
609                                                 WEP_CVAR(shockwave, blast_multiplier_min),
610                                                 (
611                                                         (multiplier_from_accuracy * WEP_CVAR(shockwave, blast_multiplier_accuracy))
612                                                         +
613                                                         (multiplier_from_distance * WEP_CVAR(shockwave, blast_multiplier_distance))
614                                                 )
615                                         );
616
617                                 // calculate damage from multiplier: 1 = "highest" damage, 0 = "lowest" edgedamage
618                                 final_damage =
619                                         (
620                                                 (WEP_CVAR(shockwave, blast_damage) * multiplier)
621                                                 +
622                                                 (WEP_CVAR(shockwave, blast_edgedamage) * (1 - multiplier))
623                                         );
624
625                                 // figure out the direction of force
626                                 final_force = (w_shotdir * WEP_CVAR(shockwave, blast_force_forwardbias));
627                                 final_force = normalize(center - (nearest_on_line - final_force));
628                                 //te_lightning2(NULL, nearest_on_line, (attack_hitpos + (final_force * 200)));
629
630                                 // now multiply the direction by force units
631                                 final_force *= (WEP_CVAR(shockwave, blast_force) * multiplier);
632                                 final_force.z *= WEP_CVAR(shockwave, blast_force_zscale);
633
634                                 // queue damage with this calculated info
635                                 if(W_Shockwave_Attack_CheckHit(queue, head, final_force, final_damage)) { queue = min(queue + 1, MAX_SHOCKWAVE_HITS); }
636
637                                 #ifdef DEBUG_SHOCKWAVE
638                                 LOG_INFO(sprintf(
639                                         "BLAST HIT: multiplier = %f, damage = %f, force = %f... "
640                                         "multiplier_from_accuracy = %f, multiplier_from_distance = %f.\n",
641                                         multiplier,
642                                         final_damage,
643                                         vlen(final_force),
644                                         multiplier_from_accuracy,
645                                         multiplier_from_distance
646                                 ));
647                                 #endif
648                         }
649                 }
650                 head = head.chain;
651         }
652
653         for(i = 1; i <= queue; ++i)
654         {
655                 head = shockwave_hit[i-1];
656                 final_force = shockwave_hit_force[i-1];
657                 final_damage = shockwave_hit_damage[i-1];
658
659                 Damage(
660                         head,
661                         actor,
662                         actor,
663                         final_damage,
664                         WEP_SHOCKWAVE.m_id,
665                         head.origin,
666                         final_force
667                 );
668
669                 if(accuracy_isgooddamage(actor, head))
670                         accuracy_add(actor, WEP_SHOCKWAVE.m_id, 0, final_damage);
671
672                 #ifdef DEBUG_SHOCKWAVE
673                 LOG_INFO(sprintf(
674                         "SHOCKWAVE by %s: damage = %f, force = %f.\n",
675                         actor.netname,
676                         final_damage,
677                         vlen(final_force)
678                 ));
679                 #endif
680
681                 shockwave_hit[i-1] = NULL;
682                 shockwave_hit_force[i-1] = '0 0 0';
683                 shockwave_hit_damage[i-1] = 0;
684         }
685
686         if(lag)
687         {
688                 FOREACH_CLIENT(IS_PLAYER(it) && it != actor, antilag_restore(it, CS(it)));
689                 IL_EACH(g_monsters, it != actor,
690                 {
691                         antilag_restore(it, it);
692                 });
693         }
694 }
695
696 METHOD(Shockwave, wr_aim, void(entity thiswep, entity actor, .entity weaponentity))
697 {
698     if(vdist(actor.origin - actor.enemy.origin, <=, WEP_CVAR(shockwave, melee_range)))
699         { PHYS_INPUT_BUTTON_ATCK2(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false); }
700     else
701         { PHYS_INPUT_BUTTON_ATCK(actor) = bot_aim(actor, weaponentity, 1000000, 0, 0.001, false); }
702 }
703 METHOD(Shockwave, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
704 {
705     if(fire & 1)
706     {
707         if(time >= actor.(weaponentity).shockwave_blasttime) // handle refire separately so the secondary can be fired straight after a primary
708         {
709             if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR(shockwave, blast_animtime)))
710             {
711                 W_Shockwave_Attack(actor, weaponentity);
712                 actor.(weaponentity).shockwave_blasttime = time + WEP_CVAR(shockwave, blast_refire) * W_WeaponRateFactor(actor);
713                 weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR(shockwave, blast_animtime), w_ready);
714             }
715         }
716     }
717     else if(fire & 2)
718     {
719         //if(actor.clip_load >= 0) // we are not currently reloading
720         if(weapon_prepareattack(thiswep, actor, weaponentity, true, WEP_CVAR(shockwave, melee_refire)))
721         {
722             // attempt forcing playback of the anim by switching to another anim (that we never play) here...
723             weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, 0, W_Shockwave_Melee);
724         }
725     }
726 }
727 METHOD(Shockwave, wr_checkammo1, bool(entity thiswep, entity actor, .entity weaponentity))
728 {
729     return true; // infinite ammo
730 }
731 METHOD(Shockwave, wr_checkammo2, bool(entity thiswep, entity actor, .entity weaponentity))
732 {
733     // shockwave has infinite ammo
734     return true;
735 }
736 METHOD(Shockwave, wr_suicidemessage, Notification(entity thiswep))
737 {
738     return WEAPON_THINKING_WITH_PORTALS;
739 }
740 METHOD(Shockwave, wr_killmessage, Notification(entity thiswep))
741 {
742     if(w_deathtype & HITTYPE_SECONDARY)
743         return WEAPON_SHOCKWAVE_MURDER_SLAP;
744     else
745         return WEAPON_SHOCKWAVE_MURDER;
746 }
747
748 #endif
749 #ifdef CSQC
750 // WEAPONTODO: add client side settings for these
751 const float SW_MAXALPHA = 0.5;
752 const float SW_FADETIME = 0.4;
753 const float SW_DISTTOMIN = 200;
754 void Draw_Shockwave(entity this)
755 {
756         // fading/removal control
757         float a = bound(0, (SW_MAXALPHA - ((time - this.sw_time) / SW_FADETIME)), SW_MAXALPHA);
758         if(a < ALPHA_MIN_VISIBLE) { delete(this); }
759
760         // WEAPONTODO: save this only once when creating the entity
761         vector sw_color = entcs_GetColor(this.sv_entnum - 1); // GetTeamRGB(entcs_GetTeam(this.sv_entnum));
762
763         // WEAPONTODO: trace to find what we actually hit
764         vector endpos = (this.sw_shotorg + (this.sw_shotdir * this.sw_distance));
765
766         vectorvectors(this.sw_shotdir);
767         vector right = v_right; // save this for when we do makevectors later
768         vector up = v_up; // save this for when we do makevectors later
769
770         // WEAPONTODO: combine and simplify these calculations
771         vector min_end = ((this.sw_shotorg + (this.sw_shotdir * SW_DISTTOMIN)) + (up * this.sw_spread_min));
772         vector max_end = (endpos + (up * this.sw_spread_max));
773         float spread_to_min = vlen(normalize(min_end - this.sw_shotorg) - this.sw_shotdir);
774         float spread_to_max = vlen(normalize(max_end - min_end) - this.sw_shotdir);
775
776         vector first_min_end = '0 0 0', prev_min_end = '0 0 0', new_min_end = '0 0 0';
777         vector first_max_end = '0 0 0', prev_max_end = '0 0 0', new_max_end = '0 0 0';
778         float new_max_dist, new_min_dist;
779
780         vector deviation, angle = '0 0 0';
781         float counter, divisions = 20;
782         for(counter = 0; counter < divisions; ++counter)
783         {
784                 // perfect circle effect lines
785                 makevectors('0 360 0' * (0.75 + (counter - 0.5) / divisions));
786                 angle.y = v_forward.x;
787                 angle.z = v_forward.y;
788
789                 // first do the spread_to_min effect
790                 deviation = angle * spread_to_min;
791                 deviation = ((this.sw_shotdir + (right * deviation.y) + (up * deviation.z)));
792                 new_min_dist = SW_DISTTOMIN;
793                 new_min_end = (this.sw_shotorg + (deviation * new_min_dist));
794                 //te_lightning2(NULL, new_min_end, this.sw_shotorg);
795
796                 // then calculate spread_to_max effect
797                 deviation = angle * spread_to_max;
798                 deviation = ((this.sw_shotdir + (right * deviation.y) + (up * deviation.z)));
799                 new_max_dist = vlen(new_min_end - endpos);
800                 new_max_end = (new_min_end + (deviation * new_max_dist));
801                 //te_lightning2(NULL, new_end, prev_min_end);
802
803
804                 if(counter == 0)
805                 {
806                         first_min_end = new_min_end;
807                         first_max_end = new_max_end;
808                 }
809
810                 if(counter >= 1)
811                 {
812                         // draw from shot origin to min spread radius
813                         R_BeginPolygon("", DRAWFLAG_NORMAL);
814                         R_PolygonVertex(prev_min_end, '0 0 0', sw_color, a);
815                         R_PolygonVertex(new_min_end, '0 0 0', sw_color, a);
816                         R_PolygonVertex(this.sw_shotorg, '0 0 0', sw_color, a);
817                         R_EndPolygon();
818
819                         // draw from min spread radius to max spread radius
820                         R_BeginPolygon("", DRAWFLAG_NORMAL);
821                         R_PolygonVertex(new_min_end, '0 0 0', sw_color, a);
822                         R_PolygonVertex(prev_min_end, '0 0 0', sw_color, a);
823                         R_PolygonVertex(prev_max_end, '0 0 0', sw_color, a);
824                         R_PolygonVertex(new_max_end, '0 0 0', sw_color, a);
825                         R_EndPolygon();
826                 }
827
828                 prev_min_end = new_min_end;
829                 prev_max_end = new_max_end;
830
831                 // last division only
832                 if((counter + 1) == divisions)
833                 {
834                         // draw from shot origin to min spread radius
835                         R_BeginPolygon("", DRAWFLAG_NORMAL);
836                         R_PolygonVertex(prev_min_end, '0 0 0', sw_color, a);
837                         R_PolygonVertex(first_min_end, '0 0 0', sw_color, a);
838                         R_PolygonVertex(this.sw_shotorg, '0 0 0', sw_color, a);
839                         R_EndPolygon();
840
841                         // draw from min spread radius to max spread radius
842                         R_BeginPolygon("", DRAWFLAG_NORMAL);
843                         R_PolygonVertex(first_min_end, '0 0 0', sw_color, a);
844                         R_PolygonVertex(prev_min_end, '0 0 0', sw_color, a);
845                         R_PolygonVertex(prev_max_end, '0 0 0', sw_color, a);
846                         R_PolygonVertex(first_max_end, '0 0 0', sw_color, a);
847                         R_EndPolygon();
848                 }
849         }
850 }
851
852 NET_HANDLE(TE_CSQC_SHOCKWAVEPARTICLE, bool isNew)
853 {
854         Net_ReadShockwaveParticle();
855         return true;
856 }
857
858 void Net_ReadShockwaveParticle()
859 {
860         entity shockwave;
861         shockwave = spawn();
862         shockwave.draw = Draw_Shockwave;
863         IL_PUSH(g_drawables, shockwave);
864
865         shockwave.sw_shotorg_x = ReadCoord(); shockwave.sw_shotorg_y = ReadCoord(); shockwave.sw_shotorg_z = ReadCoord();
866         shockwave.sw_shotdir_x = ReadCoord(); shockwave.sw_shotdir_y = ReadCoord(); shockwave.sw_shotdir_z = ReadCoord();
867
868         shockwave.sw_distance = ReadShort();
869         shockwave.sw_spread_max = ReadByte();
870         shockwave.sw_spread_min = ReadByte();
871
872         shockwave.sv_entnum = ReadByte();
873
874         shockwave.sw_time = time;
875 }
876
877 METHOD(Shockwave, wr_impacteffect, void(entity thiswep, entity actor))
878 {
879     // handled by Net_ReadShockwaveParticle
880     //vector org2;
881     //org2 = w_org + w_backoff * 2;
882     //pointparticles(EFFECT_BLASTER_IMPACT, org2, w_backoff * 1000, 1);
883 }
884
885 #endif
886 #endif