qcsrc/common/weapons/weapon/vaporizer.qc

   1 #ifndef IMPLEMENTATION
   2 CLASS(Vaporizer, Weapon)
   3 /* ammotype  */ ATTRIB(Vaporizer, ammo_field, .int, ammo_cells)
   4 /* impulse   */ ATTRIB(Vaporizer, impulse, int, 7)
   5 /* flags     */ ATTRIB(Vaporizer, spawnflags, int, WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_FLAG_SUPERWEAPON | WEP_TYPE_HITSCAN);
   6 /* rating    */ ATTRIB(Vaporizer, bot_pickupbasevalue, float, BOT_PICKUP_RATING_HIGH);
   7 /* color     */ ATTRIB(Vaporizer, wpcolor, vector, '0.5 1 1');
   8 /* modelname */ ATTRIB(Vaporizer, mdl, string, "minstanex");
   9 #ifndef MENUQC
  10 /* model     */ ATTRIB(Vaporizer, m_model, Model, MDL_VAPORIZER_ITEM);
  11 #endif
  12 /* crosshair */ ATTRIB(Vaporizer, w_crosshair, string, "gfx/crosshairminstanex");
  13 /* crosshair */ ATTRIB(Vaporizer, w_crosshair_size, float, 0.6);
  14 /* wepimg    */ ATTRIB(Vaporizer, model2, string, "weaponminstanex");
  15 /* refname   */ ATTRIB(Vaporizer, netname, string, "vaporizer");
  16 /* wepname   */ ATTRIB(Vaporizer, m_name, string, _("Vaporizer"));
  17 ENDCLASS(Vaporizer)
  18 REGISTER_WEAPON(VAPORIZER, NEW(Vaporizer));
  19
  20 #define VAPORIZER_SETTINGS(w_cvar,w_prop) VAPORIZER_SETTINGS_LIST(w_cvar, w_prop, VAPORIZER, vaporizer)
  21 #define VAPORIZER_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  22         w_cvar(id, sn, PRI, ammo) \
  23         w_cvar(id, sn, PRI, animtime) \
  24         w_cvar(id, sn, PRI, damage) \
  25         w_cvar(id, sn, PRI, refire) \
  26         w_cvar(id, sn, SEC, ammo) \
  27         w_cvar(id, sn, SEC, animtime) \
  28         w_cvar(id, sn, SEC, damage) \
  29         w_cvar(id, sn, SEC, delay) \
  30         w_cvar(id, sn, SEC, edgedamage) \
  31         w_cvar(id, sn, SEC, force) \
  32         w_cvar(id, sn, SEC, lifetime) \
  33         w_cvar(id, sn, SEC, radius) \
  34         w_cvar(id, sn, SEC, refire) \
  35         w_cvar(id, sn, SEC, shotangle) \
  36         w_cvar(id, sn, SEC, speed) \
  37         w_cvar(id, sn, SEC, spread) \
  38         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  39         w_prop(id, sn, float,  reloading_time, reload_time) \
  40         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  41         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  42         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  43         w_prop(id, sn, float,  weaponstart, weaponstart) \
  44         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  45         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  46
  47 #ifdef SVQC
  48 VAPORIZER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  49 .float vaporizer_lasthit;
  50 .float jump_interval;
  51 .float jump_interval2;
  52 .bool held_down;
  53 .float rm_force;
  54 .float rm_damage;
  55 .float rm_edmg;
  56 #endif
  57 #endif
  58 #ifdef IMPLEMENTATION
  59
  60 REGISTER_NET_TEMP(TE_CSQC_VAPORBEAMPARTICLE)
  61
  62 #if defined(SVQC)
  63 void SendCSQCVaporizerBeamParticle(entity player, int hit) {
  64         vector v;
  65         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
  66         WriteHeader(MSG_BROADCAST, TE_CSQC_VAPORBEAMPARTICLE);
  67         WriteCoord(MSG_BROADCAST, w_shotorg.x);
  68         WriteCoord(MSG_BROADCAST, w_shotorg.y);
  69         WriteCoord(MSG_BROADCAST, w_shotorg.z);
  70         WriteCoord(MSG_BROADCAST, v.x);
  71         WriteCoord(MSG_BROADCAST, v.y);
  72         WriteCoord(MSG_BROADCAST, v.z);
  73         WriteByte(MSG_BROADCAST, hit);
  74         WriteByte(MSG_BROADCAST, num_for_edict(player));
  75         WriteByte(MSG_BROADCAST, player.team);
  76 }
  77 #elif defined(CSQC)
  78 bool autocvar_cl_vaporizerbeam_particle = false;
  79 float autocvar_cl_vaporizerbeam_lifetime = 0.8;
  80 float autocvar_cl_vaporizerbeam_colorboost = 0.7;
  81
  82 string Draw_VaporizerBeam_trace_callback_tex;
  83 float Draw_VaporizerBeam_trace_callback_rnd;
  84 vector Draw_VaporizerBeam_trace_callback_rgb;
  85 float Draw_VaporizerBeam_trace_callback_a;
  86 void Draw_VaporizerBeam_trace_callback(vector start, vector hit, vector end)
  87 {
  88         float i;
  89         vector vorg;
  90         vorg = WarpZone_TransformOrigin(WarpZone_trace_transform, view_origin);
  91         for(i = 0; i < Draw_VaporizerBeam_trace_callback_a; ++i)
  92                 Draw_CylindricLine(hit, start, 8, Draw_VaporizerBeam_trace_callback_tex, 0.25, Draw_VaporizerBeam_trace_callback_rnd, Draw_VaporizerBeam_trace_callback_rgb, min(1, Draw_VaporizerBeam_trace_callback_a - i), DRAWFLAG_NORMAL, vorg);
  93         Draw_VaporizerBeam_trace_callback_rnd += 0.25 * vlen(hit - start) / 8;
  94 }
  95
  96 .vector vorg1, vorg2;
  97 .float spawn_time;
  98 void VaporizerBeam_Draw(entity this)
  99 {
 100         //draw either the old v2.3 beam or the new beam
 101         particles_alphamin = particles_alphamax = particles_fade = 1;
 102
 103         string tex = "particles/lgbeam";
 104         if(this.cnt)
 105                 tex = "particles/gauntletbeam";
 106         vector rgb;
 107         //entity e = CSQCModel_server2csqc(this.sv_entnum - 1);
 108         //if (e == NULL)
 109         //{
 110                 rgb = colormapPaletteColor(stof(getplayerkeyvalue(this.sv_entnum - 1, "colors")) & 0x0F, true);
 111                 //rgb = '1 1 1';
 112         //}
 113         //else
 114         //      rgb = e.glowmod;
 115         rgb *= (1 + autocvar_cl_vaporizerbeam_colorboost);
 116
 117         float fail = (self.nextthink - time);
 118
 119         Draw_VaporizerBeam_trace_callback_tex = tex;
 120         Draw_VaporizerBeam_trace_callback_rnd = 0;
 121         Draw_VaporizerBeam_trace_callback_rgb = rgb;
 122         Draw_VaporizerBeam_trace_callback_a = bound(0, fail, 1);
 123         WarpZone_TraceBox_ThroughZone(this.vorg1, '0 0 0', '0 0 0', this.vorg2, MOVE_NOTHING, world, world, Draw_VaporizerBeam_trace_callback);
 124         Draw_VaporizerBeam_trace_callback_tex = string_null;
 125
 126         /*if(!MUTATOR_CALLHOOK(Particles_VaporizerBeam, this.vorg1, this.vorg2))
 127         if(autocvar_cl_particles_oldvortexbeam && (getstati(STAT_ALLOW_OLDVORTEXBEAM) || isdemo()))
 128                 WarpZone_TrailParticles_WithMultiplier(world, particleeffectnum(EFFECT_VORTEX_BEAM_OLD), this.vorg1, this.vorg2, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE);
 129         else
 130                 WarpZone_TrailParticles_WithMultiplier(world, particleeffectnum(EFFECT_VORTEX_BEAM), this.vorg1, this.vorg2, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE);*/
 131 }
 132
 133 NET_HANDLE(TE_CSQC_VAPORBEAMPARTICLE, bool isNew)
 134 {
 135         Net_Accept(vortex_beam);
 136         this.think = SUB_Remove_self;
 137         this.nextthink = time + bound(0, autocvar_cl_vaporizerbeam_lifetime, 10);
 138         this.draw = VaporizerBeam_Draw;
 139         this.drawmask = MASK_NORMAL;
 140
 141         this.vorg1_x = ReadCoord(); this.vorg1_y = ReadCoord(); this.vorg1_z = ReadCoord();
 142         this.vorg2_x = ReadCoord(); this.vorg2_y = ReadCoord(); this.vorg2_z = ReadCoord();
 143         this.cnt = ReadByte();
 144         int myowner = ReadByte();
 145         this.owner = playerslots[myowner - 1];
 146         this.sv_entnum = myowner;
 147         this.team = ReadByte() - 1;
 148
 149         if(autocvar_cl_vaporizerbeam_particle)
 150         {
 151                 WarpZone_TrailParticles(world, particleeffectnum(((this.cnt) ? EFFECT_VAPORIZER_HIT(this.team) : EFFECT_VAPORIZER(this.team))), this.vorg1, this.vorg2);
 152                 this.draw = func_null;
 153                 this.drawmask = MASK_NORMAL;
 154                 remove(this);
 155         }
 156
 157         pointparticles(EFFECT_VORTEX_MUZZLEFLASH, this.vorg1, normalize(this.vorg2 - this.vorg1) * 1000, 1);
 158         return true;
 159 }
 160 #endif
 161
 162 #ifdef SVQC
 163 spawnfunc(weapon_vaporizer) { weapon_defaultspawnfunc(this, WEP_VAPORIZER); }
 164 spawnfunc(weapon_minstanex) { spawnfunc_weapon_vaporizer(this); }
 165
 166 void W_RocketMinsta_Explosion(vector loc)
 167 {SELFPARAM();
 168         if(accuracy_canbegooddamage(self))
 169                 accuracy_add(self, WEP_DEVASTATOR.m_id, autocvar_g_rm_damage, 0);
 170         entity dmgent = spawn();
 171         dmgent.owner = dmgent.realowner = self;
 172         setorigin(dmgent, loc);
 173         RadiusDamage (dmgent, self, autocvar_g_rm_damage, autocvar_g_rm_edgedamage, autocvar_g_rm_radius, world, world, autocvar_g_rm_force, WEP_DEVASTATOR.m_id | HITTYPE_SPLASH, other);
 174         remove(dmgent);
 175 }
 176
 177 void W_Vaporizer_Attack(Weapon thiswep)
 178 {SELFPARAM();
 179         bool flying = IsFlying(self); // do this BEFORE to make the trace values from FireRailgunBullet last
 180         float vaporizer_damage = ((WEP_CVAR_PRI(vaporizer, damage) > 0) ? WEP_CVAR_PRI(vaporizer, damage) : 10000);
 181
 182         W_SetupShot(self, true, 0, "", CH_WEAPON_A, vaporizer_damage);
 183         // handle sound separately so we can change the volume
 184         // added bonus: no longer plays the strength sound (strength gives no bonus to instakill anyway)
 185         sound (self, CH_WEAPON_A, SND_MINSTANEXFIRE, VOL_BASE * 0.8, ATTEN_NORM);
 186
 187         yoda = 0;
 188         damage_goodhits = 0;
 189         FireRailgunBullet(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, vaporizer_damage, 800, 0, 0, 0, 0, WEP_VAPORIZER.m_id);
 190
 191         // do this now, as goodhits is disabled below
 192         SendCSQCVaporizerBeamParticle(self, damage_goodhits);
 193
 194         if(yoda && flying)
 195                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_ACHIEVEMENT_YODA);
 196         if(damage_goodhits && self.vaporizer_lasthit)
 197         {
 198                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_ACHIEVEMENT_IMPRESSIVE);
 199                 damage_goodhits = 0; // only every second time
 200         }
 201
 202         self.vaporizer_lasthit = damage_goodhits;
 203
 204         if(autocvar_g_rm)
 205         if(!(trace_dphitq3surfaceflags & (Q3SURFACEFLAG_SKY | Q3SURFACEFLAG_NOIMPACT)))
 206                 W_RocketMinsta_Explosion(trace_endpos);
 207
 208         W_DecreaseAmmo(thiswep, self, ((g_instagib) ? 1 : WEP_CVAR_PRI(vaporizer, ammo)));
 209 }
 210
 211 void W_RocketMinsta_Laser_Explode ()
 212 {SELFPARAM();
 213         if(other.takedamage == DAMAGE_AIM)
 214                 if(IS_PLAYER(other))
 215                         if(DIFF_TEAM(self.realowner, other))
 216                                 if(other.deadflag == DEAD_NO)
 217                                         if(IsFlying(other))
 218                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_ELECTROBITCH);
 219
 220         self.event_damage = func_null;
 221         self.takedamage = DAMAGE_NO;
 222         RadiusDamage (self, self.realowner, self.rm_damage, self.rm_edmg, autocvar_g_rm_laser_radius, world, world, self.rm_force, self.projectiledeathtype, other);
 223         remove(self);
 224 }
 225
 226 void W_RocketMinsta_Laser_Touch ()
 227 {SELFPARAM();
 228         PROJECTILE_TOUCH;
 229         //W_RocketMinsta_Laser_Explode ();
 230         RadiusDamage (self, self.realowner, self.rm_damage, self.rm_edmg, autocvar_g_rm_laser_radius, world, world, self.rm_force, self.projectiledeathtype, other);
 231         remove(self);
 232 }
 233
 234 void W_RocketMinsta_Attack2()
 235 {SELFPARAM();
 236         makevectors(self.v_angle);
 237
 238         entity proj;
 239         float counter = 0;
 240         float total = autocvar_g_rm_laser_count;
 241         float spread = autocvar_g_rm_laser_spread;
 242         float rndspread = autocvar_g_rm_laser_spread_random;
 243
 244         float w = self.weapon;
 245         self.weapon = WEP_ELECTRO.m_id;
 246         W_SetupShot_ProjectileSize (self, '0 0 -3', '0 0 -3', false, 2, SND(CRYLINK_FIRE), CH_WEAPON_A, autocvar_g_rm_laser_damage);
 247         self.weapon = w;
 248
 249         Send_Effect(EFFECT_ELECTRO_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 250
 251     while(counter < total)
 252         {
 253         proj = new(plasma_prim);
 254         proj.owner = proj.realowner = self;
 255         proj.bot_dodge = true;
 256         proj.bot_dodgerating = autocvar_g_rm_laser_damage;
 257         proj.use = W_RocketMinsta_Laser_Explode;
 258         proj.think = adaptor_think2use_hittype_splash;
 259         proj.nextthink = time + autocvar_g_rm_laser_lifetime;
 260         PROJECTILE_MAKETRIGGER(proj);
 261         proj.projectiledeathtype = WEP_ELECTRO.m_id;
 262         setorigin(proj, w_shotorg);
 263
 264                 proj.rm_force = autocvar_g_rm_laser_force / total;
 265                 proj.rm_damage = autocvar_g_rm_laser_damage / total;
 266                 proj.rm_edmg = proj.rm_damage;
 267
 268         //W_SetupProjectileVelocity(proj, autocvar_g_rm_laser_speed, spread * (rndspread ? random() : 1) * autocvar_g_rm_laser_speed);
 269
 270         proj.movetype = MOVETYPE_BOUNCEMISSILE;
 271         //W_SETUPPROJECTILEVELOCITY(proj, g_balance_minstanex_laser);
 272                 proj.velocity = (w_shotdir + (((counter + 0.5) / total) * 2 - 1) * v_right * (spread * (rndspread ? random() : 1))) * cvar("g_rm_laser_speed");
 273                 proj.velocity_z = proj.velocity_z + cvar("g_rm_laser_zspread") * (random() - 0.5);
 274                 proj.velocity = W_CalculateProjectileVelocity(proj.realowner.velocity, proj.velocity, true);
 275         proj.angles = vectoangles(proj.velocity);
 276         proj.touch = W_RocketMinsta_Laser_Touch;
 277         setsize(proj, '0 0 -3', '0 0 -3');
 278         proj.flags = FL_PROJECTILE;
 279         proj.missile_flags = MIF_SPLASH;
 280
 281         CSQCProjectile(proj, true, PROJECTILE_ROCKETMINSTA_LASER, true);
 282
 283         MUTATOR_CALLHOOK(EditProjectile, self, proj);
 284         counter++;
 285     }
 286 }
 287
 288 void W_RocketMinsta_Attack3 ()
 289 {SELFPARAM();
 290         makevectors(self.v_angle);
 291
 292         entity proj;
 293         float counter = 0;
 294         float total = 1;
 295
 296         int w = self.weapon;
 297         self.weapon = WEP_ELECTRO.m_id;
 298         W_SetupShot_ProjectileSize (self, '0 0 -3', '0 0 -3', false, 2, SND(ELECTRO_FIRE2), CH_WEAPON_A, autocvar_g_rm_laser_damage);
 299         self.weapon = w;
 300
 301         Send_Effect(EFFECT_ELECTRO_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 302
 303     while(counter < total)
 304         {
 305         proj = new(plasma_prim);
 306         proj.owner = proj.realowner = self;
 307         proj.bot_dodge = true;
 308         proj.bot_dodgerating = autocvar_g_rm_laser_damage;
 309         proj.use = W_RocketMinsta_Laser_Explode;
 310         proj.think = adaptor_think2use_hittype_splash;
 311         proj.nextthink = time + autocvar_g_rm_laser_lifetime;
 312         PROJECTILE_MAKETRIGGER(proj);
 313         proj.projectiledeathtype = WEP_ELECTRO.m_id;
 314         setorigin(proj, w_shotorg);
 315
 316                 proj.rm_force = autocvar_g_rm_laser_force / total;
 317                 proj.rm_damage = autocvar_g_rm_laser_damage / total;
 318                 proj.rm_edmg = proj.rm_damage;
 319
 320         //W_SetupProjectileVelocity(proj, autocvar_g_rm_laser_speed, spread * (rndspread ? random() : 1) * autocvar_g_rm_laser_speed);
 321
 322         proj.movetype = MOVETYPE_BOUNCEMISSILE;
 323                 proj.velocity = w_shotdir * autocvar_g_rm_laser_speed;
 324                 proj.velocity = W_CalculateProjectileVelocity(proj.realowner.velocity, proj.velocity, true);
 325         proj.angles = vectoangles(proj.velocity);
 326         proj.touch = W_RocketMinsta_Laser_Touch;
 327         setsize(proj, '0 0 -3', '0 0 -3');
 328         proj.flags = FL_PROJECTILE;
 329         proj.missile_flags = MIF_SPLASH;
 330
 331         CSQCProjectile(proj, true, PROJECTILE_ROCKETMINSTA_LASER, true);
 332
 333         MUTATOR_CALLHOOK(EditProjectile, self, proj);
 334         counter++;
 335     }
 336 }
 337
 338                 METHOD(Vaporizer, wr_aim, void(entity thiswep))
 339                 {
 340                         if(self.WEP_AMMO(VAPORIZER) > 0)
 341                                 self.BUTTON_ATCK = bot_aim(1000000, 0, 1, false);
 342                         else
 343                                 self.BUTTON_ATCK2 = bot_aim(WEP_CVAR_SEC(vaporizer, speed), 0, WEP_CVAR_SEC(vaporizer, lifetime), false); // WEAPONTODO: replace with proper vaporizer cvars
 344                 }
 345                 METHOD(Vaporizer, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 346                 {
 347                         float vaporizer_ammo = ((g_instagib) ? 1 : WEP_CVAR_PRI(vaporizer, ammo));
 348                         // if the laser uses load, we also consider its ammo for reloading
 349                         if(WEP_CVAR(vaporizer, reload_ammo) && WEP_CVAR_SEC(vaporizer, ammo) && actor.clip_load < min(vaporizer_ammo, WEP_CVAR_SEC(vaporizer, ammo))) { // forced reload
 350                                 Weapon w = get_weaponinfo(actor.weapon);
 351                                 w.wr_reload(w);
 352                         } else if(WEP_CVAR(vaporizer, reload_ammo) && actor.clip_load < vaporizer_ammo) { // forced reload
 353                                 Weapon w = get_weaponinfo(actor.weapon);
 354                                 w.wr_reload(w);
 355                         }
 356                         if((fire & 1) && (actor.ammo_cells || !autocvar_g_rm) && !forbidWeaponUse(actor))
 357                         {
 358                                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(vaporizer, refire)))
 359                                 {
 360                                         W_Vaporizer_Attack(thiswep);
 361                                         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(vaporizer, animtime), w_ready);
 362                                 }
 363                         }
 364                         if((fire & 2) || ((fire & 1) && !actor.ammo_cells && autocvar_g_rm))
 365                         {
 366                                 if((autocvar_g_rm && autocvar_g_rm_laser) || autocvar_g_rm_laser == 2)
 367                                 {
 368                                         bool rapid = autocvar_g_rm_laser_rapid;
 369                                         if(actor.jump_interval <= time && !actor.held_down)
 370                                         {
 371                                                 if(rapid)
 372                                                         actor.held_down = true;
 373                                                 actor.jump_interval = time + autocvar_g_rm_laser_refire;
 374                                                 actor.jump_interval2 = time + autocvar_g_rm_laser_rapid_delay;
 375                                                 damage_goodhits = 0;
 376                                                 W_RocketMinsta_Attack2();
 377                                         }
 378                                         else if(rapid && actor.jump_interval2 <= time && actor.held_down)
 379                                         {
 380                                                 actor.jump_interval2 = time + autocvar_g_rm_laser_rapid_refire;
 381                                                 damage_goodhits = 0;
 382                                                 W_RocketMinsta_Attack3();
 383                                                 //weapon_thinkf(actor, WFRAME_FIRE2, autocvar_g_rm_laser_rapid_animtime, w_ready);
 384                                         }
 385                                 }
 386                                 else if (actor.jump_interval <= time)
 387                                 {
 388                                         // handle refire manually, so that primary and secondary can be fired without conflictions (important for instagib)
 389                                         actor.jump_interval = time + WEP_CVAR_SEC(vaporizer, refire) * W_WeaponRateFactor();
 390
 391                                         // decrease ammo for the laser?
 392                                         if(WEP_CVAR_SEC(vaporizer, ammo))
 393                                                 W_DecreaseAmmo(thiswep, actor, WEP_CVAR_SEC(vaporizer, ammo));
 394
 395                                         // ugly instagib hack to reuse the fire mode of the laser
 396                                         makevectors(actor.v_angle);
 397                                         int oldwep = actor.weapon; // we can't avoid this hack
 398                                         actor.weapon = WEP_BLASTER.m_id;
 399                                         W_Blaster_Attack(
 400                                                 actor,
 401                                                 WEP_BLASTER.m_id | HITTYPE_SECONDARY,
 402                                                 WEP_CVAR_SEC(vaporizer, shotangle),
 403                                                 WEP_CVAR_SEC(vaporizer, damage),
 404                                                 WEP_CVAR_SEC(vaporizer, edgedamage),
 405                                                 WEP_CVAR_SEC(vaporizer, radius),
 406                                                 WEP_CVAR_SEC(vaporizer, force),
 407                                                 WEP_CVAR_SEC(vaporizer, speed),
 408                                                 WEP_CVAR_SEC(vaporizer, spread),
 409                                                 WEP_CVAR_SEC(vaporizer, delay),
 410                                                 WEP_CVAR_SEC(vaporizer, lifetime)
 411                                         );
 412                                         actor.weapon = oldwep;
 413
 414                                         // now do normal refire
 415                                         weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(vaporizer, animtime), w_ready);
 416                                 }
 417                         }
 418                         else
 419                                 actor.held_down = false;
 420                 }
 421                 METHOD(Vaporizer, wr_init, void(entity thiswep))
 422                 {
 423                         //W_Blaster(WR_INIT); // Samual: Is this really the proper thing to do? Didn't we already run this previously?
 424                         VAPORIZER_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
 425                 }
 426                 METHOD(Vaporizer, wr_setup, void(entity thiswep))
 427                 {
 428                         self.ammo_field = WEP_AMMO(VAPORIZER);
 429                         self.vaporizer_lasthit = 0;
 430                 }
 431                 METHOD(Vaporizer, wr_checkammo1, bool(entity thiswep))
 432                 {
 433                         float vaporizer_ammo = ((g_instagib) ? 1 : WEP_CVAR_PRI(vaporizer, ammo));
 434                         float ammo_amount = self.WEP_AMMO(VAPORIZER) >= vaporizer_ammo;
 435                         ammo_amount += self.(weapon_load[WEP_VAPORIZER.m_id]) >= vaporizer_ammo;
 436                         return ammo_amount;
 437                 }
 438                 METHOD(Vaporizer, wr_checkammo2, bool(entity thiswep))
 439                 {
 440                         if(!WEP_CVAR_SEC(vaporizer, ammo))
 441                                 return true;
 442                         float ammo_amount = self.WEP_AMMO(VAPORIZER) >= WEP_CVAR_SEC(vaporizer, ammo);
 443                         ammo_amount += self.(weapon_load[WEP_VAPORIZER.m_id]) >= WEP_CVAR_SEC(vaporizer, ammo);
 444                         return ammo_amount;
 445                 }
 446                 METHOD(Vaporizer, wr_config, void(entity thiswep))
 447                 {
 448                         VAPORIZER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
 449                 }
 450                 METHOD(Vaporizer, wr_resetplayer, void(entity thiswep))
 451                 {
 452                         self.vaporizer_lasthit = 0;
 453                 }
 454                 METHOD(Vaporizer, wr_reload, void(entity thiswep))
 455                 {
 456                         float vaporizer_ammo = ((g_instagib) ? 1 : WEP_CVAR_PRI(vaporizer, ammo));
 457                         float used_ammo;
 458                         if(WEP_CVAR_SEC(vaporizer, ammo))
 459                                 used_ammo = min(vaporizer_ammo, WEP_CVAR_SEC(vaporizer, ammo));
 460                         else
 461                                 used_ammo = vaporizer_ammo;
 462
 463                         W_Reload(self, used_ammo, SND(RELOAD));
 464                 }
 465                 METHOD(Vaporizer, wr_suicidemessage, int(entity thiswep))
 466                 {
 467                         return WEAPON_THINKING_WITH_PORTALS;
 468                 }
 469                 METHOD(Vaporizer, wr_killmessage, int(entity thiswep))
 470                 {
 471                         return WEAPON_VAPORIZER_MURDER;
 472                 }
 473
 474 #endif
 475 #ifdef CSQC
 476
 477                 METHOD(Vaporizer, wr_impacteffect, void(entity thiswep))
 478                 {
 479                         vector org2 = w_org + w_backoff * 6;
 480                         if(w_deathtype & HITTYPE_SECONDARY)
 481                         {
 482                                 pointparticles(EFFECT_BLASTER_IMPACT, org2, w_backoff * 1000, 1);
 483                                 if(!w_issilent) { sound(self, CH_SHOTS, SND_LASERIMPACT, VOL_BASE, ATTN_NORM); }
 484                         }
 485                         else
 486                         {
 487                                 pointparticles(EFFECT_VORTEX_IMPACT, org2, '0 0 0', 1);
 488                                 if(!w_issilent) { sound(self, CH_SHOTS, SND_NEXIMPACT, VOL_BASE, ATTN_NORM); }
 489                         }
 490                 }
 491                 METHOD(Vaporizer, wr_init, void(entity thiswep))
 492                 {
 493                         if(autocvar_cl_reticle && autocvar_cl_reticle_weapon)
 494                         {
 495                                 precache_pic("gfx/reticle_nex");
 496                         }
 497                 }
 498                 METHOD(Vaporizer, wr_zoomreticle, bool(entity thiswep))
 499                 {
 500                         if(button_zoom || zoomscript_caught)
 501                         {
 502                                 reticle_image = "gfx/reticle_nex";
 503                                 return true;
 504                         }
 505                         else
 506                         {
 507                                 // no weapon specific image for this weapon
 508                                 return false;
 509                         }
 510                 }
 511
 512 #endif
 513 #endif