qcsrc/common/weapons/weapon/vaporizer.qc

   1 #ifndef IMPLEMENTATION
   2 CLASS(Vaporizer, Weapon)
   3 /* ammotype  */ ATTRIB(Vaporizer, ammo_field, .int, ammo_cells)
   4 /* impulse   */ ATTRIB(Vaporizer, impulse, int, 7)
   5 /* flags     */ ATTRIB(Vaporizer, spawnflags, int, WEP_FLAG_RELOADABLE | WEP_FLAG_CANCLIMB | WEP_FLAG_SUPERWEAPON | WEP_TYPE_HITSCAN);
   6 /* rating    */ ATTRIB(Vaporizer, bot_pickupbasevalue, float, BOT_PICKUP_RATING_HIGH);
   7 /* color     */ ATTRIB(Vaporizer, wpcolor, vector, '0.5 1 1');
   8 /* modelname */ ATTRIB(Vaporizer, mdl, string, "minstanex");
   9 #ifndef MENUQC
  10 /* model     */ ATTRIB(Vaporizer, m_model, Model, MDL_VAPORIZER_ITEM);
  11 #endif
  12 /* crosshair */ ATTRIB(Vaporizer, w_crosshair, string, "gfx/crosshairminstanex");
  13 /* crosshair */ ATTRIB(Vaporizer, w_crosshair_size, float, 0.6);
  14 /* wepimg    */ ATTRIB(Vaporizer, model2, string, "weaponminstanex");
  15 /* refname   */ ATTRIB(Vaporizer, netname, string, "vaporizer");
  16 /* wepname   */ ATTRIB(Vaporizer, m_name, string, _("Vaporizer"));
  17 ENDCLASS(Vaporizer)
  18 REGISTER_WEAPON(VAPORIZER, NEW(Vaporizer));
  19
  20 #define VAPORIZER_SETTINGS(w_cvar,w_prop) VAPORIZER_SETTINGS_LIST(w_cvar, w_prop, VAPORIZER, vaporizer)
  21 #define VAPORIZER_SETTINGS_LIST(w_cvar,w_prop,id,sn) \
  22         w_cvar(id, sn, PRI, ammo) \
  23         w_cvar(id, sn, PRI, animtime) \
  24         w_cvar(id, sn, PRI, damage) \
  25         w_cvar(id, sn, PRI, refire) \
  26         w_cvar(id, sn, SEC, ammo) \
  27         w_cvar(id, sn, SEC, animtime) \
  28         w_cvar(id, sn, SEC, damage) \
  29         w_cvar(id, sn, SEC, delay) \
  30         w_cvar(id, sn, SEC, edgedamage) \
  31         w_cvar(id, sn, SEC, force) \
  32         w_cvar(id, sn, SEC, lifetime) \
  33         w_cvar(id, sn, SEC, radius) \
  34         w_cvar(id, sn, SEC, refire) \
  35         w_cvar(id, sn, SEC, shotangle) \
  36         w_cvar(id, sn, SEC, speed) \
  37         w_cvar(id, sn, SEC, spread) \
  38         w_prop(id, sn, float,  reloading_ammo, reload_ammo) \
  39         w_prop(id, sn, float,  reloading_time, reload_time) \
  40         w_prop(id, sn, float,  switchdelay_raise, switchdelay_raise) \
  41         w_prop(id, sn, float,  switchdelay_drop, switchdelay_drop) \
  42         w_prop(id, sn, string, weaponreplace, weaponreplace) \
  43         w_prop(id, sn, float,  weaponstart, weaponstart) \
  44         w_prop(id, sn, float,  weaponstartoverride, weaponstartoverride) \
  45         w_prop(id, sn, float,  weaponthrowable, weaponthrowable)
  46
  47 #ifdef SVQC
  48 VAPORIZER_SETTINGS(WEP_ADD_CVAR, WEP_ADD_PROP)
  49 .float vaporizer_lasthit;
  50 .float jump_interval;
  51 .float jump_interval2;
  52 .bool held_down;
  53 .float rm_force;
  54 .float rm_damage;
  55 .float rm_edmg;
  56 #endif
  57 #endif
  58 #ifdef IMPLEMENTATION
  59
  60 REGISTER_NET_TEMP(TE_CSQC_VAPORBEAMPARTICLE)
  61
  62 #if defined(SVQC)
  63 void SendCSQCVaporizerBeamParticle(entity player, int hit) {
  64         vector v;
  65         v = WarpZone_UnTransformOrigin(WarpZone_trace_transform, trace_endpos);
  66         WriteHeader(MSG_BROADCAST, TE_CSQC_VAPORBEAMPARTICLE);
  67         WriteCoord(MSG_BROADCAST, w_shotorg.x);
  68         WriteCoord(MSG_BROADCAST, w_shotorg.y);
  69         WriteCoord(MSG_BROADCAST, w_shotorg.z);
  70         WriteCoord(MSG_BROADCAST, v.x);
  71         WriteCoord(MSG_BROADCAST, v.y);
  72         WriteCoord(MSG_BROADCAST, v.z);
  73         WriteByte(MSG_BROADCAST, hit);
  74         WriteShort(MSG_BROADCAST, num_for_edict(player));
  75         WriteByte(MSG_BROADCAST, player.team);
  76 }
  77 #elif defined(CSQC)
  78 bool autocvar_cl_vaporizerbeam_particle = true;
  79 float autocvar_cl_vaporizerbeam_lifetime = 0.8;
  80
  81 string Draw_VaporizerBeam_trace_callback_tex;
  82 float Draw_VaporizerBeam_trace_callback_rnd;
  83 vector Draw_VaporizerBeam_trace_callback_rgb;
  84 float Draw_VaporizerBeam_trace_callback_a;
  85 void Draw_VaporizerBeam_trace_callback(vector start, vector hit, vector end)
  86 {
  87         float i;
  88         vector vorg;
  89         vorg = WarpZone_TransformOrigin(WarpZone_trace_transform, view_origin);
  90         for(i = 0; i < Draw_VaporizerBeam_trace_callback_a; ++i)
  91                 Draw_CylindricLine(hit, start, 8, Draw_VaporizerBeam_trace_callback_tex, 0.25, Draw_VaporizerBeam_trace_callback_rnd, Draw_VaporizerBeam_trace_callback_rgb, min(1, Draw_VaporizerBeam_trace_callback_a - i), DRAWFLAG_NORMAL, vorg);
  92         Draw_VaporizerBeam_trace_callback_rnd += 0.25 * vlen(hit - start) / 8;
  93 }
  94
  95 .vector vorg1, vorg2;
  96 .float spawn_time;
  97 void VaporizerBeam_Draw(entity this)
  98 {
  99         //draw either the old v2.3 beam or the new beam
 100         particles_alphamin = particles_alphamax = particles_fade = 1;
 101
 102         string tex = "particles/lgbeam";
 103         if(this.cnt)
 104                 tex = "particles/gauntletbeam";
 105         vector rgb = getcsqcplayercolor(this.sv_entnum);
 106         rgb *= (1 + 0.7);
 107
 108         float fail = (self.nextthink - time);
 109
 110         Draw_VaporizerBeam_trace_callback_tex = tex;
 111         Draw_VaporizerBeam_trace_callback_rnd = 0;
 112         Draw_VaporizerBeam_trace_callback_rgb = rgb;
 113         Draw_VaporizerBeam_trace_callback_a = bound(0, fail, 1);
 114         WarpZone_TraceBox_ThroughZone(this.vorg1, '0 0 0', '0 0 0', this.vorg2, MOVE_NOTHING, world, world, Draw_VaporizerBeam_trace_callback);
 115         Draw_VaporizerBeam_trace_callback_tex = string_null;
 116
 117         /*if(!MUTATOR_CALLHOOK(Particles_VaporizerBeam, this.vorg1, this.vorg2))
 118         if(autocvar_cl_particles_oldvortexbeam && (getstati(STAT_ALLOW_OLDVORTEXBEAM) || isdemo()))
 119                 WarpZone_TrailParticles_WithMultiplier(world, particleeffectnum(EFFECT_VORTEX_BEAM_OLD), this.vorg1, this.vorg2, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE);
 120         else
 121                 WarpZone_TrailParticles_WithMultiplier(world, particleeffectnum(EFFECT_VORTEX_BEAM), this.vorg1, this.vorg2, 1, PARTICLES_USEALPHA | PARTICLES_USEFADE);*/
 122 }
 123
 124 NET_HANDLE(TE_CSQC_VAPORBEAMPARTICLE, bool isNew)
 125 {
 126         Net_Accept(vortex_beam);
 127         this.think = SUB_Remove;
 128         this.nextthink = time + bound(0, autocvar_cl_vaporizerbeam_lifetime, 10);
 129         this.draw = VaporizerBeam_Draw;
 130         this.drawmask = MASK_NORMAL;
 131
 132         this.vorg1_x = ReadCoord(); this.vorg1_y = ReadCoord(); this.vorg1_z = ReadCoord();
 133         this.vorg2_x = ReadCoord(); this.vorg2_y = ReadCoord(); this.vorg2_z = ReadCoord();
 134         this.cnt = ReadByte();
 135         this.sv_entnum = ReadShort();
 136         this.team = ReadByte() - 1;
 137
 138         if(autocvar_cl_vaporizerbeam_particle)
 139         {
 140                 WarpZone_TrailParticles(world, particleeffectnum(((this.cnt) ? EFFECT_VAPORIZER_HIT(this.team) : EFFECT_VAPORIZER(this.team))), this.vorg1, this.vorg2);
 141                 this.draw = func_null;
 142                 this.drawmask = MASK_NORMAL;
 143                 remove(this);
 144         }
 145
 146         pointparticles(EFFECT_VORTEX_MUZZLEFLASH, this.vorg1, normalize(this.vorg2 - this.vorg1) * 1000, 1);
 147         return true;
 148 }
 149 #endif
 150
 151 #ifdef SVQC
 152 spawnfunc(weapon_vaporizer) { weapon_defaultspawnfunc(this, WEP_VAPORIZER); }
 153 spawnfunc(weapon_minstanex) { spawnfunc_weapon_vaporizer(this); }
 154
 155 void W_RocketMinsta_Explosion(vector loc)
 156 {SELFPARAM();
 157         if(accuracy_canbegooddamage(self))
 158                 accuracy_add(self, WEP_DEVASTATOR.m_id, autocvar_g_rm_damage, 0);
 159         entity dmgent = spawn();
 160         dmgent.owner = dmgent.realowner = self;
 161         setorigin(dmgent, loc);
 162         RadiusDamage (dmgent, self, autocvar_g_rm_damage, autocvar_g_rm_edgedamage, autocvar_g_rm_radius, world, world, autocvar_g_rm_force, WEP_DEVASTATOR.m_id | HITTYPE_SPLASH, other);
 163         remove(dmgent);
 164 }
 165
 166 void W_Vaporizer_Attack(Weapon thiswep)
 167 {SELFPARAM();
 168         bool flying = IsFlying(self); // do this BEFORE to make the trace values from FireRailgunBullet last
 169         float vaporizer_damage = ((WEP_CVAR_PRI(vaporizer, damage) > 0) ? WEP_CVAR_PRI(vaporizer, damage) : 10000);
 170
 171         W_SetupShot(self, true, 0, "", CH_WEAPON_A, vaporizer_damage);
 172         // handle sound separately so we can change the volume
 173         // added bonus: no longer plays the strength sound (strength gives no bonus to instakill anyway)
 174         sound (self, CH_WEAPON_A, SND_MINSTANEXFIRE, VOL_BASE * 0.8, ATTEN_NORM);
 175
 176         yoda = 0;
 177         damage_goodhits = 0;
 178         FireRailgunBullet(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, vaporizer_damage, 800, 0, 0, 0, 0, WEP_VAPORIZER.m_id);
 179
 180         // do this now, as goodhits is disabled below
 181         SendCSQCVaporizerBeamParticle(self, damage_goodhits);
 182
 183         if(yoda && flying)
 184                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_ACHIEVEMENT_YODA);
 185         if(damage_goodhits && self.vaporizer_lasthit)
 186         {
 187                 Send_Notification(NOTIF_ONE, self, MSG_ANNCE, ANNCE_ACHIEVEMENT_IMPRESSIVE);
 188                 damage_goodhits = 0; // only every second time
 189         }
 190
 191         self.vaporizer_lasthit = damage_goodhits;
 192
 193         if(autocvar_g_rm)
 194         if(!(trace_dphitq3surfaceflags & (Q3SURFACEFLAG_SKY | Q3SURFACEFLAG_NOIMPACT)))
 195                 W_RocketMinsta_Explosion(trace_endpos);
 196
 197         W_DecreaseAmmo(thiswep, self, ((g_instagib) ? 1 : WEP_CVAR_PRI(vaporizer, ammo)));
 198 }
 199
 200 void W_RocketMinsta_Laser_Explode ()
 201 {SELFPARAM();
 202         if(other.takedamage == DAMAGE_AIM)
 203                 if(IS_PLAYER(other))
 204                         if(DIFF_TEAM(self.realowner, other))
 205                                 if(other.deadflag == DEAD_NO)
 206                                         if(IsFlying(other))
 207                                                 Send_Notification(NOTIF_ONE, self.realowner, MSG_ANNCE, ANNCE_ACHIEVEMENT_ELECTROBITCH);
 208
 209         self.event_damage = func_null;
 210         self.takedamage = DAMAGE_NO;
 211         RadiusDamage (self, self.realowner, self.rm_damage, self.rm_edmg, autocvar_g_rm_laser_radius, world, world, self.rm_force, self.projectiledeathtype, other);
 212         remove(self);
 213 }
 214
 215 void W_RocketMinsta_Laser_Touch ()
 216 {SELFPARAM();
 217         PROJECTILE_TOUCH;
 218         //W_RocketMinsta_Laser_Explode ();
 219         RadiusDamage (self, self.realowner, self.rm_damage, self.rm_edmg, autocvar_g_rm_laser_radius, world, world, self.rm_force, self.projectiledeathtype, other);
 220         remove(self);
 221 }
 222
 223 void W_RocketMinsta_Attack2()
 224 {SELFPARAM();
 225         makevectors(self.v_angle);
 226
 227         entity proj;
 228         float counter = 0;
 229         float total = autocvar_g_rm_laser_count;
 230         float spread = autocvar_g_rm_laser_spread;
 231         float rndspread = autocvar_g_rm_laser_spread_random;
 232
 233         float w = self.weapon;
 234         self.weapon = WEP_ELECTRO.m_id;
 235         W_SetupShot_ProjectileSize (self, '0 0 -3', '0 0 -3', false, 2, SND(CRYLINK_FIRE), CH_WEAPON_A, autocvar_g_rm_laser_damage);
 236         self.weapon = w;
 237
 238         Send_Effect(EFFECT_ELECTRO_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 239
 240     while(counter < total)
 241         {
 242         proj = new(plasma_prim);
 243         proj.owner = proj.realowner = self;
 244         proj.bot_dodge = true;
 245         proj.bot_dodgerating = autocvar_g_rm_laser_damage;
 246         proj.use = W_RocketMinsta_Laser_Explode;
 247         proj.think = adaptor_think2use_hittype_splash;
 248         proj.nextthink = time + autocvar_g_rm_laser_lifetime;
 249         PROJECTILE_MAKETRIGGER(proj);
 250         proj.projectiledeathtype = WEP_ELECTRO.m_id;
 251         setorigin(proj, w_shotorg);
 252
 253                 proj.rm_force = autocvar_g_rm_laser_force / total;
 254                 proj.rm_damage = autocvar_g_rm_laser_damage / total;
 255                 proj.rm_edmg = proj.rm_damage;
 256
 257         //W_SetupProjectileVelocity(proj, autocvar_g_rm_laser_speed, spread * (rndspread ? random() : 1) * autocvar_g_rm_laser_speed);
 258
 259         proj.movetype = MOVETYPE_BOUNCEMISSILE;
 260         //W_SETUPPROJECTILEVELOCITY(proj, g_balance_minstanex_laser);
 261                 proj.velocity = (w_shotdir + (((counter + 0.5) / total) * 2 - 1) * v_right * (spread * (rndspread ? random() : 1))) * cvar("g_rm_laser_speed");
 262                 proj.velocity_z = proj.velocity_z + cvar("g_rm_laser_zspread") * (random() - 0.5);
 263                 proj.velocity = W_CalculateProjectileVelocity(proj.realowner.velocity, proj.velocity, true);
 264         proj.angles = vectoangles(proj.velocity);
 265         proj.touch = W_RocketMinsta_Laser_Touch;
 266         setsize(proj, '0 0 -3', '0 0 -3');
 267         proj.flags = FL_PROJECTILE;
 268         proj.missile_flags = MIF_SPLASH;
 269
 270         CSQCProjectile(proj, true, PROJECTILE_ROCKETMINSTA_LASER, true);
 271
 272         MUTATOR_CALLHOOK(EditProjectile, self, proj);
 273         counter++;
 274     }
 275 }
 276
 277 void W_RocketMinsta_Attack3 ()
 278 {SELFPARAM();
 279         makevectors(self.v_angle);
 280
 281         entity proj;
 282         float counter = 0;
 283         float total = 1;
 284
 285         int w = self.weapon;
 286         self.weapon = WEP_ELECTRO.m_id;
 287         W_SetupShot_ProjectileSize (self, '0 0 -3', '0 0 -3', false, 2, SND(ELECTRO_FIRE2), CH_WEAPON_A, autocvar_g_rm_laser_damage);
 288         self.weapon = w;
 289
 290         Send_Effect(EFFECT_ELECTRO_MUZZLEFLASH, w_shotorg, w_shotdir * 1000, 1);
 291
 292     while(counter < total)
 293         {
 294         proj = new(plasma_prim);
 295         proj.owner = proj.realowner = self;
 296         proj.bot_dodge = true;
 297         proj.bot_dodgerating = autocvar_g_rm_laser_damage;
 298         proj.use = W_RocketMinsta_Laser_Explode;
 299         proj.think = adaptor_think2use_hittype_splash;
 300         proj.nextthink = time + autocvar_g_rm_laser_lifetime;
 301         PROJECTILE_MAKETRIGGER(proj);
 302         proj.projectiledeathtype = WEP_ELECTRO.m_id;
 303         setorigin(proj, w_shotorg);
 304
 305                 proj.rm_force = autocvar_g_rm_laser_force / total;
 306                 proj.rm_damage = autocvar_g_rm_laser_damage / total;
 307                 proj.rm_edmg = proj.rm_damage;
 308
 309         //W_SetupProjectileVelocity(proj, autocvar_g_rm_laser_speed, spread * (rndspread ? random() : 1) * autocvar_g_rm_laser_speed);
 310
 311         proj.movetype = MOVETYPE_BOUNCEMISSILE;
 312                 proj.velocity = w_shotdir * autocvar_g_rm_laser_speed;
 313                 proj.velocity = W_CalculateProjectileVelocity(proj.realowner.velocity, proj.velocity, true);
 314         proj.angles = vectoangles(proj.velocity);
 315         proj.touch = W_RocketMinsta_Laser_Touch;
 316         setsize(proj, '0 0 -3', '0 0 -3');
 317         proj.flags = FL_PROJECTILE;
 318         proj.missile_flags = MIF_SPLASH;
 319
 320         CSQCProjectile(proj, true, PROJECTILE_ROCKETMINSTA_LASER, true);
 321
 322         MUTATOR_CALLHOOK(EditProjectile, self, proj);
 323         counter++;
 324     }
 325 }
 326
 327                 METHOD(Vaporizer, wr_aim, void(entity thiswep))
 328                 {
 329                         if(self.WEP_AMMO(VAPORIZER) > 0)
 330                                 self.BUTTON_ATCK = bot_aim(1000000, 0, 1, false);
 331                         else
 332                                 self.BUTTON_ATCK2 = bot_aim(WEP_CVAR_SEC(vaporizer, speed), 0, WEP_CVAR_SEC(vaporizer, lifetime), false); // WEAPONTODO: replace with proper vaporizer cvars
 333                 }
 334                 METHOD(Vaporizer, wr_think, void(entity thiswep, entity actor, .entity weaponentity, int fire))
 335                 {
 336                         float vaporizer_ammo = ((g_instagib) ? 1 : WEP_CVAR_PRI(vaporizer, ammo));
 337                         // if the laser uses load, we also consider its ammo for reloading
 338                         if(WEP_CVAR(vaporizer, reload_ammo) && WEP_CVAR_SEC(vaporizer, ammo) && actor.clip_load < min(vaporizer_ammo, WEP_CVAR_SEC(vaporizer, ammo))) { // forced reload
 339                                 Weapon w = get_weaponinfo(actor.weapon);
 340                                 w.wr_reload(w);
 341                         } else if(WEP_CVAR(vaporizer, reload_ammo) && actor.clip_load < vaporizer_ammo) { // forced reload
 342                                 Weapon w = get_weaponinfo(actor.weapon);
 343                                 w.wr_reload(w);
 344                         }
 345                         if((fire & 1) && (actor.ammo_cells || !autocvar_g_rm) && !forbidWeaponUse(actor))
 346                         {
 347                                 if(weapon_prepareattack(thiswep, actor, weaponentity, false, WEP_CVAR_PRI(vaporizer, refire)))
 348                                 {
 349                                         W_Vaporizer_Attack(thiswep);
 350                                         weapon_thinkf(actor, weaponentity, WFRAME_FIRE1, WEP_CVAR_PRI(vaporizer, animtime), w_ready);
 351                                 }
 352                         }
 353                         if((fire & 2) || ((fire & 1) && !actor.ammo_cells && autocvar_g_rm))
 354                         {
 355                                 if((autocvar_g_rm && autocvar_g_rm_laser) || autocvar_g_rm_laser == 2)
 356                                 {
 357                                         bool rapid = autocvar_g_rm_laser_rapid;
 358                                         if(actor.jump_interval <= time && !actor.held_down)
 359                                         {
 360                                                 if(rapid)
 361                                                         actor.held_down = true;
 362                                                 actor.jump_interval = time + autocvar_g_rm_laser_refire;
 363                                                 actor.jump_interval2 = time + autocvar_g_rm_laser_rapid_delay;
 364                                                 damage_goodhits = 0;
 365                                                 W_RocketMinsta_Attack2();
 366                                         }
 367                                         else if(rapid && actor.jump_interval2 <= time && actor.held_down)
 368                                         {
 369                                                 actor.jump_interval2 = time + autocvar_g_rm_laser_rapid_refire;
 370                                                 damage_goodhits = 0;
 371                                                 W_RocketMinsta_Attack3();
 372                                                 //weapon_thinkf(actor, WFRAME_FIRE2, autocvar_g_rm_laser_rapid_animtime, w_ready);
 373                                         }
 374                                 }
 375                                 else if (actor.jump_interval <= time)
 376                                 {
 377                                         // handle refire manually, so that primary and secondary can be fired without conflictions (important for instagib)
 378                                         actor.jump_interval = time + WEP_CVAR_SEC(vaporizer, refire) * W_WeaponRateFactor();
 379
 380                                         // decrease ammo for the laser?
 381                                         if(WEP_CVAR_SEC(vaporizer, ammo))
 382                                                 W_DecreaseAmmo(thiswep, actor, WEP_CVAR_SEC(vaporizer, ammo));
 383
 384                                         // ugly instagib hack to reuse the fire mode of the laser
 385                                         makevectors(actor.v_angle);
 386                                         int oldwep = actor.weapon; // we can't avoid this hack
 387                                         actor.weapon = WEP_BLASTER.m_id;
 388                                         W_Blaster_Attack(
 389                                                 actor,
 390                                                 WEP_BLASTER.m_id | HITTYPE_SECONDARY,
 391                                                 WEP_CVAR_SEC(vaporizer, shotangle),
 392                                                 WEP_CVAR_SEC(vaporizer, damage),
 393                                                 WEP_CVAR_SEC(vaporizer, edgedamage),
 394                                                 WEP_CVAR_SEC(vaporizer, radius),
 395                                                 WEP_CVAR_SEC(vaporizer, force),
 396                                                 WEP_CVAR_SEC(vaporizer, speed),
 397                                                 WEP_CVAR_SEC(vaporizer, spread),
 398                                                 WEP_CVAR_SEC(vaporizer, delay),
 399                                                 WEP_CVAR_SEC(vaporizer, lifetime)
 400                                         );
 401                                         actor.weapon = oldwep;
 402
 403                                         // now do normal refire
 404                                         weapon_thinkf(actor, weaponentity, WFRAME_FIRE2, WEP_CVAR_SEC(vaporizer, animtime), w_ready);
 405                                 }
 406                         }
 407                         else
 408                                 actor.held_down = false;
 409                 }
 410                 METHOD(Vaporizer, wr_init, void(entity thiswep))
 411                 {
 412                         //W_Blaster(WR_INIT); // Samual: Is this really the proper thing to do? Didn't we already run this previously?
 413                         VAPORIZER_SETTINGS(WEP_SKIP_CVAR, WEP_SET_PROP);
 414                 }
 415                 METHOD(Vaporizer, wr_setup, void(entity thiswep))
 416                 {
 417                         self.ammo_field = WEP_AMMO(VAPORIZER);
 418                         self.vaporizer_lasthit = 0;
 419                 }
 420                 METHOD(Vaporizer, wr_checkammo1, bool(entity thiswep))
 421                 {
 422                         float vaporizer_ammo = ((g_instagib) ? 1 : WEP_CVAR_PRI(vaporizer, ammo));
 423                         float ammo_amount = self.WEP_AMMO(VAPORIZER) >= vaporizer_ammo;
 424                         ammo_amount += self.(weapon_load[WEP_VAPORIZER.m_id]) >= vaporizer_ammo;
 425                         return ammo_amount;
 426                 }
 427                 METHOD(Vaporizer, wr_checkammo2, bool(entity thiswep))
 428                 {
 429                         if(!WEP_CVAR_SEC(vaporizer, ammo))
 430                                 return true;
 431                         float ammo_amount = self.WEP_AMMO(VAPORIZER) >= WEP_CVAR_SEC(vaporizer, ammo);
 432                         ammo_amount += self.(weapon_load[WEP_VAPORIZER.m_id]) >= WEP_CVAR_SEC(vaporizer, ammo);
 433                         return ammo_amount;
 434                 }
 435                 METHOD(Vaporizer, wr_config, void(entity thiswep))
 436                 {
 437                         VAPORIZER_SETTINGS(WEP_CONFIG_WRITE_CVARS, WEP_CONFIG_WRITE_PROPS);
 438                 }
 439                 METHOD(Vaporizer, wr_resetplayer, void(entity thiswep))
 440                 {
 441                         self.vaporizer_lasthit = 0;
 442                 }
 443                 METHOD(Vaporizer, wr_reload, void(entity thiswep))
 444                 {
 445                         float vaporizer_ammo = ((g_instagib) ? 1 : WEP_CVAR_PRI(vaporizer, ammo));
 446                         float used_ammo;
 447                         if(WEP_CVAR_SEC(vaporizer, ammo))
 448                                 used_ammo = min(vaporizer_ammo, WEP_CVAR_SEC(vaporizer, ammo));
 449                         else
 450                                 used_ammo = vaporizer_ammo;
 451
 452                         W_Reload(self, used_ammo, SND(RELOAD));
 453                 }
 454                 METHOD(Vaporizer, wr_suicidemessage, int(entity thiswep))
 455                 {
 456                         return WEAPON_THINKING_WITH_PORTALS;
 457                 }
 458                 METHOD(Vaporizer, wr_killmessage, int(entity thiswep))
 459                 {
 460                         return WEAPON_VAPORIZER_MURDER;
 461                 }
 462
 463 #endif
 464 #ifdef CSQC
 465
 466                 METHOD(Vaporizer, wr_impacteffect, void(entity thiswep))
 467                 {
 468                         vector org2 = w_org + w_backoff * 6;
 469                         if(w_deathtype & HITTYPE_SECONDARY)
 470                         {
 471                                 pointparticles(EFFECT_BLASTER_IMPACT, org2, w_backoff * 1000, 1);
 472                                 if(!w_issilent) { sound(self, CH_SHOTS, SND_LASERIMPACT, VOL_BASE, ATTN_NORM); }
 473                         }
 474                         else
 475                         {
 476                                 pointparticles(EFFECT_VORTEX_IMPACT, org2, '0 0 0', 1);
 477                                 if(!w_issilent) { sound(self, CH_SHOTS, SND_NEXIMPACT, VOL_BASE, ATTN_NORM); }
 478                         }
 479                 }
 480                 METHOD(Vaporizer, wr_init, void(entity thiswep))
 481                 {
 482                         if(autocvar_cl_reticle && autocvar_cl_reticle_weapon)
 483                         {
 484                                 precache_pic("gfx/reticle_nex");
 485                         }
 486                 }
 487                 METHOD(Vaporizer, wr_zoomreticle, bool(entity thiswep))
 488                 {
 489                         if(button_zoom || zoomscript_caught)
 490                         {
 491                                 reticle_image = "gfx/reticle_nex";
 492                                 return true;
 493                         }
 494                         else
 495                         {
 496                                 // no weapon specific image for this weapon
 497                                 return false;
 498                         }
 499                 }
 500
 501 #endif
 502 #endif