qcsrc/lib/deglobalization.qh

   1 #include "lib/float.qh"
   2 #include "lib/misc.qh"
   3 #include "lib/static.qh"
   4 #include "lib/vector.qh"
   5
   6 // These macros wrap functions which use globals so mutation only occurs inside them and is not visible from outside.
   7 // Functions for which all usages are replaced with these macros can be hidden by #defines inside our `*defs.qh` files
   8 // to prevent anyone from using them accidentally in the future
   9
  10 // TODO stuff in the engine that uses the v_forward/v_right/v_up globals and is not wrapped yet:
  11 //  - RF_USEAXIS, addentities, predraw,
  12 //    - CL_GetEntityMatrix (in engine but is called from other functions so transitively any of them can use the globals - e.g. V_CalcRefdef, maybe others)
  13 //    - however RF_USEAXIS is only used if MF_ROTATE is used which is only set in one place
  14 //  - e.camera_transform / CL_VM_TransformView (in engine
  15 //    - this is the only used function that both sets and gets the globals (aim does too but isn't used in our code)
  16
  17 #define NEW_VECS(...) EVAL(OVERLOAD(NEW_VECS, __VA_ARGS__))
  18 #define NEW_VECS_3(forward, right, up) vector forward = '0 0 0'; vector right = '0 0 0'; vector up = '0 0 0'
  19 #define NEW_VECS_4(forward, right, up, origin) NEW_VECS_3(forward, right, up); vector origin = '0 0 0'
  20
  21 // convenience for deglobalized code - don't use these just to hide that globals are still used
  22 #define CLEAR_V_GLOBALS() v_forward = VEC_NAN; v_right = VEC_NAN; v_up = VEC_NAN;
  23 #define GET_V_GLOBALS(forward, right, up) forward = v_forward; right = v_right; up = v_up;
  24 #define SET_V_GLOBALS(forward, right, up) v_forward = forward; v_right = right; v_up = up;
  25
  26 #ifdef GAMEQC
  27 STATIC_INIT(globals) {
  28         // set to NaN to more easily detect uninitialized use
  29         // TODO when all functions are wrapped and the raw functions are not used anymore,
  30         // uncomment the defines in *progs.qh files that hide the raw functions
  31         // and assert that the global vectors are NaN before calling the raw functions here
  32         // to make sure nobody (even builtins) is accidentally using them - NaN is the most likely value to expose remaining usages
  33
  34         CLEAR_V_GLOBALS();
  35 }
  36 #endif
  37
  38 /// Same as the `makevectors` builtin but uses the provided locals instead of the `v_*` globals.
  39 /// Always use this instead of raw `makevectors` to make the data flow clear.
  40 /// Note that you might prefer `FIXED_MAKE_VECTORS` for new code.
  41 #define MAKE_VECTORS(angles, forward, right, up) MACRO_BEGIN { \
  42         _makevectors_hidden(angles); \
  43         GET_V_GLOBALS(forward, right, up); \
  44         CLEAR_V_GLOBALS(); \
  45 } MACRO_END
  46
  47 /// Same as `MAKE_VECTORS` but also creates the locals for convenience.
  48 #define MAKE_VECTORS_NEW(angles, forward, right, up) \
  49         NEW_VECS(forward, right, up); \
  50         MAKE_VECTORS(angles, forward, right, up);
  51
  52 /// Returns all 4 vectors by assigning to them (instead of returning a value) for consistency (and sanity)
  53 #define SKEL_GET_BONE_ABS(skel, bonenum, forward, right, up, origin) MACRO_BEGIN { \
  54         origin = _skel_get_boneabs_hidden(skel, bonenum) \
  55         GET_V_GLOBALS(forward, right, up); \
  56         CLEAR_V_GLOBALS(); \
  57 } MACRO_END
  58
  59 #define SKEL_GET_BONE_ABS_NEW(skel, bonenum, forward, right, up, origin) \
  60         NEW_VECS(forward, right, up, origin); \
  61         SKEL_GET_BONE_ABS(skel, bonenum, forward, right, up, origin)
  62
  63 #define SKEL_SET_BONE(skel, bonenum, org, forward, right, up) MACRO_BEGIN { \
  64         SET_V_GLOBALS(forward, right, up); \
  65         _skel_set_bone_hidden(skel, bonenum, org); \
  66         CLEAR_V_GLOBALS(); \
  67 } MACRO_END
  68
  69 #define ADD_DYNAMIC_LIGHT(org, radius, lightcolours, forward, right, up) MACRO_BEGIN { \
  70         SET_V_GLOBALS(forward, right, up); \
  71         _adddynamiclight_hidden(org, radius, lightcolours); \
  72         CLEAR_V_GLOBALS(); \
  73 } MACRO_END
  74
  75 #define VECTOR_VECTORS(forward_in, forward, right, up) MACRO_BEGIN { \
  76         _vectorvectors_hidden(forward_in); \
  77         GET_V_GLOBALS(forward, right, up); \
  78         CLEAR_V_GLOBALS(); \
  79 } MACRO_END
  80
  81 #define VECTOR_VECTORS_NEW(forward_in, forward, right, up) \
  82         NEW_VECS(forward, right, up); \
  83         VECTOR_VECTORS(forward_in, forward, right, up);
  84
  85 /// Note that this only avoids the v_* globals, not the gettaginfo_* ones
  86 #define GET_TAG_INFO(ent, tagindex, forward, right, up, origin) MACRO_BEGIN {  \
  87         origin = _gettaginfo_hidden(ent, tagindex); \
  88         GET_V_GLOBALS(forward, right, up); \
  89         CLEAR_V_GLOBALS(); \
  90 } MACRO_END
  91
  92 #define GET_TAG_INFO_NEW(ent, tagindex, forward, right, up, origin) \
  93         NEW_VECS(forward, right, up, origin); \
  94         GET_TAG_INFO(ent, tagindex, forward, right, up, origin);