qcsrc/lib/iter.qh

   1 #ifndef ITER_H
   2 #define ITER_H
   3
   4 #define FOREACH_ARRAY(arr, start, end, cond, body) \
   5         do \
   6         { \
   7                 for (int i = start; i < end; ++i) \
   8                 { \
   9                         const noref entity it = arr[i]; \
  10                         if (cond) { body } \
  11                 } \
  12         } \
  13         while (0)
  14
  15 #define FOREACH_LIST(list, next, cond, body) \
  16         do \
  17         { \
  18                 int i = 0; \
  19                 for (entity it = list##_first; it; (it = it.next, ++i)) \
  20                 { \
  21                         if (cond) { body } \
  22                 } \
  23         } \
  24         while (0)
  25
  26 #define FOREACH_WORD(words, cond, body) \
  27         do \
  28         { \
  29                 string _words = words; \
  30                 int i = 0; \
  31                 for (string _it; (_it = car(_words)); (_words = cdr(_words), ++i)) \
  32                 { \
  33                         const noref string it = _it; \
  34                         if (cond) { body } \
  35                 } \
  36         } \
  37         while (0)
  38
  39 #if defined(CSQC)
  40         entity(.string fld, string match, .entity tofield) _findchainstring_tofield = #402;
  41         entity(.entity fld, entity match, .entity tofield) findchainentity_tofield = #403;
  42         entity(.float fld, float match, .entity tofield) _findchainflags_tofield = #450;
  43 #elif defined(SVQC)
  44         entity(.string fld, string match, .entity tofield) _findchainstring_tofield = #402;
  45         entity(.entity fld, entity match, .entity tofield) findchainentity_tofield = #403;
  46         entity(.float fld, float match, .entity tofield) _findchainflags_tofield = #450;
  47 #elif defined(MENUQC)
  48         entity(.string fld, string match, .entity tofield) _findchainstring_tofield = #26;
  49         entity(.entity fld, entity match, .entity tofield) findchainentity_tofield = #27;
  50         entity(.float fld, float match, .entity tofield) _findchainflags_tofield = #88;
  51 #endif
  52
  53 .entity _FOREACH_ENTITY_fld;
  54 .entity _FOREACH_ENTITY_next;
  55
  56 #define FOREACH_ENTITY_UNORDERED(cond, body) \
  57         do { \
  58                 int i = 0; \
  59                 for (entity it = findchainentity_tofield(_FOREACH_ENTITY_fld, NULL, _FOREACH_ENTITY_next); it; (it = it._FOREACH_ENTITY_next, ++i)) \
  60                 { \
  61                         if (cond) { body } \
  62                 } \
  63         } \
  64         while (0)
  65
  66 #define FOREACH_ENTITY_ORDERED(cond, body) \
  67         do { \
  68                 int i = 0; \
  69                 for (entity it = NULL; (it = nextent(it)); ++i) \
  70                 { \
  71                         if (cond) { body } \
  72                 } \
  73         } \
  74         while (0)
  75
  76 #define FOREACH_ENTITY_FLAGS(fld, flags, body) \
  77         do { \
  78                 int i = 0; \
  79                 for (entity it = _findchainflags_tofield(fld, flags, _FOREACH_ENTITY_next); it; (it = it._FOREACH_ENTITY_next, ++i)) \
  80                 { \
  81                         body \
  82                 } \
  83         } \
  84         while (0)
  85
  86 #define FOREACH_ENTITY_CLASS(class, cond, body) \
  87         do { \
  88                 int i = 0; \
  89                 for (entity it = _findchainstring_tofield(classname, class, _FOREACH_ENTITY_next); it; (it = it._FOREACH_ENTITY_next, ++i)) \
  90                 { \
  91                         if (cond) { body } \
  92                 } \
  93         } \
  94         while (0)
  95
  96 #define FOREACH_ENTITY(cond, body) FOREACH_ENTITY_UNORDERED(cond, body)
  97
  98 #define FOREACH(list, cond, body) FOREACH_LIST(list, enemy, cond, body)
  99
 100 #endif