qcsrc/lib/net.qh

   1 #ifndef NET_H
   2 #define NET_H
   3
   4 #ifdef SVQC
   5         .int Version;  // deprecated, use SendFlags
   6         .int SendFlags;
   7         .bool(entity to, int sendflags) SendEntity;
   8         /** return false to remove from the client */
   9         .bool(entity this, entity to, int sendflags) SendEntity3;
  10
  11         bool SendEntity_self(entity to, int sendflags) { return self.SendEntity3(self, to, sendflags); }
  12
  13         void Net_LinkEntity(entity e, bool docull, float dt, bool(entity this, entity to, int sendflags) sendfunc)
  14         {
  15                 if (e.classname == "") e.classname = "net_linked";
  16
  17                 if (e.model == "" || self.modelindex == 0)
  18                 {
  19                         vector mi = e.mins;
  20                         vector ma = e.maxs;
  21                         _setmodel(e, "null");
  22                         setsize(e, mi, ma);
  23                 }
  24
  25                 e.SendEntity = SendEntity_self;
  26                 e.SendEntity3 = sendfunc;
  27                 e.SendFlags = 0xFFFFFF;
  28
  29                 if (!docull) e.effects |= EF_NODEPTHTEST;
  30
  31                 if (dt)
  32                 {
  33                         e.nextthink = time + dt;
  34                         e.think = SUB_Remove_self;
  35                 }
  36         }
  37
  38         .void() uncustomizeentityforclient;
  39         .float uncustomizeentityforclient_set;
  40
  41         void SetCustomizer(entity e, float() customizer, void() uncustomizer)
  42         {
  43                 e.customizeentityforclient = customizer;
  44                 e.uncustomizeentityforclient = uncustomizer;
  45                 e.uncustomizeentityforclient_set = !!uncustomizer;
  46         }
  47
  48         void UncustomizeEntitiesRun()
  49         {
  50                 for (entity e = NULL; (e = findfloat(e, uncustomizeentityforclient_set, 1)); )
  51                         WITH(entity, self, e, e.uncustomizeentityforclient());
  52         }
  53
  54 #endif
  55
  56 #include "registry.qh"
  57 #include "sort.qh"
  58
  59 .string netname;
  60 .int m_id;
  61 .bool(entity this, bool isNew) m_read;
  62
  63 #ifdef CSQC
  64         #define Net_Accept(classname) \
  65                 do \
  66                 { \
  67                         if (!this)    this = new(classname); \
  68                 } \
  69                 while (0)
  70         #define Net_Reject() \
  71                 do \
  72                 { \
  73                         if (this)     remove(this); \
  74                 } \
  75                 while (0)
  76         #define NET_HANDLE(id, param) \
  77                 bool Net_Handle_##id(entity this, param)
  78 #else
  79         #define WriteHeader(to, id) \
  80                 do \
  81                 { \
  82                         if (NET_##id##_istemp) WriteByte(to, SVC_TEMPENTITY); \
  83                         WriteByte(to, NET_##id.m_id); \
  84                 } \
  85                 while (0)
  86 #endif
  87
  88 #ifdef CSQC
  89         #define REGISTER_NET_LINKED(id) \
  90                 [[accumulate]] NET_HANDLE(id, bool isnew) \
  91                 { \
  92                         this = self; \
  93                         this.sourceLocFile = __FILE__; \
  94                         this.sourceLocLine = __LINE__; \
  95                         if (!this) isnew = true; \
  96                 } \
  97                 REGISTER(LinkedEntities, NET, id, m_id, new(net_linked_packet)) \
  98                 { \
  99                         make_pure(this); \
 100                         this.netname = #id; \
 101                         this.m_read = Net_Handle_##id; \
 102                 }
 103 #else
 104         #define REGISTER_NET_LINKED(id) \
 105                 const bool NET_##id##_istemp = false; \
 106                 REGISTER(LinkedEntities, NET, id, m_id, new(net_linked_packet)) \
 107                 { \
 108                         make_pure(this); \
 109                         this.netname = #id; \
 110                 }
 111 #endif
 112
 113 REGISTRY(LinkedEntities, BITS(8) - 1)
 114 #define LinkedEntities_from(i) _LinkedEntities_from(i, NULL)
 115 REGISTER_REGISTRY(LinkedEntities)
 116 REGISTRY_SORT(LinkedEntities)
 117 REGISTRY_CHECK(LinkedEntities)
 118 STATIC_INIT(RegisterLinkedEntities_renumber)
 119 {
 120         for (int i = 0; i < LinkedEntities_COUNT; ++i)
 121                 LinkedEntities_from(i).m_id = 1 + i;
 122 }
 123
 124 #ifdef CSQC
 125         #define REGISTER_NET_TEMP(id) \
 126                 NET_HANDLE(id, bool); \
 127                 REGISTER(TempEntities, NET, id, m_id, new(net_temp_packet)) \
 128                 { \
 129                         make_pure(this); \
 130                         this.netname = #id; \
 131                         this.m_read = Net_Handle_##id; \
 132                 }
 133 #else
 134         #define REGISTER_NET_TEMP(id) \
 135                 const bool NET_##id##_istemp = true; \
 136                 REGISTER(TempEntities, NET, id, m_id, new(net_temp_packet)) \
 137                 { \
 138                         make_pure(this); \
 139                         this.netname = #id; \
 140                 }
 141 #endif
 142
 143 REGISTRY(TempEntities, BITS(8) - 80)
 144 #define TempEntities_from(i) _TempEntities_from(i, NULL)
 145 REGISTER_REGISTRY(TempEntities)
 146 REGISTRY_SORT(TempEntities)
 147 REGISTRY_CHECK(TempEntities)
 148 STATIC_INIT(RegisterTempEntities_renumber)
 149 {
 150         for (int i = 0; i < TempEntities_COUNT; ++i)
 151                 TempEntities_from(i).m_id = 80 + i;
 152 }
 153
 154 #ifndef MENUQC
 155         const float APPROXPASTTIME_ACCURACY_REQUIREMENT = 0.05;
 156         #define APPROXPASTTIME_MAX (16384 * APPROXPASTTIME_ACCURACY_REQUIREMENT)
 157         #define APPROXPASTTIME_RANGE (64 * APPROXPASTTIME_ACCURACY_REQUIREMENT)
 158
 159         #ifdef CSQC
 160                 entity ReadCSQCEntity()
 161                 {
 162                         int f = ReadShort();
 163                         if (f == 0) return world;
 164                         return findfloat(world, entnum, f);
 165                 }
 166                 int ReadInt24_t()
 167                 {
 168                         int v = ReadShort() << 8; // note: this is signed
 169                         v += ReadByte();          // note: this is unsigned
 170                         return v;
 171                 }
 172                 vector ReadInt48_t()
 173                 {
 174                         vector v;
 175                         v.x = ReadInt24_t();
 176                         v.y = ReadInt24_t();
 177                         v.z = 0;
 178                         return v;
 179                 }
 180                 vector ReadInt72_t()
 181                 {
 182                         vector v;
 183                         v.x = ReadInt24_t();
 184                         v.y = ReadInt24_t();
 185                         v.z = ReadInt24_t();
 186                         return v;
 187                 }
 188
 189                 #define ReadFloat() ReadCoord()
 190         vector ReadVector() { vector v; v.x = ReadFloat(); v_y = ReadFloat(); v.z = ReadFloat(); return v; }
 191                 vector ReadVector2D() { vector v; v.x = ReadFloat(); v.y = ReadFloat(); v.z = 0; return v; }
 192
 193                 float ReadApproxPastTime()
 194                 {
 195                         float dt = ReadByte();
 196
 197                         // map from range...PPROXPASTTIME_MAX / 256
 198                         dt = (APPROXPASTTIME_MAX / 256) * (dt / (256 - dt));
 199
 200                         return servertime - dt;
 201                 }
 202
 203         #else
 204                 const int MSG_ENTITY = 5;
 205
 206                 void WriteInt24_t(float dst, float val)
 207                 {
 208                         float v;
 209                         WriteShort(dst, (v = floor(val >> 8)));
 210                         WriteByte(dst, val - (v << 8));  // 0..255
 211                 }
 212                 void WriteInt48_t(float dst, vector val)
 213                 {
 214                         WriteInt24_t(dst, val.x);
 215                         WriteInt24_t(dst, val.y);
 216                 }
 217                 void WriteInt72_t(float dst, vector val)
 218                 {
 219                         WriteInt24_t(dst, val.x);
 220                         WriteInt24_t(dst, val.y);
 221                         WriteInt24_t(dst, val.z);
 222                 }
 223
 224         #define WriteFloat(to, f) WriteCoord(to, f)
 225                 #define WriteVector(to, v) do { WriteFloat(to, v.x); WriteFloat(to, v.y); WriteFloat(to, v.z); } while (0)
 226         #define WriteVector2D(to, v) do { WriteFloat(to, v.x); WriteFloat(to, v.y); } while (0)
 227
 228                 // this will use the value:
 229                 //   128
 230                 // accuracy near zero is APPROXPASTTIME_MAX/(256*255)
 231                 // accuracy at x is 1/derivative, i.e.
 232                 //   APPROXPASTTIME_MAX * (1 + 256 * (dt / APPROXPASTTIME_MAX))^2 / 65536
 233                 void WriteApproxPastTime(float dst, float t)
 234                 {
 235                         float dt = time - t;
 236
 237                         // warning: this is approximate; do not resend when you don't have to!
 238                         // be careful with sendflags here!
 239                         // we want: 0 -> 0.05, 1 -> 0.1, ..., 255 -> 12.75
 240
 241                         // map to range...
 242                         dt = 256 * (dt / ((APPROXPASTTIME_MAX / 256) + dt));
 243
 244                         // round...
 245                         dt = rint(bound(0, dt, 255));
 246
 247                         WriteByte(dst, dt);
 248                 }
 249
 250                 // allow writing to also pass through to spectators (like so spectators see the same centerprints as players for example)
 251                 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname, statement) \
 252                         entity varname; varname = msg_entity; \
 253                         FOR_EACH_REALCLIENT(msg_entity) \
 254                         if (msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) \
 255                                 statement msg_entity = varname
 256                 #define WRITESPECTATABLE_MSG_ONE(statement) \
 257                         do \
 258                         { \
 259                                 WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement); \
 260                         } \
 261                         while (0)
 262                 #define WRITESPECTATABLE(msg, statement) \
 263                         if (msg == MSG_ONE) WRITESPECTATABLE_MSG_ONE(statement); \
 264                         else \
 265                                 statement float WRITESPECTATABLE_workaround = 0
 266         #endif
 267 #endif
 268
 269 #endif