qcsrc/lib/net.qh

   1 #ifndef NET_H
   2 #define NET_H
   3
   4 #ifdef SVQC
   5         .int Version;  // deprecated, use SendFlags
   6         .int SendFlags;
   7         .bool(entity to, int sendflags) SendEntity;
   8         .bool(entity this, entity to, int sendflags) SendEntity3;
   9
  10         bool SendEntity_self(entity to, int sendflags) { return self.SendEntity3(self, to, sendflags); }
  11
  12         void Net_LinkEntity(entity e, bool docull, float dt, bool(entity this, entity to, int sendflags) sendfunc)
  13         {
  14                 if (e.classname == "") e.classname = "net_linked";
  15
  16                 if (e.model == "" || self.modelindex == 0)
  17                 {
  18                         vector mi = e.mins;
  19                         vector ma = e.maxs;
  20                         _setmodel(e, "null");
  21                         setsize(e, mi, ma);
  22                 }
  23
  24                 e.SendEntity = SendEntity_self;
  25                 e.SendEntity3 = sendfunc;
  26                 e.SendFlags = 0xFFFFFF;
  27
  28                 if (!docull) e.effects |= EF_NODEPTHTEST;
  29
  30                 if (dt)
  31                 {
  32                         e.nextthink = time + dt;
  33                         e.think = SUB_Remove;
  34                 }
  35         }
  36
  37         .void() uncustomizeentityforclient;
  38         .float uncustomizeentityforclient_set;
  39
  40         void SetCustomizer(entity e, float() customizer, void() uncustomizer)
  41         {
  42                 e.customizeentityforclient = customizer;
  43                 e.uncustomizeentityforclient = uncustomizer;
  44                 e.uncustomizeentityforclient_set = !!uncustomizer;
  45         }
  46
  47         void UncustomizeEntitiesRun()
  48         {
  49                 for (entity e = NULL; (e = findfloat(e, uncustomizeentityforclient_set, 1)); )
  50                         WITH(entity, self, e, e.uncustomizeentityforclient());
  51         }
  52
  53 #endif
  54
  55 #include "registry.qh"
  56 #include "sort.qh"
  57
  58 .string netname;
  59 .int m_id;
  60 .bool(entity this, bool isNew) m_read;
  61
  62 #ifdef CSQC
  63         #define Net_Accept(classname) \
  64                 do \
  65                 { \
  66                         if (!this)    this = new(classname); \
  67                 } \
  68                 while (0)
  69         #define Net_Reject() \
  70                 do \
  71                 { \
  72                         if (this)     remove(this); \
  73                 } \
  74                 while (0)
  75         #define NET_HANDLE(id, param) \
  76                 bool Net_Handle_##id(entity this, param)
  77 #else
  78         #define WriteHeader(to, id) \
  79                 do \
  80                 { \
  81                         if (NET_##id##_istemp) WriteByte(to, SVC_TEMPENTITY); \
  82                         WriteByte(to, NET_##id.m_id); \
  83                 } \
  84                 while (0)
  85 #endif
  86
  87 #ifdef CSQC
  88         #define REGISTER_NET_LINKED(id) \
  89                 [[accumulate]] NET_HANDLE(id, bool) \
  90                 { \
  91                         this = self; \
  92                         this.sourceLocFile = __FILE__; \
  93                         this.sourceLocLine = __LINE__; \
  94                 } \
  95                 REGISTER(RegisterLinkedEntities, NET, LinkedEntities, id, m_id, new(net_linked_packet)) \
  96                 { \
  97                         make_pure(this); \
  98                         this.netname = #id; \
  99                         this.m_read = Net_Handle_##id; \
 100                 }
 101 #else
 102         #define REGISTER_NET_LINKED(id) \
 103                 const bool NET_##id##_istemp = false; \
 104                 REGISTER(RegisterLinkedEntities, NET, LinkedEntities, id, m_id, new(net_linked_packet)) \
 105                 { \
 106                         make_pure(this); \
 107                         this.netname = #id; \
 108                 }
 109 #endif
 110
 111 REGISTRY(LinkedEntities, BITS(8) - 1)
 112 #define LinkedEntities_from(i) _LinkedEntities_from(i, NULL)
 113 REGISTER_REGISTRY(RegisterLinkedEntities)
 114 REGISTRY_SORT(LinkedEntities, 0)
 115 STATIC_INIT(RegisterLinkedEntities_renumber)
 116 {
 117         for (int i = 0; i < LinkedEntities_COUNT; ++i)
 118                 LinkedEntities_from(i).m_id = 1 + i;
 119 }
 120
 121 #ifdef CSQC
 122         #define REGISTER_NET_TEMP(id) \
 123                 NET_HANDLE(id, bool); \
 124                 REGISTER(RegisterTempEntities, NET, TempEntities, id, m_id, new(net_temp_packet)) \
 125                 { \
 126                         make_pure(this); \
 127                         this.netname = #id; \
 128                         this.m_read = Net_Handle_##id; \
 129                 }
 130 #else
 131         #define REGISTER_NET_TEMP(id) \
 132                 const bool NET_##id##_istemp = true; \
 133                 REGISTER(RegisterTempEntities, NET, TempEntities, id, m_id, new(net_temp_packet)) \
 134                 { \
 135                         make_pure(this); \
 136                         this.netname = #id; \
 137                 }
 138 #endif
 139
 140 REGISTRY(TempEntities, BITS(8) - 80)
 141 #define TempEntities_from(i) _TempEntities_from(i, NULL)
 142 REGISTER_REGISTRY(RegisterTempEntities)
 143 REGISTRY_SORT(TempEntities, 0)
 144 STATIC_INIT(RegisterTempEntities_renumber)
 145 {
 146         for (int i = 0; i < TempEntities_COUNT; ++i)
 147                 TempEntities_from(i).m_id = 80 + i;
 148 }
 149
 150 #ifndef MENUQC
 151         const float APPROXPASTTIME_ACCURACY_REQUIREMENT = 0.05;
 152         #define APPROXPASTTIME_MAX (16384 * APPROXPASTTIME_ACCURACY_REQUIREMENT)
 153         #define APPROXPASTTIME_RANGE (64 * APPROXPASTTIME_ACCURACY_REQUIREMENT)
 154
 155         #ifdef CSQC
 156                 entity ReadCSQCEntity()
 157                 {
 158                         int f = ReadShort();
 159                         if (f == 0) return world;
 160                         return findfloat(world, entnum, f);
 161                 }
 162                 int ReadInt24_t()
 163                 {
 164                         int v = ReadShort() << 8; // note: this is signed
 165                         v += ReadByte();          // note: this is unsigned
 166                         return v;
 167                 }
 168                 vector ReadInt48_t()
 169                 {
 170                         vector v;
 171                         v.x = ReadInt24_t();
 172                         v.y = ReadInt24_t();
 173                         v.z = 0;
 174                         return v;
 175                 }
 176                 vector ReadInt72_t()
 177                 {
 178                         vector v;
 179                         v.x = ReadInt24_t();
 180                         v.y = ReadInt24_t();
 181                         v.z = ReadInt24_t();
 182                         return v;
 183                 }
 184
 185                 float ReadApproxPastTime()
 186                 {
 187                         float dt = ReadByte();
 188
 189                         // map from range...PPROXPASTTIME_MAX / 256
 190                         dt = (APPROXPASTTIME_MAX / 256) * (dt / (256 - dt));
 191
 192                         return servertime - dt;
 193                 }
 194
 195         #else
 196                 const int MSG_ENTITY = 5;
 197
 198                 void WriteInt24_t(float dst, float val)
 199                 {
 200                         float v;
 201                         WriteShort(dst, (v = floor(val >> 8)));
 202                         WriteByte(dst, val - (v << 8));  // 0..255
 203                 }
 204                 void WriteInt48_t(float dst, vector val)
 205                 {
 206                         WriteInt24_t(dst, val.x);
 207                         WriteInt24_t(dst, val.y);
 208                 }
 209                 void WriteInt72_t(float dst, vector val)
 210                 {
 211                         WriteInt24_t(dst, val.x);
 212                         WriteInt24_t(dst, val.y);
 213                         WriteInt24_t(dst, val.z);
 214                 }
 215
 216                 // this will use the value:
 217                 //   128
 218                 // accuracy near zero is APPROXPASTTIME_MAX/(256*255)
 219                 // accuracy at x is 1/derivative, i.e.
 220                 //   APPROXPASTTIME_MAX * (1 + 256 * (dt / APPROXPASTTIME_MAX))^2 / 65536
 221                 void WriteApproxPastTime(float dst, float t)
 222                 {
 223                         float dt = time - t;
 224
 225                         // warning: this is approximate; do not resend when you don't have to!
 226                         // be careful with sendflags here!
 227                         // we want: 0 -> 0.05, 1 -> 0.1, ..., 255 -> 12.75
 228
 229                         // map to range...
 230                         dt = 256 * (dt / ((APPROXPASTTIME_MAX / 256) + dt));
 231
 232                         // round...
 233                         dt = rint(bound(0, dt, 255));
 234
 235                         WriteByte(dst, dt);
 236                 }
 237
 238                 // allow writing to also pass through to spectators (like so spectators see the same centerprints as players for example)
 239                 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname, statement) \
 240                         entity varname; varname = msg_entity; \
 241                         FOR_EACH_REALCLIENT(msg_entity) \
 242                         if (msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) \
 243                                 statement msg_entity = varname
 244                 #define WRITESPECTATABLE_MSG_ONE(statement) \
 245                         do \
 246                         { \
 247                                 WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement); \
 248                         } \
 249                         while (0)
 250                 #define WRITESPECTATABLE(msg, statement) \
 251                         if (msg == MSG_ONE) WRITESPECTATABLE_MSG_ONE(statement); \
 252                         else \
 253                                 statement float WRITESPECTATABLE_workaround = 0
 254         #endif
 255 #endif
 256
 257 #endif