qcsrc/lib/net.qh

   1 #ifndef NET_H
   2 #define NET_H
   3
   4 #ifdef SVQC
   5         .int Version;  // deprecated, use SendFlags
   6         .int SendFlags;
   7         .bool(entity to, int sendflags) SendEntity;
   8         .bool(entity this, entity to, int sendflags) SendEntity3;
   9
  10         bool SendEntity_self(entity to, int sendflags) { return self.SendEntity3(self, to, sendflags); }
  11
  12         void Net_LinkEntity(entity e, bool docull, float dt, bool(entity this, entity to, int sendflags) sendfunc)
  13         {
  14                 if (e.classname == "") e.classname = "net_linked";
  15
  16                 if (e.model == "" || self.modelindex == 0)
  17                 {
  18                         vector mi = e.mins;
  19                         vector ma = e.maxs;
  20                         _setmodel(e, "null");
  21                         setsize(e, mi, ma);
  22                 }
  23
  24                 e.SendEntity = SendEntity_self;
  25                 e.SendEntity3 = sendfunc;
  26                 e.SendFlags = 0xFFFFFF;
  27
  28                 if (!docull) e.effects |= EF_NODEPTHTEST;
  29
  30                 if (dt)
  31                 {
  32                         e.nextthink = time + dt;
  33                         e.think = SUB_Remove;
  34                 }
  35         }
  36
  37         .void() uncustomizeentityforclient;
  38         .float uncustomizeentityforclient_set;
  39
  40         void SetCustomizer(entity e, float() customizer, void() uncustomizer)
  41         {
  42                 e.customizeentityforclient = customizer;
  43                 e.uncustomizeentityforclient = uncustomizer;
  44                 e.uncustomizeentityforclient_set = !!uncustomizer;
  45         }
  46
  47         void UncustomizeEntitiesRun()
  48         {
  49                 for (entity e = NULL; (e = findfloat(e, uncustomizeentityforclient_set, 1)); )
  50                         WITH(entity, self, e, e.uncustomizeentityforclient());
  51         }
  52
  53 #endif
  54
  55 #include "registry.qh"
  56 #include "sort.qh"
  57
  58 .string netname;
  59 .int m_id;
  60 .bool(entity this, bool isNew) m_read;
  61
  62 #ifdef CSQC
  63         #define Net_Accept(classname) \
  64                 do \
  65                 { \
  66                         if (!this)    this = new(classname); \
  67                 } \
  68                 while (0)
  69         #define Net_Reject() \
  70                 do \
  71                 { \
  72                         if (this)     remove(this); \
  73                 } \
  74                 while (0)
  75         #define NET_HANDLE(id, param) \
  76                 bool Net_Handle_##id(entity this, param)
  77 #else
  78         #define WriteHeader(to, id) \
  79                 do \
  80                 { \
  81                         if (NET_##id##_istemp) WriteByte(to, SVC_TEMPENTITY); \
  82                         WriteByte(to, NET_##id.m_id); \
  83                 } \
  84                 while (0)
  85 #endif
  86
  87 #ifdef CSQC
  88         #define REGISTER_NET_LINKED(id) \
  89                 [[accumulate]] NET_HANDLE(id, bool) \
  90                 { \
  91                         this = self; \
  92                         this.sourceLocFile = __FILE__; \
  93                         this.sourceLocLine = __LINE__; \
  94                 } \
  95                 REGISTER(RegisterLinkedEntities, NET, LinkedEntities, id, m_id, new(net_linked_packet)) \
  96                 { \
  97                         make_pure(this); \
  98                         this.netname = #id; \
  99                         this.m_read = Net_Handle_##id; \
 100                 }
 101 #else
 102         #define REGISTER_NET_LINKED(id) \
 103                 const bool NET_##id##_istemp = false; \
 104                 REGISTER(RegisterLinkedEntities, NET, LinkedEntities, id, m_id, new(net_linked_packet)) \
 105                 { \
 106                         make_pure(this); \
 107                         this.netname = #id; \
 108                 }
 109 #endif
 110
 111 REGISTRY(LinkedEntities, BITS(8) - 1)
 112 #define LinkedEntities_from(i) _LinkedEntities_from(i, NULL)
 113 REGISTER_REGISTRY(RegisterLinkedEntities)
 114 REGISTRY_SORT(LinkedEntities, 0)
 115 REGISTRY_CHECK(LinkedEntities)
 116 STATIC_INIT(RegisterLinkedEntities_renumber)
 117 {
 118         for (int i = 0; i < LinkedEntities_COUNT; ++i)
 119                 LinkedEntities_from(i).m_id = 1 + i;
 120 }
 121
 122 #ifdef CSQC
 123         #define REGISTER_NET_TEMP(id) \
 124                 NET_HANDLE(id, bool); \
 125                 REGISTER(RegisterTempEntities, NET, TempEntities, id, m_id, new(net_temp_packet)) \
 126                 { \
 127                         make_pure(this); \
 128                         this.netname = #id; \
 129                         this.m_read = Net_Handle_##id; \
 130                 }
 131 #else
 132         #define REGISTER_NET_TEMP(id) \
 133                 const bool NET_##id##_istemp = true; \
 134                 REGISTER(RegisterTempEntities, NET, TempEntities, id, m_id, new(net_temp_packet)) \
 135                 { \
 136                         make_pure(this); \
 137                         this.netname = #id; \
 138                 }
 139 #endif
 140
 141 REGISTRY(TempEntities, BITS(8) - 80)
 142 #define TempEntities_from(i) _TempEntities_from(i, NULL)
 143 REGISTER_REGISTRY(RegisterTempEntities)
 144 REGISTRY_SORT(TempEntities, 0)
 145 REGISTRY_CHECK(TempEntities)
 146 STATIC_INIT(RegisterTempEntities_renumber)
 147 {
 148         for (int i = 0; i < TempEntities_COUNT; ++i)
 149                 TempEntities_from(i).m_id = 80 + i;
 150 }
 151
 152 #ifndef MENUQC
 153         const float APPROXPASTTIME_ACCURACY_REQUIREMENT = 0.05;
 154         #define APPROXPASTTIME_MAX (16384 * APPROXPASTTIME_ACCURACY_REQUIREMENT)
 155         #define APPROXPASTTIME_RANGE (64 * APPROXPASTTIME_ACCURACY_REQUIREMENT)
 156
 157         #ifdef CSQC
 158                 entity ReadCSQCEntity()
 159                 {
 160                         int f = ReadShort();
 161                         if (f == 0) return world;
 162                         return findfloat(world, entnum, f);
 163                 }
 164                 int ReadInt24_t()
 165                 {
 166                         int v = ReadShort() << 8; // note: this is signed
 167                         v += ReadByte();          // note: this is unsigned
 168                         return v;
 169                 }
 170                 vector ReadInt48_t()
 171                 {
 172                         vector v;
 173                         v.x = ReadInt24_t();
 174                         v.y = ReadInt24_t();
 175                         v.z = 0;
 176                         return v;
 177                 }
 178                 vector ReadInt72_t()
 179                 {
 180                         vector v;
 181                         v.x = ReadInt24_t();
 182                         v.y = ReadInt24_t();
 183                         v.z = ReadInt24_t();
 184                         return v;
 185                 }
 186
 187                 float ReadApproxPastTime()
 188                 {
 189                         float dt = ReadByte();
 190
 191                         // map from range...PPROXPASTTIME_MAX / 256
 192                         dt = (APPROXPASTTIME_MAX / 256) * (dt / (256 - dt));
 193
 194                         return servertime - dt;
 195                 }
 196
 197         #else
 198                 const int MSG_ENTITY = 5;
 199
 200                 void WriteInt24_t(float dst, float val)
 201                 {
 202                         float v;
 203                         WriteShort(dst, (v = floor(val >> 8)));
 204                         WriteByte(dst, val - (v << 8));  // 0..255
 205                 }
 206                 void WriteInt48_t(float dst, vector val)
 207                 {
 208                         WriteInt24_t(dst, val.x);
 209                         WriteInt24_t(dst, val.y);
 210                 }
 211                 void WriteInt72_t(float dst, vector val)
 212                 {
 213                         WriteInt24_t(dst, val.x);
 214                         WriteInt24_t(dst, val.y);
 215                         WriteInt24_t(dst, val.z);
 216                 }
 217
 218                 // this will use the value:
 219                 //   128
 220                 // accuracy near zero is APPROXPASTTIME_MAX/(256*255)
 221                 // accuracy at x is 1/derivative, i.e.
 222                 //   APPROXPASTTIME_MAX * (1 + 256 * (dt / APPROXPASTTIME_MAX))^2 / 65536
 223                 void WriteApproxPastTime(float dst, float t)
 224                 {
 225                         float dt = time - t;
 226
 227                         // warning: this is approximate; do not resend when you don't have to!
 228                         // be careful with sendflags here!
 229                         // we want: 0 -> 0.05, 1 -> 0.1, ..., 255 -> 12.75
 230
 231                         // map to range...
 232                         dt = 256 * (dt / ((APPROXPASTTIME_MAX / 256) + dt));
 233
 234                         // round...
 235                         dt = rint(bound(0, dt, 255));
 236
 237                         WriteByte(dst, dt);
 238                 }
 239
 240                 // allow writing to also pass through to spectators (like so spectators see the same centerprints as players for example)
 241                 #define WRITESPECTATABLE_MSG_ONE_VARNAME(varname, statement) \
 242                         entity varname; varname = msg_entity; \
 243                         FOR_EACH_REALCLIENT(msg_entity) \
 244                         if (msg_entity == varname || (msg_entity.classname == STR_SPECTATOR && msg_entity.enemy == varname)) \
 245                                 statement msg_entity = varname
 246                 #define WRITESPECTATABLE_MSG_ONE(statement) \
 247                         do \
 248                         { \
 249                                 WRITESPECTATABLE_MSG_ONE_VARNAME(oldmsg_entity, statement); \
 250                         } \
 251                         while (0)
 252                 #define WRITESPECTATABLE(msg, statement) \
 253                         if (msg == MSG_ONE) WRITESPECTATABLE_MSG_ONE(statement); \
 254                         else \
 255                                 statement float WRITESPECTATABLE_workaround = 0
 256         #endif
 257 #endif
 258
 259 #endif