qcsrc/lib/registry.qh

   1 #ifndef REGISTRY_H
   2 #define REGISTRY_H
   3
   4 #include "oo.qh"
   5
   6 #if 1
   7         #define _R_MAP(r, max) AL_declare(r); STATIC_INIT(r) { AL_init(r, max, NULL, e); }
   8         #define _R_GET(r, i) AL_gete(r, i)
   9         #define _R_SET(r, i, e) AL_sete(r, i, e)
  10         #define _R_DEL(r) AL_delete(r)
  11 #else
  12         #define _R_MAP(r, max) entity r[max]
  13         #define _R_GET(r, i) r[i]
  14         #define _R_SET(r, i, e) r[i] = e
  15         #define _R_DEL(r)
  16 #endif
  17
  18 /**
  19  * Declare a new registry.
  20  *
  21  * Don't forget to call `REGISTER_REGISTRY`:
  22  *     REGISTER_REGISTRY(Foos)
  23  */
  24 #define REGISTRY(id, max) \
  25         void Register##id() {} \
  26         const int id##_MAX = max; \
  27         noref entity id##_first, id##_last; \
  28         _R_MAP(_##id, id##_MAX); \
  29         SHUTDOWN(id) { _R_DEL(_##id); } \
  30         int id##_COUNT; \
  31         entity _##id##_from(int i, entity null) { if (i >= 0 && i < id##_COUNT) { entity e = _R_GET(_##id, i); if (e) return e; } return null; }
  32
  33 REGISTRY(Registries, BITS(8))
  34
  35 /** registered item identifier */
  36 .string registered_id;
  37
  38 /**
  39  * Register a new entity with a registry.
  40  * Must be followed by a semicolon or a function body with a `this` parameter.
  41  * Wrapper macros may perform actions after user initialization like so:
  42  *     #define REGISTER_FOO(id) \
  43  *         REGISTER(Foos, FOO, id, m_id, NEW(Foo)); \
  44  *         REGISTER_INIT_POST(FOO, id) { \
  45  *             print("Registering foo #", this.m_id + 1, "\n"); \
  46  *         } \
  47  *         REGISTER_INIT(FOO, id)
  48  *
  49  *
  50  * @param registry  The registry to add each entity to.
  51  * @param ns        Short for namespace, prefix for each global (ns##_##id)
  52  * @param id        The identifier of the current entity being registered
  53  * @param fld       The field to store the locally unique unique entity id
  54  * @param inst      An expression to create a new instance, invoked for every registration
  55  */
  56 #define REGISTER(...) EVAL(OVERLOAD(REGISTER, __VA_ARGS__))
  57 #define REGISTER_5(registry, ns, id, fld, inst) REGISTER_4(registry, ns##_##id, fld, inst)
  58 #define REGISTER_4(registry, id, fld, inst) \
  59         entity id; \
  60         REGISTER_INIT(id) {} \
  61         REGISTER_INIT_POST(id) {} \
  62         void Register_##id() \
  63         { \
  64                 if (registry##_COUNT >= registry##_MAX) LOG_FATALF("Registry capacity exceeded (%s)", ftos(registry##_MAX)); \
  65                 entity this = id = inst; \
  66                 this.registered_id = #id; \
  67                 this.fld = registry##_COUNT; \
  68                 _R_SET(_##registry, registry##_COUNT, this); \
  69                 ++registry##_COUNT; \
  70                 if (!registry##_first) registry##_first = this; \
  71                 if (registry##_last)   registry##_last.REGISTRY_NEXT = this; \
  72                 registry##_last = this; \
  73                 Register_##id##_init(this); \
  74                 Register_##id##_init_post(this); \
  75         } \
  76         ACCUMULATE_FUNCTION(Register##registry, Register_##id) \
  77         REGISTER_INIT(id)
  78
  79 #define REGISTER_INIT(id) [[accumulate]] void Register_##id##_init(entity this)
  80 #define REGISTER_INIT_POST(id) [[accumulate]] void Register_##id##_init_post(entity this)
  81
  82 /** internal next pointer */
  83 #define REGISTRY_NEXT enemy
  84 .entity REGISTRY_NEXT;
  85
  86 #define REGISTRY_SORT(...) EVAL(OVERLOAD(REGISTRY_SORT, __VA_ARGS__))
  87 #define REGISTRY_SORT_1(id) REGISTRY_SORT_2(id, 0)
  88 #define REGISTRY_SORT_2(id, skip) \
  89         void _REGISTRY_SWAP_##id(int i, int j, entity pass) \
  90         { \
  91                 i += skip; j += skip; \
  92                 \
  93                 entity a = _R_GET(_##id, i), b = _R_GET(_##id, j); \
  94                 _R_SET(_##id, i, b); \
  95                 _R_SET(_##id, j, a); \
  96         \
  97                 entity a_next = a.REGISTRY_NEXT, b_next = b.REGISTRY_NEXT; \
  98                 a.REGISTRY_NEXT = b_next; \
  99                 b.REGISTRY_NEXT = a_next; \
 100         \
 101                 if (i == 0) id##_first = b; \
 102                 else _R_GET(_##id, i - 1).REGISTRY_NEXT = b; \
 103         \
 104                 if (j == 0) id##_first = a; \
 105                 else _R_GET(_##id, j - 1).REGISTRY_NEXT = a; \
 106         } \
 107         int _REGISTRY_CMP_##id(int i, int j, entity pass) \
 108         { \
 109                 i += skip; j += skip; \
 110                 string a = _R_GET(_##id, i).registered_id; \
 111                 string b = _R_GET(_##id, j).registered_id; \
 112                 return strcmp(a, b); \
 113         } \
 114         STATIC_INIT(Registry_sort_##id) \
 115         { \
 116                 heapsort(id##_COUNT - (skip), _REGISTRY_SWAP_##id, _REGISTRY_CMP_##id, NULL); \
 117         }
 118
 119 #define REGISTRY_HASH(id) Registry_hash_##id
 120
 121 [[accumulate]] void Registry_check(string r, string server) { }
 122 [[accumulate]] void Registry_send_all() { }
 123
 124 #ifdef SVQC
 125 void Registry_send(string id, string hash);
 126 #else
 127 #define Registry_send(id, hash)
 128 #endif
 129
 130 #define REGISTRY_CHECK(id) \
 131         string REGISTRY_HASH(id); \
 132         STATIC_INIT(Registry_check_##id) \
 133         { \
 134                 string algo = "SHA256"; \
 135                 string join = ":"; \
 136                 string s = ""; \
 137                 FOREACH(id, true, LAMBDA(s = strcat(s, join, it.registered_id))); \
 138                 s = substring(s, strlen(join), -1); \
 139                 string h = REGISTRY_HASH(id) = strzone(digest_hex(algo, s)); \
 140                 LOG_TRACEF(#id ": %s\n[%s]\n", h, s); \
 141         } \
 142         void Registry_check(string r, string sv) \
 143         { \
 144                 if (r == #id) \
 145                 { \
 146                         string cl = REGISTRY_HASH(id); \
 147                         if (cl != sv) \
 148                         { \
 149                                 LOG_FATALF("client/server mismatch (%s).\nCL: %s\nSV: %s\n", r, cl, sv); \
 150                         } \
 151                 } \
 152         } \
 153         void Registry_send_all() { Registry_send(#id, REGISTRY_HASH(id)); } \
 154
 155 #define REGISTER_REGISTRY(...) EVAL(OVERLOAD(REGISTER_REGISTRY, __VA_ARGS__))
 156 #define REGISTER_REGISTRY_1(id) REGISTER_REGISTRY_2(id, #id)
 157 #define REGISTER_REGISTRY_2(id, str) \
 158         ACCUMULATE_FUNCTION(__static_init, Register##id) \
 159         CLASS(id##Registry, Object) \
 160                 ATTRIB(id##Registry, m_name, string, str) \
 161                 ATTRIB(id##Registry, REGISTRY_NEXT, entity, id##_first) \
 162         ENDCLASS(id##Registry) \
 163         REGISTER(Registries, REGISTRY, id, m_id, NEW(id##Registry));
 164
 165
 166 #endif