qcsrc/lib/vector.qh

   1 #ifndef VECTOR_H
   2 #define VECTOR_H
   3
   4 noref vector _vlen2;
   5 #define vlen2(v) (_vlen2 = (v), dotproduct(_vlen2, _vlen2))
   6
   7 #if 1
   8 noref float _vdist_f;
   9 /** Vector distance comparison, avoids sqrt() */
  10 #define vdist(v, cmp, f) (vlen2(v) cmp (_vdist_f = (f), _vdist_f * _vdist_f))
  11 #else
  12 #define vdist(v, cmp, f) (vlen(v) cmp (f))
  13 #endif
  14
  15 #if 1
  16 #define dotproduct(a, b) ((a) * (b))
  17 #else
  18 noref vector _dotproduct_a, _dotproduct_b;
  19 #define dotproduct(a, b) \
  20         (_dotproduct_a = (a), _dotproduct_b = (b), \
  21           _dotproduct_a.x * _dotproduct_b.x \
  22         + _dotproduct_a.y * _dotproduct_b.y \
  23         + _dotproduct_a.z * _dotproduct_b.z)
  24 #endif
  25
  26 #if 1
  27 #define cross(a, b) ((a) >< (b))
  28 #else
  29 vector cross(vector a, vector b)
  30 {
  31         return
  32                 '1 0 0' * (a.y * b.z - a.z * b.y)
  33         +       '0 1 0' * (a.z * b.x - a.x * b.z)
  34         +       '0 0 1' * (a.x * b.y - a.y * b.x);
  35 }
  36 #endif
  37
  38 const vector eX = '1 0 0';
  39 const vector eY = '0 1 0';
  40 const vector eZ = '0 0 1';
  41
  42 vector randompos(vector m1, vector m2)
  43 {
  44         vector v;
  45         m2 = m2 - m1;
  46         v_x = m2_x * random() + m1_x;
  47         v_y = m2_y * random() + m1_y;
  48         v_z = m2_z * random() + m1_z;
  49         return v;
  50 }
  51
  52 float vlen_maxnorm2d(vector v)
  53 {
  54         return max(v.x, v.y, -v.x, -v.y);
  55 }
  56
  57 float vlen_minnorm2d(vector v)
  58 {
  59         return min(max(v.x, -v.x), max(v.y, -v.y));
  60 }
  61
  62 float dist_point_line(vector p, vector l0, vector ldir)
  63 {
  64         ldir = normalize(ldir);
  65
  66         // remove the component in line direction
  67         p = p - (p * ldir) * ldir;
  68
  69         // vlen of the remaining vector
  70         return vlen(p);
  71 }
  72
  73 /** requires that m2>m1 in all coordinates, and that m4>m3 */
  74 float boxesoverlap(vector m1, vector m2, vector m3, vector m4) { return m2_x >= m3_x && m1_x <= m4_x && m2_y >= m3_y && m1_y <= m4_y && m2_z >= m3_z && m1_z <= m4_z; }
  75
  76 /** requires the same as boxesoverlap, but is a stronger condition */
  77 float boxinsidebox(vector smins, vector smaxs, vector bmins, vector bmaxs) { return smins.x >= bmins.x && smaxs.x <= bmaxs.x && smins.y >= bmins.y && smaxs.y <= bmaxs.y && smins.z >= bmins.z && smaxs.z <= bmaxs.z; }
  78
  79 #define PITCH(v) ((v).x)
  80 #define YAW(v) ((v).y)
  81 #define ROLL(v) ((v).z)
  82
  83 #define MAKEVECTORS(f, angles, forward, right, up) MACRO_BEGIN { \
  84         f(angles); \
  85         forward = v_forward; \
  86         right = v_right; \
  87         up = v_up; \
  88 } MACRO_END
  89
  90 noref vector _vec2;
  91 #define vec2(v) (_vec2 = (v), _vec2.z = 0, _vec2)
  92
  93 noref vector _vec3;
  94 #define vec3(x, y, z) (_vec3_x = (x), _vec3_y = (y), _vec3_z = (z), _vec3)
  95
  96 vector rotate(vector v, float a)
  97 {
  98         float a_sin = sin(a), a_cos = cos(a);
  99         vector r = '0 0 0';
 100         r.x =      v.x * a_cos + v.y * a_sin;
 101         r.y = -1 * v.x * a_sin + v.y * a_cos;
 102         return r;
 103 }
 104
 105 noref vector _yinvert;
 106 #define yinvert(v) (_yinvert = (v), _yinvert.y = 1 - _yinvert.y, _yinvert)
 107
 108 #ifndef MENUQC
 109         vector get_corner_position(entity box, int corner)
 110         {
 111                 switch (corner)
 112                 {
 113                         case 1: return vec3(box.absmin.x, box.absmin.y, box.absmin.z);
 114                         case 2: return vec3(box.absmax.x, box.absmin.y, box.absmin.z);
 115                         case 3: return vec3(box.absmin.x, box.absmax.y, box.absmin.z);
 116                         case 4: return vec3(box.absmin.x, box.absmin.y, box.absmax.z);
 117                         case 5: return vec3(box.absmax.x, box.absmax.y, box.absmin.z);
 118                         case 6: return vec3(box.absmin.x, box.absmax.y, box.absmax.z);
 119                         case 7: return vec3(box.absmax.x, box.absmin.y, box.absmax.z);
 120                         case 8: return vec3(box.absmax.x, box.absmax.y, box.absmax.z);
 121                         default: return '0 0 0';
 122                 }
 123         }
 124
 125         vector NearestPointOnBox(entity box, vector org)
 126         {
 127                 vector m1 = box.mins + box.origin;
 128                 vector m2 = box.maxs + box.origin;
 129
 130                 vector ret;
 131                 ret.x = bound(m1.x, org.x, m2.x);
 132                 ret.y = bound(m1.y, org.y, m2.y);
 133                 ret.z = bound(m1.z, org.z, m2.z);
 134                 return ret;
 135         }
 136 #endif
 137
 138 #endif