qcsrc/menu/item/slider.qc

   1 // Note:
   2 //   to use this, you FIRST call configureSliderVisuals, then configureSliderValues
   3 #ifndef ITEM_SLIDER_H
   4 #define ITEM_SLIDER_H
   5 #include "label.qc"
   6 CLASS(Slider, Label)
   7         METHOD(Slider, resizeNotify, void(entity, vector, vector, vector, vector));
   8         METHOD(Slider, configureSliderVisuals, void(entity, float, float, float, string));
   9         METHOD(Slider, configureSliderValues, void(entity, float, float, float, float, float, float));
  10         METHOD(Slider, draw, void(entity));
  11         METHOD(Slider, keyDown, float(entity, float, float, float));
  12         METHOD(Slider, keyUp, float(entity, float, float, float));
  13         METHOD(Slider, mousePress, float(entity, vector));
  14         METHOD(Slider, mouseDrag, float(entity, vector));
  15         METHOD(Slider, mouseRelease, float(entity, vector));
  16         METHOD(Slider, valueToText, string(entity, float));
  17         METHOD(Slider, toString, string(entity));
  18         METHOD(Slider, setValue_allowAnim, void(entity, float, bool));
  19         METHOD(Slider, setValue_noAnim, void(entity, float));
  20         METHOD(Slider, setValue, void(entity, float));
  21         METHOD(Slider, setSliderValue, void(entity, float));
  22         METHOD(Slider, showNotify, void(entity));
  23         ATTRIB(Slider, src, string, string_null)
  24         ATTRIB(Slider, focusable, float, 1)
  25         ATTRIB(Slider, allowFocusSound, float, 1)
  26         ATTRIB(Slider, value, float, 0)
  27         ATTRIB(Slider, animated, float, 1)
  28         ATTRIB(Slider, sliderValue, float, 0)
  29         ATTRIB(Slider, sliderAnim, entity, world)
  30         ATTRIB(Slider, valueMin, float, 0)
  31         ATTRIB(Slider, valueMax, float, 0)
  32         ATTRIB(Slider, valueStep, float, 0)
  33         ATTRIB(Slider, valueDigits, float, 0)
  34         ATTRIB(Slider, valueKeyStep, float, 0)
  35         ATTRIB(Slider, valuePageStep, float, 0)
  36         ATTRIB(Slider, valueDisplayMultiplier, float, 1.0)
  37         ATTRIB(Slider, textSpace, float, 0)
  38         ATTRIB(Slider, controlWidth, float, 0)
  39         ATTRIB(Slider, pressed, float, 0)
  40         ATTRIB(Slider, pressOffset, float, 0)
  41         ATTRIB(Slider, previousValue, float, 0)
  42         ATTRIB(Slider, tolerance, vector, '0 0 0')
  43         ATTRIB(Slider, disabled, float, 0)
  44         ATTRIB(Slider, color, vector, '1 1 1')
  45         ATTRIB(Slider, color2, vector, '1 1 1')
  46         ATTRIB(Slider, colorD, vector, '1 1 1')
  47         ATTRIB(Slider, colorC, vector, '1 1 1')
  48         ATTRIB(Slider, colorF, vector, '1 1 1')
  49         ATTRIB(Slider, disabledAlpha, float, 0.3)
  50 ENDCLASS(Slider)
  51 #endif
  52
  53 #ifdef IMPLEMENTATION
  54 void Slider_setValue_allowAnim(entity me, float val, bool allowAnim)
  55 {
  56         if(allowAnim && me.animated) {
  57                 float t = 0.5;
  58                 if(!me.sliderAnim)
  59                         me.sliderAnim = makeHostedEasing(me, Slider_setSliderValue, easingQuadOut, t, me.sliderValue, val);
  60                 else
  61                         me.sliderAnim.update(me.sliderAnim, t, me.sliderValue, val);
  62         } else {
  63                 me.setSliderValue(me, val);
  64         }
  65         me.value = val;
  66 }
  67 void Slider_setValue_noAnim(entity me, float val)
  68 {
  69         Slider_setValue_allowAnim(me, val, false);
  70 }
  71 void Slider_setValue(entity me, float val)
  72 {
  73         Slider_setValue_allowAnim(me, val, true);
  74 }
  75 void Slider_setSliderValue(entity me, float val)
  76 {
  77         me.sliderValue = val;
  78 }
  79 string Slider_toString(entity me)
  80 {
  81         return sprintf("%d (%s)", me.value, me.valueToText(me, me.value));
  82 }
  83 void Slider_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  84 {
  85         SUPER(Slider).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
  86         me.controlWidth = absSize.x == 0 ? 0 : (absSize.y / absSize.x);
  87 }
  88 string Slider_valueToText(entity me, float val)
  89 {
  90         if(almost_in_bounds(me.valueMin, val, me.valueMax))
  91                 return ftos_decimals(val * me.valueDisplayMultiplier, me.valueDigits);
  92         return "";
  93 }
  94 void Slider_configureSliderVisuals(entity me, float sz, float theAlign, float theTextSpace, string gfx)
  95 {
  96         SUPER(Slider).configureLabel(me, string_null, sz, theAlign);
  97         me.textSpace = theTextSpace;
  98         me.keepspaceLeft = (theTextSpace == 0) ? 0 : (1 - theTextSpace);
  99         me.src = gfx;
 100 }
 101 void Slider_configureSliderValues(entity me, float theValueMin, float theValue, float theValueMax, float theValueStep, float theValueKeyStep, float theValuePageStep)
 102 {
 103         me.value = theValue;
 104         me.sliderValue = theValue;
 105         me.valueStep = theValueStep;
 106         me.valueMin = theValueMin;
 107         me.valueMax = theValueMax;
 108         me.valueKeyStep = theValueKeyStep;
 109         me.valuePageStep = theValuePageStep;
 110         me.valueDigits = 3;
 111         if(fabs(floor(me.valueStep * 100 + 0.5) - (me.valueStep * 100)) < 0.01) // about a whole number of 100ths
 112                 me.valueDigits = 2;
 113         if(fabs(floor(me.valueStep * 10 + 0.5) - (me.valueStep * 10)) < 0.01) // about a whole number of 10ths
 114                 me.valueDigits = 1;
 115         if(fabs(floor(me.valueStep * 1 + 0.5) - (me.valueStep * 1)) < 0.01) // about a whole number
 116                 me.valueDigits = 0;
 117 }
 118 float Slider_keyDown(entity me, float key, float ascii, float shift)
 119 {
 120         float inRange;
 121         if(me.disabled)
 122                 return 0;
 123         inRange = (almost_in_bounds(me.valueMin, me.value, me.valueMax));
 124         if(key == K_LEFTARROW || key == K_KP_LEFTARROW || key == K_MWHEELDOWN)
 125         {
 126                 if(inRange)
 127                         me.setValue(me, median(me.valueMin, me.value - me.valueKeyStep, me.valueMax));
 128                 else
 129                         me.setValue(me, me.valueMax);
 130                 return 1;
 131         }
 132         if(key == K_RIGHTARROW || key == K_KP_RIGHTARROW || key == K_MWHEELUP)
 133         {
 134                 if(inRange)
 135                         me.setValue(me, median(me.valueMin, me.value + me.valueKeyStep, me.valueMax));
 136                 else
 137                         me.setValue(me, me.valueMin);
 138                 return 1;
 139         }
 140         if(key == K_PGDN || key == K_KP_PGDN)
 141         {
 142                 if(inRange)
 143                         me.setValue(me, median(me.valueMin, me.value - me.valuePageStep, me.valueMax));
 144                 else
 145                         me.setValue(me, me.valueMax);
 146                 return 1;
 147         }
 148         if(key == K_PGUP || key == K_KP_PGUP)
 149         {
 150                 if(inRange)
 151                         me.setValue(me, median(me.valueMin, me.value + me.valuePageStep, me.valueMax));
 152                 else
 153                         me.setValue(me, me.valueMin);
 154                 return 1;
 155         }
 156         if(key == K_HOME || key == K_KP_HOME)
 157         {
 158                 me.setValue(me, me.valueMin);
 159                 return 1;
 160         }
 161         if(key == K_END || key == K_KP_END)
 162         {
 163                 me.setValue(me, me.valueMax);
 164                 return 1;
 165         }
 166         // TODO more keys (NOTE also add them to Slider_keyUp)
 167         return 0;
 168 }
 169 float Slider_keyUp(entity me, float key, float ascii, float shift)
 170 {
 171         if(me.disabled)
 172                 return 0;
 173         switch(key)
 174         {
 175                 case K_LEFTARROW:
 176                 case K_KP_LEFTARROW:
 177                 case K_RIGHTARROW:
 178                 case K_KP_RIGHTARROW:
 179                 case K_PGUP:
 180                 case K_KP_PGUP:
 181                 case K_PGDN:
 182                 case K_KP_PGDN:
 183                 case K_HOME:
 184                 case K_KP_HOME:
 185                 case K_END:
 186                 case K_KP_END:
 187                         m_play_click_sound(MENU_SOUND_SLIDE);
 188         }
 189         return 0;
 190 }
 191 float Slider_mouseDrag(entity me, vector pos)
 192 {
 193         float hit;
 194         float v;
 195         if(me.disabled)
 196                 return 0;
 197
 198         if(me.pressed)
 199         {
 200                 hit = 1;
 201                 if(pos.x < 0 - me.tolerance.x) hit = 0;
 202                 if(pos.y < 0 - me.tolerance.y) hit = 0;
 203                 if(pos.x >= 1 - me.textSpace + me.tolerance.x) hit = 0;
 204                 if(pos.y >= 1 + me.tolerance.y) hit = 0;
 205                 if(hit)
 206                 {
 207                         // handle dragging
 208                         me.pressed = 2;
 209
 210                         v = median(0, (pos.x - me.pressOffset - 0.5 * me.controlWidth) / (1 - me.textSpace - me.controlWidth), 1) * (me.valueMax - me.valueMin) + me.valueMin;
 211                         if(me.valueStep)
 212                                 v = floor(0.5 + v / me.valueStep) * me.valueStep;
 213                         me.setValue_noAnim(me, v);
 214                 }
 215                 else
 216                         me.setValue(me, me.previousValue);
 217         }
 218
 219         return 1;
 220 }
 221 float Slider_mousePress(entity me, vector pos)
 222 {
 223         float controlCenter;
 224         if(me.disabled)
 225                 return 0;
 226         if(pos.x < 0) return 0;
 227         if(pos.y < 0) return 0;
 228         if(pos.x >= 1 - me.textSpace) return 0;
 229         if(pos.y >= 1) return 0;
 230         controlCenter = (me.value - me.valueMin) / (me.valueMax - me.valueMin) * (1 - me.textSpace - me.controlWidth) + 0.5 * me.controlWidth;
 231         if(fabs(pos.x - controlCenter) <= 0.5 * me.controlWidth)
 232         {
 233                 me.pressed = 1;
 234                 me.pressOffset = pos.x - controlCenter;
 235                 me.previousValue = me.value;
 236                 //me.mouseDrag(me, pos);
 237         }
 238         else
 239         {
 240                 float clickValue, pageValue, inRange;
 241                 clickValue = median(0, (pos.x - me.pressOffset - 0.5 * me.controlWidth) / (1 - me.textSpace - me.controlWidth), 1) * (me.valueMax - me.valueMin) + me.valueMin;
 242                 inRange = (almost_in_bounds(me.valueMin, me.value, me.valueMax));
 243                 if(pos.x < controlCenter)
 244                 {
 245                         pageValue = me.value - me.valuePageStep;
 246                         if(me.valueStep)
 247                                 clickValue = floor(clickValue / me.valueStep) * me.valueStep;
 248                         pageValue = max(pageValue, clickValue);
 249                         if(inRange)
 250                                 me.setValue(me, median(me.valueMin, pageValue, me.valueMax));
 251                         else
 252                                 me.setValue(me, me.valueMax);
 253                 }
 254                 else
 255                 {
 256                         pageValue = me.value + me.valuePageStep;
 257                         if(me.valueStep)
 258                                 clickValue = ceil(clickValue / me.valueStep) * me.valueStep;
 259                         pageValue = min(pageValue, clickValue);
 260                         if(inRange)
 261                                 me.setValue(me, median(me.valueMin, pageValue, me.valueMax));
 262                         else
 263                                 me.setValue(me, me.valueMax);
 264                 }
 265                 if(pageValue == clickValue)
 266                 {
 267                         controlCenter = (me.value - me.valueMin) / (me.valueMax - me.valueMin) * (1 - me.textSpace - me.controlWidth) + 0.5 * me.controlWidth;
 268                         me.pressed = 1;
 269                         me.pressOffset = pos.x - controlCenter;
 270                         me.previousValue = me.value;
 271                         //me.mouseDrag(me, pos);
 272                 }
 273         }
 274         return 1;
 275 }
 276 float Slider_mouseRelease(entity me, vector pos)
 277 {
 278         me.pressed = 0;
 279         if(me.disabled)
 280                 return 0;
 281         m_play_click_sound(MENU_SOUND_SLIDE);
 282         return 1;
 283 }
 284 void Slider_showNotify(entity me)
 285 {
 286         me.focusable = !me.disabled;
 287 }
 288 void Slider_draw(entity me)
 289 {
 290         float controlLeft;
 291         float save;
 292         me.focusable = !me.disabled;
 293         save = draw_alpha;
 294         if(me.disabled)
 295                 draw_alpha *= me.disabledAlpha;
 296         draw_ButtonPicture('0 0 0', strcat(me.src, "_s"), eX * (1 - me.textSpace) + eY, me.color2, 1);
 297         if(almost_in_bounds(me.valueMin, me.sliderValue, me.valueMax))
 298         {
 299                 controlLeft = (me.sliderValue - me.valueMin) / (me.valueMax - me.valueMin) * (1 - me.textSpace - me.controlWidth);
 300                 if(me.disabled)
 301                         draw_Picture(eX * controlLeft, strcat(me.src, "_d"), eX * me.controlWidth + eY, me.colorD, 1);
 302                 else if(me.pressed)
 303                         draw_Picture(eX * controlLeft, strcat(me.src, "_c"), eX * me.controlWidth + eY, me.colorC, 1);
 304                 else if(me.focused)
 305                         draw_Picture(eX * controlLeft, strcat(me.src, "_f"), eX * me.controlWidth + eY, me.colorF, 1);
 306                 else
 307                         draw_Picture(eX * controlLeft, strcat(me.src, "_n"), eX * me.controlWidth + eY, me.color, 1);
 308         }
 309
 310         if(me.sliderAnim)
 311         if(me.sliderAnim.isFinished(me.sliderAnim))
 312         {
 313                 anim.removeObjAnim(anim, me);
 314                 me.sliderAnim = world;
 315         }
 316
 317         me.setText(me, me.valueToText(me, me.value));
 318         draw_alpha = save;
 319         SUPER(Slider).draw(me);
 320         me.text = string_null; // TEMPSTRING!
 321 }
 322 #endif