qcsrc/menu/xonotic/campaign.qc

   1 #include "campaign.qh"
   2 #include <common/campaign_common.qh>
   3
   4 #ifndef CAMPAIGN_H
   5 #define CAMPAIGN_H
   6 #include "listbox.qc"
   7 CLASS(XonoticCampaignList, XonoticListBox)
   8         METHOD(XonoticCampaignList, configureXonoticCampaignList, void(entity));
   9         ATTRIB(XonoticCampaignList, rowsPerItem, float, 10)
  10         METHOD(XonoticCampaignList, draw, void(entity));
  11         METHOD(XonoticCampaignList, drawListBoxItem, void(entity, int, vector, bool, bool));
  12         METHOD(XonoticCampaignList, doubleClickListBoxItem, void(entity, float, vector));
  13         METHOD(XonoticCampaignList, resizeNotify, void(entity, vector, vector, vector, vector));
  14         METHOD(XonoticCampaignList, setSelected, void(entity, float));
  15         METHOD(XonoticCampaignList, keyDown, float(entity, float, float, float));
  16         METHOD(XonoticCampaignList, campaignGo, void(entity, float));
  17         METHOD(XonoticCampaignList, destroy, void(entity));
  18
  19         ATTRIB(XonoticCampaignList, campaignGlob, float, 0)
  20         ATTRIB(XonoticCampaignList, realFontSize, vector, '0 0 0')
  21         ATTRIB(XonoticCampaignList, columnPreviewOrigin, float, 0)
  22         ATTRIB(XonoticCampaignList, columnPreviewSize, float, 0)
  23         ATTRIB(XonoticCampaignList, columnNameOrigin, float, 0)
  24         ATTRIB(XonoticCampaignList, columnNameSize, float, 0)
  25         ATTRIB(XonoticCampaignList, columnCheckMarkOrigin, float, 0)
  26         ATTRIB(XonoticCampaignList, columnCheckMarkSize, float, 0)
  27         ATTRIB(XonoticCampaignList, checkMarkOrigin, vector, '0 0 0')
  28         ATTRIB(XonoticCampaignList, checkMarkSize, vector, '0 0 0')
  29         ATTRIB(XonoticCampaignList, realUpperMargin1, float, 0)
  30         ATTRIB(XonoticCampaignList, realUpperMargin2, float, 0)
  31
  32         ATTRIB(XonoticCampaignList, origin, vector, '0 0 0')
  33         ATTRIB(XonoticCampaignList, itemAbsSize, vector, '0 0 0')
  34         ATTRIB(XonoticCampaignList, emptyLineHeight, float, 0.5)
  35
  36         ATTRIB(XonoticCampaignList, campaignIndex, float, 0)
  37         ATTRIB(XonoticCampaignList, cvarName, string, string_null)
  38         METHOD(XonoticCampaignList, loadCvars, void(entity));
  39         METHOD(XonoticCampaignList, saveCvars, void(entity));
  40
  41         ATTRIB(XonoticCampaignList, buttonNext, entity, NULL)
  42         ATTRIB(XonoticCampaignList, buttonPrev, entity, NULL)
  43         ATTRIB(XonoticCampaignList, labelTitle, entity, NULL)
  44 ENDCLASS(XonoticCampaignList)
  45 entity makeXonoticCampaignList();
  46 void CampaignList_LoadMap(entity btn, entity me);
  47 void MultiCampaign_Next(entity btn, entity me);
  48 void MultiCampaign_Prev(entity btn, entity me);
  49 #endif
  50
  51 #ifdef IMPLEMENTATION
  52 string campaign_longdesc_wrapped[CAMPAIGN_MAX_ENTRIES];
  53
  54 void rewrapCampaign(float w, float l0, float emptyheight, vector theFontSize)
  55 {
  56         int i, j;
  57         int n;
  58         float l;
  59         string r, s;
  60         for(i = 0; i < campaign_entries; ++i)
  61         {
  62                 l = l0;
  63                 if(campaign_longdesc_wrapped[i])
  64                         strunzone(campaign_longdesc_wrapped[i]);
  65                 n = tokenizebyseparator(campaign_longdesc[i], "\n");
  66                 r = "";
  67                 for(j = 0; j < n; ++j)
  68                 {
  69                         s = argv(j);
  70                         if(s == "")
  71                         {
  72                                 l -= emptyheight;
  73                                 r = strcat(r, "\n");
  74                                 continue;
  75                         }
  76
  77                         getWrappedLine_remaining = s;
  78                         while(getWrappedLine_remaining)
  79                         {
  80                                 s = getWrappedLine(w, theFontSize, draw_TextWidth_WithoutColors);
  81                                 if(--l < 0) goto toolong;
  82                                 r = strcat(r, s, "\n");
  83                         }
  84                 }
  85                 goto nottoolong;
  86 :toolong
  87                 while(substring(r, strlen(r) - 1, 1) == "\n")
  88                         r = substring(r, 0, strlen(r) - 1);
  89                 r = strcat(r, "...\n");
  90 :nottoolong
  91                 campaign_longdesc_wrapped[i] = strzone(substring(r, 0, strlen(r) - 1));
  92         }
  93 }
  94
  95 entity makeXonoticCampaignList()
  96 {
  97         entity me;
  98         me = NEW(XonoticCampaignList);
  99         me.configureXonoticCampaignList(me);
 100         return me;
 101 }
 102 void XonoticCampaignList_configureXonoticCampaignList(entity me)
 103 {
 104         me.configureXonoticListBox(me);
 105         me.campaignGlob = search_begin("maps/campaign*.txt", true, true);
 106         me.loadCvars(me);
 107         me.campaignGo(me, 0); // takes care of enabling/disabling buttons too
 108 }
 109
 110 void XonoticCampaignList_destroy(entity me)
 111 {
 112         if(me.campaignGlob >= 0)
 113                 search_end(me.campaignGlob);
 114 }
 115
 116 void XonoticCampaignList_loadCvars(entity me)
 117 {
 118         // read campaign cvars
 119         if(campaign_name)
 120                 strunzone(campaign_name);
 121         if(me.cvarName)
 122                 strunzone(me.cvarName);
 123         campaign_name = strzone(cvar_string("g_campaign_name"));
 124         me.cvarName = strzone(strcat("g_campaign", campaign_name, "_index"));
 125         registercvar(me.cvarName, "", 0); // saved by server QC anyway
 126         CampaignFile_Unload();
 127         CampaignFile_Load(0, CAMPAIGN_MAX_ENTRIES);
 128         me.campaignIndex = bound(0, cvar(me.cvarName), campaign_entries);
 129         cvar_set(me.cvarName, ftos(me.campaignIndex));
 130         if(me.columnNameSize)
 131                 rewrapCampaign(me.columnNameSize, me.rowsPerItem - 3, me.emptyLineHeight, me.realFontSize);
 132         me.nItems = min(me.campaignIndex + 2, campaign_entries);
 133         me.setSelected(me, min(me.campaignIndex, me.nItems - 1));
 134         if(me.nItems - 1 > me.campaignIndex)
 135                 me.scrollToItem(me, me.nItems - 1);
 136         if(me.labelTitle)
 137                 me.labelTitle.setText(me.labelTitle, campaign_title);
 138 }
 139
 140 void XonoticCampaignList_saveCvars(entity me)
 141 {
 142         // write campaign cvars
 143         // no reason to do this!
 144         // cvar_set("g_campaign_name", campaign_name);
 145         // cvar_set(me.cvarName, ftos(me.campaignIndex)); // NOTE: only server QC does that!
 146 }
 147
 148 void XonoticCampaignList_campaignGo(entity me, float step)
 149 {
 150         float canNext, canPrev;
 151         string s;
 152         float i, j, n;
 153
 154         canNext = canPrev = 0;
 155
 156         if(me.campaignGlob >= 0)
 157         {
 158                 n = search_getsize(me.campaignGlob);
 159                 if(n > 0)
 160                 {
 161                         j = -1;
 162                         s = strcat("maps/campaign", campaign_name, ".txt");
 163                         for(i = 0; i < n; ++i)
 164                         {
 165                                 if(search_getfilename(me.campaignGlob, i) == s)
 166                                         j = i;
 167                         }
 168                         if(j < 0)
 169                         {
 170                                 s = strcat("maps/campaign", cvar_defstring("g_campaign_name"), ".txt");
 171                                 for(i = 0; i < n; ++i)
 172                                 {
 173                                         if(search_getfilename(me.campaignGlob, i) == s)
 174                                                 j = i;
 175                                 }
 176                         }
 177                         if(j < 0)
 178                         {
 179                                 if(step >= 0)
 180                                         j = 0;
 181                                 else
 182                                         j = n - 1;
 183                         }
 184                         else
 185                                 j = mod(j + step, n);
 186                         s = search_getfilename(me.campaignGlob, j);
 187                         s = substring(s, 13, strlen(s) - 17);
 188                         cvar_set("g_campaign_name", s);
 189                         me.loadCvars(me);
 190                         canNext = (j != n - 1);
 191                         canPrev = (j != 0);
 192                 }
 193         }
 194
 195         if(me.buttonNext)
 196                 me.buttonNext.disabled = !canNext;
 197         if(me.buttonPrev)
 198                 me.buttonPrev.disabled = !canPrev;
 199 }
 200
 201 void MultiCampaign_Next(entity btn, entity me)
 202 {
 203         me.campaignGo(me, +1);
 204 }
 205 void MultiCampaign_Prev(entity btn, entity me)
 206 {
 207         me.campaignGo(me, -1);
 208 }
 209
 210 void XonoticCampaignList_draw(entity me)
 211 {
 212         if(cvar(me.cvarName) != me.campaignIndex || cvar_string("g_campaign_name") != campaign_name)
 213                 me.loadCvars(me);
 214         SUPER(XonoticCampaignList).draw(me);
 215 }
 216
 217 void XonoticCampaignList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 218 {
 219         me.itemAbsSize = '0 0 0';
 220         SUPER(XonoticCampaignList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 221
 222         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize.y * me.itemHeight));
 223         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize.x * (1 - me.controlWidth)));
 224         me.realUpperMargin1 = 0.5 * me.realFontSize.y;
 225         me.realUpperMargin2 = me.realUpperMargin1 + 2 * me.realFontSize.y;
 226
 227         me.checkMarkSize = (eX * (me.itemAbsSize.y / me.itemAbsSize.x) + eY) * 0.5;
 228
 229         me.columnPreviewOrigin = 0;
 230         me.columnPreviewSize = me.itemAbsSize.y / me.itemAbsSize.x * 4 / 3;
 231         me.columnCheckMarkSize = me.checkMarkSize.x;
 232         me.columnNameSize = 1 - me.columnPreviewSize - me.columnCheckMarkSize - 4 * me.realFontSize.x;
 233         me.columnNameOrigin = me.columnPreviewOrigin + me.columnPreviewSize + me.realFontSize.x;
 234         me.columnCheckMarkOrigin = me.columnNameOrigin + me.columnNameSize + me.realFontSize.x * 2;
 235
 236         me.checkMarkOrigin = eY + eX * (me.columnCheckMarkOrigin + me.columnCheckMarkSize) - me.checkMarkSize;
 237
 238         rewrapCampaign(me.columnNameSize, me.rowsPerItem - 3, me.emptyLineHeight, me.realFontSize);
 239 }
 240 void XonoticCampaignList_doubleClickListBoxItem(entity me, float i, vector where)
 241 {
 242         CampaignList_LoadMap(me, me);
 243 }
 244 void XonoticCampaignList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
 245 {
 246         string s;
 247         vector theColor;
 248         float theAlpha;
 249         float j, n;
 250         vector o;
 251
 252         if(i < me.campaignIndex)
 253         {
 254                 theAlpha = SKINALPHA_CAMPAIGN_SELECTABLE;
 255                 theColor = SKINCOLOR_CAMPAIGN_SELECTABLE;
 256         }
 257         else if(i == me.campaignIndex)
 258         {
 259                 theAlpha = SKINALPHA_CAMPAIGN_CURRENT;
 260                 theColor = SKINCOLOR_CAMPAIGN_CURRENT;
 261         }
 262         else
 263         {
 264                 theAlpha = SKINALPHA_CAMPAIGN_FUTURE;
 265                 theColor = SKINCOLOR_CAMPAIGN_FUTURE;
 266         }
 267
 268         if(isSelected)
 269                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 270         else if(isFocused)
 271         {
 272                 me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
 273                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
 274         }
 275
 276         if(draw_PictureSize(strcat("/maps/", campaign_mapname[i])) == '0 0 0')
 277                 draw_Picture(me.columnPreviewOrigin * eX, "nopreview_map", me.columnPreviewSize * eX + eY, '1 1 1', theAlpha);
 278         else
 279                 draw_Picture(me.columnPreviewOrigin * eX, strcat("/maps/", campaign_mapname[i]), me.columnPreviewSize * eX + eY, '1 1 1', theAlpha);
 280
 281         if(i < me.campaignIndex)
 282                 draw_Picture(me.checkMarkOrigin, "checkmark", me.checkMarkSize, '1 1 1', 1);
 283         if(i <= me.campaignIndex)
 284                 s = campaign_shortdesc[i]; // fteqcc sucks
 285         else
 286                 s = "???";
 287         s = draw_TextShortenToWidth(sprintf(_("Level %d: %s"), i+1, s), me.columnNameSize, 0, me.realFontSize);
 288         draw_Text(me.realUpperMargin1 * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, theColor, theAlpha, 0);
 289
 290         if(i <= me.campaignIndex)
 291         {
 292                 s = campaign_longdesc_wrapped[i];
 293                 n = tokenizebyseparator(s, "\n");
 294                 o = me.realUpperMargin2 * eY + me.columnNameOrigin * eX;
 295                 for(j = 0; j < n; ++j)
 296                         if(argv(j) != "")
 297                         {
 298                                 draw_Text(o, argv(j), me.realFontSize, theColor, theAlpha * SKINALPHA_CAMPAIGN_DESCRIPTION, 0);
 299                                 o.y += me.realFontSize.y;
 300                         }
 301                         else
 302                                 o.y += me.realFontSize.y * me.emptyLineHeight;
 303         }
 304 }
 305 void CampaignList_LoadMap(entity btn, entity me)
 306 {
 307         if(me.selectedItem >= me.nItems || me.selectedItem < 0)
 308                 return;
 309         CampaignSetup(me.selectedItem);
 310 }
 311
 312 void XonoticCampaignList_setSelected(entity me, float i)
 313 {
 314         // prevent too late items from being played
 315         SUPER(XonoticCampaignList).setSelected(me, min(i, me.campaignIndex));
 316 }
 317
 318 float XonoticCampaignList_keyDown(entity me, float scan, float ascii, float shift)
 319 {
 320         if(scan == K_ENTER || scan == K_SPACE || scan == K_KP_ENTER)
 321                 CampaignList_LoadMap(me, me);
 322         else
 323                 return SUPER(XonoticCampaignList).keyDown(me, scan, ascii, shift);
 324         return 1;
 325 }
 326 #endif