qcsrc/menu/xonotic/colorbutton.qc

   1 #include "colorbutton.qh"
   2 #ifndef COLORBUTTON_H
   3 #define COLORBUTTON_H
   4 #include "../item/radiobutton.qc"
   5 CLASS(XonoticColorButton, RadioButton)
   6         METHOD(XonoticColorButton, configureXonoticColorButton, void(entity, float, float, float));
   7         METHOD(XonoticColorButton, setChecked, void(entity, float));
   8         METHOD(XonoticColorButton, draw, void(entity));
   9         ATTRIB(XonoticColorButton, fontSize, float, 0)
  10         ATTRIB(XonoticColorButton, image, string, SKINGFX_COLORBUTTON)
  11
  12         ATTRIB(XonoticColorButton, useDownAsChecked, float, 1)
  13
  14         ATTRIB(XonoticColorButton, cvarPart, float, 0)
  15         ATTRIB(XonoticColorButton, cvarName, string, string_null)
  16         ATTRIB(XonoticColorButton, cvarValueFloat, float, 0)
  17         METHOD(XonoticColorButton, loadCvars, void(entity));
  18         METHOD(XonoticColorButton, saveCvars, void(entity));
  19 ENDCLASS(XonoticColorButton)
  20 entity makeXonoticColorButton(float, float, float);
  21 #endif
  22
  23 #ifdef IMPLEMENTATION
  24 entity makeXonoticColorButton(float theGroup, float theColor, float theValue)
  25 {
  26         entity me;
  27         me = NEW(XonoticColorButton);
  28         me.configureXonoticColorButton(me, theGroup, theColor, theValue);
  29         return me;
  30 }
  31 void XonoticColorButton_configureXonoticColorButton(entity me, float theGroup, float theColor, float theValue)
  32 {
  33         switch(theValue)
  34         {
  35                 // rearrange 1..14 for rainbow order
  36                 case  1: theValue = 10; break;
  37                 case  2: theValue =  4; break;
  38                 case  3: theValue =  1; break;
  39                 case  4: theValue = 14; break;
  40                 case  5: theValue = 12; break;
  41                 case  6: theValue =  7; break;
  42                 case  7: theValue =  3; break;
  43                 case  8: theValue =  2; break;
  44                 case  9: theValue =  6; break;
  45                 case 10: theValue =  5; break;
  46                 case 11: theValue = 13; break;
  47                 case 12: theValue = 11; break;
  48                 case 13: theValue =  8; break;
  49                 case 14: theValue =  9; break;
  50                 default:
  51                         // no change
  52                         break;
  53         }
  54         me.cvarName = "_cl_color";
  55         me.cvarValueFloat = theValue;
  56         me.cvarPart = theColor;
  57         me.loadCvars(me);
  58         me.configureRadioButton(me, string_null, me.fontSize, me.image, theGroup, 0);
  59 }
  60 void XonoticColorButton_setChecked(entity me, float val)
  61 {
  62         if(val != me.checked)
  63         {
  64                 me.checked = val;
  65                 me.saveCvars(me);
  66         }
  67 }
  68 void XonoticColorButton_loadCvars(entity me)
  69 {
  70         if (!me.cvarName)
  71                 return;
  72
  73         if(cvar_string(me.cvarName) == cvar_defstring(me.cvarName))
  74                 cvar_set(me.cvarName, ftos(16 * floor(random() * 15) + floor(random() * 15)));
  75
  76         if(me.cvarPart == 1)
  77                 me.checked = (cvar(me.cvarName) & 240) == me.cvarValueFloat * 16;
  78         else
  79                 me.checked = (cvar(me.cvarName) & 15) == me.cvarValueFloat;
  80 }
  81 void XonoticColorButton_saveCvars(entity me)
  82 {
  83         if (!me.cvarName)
  84                 return;
  85
  86         if(me.checked)
  87         {
  88                 if(me.cvarPart == 1)
  89                         cvar_set(me.cvarName, ftos((cvar(me.cvarName) & 15) + me.cvarValueFloat * 16));
  90                 else
  91                         cvar_set(me.cvarName, ftos((cvar(me.cvarName) & 240) + me.cvarValueFloat));
  92         }
  93         // TODO on an apply button, read _cl_color and execute the color command for it
  94 }
  95 void XonoticColorButton_draw(entity me)
  96 {
  97         me.color  = colormapPaletteColor(me.cvarValueFloat, me.cvarPart);
  98         me.colorC = me.color;
  99         me.colorF = me.color;
 100         me.colorD = me.color;
 101         SUPER(XonoticColorButton).draw(me);
 102 }
 103 #endif