qcsrc/menu/xonotic/dialog_multiplayer_playersetup.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticPlayerSettingsTab) EXTENDS(XonoticTab)
   3         METHOD(XonoticPlayerSettingsTab, fill, void(entity))
   4         METHOD(XonoticPlayerSettingsTab, draw, void(entity))
   5         ATTRIB(XonoticPlayerSettingsTab, title, string, _("Player Setup"))
   6         ATTRIB(XonoticPlayerSettingsTab, intendedWidth, float, 0.9)
   7         ATTRIB(XonoticPlayerSettingsTab, rows, float, 22)
   8         ATTRIB(XonoticPlayerSettingsTab, columns, float, 6.2) // added extra .2 for center space
   9         ATTRIB(XonoticPlayerSettingsTab, playerNameLabel, entity, NULL)
  10         ATTRIB(XonoticPlayerSettingsTab, playerNameLabelAlpha, float, 0)
  11 ENDCLASS(XonoticPlayerSettingsTab)
  12 entity makeXonoticPlayerSettingsTab();
  13 #endif
  14
  15 #ifdef IMPLEMENTATION
  16 entity makeXonoticPlayerSettingsTab()
  17 {
  18         entity me;
  19         me = spawnXonoticPlayerSettingsTab();
  20         me.configureDialog(me);
  21         return me;
  22 }
  23 void XonoticPlayerSettingsTab_draw(entity me)
  24 {
  25         if(cvar_string("_cl_name") == "Player")
  26                 me.playerNameLabel.alpha = ((mod(time * 2, 2) < 1) ? 1 : 0);
  27         else
  28                 me.playerNameLabel.alpha = me.playerNameLabelAlpha;
  29         SUPER(XonoticPlayerSettingsTab).draw(me);
  30 }
  31 void XonoticPlayerSettingsTab_fill(entity me)
  32 {
  33         entity e, pms, label, box;
  34         float i, r, m, n;
  35
  36         me.TR(me);
  37                 me.TD(me, 1, 0.5, me.playerNameLabel = makeXonoticTextLabel(0, _("Name:")));
  38                         me.playerNameLabelAlpha = me.playerNameLabel.alpha;
  39                 me.TD(me, 1, 2.5, label = makeXonoticTextLabel(0, string_null));
  40                         label.allowCut = 1;
  41                         label.allowColors = 1;
  42                         label.alpha = 1;
  43         me.TR(me);
  44                 me.TD(me, 1, 3.0, box = makeXonoticInputBox(1, "_cl_name"));
  45                         box.forbiddenCharacters = "\r\n\\\"$"; // don't care, isn't getting saved
  46                         box.maxLength = -127; // negative means encoded length in bytes
  47                         box.saveImmediately = 1;
  48                         box.enableClearButton = 0;
  49                         label.textEntity = box;
  50         me.TR(me);
  51                 me.TD(me, 5, 1, e = makeXonoticColorpicker(box));
  52                 me.TD(me, 5, 2, e = makeXonoticCharmap(box));
  53         me.TR(me);
  54         me.TR(me);
  55         me.TR(me);
  56         me.TR(me);
  57         me.TR(me);
  58         me.TR(me);
  59         me.gotoRC(me, 8, 0.0);
  60                 pms = makeXonoticPlayerModelSelector();
  61                 me.TD(me, 1, 0.6, e = makeXonoticTextLabel(1, _("Model:")));
  62                 me.TD(me, 1, 0.3, e = makeXonoticButton("<<", '0 0 0'));
  63                         e.onClick = PlayerModelSelector_Prev_Click;
  64                         e.onClickEntity = pms;
  65                 me.TD(me, me.rows - (me.currentRow + 2), 1.8, pms);
  66                 me.TD(me, 1, 0.3, e = makeXonoticButton(">>", '0 0 0'));
  67                         e.onClick = PlayerModelSelector_Next_Click;
  68                         e.onClickEntity = pms;
  69         me.TR(me);
  70                 r = me.currentRow;
  71                 m = me.rows - (r + 3);
  72                 n = 16 - !cvar("developer");
  73                 m = m / (n - 1);
  74                 for(i = 0; i < n; ++i)
  75                 {
  76                         me.gotoRC(me, r + i * m, 0.1);
  77                         me.TDNoMargin(me, m, 0.2, e = makeXonoticColorButton(1, 0, i), '0 1 0');
  78                 }
  79                 for(i = 0; i < n; ++i)
  80                 {
  81                         me.gotoRC(me, r + i * m, 0.4);
  82                         me.TDNoMargin(me, m, 0.2, e = makeXonoticColorButton(2, 1, i), '0 1 0');
  83                 }
  84
  85
  86         // crosshair_enabled: 0 = no crosshair options, 1 = no crosshair selection, but everything else enabled, 2 = all crosshair options enabled
  87         // FIXME: In the future, perhaps make one global crosshair_type cvar which has 0 for disabled, 1 for custom, 2 for per weapon, etc?
  88         me.gotoRC(me, 0, 3.2); me.setFirstColumn(me, me.currentColumn);
  89                 me.TD(me, 1, 3, e = makeXonoticRadioButton(3, "crosshair_enabled", "0", _("No crosshair")));
  90         me.TR(me);
  91                 me.TD(me, 1, 3, e = makeXonoticRadioButton(3, "crosshair_per_weapon", string_null, _("Per weapon crosshair")));
  92                 makeMulti(e, "crosshair_enabled");
  93         me.TR(me);
  94                 me.TD(me, 1, 3, e = makeXonoticRadioButton(3, "crosshair_enabled", "2", _("Custom crosshair")));
  95         me.TR(me);
  96                 me.TDempty(me, 0.1);
  97                 for(i = 1; i <= 14; ++i) {
  98                         me.TDNoMargin(me, 1, 2 / 14, e = makeXonoticCrosshairButton(4, i), '1 1 0');
  99                                 setDependentAND(e, "crosshair_per_weapon", 0, 0, "crosshair_enabled", 1, 2);
 100                 }
 101                 // show a larger preview of the selected crosshair
 102                 me.TDempty(me, 0.1);
 103                 me.TDNoMargin(me, 3, 0.8, e = makeXonoticCrosshairButton(7, -1), '1 1 0'); // crosshair -1 makes this a preview
 104                         setDependentAND(e, "crosshair_per_weapon", 0, 0, "crosshair_enabled", 1, 2);
 105         me.TR(me);
 106                 me.TDempty(me, 0.1);
 107                 for(i = 15; i <= 28; ++i) {
 108                         me.TDNoMargin(me, 1, 2 / 14, e = makeXonoticCrosshairButton(4, i), '1 1 0');
 109                                 setDependentAND(e, "crosshair_per_weapon", 0, 0, "crosshair_enabled", 1, 2);
 110                 }
 111         me.TR(me);
 112         me.TR(me);
 113                 me.TD(me, 1, 1, e = makeXonoticTextLabel(0, _("Crosshair size:")));
 114                         setDependent(e, "crosshair_enabled", 1, 2);
 115                 me.TD(me, 1, 2, e = makeXonoticSlider(0.1, 1.0, 0.01, "crosshair_size"));
 116                         setDependent(e, "crosshair_enabled", 1, 2);
 117         me.TR(me);
 118                 me.TD(me, 1, 1, e = makeXonoticTextLabel(0, _("Crosshair alpha:")));
 119                         setDependent(e, "crosshair_enabled", 1, 2);
 120                 me.TD(me, 1, 2, e = makeXonoticSlider(0, 1, 0.1, "crosshair_alpha"));
 121                         setDependent(e, "crosshair_enabled", 1, 2);
 122         me.TR(me);
 123         me.TR(me);
 124                 me.TD(me, 1, 1, e = makeXonoticTextLabel(0, _("Crosshair color:")));
 125                         setDependent(e, "crosshair_enabled", 1, 2);
 126                 me.TD(me, 1, 1, e = makeXonoticRadioButton(5, "crosshair_color_per_weapon", string_null, _("Per weapon")));
 127                         setDependent(e, "crosshair_enabled", 1, 2);
 128                 me.TD(me, 1, 1, e = makeXonoticRadioButton(5, "crosshair_color_by_health", string_null, _("By health")));
 129                         setDependent(e, "crosshair_enabled", 1, 2);
 130         me.TR(me);
 131                 me.TDempty(me, 0.1);
 132                 me.TD(me, 1, 0.9, e = makeXonoticRadioButton(5, string_null, string_null, _("Custom")));
 133                         setDependent(e, "crosshair_enabled", 1, 2);
 134                 me.TD(me, 2, 2, e = makeXonoticColorpickerString("crosshair_color", "crosshair_color"));
 135                         setDependentAND3(e, "crosshair_color_per_weapon", 0, 0, "crosshair_color_by_health", 0, 0, "crosshair_enabled", 1, 2);
 136         me.TR(me);
 137         me.TR(me);
 138         me.TR(me);
 139                 me.TDempty(me, 0.5);
 140                 me.TD(me, 1, 2, e = makeXonoticButton(_("Other crosshair settings"), '0 0 0'));
 141                         e.onClick = DialogOpenButton_Click;
 142                         e.onClickEntity = main.crosshairDialog;
 143                 setDependent(e, "crosshair_enabled", 1, 2);
 144                 // TODO: show status of crosshair dot and hittest and pickups and such here with text
 145         me.TR(me);
 146         me.TR(me);
 147                 me.TDempty(me, 0.5);
 148                 me.TD(me, 1, 2, e = makeXonoticButton(_("Model settings"), '0 0 0'));
 149                         e.onClick = DialogOpenButton_Click;
 150                         e.onClickEntity = main.modelDialog;
 151                 // TODO: show csqc model settings like forcemyplayer and deglowing/ghosting bodies with text here
 152         me.TR(me);
 153                 me.TDempty(me, 0.5);
 154                 me.TD(me, 1, 2, e = makeXonoticButton(_("View settings"), '0 0 0'));
 155                         e.onClick = DialogOpenButton_Click;
 156                         e.onClickEntity = main.viewDialog;
 157                 // TODO: show fov and other settings with text here
 158         me.TR(me);
 159                 me.TDempty(me, 0.5);
 160                 me.TD(me, 1, 2, e = makeXonoticButton(_("Weapon settings"), '0 0 0'));
 161                         e.onClick = DialogOpenButton_Click;
 162                         e.onClickEntity = main.weaponsDialog;
 163                 // I don't really think this is useful as is, and especially it doesn't look very clean...
 164                 // In the future, if ALL of these buttons had some information, then it would be justified/clean
 165                 //me.TD(me, 1, 1, e0 = makeXonoticTextLabel(0, string_null));
 166                 //      e0.textEntity = main.weaponsDialog;
 167                 //      e0.allowCut = 1;
 168         me.TR(me);
 169                 me.TDempty(me, 0.5);
 170                 me.TD(me, 1, 2, e = makeXonoticButton(_("HUD settings"), '0 0 0'));
 171                         e.onClick = DialogOpenButton_Click;
 172                         e.onClickEntity = main.hudDialog;
 173                 // TODO: show hud config name with text here
 174
 175         me.gotoRC(me, me.rows - 1, 0);
 176                 me.TD(me, 1, me.columns, makeXonoticCommandButton(_("Apply immediately"), '0 0 0', "color -1 -1;name \"$_cl_name\";sendcvar cl_weaponpriority;sendcvar cl_autoswitch;sendcvar cl_forceplayermodels;sendcvar cl_forceplayermodelsfromxonotic;playermodel $_cl_playermodel;playerskin $_cl_playerskin", COMMANDBUTTON_APPLY));
 177 }
 178 #endif