qcsrc/menu/xonotic/dialog_singleplayer.qc

   1 #ifndef DIALOG_SINGLEPLAYER_H
   2 #define DIALOG_SINGLEPLAYER_H
   3 CLASS(XonoticSingleplayerDialog, XonoticDialog)
   4         METHOD(XonoticSingleplayerDialog, fill, void(entity))
   5         ATTRIB(XonoticSingleplayerDialog, title, string, _("Singleplayer"))
   6         ATTRIB(XonoticSingleplayerDialog, color, vector, SKINCOLOR_DIALOG_SINGLEPLAYER)
   7         ATTRIB(XonoticSingleplayerDialog, intendedWidth, float, 0.80)
   8         ATTRIB(XonoticSingleplayerDialog, rows, float, 24)
   9         ATTRIB(XonoticSingleplayerDialog, columns, float, 5)
  10         ATTRIB(XonoticSingleplayerDialog, campaignBox, entity, NULL)
  11 ENDCLASS(XonoticSingleplayerDialog)
  12 #endif
  13
  14 #ifdef IMPLEMENTATION
  15
  16 void InstantAction_LoadMap(entity btn, entity dummy)
  17 {
  18         float pmin = 2, pmax = 16, pstep = 1;
  19
  20         cvar_set("timelimit_override", "10");
  21         cvar_set("g_lms_lives_override", "9");
  22
  23         if(random() < 0.4) // 40% are DM
  24         {
  25                 MapInfo_SwitchGameType(MAPINFO_TYPE_DEATHMATCH);
  26                 pmin = 2;
  27                 pmax = 8;
  28                 pstep = 1;
  29         }
  30         else if(random() < 0.5) // half of the remaining 60%, i.e. 30%, are CTF
  31         {
  32                 MapInfo_SwitchGameType(MAPINFO_TYPE_CTF);
  33                 pmin = 4;
  34                 pmax = 12;
  35                 pstep = 2;
  36         }
  37         else if(random() < 0.5) // half of the remaining 30%, i.e. 15%, are TDM
  38         {
  39                 MapInfo_SwitchGameType(MAPINFO_TYPE_TEAM_DEATHMATCH);
  40                 pmin = 4;
  41                 pmax = 8;
  42                 pstep = 2;
  43         }
  44         else if(random() < 0.666) // 2/3 of the remaining 15%, i.e. 10%, are KH
  45         {
  46                 MapInfo_SwitchGameType(MAPINFO_TYPE_KEYHUNT);
  47                 pmin = 6;
  48                 pmax = 6;
  49                 pstep = 6; // works both for 2 and 3 teams
  50                 // TODO find team count of map, set pstep=2 or 3, and use 2v2(v2) games at least
  51         }
  52         else // somehow distribute the remaining 5%
  53         {
  54                 float r;
  55                 r = floor(random() * 4);
  56                 switch(r)
  57                 {
  58                         default:
  59                         case 0:
  60                                 MapInfo_SwitchGameType(MAPINFO_TYPE_LMS);
  61                                 pmin = 2;
  62                                 pmax = 6;
  63                                 pstep = 1;
  64                                 cvar_set("timelimit_override", "-1");
  65                                 break;
  66                         case 1:
  67                                 MapInfo_SwitchGameType(MAPINFO_TYPE_DOMINATION);
  68                                 pmin = 2;
  69                                 pmax = 8;
  70                                 pstep = 2;
  71                                 break;
  72                         case 2:
  73                                 MapInfo_SwitchGameType(MAPINFO_TYPE_ONSLAUGHT);
  74                                 pmin = 6;
  75                                 pmax = 16;
  76                                 pstep = 2;
  77                                 break;
  78                         case 3:
  79                                 MapInfo_SwitchGameType(MAPINFO_TYPE_ASSAULT);
  80                                 pmin = 4;
  81                                 pmax = 16;
  82                                 pstep = 2;
  83                                 break;
  84                         // CA, Freezetag: bot AI does not work, add them once it does
  85                 }
  86         }
  87
  88         // find random map
  89         MapInfo_FilterGametype(MapInfo_CurrentGametype(), MapInfo_CurrentFeatures(), MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
  90         string s;
  91         do
  92         {
  93                 float m;
  94                 m = floor(random() * MapInfo_count);
  95                 s = MapInfo_BSPName_ByID(m);
  96         }
  97         while(!fexists(sprintf("maps/%s.waypoints", s)));
  98         MapInfo_LoadMap(s, 1);
  99
 100         // configure bots
 101         float p;
 102         pmin = pstep * ceil(pmin / pstep);
 103         pmax = pstep * floor(pmax / pstep);
 104         p = pmin + pstep * floor(random() * ((pmax - pmin) / pstep + 1));
 105         cvar_set("bot_number", ftos(p - 1));
 106
 107         // make sure we go back to menu
 108         cvar_set("lastlevel", "1");
 109 }
 110
 111 void XonoticSingleplayerDialog_fill(entity me)
 112 {
 113         entity e, btnPrev, btnNext, lblTitle;
 114
 115         me.TR(me);
 116                 me.TDempty(me, (me.columns - 3) / 2);
 117                 me.TD(me, 2, 3, e = makeXonoticBigButton(_("Instant action! (random map with bots)"), '0 0 0'));
 118                         e.onClick = InstantAction_LoadMap;
 119                         e.onClickEntity = NULL;
 120         me.TR(me);
 121         me.TR(me);
 122         me.TR(me);
 123                 me.TD(me, 1, 1, btnPrev = makeXonoticButton("<<", '0 0 0'));
 124                 me.TD(me, 1, me.columns - 2, lblTitle = makeXonoticTextLabel(0.5, _("???")));
 125                 me.TD(me, 1, 1, btnNext = makeXonoticButton(">>", '0 0 0'));
 126         me.TR(me);
 127                 me.TD(me, me.rows - 6, me.columns, me.campaignBox = makeXonoticCampaignList());
 128                         btnPrev.onClick = MultiCampaign_Prev;
 129                         btnPrev.onClickEntity = me.campaignBox;
 130                         btnNext.onClick = MultiCampaign_Next;
 131                         btnNext.onClickEntity = me.campaignBox;
 132                         me.campaignBox.buttonNext = btnNext;
 133                         me.campaignBox.buttonPrev = btnPrev;
 134                         me.campaignBox.labelTitle = lblTitle;
 135                         me.campaignBox.campaignGo(me.campaignBox, 0);
 136
 137         me.gotoRC(me, me.rows - 2, 0);
 138                 me.TD(me, 1, 2, e = makeXonoticTextLabel(0.5, _("Campaign Difficulty:")));
 139                 me.TD(me, 1, 1, e = makeXonoticRadioButton(1, "g_campaign_skill", "-2", ZCTX(_("CSKL^Easy"))));
 140                 me.TD(me, 1, 1, e = makeXonoticRadioButton(1, "g_campaign_skill", "-1", ZCTX(_("CSKL^Medium"))));
 141                 me.TD(me, 1, 1, e = makeXonoticRadioButton(1, "g_campaign_skill", "0", ZCTX(_("CSKL^Hard"))));
 142                 me.TR(me);
 143                 me.TD(me, 1, me.columns, e = makeXonoticButton(_("Start Singleplayer!"), '0 0 0'));
 144                         e.onClick = CampaignList_LoadMap;
 145                         e.onClickEntity = me.campaignBox;
 146 }
 147 #endif