qcsrc/menu/xonotic/languagelist.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticLanguageList) EXTENDS(XonoticListBox)
   3         METHOD(XonoticLanguageList, configureXonoticLanguageList, void(entity))
   4         ATTRIB(XonoticLanguageList, rowsPerItem, float, 1)
   5         METHOD(XonoticLanguageList, drawListBoxItem, void(entity, float, vector, float))
   6         METHOD(XonoticLanguageList, resizeNotify, void(entity, vector, vector, vector, vector))
   7         METHOD(XonoticLanguageList, setSelected, void(entity, float))
   8         METHOD(XonoticLanguageList, loadCvars, void(entity))
   9         METHOD(XonoticLanguageList, saveCvars, void(entity))
  10
  11         ATTRIB(XonoticLanguageList, realFontSize, vector, '0 0 0')
  12         ATTRIB(XonoticLanguageList, realUpperMargin, float, 0)
  13         ATTRIB(XonoticLanguageList, columnNameOrigin, float, 0)
  14         ATTRIB(XonoticLanguageList, columnNameSize, float, 0)
  15         ATTRIB(XonoticLanguageList, columnPercentageOrigin, float, 0)
  16         ATTRIB(XonoticLanguageList, columnPercentageSize, float, 0)
  17
  18         METHOD(XonoticLanguageList, clickListBoxItem, void(entity, float, vector)) // double click handling
  19         METHOD(XonoticLanguageList, keyDown, float(entity, float, float, float)) // enter handling
  20         ATTRIB(XonoticLanguageList, lastClickedLanguage, float, -1)
  21         ATTRIB(XonoticLanguageList, lastClickedTime, float, 0)
  22
  23         METHOD(XonoticLanguageList, destroy, void(entity))
  24
  25         ATTRIB(XonoticLanguageList, languagelist, float, -1)
  26         METHOD(XonoticLanguageList, getLanguages, void(entity))
  27         METHOD(XonoticLanguageList, setLanguage, void(entity))
  28         METHOD(XonoticLanguageList, languageParameter, string(entity, float, float))
  29
  30         ATTRIB(XonoticLanguageList, name, string, "languageselector") // change this to make it noninteractive (for first run dialog)
  31 ENDCLASS(XonoticLanguageList)
  32
  33 entity makeXonoticLanguageList();
  34 void SetLanguage_Click(entity btn, entity me);
  35 #endif
  36
  37 #ifdef IMPLEMENTATION
  38
  39 #define LANGPARM_ID 0
  40 #define LANGPARM_NAME 1
  41 #define LANGPARM_NAME_LOCALIZED 2
  42 #define LANGPARM_PERCENTAGE 3
  43 #define LANGPARM_COUNT 4
  44
  45 entity makeXonoticLanguageList()
  46 {
  47         entity me;
  48         me = spawnXonoticLanguageList();
  49         me.configureXonoticLanguageList(me);
  50         return me;
  51 }
  52
  53 void XonoticLanguageList_configureXonoticLanguageList(entity me)
  54 {
  55         me.configureXonoticListBox(me);
  56         me.getLanguages(me);
  57         me.loadCvars(me);
  58 }
  59
  60 void XonoticLanguageList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
  61 {
  62         string s, p;
  63         if(isSelected)
  64                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
  65
  66         s = me.languageParameter(me, i, LANGPARM_NAME_LOCALIZED);
  67
  68         vector save_fontscale = draw_fontscale;
  69         float f = draw_CondensedFontFactor(s, FALSE, me.realFontSize, 1);
  70         draw_fontscale_x *= f;
  71         vector fs = me.realFontSize;
  72         fs_x *= f;
  73         draw_Text(me.realUpperMargin * eY + me.columnNameOrigin * eX, s, fs, SKINCOLOR_TEXT, SKINALPHA_TEXT, 0);
  74         draw_fontscale = save_fontscale;
  75
  76         p = me.languageParameter(me, i, LANGPARM_PERCENTAGE);
  77         if(p != "")
  78         {
  79                 vector save_fontscale = draw_fontscale;
  80                 float f = draw_CondensedFontFactor(p, FALSE, me.realFontSize, 1);
  81                 draw_fontscale_x *= f;
  82                 vector fs = me.realFontSize;
  83                 fs_x *= f;
  84                 draw_Text(me.realUpperMargin * eY + (me.columnPercentageOrigin + (me.columnPercentageSize - draw_TextWidth(p, 0, fs))) * eX, p, fs, SKINCOLOR_TEXT, SKINALPHA_TEXT, 0);
  85                 draw_fontscale = save_fontscale;
  86         }
  87 }
  88
  89 void XonoticLanguageList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  90 {
  91         SUPER(XonoticLanguageList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
  92         me.realFontSize_y = me.fontSize / (absSize_y * me.itemHeight);
  93         me.realFontSize_x = me.fontSize / (absSize_x * (1 - me.controlWidth));
  94         me.realUpperMargin = 0.5 * (1 - me.realFontSize_y);
  95         me.columnPercentageSize = me.realFontSize_x * 3;
  96         me.columnPercentageOrigin = 1 - me.columnPercentageSize;
  97         me.columnNameOrigin = 0;
  98         me.columnNameSize = me.columnPercentageOrigin;
  99 }
 100
 101 void XonoticLanguageList_setSelected(entity me, float i)
 102 {
 103         SUPER(XonoticLanguageList).setSelected(me, i);
 104         me.saveCvars(me);
 105 }
 106
 107 void XonoticLanguageList_loadCvars(entity me)
 108 {
 109         string s;
 110         float i, n;
 111         s = cvar_string("_menu_prvm_language");
 112         n = me.nItems;
 113
 114         // default to English
 115         for(i = 0; i < n; ++i)
 116         {
 117                 if(me.languageParameter(me, i, LANGPARM_ID) == "en")
 118                 {
 119                         me.selectedItem = i;
 120                         break;
 121                 }
 122         }
 123
 124         // otherwise, find the language
 125         for(i = 0; i < n; ++i)
 126         {
 127                 if(me.languageParameter(me, i, LANGPARM_ID) == s)
 128                 {
 129                         me.selectedItem = i;
 130                         break;
 131                 }
 132         }
 133
 134         // save it off (turning anything unknown into "en")
 135         me.saveCvars(me);
 136 }
 137
 138 void XonoticLanguageList_saveCvars(entity me)
 139 {
 140         cvar_set("_menu_prvm_language", me.languageParameter(me, me.selectedItem, LANGPARM_ID));
 141 }
 142
 143 void XonoticLanguageList_clickListBoxItem(entity me, float i, vector where)
 144 {
 145         if(i == me.lastClickedLanguage)
 146                 if(time < me.lastClickedTime + 0.3)
 147                 {
 148                         // DOUBLE CLICK!
 149                         me.setSelected(me, i);
 150                         me.setLanguage(me);
 151                 }
 152         me.lastClickedLanguage = i;
 153         me.lastClickedTime = time;
 154 }
 155
 156 float XonoticLanguageList_keyDown(entity me, float scan, float ascii, float shift)
 157 {
 158         if(scan == K_ENTER || scan == K_KP_ENTER) {
 159                 me.setLanguage(me);
 160                 return 1;
 161         }
 162         else
 163                 return SUPER(XonoticLanguageList).keyDown(me, scan, ascii, shift);
 164 }
 165
 166 void XonoticLanguageList_destroy(entity me)
 167 {
 168         buf_del(me.languagelist);
 169 }
 170
 171 void XonoticLanguageList_getLanguages(entity me)
 172 {
 173         float buf, i, n, fh;
 174         string s;
 175
 176         buf = buf_create();
 177
 178         fh = fopen("languages.txt", FILE_READ);
 179         i = 0;
 180         while((s = fgets(fh)))
 181         {
 182                 n = tokenize_console(s);
 183                 if(n < 3)
 184                         continue;
 185                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_ID, argv(0));
 186                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_NAME, argv(1));
 187                 float k = strstrofs(argv(2), "(", 0);
 188                 if(k > 0)
 189                 if(substring(argv(2), strlen(argv(2)) - 1, 1) == ")")
 190                 {
 191                         string percent = substring(argv(2), k + 1, -2);
 192                         if(percent != "100%")
 193                                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_PERCENTAGE, percent);
 194                 }
 195                 bufstr_set(buf, i * LANGPARM_COUNT + LANGPARM_NAME_LOCALIZED, (k < 0) ? argv(2) : substring(argv(2), 0, k - 1));
 196                 ++i;
 197         }
 198         fclose(fh);
 199
 200         me.languagelist = buf;
 201         me.nItems = i;
 202 }
 203
 204 void XonoticLanguageList_setLanguage(entity me)
 205 {
 206         if(prvm_language != cvar_string("_menu_prvm_language"))
 207         {
 208                 if(!(gamestatus & GAME_CONNECTED))
 209                         localcmd("\nprvm_language \"$_menu_prvm_language\"; menu_restart; menu_cmd languageselect\n");
 210                 else
 211                         DialogOpenButton_Click(me, main.languageWarningDialog);
 212         }
 213 }
 214
 215 string XonoticLanguageList_languageParameter(entity me, float i, float key)
 216 {
 217         return bufstr_get(me.languagelist, i * LANGPARM_COUNT + key);
 218 }
 219
 220 void SetLanguage_Click(entity btn, entity me)
 221 {
 222         me.setLanguage(me);
 223 }
 224
 225 #endif