qcsrc/menu/xonotic/maplist.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticMapList) EXTENDS(XonoticListBox)
   3         METHOD(XonoticMapList, configureXonoticMapList, void(entity))
   4         ATTRIB(XonoticMapList, rowsPerItem, float, 4)
   5         METHOD(XonoticMapList, draw, void(entity))
   6         METHOD(XonoticMapList, drawListBoxItem, void(entity, float, vector, float))
   7         METHOD(XonoticMapList, clickListBoxItem, void(entity, float, vector))
   8         METHOD(XonoticMapList, resizeNotify, void(entity, vector, vector, vector, vector))
   9         METHOD(XonoticMapList, refilter, void(entity))
  10         METHOD(XonoticMapList, refilterCallback, void(entity, entity))
  11         METHOD(XonoticMapList, keyDown, float(entity, float, float, float))
  12
  13         ATTRIB(XonoticMapList, realFontSize, vector, '0 0 0')
  14         ATTRIB(XonoticMapList, columnPreviewOrigin, float, 0)
  15         ATTRIB(XonoticMapList, columnPreviewSize, float, 0)
  16         ATTRIB(XonoticMapList, columnNameOrigin, float, 0)
  17         ATTRIB(XonoticMapList, columnNameSize, float, 0)
  18         ATTRIB(XonoticMapList, checkMarkOrigin, vector, '0 0 0')
  19         ATTRIB(XonoticMapList, checkMarkSize, vector, '0 0 0')
  20         ATTRIB(XonoticMapList, realUpperMargin1, float, 0)
  21         ATTRIB(XonoticMapList, realUpperMargin2, float, 0)
  22
  23         ATTRIB(XonoticMapList, lastClickedMap, float, -1)
  24         ATTRIB(XonoticMapList, lastClickedTime, float, 0)
  25
  26         ATTRIB(XonoticMapList, lastGametype, float, 0)
  27         ATTRIB(XonoticMapList, lastFeatures, float, 0)
  28
  29         ATTRIB(XonoticMapList, origin, vector, '0 0 0')
  30         ATTRIB(XonoticMapList, itemAbsSize, vector, '0 0 0')
  31
  32         ATTRIB(XonoticMapList, g_maplistCache, string, string_null)
  33         METHOD(XonoticMapList, g_maplistCacheToggle, void(entity, float))
  34         METHOD(XonoticMapList, g_maplistCacheQuery, float(entity, float))
  35
  36         ATTRIB(XonoticMapList, startButton, entity, NULL)
  37
  38         METHOD(XonoticMapList, loadCvars, void(entity))
  39
  40         ATTRIB(XonoticMapList, typeToSearchString, string, string_null)
  41         ATTRIB(XonoticMapList, typeToSearchTime, float, 0)
  42
  43         METHOD(XonoticMapList, destroy, void(entity))
  44
  45         ATTRIB(XonoticListBox, alphaBG, float, 0)
  46 ENDCLASS(XonoticMapList)
  47 entity makeXonoticMapList();
  48 void MapList_All(entity btn, entity me);
  49 void MapList_None(entity btn, entity me);
  50 void MapList_LoadMap(entity btn, entity me);
  51 #endif
  52
  53 #ifdef IMPLEMENTATION
  54 void XonoticMapList_destroy(entity me)
  55 {
  56         MapInfo_Shutdown();
  57 }
  58
  59 entity makeXonoticMapList()
  60 {
  61         entity me;
  62         me = spawnXonoticMapList();
  63         me.configureXonoticMapList(me);
  64         return me;
  65 }
  66
  67 void XonoticMapList_configureXonoticMapList(entity me)
  68 {
  69         me.configureXonoticListBox(me);
  70         me.refilter(me);
  71 }
  72
  73 void XonoticMapList_loadCvars(entity me)
  74 {
  75         me.refilter(me);
  76 }
  77
  78 float XonoticMapList_g_maplistCacheQuery(entity me, float i)
  79 {
  80         return stof(substring(me.g_maplistCache, i, 1));
  81 }
  82 void XonoticMapList_g_maplistCacheToggle(entity me, float i)
  83 {
  84         string a, b, c, s, bspname;
  85         float n;
  86         s = me.g_maplistCache;
  87         if (!s)
  88                 return;
  89         b = substring(s, i, 1);
  90         if(b == "0")
  91                 b = "1";
  92         else if(b == "1")
  93                 b = "0";
  94         else
  95                 return; // nothing happens
  96         a = substring(s, 0, i);
  97         c = substring(s, i+1, strlen(s) - (i+1));
  98         strunzone(s);
  99         me.g_maplistCache = strzone(strcat(a, b, c));
 100         // TODO also update the actual cvar
 101         if (!((bspname = MapInfo_BSPName_ByID(i))))
 102                 return;
 103         if(b == "1")
 104                 cvar_set("g_maplist", strcat(bspname, " ", cvar_string("g_maplist")));
 105         else
 106         {
 107                 s = "";
 108                 n = tokenize_console(cvar_string("g_maplist"));
 109                 for(i = 0; i < n; ++i)
 110                         if(argv(i) != bspname)
 111                                 s = strcat(s, " ", argv(i));
 112                 cvar_set("g_maplist", substring(s, 1, strlen(s) - 1));
 113         }
 114 }
 115
 116 void XonoticMapList_draw(entity me)
 117 {
 118         if(me.startButton)
 119                 me.startButton.disabled = ((me.selectedItem < 0) || (me.selectedItem >= me.nItems));
 120         SUPER(XonoticMapList).draw(me);
 121 }
 122
 123 void XonoticMapList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 124 {
 125         me.itemAbsSize = '0 0 0';
 126         SUPER(XonoticMapList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 127
 128         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize_y * me.itemHeight));
 129         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize_x * (1 - me.controlWidth)));
 130         me.realUpperMargin1 = 0.5 * (1 - 2.5 * me.realFontSize_y);
 131         me.realUpperMargin2 = me.realUpperMargin1 + 1.5 * me.realFontSize_y;
 132
 133         me.columnPreviewOrigin = 0;
 134         me.columnPreviewSize = me.itemAbsSize_y / me.itemAbsSize_x * 4 / 3;
 135         me.columnNameOrigin = me.columnPreviewOrigin + me.columnPreviewSize + me.realFontSize_x;
 136         me.columnNameSize = 1 - me.columnPreviewSize - 2 * me.realFontSize_x;
 137
 138         me.checkMarkSize = (eX * (me.itemAbsSize_y / me.itemAbsSize_x) + eY) * 0.5;
 139         me.checkMarkOrigin = eY + eX * (me.columnPreviewOrigin + me.columnPreviewSize) - me.checkMarkSize;
 140 }
 141
 142 void XonoticMapList_clickListBoxItem(entity me, float i, vector where)
 143 {
 144         if(where_x <= me.columnPreviewOrigin + me.columnPreviewSize)
 145                 if(where_x >= 0)
 146                         me.g_maplistCacheToggle(me, i);
 147
 148         if(where_x >= me.columnNameOrigin)
 149                 if(where_x <= 1)
 150                 {
 151                         if(i == me.lastClickedMap)
 152                                 if(time < me.lastClickedTime + 0.3)
 153                                 {
 154                                         // DOUBLE CLICK!
 155                                         // pop up map info screen
 156                                         main.mapInfoDialog.loadMapInfo(main.mapInfoDialog, i, me);
 157                                         DialogOpenButton_Click_withCoords(NULL, main.mapInfoDialog, me.origin + eX * (me.columnNameOrigin * me.size_x) + eY * ((me.itemHeight * i - me.scrollPos) * me.size_y), eY * me.itemAbsSize_y + eX * (me.itemAbsSize_x * me.columnNameSize));
 158                                         return;
 159                                 }
 160                         me.lastClickedMap = i;
 161                         me.lastClickedTime = time;
 162                 }
 163 }
 164
 165 void XonoticMapList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
 166 {
 167         // layout: Ping, Map name, Map name, NP, TP, MP
 168         string s;
 169         float theAlpha;
 170         float included;
 171
 172         if(!MapInfo_Get_ByID(i))
 173                 return;
 174
 175         included = me.g_maplistCacheQuery(me, i);
 176         if(included || isSelected)
 177                 theAlpha = SKINALPHA_MAPLIST_INCLUDEDFG;
 178         else
 179                 theAlpha = SKINALPHA_MAPLIST_NOTINCLUDEDFG;
 180
 181         if(isSelected)
 182                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 183         else if(included)
 184                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_MAPLIST_INCLUDEDBG, SKINALPHA_MAPLIST_INCLUDEDBG);
 185
 186         if(draw_PictureSize(strcat("/maps/", MapInfo_Map_bspname)) == '0 0 0')
 187                 draw_Picture(me.columnPreviewOrigin * eX, "nopreview_map", me.columnPreviewSize * eX + eY, '1 1 1', theAlpha);
 188         else
 189                 draw_Picture(me.columnPreviewOrigin * eX, strcat("/maps/", MapInfo_Map_bspname), me.columnPreviewSize * eX + eY, '1 1 1', theAlpha);
 190
 191         if(included)
 192                 draw_Picture(me.checkMarkOrigin, "checkmark", me.checkMarkSize, '1 1 1', 1);
 193         s = draw_TextShortenToWidth(strdecolorize(MapInfo_Map_titlestring), me.columnNameSize, 0, me.realFontSize);
 194         draw_Text(me.realUpperMargin1 * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, SKINCOLOR_MAPLIST_TITLE, theAlpha, 0);
 195         s = draw_TextShortenToWidth(strdecolorize(MapInfo_Map_author), me.columnNameSize, 0,  me.realFontSize);
 196         draw_Text(me.realUpperMargin2 * eY + (me.columnNameOrigin + 1.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, SKINCOLOR_MAPLIST_AUTHOR, theAlpha, 0);
 197
 198         MapInfo_ClearTemps();
 199 }
 200
 201 void XonoticMapList_refilter(entity me)
 202 {
 203         float i, j, n;
 204         string s;
 205         float gt, f;
 206         gt = MapInfo_CurrentGametype();
 207         f = MapInfo_CurrentFeatures();
 208         MapInfo_FilterGametype(gt, f, MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 209         me.nItems = MapInfo_count;
 210         for(i = 0; i < MapInfo_count; ++i)
 211                 draw_PreloadPicture(strcat("/maps/", MapInfo_BSPName_ByID(i)));
 212         if(me.g_maplistCache)
 213                 strunzone(me.g_maplistCache);
 214         s = "0";
 215         for(i = 1; i < MapInfo_count; i *= 2)
 216                 s = strcat(s, s);
 217         n = tokenize_console(cvar_string("g_maplist"));
 218         for(i = 0; i < n; ++i)
 219         {
 220                 j = MapInfo_FindName(argv(i));
 221                 if(j >= 0)
 222                         s = strcat(
 223                                 substring(s, 0, j),
 224                                 "1",
 225                                 substring(s, j+1, MapInfo_count - (j+1))
 226                         );
 227         }
 228         me.g_maplistCache = strzone(s);
 229         if(gt != me.lastGametype || f != me.lastFeatures)
 230         {
 231                 me.lastGametype = gt;
 232                 me.lastFeatures = f;
 233                 me.setSelected(me, 0);
 234         }
 235 }
 236
 237 void XonoticMapList_refilterCallback(entity me, entity cb)
 238 {
 239         me.refilter(me);
 240 }
 241
 242 void MapList_All(entity btn, entity me)
 243 {
 244         float i;
 245         string s;
 246         MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, MapInfo_ForbiddenFlags(), 0); // all
 247         s = "";
 248         for(i = 0; i < MapInfo_count; ++i)
 249                 s = strcat(s, " ", MapInfo_BSPName_ByID(i));
 250         cvar_set("g_maplist", substring(s, 1, strlen(s) - 1));
 251         me.refilter(me);
 252 }
 253
 254 void MapList_None(entity btn, entity me)
 255 {
 256         cvar_set("g_maplist", "");
 257         me.refilter(me);
 258 }
 259
 260 void MapList_LoadMap(entity btn, entity me)
 261 {
 262         string m;
 263         float i;
 264
 265         i = me.selectedItem;
 266
 267         if(btn.parent.instanceOfXonoticMapInfoDialog)
 268         {
 269                 i = btn.parent.currentMapIndex;
 270                 Dialog_Close(btn, btn.parent);
 271         }
 272
 273         if(i >= me.nItems || i < 0)
 274                 return;
 275
 276         m = MapInfo_BSPName_ByID(i);
 277         if (!m)
 278         {
 279                 print(_("Huh? Can't play this (m is NULL). Refiltering so this won't happen again.\n"));
 280                 me.refilter(me);
 281                 return;
 282         }
 283         if(MapInfo_CheckMap(m))
 284         {
 285                 localcmd("\nmenu_loadmap_prepare\n");
 286                 if(cvar("menu_use_default_hostname"))
 287                         localcmd("hostname \"", sprintf(_("%s's Xonotic Server"), strdecolorize(cvar_string("_cl_name"))), "\"\n");
 288                 MapInfo_LoadMap(m, 1);
 289         }
 290         else
 291         {
 292                 print(_("Huh? Can't play this (invalid game type). Refiltering so this won't happen again.\n"));
 293                 me.refilter(me);
 294                 return;
 295         }
 296 }
 297
 298 float XonoticMapList_keyDown(entity me, float scan, float ascii, float shift)
 299 {
 300         string ch, save;
 301         if(me.nItems <= 0)
 302                 return SUPER(XonoticMapList).keyDown(me, scan, ascii, shift);
 303         if(scan == K_MOUSE2 || scan == K_SPACE || scan == K_ENTER || scan == K_KP_ENTER)
 304         {
 305                 // pop up map info screen
 306                 main.mapInfoDialog.loadMapInfo(main.mapInfoDialog, me.selectedItem, me);
 307                 DialogOpenButton_Click_withCoords(NULL, main.mapInfoDialog, me.origin + eX * (me.columnNameOrigin * me.size_x) + eY * ((me.itemHeight * me.selectedItem - me.scrollPos) * me.size_y), eY * me.itemAbsSize_y + eX * (me.itemAbsSize_x * me.columnNameSize));
 308         }
 309         else if(scan == K_MOUSE3 || scan == K_INS || scan == K_KP_INS)
 310         {
 311                 me.g_maplistCacheToggle(me, me.selectedItem);
 312         }
 313         else if(ascii == 43) // +
 314         {
 315                 if (!me.g_maplistCacheQuery(me, me.selectedItem))
 316                         me.g_maplistCacheToggle(me, me.selectedItem);
 317         }
 318         else if(ascii == 45) // -
 319         {
 320                 if(me.g_maplistCacheQuery(me, me.selectedItem))
 321                         me.g_maplistCacheToggle(me, me.selectedItem);
 322         }
 323         else if(scan == K_BACKSPACE)
 324         {
 325                 if(time < me.typeToSearchTime)
 326                 {
 327                         save = substring(me.typeToSearchString, 0, strlen(me.typeToSearchString) - 1);
 328                         if(me.typeToSearchString)
 329                                 strunzone(me.typeToSearchString);
 330                         me.typeToSearchString = strzone(save);
 331                         me.typeToSearchTime = time + 0.5;
 332                         if(strlen(me.typeToSearchString))
 333                         {
 334                                 MapInfo_FindName(me.typeToSearchString);
 335                                 if(MapInfo_FindName_firstResult >= 0)
 336                                         me.setSelected(me, MapInfo_FindName_firstResult);
 337                         }
 338                 }
 339         }
 340         else if(ascii >= 32 && ascii != 127)
 341         {
 342                 ch = chr(ascii);
 343                 if(time > me.typeToSearchTime)
 344                         save = ch;
 345                 else
 346                         save = strcat(me.typeToSearchString, ch);
 347                 if(me.typeToSearchString)
 348                         strunzone(me.typeToSearchString);
 349                 me.typeToSearchString = strzone(save);
 350                 me.typeToSearchTime = time + 0.5;
 351                 MapInfo_FindName(me.typeToSearchString);
 352                 if(MapInfo_FindName_firstResult >= 0)
 353                         me.setSelected(me, MapInfo_FindName_firstResult);
 354         }
 355         else
 356                 return SUPER(XonoticMapList).keyDown(me, scan, ascii, shift);
 357         return 1;
 358 }
 359
 360 #endif