qcsrc/menu/xonotic/maplist.qc

   1 #ifndef MAPLIST_H
   2 #define MAPLIST_H
   3 #include "listbox.qc"
   4 CLASS(XonoticMapList, XonoticListBox)
   5         METHOD(XonoticMapList, configureXonoticMapList, void(entity))
   6         ATTRIB(XonoticMapList, rowsPerItem, float, 4)
   7         METHOD(XonoticMapList, draw, void(entity))
   8         METHOD(XonoticMapList, drawListBoxItem, void(entity, float, vector, float))
   9         METHOD(XonoticMapList, clickListBoxItem, void(entity, float, vector))
  10         METHOD(XonoticMapList, doubleClickListBoxItem, void(entity, float, vector))
  11         METHOD(XonoticMapList, resizeNotify, void(entity, vector, vector, vector, vector))
  12         METHOD(XonoticMapList, refilter, void(entity))
  13         METHOD(XonoticMapList, refilterCallback, void(entity, entity))
  14         METHOD(XonoticMapList, keyDown, float(entity, float, float, float))
  15
  16         ATTRIB(XonoticMapList, realFontSize, vector, '0 0 0')
  17         ATTRIB(XonoticMapList, columnPreviewOrigin, float, 0)
  18         ATTRIB(XonoticMapList, columnPreviewSize, float, 0)
  19         ATTRIB(XonoticMapList, columnNameOrigin, float, 0)
  20         ATTRIB(XonoticMapList, columnNameSize, float, 0)
  21         ATTRIB(XonoticMapList, checkMarkOrigin, vector, '0 0 0')
  22         ATTRIB(XonoticMapList, checkMarkSize, vector, '0 0 0')
  23         ATTRIB(XonoticMapList, realUpperMargin1, float, 0)
  24         ATTRIB(XonoticMapList, realUpperMargin2, float, 0)
  25
  26         ATTRIB(XonoticMapList, lastGametype, float, 0)
  27         ATTRIB(XonoticMapList, lastFeatures, float, 0)
  28
  29         ATTRIB(XonoticMapList, origin, vector, '0 0 0')
  30         ATTRIB(XonoticMapList, itemAbsSize, vector, '0 0 0')
  31
  32         ATTRIB(XonoticMapList, g_maplistCache, string, string_null)
  33         METHOD(XonoticMapList, g_maplistCacheToggle, void(entity, float))
  34         METHOD(XonoticMapList, g_maplistCacheQuery, float(entity, float))
  35
  36         ATTRIB(XonoticMapList, stringFilter, string, string_null)
  37         ATTRIB(XonoticMapList, stringFilterBox, entity, NULL)
  38
  39         ATTRIB(XonoticMapList, startButton, entity, NULL)
  40
  41         METHOD(XonoticMapList, loadCvars, void(entity))
  42
  43         ATTRIB(XonoticMapList, typeToSearchString, string, string_null)
  44         ATTRIB(XonoticMapList, typeToSearchTime, float, 0)
  45
  46         METHOD(XonoticMapList, destroy, void(entity))
  47
  48         ATTRIB(XonoticMapList, alphaBG, float, 0)
  49 ENDCLASS(XonoticMapList)
  50 entity makeXonoticMapList();
  51 entity makeXonoticMapListStringFilterBox(entity me, float doEditColorCodes, string theCvar);
  52 void MapList_StringFilterBox_Change(entity box, entity me);
  53 float MapList_StringFilterBox_keyDown(entity me, float key, float ascii, float shift);
  54 void MapList_Add_Shown(entity btn, entity me);
  55 void MapList_Remove_Shown(entity btn, entity me);
  56 void MapList_Add_All(entity btn, entity me);
  57 void MapList_Remove_All(entity btn, entity me);
  58 void MapList_LoadMap(entity btn, entity me);
  59 #endif
  60
  61 #ifdef IMPLEMENTATION
  62 void XonoticMapList_destroy(entity me)
  63 {
  64         MapInfo_Shutdown();
  65 }
  66
  67 entity makeXonoticMapListStringFilterBox(entity me, float doEditColorCodes, string theCvar)
  68 {
  69         return makeXonoticInputBox(doEditColorCodes, theCvar);
  70 }
  71 entity makeXonoticMapList()
  72 {
  73         entity me;
  74         me = NEW(XonoticMapList);
  75         me.configureXonoticMapList(me);
  76         return me;
  77 }
  78
  79 entity MapList_Set_String_Filter_Box(entity me, entity e)
  80 {
  81         me.stringFilterBox = e;
  82         return e;
  83 }
  84
  85 void XonoticMapList_configureXonoticMapList(entity me)
  86 {
  87         me.configureXonoticListBox(me);
  88         me.refilter(me);
  89 }
  90
  91 void XonoticMapList_loadCvars(entity me)
  92 {
  93         me.refilter(me);
  94 }
  95
  96
  97 float XonoticMapList_g_maplistCacheQuery(entity me, float i)
  98 {
  99         return stof(substring(me.g_maplistCache, i, 1));
 100 }
 101 void XonoticMapList_g_maplistCacheToggle(entity me, float i)
 102 {
 103         string a, b, c, s, bspname;
 104         float n;
 105         s = me.g_maplistCache;
 106         if (!s)
 107                 return;
 108         b = substring(s, i, 1);
 109         if(b == "0")
 110                 b = "1";
 111         else if(b == "1")
 112                 b = "0";
 113         else
 114                 return; // nothing happens
 115         a = substring(s, 0, i);
 116         c = substring(s, i+1, strlen(s) - (i+1));
 117         strunzone(s);
 118         me.g_maplistCache = strzone(strcat(a, b, c));
 119         // TODO also update the actual cvar
 120         if (!((bspname = MapInfo_BSPName_ByID(i))))
 121                 return;
 122         if(b == "1")
 123                 cvar_set("g_maplist", strcat(bspname, " ", cvar_string("g_maplist")));
 124         else
 125         {
 126                 s = "";
 127                 n = tokenize_console(cvar_string("g_maplist"));
 128                 for(i = 0; i < n; ++i)
 129                         if(argv(i) != bspname)
 130                                 s = strcat(s, " ", argv(i));
 131                 cvar_set("g_maplist", substring(s, 1, strlen(s) - 1));
 132         }
 133 }
 134
 135 void XonoticMapList_draw(entity me)
 136 {
 137         if(me.startButton)
 138                 me.startButton.disabled = ((me.selectedItem < 0) || (me.selectedItem >= me.nItems));
 139         SUPER(XonoticMapList).draw(me);
 140 }
 141
 142 void XonoticMapList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 143 {
 144         me.itemAbsSize = '0 0 0';
 145         SUPER(XonoticMapList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 146
 147         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize.y * me.itemHeight));
 148         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize.x * (1 - me.controlWidth)));
 149         me.realUpperMargin1 = 0.5 * (1 - 2.5 * me.realFontSize.y);
 150         me.realUpperMargin2 = me.realUpperMargin1 + 1.5 * me.realFontSize.y;
 151
 152         me.columnPreviewOrigin = 0;
 153         me.columnPreviewSize = me.itemAbsSize.y / me.itemAbsSize.x * 4 / 3;
 154         me.columnNameOrigin = me.columnPreviewOrigin + me.columnPreviewSize + me.realFontSize.x;
 155         me.columnNameSize = 1 - me.columnPreviewSize - 2 * me.realFontSize.x;
 156
 157         me.checkMarkSize = (eX * (me.itemAbsSize.y / me.itemAbsSize.x) + eY) * 0.5;
 158         me.checkMarkOrigin = eY + eX * (me.columnPreviewOrigin + me.columnPreviewSize) - me.checkMarkSize;
 159 }
 160
 161 void XonoticMapList_clickListBoxItem(entity me, float i, vector where)
 162 {
 163         if(where.x <= me.columnPreviewOrigin + me.columnPreviewSize)
 164                 if(where.x >= 0)
 165                 {
 166                         m_play_click_sound(MENU_SOUND_SELECT);
 167                         me.g_maplistCacheToggle(me, i);
 168                 }
 169 }
 170
 171 void XonoticMapList_doubleClickListBoxItem(entity me, float i, vector where)
 172 {
 173         if(where.x >= me.columnNameOrigin)
 174                 if(where.x <= 1)
 175                 {
 176                         // pop up map info screen
 177                         m_play_click_sound(MENU_SOUND_OPEN);
 178                         main.mapInfoDialog.loadMapInfo(main.mapInfoDialog, i, me);
 179                         DialogOpenButton_Click_withCoords(NULL, main.mapInfoDialog, me.origin + eX * (me.columnNameOrigin * me.size.x) + eY * ((me.itemHeight * i - me.scrollPos) * me.size.y), eY * me.itemAbsSize.y + eX * (me.itemAbsSize.x * me.columnNameSize));
 180                 }
 181 }
 182
 183 void XonoticMapList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
 184 {
 185         // layout: Ping, Map name, Map name, NP, TP, MP
 186         string s;
 187         float theAlpha;
 188         float included;
 189
 190         if(!MapInfo_Get_ByID(i))
 191                 return;
 192
 193         included = me.g_maplistCacheQuery(me, i);
 194         if(included || isSelected)
 195                 theAlpha = SKINALPHA_MAPLIST_INCLUDEDFG;
 196         else
 197                 theAlpha = SKINALPHA_MAPLIST_NOTINCLUDEDFG;
 198
 199         if(isSelected)
 200                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 201         else if(included)
 202                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_MAPLIST_INCLUDEDBG, SKINALPHA_MAPLIST_INCLUDEDBG);
 203
 204         if(draw_PictureSize(strcat("/maps/", MapInfo_Map_bspname)) == '0 0 0')
 205                 draw_Picture(me.columnPreviewOrigin * eX, "nopreview_map", me.columnPreviewSize * eX + eY, '1 1 1', theAlpha);
 206         else
 207                 draw_Picture(me.columnPreviewOrigin * eX, strcat("/maps/", MapInfo_Map_bspname), me.columnPreviewSize * eX + eY, '1 1 1', theAlpha);
 208
 209         if(included)
 210                 draw_Picture(me.checkMarkOrigin, "checkmark", me.checkMarkSize, '1 1 1', 1);
 211         s = draw_TextShortenToWidth(strdecolorize(MapInfo_Map_titlestring), me.columnNameSize, 0, me.realFontSize);
 212         draw_Text(me.realUpperMargin1 * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, SKINCOLOR_MAPLIST_TITLE, theAlpha, 0);
 213         s = draw_TextShortenToWidth(strdecolorize(MapInfo_Map_author), me.columnNameSize, 0,  me.realFontSize);
 214         draw_Text(me.realUpperMargin2 * eY + (me.columnNameOrigin + 1.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, SKINCOLOR_MAPLIST_AUTHOR, theAlpha, 0);
 215
 216         MapInfo_ClearTemps();
 217 }
 218
 219 void XonoticMapList_refilter(entity me)
 220 {
 221         float i, j, n;
 222         string s;
 223         float gt, f;
 224         gt = MapInfo_CurrentGametype();
 225         f = MapInfo_CurrentFeatures();
 226         MapInfo_FilterGametype(gt, f, MapInfo_RequiredFlags(), MapInfo_ForbiddenFlags(), 0);
 227         if (me.stringFilter)
 228                 MapInfo_FilterString(me.stringFilter);
 229         me.nItems = MapInfo_count;
 230
 231         for(i = 0; i < MapInfo_count; ++i)
 232                 draw_PreloadPicture(strcat("/maps/", MapInfo_BSPName_ByID(i)));
 233         if(me.g_maplistCache)
 234                 strunzone(me.g_maplistCache);
 235         s = "0";
 236         for(i = 1; i < MapInfo_count; i *= 2)
 237                 s = strcat(s, s);
 238         n = tokenize_console(cvar_string("g_maplist"));
 239         for(i = 0; i < n; ++i)
 240         {
 241                 j = MapInfo_FindName(argv(i));
 242                 if(j >= 0)
 243                         s = strcat(
 244                                 substring(s, 0, j),
 245                                 "1",
 246                                 substring(s, j+1, MapInfo_count - (j+1))
 247                         );
 248         }
 249         me.g_maplistCache = strzone(s);
 250         if(gt != me.lastGametype || f != me.lastFeatures)
 251         {
 252                 me.lastGametype = gt;
 253                 me.lastFeatures = f;
 254                 me.setSelected(me, 0);
 255         }
 256 }
 257
 258 void XonoticMapList_refilterCallback(entity me, entity cb)
 259 {
 260         me.refilter(me);
 261 }
 262
 263 void MapList_StringFilterBox_Change(entity box, entity me)
 264 {
 265         if(me.stringFilter)
 266                 strunzone(me.stringFilter);
 267         if(box.text != "")
 268                 me.stringFilter = strzone(box.text);
 269         else
 270                 me.stringFilter = string_null;
 271
 272         me.refilter(me);
 273 }
 274
 275 void MapList_Add_Shown(entity btn, entity me)
 276 {
 277         float i, n;
 278         n = strlen(me.g_maplistCache);
 279         for (i = 0 ; i < n; i++)
 280         {
 281                 if (!me.g_maplistCacheQuery(me, i))
 282                         me.g_maplistCacheToggle(me, i);
 283         }
 284         me.refilter(me);
 285 }
 286
 287 void MapList_Remove_Shown(entity btn, entity me)
 288 {
 289         float i, n;
 290         n = strlen(me.g_maplistCache);
 291         for (i = 0 ; i < n; i++)
 292         {
 293                 if (me.g_maplistCacheQuery(me, i))
 294                         me.g_maplistCacheToggle(me, i);
 295         }
 296         me.refilter(me);
 297 }
 298
 299 void MapList_Add_All(entity btn, entity me)
 300 {
 301         float i;
 302         string s;
 303         MapInfo_FilterGametype(MAPINFO_TYPE_ALL, 0, 0, MapInfo_ForbiddenFlags(), 0); // all
 304         s = "";
 305         for(i = 0; i < MapInfo_count; ++i)
 306                 s = strcat(s, " ", MapInfo_BSPName_ByID(i));
 307         cvar_set("g_maplist", substring(s, 1, strlen(s) - 1));
 308         me.refilter(me);
 309 }
 310
 311 void MapList_Remove_All(entity btn, entity me)
 312 {
 313         cvar_set("g_maplist", "");
 314         me.refilter(me);
 315 }
 316
 317 void MapList_LoadMap(entity btn, entity me)
 318 {
 319         string m;
 320         float i;
 321
 322         i = me.selectedItem;
 323
 324         if(btn.parent.instanceOfXonoticMapInfoDialog)
 325         {
 326                 i = btn.parent.currentMapIndex;
 327                 Dialog_Close(btn, btn.parent);
 328         }
 329
 330         if(i >= me.nItems || i < 0)
 331                 return;
 332
 333         m = MapInfo_BSPName_ByID(i);
 334         if (!m)
 335         {
 336                 print(_("Huh? Can't play this (m is NULL). Refiltering so this won't happen again.\n"));
 337                 me.refilter(me);
 338                 return;
 339         }
 340         if(MapInfo_CheckMap(m))
 341         {
 342                 localcmd("\nmenu_loadmap_prepare\n");
 343                 if(cvar("menu_use_default_hostname"))
 344                         localcmd("hostname \"", sprintf(_("%s's Xonotic Server"), strdecolorize(cvar_string("_cl_name"))), "\"\n");
 345                 MapInfo_LoadMap(m, 1);
 346         }
 347         else
 348         {
 349                 print(_("Huh? Can't play this (invalid game type). Refiltering so this won't happen again.\n"));
 350                 me.refilter(me);
 351                 return;
 352         }
 353 }
 354
 355 float XonoticMapList_keyDown(entity me, float scan, float ascii, float shift)
 356 {
 357         string ch, save;
 358         if(me.nItems <= 0)
 359                 return SUPER(XonoticMapList).keyDown(me, scan, ascii, shift);
 360         if(scan == K_MOUSE2 || scan == K_SPACE || scan == K_ENTER || scan == K_KP_ENTER)
 361         {
 362                 // pop up map info screen
 363                 m_play_click_sound(MENU_SOUND_OPEN);
 364                 main.mapInfoDialog.loadMapInfo(main.mapInfoDialog, me.selectedItem, me);
 365                 DialogOpenButton_Click_withCoords(NULL, main.mapInfoDialog, me.origin + eX * (me.columnNameOrigin * me.size.x) + eY * ((me.itemHeight * me.selectedItem - me.scrollPos) * me.size.y), eY * me.itemAbsSize.y + eX * (me.itemAbsSize.x * me.columnNameSize));
 366         }
 367         else if(scan == K_MOUSE3 || scan == K_INS || scan == K_KP_INS)
 368         {
 369                 m_play_click_sound(MENU_SOUND_SELECT);
 370                 me.g_maplistCacheToggle(me, me.selectedItem);
 371         }
 372         else if(ascii == 43) // +
 373         {
 374                 if (!me.g_maplistCacheQuery(me, me.selectedItem))
 375                 {
 376                         m_play_click_sound(MENU_SOUND_SELECT);
 377                         me.g_maplistCacheToggle(me, me.selectedItem);
 378                 }
 379         }
 380         else if(ascii == 45) // -
 381         {
 382                 if(me.g_maplistCacheQuery(me, me.selectedItem))
 383                 {
 384                         m_play_click_sound(MENU_SOUND_SELECT);
 385                         me.g_maplistCacheToggle(me, me.selectedItem);
 386                 }
 387         }
 388         else if(scan == K_BACKSPACE)
 389         {
 390                 if(time < me.typeToSearchTime)
 391                 {
 392                         save = substring(me.typeToSearchString, 0, strlen(me.typeToSearchString) - 1);
 393                         if(me.typeToSearchString)
 394                                 strunzone(me.typeToSearchString);
 395                         me.typeToSearchString = strzone(save);
 396                         me.typeToSearchTime = time + 0.5;
 397                         if(strlen(me.typeToSearchString))
 398                         {
 399                                 MapInfo_FindName(me.typeToSearchString);
 400                                 if(MapInfo_FindName_firstResult >= 0)
 401                                         me.setSelected(me, MapInfo_FindName_firstResult);
 402                         }
 403                 }
 404         }
 405         else if(ascii >= 32 && ascii != 127)
 406         {
 407                 ch = chr(ascii);
 408                 if(time > me.typeToSearchTime)
 409                         save = ch;
 410                 else
 411                         save = strcat(me.typeToSearchString, ch);
 412                 if(me.typeToSearchString)
 413                         strunzone(me.typeToSearchString);
 414                 me.typeToSearchString = strzone(save);
 415                 me.typeToSearchTime = time + 0.5;
 416                 MapInfo_FindName(me.typeToSearchString);
 417                 if(MapInfo_FindName_firstResult >= 0)
 418                         me.setSelected(me, MapInfo_FindName_firstResult);
 419         }
 420         else if(shift & S_CTRL && scan == 'f') // ctrl-f (as in "F"ind)
 421         {
 422                 me.parent.setFocus(me.parent, me.stringFilterBox);
 423         }
 424         else if(shift & S_CTRL && scan == 'u') // ctrl-u (remove stringFilter line
 425         {
 426                 me.stringFilterBox.setText(me.stringFilterBox, "");
 427                 MapList_StringFilterBox_Change(me.stringFilterBox, me);
 428         }
 429         else
 430                 return SUPER(XonoticMapList).keyDown(me, scan, ascii, shift);
 431         return 1;
 432 }
 433
 434 float MapList_StringFilterBox_keyDown(entity me, float scan, float ascii, float shift)
 435 {
 436         // in this section, note that onChangeEntity has the ref to mapListBox
 437         // we make use of that, instead of extending a class to add one more attrib
 438         switch(scan)
 439         {
 440                 case K_KP_ENTER:
 441                 case K_ENTER:
 442                         // move the focus to the mapListBox
 443                         me.onChangeEntity.parent.setFocus(me.onChangeEntity.parent, me.onChangeEntity);
 444                         return 1;
 445                 case K_KP_UPARROW:
 446                 case K_UPARROW:
 447                 case K_KP_DOWNARROW:
 448                 case K_DOWNARROW:
 449                         // pass the event to the mapListBox (to scroll up and down)
 450                         return me.onChangeEntity.keyDown(me.onChangeEntity, scan, ascii, shift);
 451         }
 452         return SUPER(XonoticInputBox).keyDown(me, scan, ascii, shift);
 453 }
 454 #endif