qcsrc/menu/xonotic/radiobutton.qc

   1 #ifndef RADIOBUTTON_H
   2 #define RADIOBUTTON_H
   3 #include "../item/radiobutton.qc"
   4 CLASS(XonoticRadioButton, RadioButton)
   5         METHOD(XonoticRadioButton, configureXonoticRadioButton, void(entity, float, string, string, string, string));
   6         METHOD(XonoticRadioButton, draw, void(entity));
   7         METHOD(XonoticRadioButton, setChecked, void(entity, float));
   8         ATTRIB(XonoticRadioButton, fontSize, float, SKINFONTSIZE_NORMAL)
   9         ATTRIB(XonoticRadioButton, image, string, SKINGFX_RADIOBUTTON)
  10         ATTRIB(XonoticRadioButton, color, vector, SKINCOLOR_RADIOBUTTON_N)
  11         ATTRIB(XonoticRadioButton, colorC, vector, SKINCOLOR_RADIOBUTTON_C)
  12         ATTRIB(XonoticRadioButton, colorF, vector, SKINCOLOR_RADIOBUTTON_F)
  13         ATTRIB(XonoticRadioButton, colorD, vector, SKINCOLOR_RADIOBUTTON_D)
  14
  15         ATTRIB(XonoticRadioButton, cvarName, string, string_null)
  16         ATTRIB(XonoticRadioButton, cvarValue, string, string_null)
  17         ATTRIB(XonoticRadioButton, cvarOffValue, string, string_null)
  18         ATTRIB(XonoticRadioButton, cvarValueIsAnotherCvar, float, 0)
  19         METHOD(XonoticRadioButton, loadCvars, void(entity));
  20         METHOD(XonoticRadioButton, saveCvars, void(entity));
  21
  22         ATTRIB(XonoticRadioButton, alpha, float, SKINALPHA_TEXT)
  23         ATTRIB(XonoticRadioButton, disabledAlpha, float, SKINALPHA_DISABLED)
  24 ENDCLASS(XonoticRadioButton)
  25 entity makeXonoticRadioButton_T(float, string, string, string, string theTooltip);
  26 entity makeXonoticRadioButton(float, string, string, string);
  27 #endif
  28
  29 #ifdef IMPLEMENTATION
  30 entity makeXonoticRadioButton_T(float theGroup, string theCvar, string theValue, string theText, string theTooltip)
  31 {
  32         entity me;
  33         me = NEW(XonoticRadioButton);
  34         me.configureXonoticRadioButton(me, theGroup, theCvar, theValue, theText, theTooltip);
  35         return me;
  36 }
  37 entity makeXonoticRadioButton(float theGroup, string theCvar, string theValue, string theText)
  38 {
  39         return makeXonoticRadioButton_T(theGroup, theCvar, theValue, theText, string_null);
  40 }
  41 void XonoticRadioButton_configureXonoticRadioButton(entity me, float theGroup, string theCvar, string theValue, string theText, string theTooltip)
  42 {
  43         me.cvarName = (theCvar) ? theCvar : string_null;
  44         me.loadCvars(me);
  45         setZonedTooltip(me, theTooltip, theCvar);
  46         me.configureRadioButton(me, theText, me.fontSize, me.image, theGroup, 0);
  47 }
  48 void XonoticRadioButton_setChecked(entity me, float val)
  49 {
  50         if(val != me.checked)
  51         {
  52                 me.checked = val;
  53                 me.saveCvars(me);
  54         }
  55 }
  56 void XonoticRadioButton_loadCvars(entity me)
  57 {
  58         if(me.cvarValue)
  59         {
  60                 if(me.cvarName)
  61                 {
  62                         if(me.cvarValueIsAnotherCvar)
  63                                 me.checked = (cvar_string(me.cvarName) == cvar_string(me.cvarValue));
  64                         else
  65                                 me.checked = (cvar_string(me.cvarName) == me.cvarValue);
  66                 }
  67         }
  68         else
  69         {
  70                 if(me.cvarName)
  71                 {
  72                         me.checked = !!cvar(me.cvarName);
  73                 }
  74                 else
  75                 {
  76                         // this is difficult
  77                         // this is the "generic" selection... but at this time, not
  78                         // everything is constructed yet.
  79                         // we need to set this later in draw()
  80                         me.checked = 0;
  81                 }
  82         }
  83 }
  84 void XonoticRadioButton_draw(entity me)
  85 {
  86         if (!me.cvarValue)
  87                 if (!me.cvarName)
  88                 {
  89                         // this is the "other" option
  90                         // always select this if none other is
  91                         entity e;
  92                         float found;
  93                         found = 0;
  94                         for(e = me.parent.firstChild; e; e = e.nextSibling)
  95                                 if(e.group == me.group)
  96                                         if(e.checked)
  97                                                 found = 1;
  98                         if(!found)
  99                                 me.setChecked(me, 1);
 100                 }
 101         SUPER(XonoticRadioButton).draw(me);
 102 }
 103 void XonoticRadioButton_saveCvars(entity me)
 104 {
 105         if(me.cvarValue)
 106         {
 107                 if(me.cvarName)
 108                 {
 109                         if(me.checked)
 110                         {
 111                                 if(me.cvarValueIsAnotherCvar)
 112                                         cvar_set(me.cvarName, cvar_string(me.cvarValue));
 113                                 else
 114                                         cvar_set(me.cvarName, me.cvarValue);
 115                         }
 116                         else if(me.cvarOffValue)
 117                                 cvar_set(me.cvarName, me.cvarOffValue);
 118                 }
 119         }
 120         else
 121         {
 122                 if(me.cvarName)
 123                 {
 124                         cvar_set(me.cvarName, ftos(me.checked));
 125                 }
 126         }
 127 }
 128 #endif