qcsrc/menu/xonotic/screenshotlist.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticScreenshotList) EXTENDS(XonoticListBox)
   3         METHOD(XonoticScreenshotList, configureXonoticScreenshotList, void(entity))
   4         ATTRIB(XonoticScreenshotList, rowsPerItem, float, 1)
   5         METHOD(XonoticScreenshotList, resizeNotify, void(entity, vector, vector, vector, vector))
   6         METHOD(XonoticScreenshotList, drawListBoxItem, void(entity, float, vector, float))
   7         METHOD(XonoticScreenshotList, getScreenshots, void(entity))
   8         METHOD(XonoticScreenshotList, startScreenshot, void(entity))
   9         METHOD(XonoticScreenshotList, screenshotName, string(entity, float))
  10         METHOD(XonoticScreenshotList, clickListBoxItem, void(entity, float, vector))
  11         METHOD(XonoticScreenshotList, keyDown, float(entity, float, float, float))
  12         METHOD(XonoticScreenshotList, destroy, void(entity))
  13         METHOD(XonoticScreenshotList, showNotify, void(entity))
  14         ATTRIB(XonoticScreenshotList, listScreenshot, float, -1)
  15         ATTRIB(XonoticScreenshotList, realFontSize, vector, '0 0 0')
  16         ATTRIB(XonoticScreenshotList, columnNameOrigin, float, 0)
  17         ATTRIB(XonoticScreenshotList, columnNameSize, float, 0)
  18         ATTRIB(XonoticScreenshotList, realUpperMargin, float, 0)
  19         ATTRIB(XonoticScreenshotList, origin, vector, '0 0 0')
  20         ATTRIB(XonoticScreenshotList, itemAbsSize, vector, '0 0 0')
  21         ATTRIB(XonoticScreenshotList, lastClickedScreenshot, float, -1)
  22         ATTRIB(XonoticScreenshotList, lastClickedTime, float, 0)
  23         ATTRIB(XonoticScreenshotList, filterString, string, string_null)
  24         ATTRIB(XonoticScreenshotList, screenshotViewerDialog, entity, NULL)
  25         METHOD(XonoticScreenshotList, goScreenshot, void(entity, float))
  26 ENDCLASS(XonoticScreenshotList)
  27
  28 entity makeXonoticScreenshotList();
  29 void StartScreenshot_Click(entity btn, entity me);
  30 void ScreenshotList_Filter_Change(entity box, entity me);
  31 #endif
  32
  33 #ifdef IMPLEMENTATION
  34
  35 entity makeXonoticScreenshotList()
  36 {
  37         entity me;
  38         me = spawnXonoticScreenshotList();
  39         me.configureXonoticScreenshotList(me);
  40         return me;
  41 }
  42
  43 void XonoticScreenshotList_configureXonoticScreenshotList(entity me)
  44 {
  45         me.configureXonoticListBox(me);
  46         me.getScreenshots(me);
  47 }
  48
  49 string XonoticScreenshotList_screenshotName(entity me, float i )
  50 {
  51         string s;
  52         s = bufstr_get(me.listScreenshot, i);
  53         s = substring(s, 12, strlen(s) - 12 - 4);  // screenshots/, .<ext>
  54         return s;
  55 }
  56
  57 // if subdir is TRUE look in subdirectories too (1 level)
  58 void getScreenshots_for_ext(entity me, string ext, float subdir)
  59 {
  60         string s;
  61         if (subdir)
  62                 s="screenshots/*/";
  63         else
  64                 s="screenshots/";
  65         if(me.filterString)
  66                 s=strcat(s, me.filterString, ext);
  67         else
  68                 s=strcat(s, "*", ext);
  69
  70         float list, i, n;
  71         list = search_begin(s, FALSE, TRUE);
  72         if(list >= 0)
  73         {
  74                 n = search_getsize(list);
  75                 for(i = 0; i < n; ++i)
  76                         bufstr_add(me.listScreenshot, search_getfilename(list, i), TRUE);
  77                 search_end(list);
  78         }
  79
  80         if (subdir)
  81                 getScreenshots_for_ext(me, ext, FALSE);
  82 }
  83
  84 void XonoticScreenshotList_getScreenshots(entity me)
  85 {
  86         if (me.listScreenshot >= 0)
  87                 buf_del(me.listScreenshot);
  88         me.listScreenshot = buf_create();
  89         if (me.listScreenshot < 0)
  90         {
  91                 me.nItems = 0;
  92                 return;
  93         }
  94         getScreenshots_for_ext(me, ".jpg", TRUE);
  95         getScreenshots_for_ext(me, ".tga", TRUE);
  96         getScreenshots_for_ext(me, ".png", TRUE);
  97         me.nItems = buf_getsize(me.listScreenshot);
  98         buf_sort(me.listScreenshot, 128, FALSE);
  99 }
 100
 101 void XonoticScreenshotList_destroy(entity me)
 102 {
 103         buf_del(me.listScreenshot);
 104 }
 105
 106 void XonoticScreenshotList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 107 {
 108         me.itemAbsSize = '0 0 0';
 109         SUPER(XonoticScreenshotList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 110
 111         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize_y * me.itemHeight));
 112         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize_x * (1 - me.controlWidth)));
 113         me.realUpperMargin = 0.5 * (1 - me.realFontSize_y);
 114
 115         me.columnNameOrigin = me.realFontSize_x;
 116         me.columnNameSize = 1 - 2 * me.realFontSize_x;
 117 }
 118
 119 void XonoticScreenshotList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
 120 {
 121         string s;
 122         if(isSelected)
 123                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 124
 125         s = me.screenshotName(me,i);
 126         s = draw_TextShortenToWidth(s, me.columnNameSize, 0, me.realFontSize);
 127         draw_Text(me.realUpperMargin * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
 128 }
 129
 130 void XonoticScreenshotList_showNotify(entity me)
 131 {
 132         me.getScreenshots(me);
 133 }
 134
 135 void ScreenshotList_Filter_Change(entity box, entity me)
 136 {
 137         if(me.filterString)
 138                 strunzone(me.filterString);
 139
 140         if(box.text != "")
 141         {
 142                 if (strstrofs(box.text, "*", 0) >= 0 || strstrofs(box.text, "?", 0) >= 0)
 143                         me.filterString = strzone(box.text);
 144                 else
 145                         me.filterString = strzone(strcat("*", box.text, "*"));
 146         }
 147         else
 148                 me.filterString = string_null;
 149
 150         me.getScreenshots(me);
 151 }
 152
 153 void XonoticScreenshotList_goScreenshot(entity me, float d)
 154 {
 155         if(!me.screenshotViewerDialog)
 156                 return;
 157         me.setSelected(me, me.selectedItem + d);
 158         main.screenshotViewerDialog.loadScreenshot(main.screenshotViewerDialog, strcat("/screenshots/", me.screenshotName(me,me.selectedItem)));
 159 }
 160
 161 void XonoticScreenshotList_startScreenshot(entity me)
 162 {
 163         main.screenshotViewerDialog.loadScreenshot(main.screenshotViewerDialog, strcat("/screenshots/", me.screenshotName(me,me.selectedItem)));
 164         // pop up screenshot
 165         DialogOpenButton_Click_withCoords(NULL, main.screenshotViewerDialog, me.origin + eX * (me.columnNameOrigin * me.size_x) + eY * ((me.itemHeight * me.selectedItem - me.scrollPos) * me.size_y), eY * me.itemAbsSize_y + eX * (me.itemAbsSize_x * me.columnNameSize));
 166 }
 167
 168 void StartScreenshot_Click(entity btn, entity me)
 169 {
 170         me.startScreenshot(me);
 171 }
 172
 173 void XonoticScreenshotList_clickListBoxItem(entity me, float i, vector where)
 174 {
 175         if(i == me.lastClickedScreenshot)
 176                 if(time < me.lastClickedTime + 0.3)
 177                 {
 178                         // DOUBLE CLICK!
 179                         // pop up screenshot
 180                         me.setSelected(me, i);
 181                         me.startScreenshot(me);
 182                 }
 183         me.lastClickedScreenshot = i;
 184         me.lastClickedTime = time;
 185 }
 186
 187 float XonoticScreenshotList_keyDown(entity me, float scan, float ascii, float shift)
 188 {
 189         if(scan == K_ENTER || scan == K_KP_ENTER) {
 190                 me.startScreenshot(me);
 191                 return 1;
 192         }
 193         else
 194                 return SUPER(XonoticScreenshotList).keyDown(me, scan, ascii, shift);
 195 }
 196 #endif