qcsrc/menu/xonotic/screenshotlist.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticScreenshotList) EXTENDS(XonoticListBox)
   3         METHOD(XonoticScreenshotList, configureXonoticScreenshotList, void(entity))
   4         ATTRIB(XonoticScreenshotList, rowsPerItem, float, 1)
   5         METHOD(XonoticScreenshotList, resizeNotify, void(entity, vector, vector, vector, vector))
   6         METHOD(XonoticScreenshotList, setSelected, void(entity, float))
   7         METHOD(XonoticScreenshotList, draw, void(entity))
   8         METHOD(XonoticScreenshotList, drawListBoxItem, void(entity, float, vector, float))
   9         METHOD(XonoticScreenshotList, getScreenshots, void(entity))
  10         METHOD(XonoticScreenshotList, previewScreenshot, void(entity))
  11         METHOD(XonoticScreenshotList, startScreenshot, void(entity))
  12         METHOD(XonoticScreenshotList, screenshotName, string(entity, float))
  13         METHOD(XonoticScreenshotList, clickListBoxItem, void(entity, float, vector))
  14         METHOD(XonoticScreenshotList, keyDown, float(entity, float, float, float))
  15         METHOD(XonoticScreenshotList, destroy, void(entity))
  16         METHOD(XonoticScreenshotList, showNotify, void(entity))
  17         ATTRIB(XonoticScreenshotList, listScreenshot, float, -1)
  18         ATTRIB(XonoticScreenshotList, realFontSize, vector, '0 0 0')
  19         ATTRIB(XonoticScreenshotList, columnNameOrigin, float, 0)
  20         ATTRIB(XonoticScreenshotList, columnNameSize, float, 0)
  21         ATTRIB(XonoticScreenshotList, realUpperMargin, float, 0)
  22         ATTRIB(XonoticScreenshotList, origin, vector, '0 0 0')
  23         ATTRIB(XonoticScreenshotList, itemAbsSize, vector, '0 0 0')
  24         ATTRIB(XonoticScreenshotList, lastClickedScreenshot, float, -1)
  25         ATTRIB(XonoticScreenshotList, lastClickedTime, float, 0)
  26         ATTRIB(XonoticScreenshotList, filterString, string, string_null)
  27         ATTRIB(XonoticScreenshotList, filterBox, entity, NULL)
  28         ATTRIB(XonoticScreenshotList, filterTime, float, 0)
  29
  30         ATTRIB(XonoticScreenshotList, newScreenshotTime, float, 0)
  31         ATTRIB(XonoticScreenshotList, newSlideShowScreenshotTime, float, 0)
  32         ATTRIB(XonoticScreenshotList, prevSelectedItem, float, 0)
  33
  34         ATTRIB(XonoticScreenshotList, screenshotBrowserDialog, entity, NULL)
  35         ATTRIB(XonoticScreenshotList, screenshotPreview, entity, NULL)
  36         ATTRIB(XonoticScreenshotList, screenshotViewerDialog, entity, NULL)
  37         METHOD(XonoticScreenshotList, goScreenshot, void(entity, float))
  38         METHOD(XonoticScreenshotList, startSlideShow, void(entity))
  39         METHOD(XonoticScreenshotList, stopSlideShow, void(entity))
  40 ENDCLASS(XonoticScreenshotList)
  41
  42 entity makeXonoticScreenshotList();
  43 void StartScreenshot_Click(entity btn, entity me);
  44 void ScreenshotList_Refresh_Click(entity btn, entity me);
  45 void ScreenshotList_Filter_Would_Change(entity box, entity me);
  46 void ScreenshotList_Filter_Change(entity box, entity me);
  47 #endif
  48
  49 #ifdef IMPLEMENTATION
  50
  51 entity makeXonoticScreenshotList()
  52 {
  53         entity me;
  54         me = spawnXonoticScreenshotList();
  55         me.configureXonoticScreenshotList(me);
  56         return me;
  57 }
  58
  59 void XonoticScreenshotList_configureXonoticScreenshotList(entity me)
  60 {
  61         me.configureXonoticListBox(me);
  62         me.getScreenshots(me);
  63 }
  64
  65 string XonoticScreenshotList_screenshotName(entity me, float i )
  66 {
  67         string s;
  68         s = bufstr_get(me.listScreenshot, i);
  69         s = substring(s, 12, strlen(s) - 12 - 4);  // screenshots/, .<ext>
  70         return s;
  71 }
  72
  73 // if subdir is TRUE look in subdirectories too (1 level)
  74 void getScreenshots_for_ext(entity me, string ext, float subdir)
  75 {
  76         string s;
  77         if (subdir)
  78                 s="screenshots/*/";
  79         else
  80                 s="screenshots/";
  81         if(me.filterString)
  82                 s=strcat(s, me.filterString, ext);
  83         else
  84                 s=strcat(s, "*", ext);
  85
  86         float list, i, n;
  87         list = search_begin(s, FALSE, TRUE);
  88         if(list >= 0)
  89         {
  90                 n = search_getsize(list);
  91                 for(i = 0; i < n; ++i)
  92                         bufstr_add(me.listScreenshot, search_getfilename(list, i), TRUE);
  93                 search_end(list);
  94         }
  95
  96         if (subdir)
  97                 getScreenshots_for_ext(me, ext, FALSE);
  98 }
  99
 100 void XonoticScreenshotList_getScreenshots(entity me)
 101 {
 102         if (me.listScreenshot >= 0)
 103                 buf_del(me.listScreenshot);
 104         me.listScreenshot = buf_create();
 105         if (me.listScreenshot < 0)
 106         {
 107                 me.nItems = 0;
 108                 return;
 109         }
 110         getScreenshots_for_ext(me, ".jpg", TRUE);
 111         getScreenshots_for_ext(me, ".tga", TRUE);
 112         getScreenshots_for_ext(me, ".png", TRUE);
 113         me.nItems = buf_getsize(me.listScreenshot);
 114         if(me.nItems > 0)
 115                 buf_sort(me.listScreenshot, 128, FALSE);
 116 }
 117
 118 void XonoticScreenshotList_destroy(entity me)
 119 {
 120         if(me.nItems > 0)
 121                 buf_del(me.listScreenshot);
 122 }
 123
 124 void XonoticScreenshotList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 125 {
 126         me.itemAbsSize = '0 0 0';
 127         SUPER(XonoticScreenshotList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 128
 129         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize_y * me.itemHeight));
 130         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize_x * (1 - me.controlWidth)));
 131         me.realUpperMargin = 0.5 * (1 - me.realFontSize_y);
 132
 133         me.columnNameOrigin = me.realFontSize_x;
 134         me.columnNameSize = 1 - 2 * me.realFontSize_x;
 135 }
 136
 137 void XonoticScreenshotList_setSelected(entity me, float i)
 138 {
 139         if (me.newSlideShowScreenshotTime)
 140                 me.startSlideShow(me);
 141         me.prevSelectedItem = me.selectedItem;
 142         SUPER(XonoticScreenshotList).setSelected(me, i);
 143         if (me.pressed && me.selectedItem != me.prevSelectedItem)
 144         {
 145                 // while dragging the scrollbar (or an item)
 146                 // for a smooth mouse movement do not load immediately the new selected images
 147                 me.newScreenshotTime = time + 0.22; // dragging an item we need a delay > 0.2 (from listbox: me.dragScrollTimer = time + 0.2;)
 148         }
 149         else if (time > me.newScreenshotTime)
 150         {
 151                 me.newScreenshotTime = 0;
 152                 me.previewScreenshot(me); // load the preview on selection change
 153         }
 154 }
 155
 156 void XonoticScreenshotList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
 157 {
 158         string s;
 159         if(isSelected)
 160                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 161
 162         s = me.screenshotName(me,i);
 163         s = draw_TextShortenToWidth(s, me.columnNameSize, 0, me.realFontSize);
 164         draw_Text(me.realUpperMargin * eY + (me.columnNameOrigin + 0.00 * (me.columnNameSize - draw_TextWidth(s, 0, me.realFontSize))) * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
 165 }
 166
 167 void XonoticScreenshotList_showNotify(entity me)
 168 {
 169         me.getScreenshots(me);
 170         me.previewScreenshot(me);
 171 }
 172
 173 void ScreenshotList_Refresh_Click(entity btn, entity me)
 174 {
 175         me.getScreenshots(me);
 176         me.setSelected(me, 0); //always select the first element after a list update
 177 }
 178
 179 void ScreenshotList_Filter_Change(entity box, entity me)
 180 {
 181         if(me.filterString)
 182                 strunzone(me.filterString);
 183
 184         if(box.text != "")
 185         {
 186                 if (strstrofs(box.text, "*", 0) >= 0 || strstrofs(box.text, "?", 0) >= 0)
 187                         me.filterString = strzone(box.text);
 188                 else
 189                         me.filterString = strzone(strcat("*", box.text, "*"));
 190         }
 191         else
 192                 me.filterString = string_null;
 193
 194         ScreenshotList_Refresh_Click(world, me);
 195 }
 196
 197 void ScreenshotList_Filter_Would_Change(entity box, entity me)
 198 {
 199         me.filterBox = box;
 200         me.filterTime = time + 0.5;
 201 }
 202
 203 void XonoticScreenshotList_draw(entity me)
 204 {
 205         if (me.filterTime && time > me.filterTime)
 206         {
 207                 ScreenshotList_Filter_Change(me.filterBox, me);
 208                 me.filterTime = 0;
 209         }
 210         if (me.newScreenshotTime && time > me.newScreenshotTime)
 211         {
 212                 me.previewScreenshot(me);
 213                 me.newScreenshotTime = 0;
 214         }
 215         else if (me.newSlideShowScreenshotTime && time > me.newSlideShowScreenshotTime)
 216         {
 217                 if (me.selectedItem == me.nItems - 1) //last screenshot?
 218                 {
 219                         // restart from the first screenshot
 220                         me.setSelected(me, 0);
 221                         me.goScreenshot(me, +0);
 222                 }
 223                 else
 224                         me.goScreenshot(me, +1);
 225         }
 226         SUPER(XonoticScreenshotList).draw(me);
 227 }
 228
 229 void XonoticScreenshotList_startSlideShow(entity me)
 230 {
 231         me.newSlideShowScreenshotTime = time + 3;
 232 }
 233
 234 void XonoticScreenshotList_stopSlideShow(entity me)
 235 {
 236         me.newSlideShowScreenshotTime = 0;
 237 }
 238
 239 void XonoticScreenshotList_goScreenshot(entity me, float d)
 240 {
 241         if(!me.screenshotViewerDialog)
 242                 return;
 243         me.setSelected(me, me.selectedItem + d);
 244         me.screenshotViewerDialog.loadScreenshot(me.screenshotViewerDialog, strcat("/screenshots/", me.screenshotName(me,me.selectedItem)));
 245 }
 246
 247 void XonoticScreenshotList_startScreenshot(entity me)
 248 {
 249         me.screenshotViewerDialog.loadScreenshot(me.screenshotViewerDialog, strcat("/screenshots/", me.screenshotName(me,me.selectedItem)));
 250         // pop up screenshot
 251         DialogOpenButton_Click_withCoords(NULL, me.screenshotViewerDialog, me.origin + eX * (me.columnNameOrigin * me.size_x) + eY * ((me.itemHeight * me.selectedItem - me.scrollPos) * me.size_y), eY * me.itemAbsSize_y + eX * (me.itemAbsSize_x * me.columnNameSize));
 252 }
 253
 254 void XonoticScreenshotList_previewScreenshot(entity me)
 255 {
 256         if(!me.screenshotBrowserDialog)
 257                 return;
 258         if (me.nItems <= 0)
 259                 me.screenshotBrowserDialog.loadPreviewScreenshot(me.screenshotBrowserDialog, "");
 260         else
 261                 me.screenshotBrowserDialog.loadPreviewScreenshot(me.screenshotBrowserDialog, strcat("/screenshots/", me.screenshotName(me,me.selectedItem)));
 262 }
 263
 264 void StartScreenshot_Click(entity btn, entity me)
 265 {
 266         me.startScreenshot(me);
 267 }
 268
 269 void XonoticScreenshotList_clickListBoxItem(entity me, float i, vector where)
 270 {
 271         if(i == me.lastClickedScreenshot)
 272                 if(time < me.lastClickedTime + 0.3)
 273                 {
 274                         // DOUBLE CLICK!
 275                         // pop up screenshot
 276                         me.setSelected(me, i);
 277                         me.startScreenshot(me);
 278                 }
 279         me.lastClickedScreenshot = i;
 280         me.lastClickedTime = time;
 281 }
 282
 283 float XonoticScreenshotList_keyDown(entity me, float scan, float ascii, float shift)
 284 {
 285         if(scan == K_ENTER || scan == K_KP_ENTER) {
 286                 me.startScreenshot(me);
 287                 return 1;
 288         }
 289         if(scan == K_MWHEELUP || scan == K_MWHEELDOWN)
 290                 me.newScreenshotTime = time + 0.2;
 291         return SUPER(XonoticScreenshotList).keyDown(me, scan, ascii, shift);
 292 }
 293 #endif