qcsrc/menu/xonotic/serverlist.qc

   1 #include "serverlist.qh"
   2
   3 #include "checkbox.qh"
   4 #include "inputbox.qh"
   5 #include "mainwindow.qh"
   6 #include "dialog_multiplayer_join_serverinfo.qh"
   7 #include <common/mapinfo.qh>
   8
   9 void SL_ProcessCategoryOverrides(.string override_field_string, .float override_field)
  10 {
  11         for (int i = 0; i < category_ent_count; ++i)
  12         {
  13                 string s = categories[i].override_field_string;
  14                 if (s != "" && s != categories[i].cat_name)
  15                 {
  16                         int catnum = 0;
  17                         for (int x = 0; x < category_ent_count; ++x)
  18                         {
  19                                 if(categories[x].cat_name == s)
  20                                 {
  21                                         catnum = x + 1;
  22                                         break;
  23                                 }
  24                         }
  25                         if (catnum)
  26                         {
  27                                 strfree(categories[i].override_field_string);
  28                                 categories[i].override_field = catnum;
  29                                 continue;
  30                         }
  31                         LOG_INFOF("RegisterSLCategories(): Improper override '%s' for category '%s'!", s, categories[i].cat_name);
  32                 }
  33                 strfree(categories[i].override_field_string);
  34                 categories[i].override_field = 0;
  35         }
  36 }
  37
  38 void RegisterSLCategories()
  39 {
  40         entity cat;
  41         #define SLIST_CATEGORY(name,enoverride,dioverride,str) \
  42                 SET_FIELD_COUNT(name, CATEGORY_FIRST, category_ent_count) \
  43                 CHECK_MAX_COUNT(name, MAX_CATEGORIES, category_ent_count, "SLIST_CATEGORY") \
  44                 cat = categories[name - 1] = new(slist_category); \
  45                 cat.cat_name = #name; \
  46                 cat.cat_enoverride_string = strzone(SLIST_CATEGORY_AUTOCVAR(name)); \
  47                 cat.cat_dioverride_string = strzone(dioverride); \
  48                 cat.cat_string = strzone(str);
  49         SLIST_CATEGORIES
  50         #undef SLIST_CATEGORY
  51
  52         SL_ProcessCategoryOverrides(cat_enoverride_string, cat_enoverride);
  53         SL_ProcessCategoryOverrides(cat_dioverride_string, cat_dioverride);
  54 }
  55
  56 // Supporting Functions
  57 entity RetrieveCategoryEnt(int catnum)
  58 {
  59         if((catnum > 0) && (catnum <= category_ent_count))
  60         {
  61                 return categories[catnum - 1];
  62         }
  63         else
  64         {
  65                 error(sprintf("RetrieveCategoryEnt(%d): Improper category number!\n", catnum));
  66                 return NULL;
  67         }
  68 }
  69
  70 bool IsServerInList(string list, string srv)
  71 {
  72         if(srv == "")
  73                 return false;
  74         srv = netaddress_resolve(srv, 26000);
  75         if(srv == "")
  76                 return false;
  77         string p = crypto_getidfp(srv);
  78         int n = tokenize_console(list);
  79         for(int i = 0; i < n; ++i)
  80         {
  81                 if(substring(argv(i), 0, 1) != "[" && strlen(argv(i)) == 44 && strstrofs(argv(i), ".", 0) < 0)
  82                 {
  83                         if(p && argv(i) == p)
  84                                 return true;
  85                 }
  86                 else
  87                 {
  88                         if(srv == netaddress_resolve(argv(i), 26000))
  89                                 return true;
  90                 }
  91         }
  92         return false;
  93 }
  94
  95 int CategoryOverride(int cat)
  96 {
  97         entity catent = RetrieveCategoryEnt(cat);
  98         if(catent)
  99         {
 100                 int override = (autocvar_menu_slist_categories ? catent.cat_enoverride : catent.cat_dioverride);
 101                 if(override) { return override; }
 102                 else { return cat; }
 103         }
 104         else
 105         {
 106                 error(sprintf("CategoryOverride(%d): Improper category number!\n", cat));
 107                 return cat;
 108         }
 109 }
 110
 111 int CategoryForEntry(int entry)
 112 {
 113         string s, k, v, modtype = "";
 114         int j, m, impure = 0, freeslots = 0, sflags = 0;
 115         s = gethostcachestring(SLIST_FIELD_QCSTATUS, entry);
 116         m = tokenizebyseparator(s, ":");
 117
 118         for(j = 2; j < m; ++j)
 119         {
 120                 if(argv(j) == "") { break; }
 121                 k = substring(argv(j), 0, 1);
 122                 v = substring(argv(j), 1, -1);
 123                 switch(k)
 124                 {
 125                         case "P": { impure = stof(v); break; }
 126                         case "S": { freeslots = stof(v); break; }
 127                         case "F": { sflags = stof(v); break; }
 128                         case "M": { modtype = strtolower(v); break; }
 129                 }
 130         }
 131
 132         if(modtype != "xonotic") { impure += autocvar_menu_slist_modimpurity; }
 133
 134         // check if this server is favorited
 135         if(gethostcachenumber(SLIST_FIELD_ISFAVORITE, entry)) { return CAT_FAVORITED; }
 136
 137         // now check if it's recommended
 138         if(autocvar_menu_slist_recommendations)
 139         {
 140                 string cname = gethostcachestring(SLIST_FIELD_CNAME, entry);
 141
 142                 if(IsPromoted(cname)) { return CAT_RECOMMENDED; }
 143                 else
 144                 {
 145                         float recommended = 0;
 146                         if(autocvar_menu_slist_recommendations & 1)
 147                         {
 148                                 if(IsRecommended(cname)) { ++recommended; }
 149                                 else { --recommended; }
 150                         }
 151                         if(autocvar_menu_slist_recommendations & 2)
 152                         {
 153                                 if(
 154                                         ///// check for minimum free slots
 155                                         (freeslots >= autocvar_menu_slist_recommendations_minfreeslots)
 156
 157                                         && // check for purity requirement
 158                                         (
 159                                                 (autocvar_menu_slist_recommendations_purethreshold < 0)
 160                                                 ||
 161                                                 (impure <= autocvar_menu_slist_recommendations_purethreshold)
 162                                         )
 163
 164                                         && // check for minimum amount of humans
 165                                         (
 166                                                 gethostcachenumber(SLIST_FIELD_NUMHUMANS, entry)
 167                                                 >=
 168                                                 autocvar_menu_slist_recommendations_minhumans
 169                                         )
 170
 171                                         && // check for maximum latency
 172                                         (
 173                                                 gethostcachenumber(SLIST_FIELD_PING, entry)
 174                                                 <=
 175                                                 autocvar_menu_slist_recommendations_maxping
 176                                         )
 177                                 )
 178                                         { ++recommended; }
 179                                 else
 180                                         { --recommended; }
 181                         }
 182                         if(recommended > 0) { return CAT_RECOMMENDED; }
 183                 }
 184         }
 185
 186         // if not favorited or recommended, check modname
 187         if(modtype != "xonotic")
 188         {
 189                 switch(modtype)
 190                 {
 191                         // old servers which don't report their mod name are considered modified now
 192                         case "": { return CAT_MODIFIED; }
 193
 194                         case "xpm": { return CAT_XPM; }
 195                         case "minstagib":
 196                         case "instagib": { return CAT_INSTAGIB; }
 197                         case "overkill": { return CAT_OVERKILL; }
 198
 199                         // "cts" is allowed as compat, xdf is replacement
 200                         case "cts":
 201                         case "xdf": { return CAT_DEFRAG; }
 202
 203                         default: { LOG_TRACEF("Found strange mod type: %s", modtype); return CAT_MODIFIED; }
 204                 }
 205         }
 206
 207         // must be normal or impure server
 208         return ((impure > autocvar_menu_slist_purethreshold) ? CAT_MODIFIED : CAT_NORMAL);
 209 }
 210
 211 METHOD(XonoticServerList, toggleFavorite, void(XonoticServerList this, string srv))
 212 {
 213         bool adding = true;
 214         string srv_resolved = netaddress_resolve(srv, 26000);
 215         string p = crypto_getidfp(srv_resolved);
 216         string s = cvar_string("net_slist_favorites");
 217         string ret = s;
 218         for (int i = 0, n = tokenize_console(s); i < n; ++i)
 219         {
 220                 bool match;
 221                 if (substring(argv(i), 0, 1) != "[" && strlen(argv(i)) == 44 && strstrofs(argv(i), ".", 0) < 0)
 222                 {
 223                         // it's a pubkey hash
 224                         match = (p && p == argv(i));
 225                 }
 226                 else
 227                 {
 228                         // it's an ip
 229                         match = (srv_resolved == netaddress_resolve(argv(i), 26000));
 230                 }
 231                 if (!match) continue;
 232                 // on match: remove
 233                 adding = false;
 234                 string before = (i > 0) ? substring(s, 0, argv_end_index(i - 1)) : "";
 235                 string after = (i < n - 1) ? substring(s, argv_start_index(i + 1), -1) : "";
 236                 s = strcat(before, (before != "" && after != "" ? " " : ""), after);
 237                 ret = s;
 238                 // keep searching
 239                 // TODO: why not break here?
 240                 n = tokenize_console(s);
 241                 --i; // offset the increment that is about to happen
 242         }
 243         if (adding)
 244         {
 245                 ret = strcat(s, (s != "" ? " " : ""), p ? p : srv);
 246         }
 247         cvar_set("net_slist_favorites", ret);
 248         this.refreshServerList(this, REFRESHSERVERLIST_RESORT);
 249 }
 250
 251 void ServerList_Update_favoriteButton(entity btn, entity me)
 252 {
 253         entity e = me.favoriteButton;
 254         if(IsFavorite(me.ipAddressBox.text))
 255         {
 256                 e.setText(e, _("Remove favorite"));
 257                 setZonedTooltip(e, _("Remove the currently highlighted server from bookmarks"), string_null);
 258         }
 259         else
 260         {
 261                 e.setText(e, _("Favorite"));
 262                 setZonedTooltip(e, _("Bookmark the currently highlighted server so that it's faster to find in the future"), string_null);
 263         }
 264 }
 265
 266 entity makeXonoticServerList()
 267 {
 268         entity me;
 269         me = NEW(XonoticServerList);
 270         me.configureXonoticServerList(me);
 271         return me;
 272 }
 273 void XonoticServerList_configureXonoticServerList(entity me)
 274 {
 275         me.configureXonoticListBox(me);
 276
 277         // update field ID's
 278         #define SLIST_FIELD(suffix,name) SLIST_FIELD_##suffix = gethostcacheindexforkey(name);
 279         SLIST_FIELDS
 280         #undef SLIST_FIELD
 281
 282         // clear list
 283         me.nItems = 0;
 284 }
 285 void XonoticServerList_setSelected(entity me, int i)
 286 {
 287         me.lockedSelectedItem = false;
 288         //int save = me.selectedItem;
 289         SUPER(XonoticServerList).setSelected(me, i);
 290         /*
 291         if(me.selectedItem == save)
 292                 return;
 293         */
 294         if(me.nItems == 0)
 295                 return;
 296         if(gethostcachevalue(SLIST_HOSTCACHEVIEWCOUNT) != me.nItems)
 297                 return; // sorry, it would be wrong
 298
 299         strcpy(me.selectedServer, gethostcachestring(SLIST_FIELD_CNAME, me.selectedItem));
 300
 301         me.ipAddressBox.setText(me.ipAddressBox, me.selectedServer);
 302         me.ipAddressBox.cursorPos = strlen(me.selectedServer);
 303         me.ipAddressBoxFocused = -1;
 304 }
 305 void XonoticServerList_refreshServerList(entity me, int mode)
 306 {
 307         //print("refresh of type ", ftos(mode), "\n");
 308
 309         if(mode >= REFRESHSERVERLIST_REFILTER)
 310         {
 311                 string s = me.filterString;
 312
 313                 string typestr;
 314                 int m = strstrofs(s, ":", 0);
 315                 if(m >= 0)
 316                 {
 317                         typestr = substring(s, 0, m);
 318                         s = substring(s, m + 1, strlen(s) - m - 1);
 319                         while(substring(s, 0, 1) == " ")
 320                                 s = substring(s, 1, strlen(s) - 1);
 321                 }
 322                 else
 323                         typestr = "";
 324
 325                 string modstr = cvar_string("menu_slist_modfilter");
 326
 327                 m = SLIST_MASK_AND - 1;
 328                 resethostcachemasks();
 329
 330                 // ping: reject negative ping (no idea why this happens in the first place, engine bug)
 331                 sethostcachemasknumber(++m, SLIST_FIELD_PING, 0, SLIST_TEST_GREATEREQUAL);
 332
 333                 // show full button
 334                 if(!me.filterShowFull)
 335                 {
 336                         sethostcachemasknumber(++m, SLIST_FIELD_FREESLOTS, 1, SLIST_TEST_GREATEREQUAL); // legacy
 337                         sethostcachemaskstring(++m, SLIST_FIELD_QCSTATUS, ":S0:", SLIST_TEST_NOTCONTAIN); // g_maxplayers support
 338                 }
 339
 340                 // show empty button
 341                 if(!me.filterShowEmpty)
 342                         sethostcachemasknumber(++m, SLIST_FIELD_NUMHUMANS, 1, SLIST_TEST_GREATEREQUAL);
 343
 344                 // gametype filtering
 345                 if(typestr != "")
 346                         sethostcachemaskstring(++m, SLIST_FIELD_QCSTATUS, strcat(typestr, ":"), SLIST_TEST_STARTSWITH);
 347
 348                 // mod filtering
 349                 if(modstr != "")
 350                 {
 351                         if(substring(modstr, 0, 1) == "!")
 352                                 sethostcachemaskstring(++m, SLIST_FIELD_MOD, resolvemod(substring(modstr, 1, strlen(modstr) - 1)), SLIST_TEST_NOTEQUAL);
 353                         else
 354                                 sethostcachemaskstring(++m, SLIST_FIELD_MOD, resolvemod(modstr), SLIST_TEST_EQUAL);
 355                 }
 356
 357                 // server banning
 358                 int n = tokenizebyseparator(_Nex_ExtResponseSystem_BannedServers, " ");
 359                 for(int i = 0; i < n; ++i)
 360                         if(argv(i) != "")
 361                                 sethostcachemaskstring(++m, SLIST_FIELD_CNAME, argv(i), SLIST_TEST_NOTSTARTSWITH);
 362
 363                 m = SLIST_MASK_OR - 1;
 364                 if(s != "")
 365                 {
 366                         sethostcachemaskstring(++m, SLIST_FIELD_NAME, s, SLIST_TEST_CONTAINS);
 367                         sethostcachemaskstring(++m, SLIST_FIELD_MAP, s, SLIST_TEST_CONTAINS);
 368                         sethostcachemaskstring(++m, SLIST_FIELD_PLAYERS, s, SLIST_TEST_CONTAINS);
 369                         sethostcachemaskstring(++m, SLIST_FIELD_QCSTATUS, strcat(s, ":"), SLIST_TEST_STARTSWITH);
 370                 }
 371
 372                 int sorting_flags = 0;
 373                 //sorting_flags |= SLSF_FAVORITES;
 374                 sorting_flags |= SLSF_CATEGORIES;
 375                 if(me.currentSortOrder < 0) { sorting_flags |= SLSF_DESCENDING; }
 376                 sethostcachesort(me.currentSortField, sorting_flags);
 377         }
 378
 379         resorthostcache();
 380         if(mode >= REFRESHSERVERLIST_ASK)
 381                 refreshhostcache(mode >= REFRESHSERVERLIST_RESET);
 382 }
 383 void XonoticServerList_focusEnter(entity me)
 384 {
 385         SUPER(XonoticServerList).focusEnter(me);
 386         if(time < me.nextRefreshTime)
 387         {
 388                 //print("sorry, no refresh yet\n");
 389                 return;
 390         }
 391         me.nextRefreshTime = time + 10;
 392         me.refreshServerList(me, REFRESHSERVERLIST_ASK);
 393 }
 394
 395 void XonoticServerList_draw(entity me)
 396 {
 397         int i;
 398         bool found = false, owned;
 399
 400         if(_Nex_ExtResponseSystem_BannedServersNeedsRefresh)
 401         {
 402                 if(!me.needsRefresh)
 403                         me.needsRefresh = 2;
 404                 _Nex_ExtResponseSystem_BannedServersNeedsRefresh = 0;
 405         }
 406
 407         if(_Nex_ExtResponseSystem_PromotedServersNeedsRefresh)
 408         {
 409                 if(!me.needsRefresh)
 410                         me.needsRefresh = 3;
 411                 _Nex_ExtResponseSystem_PromotedServersNeedsRefresh = 0;
 412         }
 413
 414         if(_Nex_ExtResponseSystem_RecommendedServersNeedsRefresh)
 415         {
 416                 if(!me.needsRefresh)
 417                         me.needsRefresh = 3;
 418                 _Nex_ExtResponseSystem_RecommendedServersNeedsRefresh = 0;
 419         }
 420
 421         if(me.currentSortField == -1)
 422         {
 423                 me.setSortOrder(me, SLIST_FIELD_PING, +1);
 424                 me.refreshServerList(me, REFRESHSERVERLIST_RESET);
 425         }
 426         else if(me.needsRefresh == 1)
 427         {
 428                 me.needsRefresh = 2; // delay by one frame to make sure "slist" has been executed
 429         }
 430         else if(me.needsRefresh == 2)
 431         {
 432                 me.needsRefresh = 0;
 433                 me.refreshServerList(me, REFRESHSERVERLIST_REFILTER);
 434         }
 435         else if(me.needsRefresh == 3)
 436         {
 437                 me.needsRefresh = 0;
 438                 me.refreshServerList(me, REFRESHSERVERLIST_RESORT);
 439         }
 440
 441         owned = ((me.selectedServer == me.ipAddressBox.text) && (me.ipAddressBox.text != ""));
 442
 443         for(i = 0; i < category_draw_count; ++i) { category_name[i] = -1; category_item[i] = -1; }
 444         category_draw_count = 0;
 445
 446         if(autocvar_menu_slist_categories >= 0) // if less than 0, don't even draw a category heading for favorites
 447         {
 448                 float itemcount = gethostcachevalue(SLIST_HOSTCACHEVIEWCOUNT);
 449                 me.nItems = itemcount;
 450
 451                 //float visible = floor(me.scrollPos / me.itemHeight);
 452                 // ^ unfortunately no such optimization can be made-- we must process through the
 453                 // entire list, otherwise there is no way to know which item is first in its category.
 454
 455                 // binary search method suggested by div
 456                 float begin = 0;
 457                 for(int j = 1; j <= category_ent_count; ++j) {
 458                         float first = begin;
 459                         float last = (itemcount - 1);
 460                         if (first > last) {
 461                                 // List is empty.
 462                                 break;
 463                         }
 464                         float catf = gethostcachenumber(SLIST_FIELD_CATEGORY, first);
 465                         float catl = gethostcachenumber(SLIST_FIELD_CATEGORY, last);
 466                         if (catf > j) {
 467                                 // The first one is already > j.
 468                                 // Therefore, category j does not exist.
 469                                 // Higher numbered categories do exist though.
 470                         } else if (catl < j) {
 471                                 // The last one is < j.
 472                                 // Thus this category - and any following -
 473                                 // don't exist.
 474                                 break;
 475                         } else if (catf == j) {
 476                                 // Starts at first. This breaks the loop
 477                                 // invariant in the binary search and thus has
 478                                 // to be handled separately.
 479                                 if(gethostcachenumber(SLIST_FIELD_CATEGORY, first) != j)
 480                                         error("Category mismatch I");
 481                                 if(first > 0)
 482                                         if(gethostcachenumber(SLIST_FIELD_CATEGORY, first - 1) == j)
 483                                                 error("Category mismatch II");
 484                                 category_name[category_draw_count] = j;
 485                                 category_item[category_draw_count] = first;
 486                                 ++category_draw_count;
 487                                 begin = first + 1;
 488                         } else {
 489                                 // At this point, catf <= j < catl, thus
 490                                 // catf < catl, thus first < last.
 491                                 // INVARIANTS:
 492                                 // last - first >= 1
 493                                 // catf == gethostcachenumber(SLIST_FIELD_CATEGORY(first)
 494                                 // catl == gethostcachenumber(SLIST_FIELD_CATEGORY(last)
 495                                 // catf < j
 496                                 // catl >= j
 497                                 while (last - first > 1) {
 498                                         float middle = floor((first + last) / 2);
 499                                         // By loop condition, middle != first && middle != last.
 500                                         float cat = gethostcachenumber(SLIST_FIELD_CATEGORY, middle);
 501                                         if (cat >= j) {
 502                                                 last = middle;
 503                                                 catl = cat;
 504                                         } else {
 505                                                 first = middle;
 506                                                 catf = cat;
 507                                         }
 508                                 }
 509                                 if (catl == j) {
 510                                         if(gethostcachenumber(SLIST_FIELD_CATEGORY, last) != j)
 511                                                 error("Category mismatch III");
 512                                         if(last > 0)
 513                                                 if(gethostcachenumber(SLIST_FIELD_CATEGORY, last - 1) == j)
 514                                                         error("Category mismatch IV");
 515                                         category_name[category_draw_count] = j;
 516                                         category_item[category_draw_count] = last;
 517                                         ++category_draw_count;
 518                                         begin = last + 1; // already scanned through these, skip 'em
 519                                 }
 520                                 else
 521                                         begin = last; // already scanned through these, skip 'em
 522                         }
 523                 }
 524                 if(autocvar_menu_slist_categories_onlyifmultiple && (category_draw_count == 1))
 525                 {
 526                         category_name[0] = -1;
 527                         category_item[0] = -1;
 528                         category_draw_count = 0;
 529                         me.nItems = itemcount;
 530                 }
 531         }
 532         else { me.nItems = gethostcachevalue(SLIST_HOSTCACHEVIEWCOUNT); }
 533
 534         me.connectButton.disabled = (me.lockedSelectedItem || (me.nItems == 0 && me.ipAddressBox.text == ""));
 535         //me.disconnectButton.disabled = (!(gamestatus & (GAME_ISSERVER | GAME_CONNECTED)));
 536         me.infoButton.disabled = (me.lockedSelectedItem || me.nItems == 0 || !owned);
 537         me.favoriteButton.disabled = (me.lockedSelectedItem || (me.nItems == 0 && me.ipAddressBox.text == ""));
 538
 539         if(me.lockedSelectedItem)
 540         {
 541                 if(me.nItems > 0)
 542                 {
 543                         if(gethostcachestring(SLIST_FIELD_CNAME, me.selectedItem) != me.selectedServer)
 544                         {
 545                                 strcpy(me.selectedServer, gethostcachestring(SLIST_FIELD_CNAME, me.selectedItem));
 546                         }
 547                         found = true;
 548                 }
 549         }
 550         else if(me.selectedServer)
 551         {
 552                 for(i = 0; i < me.nItems; ++i)
 553                 {
 554                         if(gethostcachestring(SLIST_FIELD_CNAME, i) == me.selectedServer)
 555                         {
 556                                 // don't follow the selected item with SUPER(XonoticServerList).setSelected(me, i);
 557                                 me.selectedItem = i;
 558                                 found = true;
 559                                 break;
 560                         }
 561                 }
 562         }
 563         if(!found)
 564         {
 565                 if(me.nItems > 0)
 566                 {
 567                         // selected server disappeared, select the last server (scrolling to it)
 568                         if(me.selectedItem >= me.nItems)
 569                                 SUPER(XonoticServerList).setSelected(me, me.nItems - 1);
 570                         strcpy(me.selectedServer, gethostcachestring(SLIST_FIELD_CNAME, me.selectedItem));
 571                 }
 572         }
 573
 574         if(owned)
 575         {
 576                 if(me.selectedServer != me.ipAddressBox.text)
 577                 {
 578                         me.ipAddressBox.setText(me.ipAddressBox, me.selectedServer);
 579                         me.ipAddressBox.cursorPos = strlen(me.selectedServer);
 580                         me.ipAddressBoxFocused = -1;
 581                 }
 582         }
 583
 584         if(me.ipAddressBoxFocused != me.ipAddressBox.focused)
 585         {
 586                 if(me.ipAddressBox.focused || me.ipAddressBoxFocused < 0)
 587                         ServerList_Update_favoriteButton(NULL, me);
 588                 me.ipAddressBoxFocused = me.ipAddressBox.focused;
 589         }
 590
 591         SUPER(XonoticServerList).draw(me);
 592 }
 593 void ServerList_PingSort_Click(entity btn, entity me)
 594 {
 595         me.setSortOrder(me, SLIST_FIELD_PING, +1);
 596 }
 597 void ServerList_NameSort_Click(entity btn, entity me)
 598 {
 599         me.setSortOrder(me, SLIST_FIELD_NAME, -1); // why?
 600 }
 601 void ServerList_MapSort_Click(entity btn, entity me)
 602 {
 603         me.setSortOrder(me, SLIST_FIELD_MAP, -1); // why?
 604 }
 605 void ServerList_PlayerSort_Click(entity btn, entity me)
 606 {
 607         me.setSortOrder(me, SLIST_FIELD_NUMHUMANS, -1);
 608 }
 609 void ServerList_TypeSort_Click(entity btn, entity me)
 610 {
 611         string s = me.filterString;
 612         int m = strstrofs(s, ":", 0);
 613         if(m >= 0)
 614         {
 615                 s = substring(s, 0, m);
 616                 while(substring(s, m+1, 1) == " ") // skip spaces
 617                         ++m;
 618         }
 619         else
 620                 s = "";
 621
 622         Gametype first = NULL; FOREACH(Gametypes, !first, first = it; break);
 623         bool flag = false;
 624         FOREACH(Gametypes, s == MapInfo_Type_ToString(it), {
 625                 // the type was found
 626                 // choose the next one
 627                 flag = true;
 628                 s = MapInfo_Type_ToString(Gametypes_from(it.m_id + 1));
 629                 if (s == "") s = MapInfo_Type_ToString(first);
 630                 break;
 631         });
 632         if (!flag) {
 633                 // no type was found
 634                 // choose the first one
 635                 s = MapInfo_Type_ToString(first);
 636         }
 637
 638         if(s != "") s = strcat(s, ":");
 639         s = strcat(s, substring(me.filterString, m+1, strlen(me.filterString) - m - 1));
 640
 641         me.controlledTextbox.setText(me.controlledTextbox, s);
 642         me.controlledTextbox.keyDown(me.controlledTextbox, K_END, 0, 0);
 643         me.controlledTextbox.keyUp(me.controlledTextbox, K_END, 0, 0);
 644         //ServerList_Filter_Change(me.controlledTextbox, me);
 645 }
 646 void ServerList_Filter_Change(entity box, entity me)
 647 {
 648         strfree(me.filterString);
 649         if(box.text != "")
 650                 me.filterString = strzone(box.text);
 651         me.refreshServerList(me, REFRESHSERVERLIST_REFILTER);
 652
 653         me.ipAddressBox.setText(me.ipAddressBox, "");
 654         me.ipAddressBox.cursorPos = 0;
 655         me.ipAddressBoxFocused = -1;
 656 }
 657 void ServerList_Categories_Click(entity box, entity me)
 658 {
 659         box.setChecked(box, autocvar_menu_slist_categories = !autocvar_menu_slist_categories);
 660         me.refreshServerList(me, REFRESHSERVERLIST_RESORT);
 661
 662         me.ipAddressBox.setText(me.ipAddressBox, "");
 663         me.ipAddressBox.cursorPos = 0;
 664         me.ipAddressBoxFocused = -1;
 665 }
 666 void ServerList_ShowEmpty_Click(entity box, entity me)
 667 {
 668         box.setChecked(box, me.filterShowEmpty = !me.filterShowEmpty);
 669         me.refreshServerList(me, REFRESHSERVERLIST_REFILTER);
 670
 671         me.ipAddressBox.setText(me.ipAddressBox, "");
 672         me.ipAddressBox.cursorPos = 0;
 673         me.ipAddressBoxFocused = -1;
 674 }
 675 void ServerList_ShowFull_Click(entity box, entity me)
 676 {
 677         box.setChecked(box, me.filterShowFull = !me.filterShowFull);
 678         me.refreshServerList(me, REFRESHSERVERLIST_REFILTER);
 679
 680         me.ipAddressBox.setText(me.ipAddressBox, "");
 681         me.ipAddressBox.cursorPos = 0;
 682         me.ipAddressBoxFocused = -1;
 683 }
 684 void XonoticServerList_setSortOrder(entity me, int fld, int direction)
 685 {
 686         if(me.currentSortField == fld)
 687                 direction = -me.currentSortOrder;
 688         me.currentSortOrder = direction;
 689         me.currentSortField = fld;
 690         me.sortButton1.forcePressed = (fld == SLIST_FIELD_PING);
 691         me.sortButton2.forcePressed = (fld == SLIST_FIELD_NAME);
 692         me.sortButton3.forcePressed = (fld == SLIST_FIELD_MAP);
 693         me.sortButton4.forcePressed = 0;
 694         me.sortButton5.forcePressed = (fld == SLIST_FIELD_NUMHUMANS);
 695         me.selectedItem = 0;
 696         strfree(me.selectedServer);
 697         me.refreshServerList(me, REFRESHSERVERLIST_REFILTER);
 698 }
 699 void XonoticServerList_positionSortButton(entity me, entity btn, float theOrigin, float theSize, string theTitle, void(entity, entity) theFunc)
 700 {
 701         vector originInLBSpace = eY * (-me.itemHeight);
 702         vector sizeInLBSpace = eY * me.itemHeight + eX * (1 - me.controlWidth);
 703
 704         vector originInDialogSpace = boxToGlobal(originInLBSpace, me.Container_origin, me.Container_size);
 705         vector sizeInDialogSpace = boxToGlobalSize(sizeInLBSpace, me.Container_size);
 706
 707         btn.Container_origin_x = originInDialogSpace.x + sizeInDialogSpace.x * theOrigin;
 708         btn.Container_size_x   =                         sizeInDialogSpace.x * theSize;
 709         btn.setText(btn, theTitle);
 710         btn.onClick = theFunc;
 711         btn.onClickEntity = me;
 712         btn.resized = 1;
 713 }
 714 void XonoticServerList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
 715 {
 716         SUPER(XonoticServerList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
 717
 718         me.realFontSize_y = me.fontSize / (absSize.y * me.itemHeight);
 719         me.realFontSize_x = me.fontSize / (absSize.x * (1 - me.controlWidth));
 720         me.realUpperMargin = 0.5 * (1 - me.realFontSize.y);
 721
 722         me.columnIconsOrigin = 0;
 723         me.columnIconsSize = me.realFontSize.x * 4 * me.iconsSizeFactor;
 724         me.columnPingSize = me.realFontSize.x * 3;
 725         me.columnMapSize = me.realFontSize.x * 10;
 726         me.columnTypeSize = me.realFontSize.x * 4;
 727         me.columnPlayersSize = me.realFontSize.x * 5;
 728         me.columnNameSize = 1 - me.columnPlayersSize - me.columnMapSize - me.columnPingSize - me.columnIconsSize - me.columnTypeSize - 5 * me.realFontSize.x;
 729         me.columnPingOrigin = me.columnIconsOrigin + me.columnIconsSize + me.realFontSize.x;
 730         me.columnNameOrigin = me.columnPingOrigin + me.columnPingSize + me.realFontSize.x;
 731         me.columnMapOrigin = me.columnNameOrigin + me.columnNameSize + me.realFontSize.x;
 732         me.columnTypeOrigin = me.columnMapOrigin + me.columnMapSize + me.realFontSize.x;
 733         me.columnPlayersOrigin = me.columnTypeOrigin + me.columnTypeSize + me.realFontSize.x;
 734
 735         me.positionSortButton(me, me.sortButton1, me.columnPingOrigin, me.columnPingSize, _("Ping"), ServerList_PingSort_Click);
 736         me.positionSortButton(me, me.sortButton2, me.columnNameOrigin, me.columnNameSize, _("Hostname"), ServerList_NameSort_Click);
 737         me.positionSortButton(me, me.sortButton3, me.columnMapOrigin, me.columnMapSize, _("Map"), ServerList_MapSort_Click);
 738         me.positionSortButton(me, me.sortButton4, me.columnTypeOrigin, me.columnTypeSize, _("Type"), ServerList_TypeSort_Click);
 739         me.positionSortButton(me, me.sortButton5, me.columnPlayersOrigin, me.columnPlayersSize, _("Players"), ServerList_PlayerSort_Click);
 740
 741         int f = me.currentSortField;
 742         if(f >= 0)
 743         {
 744                 me.currentSortField = -1;
 745                 me.setSortOrder(me, f, me.currentSortOrder); // force resetting the sort order
 746         }
 747 }
 748 void ServerList_Connect_Click(entity btn, entity me)
 749 {
 750         if (me.lockedSelectedItem)
 751                 return;
 752         string sv = (me.ipAddressBox.text != "") ? me.ipAddressBox.text : me.selectedServer;
 753         localcmd(sprintf("connect %s\n", sv));
 754 }
 755 void ServerList_Favorite_Click(entity btn, entity this)
 756 {
 757         string addr = this.ipAddressBox.text;
 758         string ipstr = netaddress_resolve(addr, 26000);
 759         if (ipstr == "") return;
 760         m_play_click_sound(MENU_SOUND_SELECT);
 761         this.toggleFavorite(this, addr);
 762         this.ipAddressBoxFocused = -1;
 763 }
 764 void ServerList_Info_Click(entity btn, entity me)
 765 {
 766         if (me.nItems != 0)
 767                 main.serverInfoDialog.loadServerInfo(main.serverInfoDialog, me.selectedItem);
 768
 769         vector org = boxToGlobal(eY * (me.selectedItem * me.itemHeight - me.scrollPos), me.origin, me.size);
 770         vector sz = boxToGlobalSize(eY * me.itemHeight + eX * (1 - me.controlWidth), me.size);
 771         DialogOpenButton_Click_withCoords(me, main.serverInfoDialog, org, sz);
 772 }
 773 void XonoticServerList_doubleClickListBoxItem(entity me, int i, vector where)
 774 {
 775         ServerList_Connect_Click(NULL, me);
 776 }
 777 void XonoticServerList_drawListBoxItem(entity me, int i, vector absSize, bool isSelected, bool isFocused)
 778 {
 779         vector oldscale = draw_scale;
 780         vector oldshift = draw_shift;
 781 #define SET_YRANGE(start,end) \
 782         draw_scale = boxToGlobalSize(eX + eY * (end - start), oldscale); \
 783         draw_shift = boxToGlobal(eY * start, oldshift, oldscale);
 784
 785         int c;
 786         for (c = 0; c < category_draw_count; ++c) {
 787                 // Matches exactly the headings with increased height.
 788                 if (i == category_item[c])
 789                         break;
 790         }
 791
 792         if (c < category_draw_count)
 793         {
 794                 entity catent = RetrieveCategoryEnt(category_name[c]);
 795                 if(catent)
 796                 {
 797                         SET_YRANGE(
 798                                 (me.categoriesHeight - 1) / (me.categoriesHeight + 1),
 799                                 me.categoriesHeight / (me.categoriesHeight + 1)
 800                         );
 801                         draw_Text(
 802                                 eY * me.realUpperMargin
 803                                 +
 804 #if 0
 805                                 eX * (me.columnNameOrigin + (me.columnNameSize - draw_TextWidth(catent.cat_string, 0, me.realFontSize)) * 0.5),
 806                                 catent.cat_string,
 807 #else
 808                                 eX * (me.columnNameOrigin),
 809                                 strcat(catent.cat_string, ":"),
 810 #endif
 811                                 me.realFontSize,
 812                                 SKINCOLOR_SERVERLIST_CATEGORY,
 813                                 SKINALPHA_SERVERLIST_CATEGORY,
 814                                 0
 815                         );
 816                         SET_YRANGE(me.categoriesHeight / (me.categoriesHeight + 1), 1);
 817                 }
 818         }
 819
 820         if(isSelected && !me.lockedSelectedItem)
 821                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 822         else if(isFocused)
 823         {
 824                 me.focusedItemAlpha = getFadedAlpha(me.focusedItemAlpha, SKINALPHA_LISTBOX_FOCUSED, SKINFADEALPHA_LISTBOX_FOCUSED);
 825                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_FOCUSED, me.focusedItemAlpha);
 826         }
 827
 828         string s = gethostcachestring(SLIST_FIELD_QCSTATUS, i);
 829         int m = tokenizebyseparator(s, ":");
 830         string typestr = "", versionstr = "";
 831         if(m >= 2)
 832         {
 833                 typestr = argv(0);
 834                 versionstr = argv(1);
 835         }
 836         bool pure = false, pure_available = false;
 837         int freeslots = -1, sflags = -1;
 838         string modname = "";
 839         for(int j = 2; j < m; ++j)
 840         {
 841                 if(argv(j) == "")
 842                         break;
 843                 string key = substring(argv(j), 0, 1);
 844                 string value = substring(argv(j), 1, -1);
 845                 if(key == "P")
 846                 {
 847                         pure = (stof(value) == 0);
 848                         pure_available = true;
 849                 }
 850                 else if(key == "S")
 851                         freeslots = stof(value);
 852                 else if(key == "F")
 853                         sflags = stoi(value);
 854                 else if(key == "M")
 855                         modname = value;
 856         }
 857
 858 #ifdef COMPAT_NO_MOD_IS_XONOTIC
 859         if(modname == "")
 860                 modname = "Xonotic";
 861 #endif
 862
 863         string original_modname = modname;
 864         modname = strtolower(modname);
 865
 866         /*
 867         SLIST_FIELD_MOD = gethostcacheindexforkey("mod");
 868         s = gethostcachestring(SLIST_FIELD_MOD, i);
 869         if(s != "data")
 870                 if(modname == "xonotic")
 871                         modname = s;
 872         */
 873
 874         // list the mods here on which the pure server check actually works
 875         if(modname != "xonotic")
 876         if(modname != "instagib" || modname != "minstagib")
 877         if(modname != "cts")
 878         if(modname != "nix")
 879         if(modname != "newtoys")
 880                 pure_available = false;
 881
 882         float theAlpha;
 883         if(gethostcachenumber(SLIST_FIELD_FREESLOTS, i) <= 0)
 884                 theAlpha = SKINALPHA_SERVERLIST_FULL;
 885         else if(freeslots == 0)
 886                 theAlpha = SKINALPHA_SERVERLIST_FULL; // g_maxplayers support
 887         else if (!gethostcachenumber(SLIST_FIELD_NUMHUMANS, i))
 888                 theAlpha = SKINALPHA_SERVERLIST_EMPTY;
 889         else
 890                 theAlpha = 1;
 891
 892         float ping = gethostcachenumber(SLIST_FIELD_PING, i);
 893         const int PING_LOW = 75;
 894         const int PING_MED = 200;
 895         const int PING_HIGH = 500;
 896         vector theColor;
 897         if(ping < PING_LOW)
 898                 theColor = SKINCOLOR_SERVERLIST_LOWPING + (SKINCOLOR_SERVERLIST_MEDPING - SKINCOLOR_SERVERLIST_LOWPING) * (ping / PING_LOW);
 899         else if(ping < PING_MED)
 900                 theColor = SKINCOLOR_SERVERLIST_MEDPING + (SKINCOLOR_SERVERLIST_HIGHPING - SKINCOLOR_SERVERLIST_MEDPING) * ((ping - PING_LOW) / (PING_MED - PING_LOW));
 901         else if(ping < PING_HIGH)
 902         {
 903                 theColor = SKINCOLOR_SERVERLIST_HIGHPING;
 904                 theAlpha *= 1 + (SKINALPHA_SERVERLIST_HIGHPING - 1) * ((ping - PING_MED) / (PING_HIGH - PING_MED));
 905         }
 906         else
 907         {
 908                 theColor = eX;
 909                 theAlpha *= SKINALPHA_SERVERLIST_HIGHPING;
 910         }
 911
 912         if(gethostcachenumber(SLIST_FIELD_ISFAVORITE, i))
 913         {
 914                 theColor = theColor * (1 - SKINALPHA_SERVERLIST_FAVORITE) + SKINCOLOR_SERVERLIST_FAVORITE * SKINALPHA_SERVERLIST_FAVORITE;
 915                 theAlpha = theAlpha * (1 - SKINALPHA_SERVERLIST_FAVORITE) + SKINALPHA_SERVERLIST_FAVORITE;
 916         }
 917
 918         s = gethostcachestring(SLIST_FIELD_CNAME, i);
 919
 920         bool isv4 = false, isv6 = false;
 921         if(substring(s, 0, 1) == "[")
 922         {
 923                 isv6 = true;
 924                 me.seenIPv6 += 1;
 925         }
 926         else if(IS_DIGIT(substring(s, 0, 1)))
 927         {
 928                 isv4 = true;
 929                 me.seenIPv4 += 1;
 930         }
 931
 932         int crypto = stof(substring(crypto_getencryptlevel(s), 0, 1));
 933         if((crypto <= 0 && cvar("crypto_aeslevel") >= 3) || (crypto >= 3 && cvar("crypto_aeslevel") <= 0))
 934         {
 935                 theColor = SKINCOLOR_SERVERLIST_IMPOSSIBLE;
 936                 theAlpha = SKINALPHA_SERVERLIST_IMPOSSIBLE;
 937         }
 938
 939         if(crypto == 1)
 940         {
 941                 if(cvar("crypto_aeslevel") >= 2)
 942                         crypto |= 4;
 943         }
 944         if(crypto == 2)
 945         {
 946                 if(cvar("crypto_aeslevel") >= 1)
 947                         crypto |= 4;
 948         }
 949         if(crypto == 3)
 950                 crypto = 5;
 951         else if(crypto >= 3)
 952                 crypto -= 2;
 953         // possible status:
 954         // 0: crypto off
 955         // 1: AES possible
 956         // 2: AES recommended but not available
 957         // 3: AES possible and will be used
 958         // 4: AES recommended and will be used
 959         // 5: AES required
 960
 961         // --------------
 962         //  RENDER ICONS
 963         // --------------
 964         vector iconSize = '0 0 0';
 965         iconSize_y = me.realFontSize.y * me.iconsSizeFactor;
 966         iconSize_x = me.realFontSize.x * me.iconsSizeFactor;
 967
 968         vector iconPos = '0 0 0';
 969         iconPos_x = (me.columnIconsSize - 3 * iconSize.x) * 0.5;
 970         iconPos_y = (1 - iconSize.y) * 0.5;
 971
 972         // IP
 973         if(me.seenIPv4 && me.seenIPv6)
 974         {
 975                 if(isv6)
 976                         draw_Picture(iconPos, "icon_ipv6", iconSize, '1 1 1', 1);
 977                 else if(isv4)
 978                         draw_Picture(iconPos, "icon_ipv4", iconSize, '1 1 1', 1);
 979         }
 980
 981         iconPos.x += iconSize.x;
 982
 983         // AES
 984         if(crypto > 0)
 985                 draw_Picture(iconPos, strcat("icon_aeslevel", ftos(crypto)), iconSize, '1 1 1', 1);
 986
 987         iconPos.x += iconSize.x;
 988
 989         // Mod
 990         if(modname == "xonotic")
 991         {
 992                 // Here, pure_available should always be set. If not, consider
 993                 // it an impurity.
 994                 if(pure_available && pure)
 995                         draw_Picture(iconPos, "icon_pure1", iconSize, '1 1 1', 1);
 996         }
 997         else
 998         {
 999                 string icon = strcat("icon_mod_", modname);
1000                 if(draw_PictureSize(icon) == '0 0 0')
1001                         icon = "icon_mod_";
1002
1003                 // In mods, pure_available not being present indicates
1004                 // non-support of the feature. Just show the mod icon as is
1005                 // then.
1006                 if(pure_available && !pure)
1007                         draw_Picture(iconPos, icon, iconSize, '1 1 1', SKINALPHA_SERVERLIST_ICON_NONPURE);
1008                 else
1009                         draw_Picture(iconPos, icon, iconSize, '1 1 1', 1);
1010         }
1011
1012         iconPos.x += iconSize.x;
1013
1014         // Stats
1015         if(sflags >= 0 && (sflags & SERVERFLAG_PLAYERSTATS))
1016                 draw_Picture(iconPos, "icon_stats1", iconSize, '1 1 1', 1);
1017
1018         if(isFocused && me.mouseOverIcons && !me.tooltip)
1019         {
1020                 string t = "";
1021                 if(me.seenIPv4 && me.seenIPv6)
1022                         t = strcat(t, (isv6) ? "IPv6, " : "IPv4, ");
1023                 t = strcat(t, _("encryption:"), " ", (crypto ? sprintf(_("AES level %d"), crypto) : ZCTX(_("ENC^none"))), ", ");
1024                 t = strcat(t, sprintf(_("mod: %s"), ((modname == "xonotic") ? ZCTX(_("MOD^Default")) : original_modname)));
1025                 if(pure_available)
1026                         t = strcat(t, sprintf(" (%s)", (pure) ? _("official settings") : _("modified settings")));
1027                 t = strcat(t, ", ");
1028                 t = strcat(t, ((sflags >= 0 && (sflags & SERVERFLAG_PLAYERSTATS)) ? _("stats enabled") : _("stats disabled")));
1029                 setZonedTooltip(me, t, string_null);
1030         }
1031         // --------------
1032         //  RENDER TEXT
1033         // --------------
1034
1035         // ping
1036         s = ftos(ping);
1037         draw_Text(me.realUpperMargin * eY + (me.columnPingOrigin + me.columnPingSize - draw_TextWidth(s, 0, me.realFontSize)) * eX, s, me.realFontSize, theColor, theAlpha, 0);
1038
1039         // server name
1040         s = draw_TextShortenToWidth(gethostcachestring(SLIST_FIELD_NAME, i), me.columnNameSize, 0, me.realFontSize);
1041         draw_Text(me.realUpperMargin * eY + me.columnNameOrigin * eX, s, me.realFontSize, theColor, theAlpha, 0);
1042
1043         // server map
1044         s = draw_TextShortenToWidth(gethostcachestring(SLIST_FIELD_MAP, i), me.columnMapSize, 0, me.realFontSize);
1045         draw_Text(me.realUpperMargin * eY + (me.columnMapOrigin + (me.columnMapSize - draw_TextWidth(s, 0, me.realFontSize)) * 0.5) * eX, s, me.realFontSize, theColor, theAlpha, 0);
1046
1047         // server gametype
1048         s = draw_TextShortenToWidth(typestr, me.columnTypeSize, 0, me.realFontSize);
1049         draw_Text(me.realUpperMargin * eY + (me.columnTypeOrigin + (me.columnTypeSize - draw_TextWidth(s, 0, me.realFontSize)) * 0.5) * eX, s, me.realFontSize, theColor, theAlpha, 0);
1050
1051         // server playercount
1052         s = strcat(ftos(gethostcachenumber(SLIST_FIELD_NUMHUMANS, i)), "/", ftos(gethostcachenumber(SLIST_FIELD_MAXPLAYERS, i)));
1053         draw_Text(me.realUpperMargin * eY + (me.columnPlayersOrigin + (me.columnPlayersSize - draw_TextWidth(s, 0, me.realFontSize)) * 0.5) * eX, s, me.realFontSize, theColor, theAlpha, 0);
1054 }
1055
1056 void XonoticServerList_focusedItemChangeNotify(entity me)
1057 {
1058         clearTooltip(me);
1059 }
1060
1061 float XonoticServerList_mouseMove(entity me, vector pos)
1062 {
1063         if(!SUPER(XonoticServerList).mouseMove(me, pos))
1064         {
1065                 me.mouseOverIcons = false;
1066                 clearTooltip(me);
1067                 return 1;
1068         }
1069
1070         me.mouseOverIcons = (pos_x <= me.columnIconsSize);
1071         if(!me.mouseOverIcons)
1072                 clearTooltip(me);
1073         return 1;
1074 }
1075
1076 bool XonoticServerList_keyDown(entity me, int scan, bool ascii, bool shift)
1077 {
1078         if(scan == K_ENTER || scan == K_KP_ENTER)
1079         {
1080                 ServerList_Connect_Click(NULL, me);
1081                 return true;
1082         }
1083         else if(scan == K_MOUSE2 || scan == K_SPACE)
1084         {
1085                 if(me.nItems != 0)
1086                 {
1087                         vector org = boxToGlobal(eY * (me.selectedItem * me.itemHeight - me.scrollPos), me.origin, me.size);
1088                         vector sz = boxToGlobalSize(eY * me.itemHeight + eX * (1 - me.controlWidth), me.size);
1089                         m_play_click_sound(MENU_SOUND_OPEN);
1090                         main.serverInfoDialog.loadServerInfo(main.serverInfoDialog, me.selectedItem);
1091                         DialogOpenButton_Click_withCoords(me, main.serverInfoDialog, org, sz);
1092                         return true;
1093                 }
1094                 return false;
1095         }
1096         else if(scan == K_INS || scan == K_MOUSE3 || scan == K_KP_INS)
1097         {
1098                 if(me.nItems != 0)
1099                 {
1100                         me.toggleFavorite(me, me.selectedServer);
1101                         me.ipAddressBoxFocused = -1;
1102                         return true;
1103                 }
1104                 return false;
1105         }
1106         else if(SUPER(XonoticServerList).keyDown(me, scan, ascii, shift))
1107                 return true;
1108         else if(!me.controlledTextbox)
1109                 return false;
1110         else
1111                 return me.controlledTextbox.keyDown(me.controlledTextbox, scan, ascii, shift);
1112 }
1113
1114 float XonoticServerList_getTotalHeight(entity me)
1115 {
1116         float num_normal_rows = me.nItems;
1117         int num_headers = category_draw_count;
1118         return me.itemHeight * (num_normal_rows + me.categoriesHeight * num_headers);
1119 }
1120 int XonoticServerList_getItemAtPos(entity me, float pos)
1121 {
1122         pos = pos / me.itemHeight;
1123         int i;
1124         for (i = category_draw_count - 1; i >= 0; --i) {
1125                 int itemidx = category_item[i];
1126                 float itempos = i * me.categoriesHeight + category_item[i];
1127                 if (pos >= itempos + me.categoriesHeight + 1)
1128                         return itemidx + 1 + floor(pos - (itempos + me.categoriesHeight + 1));
1129                 if (pos >= itempos)
1130                         return itemidx;
1131         }
1132         // No category matches? Note that category 0 is... 0. Therefore no headings exist at all.
1133         return floor(pos);
1134 }
1135 float XonoticServerList_getItemStart(entity me, int item)
1136 {
1137         int i;
1138         for (i = category_draw_count - 1; i >= 0; --i) {
1139                 int itemidx = category_item[i];
1140                 float itempos = i * me.categoriesHeight + category_item[i];
1141                 if (item >= itemidx + 1)
1142                         return (itempos + me.categoriesHeight + 1 + item - (itemidx + 1)) * me.itemHeight;
1143                 if (item >= itemidx)
1144                         return itempos * me.itemHeight;
1145         }
1146         // No category matches? Note that category 0 is... 0. Therefore no headings exist at all.
1147         return item * me.itemHeight;
1148 }
1149 float XonoticServerList_getItemHeight(entity me, int item)
1150 {
1151         int i;
1152         for (i = 0; i < category_draw_count; ++i) {
1153                 // Matches exactly the headings with increased height.
1154                 if (item == category_item[i])
1155                         return me.itemHeight * (me.categoriesHeight + 1);
1156         }
1157         return me.itemHeight;
1158 }