qcsrc/menu/xonotic/soundlist.c

   1 #ifdef INTERFACE
   2 CLASS(XonoticSoundList) EXTENDS(XonoticListBox)
   3         METHOD(XonoticSoundList, configureXonoticSoundList, void(entity))
   4         ATTRIB(XonoticSoundList, rowsPerItem, float, 1)
   5         METHOD(XonoticSoundList, resizeNotify, void(entity, vector, vector, vector, vector))
   6         METHOD(XonoticSoundList, drawListBoxItem, void(entity, float, vector, float))
   7         METHOD(XonoticSoundList, getSounds, void(entity))
   8         METHOD(XonoticSoundList, soundName, string(entity, float))
   9         METHOD(XonoticSoundList, clickListBoxItem, void(entity, float, vector))
  10         METHOD(XonoticSoundList, keyDown, float(entity, float, float, float))
  11         METHOD(XonoticSoundList, destroy, void(entity))
  12         METHOD(XonoticSoundList, showNotify, void(entity))
  13
  14         ATTRIB(XonoticSoundList, listSound, float, -1)
  15         ATTRIB(XonoticSoundList, realFontSize, vector, '0 0 0')
  16         ATTRIB(XonoticSoundList, columnNameOrigin, float, 0)
  17         ATTRIB(XonoticSoundList, columnNameSize, float, 0)
  18         ATTRIB(XonoticSoundList, columnNumberOrigin, float, 0)
  19         ATTRIB(XonoticSoundList, columnNumberSize, float, 0)
  20         ATTRIB(XonoticSoundList, realUpperMargin, float, 0)
  21         ATTRIB(XonoticSoundList, origin, vector, '0 0 0')
  22         ATTRIB(XonoticSoundList, itemAbsSize, vector, '0 0 0')
  23
  24         ATTRIB(XonoticSoundList, lastClickedSound, float, -1)
  25         ATTRIB(XonoticSoundList, lastClickedTime, float, 0)
  26         ATTRIB(XonoticSoundList, filterString, string, string_null)
  27         ATTRIB(XonoticSoundList, playlist, entity, world)
  28 ENDCLASS(XonoticSoundList)
  29
  30 entity makeXonoticSoundList();
  31 void SoundList_Filter_Change(entity box, entity me);
  32 void SoundList_Add(entity box, entity me);
  33 void SoundList_Add_All(entity box, entity me);
  34 void SoundList_Menu_Track_Change(entity box, entity me);
  35 void SoundList_Menu_Track_Reset(entity box, entity me);
  36 #endif
  37
  38 #ifdef IMPLEMENTATION
  39
  40 entity makeXonoticSoundList()
  41 {
  42         entity me;
  43         me = spawnXonoticSoundList();
  44         me.configureXonoticSoundList(me);
  45         return me;
  46 }
  47
  48 void XonoticSoundList_configureXonoticSoundList(entity me)
  49 {
  50         me.configureXonoticListBox(me);
  51         me.getSounds(me);
  52 }
  53
  54 string XonoticSoundList_soundName(entity me, float i )
  55 {
  56         string s;
  57         s = search_getfilename(me.listSound, i);
  58         s = substring(s, 15, strlen(s) - 15 - 4);  // sound/cdtracks/, .ogg
  59         return s;
  60 }
  61
  62
  63 void XonoticSoundList_getSounds(entity me)
  64 {
  65         string s;
  66
  67         if(me.filterString)
  68                 //subdirectory in filterString allowed
  69                 s = strcat("sound/cdtracks/*", me.filterString, "*.ogg");
  70         else
  71                 s = "sound/cdtracks/*.ogg";
  72
  73         if(me.listSound >= 0)
  74                 search_end(me.listSound);
  75
  76         me.listSound = search_begin(s, FALSE, TRUE);
  77
  78         if(me.listSound < 0)
  79                 me.nItems=0;
  80         else
  81                 me.nItems=search_getsize(me.listSound);
  82 }
  83
  84 void XonoticSoundList_destroy(entity me)
  85 {
  86         if(me.listSound >= 0)
  87                 search_end(me.listSound);
  88 }
  89
  90 void XonoticSoundList_resizeNotify(entity me, vector relOrigin, vector relSize, vector absOrigin, vector absSize)
  91 {
  92         me.itemAbsSize = '0 0 0';
  93         SUPER(XonoticSoundList).resizeNotify(me, relOrigin, relSize, absOrigin, absSize);
  94
  95         me.realFontSize_y = me.fontSize / (me.itemAbsSize_y = (absSize_y * me.itemHeight));
  96         me.realFontSize_x = me.fontSize / (me.itemAbsSize_x = (absSize_x * (1 - me.controlWidth)));
  97         me.realUpperMargin = 0.5 * (1 - me.realFontSize_y);
  98
  99         me.columnNumberOrigin = 0;
 100         me.columnNumberSize = me.realFontSize_x * 3;
 101
 102         me.columnNameOrigin = me.columnNumberSize;
 103         me.columnNameSize = 1 - me.columnNameOrigin - me.realFontSize_x;
 104 }
 105
 106 void XonoticSoundList_drawListBoxItem(entity me, float i, vector absSize, float isSelected)
 107 {
 108         string s;
 109         if(isSelected)
 110                 draw_Fill('0 0 0', '1 1 0', SKINCOLOR_LISTBOX_SELECTED, SKINALPHA_LISTBOX_SELECTED);
 111
 112         s = me.soundName(me,i);
 113         if(s == cvar_string("menu_cdtrack")) // current menu track
 114                 draw_CenterText((me.columnNumberOrigin + 0.5 * me.columnNumberSize) * eX + me.realUpperMargin * eY, "[C]", me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
 115         else if(s == cvar_defstring("menu_cdtrack")) // default menu track
 116                 draw_CenterText((me.columnNumberOrigin + 0.5 * me.columnNumberSize) * eX + me.realUpperMargin * eY, "[D]", me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
 117
 118         s = draw_TextShortenToWidth(s, me.columnNameSize, 0, me.realFontSize);
 119         draw_Text(me.realUpperMargin * eY + me.columnNameOrigin * eX, s, me.realFontSize, '1 1 1', SKINALPHA_TEXT, 0);
 120 }
 121
 122 void XonoticSoundList_showNotify(entity me)
 123 {
 124         me.getSounds(me);
 125 }
 126
 127 void SoundList_Menu_Track_Change(entity box, entity me)
 128 {
 129         cvar_set("menu_cdtrack", me.soundName(me,me.selectedItem));
 130 }
 131
 132 void SoundList_Menu_Track_Reset(entity box, entity me)
 133 {
 134         cvar_set("menu_cdtrack", cvar_defstring("menu_cdtrack"));
 135 }
 136
 137 void SoundList_Filter_Change(entity box, entity me)
 138 {
 139         if(me.filterString)
 140                 strunzone(me.filterString);
 141
 142         if(box.text != "")
 143                 me.filterString = strzone(box.text);
 144         else
 145                 me.filterString = string_null;
 146
 147         me.getSounds(me);
 148 }
 149
 150 void SoundList_Add(entity box, entity me)
 151 {
 152         me.playlist.addToPlayList(me.playlist, me.soundName(me, me.selectedItem));
 153 }
 154
 155 void SoundList_Add_All(entity box, entity me)
 156 {
 157         float i;
 158         for(i = 0; i < me.nItems; ++i)
 159                 me.playlist.addToPlayList(me.playlist, me.soundName(me, i));
 160 }
 161
 162 void XonoticSoundList_clickListBoxItem(entity me, float i, vector where)
 163 {
 164         if(i == me.lastClickedSound)
 165                 if(time < me.lastClickedTime + 0.3)
 166                 {
 167                         // DOUBLE CLICK!
 168                         me.setSelected(me, i);
 169                         me.playlist.addToPlayList(me.playlist, me.soundName(me, i));
 170                 }
 171         me.lastClickedSound = i;
 172         me.lastClickedTime = time;
 173 }
 174
 175 float XonoticSoundList_keyDown(entity me, float scan, float ascii, float shift)
 176 {
 177         if(scan == K_ENTER || scan == K_KP_ENTER || scan == K_SPACE) {
 178                 me.playlist.addToPlayList(me.playlist, me.soundName(me, me.selectedItem));
 179                 return 1;
 180         }
 181         else
 182                 return SUPER(XonoticSoundList).keyDown(me, scan, ascii, shift);
 183 }
 184 #endif
 185