qcsrc/server/anticheat.qc

   1 #if defined(CSQC)
   2 #elif defined(MENUQC)
   3 #elif defined(SVQC)
   4         #include "../dpdefs/progsdefs.qh"
   5     #include "../dpdefs/dpextensions.qh"
   6     #include "../warpzonelib/mathlib.qh"
   7     #include "autocvars.qh"
   8     #include "defs.qh"
   9     #include "command/common.qh"
  10     #include "anticheat.qh"
  11 #endif
  12
  13 .float anticheat_jointime;
  14
  15 void mean_accumulate(entity e, .float a, .float c, float mean, float value, float weight)
  16 {
  17         if(weight == 0)
  18                 return;
  19         if(mean == 0)
  20                 e.a *= pow(value, weight);
  21         else
  22                 e.a += pow(value, mean) * weight;
  23         e.c += weight;
  24 }
  25
  26 float mean_evaluate(entity e, .float a, .float c, float mean)
  27 {
  28         if(e.c == 0)
  29                 return 0;
  30         if(mean == 0)
  31                 return pow(e.a, 1.0 / e.c);
  32         else
  33                 return pow(e.a / e.c, 1.0 / mean);
  34 }
  35
  36 #define MEAN_ACCUMULATE(prefix,v,w) mean_accumulate(self,prefix##_accumulator,prefix##_count,prefix##_mean,v,w)
  37 #define MEAN_EVALUATE(prefix) mean_evaluate(self,prefix##_accumulator,prefix##_count,prefix##_mean)
  38 #define MEAN_DECLARE(prefix,m) float prefix##_mean = m; .float prefix##_count, prefix##_accumulator
  39
  40 .float anticheat_fixangle_endtime;
  41
  42 float anticheat_div0_evade_evasion_delta;
  43 .float anticheat_div0_evade_offset;
  44 .vector anticheat_div0_evade_v_angle;
  45 .vector anticheat_div0_evade_forward_initial;
  46 MEAN_DECLARE(anticheat_div0_evade, 5);
  47
  48 .vector anticheat_div0_strafebot_movement_prev;
  49 MEAN_DECLARE(anticheat_div0_strafebot_old, 5);
  50
  51 .vector anticheat_div0_strafebot_forward_prev;
  52 MEAN_DECLARE(anticheat_div0_strafebot_new, 5);
  53
  54 // Snap-aim detection: we track the average angular speed of aiming over time, in "radians per second".
  55 // Signal: a high-power mean. Cheaters will have high "signal" here.
  56 // Noise: a low-power mean. Active/shivery players will have high "noise" here.
  57 // Note one can always artificially add noise - so very high values of both signal and noise need to be checked too.
  58 MEAN_DECLARE(anticheat_idle_snapaim_signal, 5);
  59 MEAN_DECLARE(anticheat_idle_snapaim_noise, 1);
  60
  61 // TEMP DEBUG STUFF.
  62 MEAN_DECLARE(anticheat_idle_snapaim_m2, 2);
  63 MEAN_DECLARE(anticheat_idle_snapaim_m3, 3);
  64 MEAN_DECLARE(anticheat_idle_snapaim_m4, 4);
  65 MEAN_DECLARE(anticheat_idle_snapaim_m7, 7);
  66 MEAN_DECLARE(anticheat_idle_snapaim_m10, 10);
  67
  68 .float anticheat_speedhack_offset;
  69 .float anticheat_speedhack_movetime, anticheat_speedhack_movetime_count, anticheat_speedhack_movetime_frac;
  70 MEAN_DECLARE(anticheat_speedhack, 5);
  71
  72 .float anticheat_speedhack_accu;
  73 .float anticheat_speedhack_lasttime;
  74 MEAN_DECLARE(anticheat_speedhack_m1, 1);
  75 MEAN_DECLARE(anticheat_speedhack_m2, 2);
  76 MEAN_DECLARE(anticheat_speedhack_m3, 3);
  77 MEAN_DECLARE(anticheat_speedhack_m4, 4);
  78 MEAN_DECLARE(anticheat_speedhack_m5, 5);
  79
  80 float movement_oddity(vector m0, vector m1)
  81 {
  82         float cosangle = normalize(m0) * normalize(m1);
  83         if(cosangle >= 0)
  84                 return 0;
  85         return 0.5 - 0.5 * cos(cosangle * cosangle * 4 * M_PI);
  86                 // returns 0 for: -1, -sqrt(0.5), 0 (angles that commonly happen with kbd)
  87 }
  88
  89 void anticheat_physics()
  90 {
  91         float f;
  92
  93         // div0_evade -> SPECTATORS
  94         makevectors(self.v_angle);
  95         if(self.anticheat_div0_evade_offset == 0)
  96         {
  97                 f = fabs(anticheat_div0_evade_evasion_delta - floor(anticheat_div0_evade_evasion_delta) - 0.5) * 2; // triangle function
  98                 self.anticheat_div0_evade_offset = servertime + sys_frametime * (3 * f - 1);
  99                 self.anticheat_div0_evade_v_angle = self.v_angle;
 100                 self.anticheat_div0_evade_forward_initial = v_forward;
 101                 MEAN_ACCUMULATE(anticheat_div0_evade, 0, 1);
 102         }
 103         else
 104         {
 105                 if(time < self.anticheat_div0_evade_offset)
 106                         self.anticheat_div0_evade_v_angle = self.v_angle;
 107                 MEAN_ACCUMULATE(anticheat_div0_evade, 0.5 - 0.5 * (self.anticheat_div0_evade_forward_initial * v_forward), 1);
 108         }
 109
 110         MEAN_ACCUMULATE(anticheat_div0_strafebot_old, movement_oddity(self.movement, self.anticheat_div0_strafebot_movement_prev), 1);
 111         self.anticheat_div0_strafebot_movement_prev = self.movement;
 112
 113         // Note: this actually tries to detect snap-aim.
 114         if(vlen(self.anticheat_div0_strafebot_forward_prev) && time > self.anticheat_fixangle_endtime) {
 115                 float cosangle = self.anticheat_div0_strafebot_forward_prev * v_forward;
 116                 float angle = cosangle < -1 ? M_PI : cosangle > 1 ? 0 : acos(cosangle);
 117                 /*
 118                 if (angle >= 10 * M_PI / 180)
 119                         printf("SNAP %s: %f for %f, %f since fixangle\n", self.netname, angle * 180 / M_PI, cosangle, time - self.anticheat_fixangle_endtime);
 120                 */
 121                 MEAN_ACCUMULATE(anticheat_div0_strafebot_new, angle / M_PI, 1);
 122
 123                 if (autocvar_slowmo > 0) {
 124                         // Technically this is a NOP, as the engine should be ensuring
 125                         // this in the first place. Let's guard against dividing by
 126                         // zero anyway.
 127                         float dt = max(0.001, frametime) / autocvar_slowmo;
 128
 129                         float anglespeed = angle / dt;
 130                         MEAN_ACCUMULATE(anticheat_idle_snapaim_signal, anglespeed, dt);
 131                         MEAN_ACCUMULATE(anticheat_idle_snapaim_noise, anglespeed, dt);
 132                         MEAN_ACCUMULATE(anticheat_idle_snapaim_m2, anglespeed, dt);
 133                         MEAN_ACCUMULATE(anticheat_idle_snapaim_m3, anglespeed, dt);
 134                         MEAN_ACCUMULATE(anticheat_idle_snapaim_m4, anglespeed, dt);
 135                         MEAN_ACCUMULATE(anticheat_idle_snapaim_m7, anglespeed, dt);
 136                         MEAN_ACCUMULATE(anticheat_idle_snapaim_m10, anglespeed, dt);
 137                 }
 138         }
 139         self.anticheat_div0_strafebot_forward_prev = v_forward;
 140
 141         // generic speedhack detection: correlate anticheat_speedhack_movetime (UPDATED BEFORE THIS) and server time
 142         self.anticheat_speedhack_movetime_frac += frametime;
 143         f = floor(self.anticheat_speedhack_movetime_frac);
 144         self.anticheat_speedhack_movetime_frac -= f;
 145         self.anticheat_speedhack_movetime_count += f;
 146         self.anticheat_speedhack_movetime = self.anticheat_speedhack_movetime_frac + self.anticheat_speedhack_movetime_count;
 147         f = self.anticheat_speedhack_movetime - servertime;
 148         if(self.anticheat_speedhack_offset == 0)
 149                 self.anticheat_speedhack_offset = f;
 150         else
 151         {
 152                 MEAN_ACCUMULATE(anticheat_speedhack, max(0, f - self.anticheat_speedhack_offset), 1);
 153                 self.anticheat_speedhack_offset += (f - self.anticheat_speedhack_offset) * frametime * 0.1;
 154         }
 155
 156         // new generic speedhack detection
 157         if (self.anticheat_speedhack_lasttime > 0) {
 158                 float dt = servertime - self.anticheat_speedhack_lasttime;
 159                 const float falloff = 0.2;
 160                 self.anticheat_speedhack_accu *= exp(-dt * falloff);
 161                 self.anticheat_speedhack_accu += frametime * falloff;
 162                 // NOTE: at cl_netfps x, this actually averages not to 1, but to 1/x * falloff / (1 - exp(-1/x * falloff))
 163                 // For 15 netfps (absolute minimum bearable), and 0.2 falloff, this is: 1.0067
 164                 self.anticheat_speedhack_lasttime = servertime;
 165                 MEAN_ACCUMULATE(anticheat_speedhack_m1, self.anticheat_speedhack_accu, frametime);
 166                 MEAN_ACCUMULATE(anticheat_speedhack_m2, self.anticheat_speedhack_accu, frametime);
 167                 MEAN_ACCUMULATE(anticheat_speedhack_m3, self.anticheat_speedhack_accu, frametime);
 168                 MEAN_ACCUMULATE(anticheat_speedhack_m4, self.anticheat_speedhack_accu, frametime);
 169                 MEAN_ACCUMULATE(anticheat_speedhack_m5, self.anticheat_speedhack_accu, frametime);
 170         } else {
 171                 self.anticheat_speedhack_accu = 1;
 172                 self.anticheat_speedhack_lasttime = servertime;
 173         }
 174 }
 175
 176 void anticheat_spectatecopy(entity spectatee)
 177 {
 178         // div0_evade -> SPECTATORS
 179         self.angles = spectatee.anticheat_div0_evade_v_angle;
 180 }
 181
 182 void anticheat_prethink()
 183 {
 184         // div0_evade -> SPECTATORS
 185         self.anticheat_div0_evade_offset = 0;
 186 }
 187
 188 string anticheat_display(float f, float tmin, float mi, float ma)
 189 {
 190         string s;
 191         s = ftos(f);
 192         if(f <= mi)
 193                 return strcat(s, ":N");
 194         if(f >= ma)
 195                 return strcat(s, ":Y");
 196         return strcat(s, ":-");
 197 }
 198
 199 void anticheat_report()
 200 {
 201         if(!autocvar_sv_eventlog)
 202                 return;
 203         // TODO(divVerent): Use xonstat to acquire good thresholds.
 204         GameLogEcho(strcat(":anticheat:_time:", ftos(self.playerid), ":", ftos(servertime - self.anticheat_jointime)));
 205         GameLogEcho(strcat(":anticheat:speedhack:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_speedhack), 240, 0, 9999))); // Actually this one seems broken.
 206         GameLogEcho(strcat(":anticheat:speedhack_m1:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_speedhack_m1), 240, 1.01, 1.25)));
 207         GameLogEcho(strcat(":anticheat:speedhack_m2:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_speedhack_m2), 240, 1.01, 1.25)));
 208         GameLogEcho(strcat(":anticheat:speedhack_m3:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_speedhack_m3), 240, 1.01, 1.25)));
 209         GameLogEcho(strcat(":anticheat:speedhack_m4:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_speedhack_m4), 240, 1.01, 1.25)));
 210         GameLogEcho(strcat(":anticheat:speedhack_m5:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_speedhack_m5), 240, 1.01, 1.25)));
 211         GameLogEcho(strcat(":anticheat:div0_strafebot_old:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_div0_strafebot_old), 120, 0.15, 0.4)));
 212         GameLogEcho(strcat(":anticheat:div0_strafebot_new:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_div0_strafebot_new), 120, 0.25, 0.8)));
 213         GameLogEcho(strcat(":anticheat:div0_evade:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_div0_evade), 120, 0.2, 0.5)));
 214         GameLogEcho(strcat(":anticheat:idle_snapaim:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_idle_snapaim_signal) - MEAN_EVALUATE(anticheat_idle_snapaim_noise), 120, 0, 9999)));
 215         GameLogEcho(strcat(":anticheat:idle_snapaim_signal:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_idle_snapaim_signal), 120, 0, 9999)));
 216         GameLogEcho(strcat(":anticheat:idle_snapaim_noise:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_idle_snapaim_noise), 120, 0, 9999)));
 217         GameLogEcho(strcat(":anticheat:idle_snapaim_m2:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_idle_snapaim_m2), 120, 0, 9999)));
 218         GameLogEcho(strcat(":anticheat:idle_snapaim_m3:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_idle_snapaim_m3), 120, 0, 9999)));
 219         GameLogEcho(strcat(":anticheat:idle_snapaim_m4:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_idle_snapaim_m4), 120, 0, 9999)));
 220         GameLogEcho(strcat(":anticheat:idle_snapaim_m7:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_idle_snapaim_m7), 120, 0, 9999)));
 221         GameLogEcho(strcat(":anticheat:idle_snapaim_m10:", ftos(self.playerid), ":", anticheat_display(MEAN_EVALUATE(anticheat_idle_snapaim_m10), 120, 0, 9999)));
 222 }
 223
 224 float anticheat_getvalue(string id)
 225 {
 226         switch(id) {
 227                 case "_time": return servertime - self.anticheat_jointime;
 228                 case "speedhack": return MEAN_EVALUATE(anticheat_speedhack);
 229                 case "speedhack_m1": return MEAN_EVALUATE(anticheat_speedhack_m1);
 230                 case "speedhack_m2": return MEAN_EVALUATE(anticheat_speedhack_m2);
 231                 case "speedhack_m3": return MEAN_EVALUATE(anticheat_speedhack_m3);
 232                 case "speedhack_m4": return MEAN_EVALUATE(anticheat_speedhack_m4);
 233                 case "speedhack_m5": return MEAN_EVALUATE(anticheat_speedhack_m5);
 234                 case "div0_strafebot_old": return MEAN_EVALUATE(anticheat_div0_strafebot_old);
 235                 case "div0_strafebot_new": return MEAN_EVALUATE(anticheat_div0_strafebot_new);
 236                 case "div0_evade": return MEAN_EVALUATE(anticheat_div0_evade);
 237                 case "idle_snapaim": return MEAN_EVALUATE(anticheat_idle_snapaim_signal) - MEAN_EVALUATE(anticheat_idle_snapaim_noise);
 238                 case "idle_snapaim_signal": return MEAN_EVALUATE(anticheat_idle_snapaim_signal);
 239                 case "idle_snapaim_noise": return MEAN_EVALUATE(anticheat_idle_snapaim_noise);
 240                 case "idle_snapaim_m2": return MEAN_EVALUATE(anticheat_idle_snapaim_m2);
 241                 case "idle_snapaim_m3": return MEAN_EVALUATE(anticheat_idle_snapaim_m3);
 242                 case "idle_snapaim_m4": return MEAN_EVALUATE(anticheat_idle_snapaim_m4);
 243                 case "idle_snapaim_m7": return MEAN_EVALUATE(anticheat_idle_snapaim_m7);
 244                 case "idle_snapaim_m10": return MEAN_EVALUATE(anticheat_idle_snapaim_m10);
 245         }
 246         return -1;
 247 }
 248
 249 void anticheat_startframe()
 250 {
 251         anticheat_div0_evade_evasion_delta += frametime * (0.5 + random());
 252 }
 253
 254 void anticheat_fixangle()
 255 {
 256         self.anticheat_fixangle_endtime = servertime + ANTILAG_LATENCY(self) + 0.2;
 257 }
 258
 259 void anticheat_endframe()
 260 {
 261         entity oldself = self;
 262         FOR_EACH_CLIENT(self)
 263                 if (self.fixangle)
 264                         anticheat_fixangle();
 265         self = oldself;
 266         anticheat_div0_evade_evasion_delta += frametime * (0.5 + random());
 267 }
 268
 269 void anticheat_init()
 270 {
 271         self.anticheat_speedhack_offset = 0;
 272         self.anticheat_jointime = servertime;
 273 }
 274
 275 void anticheat_shutdown()
 276 {
 277 }