qcsrc/server/antilag.qc

   1 #define ANTILAG_MAX_ORIGINS 64
   2 .vector antilag_origins[ANTILAG_MAX_ORIGINS];
   3 .float antilag_times[ANTILAG_MAX_ORIGINS];
   4 .float antilag_index;
   5 .vector antilag_saved_origin;
   6
   7 .float antilag_debug;
   8
   9 void antilag_dummy()
  10 {
  11         self.antilag_times = 0;
  12         self.antilag_origins = '0 0 0';
  13 }
  14
  15 void antilag_record(entity e, float t)
  16 {
  17     if(e.vehicle)
  18         antilag_record(e.vehicle, t);
  19
  20         if(time < e.(antilag_times[e.antilag_index]))
  21                 return;
  22         e.antilag_index = e.antilag_index + 1;
  23         if(e.antilag_index >= ANTILAG_MAX_ORIGINS)
  24                 e.antilag_index = 0;
  25         e.(antilag_times[e.antilag_index]) = t;
  26         e.(antilag_origins[e.antilag_index]) = e.origin;
  27
  28         if(e.antilag_debug)
  29                 te_spark(antilag_takebackorigin(e, t - e.antilag_debug), '0 0 0', 32);
  30
  31 }
  32
  33 // finds the index BEFORE t
  34 float antilag_find(entity e, float t)
  35 {
  36         float i;
  37
  38         for(i = e.antilag_index; i > 0; --i)
  39                 if(e.(antilag_times[i]) >= t)
  40                         if(e.(antilag_times[i - 1]) < t)
  41                                 return i - 1;
  42
  43         if(e.(antilag_times[0]) >= t)
  44                 if(e.(antilag_times[ANTILAG_MAX_ORIGINS - 1]) < t)
  45                         return ANTILAG_MAX_ORIGINS - 1;
  46
  47         for(i = ANTILAG_MAX_ORIGINS - 1; i > e.antilag_index + 1; --i)
  48                 if(e.(antilag_times[i]) >= t)
  49                         if(e.(antilag_times[i - 1]) < t)
  50                                 return i - 1;
  51
  52         // if we get here, t is sandwiched nowhere, so let's assume it's in the present
  53         return -1;
  54 }
  55
  56 vector lerpv(float t0, vector v0, float t1, vector v1, float t)
  57 {
  58         return v0 + (v1 - v0) * ((t - t0) / (t1 - t0));
  59 }
  60
  61 vector antilag_takebackorigin(entity e, float t)
  62 {
  63         float i0, i1;
  64
  65         i0 = antilag_find(e, t);
  66         if(i0 < 0)
  67         {
  68                 i0 = e.antilag_index - 1;
  69                 if(i0 < 0)
  70                         i0 = ANTILAG_MAX_ORIGINS - 1;
  71         }
  72         i1 = i0 + 1;
  73         if(i1 >= ANTILAG_MAX_ORIGINS)
  74                 i1 = 0;
  75
  76         return lerpv(e.(antilag_times[i0]), e.(antilag_origins[i0]), e.(antilag_times[i1]), e.(antilag_origins[i1]), t);
  77 }
  78
  79 vector antilag_takebackavgvelocity(entity e, float t0, float t1)
  80 {
  81         vector o0, o1;
  82
  83         if(t0 >= t1)
  84                 return '0 0 0';
  85         o0 = antilag_takebackorigin(e, t0);
  86         o1 = antilag_takebackorigin(e, t1);
  87         return (o1 - o0) * (1 / (t1 - t0));
  88 }
  89
  90 void antilag_takeback(entity e, float t)
  91 {
  92     if(e.vehicle)
  93         antilag_takeback(e.vehicle, t);
  94
  95         e.antilag_saved_origin = e.origin;
  96         setorigin(e, antilag_takebackorigin(e, t));
  97 }
  98
  99 void antilag_restore(entity e)
 100 {
 101     if(e.vehicle)
 102         antilag_restore(e.vehicle);
 103
 104         setorigin(e, e.antilag_saved_origin);
 105 }