qcsrc/server/bot/aim.qc

   1 #include "aim.qh"
   2 #include "../_.qh"
   3
   4 #include "bot.qh"
   5
   6 #include "../mutators/mutators_include.qh"
   7
   8 // traces multiple trajectories to find one that will impact the target
   9 // 'end' vector is the place it aims for,
  10 // returns true only if it hit targ (don't target non-solid entities)
  11
  12 float findtrajectorywithleading(vector org, vector m1, vector m2, entity targ, float shotspeed, float shotspeedupward, float maxtime, float shotdelay, entity ignore)
  13 {
  14         float c, savesolid, shottime;
  15         vector dir, end, v, o;
  16         if (shotspeed < 1)
  17                 return false; // could cause division by zero if calculated
  18         if (targ.solid < SOLID_BBOX) // SOLID_NOT and SOLID_TRIGGER
  19                 return false; // could never hit it
  20         if (!tracetossent)
  21                 tracetossent = spawn();
  22         tracetossent.owner = ignore;
  23         setsize(tracetossent, m1, m2);
  24         savesolid = targ.solid;
  25         targ.solid = SOLID_NOT;
  26         o = (targ.absmin + targ.absmax) * 0.5;
  27         shottime = ((vlen(o - org) / shotspeed) + shotdelay);
  28         v = targ.velocity * shottime + o;
  29         tracebox(o, targ.mins, targ.maxs, v, false, targ);
  30         v = trace_endpos;
  31         end = v + (targ.mins + targ.maxs) * 0.5;
  32         if ((vlen(end - org) / shotspeed + 0.2) > maxtime)
  33         {
  34                 // out of range
  35                 targ.solid = savesolid;
  36                 return false;
  37         }
  38
  39         if (!tracetossfaketarget)
  40                 tracetossfaketarget = spawn();
  41         tracetossfaketarget.solid = savesolid;
  42         tracetossfaketarget.movetype = targ.movetype;
  43         setmodel(tracetossfaketarget, targ.model); // no low precision
  44         tracetossfaketarget.model = targ.model;
  45         tracetossfaketarget.modelindex = targ.modelindex;
  46         setsize(tracetossfaketarget, targ.mins, targ.maxs);
  47         setorigin(tracetossfaketarget, v);
  48
  49         c = 0;
  50         dir = normalize(end - org);
  51         while (c < 10) // 10 traces
  52         {
  53                 setorigin(tracetossent, org); // reset
  54                 tracetossent.velocity = findtrajectory_velocity = normalize(dir) * shotspeed + shotspeedupward * '0 0 1';
  55                 tracetoss(tracetossent, ignore); // love builtin functions...
  56                 if (trace_ent == tracetossfaketarget) // done
  57                 {
  58                         targ.solid = savesolid;
  59
  60                         // make it disappear
  61                         tracetossfaketarget.solid = SOLID_NOT;
  62                         tracetossfaketarget.movetype = MOVETYPE_NONE;
  63                         tracetossfaketarget.model = "";
  64                         tracetossfaketarget.modelindex = 0;
  65                         // relink to remove it from physics considerations
  66                         setorigin(tracetossfaketarget, v);
  67
  68                         return true;
  69                 }
  70                 dir.z = dir.z + 0.1; // aim up a little more
  71                 c = c + 1;
  72         }
  73         targ.solid = savesolid;
  74
  75         // make it disappear
  76         tracetossfaketarget.solid = SOLID_NOT;
  77         tracetossfaketarget.movetype = MOVETYPE_NONE;
  78         tracetossfaketarget.model = "";
  79         tracetossfaketarget.modelindex = 0;
  80         // relink to remove it from physics considerations
  81         setorigin(tracetossfaketarget, v);
  82
  83         // leave a valid one even if it won't reach
  84         findtrajectory_velocity = normalize(end - org) * shotspeed + shotspeedupward * '0 0 1';
  85         return false;
  86 }
  87
  88 void lag_update()
  89 {
  90         if (self.lag1_time) if (time > self.lag1_time) {self.lag_func(self.lag1_time, self.lag1_float1, self.lag1_float2, self.lag1_entity1, self.lag1_vec1, self.lag1_vec2, self.lag1_vec3, self.lag1_vec4);self.lag1_time = 0;}
  91         if (self.lag2_time) if (time > self.lag2_time) {self.lag_func(self.lag2_time, self.lag2_float1, self.lag2_float2, self.lag2_entity1, self.lag2_vec1, self.lag2_vec2, self.lag2_vec3, self.lag2_vec4);self.lag2_time = 0;}
  92         if (self.lag3_time) if (time > self.lag3_time) {self.lag_func(self.lag3_time, self.lag3_float1, self.lag3_float2, self.lag3_entity1, self.lag3_vec1, self.lag3_vec2, self.lag3_vec3, self.lag3_vec4);self.lag3_time = 0;}
  93         if (self.lag4_time) if (time > self.lag4_time) {self.lag_func(self.lag4_time, self.lag4_float1, self.lag4_float2, self.lag4_entity1, self.lag4_vec1, self.lag4_vec2, self.lag4_vec3, self.lag4_vec4);self.lag4_time = 0;}
  94         if (self.lag5_time) if (time > self.lag5_time) {self.lag_func(self.lag5_time, self.lag5_float1, self.lag5_float2, self.lag5_entity1, self.lag5_vec1, self.lag5_vec2, self.lag5_vec3, self.lag5_vec4);self.lag5_time = 0;}
  95 }
  96
  97 float lag_additem(float t, float f1, float f2, entity e1, vector v1, vector v2, vector v3, vector v4)
  98 {
  99         if (self.lag1_time == 0) {self.lag1_time = t;self.lag1_float1 = f1;self.lag1_float2 = f2;self.lag1_entity1 = e1;self.lag1_vec1 = v1;self.lag1_vec2 = v2;self.lag1_vec3 = v3;self.lag1_vec4 = v4;return true;}
 100         if (self.lag2_time == 0) {self.lag2_time = t;self.lag2_float1 = f1;self.lag2_float2 = f2;self.lag2_entity1 = e1;self.lag2_vec1 = v1;self.lag2_vec2 = v2;self.lag2_vec3 = v3;self.lag2_vec4 = v4;return true;}
 101         if (self.lag3_time == 0) {self.lag3_time = t;self.lag3_float1 = f1;self.lag3_float2 = f2;self.lag3_entity1 = e1;self.lag3_vec1 = v1;self.lag3_vec2 = v2;self.lag3_vec3 = v3;self.lag3_vec4 = v4;return true;}
 102         if (self.lag4_time == 0) {self.lag4_time = t;self.lag4_float1 = f1;self.lag4_float2 = f2;self.lag4_entity1 = e1;self.lag4_vec1 = v1;self.lag4_vec2 = v2;self.lag4_vec3 = v3;self.lag4_vec4 = v4;return true;}
 103         if (self.lag5_time == 0) {self.lag5_time = t;self.lag5_float1 = f1;self.lag5_float2 = f2;self.lag5_entity1 = e1;self.lag5_vec1 = v1;self.lag5_vec2 = v2;self.lag5_vec3 = v3;self.lag5_vec4 = v4;return true;}
 104         // no room for it (what is the best thing to do here??)
 105         return false;
 106 }
 107
 108 float bot_shouldattack(entity e)
 109 {
 110         if (e.team == self.team)
 111         {
 112                 if (e == self)
 113                         return false;
 114                 if (teamplay)
 115                 if (e.team != 0)
 116                         return false;
 117         }
 118
 119         if(e.frozen)
 120                 return false;
 121
 122         // If neither player has ball then don't attack unless the ball is on the
 123         // ground.
 124         if (g_keepaway)
 125                 if (!e.ballcarried && !self.ballcarried && ka_ball.owner)
 126                         return false;
 127
 128         if(teamplay)
 129         {
 130                 if(e.team==0)
 131                         return false;
 132         }
 133         else if(bot_ignore_bots)
 134                 if(IS_BOT_CLIENT(e))
 135                         return false;
 136
 137         if (!e.takedamage)
 138                 return false;
 139         if (e.deadflag)
 140                 return false;
 141         if (e.BUTTON_CHAT)
 142                 return false;
 143         if(e.flags & FL_NOTARGET)
 144                 return false;
 145
 146         checkentity = e;
 147         if(MUTATOR_CALLHOOK(BotShouldAttack))
 148                 return false;
 149
 150         return true;
 151 }
 152
 153 void bot_lagfunc(float t, float f1, float f2, entity e1, vector v1, vector v2, vector v3, vector v4)
 154 {
 155         if(self.flags & FL_INWATER)
 156         {
 157                 self.bot_aimtarg = world;
 158                 return;
 159         }
 160         self.bot_aimtarg = e1;
 161         self.bot_aimlatency = self.ping; // FIXME?  Shouldn't this be in the lag item?
 162         self.bot_aimselforigin = v1;
 163         self.bot_aimselfvelocity = v2;
 164         self.bot_aimtargorigin = v3;
 165         self.bot_aimtargvelocity = v4;
 166         if(skill <= 0)
 167                 self.bot_canfire = (random() < 0.8);
 168         else if(skill <= 1)
 169                 self.bot_canfire = (random() < 0.9);
 170         else if(skill <= 2)
 171                 self.bot_canfire = (random() < 0.95);
 172         else
 173                 self.bot_canfire = 1;
 174 }
 175
 176 float bot_aimdir(vector v, float maxfiredeviation)
 177 {
 178         float dist, delta_t, blend;
 179         vector desiredang, diffang;
 180
 181         //dprint("aim ", self.netname, ": old:", vtos(self.v_angle));
 182         // make sure v_angle is sane first
 183         self.v_angle_y = self.v_angle.y - floor(self.v_angle.y / 360) * 360;
 184         self.v_angle_z = 0;
 185
 186         // get the desired angles to aim at
 187         //dprint(" at:", vtos(v));
 188         v = normalize(v);
 189         //te_lightning2(world, self.origin + self.view_ofs, self.origin + self.view_ofs + v * 200);
 190         if (time >= self.bot_badaimtime)
 191         {
 192                 self.bot_badaimtime = max(self.bot_badaimtime + 0.3, time);
 193                 self.bot_badaimoffset = randomvec() * bound(0, 5 - 0.5 * (skill+self.bot_offsetskill), 5) * autocvar_bot_ai_aimskill_offset;
 194         }
 195         desiredang = vectoangles(v) + self.bot_badaimoffset;
 196         //dprint(" desired:", vtos(desiredang));
 197         if (desiredang.x >= 180)
 198                 desiredang.x = desiredang.x - 360;
 199         desiredang.x = bound(-90, 0 - desiredang.x, 90);
 200         desiredang.z = self.v_angle.z;
 201         //dprint(" / ", vtos(desiredang));
 202
 203         //// pain throws off aim
 204         //if (self.bot_painintensity)
 205         //{
 206         //      // shake from pain
 207         //      desiredang = desiredang + randomvec() * self.bot_painintensity * 0.2;
 208         //}
 209
 210         // calculate turn angles
 211         diffang = (desiredang - self.bot_olddesiredang);
 212         // wrap yaw turn
 213         diffang.y = diffang.y - floor(diffang.y / 360) * 360;
 214         if (diffang.y >= 180)
 215                 diffang.y = diffang.y - 360;
 216         self.bot_olddesiredang = desiredang;
 217         //dprint(" diff:", vtos(diffang));
 218
 219         delta_t = time-self.bot_prevaimtime;
 220         self.bot_prevaimtime = time;
 221         // Here we will try to anticipate the comming aiming direction
 222         self.bot_1st_order_aimfilter= self.bot_1st_order_aimfilter
 223                 + (diffang * (1 / delta_t)    - self.bot_1st_order_aimfilter) * bound(0, autocvar_bot_ai_aimskill_order_filter_1st,1);
 224         self.bot_2nd_order_aimfilter= self.bot_2nd_order_aimfilter
 225                 + (self.bot_1st_order_aimfilter - self.bot_2nd_order_aimfilter) * bound(0, autocvar_bot_ai_aimskill_order_filter_2nd,1);
 226         self.bot_3th_order_aimfilter= self.bot_3th_order_aimfilter
 227                 + (self.bot_2nd_order_aimfilter - self.bot_3th_order_aimfilter) * bound(0, autocvar_bot_ai_aimskill_order_filter_3th,1);
 228         self.bot_4th_order_aimfilter= self.bot_4th_order_aimfilter
 229                 + (self.bot_3th_order_aimfilter - self.bot_4th_order_aimfilter) * bound(0, autocvar_bot_ai_aimskill_order_filter_4th,1);
 230         self.bot_5th_order_aimfilter= self.bot_5th_order_aimfilter
 231                 + (self.bot_4th_order_aimfilter - self.bot_5th_order_aimfilter) * bound(0, autocvar_bot_ai_aimskill_order_filter_5th,1);
 232
 233         //blend = (bound(0,skill,10)*0.1)*pow(1-bound(0,skill,10)*0.05,2.5)*5.656854249; //Plot formule before changing !
 234         blend = bound(0,skill+self.bot_aimskill,10)*0.1;
 235         desiredang = desiredang + blend *
 236         (
 237                   self.bot_1st_order_aimfilter * autocvar_bot_ai_aimskill_order_mix_1st
 238                 + self.bot_2nd_order_aimfilter * autocvar_bot_ai_aimskill_order_mix_2nd
 239                 + self.bot_3th_order_aimfilter * autocvar_bot_ai_aimskill_order_mix_3th
 240                 + self.bot_4th_order_aimfilter * autocvar_bot_ai_aimskill_order_mix_4th
 241                 + self.bot_5th_order_aimfilter * autocvar_bot_ai_aimskill_order_mix_5th
 242         );
 243
 244         // calculate turn angles
 245         diffang = desiredang - self.bot_mouseaim;
 246         // wrap yaw turn
 247         diffang.y = diffang.y - floor(diffang.y / 360) * 360;
 248         if (diffang.y >= 180)
 249                 diffang.y = diffang.y - 360;
 250         //dprint(" diff:", vtos(diffang));
 251
 252         if (time >= self.bot_aimthinktime)
 253         {
 254                 self.bot_aimthinktime = max(self.bot_aimthinktime + 0.5 - 0.05*(skill+self.bot_thinkskill), time);
 255                 self.bot_mouseaim = self.bot_mouseaim + diffang * (1-random()*0.1*bound(1,10-(skill+self.bot_thinkskill),10));
 256         }
 257
 258         //self.v_angle = self.v_angle + diffang * bound(0, r * frametime * (skill * 0.5 + 2), 1);
 259
 260         diffang = self.bot_mouseaim - desiredang;
 261         // wrap yaw turn
 262         diffang.y = diffang.y - floor(diffang.y / 360) * 360;
 263         if (diffang.y >= 180)
 264                 diffang.y = diffang.y - 360;
 265         desiredang = desiredang + diffang * bound(0,autocvar_bot_ai_aimskill_think,1);
 266
 267         // calculate turn angles
 268         diffang = desiredang - self.v_angle;
 269         // wrap yaw turn
 270         diffang.y = diffang.y - floor(diffang.y / 360) * 360;
 271         if (diffang.y >= 180)
 272                 diffang.y = diffang.y - 360;
 273         //dprint(" diff:", vtos(diffang));
 274
 275         // jitter tracking
 276         dist = vlen(diffang);
 277         //diffang = diffang + randomvec() * (dist * 0.05 * (3.5 - bound(0, skill, 3)));
 278
 279         // turn
 280         float r, fixedrate, blendrate;
 281         fixedrate = autocvar_bot_ai_aimskill_fixedrate / bound(1,dist,1000);
 282         blendrate = autocvar_bot_ai_aimskill_blendrate;
 283         r = max(fixedrate, blendrate);
 284         //self.v_angle = self.v_angle + diffang * bound(frametime, r * frametime * (2+skill*skill*0.05-random()*0.05*(10-skill)), 1);
 285         self.v_angle = self.v_angle + diffang * bound(delta_t, r * delta_t * (2+pow(skill+self.bot_mouseskill,3)*0.005-random()), 1);
 286         self.v_angle = self.v_angle * bound(0,autocvar_bot_ai_aimskill_mouse,1) + desiredang * bound(0,(1-autocvar_bot_ai_aimskill_mouse),1);
 287         //self.v_angle = self.v_angle + diffang * bound(0, r * frametime * (skill * 0.5 + 2), 1);
 288         //self.v_angle = self.v_angle + diffang * (1/ blendrate);
 289         self.v_angle_z = 0;
 290         self.v_angle_y = self.v_angle.y - floor(self.v_angle.y / 360) * 360;
 291         //dprint(" turn:", vtos(self.v_angle));
 292
 293         makevectors(self.v_angle);
 294         shotorg = self.origin + self.view_ofs;
 295         shotdir = v_forward;
 296
 297         //dprint(" dir:", vtos(v_forward));
 298         //te_lightning2(world, shotorg, shotorg + shotdir * 100);
 299
 300         // calculate turn angles again
 301         //diffang = desiredang - self.v_angle;
 302         //diffang_y = diffang_y - floor(diffang_y / 360) * 360;
 303         //if (diffang_y >= 180)
 304         //      diffang_y = diffang_y - 360;
 305
 306         //dprint("e ", vtos(diffang), " < ", ftos(maxfiredeviation), "\n");
 307
 308         // decide whether to fire this time
 309         // note the maxfiredeviation is in degrees so this has to convert to radians first
 310         //if ((normalize(v) * shotdir) >= cos(maxfiredeviation * (3.14159265358979323846 / 180)))
 311         if ((normalize(v) * shotdir) >= cos(maxfiredeviation * (3.14159265358979323846 / 180)))
 312         if (vlen(trace_endpos-shotorg) < 500+500*bound(0, skill+self.bot_aggresskill, 10) || random()*random()>bound(0,(skill+self.bot_aggresskill)*0.05,1))
 313                 self.bot_firetimer = time + bound(0.1, 0.5-(skill+self.bot_aggresskill)*0.05, 0.5);
 314         //traceline(shotorg,shotorg+shotdir*1000,false,world);
 315         //dprint(ftos(maxfiredeviation),"\n");
 316         //dprint(" diff:", vtos(diffang), "\n");
 317
 318         return self.bot_canfire && (time < self.bot_firetimer);
 319 }
 320
 321 vector bot_shotlead(vector targorigin, vector targvelocity, float shotspeed, float shotdelay)
 322 {
 323         // Try to add code here that predicts gravity effect here, no clue HOW to though ... well not yet atleast...
 324         return targorigin + targvelocity * (shotdelay + vlen(targorigin - shotorg) / shotspeed);
 325 }
 326
 327 float bot_aim(float shotspeed, float shotspeedupward, float maxshottime, float applygravity)
 328 {
 329         float f, r, hf, distanceratio;
 330         vector v;
 331         /*
 332         eprint(self);
 333         dprint("bot_aim(", ftos(shotspeed));
 334         dprint(", ", ftos(shotspeedupward));
 335         dprint(", ", ftos(maxshottime));
 336         dprint(", ", ftos(applygravity));
 337         dprint(");\n");
 338         */
 339
 340         hf = self.dphitcontentsmask;
 341         self.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 342
 343         shotspeed *= g_weaponspeedfactor;
 344         shotspeedupward *= g_weaponspeedfactor;
 345         if (!shotspeed)
 346         {
 347                 dprint("bot_aim: WARNING: weapon ", WEP_NAME(self.weapon), " shotspeed is zero!\n");
 348                 shotspeed = 1000000;
 349         }
 350         if (!maxshottime)
 351         {
 352                 dprint("bot_aim: WARNING: weapon ", WEP_NAME(self.weapon), " maxshottime is zero!\n");
 353                 maxshottime = 1;
 354         }
 355         makevectors(self.v_angle);
 356         shotorg = self.origin + self.view_ofs;
 357         shotdir = v_forward;
 358         v = bot_shotlead(self.bot_aimtargorigin, self.bot_aimtargvelocity, shotspeed, self.bot_aimlatency);
 359         distanceratio = sqrt(bound(0,skill,10000))*0.3*(vlen(v-shotorg)-100)/autocvar_bot_ai_aimskill_firetolerance_distdegrees;
 360         distanceratio = bound(0,distanceratio,1);
 361         r =  (autocvar_bot_ai_aimskill_firetolerance_maxdegrees-autocvar_bot_ai_aimskill_firetolerance_mindegrees)
 362                 * (1-distanceratio) + autocvar_bot_ai_aimskill_firetolerance_mindegrees;
 363         if (applygravity && self.bot_aimtarg)
 364         {
 365                 if (!findtrajectorywithleading(shotorg, '0 0 0', '0 0 0', self.bot_aimtarg, shotspeed, shotspeedupward, maxshottime, 0, self))
 366                 {
 367                         self.dphitcontentsmask = hf;
 368                         return false;
 369                 }
 370
 371                 f = bot_aimdir(findtrajectory_velocity - shotspeedupward * '0 0 1', r);
 372         }
 373         else
 374         {
 375                 f = bot_aimdir(v - shotorg, r);
 376                 //dprint("AIM: ");dprint(vtos(self.bot_aimtargorigin));dprint(" + ");dprint(vtos(self.bot_aimtargvelocity));dprint(" * ");dprint(ftos(self.bot_aimlatency + vlen(self.bot_aimtargorigin - shotorg) / shotspeed));dprint(" = ");dprint(vtos(v));dprint(" : aimdir = ");dprint(vtos(normalize(v - shotorg)));dprint(" : ");dprint(vtos(shotdir));dprint("\n");
 377                 //traceline(shotorg, shotorg + shotdir * 10000, false, self);
 378                 //if (trace_ent.takedamage)
 379                 //if (trace_fraction < 1)
 380                 //if (!bot_shouldattack(trace_ent))
 381                 //      return false;
 382                 traceline(shotorg, self.bot_aimtargorigin, false, self);
 383                 if (trace_fraction < 1)
 384                 if (trace_ent != self.enemy)
 385                 if (!bot_shouldattack(trace_ent))
 386                 {
 387                         self.dphitcontentsmask = hf;
 388                         return false;
 389                 }
 390         }
 391
 392         //if (r > maxshottime * shotspeed)
 393         //      return false;
 394         self.dphitcontentsmask = hf;
 395         return true;
 396 }