Fix #2177 "Bot code causes division by zero"
[xonotic/xonotic-data.pk3dir.git] / qcsrc / server / bot / default / aim.qc
1 #include "aim.qh"
2
3 #include <server/defs.qh>
4
5 #include "cvars.qh"
6
7 #include "bot.qh"
8
9 #include <common/physics/player.qh>
10 #include <common/state.qh>
11
12 #include "../../weapons/weaponsystem.qh"
13
14 #include <server/mutators/_mod.qh>
15
16 // traces multiple trajectories to find one that will impact the target
17 // 'end' vector is the place it aims for,
18 // returns true only if it hit targ (don't target non-solid entities)
19
20 float findtrajectorywithleading(vector org, vector m1, vector m2, entity targ, float shotspeed, float shotspeedupward, float maxtime, float shotdelay, entity ignore)
21 {
22         float c, savesolid, shottime;
23         vector dir, end, v, o;
24         if (shotspeed < 1)
25                 return false; // could cause division by zero if calculated
26         if (targ.solid < SOLID_BBOX) // SOLID_NOT and SOLID_TRIGGER
27                 return false; // could never hit it
28         if (!tracetossent)
29                 tracetossent = new(tracetossent);
30         tracetossent.owner = ignore;
31         setsize(tracetossent, m1, m2);
32         savesolid = targ.solid;
33         targ.solid = SOLID_NOT;
34         o = (targ.absmin + targ.absmax) * 0.5;
35         shottime = ((vlen(o - org) / shotspeed) + shotdelay);
36         v = targ.velocity * shottime + o;
37         tracebox(o, targ.mins, targ.maxs, v, false, targ);
38         v = trace_endpos;
39         end = v + (targ.mins + targ.maxs) * 0.5;
40         if ((vlen(end - org) / shotspeed + 0.2) > maxtime)
41         {
42                 // out of range
43                 targ.solid = savesolid;
44                 return false;
45         }
46
47         if (!tracetossfaketarget)
48                 tracetossfaketarget = new(tracetossfaketarget);
49         tracetossfaketarget.solid = savesolid;
50         set_movetype(tracetossfaketarget, targ.move_movetype);
51         _setmodel(tracetossfaketarget, targ.model); // no low precision
52         tracetossfaketarget.model = targ.model;
53         tracetossfaketarget.modelindex = targ.modelindex;
54         setsize(tracetossfaketarget, targ.mins, targ.maxs);
55         setorigin(tracetossfaketarget, v);
56
57         c = 0;
58         dir = normalize(end - org);
59         while (c < 10) // 10 traces
60         {
61                 setorigin(tracetossent, org); // reset
62                 tracetossent.velocity = findtrajectory_velocity = normalize(dir) * shotspeed + shotspeedupward * '0 0 1';
63                 tracetoss(tracetossent, ignore); // love builtin functions...
64                 if (trace_ent == tracetossfaketarget) // done
65                 {
66                         targ.solid = savesolid;
67
68                         // make it disappear
69                         tracetossfaketarget.solid = SOLID_NOT;
70                         set_movetype(tracetossfaketarget, MOVETYPE_NONE);
71                         tracetossfaketarget.model = "";
72                         tracetossfaketarget.modelindex = 0;
73                         // relink to remove it from physics considerations
74                         setorigin(tracetossfaketarget, v);
75
76                         return true;
77                 }
78                 dir.z = dir.z + 0.1; // aim up a little more
79                 c = c + 1;
80         }
81         targ.solid = savesolid;
82
83         // make it disappear
84         tracetossfaketarget.solid = SOLID_NOT;
85         set_movetype(tracetossfaketarget, MOVETYPE_NONE);
86         tracetossfaketarget.model = "";
87         tracetossfaketarget.modelindex = 0;
88         // relink to remove it from physics considerations
89         setorigin(tracetossfaketarget, v);
90
91         // leave a valid one even if it won't reach
92         findtrajectory_velocity = normalize(end - org) * shotspeed + shotspeedupward * '0 0 1';
93         return false;
94 }
95
96 void lag_update(entity this)
97 {
98         if (this.lag1_time && time > this.lag1_time) { this.lag_func(this, this.lag1_time, this.lag1_float1, this.lag1_float2, this.lag1_entity1, this.lag1_vec1, this.lag1_vec2, this.lag1_vec3, this.lag1_vec4); this.lag1_time = 0; }
99         if (this.lag2_time && time > this.lag2_time) { this.lag_func(this, this.lag2_time, this.lag2_float1, this.lag2_float2, this.lag2_entity1, this.lag2_vec1, this.lag2_vec2, this.lag2_vec3, this.lag2_vec4); this.lag2_time = 0; }
100         if (this.lag3_time && time > this.lag3_time) { this.lag_func(this, this.lag3_time, this.lag3_float1, this.lag3_float2, this.lag3_entity1, this.lag3_vec1, this.lag3_vec2, this.lag3_vec3, this.lag3_vec4); this.lag3_time = 0; }
101         if (this.lag4_time && time > this.lag4_time) { this.lag_func(this, this.lag4_time, this.lag4_float1, this.lag4_float2, this.lag4_entity1, this.lag4_vec1, this.lag4_vec2, this.lag4_vec3, this.lag4_vec4); this.lag4_time = 0; }
102         if (this.lag5_time && time > this.lag5_time) { this.lag_func(this, this.lag5_time, this.lag5_float1, this.lag5_float2, this.lag5_entity1, this.lag5_vec1, this.lag5_vec2, this.lag5_vec3, this.lag5_vec4); this.lag5_time = 0; }
103 }
104
105 float lag_additem(entity this, float t, float f1, float f2, entity e1, vector v1, vector v2, vector v3, vector v4)
106 {
107         if (this.lag1_time == 0) {this.lag1_time = t;this.lag1_float1 = f1;this.lag1_float2 = f2;this.lag1_entity1 = e1;this.lag1_vec1 = v1;this.lag1_vec2 = v2;this.lag1_vec3 = v3;this.lag1_vec4 = v4;return true;}
108         if (this.lag2_time == 0) {this.lag2_time = t;this.lag2_float1 = f1;this.lag2_float2 = f2;this.lag2_entity1 = e1;this.lag2_vec1 = v1;this.lag2_vec2 = v2;this.lag2_vec3 = v3;this.lag2_vec4 = v4;return true;}
109         if (this.lag3_time == 0) {this.lag3_time = t;this.lag3_float1 = f1;this.lag3_float2 = f2;this.lag3_entity1 = e1;this.lag3_vec1 = v1;this.lag3_vec2 = v2;this.lag3_vec3 = v3;this.lag3_vec4 = v4;return true;}
110         if (this.lag4_time == 0) {this.lag4_time = t;this.lag4_float1 = f1;this.lag4_float2 = f2;this.lag4_entity1 = e1;this.lag4_vec1 = v1;this.lag4_vec2 = v2;this.lag4_vec3 = v3;this.lag4_vec4 = v4;return true;}
111         if (this.lag5_time == 0) {this.lag5_time = t;this.lag5_float1 = f1;this.lag5_float2 = f2;this.lag5_entity1 = e1;this.lag5_vec1 = v1;this.lag5_vec2 = v2;this.lag5_vec3 = v3;this.lag5_vec4 = v4;return true;}
112         // no room for it (what is the best thing to do here??)
113         return false;
114 }
115
116 bool bot_shouldattack(entity this, entity targ)
117 {
118         if (targ.team == this.team)
119         {
120                 if (targ == this)
121                         return false;
122                 if (teamplay)
123                 if (targ.team != 0)
124                         return false;
125         }
126
127         if(STAT(FROZEN, targ))
128                 return false;
129
130         if(teamplay)
131         {
132                 if(targ.team==0)
133                         return false;
134         }
135         else if (autocvar_bot_ignore_bots && IS_BOT_CLIENT(targ))
136                 return false;
137
138         if (!targ.takedamage)
139                 return false;
140         if (IS_DEAD(targ))
141                 return false;
142         if (PHYS_INPUT_BUTTON_CHAT(targ) && !autocvar_bot_typefrag)
143                 return false;
144         if(targ.flags & FL_NOTARGET)
145                 return false;
146         if(targ.alpha <= 0.1 && targ.alpha != 0)
147                 return false; // invisible via alpha
148
149         if(MUTATOR_CALLHOOK(BotShouldAttack, this, targ))
150                 return false;
151
152         return true;
153 }
154
155 void bot_lagfunc(entity this, float t, float f1, float f2, entity e1, vector v1, vector v2, vector v3, vector v4)
156 {
157         this.bot_aimtarg = e1;
158         this.bot_aimlatency = CS(this).ping; // FIXME?  Shouldn't this be in the lag item?
159         //this.bot_aimorigin = v1;
160         //this.bot_aimvelocity = v2;
161         this.bot_aimtargorigin = v3;
162         this.bot_aimtargvelocity = v4;
163         if(skill <= 0)
164                 this.bot_canfire = (random() < 0.8);
165         else if(skill <= 1)
166                 this.bot_canfire = (random() < 0.9);
167         else if(skill <= 2)
168                 this.bot_canfire = (random() < 0.95);
169         else
170                 this.bot_canfire = 1;
171 }
172
173 // this function should be called after bot_aim so the aim is reset the next frame
174 void bot_aim_reset(entity this)
175 {
176         this.bot_mouseaim = this.v_angle;
177         this.bot_olddesiredang = this.v_angle;
178         this.bot_aimdir_executed = true;
179         this.bot_badaimtime = 0;
180         this.bot_aimthinktime = time;
181         this.bot_prevaimtime = time;
182         this.bot_1st_order_aimfilter = '0 0 0';
183         this.bot_2nd_order_aimfilter = '0 0 0';
184         this.bot_3th_order_aimfilter = '0 0 0';
185         this.bot_4th_order_aimfilter = '0 0 0';
186         this.bot_5th_order_aimfilter = '0 0 0';
187         this.bot_firetimer = 0;
188 }
189
190 void bot_aimdir(entity this, vector v, float maxfiredeviation)
191 {
192         float dist, delta_t, blend;
193         vector desiredang, diffang;
194
195         this.bot_aimdir_executed = true;
196
197         //dprint("aim ", this.netname, ": old:", vtos(this.v_angle));
198         // make sure v_angle is sane first
199         this.v_angle_y = this.v_angle.y - floor(this.v_angle.y / 360) * 360;
200         this.v_angle_z = 0;
201
202         // make work bot_aim_reset even if called before this function
203         if (this.bot_prevaimtime == time)
204                 return;
205
206         // invalid aim dir (can happen when bot overlaps target)
207         if(!v) return;
208
209         // get the desired angles to aim at
210         //dprint(" at:", vtos(v));
211         v = normalize(v);
212         //te_lightning2(NULL, this.origin + this.view_ofs, this.origin + this.view_ofs + v * 200);
213         if (time >= this.bot_badaimtime)
214         {
215                 this.bot_badaimtime = max(this.bot_badaimtime + 0.3, time);
216                 this.bot_badaimoffset = randomvec() * bound(0, 5 - 0.5 * (skill+this.bot_offsetskill), 5) * autocvar_bot_ai_aimskill_offset;
217         }
218         desiredang = vectoangles(v) + this.bot_badaimoffset;
219         //dprint(" desired:", vtos(desiredang));
220         if (desiredang.x >= 180)
221                 desiredang.x = desiredang.x - 360;
222         desiredang.x = bound(-90, 0 - desiredang.x, 90);
223         desiredang.z = this.v_angle.z;
224         //dprint(" / ", vtos(desiredang));
225
226         //// pain throws off aim
227         //if (this.bot_painintensity)
228         //{
229         //      // shake from pain
230         //      desiredang = desiredang + randomvec() * this.bot_painintensity * 0.2;
231         //}
232
233         // calculate turn angles
234         diffang = (desiredang - this.bot_olddesiredang);
235         // wrap yaw turn
236         diffang.y = diffang.y - floor(diffang.y / 360) * 360;
237         if (diffang.y >= 180)
238                 diffang.y = diffang.y - 360;
239         this.bot_olddesiredang = desiredang;
240         //dprint(" diff:", vtos(diffang));
241
242         delta_t = time-this.bot_prevaimtime;
243         this.bot_prevaimtime = time;
244         // Here we will try to anticipate the comming aiming direction
245         this.bot_1st_order_aimfilter= this.bot_1st_order_aimfilter
246                 + (diffang * (1 / delta_t)    - this.bot_1st_order_aimfilter) * bound(0, autocvar_bot_ai_aimskill_order_filter_1st,1);
247         this.bot_2nd_order_aimfilter= this.bot_2nd_order_aimfilter
248                 + (this.bot_1st_order_aimfilter - this.bot_2nd_order_aimfilter) * bound(0, autocvar_bot_ai_aimskill_order_filter_2nd,1);
249         this.bot_3th_order_aimfilter= this.bot_3th_order_aimfilter
250                 + (this.bot_2nd_order_aimfilter - this.bot_3th_order_aimfilter) * bound(0, autocvar_bot_ai_aimskill_order_filter_3th,1);
251         this.bot_4th_order_aimfilter= this.bot_4th_order_aimfilter
252                 + (this.bot_3th_order_aimfilter - this.bot_4th_order_aimfilter) * bound(0, autocvar_bot_ai_aimskill_order_filter_4th,1);
253         this.bot_5th_order_aimfilter= this.bot_5th_order_aimfilter
254                 + (this.bot_4th_order_aimfilter - this.bot_5th_order_aimfilter) * bound(0, autocvar_bot_ai_aimskill_order_filter_5th,1);
255
256         //blend = (bound(0,skill,10)*0.1)*((1-bound(0,skill,10)*0.05) ** 2.5)*5.656854249; //Plot formule before changing !
257         blend = bound(0,skill+this.bot_aimskill,10)*0.1;
258         desiredang = desiredang + blend *
259         (
260                   this.bot_1st_order_aimfilter * autocvar_bot_ai_aimskill_order_mix_1st
261                 + this.bot_2nd_order_aimfilter * autocvar_bot_ai_aimskill_order_mix_2nd
262                 + this.bot_3th_order_aimfilter * autocvar_bot_ai_aimskill_order_mix_3th
263                 + this.bot_4th_order_aimfilter * autocvar_bot_ai_aimskill_order_mix_4th
264                 + this.bot_5th_order_aimfilter * autocvar_bot_ai_aimskill_order_mix_5th
265         );
266         desiredang.x = bound(-90, desiredang.x, 90);
267
268         // calculate turn angles
269         diffang = desiredang - this.bot_mouseaim;
270         // wrap yaw turn
271         diffang.y = diffang.y - floor(diffang.y / 360) * 360;
272         if (diffang.y >= 180)
273                 diffang.y = diffang.y - 360;
274         //dprint(" diff:", vtos(diffang));
275
276         if (time >= this.bot_aimthinktime)
277         {
278                 this.bot_aimthinktime = max(this.bot_aimthinktime + 0.5 - 0.05*(skill+this.bot_thinkskill), time);
279                 this.bot_mouseaim = this.bot_mouseaim + diffang * (1-random()*0.1*bound(1,10-(skill+this.bot_thinkskill),10));
280         }
281
282         //this.v_angle = this.v_angle + diffang * bound(0, r * frametime * (skill * 0.5 + 2), 1);
283
284         diffang = this.bot_mouseaim - desiredang;
285         // wrap yaw turn
286         diffang.y = diffang.y - floor(diffang.y / 360) * 360;
287         if (diffang.y >= 180)
288                 diffang.y = diffang.y - 360;
289         desiredang = desiredang + diffang * bound(0,autocvar_bot_ai_aimskill_think,1);
290
291         // calculate turn angles
292         diffang = desiredang - this.v_angle;
293         // wrap yaw turn
294         diffang.y = diffang.y - floor(diffang.y / 360) * 360;
295         if (diffang.y >= 180)
296                 diffang.y = diffang.y - 360;
297         //dprint(" diff:", vtos(diffang));
298
299         // jitter tracking
300         dist = vlen(diffang);
301         //diffang = diffang + randomvec() * (dist * 0.05 * (3.5 - bound(0, skill, 3)));
302
303         // turn
304         float r, fixedrate, blendrate;
305         fixedrate = autocvar_bot_ai_aimskill_fixedrate / bound(1,dist,1000);
306         blendrate = autocvar_bot_ai_aimskill_blendrate;
307         r = max(fixedrate, blendrate);
308         //this.v_angle = this.v_angle + diffang * bound(frametime, r * frametime * (2+skill*skill*0.05-random()*0.05*(10-skill)), 1);
309         this.v_angle = this.v_angle + diffang * bound(delta_t, r * delta_t * (2 + ((skill + this.bot_mouseskill) ** 3) * 0.005 - random()), 1);
310         this.v_angle = this.v_angle * bound(0,autocvar_bot_ai_aimskill_mouse,1) + desiredang * bound(0,(1-autocvar_bot_ai_aimskill_mouse),1);
311         //this.v_angle = this.v_angle + diffang * bound(0, r * frametime * (skill * 0.5 + 2), 1);
312         //this.v_angle = this.v_angle + diffang * (1/ blendrate);
313         this.v_angle_z = 0;
314         this.v_angle_y = this.v_angle.y - floor(this.v_angle.y / 360) * 360;
315         //dprint(" turn:", vtos(this.v_angle));
316
317         makevectors(this.v_angle);
318         shotorg = this.origin + this.view_ofs;
319         shotdir = v_forward;
320
321         //dprint(" dir:", vtos(v_forward));
322         //te_lightning2(NULL, shotorg, shotorg + shotdir * 100);
323
324         // calculate turn angles again
325         //diffang = desiredang - this.v_angle;
326         //diffang_y = diffang_y - floor(diffang_y / 360) * 360;
327         //if (diffang_y >= 180)
328         //      diffang_y = diffang_y - 360;
329
330         //dprint("e ", vtos(diffang), " < ", ftos(maxfiredeviation), "\n");
331
332         // decide whether to fire this time
333         if (maxfiredeviation != 0 && v * shotdir > cos(maxfiredeviation * DEG2RAD))
334         {
335                 traceline(shotorg, shotorg + shotdir * 1000, false, NULL);
336                 if (vdist(trace_endpos - shotorg, <, 500 + 500 * bound(0, skill + this.bot_aggresskill, 10))
337                         || random() * random() > bound(0, (skill + this.bot_aggresskill) * 0.05, 1))
338                 {
339                         this.bot_firetimer = time + bound(0.1, 0.5 - (skill + this.bot_aggresskill) * 0.05, 0.5);
340                 }
341         }
342         //dprint(ftos(maxfiredeviation),"\n");
343         //dprint(" diff:", vtos(diffang), "\n");
344
345         //return this.bot_canfire && (time < this.bot_firetimer);
346 }
347
348 vector bot_shotlead(vector targorigin, vector targvelocity, float shotspeed, float shotdelay)
349 {
350         // Try to add code here that predicts gravity effect here, no clue HOW to though ... well not yet atleast...
351         return targorigin + targvelocity * (shotdelay + vlen(targorigin - shotorg) / shotspeed);
352 }
353
354 bool bot_aim(entity this, .entity weaponentity, float shotspeed, float shotspeedupward, float maxshottime, bool applygravity)
355 {
356         float r, hf, distanceratio;
357         vector v;
358         hf = this.dphitcontentsmask;
359         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
360
361         float speed_factor = W_WeaponSpeedFactor(this);
362         shotspeed *= speed_factor;
363         shotspeedupward *= speed_factor;
364         if (!shotspeed)
365         {
366                 LOG_TRACE("bot_aim: WARNING: weapon ", this.(weaponentity).m_weapon.m_name, " shotspeed is zero!");
367                 shotspeed = 1000000;
368         }
369         if (!maxshottime)
370         {
371                 LOG_TRACE("bot_aim: WARNING: weapon ", this.(weaponentity).m_weapon.m_name, " maxshottime is zero!");
372                 maxshottime = 1;
373         }
374         makevectors(this.v_angle);
375         shotorg = this.origin + this.view_ofs;
376         shotdir = v_forward;
377         v = bot_shotlead(this.bot_aimtargorigin, this.bot_aimtargvelocity, shotspeed, this.bot_aimlatency);
378         distanceratio = sqrt(bound(0,skill,10000))*0.3*(vlen(v-shotorg)-100)/autocvar_bot_ai_aimskill_firetolerance_distdegrees;
379         distanceratio = bound(0,distanceratio,1);
380         r =  (autocvar_bot_ai_aimskill_firetolerance_maxdegrees-autocvar_bot_ai_aimskill_firetolerance_mindegrees)
381                 * (1-distanceratio) + autocvar_bot_ai_aimskill_firetolerance_mindegrees;
382         if (applygravity && this.bot_aimtarg)
383         {
384                 if (!findtrajectorywithleading(shotorg, '0 0 0', '0 0 0', this.bot_aimtarg, shotspeed, shotspeedupward, maxshottime, 0, this))
385                 {
386                         this.dphitcontentsmask = hf;
387                         return false;
388                 }
389
390                 bot_aimdir(this, findtrajectory_velocity - shotspeedupward * '0 0 1', r);
391         }
392         else
393         {
394                 bot_aimdir(this, v - shotorg, r);
395                 //dprint("AIM: ");dprint(vtos(this.bot_aimtargorigin));dprint(" + ");dprint(vtos(this.bot_aimtargvelocity));dprint(" * ");dprint(ftos(this.bot_aimlatency + vlen(this.bot_aimtargorigin - shotorg) / shotspeed));dprint(" = ");dprint(vtos(v));dprint(" : aimdir = ");dprint(vtos(normalize(v - shotorg)));dprint(" : ");dprint(vtos(shotdir));dprint("\n");
396                 //traceline(shotorg, shotorg + shotdir * 10000, false, this);
397                 //if (trace_ent.takedamage)
398                 //if (trace_fraction < 1)
399                 //if (!bot_shouldattack(this, trace_ent))
400                 //      return false;
401                 traceline(shotorg, this.bot_aimtargorigin, false, this);
402                 if (trace_fraction < 1)
403                 if (trace_ent != this.enemy)
404                 if (!bot_shouldattack(this, trace_ent))
405                 {
406                         this.dphitcontentsmask = hf;
407                         return false;
408                 }
409         }
410
411         if (time > this.bot_firetimer)
412         {
413                 this.dphitcontentsmask = hf;
414                 return false;
415         }
416
417         //if (r > maxshottime * shotspeed)
418         //      return false;
419         this.dphitcontentsmask = hf;
420         return true;
421 }