qcsrc/server/bot/default/aim.qc

   1 #include "aim.qh"
   2
   3 #include <common/physics/player.qh>
   4 #include <common/state.qh>
   5 #include <common/stats.qh>
   6 #include <common/weapons/_all.qh>
   7 #include <server/bot/default/bot.qh>
   8 #include <server/bot/default/cvars.qh>
   9 #include <server/mutators/_mod.qh>
  10 #include <server/weapons/weaponsystem.qh>
  11
  12 // traces multiple trajectories to find one that will impact the target
  13 // 'end' vector is the place it aims for,
  14 // returns true only if it hit targ (don't target non-solid entities)
  15
  16 float findtrajectorywithleading(vector org, vector m1, vector m2, entity targ, float shotspeed, float shotspeedupward, float maxtime, float shotdelay, entity ignore)
  17 {
  18         float c, savesolid, shottime;
  19         vector dir, end, v, o;
  20         if (shotspeed < 1)
  21                 return false; // could cause division by zero if calculated
  22         if (targ.solid < SOLID_BBOX) // SOLID_NOT and SOLID_TRIGGER
  23                 return false; // could never hit it
  24         if (!tracetossent)
  25                 tracetossent = new(tracetossent);
  26         tracetossent.owner = ignore;
  27         setsize(tracetossent, m1, m2);
  28         savesolid = targ.solid;
  29         targ.solid = SOLID_NOT;
  30         o = (targ.absmin + targ.absmax) * 0.5;
  31         shottime = ((vlen(o - org) / shotspeed) + shotdelay);
  32         v = targ.velocity * shottime + o;
  33         tracebox(o, targ.mins, targ.maxs, v, false, targ);
  34         v = trace_endpos;
  35         end = v + (targ.mins + targ.maxs) * 0.5;
  36         if ((vlen(end - org) / shotspeed + 0.2) > maxtime)
  37         {
  38                 // out of range
  39                 targ.solid = savesolid;
  40                 return false;
  41         }
  42
  43         if (!tracetossfaketarget)
  44                 tracetossfaketarget = new(tracetossfaketarget);
  45         tracetossfaketarget.solid = savesolid;
  46         set_movetype(tracetossfaketarget, targ.move_movetype);
  47         _setmodel(tracetossfaketarget, targ.model); // no low precision
  48         tracetossfaketarget.model = targ.model;
  49         tracetossfaketarget.modelindex = targ.modelindex;
  50         setsize(tracetossfaketarget, targ.mins, targ.maxs);
  51         setorigin(tracetossfaketarget, v);
  52
  53         c = 0;
  54         dir = normalize(end - org);
  55         while (c < 10) // 10 traces
  56         {
  57                 setorigin(tracetossent, org); // reset
  58                 tracetossent.velocity = findtrajectory_velocity = normalize(dir) * shotspeed + shotspeedupward * '0 0 1';
  59                 tracetoss(tracetossent, ignore); // love builtin functions...
  60                 if (trace_ent == tracetossfaketarget) // done
  61                 {
  62                         targ.solid = savesolid;
  63
  64                         // make it disappear
  65                         tracetossfaketarget.solid = SOLID_NOT;
  66                         set_movetype(tracetossfaketarget, MOVETYPE_NONE);
  67                         tracetossfaketarget.model = "";
  68                         tracetossfaketarget.modelindex = 0;
  69                         // relink to remove it from physics considerations
  70                         setorigin(tracetossfaketarget, v);
  71
  72                         return true;
  73                 }
  74                 dir.z = dir.z + 0.1; // aim up a little more
  75                 c = c + 1;
  76         }
  77         targ.solid = savesolid;
  78
  79         // make it disappear
  80         tracetossfaketarget.solid = SOLID_NOT;
  81         set_movetype(tracetossfaketarget, MOVETYPE_NONE);
  82         tracetossfaketarget.model = "";
  83         tracetossfaketarget.modelindex = 0;
  84         // relink to remove it from physics considerations
  85         setorigin(tracetossfaketarget, v);
  86
  87         // leave a valid one even if it won't reach
  88         findtrajectory_velocity = normalize(end - org) * shotspeed + shotspeedupward * '0 0 1';
  89         return false;
  90 }
  91
  92 bool bot_shouldattack(entity this, entity targ)
  93 {
  94         if (targ.team == this.team)
  95         {
  96                 if (targ == this)
  97                         return false;
  98                 if (teamplay)
  99                 if (targ.team != 0)
 100                         return false;
 101         }
 102
 103         if(STAT(FROZEN, targ))
 104                 return false;
 105
 106         if(teamplay)
 107         {
 108                 if(targ.team==0)
 109                         return false;
 110         }
 111         else if (autocvar_bot_ignore_bots && IS_BOT_CLIENT(targ))
 112                 return false;
 113
 114         if (!targ.takedamage)
 115                 return false;
 116         if (IS_DEAD(targ))
 117                 return false;
 118         if (PHYS_INPUT_BUTTON_CHAT(targ) && !autocvar_bot_typefrag)
 119                 return false;
 120         if(targ.flags & FL_NOTARGET)
 121                 return false;
 122         if(targ.alpha <= 0.1 && targ.alpha != 0)
 123                 return false; // invisible via alpha
 124
 125         if(MUTATOR_CALLHOOK(BotShouldAttack, this, targ))
 126                 return false;
 127
 128         return true;
 129 }
 130
 131 // this function should be called after bot_aim so the aim is reset the next frame
 132 void bot_aim_reset(entity this)
 133 {
 134         this.bot_mouseaim = this.v_angle;
 135         this.bot_olddesiredang = this.v_angle;
 136         this.bot_aimdir_executed = true;
 137         this.bot_badaimtime = 0;
 138         this.bot_aimthinktime = time;
 139         this.bot_prevaimtime = time;
 140         this.bot_1st_order_aimfilter = '0 0 0';
 141         this.bot_2nd_order_aimfilter = '0 0 0';
 142         this.bot_3th_order_aimfilter = '0 0 0';
 143         this.bot_4th_order_aimfilter = '0 0 0';
 144         this.bot_5th_order_aimfilter = '0 0 0';
 145         this.bot_firetimer = 0;
 146 }
 147
 148 void bot_aimdir(entity this, vector v, float maxfiredeviation)
 149 {
 150         float dist, delta_t, blend;
 151         vector desiredang, diffang;
 152
 153         this.bot_aimdir_executed = true;
 154
 155         //dprint("aim ", this.netname, ": old:", vtos(this.v_angle));
 156         // make sure v_angle is sane first
 157         this.v_angle_y = this.v_angle.y - floor(this.v_angle.y / 360) * 360;
 158         this.v_angle_z = 0;
 159
 160         // make work bot_aim_reset even if called before this function
 161         if (this.bot_prevaimtime == time)
 162                 return;
 163
 164         // invalid aim dir (can happen when bot overlaps target)
 165         if(!v) return;
 166
 167         float skill_save = skill;
 168         // allow turning in a more natural way when bot is walking
 169         if (!this.enemy)
 170                 skill = max(4, skill);
 171
 172         // get the desired angles to aim at
 173         //dprint(" at:", vtos(v));
 174         //v = normalize(v);
 175         //te_lightning2(NULL, this.origin + this.view_ofs, this.origin + this.view_ofs + v * 200);
 176         if (time >= this.bot_badaimtime)
 177         {
 178                 this.bot_badaimtime = max(this.bot_badaimtime + 0.2 + 0.3 * random(), time);
 179                 int f = bound(0, 1 - 0.1 * (skill + this.bot_offsetskill), 1);
 180                 this.bot_badaimoffset = randomvec() * f * autocvar_bot_ai_aimskill_offset;
 181                 this.bot_badaimoffset.x *= 0.7; // smaller vertical offset
 182         }
 183         float enemy_factor = ((this.enemy) ? 5 : 2);
 184         // apply enemy_factor every frame so that the bigger offset is applied instantly when the bot aims to a new target
 185         desiredang = vectoangles(v) + this.bot_badaimoffset * enemy_factor;
 186         //dprint(" desired:", vtos(desiredang));
 187         if (desiredang.x >= 180)
 188                 desiredang.x = desiredang.x - 360;
 189         desiredang.x = bound(-90, 0 - desiredang.x, 90);
 190         desiredang.z = this.v_angle.z;
 191         //dprint(" / ", vtos(desiredang));
 192
 193         //// pain throws off aim
 194         //if (this.bot_painintensity)
 195         //{
 196         //      // shake from pain
 197         //      desiredang = desiredang + randomvec() * this.bot_painintensity * 0.2;
 198         //}
 199
 200         // calculate turn angles
 201         diffang = (desiredang - this.bot_olddesiredang);
 202         // wrap yaw turn
 203         diffang.y = diffang.y - floor(diffang.y / 360) * 360;
 204         if (diffang.y >= 180)
 205                 diffang.y = diffang.y - 360;
 206         this.bot_olddesiredang = desiredang;
 207         //dprint(" diff:", vtos(diffang));
 208
 209         delta_t = time-this.bot_prevaimtime;
 210         this.bot_prevaimtime = time;
 211         // Here we will try to anticipate the comming aiming direction
 212         this.bot_1st_order_aimfilter= this.bot_1st_order_aimfilter
 213                 + (diffang * (1 / delta_t)    - this.bot_1st_order_aimfilter) * bound(0, autocvar_bot_ai_aimskill_order_filter_1st,1);
 214         this.bot_2nd_order_aimfilter= this.bot_2nd_order_aimfilter
 215                 + (this.bot_1st_order_aimfilter - this.bot_2nd_order_aimfilter) * bound(0, autocvar_bot_ai_aimskill_order_filter_2nd,1);
 216         this.bot_3th_order_aimfilter= this.bot_3th_order_aimfilter
 217                 + (this.bot_2nd_order_aimfilter - this.bot_3th_order_aimfilter) * bound(0, autocvar_bot_ai_aimskill_order_filter_3th,1);
 218         this.bot_4th_order_aimfilter= this.bot_4th_order_aimfilter
 219                 + (this.bot_3th_order_aimfilter - this.bot_4th_order_aimfilter) * bound(0, autocvar_bot_ai_aimskill_order_filter_4th,1);
 220         this.bot_5th_order_aimfilter= this.bot_5th_order_aimfilter
 221                 + (this.bot_4th_order_aimfilter - this.bot_5th_order_aimfilter) * bound(0, autocvar_bot_ai_aimskill_order_filter_5th,1);
 222
 223         //blend = (bound(0,skill,10)*0.1)*((1-bound(0,skill,10)*0.05) ** 2.5)*5.656854249; //Plot formule before changing !
 224         blend = bound(0,skill+this.bot_aimskill,10)*0.1;
 225         desiredang = desiredang + blend *
 226         (
 227                   this.bot_1st_order_aimfilter * autocvar_bot_ai_aimskill_order_mix_1st
 228                 + this.bot_2nd_order_aimfilter * autocvar_bot_ai_aimskill_order_mix_2nd
 229                 + this.bot_3th_order_aimfilter * autocvar_bot_ai_aimskill_order_mix_3th
 230                 + this.bot_4th_order_aimfilter * autocvar_bot_ai_aimskill_order_mix_4th
 231                 + this.bot_5th_order_aimfilter * autocvar_bot_ai_aimskill_order_mix_5th
 232         );
 233         desiredang.x = bound(-90, desiredang.x, 90);
 234
 235         // calculate turn angles
 236         diffang = desiredang - this.bot_mouseaim;
 237         // wrap yaw turn
 238         diffang.y = diffang.y - floor(diffang.y / 360) * 360;
 239         if (diffang.y >= 180)
 240                 diffang.y = diffang.y - 360;
 241         //dprint(" diff:", vtos(diffang));
 242
 243         if (time >= this.bot_aimthinktime)
 244         {
 245                 this.bot_aimthinktime = max(this.bot_aimthinktime + 0.5 - 0.05*(skill+this.bot_thinkskill), time);
 246                 this.bot_mouseaim = this.bot_mouseaim + diffang * (1-random()*0.1*bound(1,10-(skill+this.bot_thinkskill),10));
 247         }
 248
 249         //this.v_angle = this.v_angle + diffang * bound(0, r * frametime * (skill * 0.5 + 2), 1);
 250
 251         diffang = this.bot_mouseaim - desiredang;
 252         // wrap yaw turn
 253         diffang.y = diffang.y - floor(diffang.y / 360) * 360;
 254         if (diffang.y >= 180)
 255                 diffang.y = diffang.y - 360;
 256         desiredang = desiredang + diffang * bound(0,autocvar_bot_ai_aimskill_think,1);
 257
 258         // calculate turn angles
 259         diffang = desiredang - this.v_angle;
 260         // wrap yaw turn
 261         diffang.y = diffang.y - floor(diffang.y / 360) * 360;
 262         if (diffang.y >= 180)
 263                 diffang.y = diffang.y - 360;
 264         //dprint(" diff:", vtos(diffang));
 265
 266         // jitter tracking
 267         dist = vlen(diffang);
 268         //diffang = diffang + randomvec() * (dist * 0.05 * (3.5 - bound(0, skill, 3)));
 269
 270         // turn
 271         float r, fixedrate, blendrate;
 272         fixedrate = autocvar_bot_ai_aimskill_fixedrate / bound(1,dist,1000);
 273         blendrate = autocvar_bot_ai_aimskill_blendrate;
 274         r = max(fixedrate, blendrate);
 275         //this.v_angle = this.v_angle + diffang * bound(frametime, r * frametime * (2+skill*skill*0.05-random()*0.05*(10-skill)), 1);
 276         r = bound(delta_t, r * delta_t * (2 + ((skill + this.bot_mouseskill) ** 3) * 0.005 - random()), 1);
 277         this.v_angle += diffang * (r + (1 - r) * bound(0, 1 - autocvar_bot_ai_aimskill_mouse, 1));
 278         this.v_angle_z = 0;
 279         this.v_angle_y = this.v_angle.y - floor(this.v_angle.y / 360) * 360;
 280         //dprint(" turn:", vtos(this.v_angle));
 281
 282         skill = skill_save;
 283
 284         if (maxfiredeviation <= 0)
 285                 return;
 286
 287         if (!autocvar_bot_ai_aimskill_firetolerance)
 288         {
 289                 this.bot_firetimer = time + 0.2;
 290                 return;
 291         }
 292
 293         makevectors(this.v_angle);
 294         shotorg = this.origin + this.view_ofs;
 295         shotdir = v_forward;
 296
 297         // decide whether to fire this time
 298         // v is the calculated trajectory, shotdir is bot view direction
 299         // NOTE: checking if (v * shotdir > cos(maxfiredeviation * DEG2RAD)) would be cheaper
 300         // but it gets evaluated to true even if v and shotdir have nearly opposite direction
 301         vector deviation = vectoangles(v) - vectoangles(shotdir);
 302         while (deviation.x < -180) deviation.x += 360; while (deviation.x > 180) deviation.x -= 360;
 303         while (deviation.y < -180) deviation.y += 360; while (deviation.y > 180) deviation.y -= 360;
 304         if (fabs(deviation.x) < maxfiredeviation && fabs(deviation.y) < maxfiredeviation)
 305         {
 306                 traceline(shotorg, shotorg + shotdir * 1000, false, NULL);
 307                 if (vdist(trace_endpos - shotorg, <, 500 + 500 * bound(0, skill + this.bot_aggresskill, 10))
 308                         || random() * random() > bound(0, (skill + this.bot_aggresskill) * 0.05, 1))
 309                 {
 310                         this.bot_firetimer = time + bound(0.1, 0.5 - (skill + this.bot_aggresskill) * 0.05, 0.5);
 311                 }
 312         }
 313 }
 314
 315 vector bot_shotlead(vector targorigin, vector targvelocity, float shotspeed, float shotdelay)
 316 {
 317         // Try to add code here that predicts gravity effect here, no clue HOW to though ... well not yet atleast...
 318         return targorigin + targvelocity * (shotdelay + vlen(targorigin - shotorg) / shotspeed);
 319 }
 320
 321 bool bot_aim(entity this, .entity weaponentity, float shotspeed, float shotspeedupward, float maxshottime, bool applygravity, bool shot_accurate)
 322 {
 323         float hf, distanceratio;
 324         vector v;
 325         hf = this.dphitcontentsmask;
 326         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
 327
 328         float speed_factor = W_WeaponSpeedFactor(this);
 329         shotspeed *= speed_factor;
 330         shotspeedupward *= speed_factor;
 331         if (!shotspeed)
 332         {
 333                 LOG_TRACE("bot_aim: WARNING: weapon ", this.(weaponentity).m_weapon.m_name, " shotspeed is zero!");
 334                 shotspeed = 1000000;
 335         }
 336         if (!maxshottime)
 337         {
 338                 LOG_TRACE("bot_aim: WARNING: weapon ", this.(weaponentity).m_weapon.m_name, " maxshottime is zero!");
 339                 maxshottime = 1;
 340         }
 341         makevectors(this.v_angle);
 342         shotorg = this.origin + this.view_ofs;
 343         shotdir = v_forward;
 344         vector enemy_org = (this.enemy.absmin + this.enemy.absmax) * 0.5;
 345         v = bot_shotlead(enemy_org, this.enemy.velocity, shotspeed, this.bot_aimlatency);
 346
 347         // this formula was created starting from empiric values of distance and max hit angle
 348         // with a player as target (32 qu wide) from the center of it right in front of the bot
 349         //  distance: 32  50    75   100  150  200  300  400  500
 350         //   max ang: 44  24  15.1  10.5  6.5  4.9  3.1  2.3  1.8
 351         float dist = max(10, vlen(v - shotorg));
 352         float maxfiredeviation = 1000 / (dist - 9) - 0.35;
 353
 354         float f = (shot_accurate) ? 1 : 1.6;
 355         f += bound(0, (10 - (skill + this.bot_aimskill)) * 0.3, 3);
 356         maxfiredeviation = min(90, maxfiredeviation * f);
 357
 358         if (applygravity && this.enemy)
 359         {
 360                 if (!findtrajectorywithleading(shotorg, '0 0 0', '0 0 0', this.enemy, shotspeed, shotspeedupward, maxshottime, 0, this))
 361                 {
 362                         this.dphitcontentsmask = hf;
 363                         return false;
 364                 }
 365
 366                 bot_aimdir(this, findtrajectory_velocity - shotspeedupward * '0 0 1', maxfiredeviation);
 367         }
 368         else
 369         {
 370                 bot_aimdir(this, v - shotorg, maxfiredeviation);
 371                 //dprint("AIM: ");dprint(vtos(enemy_org));dprint(" + ");dprint(vtos(this.enemy.velocity));dprint(" * ");dprint(ftos(this.bot_aimlatency + vlen(this.enemy.origin - shotorg) / shotspeed));dprint(" = ");dprint(vtos(v));dprint(" : aimdir = ");dprint(vtos(normalize(v - shotorg)));dprint(" : ");dprint(vtos(shotdir));dprint("\n");
 372                 //traceline(shotorg, shotorg + shotdir * 10000, false, this);
 373                 //if (trace_ent.takedamage)
 374                 //if (trace_fraction < 1)
 375                 //if (!bot_shouldattack(this, trace_ent))
 376                 //      return false;
 377                 traceline(shotorg, enemy_org, false, this);
 378                 if (trace_fraction < 1)
 379                 if (trace_ent != this.enemy)
 380                 if (!bot_shouldattack(this, trace_ent))
 381                 {
 382                         this.dphitcontentsmask = hf;
 383                         return false;
 384                 }
 385         }
 386
 387         if (time > this.bot_firetimer)
 388         {
 389                 this.dphitcontentsmask = hf;
 390                 return false;
 391         }
 392
 393         //if (r > maxshottime * shotspeed)
 394         //      return false;
 395         this.dphitcontentsmask = hf;
 396         return true;
 397 }