qcsrc/server/bot/default/bot.qc

   1 #include "bot.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "aim.qh"
   6 #include "navigation.qh"
   7 #include "scripting.qh"
   8 #include "waypoints.qh"
   9
  10 #include "havocbot/havocbot.qh"
  11 #include "havocbot/scripting.qh"
  12
  13 #include "../../teamplay.qh"
  14
  15 #include "../../antilag.qh"
  16 #include "../../autocvars.qh"
  17 #include "../../campaign.qh"
  18 #include "../../client.qh"
  19 #include "../../constants.qh"
  20 #include "../../defs.qh"
  21 #include "../../race.qh"
  22 #include <common/t_items.qh>
  23
  24 #include "../../mutators/_mod.qh"
  25
  26 #include "../../weapons/accuracy.qh"
  27
  28 #include <common/physics/player.qh>
  29 #include <common/constants.qh>
  30 #include <common/net_linked.qh>
  31 #include <common/mapinfo.qh>
  32 #include <common/teams.qh>
  33 #include <common/util.qh>
  34
  35 #include <server/scores_rules.qh>
  36
  37 #include <common/weapons/_all.qh>
  38
  39 #include <lib/csqcmodel/sv_model.qh>
  40
  41 #include <lib/warpzone/common.qh>
  42 #include <lib/warpzone/util_server.qh>
  43
  44 // TODO: remove this function! its only purpose is to update these fields since bot_setnameandstuff is called before ClientState
  45 void bot_setclientfields(entity this)
  46 {
  47         CS(this).cvar_cl_accuracy_data_share = 1;  // share the bots weapon accuracy data with the world
  48         CS(this).cvar_cl_accuracy_data_receive = 0;  // don't receive any weapon accuracy data
  49 }
  50
  51 entity bot_spawn()
  52 {
  53         entity bot = spawnclient();
  54         if (bot)
  55         {
  56                 setItemGroupCount();
  57                 currentbots = currentbots + 1;
  58                 bot_setnameandstuff(bot);
  59                 ClientConnect(bot);
  60                 bot_setclientfields(bot);
  61                 PutClientInServer(bot);
  62         }
  63         return bot;
  64 }
  65
  66 void bot_think(entity this)
  67 {
  68         if (this.bot_nextthink > time)
  69                 return;
  70
  71         this.flags &= ~FL_GODMODE;
  72         if(autocvar_bot_god)
  73                 this.flags |= FL_GODMODE;
  74
  75         this.bot_nextthink = max(time, this.bot_nextthink) + max(0.01, autocvar_bot_ai_thinkinterval * (0.5 ** this.bot_aiskill) * min(14 / (skill + 14), 1));
  76
  77         //if (this.bot_painintensity > 0)
  78         //      this.bot_painintensity = this.bot_painintensity - (skill + 1) * 40 * frametime;
  79
  80         //this.bot_painintensity = this.bot_painintensity + this.bot_oldhealth - this.health;
  81         //this.bot_painintensity = bound(0, this.bot_painintensity, 100);
  82
  83         if (!IS_PLAYER(this) || (autocvar_g_campaign && !campaign_bots_may_start))
  84         {
  85                 CS(this).movement = '0 0 0';
  86                 this.bot_nextthink = time + 0.5;
  87                 return;
  88         }
  89
  90         if (this.fixangle)
  91         {
  92                 this.v_angle = this.angles;
  93                 this.v_angle_z = 0;
  94                 this.fixangle = false;
  95         }
  96
  97         this.dmg_take = 0;
  98         this.dmg_save = 0;
  99         this.dmg_inflictor = NULL;
 100
 101         // calculate an aiming latency based on the skill setting
 102         // (simulated network latency + naturally delayed reflexes)
 103         //this.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
 104         // minimum ping 20+10 random
 105         CS(this).ping = bound(0,0.07 - bound(0, (skill + this.bot_pingskill) * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
 106         // skill 10 = ping 0.2 (adrenaline)
 107         // skill 0 = ping 0.7 (slightly drunk)
 108
 109         // clear buttons
 110         PHYS_INPUT_BUTTON_ATCK(this) = false;
 111         PHYS_INPUT_BUTTON_JUMP(this) = false;
 112         PHYS_INPUT_BUTTON_ATCK2(this) = false;
 113         PHYS_INPUT_BUTTON_ZOOM(this) = false;
 114         PHYS_INPUT_BUTTON_CROUCH(this) = false;
 115         PHYS_INPUT_BUTTON_HOOK(this) = false;
 116         PHYS_INPUT_BUTTON_INFO(this) = false;
 117         PHYS_INPUT_BUTTON_DRAG(this) = false;
 118         PHYS_INPUT_BUTTON_CHAT(this) = false;
 119         PHYS_INPUT_BUTTON_USE(this) = false;
 120
 121         if (time < game_starttime)
 122         {
 123                 // block the bot during the countdown to game start
 124                 CS(this).movement = '0 0 0';
 125                 this.bot_nextthink = game_starttime;
 126                 return;
 127         }
 128
 129         // if dead, just wait until we can respawn
 130         if (IS_DEAD(this))
 131         {
 132                 if (bot_waypoint_queue_owner == this)
 133                         bot_waypoint_queue_owner = NULL;
 134                 this.aistatus = 0;
 135                 CS(this).movement = '0 0 0';
 136                 if (this.deadflag == DEAD_DEAD)
 137                 {
 138                         PHYS_INPUT_BUTTON_JUMP(this) = true; // press jump to respawn
 139                         navigation_goalrating_timeout_force(this);
 140                 }
 141         }
 142         else if(this.aistatus & AI_STATUS_STUCK)
 143                 navigation_unstuck(this);
 144
 145         // now call the current bot AI (havocbot for example)
 146         this.bot_ai(this);
 147 }
 148
 149 void bot_setnameandstuff(entity this)
 150 {
 151         string readfile, s;
 152         float file, tokens, prio;
 153
 154         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
 155         string name, prefix, suffix;
 156
 157         if(autocvar_g_campaign)
 158         {
 159                 prefix = "";
 160                 suffix = "";
 161         }
 162         else
 163         {
 164                 prefix = autocvar_bot_prefix;
 165                 suffix = autocvar_bot_suffix;
 166         }
 167
 168         file = fopen(autocvar_bot_config_file, FILE_READ);
 169
 170         if(file < 0)
 171         {
 172                 LOG_INFOF("Error: Can not open the bot configuration file '%s'", autocvar_bot_config_file);
 173                 readfile = "";
 174         }
 175         else
 176         {
 177                 RandomSelection_Init();
 178                 while((readfile = fgets(file)))
 179                 {
 180                         if(substring(readfile, 0, 2) == "//")
 181                                 continue;
 182                         if(substring(readfile, 0, 1) == "#")
 183                                 continue;
 184                         tokens = tokenizebyseparator(readfile, "\t");
 185                         if(tokens == 0)
 186                                 continue;
 187                         s = argv(0);
 188                         prio = 1;
 189                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 190                                 if(s == it.cleanname)
 191                                 {
 192                                         prio = 0;
 193                                         break;
 194                                 }
 195                         });
 196                         RandomSelection_AddString(readfile, 1, prio);
 197                 }
 198                 readfile = RandomSelection_chosen_string;
 199                 fclose(file);
 200         }
 201
 202         tokens = tokenizebyseparator(readfile, "\t");
 203         if(argv(0) != "") bot_name = argv(0);
 204         else bot_name = "Bot";
 205
 206         if(argv(1) != "") bot_model = argv(1);
 207         else bot_model = "";
 208
 209         if(argv(2) != "") bot_skin = argv(2);
 210         else bot_skin = "0";
 211
 212         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
 213         else bot_shirt = ftos(floor(random() * 15));
 214
 215         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
 216         else bot_pants = ftos(floor(random() * 15));
 217
 218         this.bot_forced_team = stof(argv(5));
 219
 220         prio = 6;
 221
 222         #define READSKILL(f, w, r) MACRO_BEGIN { \
 223                 if(argv(prio) != "") \
 224                         this.f = stof(argv(prio)) * w; \
 225                 else \
 226                         this.f = (!autocvar_g_campaign) * (2 * random() - 1) * r * w; \
 227                 prio++; \
 228         } MACRO_END
 229         //print(bot_name, ": ping=", argv(9), "\n");
 230
 231         READSKILL(havocbot_keyboardskill, 0.5, 0.5); // keyboard skill
 232         READSKILL(bot_moveskill, 2, 0); // move skill
 233         READSKILL(bot_dodgeskill, 2, 0); // dodge skill
 234
 235         READSKILL(bot_pingskill, 0.5, 0); // ping skill
 236
 237         READSKILL(bot_weaponskill, 2, 0); // weapon skill
 238         READSKILL(bot_aggresskill, 1, 0); // aggre skill
 239         READSKILL(bot_rangepreference, 1, 0); // read skill
 240
 241         READSKILL(bot_aimskill, 2, 0); // aim skill
 242         READSKILL(bot_offsetskill, 2, 0.5); // offset skill
 243         READSKILL(bot_mouseskill, 1, 0.5); // mouse skill
 244
 245         READSKILL(bot_thinkskill, 1, 0.5); // think skill
 246         READSKILL(bot_aiskill, 2, 0); // "ai" skill
 247
 248         this.bot_config_loaded = true;
 249
 250         // this is really only a default, JoinBestTeam is called later
 251         setcolor(this, stof(bot_shirt) * 16 + stof(bot_pants));
 252         this.bot_preferredcolors = this.clientcolors;
 253
 254         // pick the name
 255         if (autocvar_bot_usemodelnames)
 256                 name = bot_model;
 257         else
 258                 name = bot_name;
 259
 260         // number bots with identical names
 261         int j = 0;
 262         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 263                 if(it.cleanname == name)
 264                         ++j;
 265         });
 266         if (j)
 267                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, "(", ftos(j), ")", suffix));
 268         else
 269                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 270
 271         this.cleanname = strzone(name);
 272
 273         // pick the model and skin
 274         if(substring(bot_model, -4, 1) != ".")
 275                 bot_model = strcat(bot_model, ".iqm");
 276         this.playermodel = this.playermodel_freeme = strzone(strcat("models/player/", bot_model));
 277         this.playerskin = this.playerskin_freeme = strzone(bot_skin);
 278 }
 279
 280 void bot_custom_weapon_priority_setup()
 281 {
 282         float tokens, i, w;
 283
 284         bot_custom_weapon = false;
 285
 286         if(     autocvar_bot_ai_custom_weapon_priority_far == "" ||
 287                 autocvar_bot_ai_custom_weapon_priority_mid == "" ||
 288                 autocvar_bot_ai_custom_weapon_priority_close == "" ||
 289                 autocvar_bot_ai_custom_weapon_priority_distances == ""
 290         )
 291                 return;
 292
 293         // Parse distances
 294         tokens = tokenizebyseparator(autocvar_bot_ai_custom_weapon_priority_distances," ");
 295
 296         if (tokens!=2)
 297                 return;
 298
 299         bot_distance_far = stof(argv(0));
 300         bot_distance_close = stof(argv(1));
 301
 302         if(bot_distance_far < bot_distance_close){
 303                 bot_distance_far = stof(argv(1));
 304                 bot_distance_close = stof(argv(0));
 305         }
 306
 307         // Initialize list of weapons
 308         bot_weapons_far[0] = -1;
 309         bot_weapons_mid[0] = -1;
 310         bot_weapons_close[0] = -1;
 311
 312         // Parse far distance weapon priorities
 313         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_far)," ");
 314
 315         int c = 0;
 316         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
 317                 w = stof(argv(i));
 318                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 319                         bot_weapons_far[c] = w;
 320                         ++c;
 321                 }
 322         }
 323         if(c < Weapons_COUNT)
 324                 bot_weapons_far[c] = -1;
 325
 326         // Parse mid distance weapon priorities
 327         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_mid)," ");
 328
 329         c = 0;
 330         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
 331                 w = stof(argv(i));
 332                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 333                         bot_weapons_mid[c] = w;
 334                         ++c;
 335                 }
 336         }
 337         if(c < Weapons_COUNT)
 338                 bot_weapons_mid[c] = -1;
 339
 340         // Parse close distance weapon priorities
 341         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_close)," ");
 342
 343         c = 0;
 344         for(i=0; i < tokens && i < Weapons_COUNT; ++i){
 345                 w = stof(argv(i));
 346                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 347                         bot_weapons_close[c] = w;
 348                         ++c;
 349                 }
 350         }
 351         if(c < Weapons_COUNT)
 352                 bot_weapons_close[c] = -1;
 353
 354         bot_custom_weapon = true;
 355 }
 356
 357 void bot_endgame()
 358 {
 359         bot_relinkplayerlist();
 360         entity e = bot_list;
 361         while (e)
 362         {
 363                 setcolor(e, e.bot_preferredcolors);
 364                 e = e.nextbot;
 365         }
 366         // if dynamic waypoints are ever implemented, save them here
 367 }
 368
 369 void bot_relinkplayerlist()
 370 {
 371         player_count = 0;
 372         currentbots = 0;
 373         bot_list = NULL;
 374
 375         entity prevbot = NULL;
 376         FOREACH_CLIENT(true,
 377         {
 378                 ++player_count;
 379
 380                 if(IS_BOT_CLIENT(it))
 381                 {
 382                         if(prevbot)
 383                                 prevbot.nextbot = it;
 384                         else
 385                                 bot_list = it;
 386                         prevbot = it;
 387                         ++currentbots;
 388                 }
 389         });
 390         if(prevbot)
 391                 prevbot.nextbot = NULL;
 392         LOG_TRACE("relink: ", ftos(currentbots), " bots seen.");
 393         bot_strategytoken = bot_list;
 394         bot_strategytoken_taken = true;
 395 }
 396
 397 void bot_clientdisconnect(entity this)
 398 {
 399         if (!IS_BOT_CLIENT(this))
 400                 return;
 401         bot_clearqueue(this);
 402         strfree(this.cleanname);
 403         strfree(this.netname_freeme);
 404         strfree(this.playermodel_freeme);
 405         strfree(this.playerskin_freeme);
 406         if(this.bot_cmd_current)
 407                 delete(this.bot_cmd_current);
 408         if(bot_waypoint_queue_owner == this)
 409                 bot_waypoint_queue_owner = NULL;
 410 }
 411
 412 void bot_clientconnect(entity this)
 413 {
 414         if (!IS_BOT_CLIENT(this)) return;
 415         this.bot_preferredcolors = this.clientcolors;
 416         this.bot_nextthink = time - random();
 417         this.lag_func = bot_lagfunc;
 418         this.isbot = true;
 419         this.createdtime = this.bot_nextthink;
 420
 421         if(!this.bot_config_loaded) // This is needed so team overrider doesn't break between matches
 422         {
 423                 bot_setnameandstuff(this);
 424                 bot_setclientfields(this);
 425         }
 426
 427         if(this.bot_forced_team==1)
 428                 this.team = NUM_TEAM_1;
 429         else if(this.bot_forced_team==2)
 430                 this.team = NUM_TEAM_2;
 431         else if(this.bot_forced_team==3)
 432                 this.team = NUM_TEAM_3;
 433         else if(this.bot_forced_team==4)
 434                 this.team = NUM_TEAM_4;
 435         else
 436                 JoinBestTeam(this, true);
 437
 438         havocbot_setupbot(this);
 439 }
 440
 441 void bot_removefromlargestteam()
 442 {
 443         CheckAllowedTeams(NULL);
 444         GetTeamCounts(NULL);
 445
 446         entity best = NULL;
 447         float besttime = 0;
 448         int bestcount = 0;
 449
 450         int bcount = 0;
 451         FOREACH_CLIENT(it.isbot,
 452         {
 453                 ++bcount;
 454
 455                 if(!best)
 456                 {
 457                         best = it;
 458                         besttime = it.createdtime;
 459                 }
 460
 461                 int thiscount = 0;
 462
 463                 switch(it.team)
 464                 {
 465                         case NUM_TEAM_1: thiscount = c1; break;
 466                         case NUM_TEAM_2: thiscount = c2; break;
 467                         case NUM_TEAM_3: thiscount = c3; break;
 468                         case NUM_TEAM_4: thiscount = c4; break;
 469                 }
 470
 471                 if(thiscount > bestcount)
 472                 {
 473                         bestcount = thiscount;
 474                         besttime = it.createdtime;
 475                         best = it;
 476                 }
 477                 else if(thiscount == bestcount && besttime < it.createdtime)
 478                 {
 479                         besttime = it.createdtime;
 480                         best = it;
 481                 }
 482         });
 483         if(!bcount)
 484                 return; // no bots to remove
 485         currentbots = currentbots - 1;
 486         dropclient(best);
 487 }
 488
 489 void bot_removenewest()
 490 {
 491         if(teamplay)
 492         {
 493                 bot_removefromlargestteam();
 494                 return;
 495         }
 496
 497         float besttime = 0;
 498         entity best = NULL;
 499         int bcount = 0;
 500
 501         FOREACH_CLIENT(it.isbot,
 502         {
 503                 ++bcount;
 504
 505                 if(!best)
 506                 {
 507                         best = it;
 508                         besttime = it.createdtime;
 509                 }
 510
 511                 if(besttime < it.createdtime)
 512                 {
 513                         besttime = it.createdtime;
 514                         best = it;
 515                 }
 516         });
 517
 518         if(!bcount)
 519                 return; // no bots to remove
 520
 521         currentbots = currentbots - 1;
 522         dropclient(best);
 523 }
 524
 525 void autoskill(float factor)
 526 {
 527         float bestbot;
 528         float bestplayer;
 529
 530         bestbot = -1;
 531         bestplayer = -1;
 532         FOREACH_CLIENT(IS_PLAYER(it), {
 533                 if(IS_REAL_CLIENT(it))
 534                         bestplayer = max(bestplayer, it.totalfrags - it.totalfrags_lastcheck);
 535                 else
 536                         bestbot = max(bestbot, it.totalfrags - it.totalfrags_lastcheck);
 537         });
 538
 539         LOG_DEBUG("autoskill: best player got ", ftos(bestplayer), ", ");
 540         LOG_DEBUG("best bot got ", ftos(bestbot), "; ");
 541         if(bestbot < 0 || bestplayer < 0)
 542         {
 543                 LOG_DEBUG("not doing anything");
 544                 // don't return, let it reset all counters below
 545         }
 546         else if(bestbot <= bestplayer * factor - 2)
 547         {
 548                 if(autocvar_skill < 17)
 549                 {
 550                         LOG_DEBUG("2 frags difference, increasing skill");
 551                         cvar_set("skill", ftos(autocvar_skill + 1));
 552                         bprint("^2SKILL UP!^7 Now at level ", ftos(autocvar_skill), "\n");
 553                 }
 554         }
 555         else if(bestbot >= bestplayer * factor + 2)
 556         {
 557                 if(autocvar_skill > 0)
 558                 {
 559                         LOG_DEBUG("2 frags difference, decreasing skill");
 560                         cvar_set("skill", ftos(autocvar_skill - 1));
 561                         bprint("^1SKILL DOWN!^7 Now at level ", ftos(autocvar_skill), "\n");
 562                 }
 563         }
 564         else
 565         {
 566                 LOG_DEBUG("not doing anything");
 567                 return;
 568                 // don't reset counters, wait for them to accumulate
 569         }
 570
 571         FOREACH_CLIENT(IS_PLAYER(it), { it.totalfrags_lastcheck = it.totalfrags; });
 572 }
 573
 574 void bot_calculate_stepheightvec()
 575 {
 576         stepheightvec = autocvar_sv_stepheight * '0 0 1';
 577         jumpheight_vec = (autocvar_sv_jumpvelocity ** 2) / (2 * autocvar_sv_gravity) * '0 0 1';
 578         jumpstepheightvec = stepheightvec + jumpheight_vec * 0.85; // reduce it a bit to make the jumps easy
 579 }
 580
 581 float bot_fixcount()
 582 {
 583         int activerealplayers = 0;
 584         int realplayers = 0;
 585         if (MUTATOR_CALLHOOK(Bot_FixCount, activerealplayers, realplayers)) {
 586                 activerealplayers = M_ARGV(0, int);
 587                 realplayers = M_ARGV(1, int);
 588         } else {
 589                 FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 590                         if(IS_PLAYER(it))
 591                                 ++activerealplayers;
 592                         ++realplayers;
 593                 });
 594         }
 595
 596         int bots;
 597         // add/remove bots if needed to make sure there are at least
 598         // minplayers+bot_number, or remove all bots if no one is playing
 599         // But don't remove bots immediately on level change, as the real players
 600         // usually haven't rejoined yet
 601         bots_would_leave = false;
 602         if (teamplay && autocvar_bot_vs_human && AvailableTeams() == 2)
 603                 bots = min(ceil(fabs(autocvar_bot_vs_human) * activerealplayers), maxclients - realplayers);
 604         else if ((realplayers || autocvar_bot_join_empty || (currentbots > 0 && time < 5)))
 605         {
 606                 float realminplayers, minplayers;
 607                 realminplayers = autocvar_minplayers;
 608                 minplayers = max(0, floor(realminplayers));
 609
 610                 float realminbots, minbots;
 611                 realminbots = autocvar_bot_number;
 612                 minbots = max(0, floor(realminbots));
 613
 614                 bots = min(max(minbots, minplayers - activerealplayers), maxclients - realplayers);
 615                 if(bots > minbots)
 616                         bots_would_leave = true;
 617         }
 618         else
 619         {
 620                 // if there are no players, remove bots
 621                 bots = 0;
 622         }
 623
 624         // only add one bot per frame to avoid utter chaos
 625         if(time > botframe_nextthink)
 626         {
 627                 if (currentbots < bots)
 628                 {
 629                         if (bot_spawn() == NULL)
 630                         {
 631                                 bprint("Can not add bot, server full.\n");
 632                                 return false;
 633                         }
 634                 }
 635                 while (currentbots > bots)
 636                         bot_removenewest();
 637         }
 638
 639         return true;
 640 }
 641
 642 void bot_remove_from_bot_list(entity this)
 643 {
 644         entity e = bot_list;
 645         entity prev_bot = NULL;
 646         while (e)
 647         {
 648                 if(e == this)
 649                 {
 650                         if(!prev_bot)
 651                                 bot_list = this.nextbot;
 652                         else
 653                                 prev_bot.nextbot = this.nextbot;
 654                         if(bot_strategytoken == this)
 655                         {
 656                                 bot_strategytoken = this.nextbot;
 657                                 bot_strategytoken_taken = true;
 658                         }
 659                         this.nextbot = NULL;
 660                         break;
 661                 }
 662                 prev_bot = e;
 663                 e = e.nextbot;
 664         }
 665 }
 666
 667 void bot_clear(entity this)
 668 {
 669         bot_remove_from_bot_list(this);
 670         if(bot_waypoint_queue_owner == this)
 671                 bot_waypoint_queue_owner = NULL;
 672         this.aistatus &= ~AI_STATUS_STUCK; // otherwise bot_waypoint_queue_owner will be set again to this by navigation_unstuck
 673 }
 674
 675 void bot_serverframe()
 676 {
 677         if (intermission_running && currentbots > 0)
 678         {
 679                 // after the end of the match all bots stay unless all human players disconnect
 680                 int realplayers = 0;
 681                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++realplayers; });
 682                 if (!realplayers)
 683                 {
 684                         FOREACH_CLIENT(IS_BOT_CLIENT(it), { dropclient(it); });
 685                         currentbots = 0;
 686                 }
 687                 return;
 688         }
 689
 690         if (game_stopped)
 691                 return;
 692
 693         // Added 0.5 to avoid possible addition + immediate removal of bots that would make them appear as
 694         // spectators in the scoreboard and never go away. This issue happens at time 2 if map is changed
 695         // with the gotomap command, minplayers is > 1 and human clients join as players very soon
 696         // either intentionally or automatically (sv_spectate 0)
 697         if (time < 2.5)
 698         {
 699                 currentbots = -1;
 700                 return;
 701         }
 702
 703         if (currentbots == -1)
 704         {
 705                 // count bots already in the server from the previous match
 706                 currentbots = 0;
 707                 FOREACH_CLIENT(IS_BOT_CLIENT(it), { ++currentbots; });
 708         }
 709
 710         if(autocvar_skill != skill)
 711         {
 712                 float wpcost_update = false;
 713                 if(skill >= autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill < autocvar_bot_ai_bunnyhop_skilloffset)
 714                         wpcost_update = true;
 715                 if(skill < autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 716                         wpcost_update = true;
 717
 718                 skill = autocvar_skill;
 719                 if (wpcost_update)
 720                         waypoint_updatecost_foralllinks();
 721         }
 722
 723         bot_calculate_stepheightvec();
 724         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 725
 726         if(time > autoskill_nextthink)
 727         {
 728                 float a;
 729                 a = autocvar_skill_auto;
 730                 if(a)
 731                         autoskill(a);
 732                 autoskill_nextthink = time + 5;
 733         }
 734
 735         if(time > botframe_nextthink)
 736         {
 737                 if(!bot_fixcount())
 738                         botframe_nextthink = time + 10;
 739         }
 740
 741         if(botframe_spawnedwaypoints)
 742         {
 743                 if(autocvar_waypoint_benchmark)
 744                         localcmd("quit\n");
 745         }
 746
 747         if (currentbots > 0 || autocvar_g_waypointeditor || autocvar_g_waypointeditor_auto)
 748         if (botframe_spawnedwaypoints)
 749         {
 750                 if(botframe_cachedwaypointlinks)
 751                 {
 752                         if(!botframe_loadedforcedlinks)
 753                                 waypoint_load_links_hardwired();
 754                 }
 755                 else
 756                 {
 757                         // TODO: Make this check cleaner
 758                         IL_EACH(g_waypoints, time - it.nextthink > 10,
 759                         {
 760                                 waypoint_save_links();
 761                                 break;
 762                         });
 763                 }
 764         }
 765         else
 766         {
 767                 botframe_spawnedwaypoints = true;
 768                 waypoint_loadall();
 769                 waypoint_load_links();
 770         }
 771
 772         if (bot_list)
 773         {
 774                 // cycle the goal token from one bot to the next each frame
 775                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
 776                 //  frame, which causes choppy framerates)
 777                 if (bot_strategytoken_taken)
 778                 {
 779                         // give goal token to the first bot without goals; if all bots don't have
 780                         // any goal (or are dead/frozen) simply give it to the next one
 781                         bot_strategytoken_taken = false;
 782                         entity bot_strategytoken_save = bot_strategytoken;
 783                         while (true)
 784                         {
 785                                 if (bot_strategytoken)
 786                                         bot_strategytoken = bot_strategytoken.nextbot;
 787                                 if (!bot_strategytoken)
 788                                         bot_strategytoken = bot_list;
 789
 790                                 if (!(IS_DEAD(bot_strategytoken) || STAT(FROZEN, bot_strategytoken))
 791                                         && !bot_strategytoken.goalcurrent)
 792                                         break;
 793
 794                                 if (!bot_strategytoken_save) // break loop if all the bots are dead or frozen
 795                                         break;
 796                                 if (bot_strategytoken == bot_strategytoken_save)
 797                                         bot_strategytoken_save = NULL; // looped through all the bots
 798                         }
 799                 }
 800
 801                 if (botframe_nextdangertime < time)
 802                 {
 803                         float interval;
 804                         interval = autocvar_bot_ai_dangerdetectioninterval;
 805                         if (botframe_nextdangertime < time - interval * 1.5)
 806                                 botframe_nextdangertime = time;
 807                         botframe_nextdangertime = botframe_nextdangertime + interval;
 808                         botframe_updatedangerousobjects(autocvar_bot_ai_dangerdetectionupdates);
 809                 }
 810         }
 811
 812         if (autocvar_g_waypointeditor)
 813                 botframe_showwaypointlinks();
 814
 815         if (autocvar_g_waypointeditor_auto)
 816                 botframe_autowaypoints();
 817
 818         if(time > bot_cvar_nextthink)
 819         {
 820                 if(currentbots>0)
 821                         bot_custom_weapon_priority_setup();
 822                 bot_cvar_nextthink = time + 5;
 823         }
 824 }