qcsrc/server/bot/default/bot.qc

   1 #include "bot.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "aim.qh"
   6 #include "navigation.qh"
   7 #include "scripting.qh"
   8 #include "waypoints.qh"
   9
  10 #include "havocbot/havocbot.qh"
  11 #include "havocbot/scripting.qh"
  12
  13 #include "../../teamplay.qh"
  14
  15 #include "../../antilag.qh"
  16 #include "../../autocvars.qh"
  17 #include "../../campaign.qh"
  18 #include "../../client.qh"
  19 #include "../../constants.qh"
  20 #include "../../defs.qh"
  21 #include "../../race.qh"
  22 #include <common/t_items.qh>
  23
  24 #include <server/mutators/_mod.qh>
  25
  26 #include "../../weapons/accuracy.qh"
  27
  28 #include <common/physics/player.qh>
  29 #include <common/constants.qh>
  30 #include <common/net_linked.qh>
  31 #include <common/mapinfo.qh>
  32 #include <common/teams.qh>
  33 #include <common/util.qh>
  34
  35 #include <server/scores_rules.qh>
  36
  37 #include <common/weapons/_all.qh>
  38
  39 #include <lib/csqcmodel/sv_model.qh>
  40
  41 #include <lib/warpzone/common.qh>
  42 #include <lib/warpzone/util_server.qh>
  43
  44 STATIC_INIT(bot) { bot_calculate_stepheightvec(); }
  45
  46 // TODO: remove this function! its only purpose is to update these fields since bot_setnameandstuff is called before ClientState
  47 void bot_setclientfields(entity this)
  48 {
  49         CS(this).cvar_cl_accuracy_data_share = 1;  // share the bots weapon accuracy data with the world
  50         CS(this).cvar_cl_accuracy_data_receive = 0;  // don't receive any weapon accuracy data
  51 }
  52
  53 entity bot_spawn()
  54 {
  55         entity bot = spawnclient();
  56         if (bot)
  57         {
  58                 setItemGroupCount();
  59                 currentbots = currentbots + 1;
  60                 bot_setnameandstuff(bot);
  61                 ClientConnect(bot);
  62                 bot_setclientfields(bot);
  63                 PutClientInServer(bot);
  64         }
  65         return bot;
  66 }
  67
  68 void bot_think(entity this)
  69 {
  70         if (this.bot_nextthink > time)
  71                 return;
  72
  73         this.flags &= ~FL_GODMODE;
  74         if(autocvar_bot_god)
  75                 this.flags |= FL_GODMODE;
  76
  77         this.bot_nextthink = max(time, this.bot_nextthink) + max(0.01, autocvar_bot_ai_thinkinterval * (0.5 ** this.bot_aiskill) * min(14 / (skill + 14), 1));
  78
  79         if (!IS_PLAYER(this) || (autocvar_g_campaign && !campaign_bots_may_start))
  80         {
  81                 CS(this).movement = '0 0 0';
  82                 this.bot_nextthink = time + 0.5;
  83                 return;
  84         }
  85
  86         if (this.fixangle)
  87         {
  88                 this.v_angle = this.angles;
  89                 this.v_angle_z = 0;
  90                 this.fixangle = false;
  91         }
  92
  93         this.dmg_take = 0;
  94         this.dmg_save = 0;
  95         this.dmg_inflictor = NULL;
  96
  97         // calculate an aiming latency based on the skill setting
  98         // (simulated network latency + naturally delayed reflexes)
  99         //this.ping = 0.7 - bound(0, 0.05 * skill, 0.5); // moved the reflexes to bot_aimdir (under the name 'think')
 100         // minimum ping 20+10 random
 101         CS(this).ping = bound(0,0.07 - bound(0, (skill + this.bot_pingskill) * 0.005,0.05)+random()*0.01,0.65); // Now holds real lag to server, and higer skill players take a less laggy server
 102         // skill 10 = ping 0.2 (adrenaline)
 103         // skill 0 = ping 0.7 (slightly drunk)
 104
 105         // clear buttons
 106         PHYS_INPUT_BUTTON_ATCK(this) = false;
 107         PHYS_INPUT_BUTTON_JUMP(this) = false;
 108         PHYS_INPUT_BUTTON_ATCK2(this) = false;
 109         PHYS_INPUT_BUTTON_ZOOM(this) = false;
 110         PHYS_INPUT_BUTTON_CROUCH(this) = false;
 111         PHYS_INPUT_BUTTON_HOOK(this) = false;
 112         PHYS_INPUT_BUTTON_INFO(this) = false;
 113         PHYS_INPUT_BUTTON_DRAG(this) = false;
 114         PHYS_INPUT_BUTTON_CHAT(this) = false;
 115         PHYS_INPUT_BUTTON_USE(this) = false;
 116
 117         if (time < game_starttime)
 118         {
 119                 // block the bot during the countdown to game start
 120                 CS(this).movement = '0 0 0';
 121                 this.bot_nextthink = game_starttime;
 122                 return;
 123         }
 124
 125         // if dead, just wait until we can respawn
 126         if (IS_DEAD(this))
 127         {
 128                 if (bot_waypoint_queue_owner == this)
 129                         bot_waypoint_queue_owner = NULL;
 130                 this.aistatus = 0;
 131                 CS(this).movement = '0 0 0';
 132                 if (this.deadflag == DEAD_DEAD)
 133                 {
 134                         PHYS_INPUT_BUTTON_JUMP(this) = true; // press jump to respawn
 135                         navigation_goalrating_timeout_force(this);
 136                 }
 137         }
 138         else if(this.aistatus & AI_STATUS_STUCK)
 139                 navigation_unstuck(this);
 140
 141         // now call the current bot AI (havocbot for example)
 142         this.bot_ai(this);
 143 }
 144
 145 void bot_setnameandstuff(entity this)
 146 {
 147         string readfile, s;
 148         float file, tokens, prio;
 149
 150         string bot_name, bot_model, bot_skin, bot_shirt, bot_pants;
 151         string name, prefix, suffix;
 152
 153         if(autocvar_g_campaign)
 154         {
 155                 prefix = "";
 156                 suffix = "";
 157         }
 158         else
 159         {
 160                 prefix = autocvar_bot_prefix;
 161                 suffix = autocvar_bot_suffix;
 162         }
 163
 164         file = fopen(autocvar_bot_config_file, FILE_READ);
 165
 166         if(file < 0)
 167         {
 168                 LOG_INFOF("Error: Can not open the bot configuration file '%s'", autocvar_bot_config_file);
 169                 readfile = "";
 170         }
 171         else
 172         {
 173                 RandomSelection_Init();
 174                 while((readfile = fgets(file)))
 175                 {
 176                         if(substring(readfile, 0, 2) == "//")
 177                                 continue;
 178                         if(substring(readfile, 0, 1) == "#")
 179                                 continue;
 180                         tokens = tokenizebyseparator(readfile, "\t");
 181                         if(tokens == 0)
 182                                 continue;
 183                         s = argv(0);
 184                         prio = 1;
 185                         FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 186                                 if(s == it.cleanname)
 187                                 {
 188                                         prio = 0;
 189                                         break;
 190                                 }
 191                         });
 192                         RandomSelection_AddString(readfile, 1, prio);
 193                 }
 194                 readfile = RandomSelection_chosen_string;
 195                 fclose(file);
 196         }
 197
 198         tokens = tokenizebyseparator(readfile, "\t");
 199         if(argv(0) != "") bot_name = argv(0);
 200         else bot_name = "Bot";
 201
 202         if(argv(1) != "") bot_model = argv(1);
 203         else bot_model = "";
 204
 205         if(argv(2) != "") bot_skin = argv(2);
 206         else bot_skin = "0";
 207
 208         if(argv(3) != "" && stof(argv(3)) >= 0) bot_shirt = argv(3);
 209         else bot_shirt = ftos(floor(random() * 15));
 210
 211         if(argv(4) != "" && stof(argv(4)) >= 0) bot_pants = argv(4);
 212         else bot_pants = ftos(floor(random() * 15));
 213
 214         this.bot_forced_team = stof(argv(5));
 215
 216         prio = 6;
 217
 218         #define READSKILL(f, w, r) MACRO_BEGIN \
 219                 if(argv(prio) != "") \
 220                         this.f = stof(argv(prio)) * w; \
 221                 else \
 222                         this.f = (!autocvar_g_campaign) * (2 * random() - 1) * r * w; \
 223                 prio++; \
 224         MACRO_END
 225         //print(bot_name, ": ping=", argv(9), "\n");
 226
 227         READSKILL(havocbot_keyboardskill, 0.5, 0.5); // keyboard skill
 228         READSKILL(bot_moveskill, 2, 0); // move skill
 229         READSKILL(bot_dodgeskill, 2, 0); // dodge skill
 230
 231         READSKILL(bot_pingskill, 0.5, 0); // ping skill
 232
 233         READSKILL(bot_weaponskill, 2, 0); // weapon skill
 234         READSKILL(bot_aggresskill, 1, 0); // aggre skill
 235         READSKILL(bot_rangepreference, 1, 0); // read skill
 236
 237         READSKILL(bot_aimskill, 2, 0); // aim skill
 238         READSKILL(bot_offsetskill, 2, 0.5); // offset skill
 239         READSKILL(bot_mouseskill, 1, 0.5); // mouse skill
 240
 241         READSKILL(bot_thinkskill, 1, 0.5); // think skill
 242         READSKILL(bot_aiskill, 2, 0); // "ai" skill
 243
 244         this.bot_config_loaded = true;
 245
 246         // this is really only a default, TeamBalance_JoinBestTeam is called later
 247         setcolor(this, stof(bot_shirt) * 16 + stof(bot_pants));
 248         this.bot_preferredcolors = this.clientcolors;
 249
 250         // pick the name
 251         if (autocvar_bot_usemodelnames)
 252                 name = bot_model;
 253         else
 254                 name = bot_name;
 255
 256         // number bots with identical names
 257         if (name == "")
 258         {
 259                 name = ftos(etof(this));
 260                 this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 261         }
 262         else
 263         {
 264                 int j = 0;
 265                 FOREACH_CLIENT(IS_BOT_CLIENT(it), {
 266                         if(it.cleanname == name)
 267                                 ++j;
 268                 });
 269                 if (j)
 270                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, "(", ftos(j), ")", suffix));
 271                 else
 272                         this.netname = this.netname_freeme = strzone(strcat(prefix, name, suffix));
 273         }
 274         this.cleanname = strzone(name);
 275
 276         // pick the model and skin
 277         if(substring(bot_model, -4, 1) != ".")
 278                 bot_model = strcat(bot_model, ".iqm");
 279         this.playermodel = this.playermodel_freeme = strzone(strcat("models/player/", bot_model));
 280         this.playerskin = this.playerskin_freeme = strzone(bot_skin);
 281 }
 282
 283 void bot_custom_weapon_priority_setup()
 284 {
 285         float tokens, i, w;
 286
 287         bot_custom_weapon = false;
 288
 289         if(     autocvar_bot_ai_custom_weapon_priority_far == "" ||
 290                 autocvar_bot_ai_custom_weapon_priority_mid == "" ||
 291                 autocvar_bot_ai_custom_weapon_priority_close == "" ||
 292                 autocvar_bot_ai_custom_weapon_priority_distances == ""
 293         )
 294                 return;
 295
 296         // Parse distances
 297         tokens = tokenizebyseparator(autocvar_bot_ai_custom_weapon_priority_distances," ");
 298
 299         if (tokens!=2)
 300                 return;
 301
 302         bot_distance_far = stof(argv(0));
 303         bot_distance_close = stof(argv(1));
 304
 305         if(bot_distance_far < bot_distance_close){
 306                 bot_distance_far = stof(argv(1));
 307                 bot_distance_close = stof(argv(0));
 308         }
 309
 310         // Initialize list of weapons
 311         bot_weapons_far[0] = -1;
 312         bot_weapons_mid[0] = -1;
 313         bot_weapons_close[0] = -1;
 314
 315         // Parse far distance weapon priorities
 316         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_far)," ");
 317
 318         int c = 0;
 319         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
 320                 w = stof(argv(i));
 321                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 322                         bot_weapons_far[c] = w;
 323                         ++c;
 324                 }
 325         }
 326         if(c < Weapons_COUNT)
 327                 bot_weapons_far[c] = -1;
 328
 329         // Parse mid distance weapon priorities
 330         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_mid)," ");
 331
 332         c = 0;
 333         for(i=0; i < tokens && c < Weapons_COUNT; ++i){
 334                 w = stof(argv(i));
 335                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 336                         bot_weapons_mid[c] = w;
 337                         ++c;
 338                 }
 339         }
 340         if(c < Weapons_COUNT)
 341                 bot_weapons_mid[c] = -1;
 342
 343         // Parse close distance weapon priorities
 344         tokens = tokenizebyseparator(W_NumberWeaponOrder(autocvar_bot_ai_custom_weapon_priority_close)," ");
 345
 346         c = 0;
 347         for(i=0; i < tokens && i < Weapons_COUNT; ++i){
 348                 w = stof(argv(i));
 349                 if ( w >= WEP_FIRST && w <= WEP_LAST) {
 350                         bot_weapons_close[c] = w;
 351                         ++c;
 352                 }
 353         }
 354         if(c < Weapons_COUNT)
 355                 bot_weapons_close[c] = -1;
 356
 357         bot_custom_weapon = true;
 358 }
 359
 360 void bot_endgame()
 361 {
 362         bot_relinkplayerlist();
 363         entity e = bot_list;
 364         while (e)
 365         {
 366                 setcolor(e, e.bot_preferredcolors);
 367                 e = e.nextbot;
 368         }
 369         // if dynamic waypoints are ever implemented, save them here
 370 }
 371
 372 void bot_relinkplayerlist()
 373 {
 374         player_count = 0;
 375         currentbots = 0;
 376         bot_list = NULL;
 377
 378         entity prevbot = NULL;
 379         FOREACH_CLIENT(true,
 380         {
 381                 ++player_count;
 382
 383                 if(IS_BOT_CLIENT(it))
 384                 {
 385                         if(prevbot)
 386                                 prevbot.nextbot = it;
 387                         else
 388                                 bot_list = it;
 389                         prevbot = it;
 390                         ++currentbots;
 391                 }
 392         });
 393         if(prevbot)
 394                 prevbot.nextbot = NULL;
 395         LOG_TRACE("relink: ", ftos(currentbots), " bots seen.");
 396         bot_strategytoken = bot_list;
 397         bot_strategytoken_taken = true;
 398 }
 399
 400 void bot_clientdisconnect(entity this)
 401 {
 402         if (!IS_BOT_CLIENT(this))
 403                 return;
 404         bot_clearqueue(this);
 405         strfree(this.cleanname);
 406         strfree(this.netname_freeme);
 407         strfree(this.playermodel_freeme);
 408         strfree(this.playerskin_freeme);
 409         if(this.bot_cmd_current)
 410                 delete(this.bot_cmd_current);
 411         if(bot_waypoint_queue_owner == this)
 412                 bot_waypoint_queue_owner = NULL;
 413 }
 414
 415 void bot_clientconnect(entity this)
 416 {
 417         if (!IS_BOT_CLIENT(this)) return;
 418         this.bot_preferredcolors = this.clientcolors;
 419         this.bot_nextthink = time - random();
 420         this.lag_func = bot_lagfunc;
 421         this.isbot = true;
 422         this.createdtime = this.bot_nextthink;
 423
 424         if(!this.bot_config_loaded) // This is needed so team overrider doesn't break between matches
 425         {
 426                 bot_setnameandstuff(this);
 427                 bot_setclientfields(this);
 428         }
 429
 430         if (Team_IsValidIndex(this.bot_forced_team))
 431         {
 432                 SetPlayerTeam(this, this.bot_forced_team, TEAM_CHANGE_MANUAL);
 433         }
 434         else
 435         {
 436                 this.bot_forced_team = 0;
 437                 TeamBalance_JoinBestTeam(this);
 438         }
 439
 440         havocbot_setupbot(this);
 441 }
 442
 443 void bot_removefromlargestteam()
 444 {
 445         entity balance = TeamBalance_CheckAllowedTeams(NULL);
 446         TeamBalance_GetTeamCounts(balance, NULL);
 447
 448         entity best = NULL;
 449         float besttime = 0;
 450         int bestcount = 0;
 451
 452         int bcount = 0;
 453         FOREACH_CLIENT(it.isbot,
 454         {
 455                 ++bcount;
 456
 457                 if(!best)
 458                 {
 459                         best = it;
 460                         besttime = it.createdtime;
 461                 }
 462
 463                 int thiscount = 0;
 464
 465                 if (Team_IsValidTeam(it.team))
 466                 {
 467                         thiscount = TeamBalance_GetNumberOfPlayers(balance,
 468                                 Team_TeamToIndex(it.team));
 469                 }
 470
 471                 if(thiscount > bestcount)
 472                 {
 473                         bestcount = thiscount;
 474                         besttime = it.createdtime;
 475                         best = it;
 476                 }
 477                 else if(thiscount == bestcount && besttime < it.createdtime)
 478                 {
 479                         besttime = it.createdtime;
 480                         best = it;
 481                 }
 482         });
 483         TeamBalance_Destroy(balance);
 484         if(!bcount)
 485                 return; // no bots to remove
 486         currentbots = currentbots - 1;
 487         dropclient(best);
 488 }
 489
 490 void bot_removenewest()
 491 {
 492         if(teamplay)
 493         {
 494                 bot_removefromlargestteam();
 495                 return;
 496         }
 497
 498         float besttime = 0;
 499         entity best = NULL;
 500         int bcount = 0;
 501
 502         FOREACH_CLIENT(it.isbot,
 503         {
 504                 ++bcount;
 505
 506                 if(!best)
 507                 {
 508                         best = it;
 509                         besttime = it.createdtime;
 510                 }
 511
 512                 if(besttime < it.createdtime)
 513                 {
 514                         besttime = it.createdtime;
 515                         best = it;
 516                 }
 517         });
 518
 519         if(!bcount)
 520                 return; // no bots to remove
 521
 522         currentbots = currentbots - 1;
 523         dropclient(best);
 524 }
 525
 526 void autoskill(float factor)
 527 {
 528         float bestbot;
 529         float bestplayer;
 530
 531         bestbot = -1;
 532         bestplayer = -1;
 533         FOREACH_CLIENT(IS_PLAYER(it), {
 534                 if(IS_REAL_CLIENT(it))
 535                         bestplayer = max(bestplayer, it.totalfrags - it.totalfrags_lastcheck);
 536                 else
 537                         bestbot = max(bestbot, it.totalfrags - it.totalfrags_lastcheck);
 538         });
 539
 540         LOG_DEBUG("autoskill: best player got ", ftos(bestplayer), ", ");
 541         LOG_DEBUG("best bot got ", ftos(bestbot), "; ");
 542         if(bestbot < 0 || bestplayer < 0)
 543         {
 544                 LOG_DEBUG("not doing anything");
 545                 // don't return, let it reset all counters below
 546         }
 547         else if(bestbot <= bestplayer * factor - 2)
 548         {
 549                 if(autocvar_skill < 17)
 550                 {
 551                         LOG_DEBUG("2 frags difference, increasing skill");
 552                         cvar_set("skill", ftos(autocvar_skill + 1));
 553                         bprint("^2SKILL UP!^7 Now at level ", ftos(autocvar_skill), "\n");
 554                 }
 555         }
 556         else if(bestbot >= bestplayer * factor + 2)
 557         {
 558                 if(autocvar_skill > 0)
 559                 {
 560                         LOG_DEBUG("2 frags difference, decreasing skill");
 561                         cvar_set("skill", ftos(autocvar_skill - 1));
 562                         bprint("^1SKILL DOWN!^7 Now at level ", ftos(autocvar_skill), "\n");
 563                 }
 564         }
 565         else
 566         {
 567                 LOG_DEBUG("not doing anything");
 568                 return;
 569                 // don't reset counters, wait for them to accumulate
 570         }
 571
 572         FOREACH_CLIENT(IS_PLAYER(it), { it.totalfrags_lastcheck = it.totalfrags; });
 573 }
 574
 575 void bot_calculate_stepheightvec()
 576 {
 577         stepheightvec = autocvar_sv_stepheight * '0 0 1';
 578         jumpheight_vec = (autocvar_sv_jumpvelocity ** 2) / (2 * autocvar_sv_gravity) * '0 0 1';
 579         jumpstepheightvec = stepheightvec + jumpheight_vec * 0.85; // reduce it a bit to make the jumps easy
 580 }
 581
 582 bool bot_fixcount()
 583 {
 584         int activerealplayers = 0;
 585         int realplayers = 0;
 586         if (MUTATOR_CALLHOOK(Bot_FixCount, activerealplayers, realplayers)) {
 587                 activerealplayers = M_ARGV(0, int);
 588                 realplayers = M_ARGV(1, int);
 589         } else {
 590                 FOREACH_CLIENT(IS_REAL_CLIENT(it), {
 591                         if(IS_PLAYER(it))
 592                                 ++activerealplayers;
 593                         ++realplayers;
 594                 });
 595         }
 596
 597         int bots;
 598         // But don't remove bots immediately on level change, as the real players
 599         // usually haven't rejoined yet
 600         bots_would_leave = false;
 601         if (teamplay && autocvar_bot_vs_human && AvailableTeams() == 2)
 602                 bots = min(ceil(fabs(autocvar_bot_vs_human) * activerealplayers), maxclients - realplayers);
 603         else if ((realplayers || autocvar_bot_join_empty || (currentbots > 0 && time < 5)))
 604         {
 605                 int minplayers = max(0, floor(autocvar_minplayers));
 606                 if (teamplay)
 607                         minplayers = max(0, floor(autocvar_minplayers_per_team) * AvailableTeams());
 608                 int minbots = max(0, floor(autocvar_bot_number));
 609
 610                 // add bots to reach minplayers if needed
 611                 bots = max(minbots, minplayers - activerealplayers);
 612                 // cap bots to the max players allowed by the server
 613                 int player_limit = GetPlayerLimit();
 614                 if(player_limit)
 615                         bots = min(bots, max(player_limit - activerealplayers, 0));
 616                 bots = min(bots, maxclients - realplayers);
 617
 618                 if(bots > minbots)
 619                         bots_would_leave = true;
 620         }
 621         else
 622         {
 623                 // if there are no players, remove bots
 624                 bots = 0;
 625         }
 626
 627         // only add one bot per frame to avoid utter chaos
 628         if(time > botframe_nextthink)
 629         {
 630                 if (currentbots < bots)
 631                 {
 632                         if (bot_spawn() == NULL)
 633                         {
 634                                 bprint("Can not add bot, server full.\n");
 635                                 return false;
 636                         }
 637                 }
 638                 while (currentbots > bots && bots >= 0)
 639                         bot_removenewest();
 640         }
 641
 642         return true;
 643 }
 644
 645 void bot_remove_from_bot_list(entity this)
 646 {
 647         entity e = bot_list;
 648         entity prev_bot = NULL;
 649         while (e)
 650         {
 651                 if(e == this)
 652                 {
 653                         if(!prev_bot)
 654                                 bot_list = this.nextbot;
 655                         else
 656                                 prev_bot.nextbot = this.nextbot;
 657                         if(bot_strategytoken == this)
 658                         {
 659                                 bot_strategytoken = this.nextbot;
 660                                 bot_strategytoken_taken = true;
 661                         }
 662                         this.nextbot = NULL;
 663                         break;
 664                 }
 665                 prev_bot = e;
 666                 e = e.nextbot;
 667         }
 668 }
 669
 670 void bot_clear(entity this)
 671 {
 672         bot_remove_from_bot_list(this);
 673         if(bot_waypoint_queue_owner == this)
 674                 bot_waypoint_queue_owner = NULL;
 675         this.aistatus &= ~AI_STATUS_STUCK; // otherwise bot_waypoint_queue_owner will be set again to this by navigation_unstuck
 676 }
 677
 678 void bot_serverframe()
 679 {
 680         if (intermission_running && currentbots > 0)
 681         {
 682                 // after the end of the match all bots stay unless all human players disconnect
 683                 int realplayers = 0;
 684                 FOREACH_CLIENT(IS_REAL_CLIENT(it), { ++realplayers; });
 685                 if (!realplayers)
 686                 {
 687                         FOREACH_CLIENT(IS_BOT_CLIENT(it), { dropclient(it); });
 688                         currentbots = 0;
 689                 }
 690                 return;
 691         }
 692
 693         if (game_stopped)
 694                 return;
 695
 696         // Added 0.5 to avoid possible addition + immediate removal of bots that would make them appear as
 697         // spectators in the scoreboard and never go away. This issue happens at time 2 if map is changed
 698         // with the gotomap command, minplayers is > 1 and human clients join as players very soon
 699         // either intentionally or automatically (sv_spectate 0)
 700         if (time < 2.5)
 701         {
 702                 currentbots = -1;
 703                 return;
 704         }
 705
 706         if (currentbots == -1)
 707         {
 708                 // count bots already in the server from the previous match
 709                 currentbots = 0;
 710                 FOREACH_CLIENT(IS_BOT_CLIENT(it), { ++currentbots; });
 711         }
 712
 713         if(autocvar_skill != skill)
 714         {
 715                 float wpcost_update = false;
 716                 if(skill >= autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill < autocvar_bot_ai_bunnyhop_skilloffset)
 717                         wpcost_update = true;
 718                 if(skill < autocvar_bot_ai_bunnyhop_skilloffset && autocvar_skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 719                         wpcost_update = true;
 720
 721                 skill = autocvar_skill;
 722                 if (wpcost_update)
 723                         waypoint_updatecost_foralllinks();
 724         }
 725
 726         bot_calculate_stepheightvec();
 727         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 728
 729         if(time > autoskill_nextthink)
 730         {
 731                 float a;
 732                 a = autocvar_skill_auto;
 733                 if(a)
 734                         autoskill(a);
 735                 autoskill_nextthink = time + 5;
 736         }
 737
 738         if(time > botframe_nextthink)
 739         {
 740                 if(!bot_fixcount())
 741                         botframe_nextthink = time + 10;
 742         }
 743
 744         if(botframe_spawnedwaypoints)
 745         {
 746                 if(autocvar_waypoint_benchmark)
 747                         localcmd("quit\n");
 748         }
 749
 750         if (currentbots > 0 || autocvar_g_waypointeditor || autocvar_g_waypointeditor_auto)
 751         if (botframe_spawnedwaypoints)
 752         {
 753                 if(botframe_cachedwaypointlinks)
 754                 {
 755                         if(!botframe_loadedforcedlinks)
 756                                 waypoint_load_links_hardwired();
 757                 }
 758                 else
 759                 {
 760                         // TODO: Make this check cleaner
 761                         IL_EACH(g_waypoints, time - it.nextthink > 10,
 762                         {
 763                                 waypoint_save_links();
 764                                 break;
 765                         });
 766                 }
 767         }
 768         else
 769         {
 770                 botframe_spawnedwaypoints = true;
 771                 waypoint_loadall();
 772                 waypoint_load_links();
 773         }
 774
 775         if (bot_list)
 776         {
 777                 // cycle the goal token from one bot to the next each frame
 778                 // (this prevents them from all doing spawnfunc_waypoint searches on the same
 779                 //  frame, which causes choppy framerates)
 780                 if (bot_strategytoken_taken)
 781                 {
 782                         // give goal token to the first bot without goals; if all bots don't have
 783                         // any goal (or are dead/frozen) simply give it to the next one
 784                         bot_strategytoken_taken = false;
 785                         entity bot_strategytoken_save = bot_strategytoken;
 786                         while (true)
 787                         {
 788                                 if (bot_strategytoken)
 789                                         bot_strategytoken = bot_strategytoken.nextbot;
 790                                 if (!bot_strategytoken)
 791                                         bot_strategytoken = bot_list;
 792
 793                                 if (!(IS_DEAD(bot_strategytoken) || STAT(FROZEN, bot_strategytoken))
 794                                         && !bot_strategytoken.goalcurrent)
 795                                         break;
 796
 797                                 if (!bot_strategytoken_save) // break loop if all the bots are dead or frozen
 798                                         break;
 799                                 if (bot_strategytoken == bot_strategytoken_save)
 800                                         bot_strategytoken_save = NULL; // looped through all the bots
 801                         }
 802                 }
 803
 804                 if (botframe_nextdangertime < time)
 805                 {
 806                         float interval;
 807                         interval = autocvar_bot_ai_dangerdetectioninterval;
 808                         if (botframe_nextdangertime < time - interval * 1.5)
 809                                 botframe_nextdangertime = time;
 810                         botframe_nextdangertime = botframe_nextdangertime + interval;
 811                         botframe_updatedangerousobjects(autocvar_bot_ai_dangerdetectionupdates);
 812                 }
 813         }
 814
 815         if (autocvar_g_waypointeditor)
 816                 botframe_showwaypointlinks();
 817
 818         if (autocvar_g_waypointeditor_auto)
 819                 botframe_autowaypoints();
 820
 821         if(time > bot_cvar_nextthink)
 822         {
 823                 if(currentbots>0)
 824                         bot_custom_weapon_priority_setup();
 825                 bot_cvar_nextthink = time + 5;
 826         }
 827 }