qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include "roles.qh"
   4
   5 #include <server/client.qh>
   6 #include <server/defs.qh>
   7 #include <server/g_damage.qh>
   8 #include <server/miscfunctions.qh>
   9 #include <server/weapons/selection.qh>
  10 #include <server/weapons/weaponsystem.qh>
  11 #include "../cvars.qh"
  12
  13 #include "../aim.qh"
  14 #include "../bot.qh"
  15 #include "../navigation.qh"
  16 #include "../scripting.qh"
  17 #include "../waypoints.qh"
  18
  19 #include <common/constants.qh>
  20 #include <common/impulses/all.qh>
  21 #include <common/net_linked.qh>
  22 #include <common/physics/player.qh>
  23 #include <common/state.qh>
  24 #include <common/items/_mod.qh>
  25 #include <common/wepent.qh>
  26
  27 #include <common/mapobjects/func/ladder.qh>
  28 #include <common/mapobjects/teleporters.qh>
  29 #include <common/mapobjects/trigger/hurt.qh>
  30 #include <common/mapobjects/trigger/jumppads.qh>
  31
  32 #include <lib/warpzone/common.qh>
  33
  34 void havocbot_ai(entity this)
  35 {
  36         if(this.draggedby)
  37                 return;
  38
  39         this.bot_aimdir_executed = false;
  40         // lock aim if teleported or passing through a warpzone
  41         if (this.lastteleporttime && !this.jumppadcount)
  42                 this.bot_aimdir_executed = true;
  43
  44         if(bot_execute_commands(this))
  45                 return;
  46
  47         if (bot_strategytoken == this && !bot_strategytoken_taken)
  48         {
  49                 if(this.havocbot_blockhead)
  50                 {
  51                         this.havocbot_blockhead = false;
  52                 }
  53                 else
  54                 {
  55                         if (!this.jumppadcount && !STAT(FROZEN, this)
  56                                 && !(this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP) && !IS_ONGROUND(this)))
  57                         {
  58                                 // find a new goal
  59                                 this.havocbot_role(this); // little too far down the rabbit hole
  60                         }
  61                 }
  62
  63                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  64                 if(!(IS_DEAD(this) || STAT(FROZEN, this)))
  65                 if(!this.goalcurrent)
  66                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  67                 {
  68                         // Look for the closest waypoint out of water
  69                         entity newgoal = NULL;
  70                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  71                         {
  72                                 if(it.origin.z < this.origin.z)
  73                                         continue;
  74
  75                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  76                                         continue;
  77
  78                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  79                                         continue;
  80
  81                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  82
  83                                 if(trace_fraction < 1)
  84                                         continue;
  85
  86                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  87                                         newgoal = it;
  88                         });
  89
  90                         if(newgoal)
  91                         {
  92                         //      te_wizspike(newgoal.origin);
  93                                 navigation_pushroute(this, newgoal);
  94                         }
  95                 }
  96
  97                 // token has been used this frame
  98                 bot_strategytoken_taken = true;
  99         }
 100
 101         if (this.goalcurrent && wasfreed(this.goalcurrent))
 102         {
 103                 navigation_clearroute(this);
 104                 navigation_goalrating_timeout_force(this);
 105                 return;
 106         }
 107
 108         if(IS_DEAD(this) || STAT(FROZEN, this))
 109         {
 110                 if (this.goalcurrent)
 111                         navigation_clearroute(this);
 112                 this.enemy = NULL;
 113                 this.bot_aimtarg = NULL;
 114                 return;
 115         }
 116
 117         havocbot_chooseenemy(this);
 118
 119         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 120         {
 121                 .entity weaponentity = weaponentities[slot];
 122                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
 123                 if(this.(weaponentity).bot_chooseweapontime < time)
 124                 {
 125                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
 126                         havocbot_chooseweapon(this, weaponentity);
 127                 }
 128         }
 129         havocbot_aim(this);
 130         lag_update(this);
 131
 132         if (this.bot_aimtarg)
 133         {
 134                 this.aistatus |= AI_STATUS_ATTACKING;
 135                 this.aistatus &= ~AI_STATUS_ROAMING;
 136
 137                 if(STAT(WEAPONS, this))
 138                 {
 139                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 140                         {
 141                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 142                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 143                         }
 144                         else
 145                         {
 146                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 147                                 {
 148                                         .entity weaponentity = weaponentities[slot];
 149                                         Weapon w = this.(weaponentity).m_weapon;
 150                                         if(w == WEP_Null && slot != 0)
 151                                                 continue;
 152                                         w.wr_aim(w, this, weaponentity);
 153                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
 154                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 155                                 }
 156                         }
 157                 }
 158                 else
 159                 {
 160                         if(IS_PLAYER(this.bot_aimtarg))
 161                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs, 0);
 162                 }
 163         }
 164         else if (this.goalcurrent)
 165         {
 166                 this.aistatus |= AI_STATUS_ROAMING;
 167                 this.aistatus &= ~AI_STATUS_ATTACKING;
 168         }
 169
 170         havocbot_movetogoal(this);
 171         if (!this.bot_aimdir_executed && this.goalcurrent)
 172         {
 173                 // Heading
 174                 vector dir = get_closer_dest(this.goalcurrent, this.origin);
 175                 dir -= this.origin + this.view_ofs;
 176                 dir.z = 0;
 177                 bot_aimdir(this, dir, 0);
 178         }
 179
 180         // if the bot is not attacking, consider reloading weapons
 181         if (!(this.aistatus & AI_STATUS_ATTACKING))
 182         {
 183                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 184                 {
 185                         .entity weaponentity = weaponentities[slot];
 186
 187                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 188                                 continue;
 189
 190                         // we are currently holding a weapon that's not fully loaded, reload it
 191                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 192                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
 193                                 CS(this).impulse = IMP_weapon_reload.impulse; // not sure if this is done right
 194
 195                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 196                         // the code above executes next frame, starting the reloading then
 197                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
 198                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
 199                         {
 200                                 FOREACH(Weapons, it != WEP_Null, {
 201                                         if((STAT(WEAPONS, this) & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
 202                                         {
 203                                                 this.(weaponentity).m_switchweapon = it;
 204                                                 break;
 205                                         }
 206                                 });
 207                         }
 208                 }
 209         }
 210 }
 211
 212 void havocbot_bunnyhop(entity this, vector dir)
 213 {
 214         bool can_run = false;
 215         if (!(this.aistatus & AI_STATUS_ATTACKING) && this.goalcurrent && !IS_PLAYER(this.goalcurrent)
 216                 && vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed) && !(this.aistatus & AI_STATUS_DANGER_AHEAD)
 217                 && this.waterlevel <= WATERLEVEL_WETFEET && !IS_DUCKED(this)
 218                 && IS_ONGROUND(this) && !(this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)))
 219         {
 220                 vector vel_angles = vectoangles(this.velocity);
 221                 vector deviation = vel_angles - vectoangles(dir);
 222                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 223                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 224                 if (fabs(deviation.y) < autocvar_bot_ai_bunnyhop_dir_deviation_max)
 225                 {
 226                         vector gco = get_closer_dest(this.goalcurrent, this.origin);
 227                         float vel = vlen(vec2(this.velocity));
 228
 229                         // with the current physics, jump distance grows linearly with the speed
 230                         float jump_distance = 52.661 + 0.606 * vel;
 231                         jump_distance += this.origin.z - gco.z; // roughly take into account vertical distance too
 232                         if (vdist(vec2(gco - this.origin), >, max(0, jump_distance)))
 233                                 can_run = true;
 234                         else if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_JUMP)
 235                                 && !(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 236                                 && this.goalstack01 && !wasfreed(this.goalstack01) && !(this.goalstack01.wpflags & WAYPOINTFLAG_JUMP)
 237                                 && vdist(vec2(gco - this.goalstack01.origin), >, 70))
 238                         {
 239                                 vector gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 240                                 vector ang = vectoangles(gco - this.origin);
 241                                 deviation = vectoangles(gno - gco) - vel_angles;
 242                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 243                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 244
 245                                 float max_turn_angle = autocvar_bot_ai_bunnyhop_turn_angle_max;
 246                                 max_turn_angle -= autocvar_bot_ai_bunnyhop_turn_angle_reduction * ((vel - autocvar_sv_maxspeed) / autocvar_sv_maxspeed);
 247                                 if ((ang.x < 90 || ang.x > 360 - autocvar_bot_ai_bunnyhop_downward_pitch_max)
 248                                         && fabs(deviation.y) < max(autocvar_bot_ai_bunnyhop_turn_angle_min, max_turn_angle))
 249                                 {
 250                                         can_run = true;
 251                                 }
 252                         }
 253                 }
 254         }
 255
 256         if (can_run)
 257         {
 258                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 259                 this.bot_jump_time = time;
 260                 this.aistatus |= AI_STATUS_RUNNING;
 261         }
 262         else
 263         {
 264                 if (IS_ONGROUND(this) || this.waterlevel > WATERLEVEL_WETFEET)
 265                         this.aistatus &= ~AI_STATUS_RUNNING;
 266         }
 267 }
 268
 269 void havocbot_keyboard_movement(entity this, vector destorg)
 270 {
 271         if(time <= this.havocbot_keyboardtime)
 272                 return;
 273
 274         float sk = skill + this.bot_moveskill;
 275         this.havocbot_keyboardtime =
 276                 max(
 277                         this.havocbot_keyboardtime
 278                                 + 0.05 / max(1, sk + this.havocbot_keyboardskill)
 279                                 + random() * 0.025 / max(0.00025, skill + this.havocbot_keyboardskill)
 280                 , time);
 281         vector keyboard = CS(this).movement / autocvar_sv_maxspeed;
 282
 283         float trigger = autocvar_bot_ai_keyboard_threshold;
 284
 285         // categorize forward movement
 286         // at skill < 1.5 only forward
 287         // at skill < 2.5 only individual directions
 288         // at skill < 4.5 only individual directions, and forward diagonals
 289         // at skill >= 4.5, all cases allowed
 290         if (keyboard.x > trigger)
 291         {
 292                 keyboard.x = 1;
 293                 if (sk < 2.5)
 294                         keyboard.y = 0;
 295         }
 296         else if (keyboard.x < -trigger && sk > 1.5)
 297         {
 298                 keyboard.x = -1;
 299                 if (sk < 4.5)
 300                         keyboard.y = 0;
 301         }
 302         else
 303         {
 304                 keyboard.x = 0;
 305                 if (sk < 1.5)
 306                         keyboard.y = 0;
 307         }
 308         if (sk < 4.5)
 309                 keyboard.z = 0;
 310
 311         if (keyboard.y > trigger)
 312                 keyboard.y = 1;
 313         else if (keyboard.y < -trigger)
 314                 keyboard.y = -1;
 315         else
 316                 keyboard.y = 0;
 317
 318         if (keyboard.z > trigger)
 319                 keyboard.z = 1;
 320         else if (keyboard.z < -trigger)
 321                 keyboard.z = -1;
 322         else
 323                 keyboard.z = 0;
 324
 325         // make sure bots don't get stuck if havocbot_keyboardtime is very high
 326         if (keyboard == '0 0 0')
 327                 this.havocbot_keyboardtime = min(this.havocbot_keyboardtime, time + 0.2);
 328
 329         this.havocbot_keyboard = keyboard * autocvar_sv_maxspeed;
 330         if (this.havocbot_ducktime > time)
 331                 PHYS_INPUT_BUTTON_CROUCH(this) = true;
 332
 333         keyboard = this.havocbot_keyboard;
 334         float blend = bound(0, vlen(destorg - this.origin) / autocvar_bot_ai_keyboard_distance, 1); // When getting close move with 360 degree
 335         //dprint("movement ", vtos(CS(this).movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 336         CS(this).movement = CS(this).movement + (keyboard - CS(this).movement) * blend;
 337 }
 338
 339 // return true when bot isn't getting closer to the current goal
 340 bool havocbot_checkgoaldistance(entity this, vector gco)
 341 {
 342         if (this.bot_stop_moving_timeout > time)
 343                 return false;
 344         float curr_dist_z = max(20, fabs(this.origin.z - gco.z));
 345         float curr_dist_2d = max(20, vlen(vec2(this.origin - gco)));
 346         float distance_time = this.goalcurrent_distance_time;
 347         if(distance_time < 0)
 348                 distance_time = -distance_time;
 349         if(curr_dist_z >= this.goalcurrent_distance_z && curr_dist_2d >= this.goalcurrent_distance_2d)
 350         {
 351                 if(!distance_time)
 352                         this.goalcurrent_distance_time = time;
 353                 else if (time - distance_time > 0.5)
 354                         return true;
 355         }
 356         else
 357         {
 358                 // reduce it a little bit so it works even with very small approaches to the goal
 359                 this.goalcurrent_distance_z = max(20, curr_dist_z - 10);
 360                 this.goalcurrent_distance_2d = max(20, curr_dist_2d - 10);
 361                 this.goalcurrent_distance_time = 0;
 362         }
 363         return false;
 364 }
 365
 366 entity havocbot_select_an_item_of_group(entity this, int gr)
 367 {
 368         entity selected = NULL;
 369         float selected_dist2 = 0;
 370         // select farthest item of this group from bot's position
 371         IL_EACH(g_items, it.item_group == gr && it.solid,
 372         {
 373                 float dist2 = vlen2(this.origin - it.origin);
 374                 if (dist2 < 600 ** 2 && dist2 > selected_dist2)
 375                 {
 376                         selected = it;
 377                         selected_dist2 = vlen2(this.origin - selected.origin);
 378                 }
 379         });
 380
 381         if (!selected)
 382                 return NULL;
 383
 384         set_tracewalk_dest(selected, this.origin, false);
 385         if (!tracewalk(this, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this),
 386                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
 387         {
 388                 return NULL;
 389         }
 390
 391         return selected;
 392 }
 393
 394 void havocbot_movetogoal(entity this)
 395 {
 396         vector diff;
 397         vector dir;
 398         vector flatdir;
 399         float dodge_enemy_factor = 1;
 400         float maxspeed;
 401         //float dist;
 402         vector dodge;
 403         //if (this.goalentity)
 404         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 405         CS(this).movement = '0 0 0';
 406         maxspeed = autocvar_sv_maxspeed;
 407
 408         PHYS_INPUT_BUTTON_CROUCH(this) = boolean(this.goalcurrent.wpflags & WAYPOINTFLAG_CROUCH);
 409
 410         PHYS_INPUT_BUTTON_JETPACK(this) = false;
 411         // Jetpack navigation
 412         if(this.navigation_jetpack_goal)
 413         if(this.goalcurrent==this.navigation_jetpack_goal)
 414         if(GetResource(this, RES_FUEL))
 415         {
 416                 if(autocvar_bot_debug_goalstack)
 417                 {
 418                         debuggoalstack(this);
 419                         te_wizspike(this.navigation_jetpack_point);
 420                 }
 421
 422                 // Take off
 423                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 424                 {
 425                         // Brake almost completely so it can get a good direction
 426                         if(vdist(this.velocity, >, 10))
 427                                 return;
 428                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 429                 }
 430
 431                 makevectors(this.v_angle.y * '0 1 0');
 432                 dir = normalize(this.navigation_jetpack_point - this.origin);
 433
 434                 // Landing
 435                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 436                 {
 437                         // Calculate brake distance in xy
 438                         float d = vlen(vec2(this.origin - (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5));
 439                         float vel2 = vlen2(vec2(this.velocity));
 440                         float db = (vel2 / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 441                         //LOG_INFOF("distance %d, velocity %d, brake at %d ", ceil(d), ceil(v), ceil(db));
 442                         if(d < db || d < 500)
 443                         {
 444                                 // Brake
 445                                 if (vel2 > (maxspeed * 0.3) ** 2)
 446                                 {
 447                                         CS(this).movement_x = dir * v_forward * -maxspeed;
 448                                         return;
 449                                 }
 450                                 // Switch to normal mode
 451                                 this.navigation_jetpack_goal = NULL;
 452                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 453                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 454                                 return;
 455                         }
 456                 }
 457                 else if(checkpvs(this.origin,this.goalcurrent))
 458                 {
 459                         // If I can see the goal switch to landing code
 460                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 461                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 462                         return;
 463                 }
 464
 465                 // Flying
 466                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 467                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
 468                 {
 469                         CS(this).movement_x = dir * v_forward * maxspeed;
 470                         CS(this).movement_y = dir * v_right * maxspeed;
 471                 }
 472                 return;
 473         }
 474
 475         // Handling of jump pads
 476         if(this.jumppadcount)
 477         {
 478                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 479                 {
 480                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 481                         if(navigation_poptouchedgoals(this))
 482                                 return;
 483                 }
 484                 else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 485                 {
 486                         // If got stuck on the jump pad try to reach the farthest visible waypoint
 487                         // but with some randomness so it can try out different paths
 488                         if(!this.goalcurrent)
 489                         {
 490                                 entity newgoal = NULL;
 491                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 492                                 {
 493                                         if(it.wpflags & WAYPOINTFLAG_TELEPORT)
 494                                         if(it.origin.z < this.origin.z - 100 && vdist(vec2(it.origin - this.origin), <, 100))
 495                                                 continue;
 496
 497                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 498
 499                                         if(trace_fraction < 1)
 500                                                 continue;
 501
 502                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
 503                                                 newgoal = it;
 504                                 });
 505
 506                                 if(newgoal)
 507                                 {
 508                                         this.ignoregoal = this.goalcurrent;
 509                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 510                                         navigation_clearroute(this);
 511                                         navigation_routetogoal(this, newgoal, this.origin);
 512                                         if(autocvar_bot_debug_goalstack)
 513                                                 debuggoalstack(this);
 514                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 515                                 }
 516                         }
 517                         else //if (this.goalcurrent)
 518                         {
 519                                 if (this.goalcurrent.bot_pickup)
 520                                 {
 521                                         entity jumppad_wp = this.goalcurrent_prev;
 522                                         navigation_poptouchedgoals(this);
 523                                         if(!this.goalcurrent && jumppad_wp.wp00)
 524                                         {
 525                                                 // head to the jumppad destination once bot reaches the goal item
 526                                                 navigation_pushroute(this, jumppad_wp.wp00);
 527                                         }
 528                                 }
 529                                 vector gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 530                                 if (this.origin.z > gco.z && vdist(vec2(this.velocity), <, autocvar_sv_maxspeed))
 531                                 {
 532                                         if (this.velocity.z < 0)
 533                                                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 534                                 }
 535                                 else if(havocbot_checkgoaldistance(this, gco))
 536                                 {
 537                                         navigation_clearroute(this);
 538                                         navigation_goalrating_timeout_force(this);
 539                                 }
 540                                 else
 541                                         return;
 542                         }
 543                 }
 544                 else //if (!(this.aistatus & AI_STATUS_OUT_JUMPPAD))
 545                 {
 546                         if(this.velocity.z > 0 && this.origin.z - this.lastteleport_origin.z > (this.maxs.z - this.mins.z) * 0.5)
 547                         {
 548                                 vector velxy = this.velocity; velxy_z = 0;
 549                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
 550                                 {
 551                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 552                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 553                                 }
 554                                 return;
 555                         }
 556
 557                         // Don't chase players while using a jump pad
 558                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 559                                 return;
 560                 }
 561         }
 562         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 563                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 564
 565         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 566         if (skill > 6 && !(IS_ONGROUND(this)))
 567         {
 568                 #define ROCKETJUMP_DAMAGE() WEP_CVAR(devastator, damage) * 0.8 \
 569                         * ((STAT(STRENGTH_FINISHED, this) > time) ? autocvar_g_balance_powerup_strength_selfdamage : 1) \
 570                         * ((STAT(INVINCIBLE_FINISHED, this) > time) ? autocvar_g_balance_powerup_invincible_takedamage : 1)
 571
 572                 // save some CPU cycles by checking trigger_hurt after checking
 573                 // that something can be done to evade it (cheaper checks)
 574                 int action_for_trigger_hurt = 0;
 575                 if (this.items & IT_JETPACK)
 576                         action_for_trigger_hurt = 1;
 577                 else if (!this.jumppadcount && !waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
 578                         && !(this.goalcurrent_prev && this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)
 579                         && GetResource(this, RES_HEALTH) + GetResource(this, RES_ARMOR) > ROCKETJUMP_DAMAGE())
 580                 {
 581                         action_for_trigger_hurt = 2;
 582                 }
 583                 else if (!this.goalcurrent)
 584                         action_for_trigger_hurt = 3;
 585
 586                 if (action_for_trigger_hurt)
 587                 {
 588                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 589                         if(!tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos))
 590                                 action_for_trigger_hurt = 0;
 591                 }
 592
 593                 if(action_for_trigger_hurt == 1) // jetpack
 594                 {
 595                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 596                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 597                         {
 598                                 if(this.velocity.z<0)
 599                                         PHYS_INPUT_BUTTON_JETPACK(this) = true;
 600                         }
 601                         else
 602                                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 603
 604                         // If there is no goal try to move forward
 605
 606                         if(this.goalcurrent==NULL)
 607                                 dir = v_forward;
 608                         else
 609                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 610
 611                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 612                         float xyspeed = xyvelocity * dir;
 613
 614                         if(xyspeed < (maxspeed / 2))
 615                         {
 616                                 makevectors(this.v_angle.y * '0 1 0');
 617                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 618                                 if(trace_fraction==1)
 619                                 {
 620                                         CS(this).movement_x = dir * v_forward * maxspeed;
 621                                         CS(this).movement_y = dir * v_right * maxspeed;
 622                                         if (skill < 10)
 623                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 624                                 }
 625                         }
 626
 627                         this.havocbot_blockhead = true;
 628
 629                         return;
 630                 }
 631                 else if(action_for_trigger_hurt == 2) // rocketjump
 632                 {
 633                         if(this.velocity.z < 0)
 634                         {
 635                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 636                                 {
 637                                         .entity weaponentity = weaponentities[slot];
 638
 639                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 640                                                 continue;
 641
 642                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
 643                                         {
 644                                                 CS(this).movement_x = maxspeed;
 645
 646                                                 if(this.rocketjumptime)
 647                                                 {
 648                                                         if(time > this.rocketjumptime)
 649                                                         {
 650                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 651                                                                 this.rocketjumptime = 0;
 652                                                         }
 653                                                         return;
 654                                                 }
 655
 656                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 657                                                 this.v_angle_x = 90;
 658                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 659                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 660                                                 return;
 661                                         }
 662                                 }
 663                         }
 664                 }
 665                 else if(action_for_trigger_hurt == 3) // no goal
 666                 {
 667                         // If there is no goal try to move forward
 668                         CS(this).movement_x = maxspeed;
 669                 }
 670         }
 671
 672         // If we are under water with no goals, swim up
 673         if(this.waterlevel && !this.goalcurrent)
 674         {
 675                 dir = '0 0 0';
 676                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 677                         dir.z = 1;
 678                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 679                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 680                 makevectors(this.v_angle.y * '0 1 0');
 681                 vector v = dir * maxspeed;
 682                 CS(this).movement.x = v * v_forward;
 683                 CS(this).movement.y = v * v_right;
 684                 CS(this).movement.z = v * v_up;
 685         }
 686
 687         // if there is nowhere to go, exit
 688         if (this.goalcurrent == NULL)
 689                 return;
 690
 691
 692         bool locked_goal = false;
 693         if((this.goalentity && wasfreed(this.goalentity))
 694                 || (this.goalcurrent == this.goalentity && this.goalentity.tag_entity))
 695         {
 696                 navigation_clearroute(this);
 697                 navigation_goalrating_timeout_force(this);
 698                 return;
 699         }
 700         else if(this.goalentity.tag_entity)
 701         {
 702                 navigation_goalrating_timeout_expire(this, 2);
 703         }
 704         else if(this.goalentity.bot_pickup)
 705         {
 706                 if(this.goalentity.bot_pickup_respawning)
 707                 {
 708                         if(this.goalentity.solid) // item respawned
 709                                 this.goalentity.bot_pickup_respawning = false;
 710                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
 711                         {
 712                                 if(checkpvs(this.origin, this.goalentity))
 713                                 {
 714                                         this.goalentity.bot_pickup_respawning = false;
 715                                         navigation_goalrating_timeout_expire(this, random());
 716                                 }
 717                                 locked_goal = true; // wait for item to respawn
 718                         }
 719                         else if(this.goalentity == this.goalcurrent)
 720                                 locked_goal = true; // wait for item to respawn
 721                 }
 722                 else if(!this.goalentity.solid && !boxesoverlap(this.goalentity.absmin, this.goalentity.absmax, this.absmin, this.absmax))
 723                 {
 724                         if(checkpvs(this.origin, this.goalentity))
 725                         {
 726                                 navigation_goalrating_timeout_expire(this, random());
 727                         }
 728                 }
 729         }
 730         if (this.goalcurrent == this.goalentity && this.goalentity_lock_timeout > time)
 731                 locked_goal = true;
 732
 733         if (navigation_shortenpath(this))
 734         {
 735                 if (vdist(this.origin - this.goalcurrent_prev.origin, <, 50)
 736                         && navigation_goalrating_timeout_can_be_anticipated(this))
 737                 {
 738                         navigation_goalrating_timeout_force(this);
 739                 }
 740         }
 741
 742         bool goalcurrent_can_be_removed = false;
 743         if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 744         {
 745                 bool freeze_state_changed = (boolean(STAT(FROZEN, this.goalentity)) != this.goalentity_shouldbefrozen);
 746                 if (IS_DEAD(this.goalcurrent) || (this.goalentity == this.goalcurrent && freeze_state_changed))
 747                 {
 748                         goalcurrent_can_be_removed = true;
 749                         // don't remove if not visible
 750                         if (checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 751                         {
 752                                 if (IS_DEAD(this.goalcurrent))
 753                                 {
 754                                         IL_EACH(g_items, it.enemy == this.goalcurrent && Item_IsLoot(it),
 755                                         {
 756                                                 if (vdist(it.origin - this.goalcurrent.death_origin, <, 50))
 757                                                 {
 758                                                         navigation_clearroute(this);
 759                                                         navigation_pushroute(this, it);
 760                                                         // loot can't be immediately rated since it isn't on ground yet
 761                                                         // it will be rated after a second when on ground, meanwhile head to it
 762                                                         navigation_goalrating_timeout_expire(this, 1);
 763                                                         return;
 764                                                 }
 765                                         });
 766                                 }
 767                                 if (!Item_IsLoot(this.goalcurrent))
 768                                 {
 769                                         navigation_goalrating_timeout_force(this);
 770                                         return;
 771                                 }
 772                         }
 773                 }
 774                 else if (!(STAT(FROZEN, this.goalentity)) && this.bot_tracewalk_time < time)
 775                 {
 776                         set_tracewalk_dest(this.goalcurrent, this.origin, true);
 777                         if (!(trace_ent == this || tracewalk(this, this.origin, this.mins, this.maxs,
 778                                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode)))
 779                         {
 780                                 navigation_goalrating_timeout_force(this);
 781                                 return;
 782                         }
 783                         this.bot_tracewalk_time = max(time, this.bot_tracewalk_time) + 0.25;
 784                 }
 785         }
 786
 787         if(!locked_goal)
 788         {
 789                 // optimize path finding by anticipating goalrating when bot is near a waypoint;
 790                 // in this case path finding can start directly from a waypoint instead of
 791                 // looking for all the reachable waypoints up to a certain distance
 792                 if (navigation_poptouchedgoals(this))
 793                 {
 794                         if (this.goalcurrent)
 795                         {
 796                                 if (goalcurrent_can_be_removed)
 797                                 {
 798                                         // remove even if not visible
 799                                         navigation_goalrating_timeout_force(this);
 800                                         return;
 801                                 }
 802                                 else if (navigation_goalrating_timeout_can_be_anticipated(this))
 803                                         navigation_goalrating_timeout_force(this);
 804                         }
 805                         else
 806                         {
 807                                 entity old_goal = this.goalcurrent_prev;
 808                                 if (old_goal.item_group && this.item_group != old_goal.item_group)
 809                                 {
 810                                         // Avoid multiple costly calls of path finding code that selects one of the closest
 811                                         // item of the group by telling the bot to head directly to the farthest item.
 812                                         // Next time we let the bot select a goal as usual which can be another item
 813                                         // of this group (the closest one) and so on
 814                                         this.item_group = old_goal.item_group;
 815                                         entity new_goal = havocbot_select_an_item_of_group(this, old_goal.item_group);
 816                                         if (new_goal)
 817                                                 navigation_pushroute(this, new_goal);
 818                                 }
 819                         }
 820                 }
 821         }
 822
 823         // if ran out of goals try to use an alternative goal or get a new strategy asap
 824         if(this.goalcurrent == NULL)
 825         {
 826                 navigation_goalrating_timeout_force(this);
 827                 return;
 828         }
 829
 830
 831         if(autocvar_bot_debug_goalstack)
 832                 debuggoalstack(this);
 833
 834         bool bunnyhop_forbidden = false;
 835         vector destorg = get_closer_dest(this.goalcurrent, this.origin);
 836         if (this.jumppadcount && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 837         {
 838                 // if bot used the jumppad, push towards jumppad origin until jumppad waypoint gets removed
 839                 destorg = this.goalcurrent.origin;
 840         }
 841         else if (this.goalcurrent.wpisbox)
 842         {
 843                 // if bot is inside the teleport waypoint, head to teleport origin until teleport gets used
 844                 // do it even if bot is on a ledge above a teleport/jumppad so it doesn't get stuck
 845                 if (boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin + eZ * this.mins.z, this.origin + eZ * this.maxs.z)
 846                         || (this.absmin.z > destorg.z && destorg.x == this.origin.x && destorg.y == this.origin.y))
 847                 {
 848                         bunnyhop_forbidden = true;
 849                         destorg = this.goalcurrent.origin;
 850                         if(destorg.z > this.origin.z)
 851                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 852                 }
 853         }
 854
 855         diff = destorg - this.origin;
 856
 857         if (time < this.bot_stop_moving_timeout
 858                 || (this.goalcurrent == this.goalentity && time < this.goalentity_lock_timeout && vdist(diff, <, 10)))
 859         {
 860                 // stop if the locked goal has been reached
 861                 destorg = this.origin;
 862                 diff = dir = '0 0 0';
 863         }
 864         else if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 865         {
 866                 if (vdist(diff, <, 80))
 867                 {
 868                         // stop if too close to target player (even if frozen)
 869                         destorg = this.origin;
 870                         diff = dir = '0 0 0';
 871                 }
 872                 else
 873                 {
 874                         // move destorg out of target players, otherwise bot will consider them
 875                         // an obstacle that needs to be jumped (especially if frozen)
 876                         dir = normalize(diff);
 877                         destorg -= dir * PL_MAX_CONST.x * M_SQRT2;
 878                         diff = destorg - this.origin;
 879                 }
 880         }
 881         else
 882                 dir = normalize(diff);
 883         flatdir = (diff.z == 0) ? dir : normalize(vec2(diff));
 884
 885         bool danger_detected = false;
 886         vector do_break = '0 0 0';
 887
 888         //if (this.bot_dodgevector_time < time)
 889         {
 890                 //this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 891                 //this.bot_dodgevector_jumpbutton = 1;
 892
 893                 this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 894                 makevectors(this.v_angle.y * '0 1 0');
 895                 if (this.waterlevel > WATERLEVEL_WETFEET)
 896                 {
 897                         if (this.waterlevel > WATERLEVEL_SWIMMING)
 898                         {
 899                                 if(!this.goalcurrent)
 900                                         this.aistatus |= AI_STATUS_OUT_WATER;
 901                                 else if(destorg.z > this.origin.z)
 902                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 903                         }
 904                         else
 905                         {
 906                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && destorg.z < this.origin.z) &&
 907                                         (this.aistatus & AI_STATUS_OUT_WATER))
 908                                 {
 909                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 910                                         dir = flatdir;
 911                                 }
 912                                 else
 913                                 {
 914                                         if (destorg.z > this.origin.z)
 915                                                 dir = flatdir;
 916                                 }
 917                         }
 918                 }
 919                 else
 920                 {
 921                         float s;
 922                         vector offset;
 923                         if(this.aistatus & AI_STATUS_OUT_WATER)
 924                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 925
 926                         // jump if going toward an obstacle that doesn't look like stairs we
 927                         // can walk up directly
 928                         vector deviation = '0 0 0';
 929                         float current_speed = vlen(vec2(this.velocity));
 930                         if (current_speed < maxspeed * 0.2)
 931                                 current_speed = maxspeed * 0.2;
 932                         else
 933                         {
 934                                 deviation = vectoangles(diff) - vectoangles(this.velocity);
 935                                 while (deviation.y < -180) deviation.y += 360;
 936                                 while (deviation.y > 180) deviation.y -= 360;
 937                         }
 938                         float turning = false;
 939                         vector flat_diff = vec2(diff);
 940                         offset = max(32, current_speed * cos(deviation.y * DEG2RAD) * 0.3) * flatdir;
 941                         vector actual_destorg = this.origin + offset;
 942                         if (this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP))
 943                         {
 944                                 if (time > this.bot_stop_moving_timeout
 945                                         && fabs(deviation.y) > 20 && current_speed > maxspeed * 0.4
 946                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), <, 50))
 947                                 {
 948                                         this.bot_stop_moving_timeout = time + 0.1;
 949                                 }
 950                                 if (current_speed > autocvar_sv_maxspeed * 0.9
 951                                         && vlen2(flat_diff) < vlen2(vec2(this.goalcurrent_prev.origin - destorg))
 952                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), >, 50)
 953                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), <, 150)
 954                                 )
 955                                 {
 956                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 957                                         this.bot_jump_time = time;
 958                                 }
 959                         }
 960                         else if (!this.goalstack01 || (this.goalcurrent.wpflags & (WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_LADDER)))
 961                         {
 962                                 if (vlen2(flat_diff) < vlen2(offset))
 963                                 {
 964                                         if ((this.goalcurrent.wpflags & WAYPOINTFLAG_JUMP) && this.goalstack01)
 965                                         {
 966                                                 // oblique warpzones need a jump otherwise bots gets stuck
 967                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 968                                         }
 969                                         else
 970                                         {
 971                                                 actual_destorg.x = destorg.x;
 972                                                 actual_destorg.y = destorg.y;
 973                                         }
 974                                 }
 975                         }
 976                         else if (vdist(flat_diff, <, 32) && diff.z < -16) // destination is under the bot
 977                         {
 978                                 actual_destorg.x = destorg.x;
 979                                 actual_destorg.y = destorg.y;
 980                         }
 981                         else if (vlen2(flat_diff) < vlen2(offset))
 982                         {
 983                                 vector next_goal_org = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 984                                 vector next_dir = normalize(vec2(next_goal_org - destorg));
 985                                 float dist = vlen(vec2(this.origin + offset - destorg));
 986                                 // if current and next goal are close to each other make sure
 987                                 // actual_destorg isn't set beyond next_goal_org
 988                                 if (dist ** 2 > vlen2(vec2(next_goal_org - destorg)))
 989                                         actual_destorg = next_goal_org;
 990                                 else
 991                                         actual_destorg = vec2(destorg) + dist * next_dir;
 992                                 actual_destorg.z = this.origin.z;
 993                                 turning = true;
 994                         }
 995
 996                         LABEL(jumpobstacle_check);
 997                         dir = flatdir = normalize(actual_destorg - this.origin);
 998
 999                         bool jump_forbidden = false;
1000                         if (!turning && fabs(deviation.y) > 50)
1001                                 jump_forbidden = true;
1002                         else if (IS_DUCKED(this))
1003                         {
1004                                 tracebox(this.origin, PL_MIN_CONST, PL_MAX_CONST, this.origin, false, this);
1005                                 if (trace_startsolid)
1006                                         jump_forbidden = true;
1007                         }
1008
1009                         if (!jump_forbidden)
1010                         {
1011                                 tracebox(this.origin, this.mins, this.maxs, actual_destorg, false, this);
1012                                 if (trace_fraction < 1 && trace_plane_normal.z < 0.7)
1013                                 {
1014                                         s = trace_fraction;
1015                                         tracebox(this.origin + stepheightvec, this.mins, this.maxs, actual_destorg + stepheightvec, false, this);
1016                                         if (trace_fraction < s + 0.01 && trace_plane_normal.z < 0.7)
1017                                         {
1018                                                 // found an obstacle
1019                                                 if (turning && fabs(deviation.y) > 5)
1020                                                 {
1021                                                         // check if the obstacle is still there without turning
1022                                                         actual_destorg = destorg;
1023                                                         turning = false;
1024                                                         this.bot_tracewalk_time = time + 0.25;
1025                                                         goto jumpobstacle_check;
1026                                                 }
1027                                                 s = trace_fraction;
1028                                                 // don't artificially reduce max jump height in real-time
1029                                                 // (jumpstepheightvec is reduced a bit to make the jumps easy in tracewalk)
1030                                                 vector jump_height = (IS_ONGROUND(this)) ? stepheightvec + jumpheight_vec : jumpstepheightvec;
1031                                                 tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1032                                                 if (trace_fraction > s)
1033                                                 {
1034                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1035                                                         this.bot_jump_time = time;
1036                                                 }
1037                                                 else
1038                                                 {
1039                                                         jump_height = stepheightvec + jumpheight_vec / 2;
1040                                                         tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1041                                                         if (trace_fraction > s)
1042                                                         {
1043                                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1044                                                                 this.bot_jump_time = time;
1045                                                         }
1046                                                 }
1047                                         }
1048                                 }
1049                         }
1050
1051                         // if bot for some reason doesn't get close to the current goal find another one
1052                         if(!this.jumppadcount && !IS_PLAYER(this.goalcurrent))
1053                         if(!(locked_goal && this.goalcurrent_distance_z < 50 && this.goalcurrent_distance_2d < 50))
1054                         if(havocbot_checkgoaldistance(this, destorg))
1055                         {
1056                                 if(this.goalcurrent_distance_time < 0) // can't get close for the second time
1057                                 {
1058                                         navigation_clearroute(this);
1059                                         navigation_goalrating_timeout_force(this);
1060                                         return;
1061                                 }
1062
1063                                 set_tracewalk_dest(this.goalcurrent, this.origin, false);
1064                                 if (!tracewalk(this, this.origin, this.mins, this.maxs,
1065                                         tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
1066                                 {
1067                                         navigation_clearroute(this);
1068                                         navigation_goalrating_timeout_force(this);
1069                                         return;
1070                                 }
1071
1072                                 // give bot only another chance to prevent bot getting stuck
1073                                 // in case it thinks it can walk but actually can't
1074                                 this.goalcurrent_distance_z = FLOAT_MAX;
1075                                 this.goalcurrent_distance_2d = FLOAT_MAX;
1076                                 this.goalcurrent_distance_time = -time; // mark second try
1077                         }
1078
1079                         if (skill + this.bot_moveskill <= 3 && time > this.bot_stop_moving_timeout
1080                                 && current_speed > maxspeed * 0.9 && fabs(deviation.y) > 70)
1081                         {
1082                                 this.bot_stop_moving_timeout = time + 0.4 + random() * 0.2;
1083                         }
1084
1085                         // Check for water/slime/lava and dangerous edges
1086                         // (only when the bot is on the ground or jumping intentionally)
1087
1088                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : flatdir * 32);
1089                         vector dst_ahead = this.origin + this.view_ofs + offset;
1090                         vector dst_down = dst_ahead - '0 0 3000';
1091                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
1092
1093                         bool unreachable = false;
1094                         s = CONTENT_SOLID;
1095                         if (trace_fraction == 1 && !this.jumppadcount
1096                                 && !waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
1097                                 && !(this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)))
1098                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
1099                         {
1100                                 // Look downwards
1101                                 traceline(dst_ahead , dst_down, true, NULL);
1102                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
1103                                 //te_lightning2(NULL, dst_ahead, trace_endpos); // Draw "downwards" look
1104                                 if(trace_endpos.z < this.origin.z + this.mins.z)
1105                                 {
1106                                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1107                                                 danger_detected = true;
1108                                         else if (trace_endpos.z < min(this.origin.z + this.mins.z, this.goalcurrent.origin.z) - 100)
1109                                                 danger_detected = true;
1110                                         else
1111                                         {
1112                                                 s = pointcontents(trace_endpos + '0 0 1');
1113                                                 if (s != CONTENT_SOLID)
1114                                                 {
1115                                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
1116                                                                 danger_detected = true;
1117                                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1118                                                         {
1119                                                                 // the traceline check isn't enough but is good as optimization,
1120                                                                 // when not true (most of the time) this tracebox call is avoided
1121                                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
1122                                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1123                                                                 {
1124                                                                         if (destorg.z > this.origin.z + jumpstepheightvec.z)
1125                                                                         {
1126                                                                                 // the goal is probably on an upper platform, assume bot can't get there
1127                                                                                 unreachable = true;
1128                                                                         }
1129                                                                         else
1130                                                                                 danger_detected = true;
1131                                                                 }
1132                                                         }
1133                                                 }
1134                                         }
1135                                 }
1136                         }
1137
1138                         dir = flatdir;
1139                         makevectors(this.v_angle.y * '0 1 0');
1140
1141                         if (danger_detected || (s == CONTENT_WATER))
1142                         {
1143                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
1144                                 if(IS_PLAYER(this.goalcurrent))
1145                                         unreachable = true;
1146                         }
1147
1148                         // slow down if bot is in the air and goal is under it
1149                         if (!waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
1150                                 && vdist(flat_diff, <, 250) && this.origin.z - destorg.z > 120
1151                                 && (!IS_ONGROUND(this) || vdist(vec2(this.velocity), >, maxspeed * 0.3)))
1152                         {
1153                                 // tracebox wouldn't work when bot is still on the ledge
1154                                 traceline(this.origin, this.origin - '0 0 200', true, this);
1155                                 if (this.origin.z - trace_endpos.z > 120)
1156                                         do_break = normalize(this.velocity) * -1;
1157                         }
1158
1159                         if(unreachable)
1160                         {
1161                                 navigation_clearroute(this);
1162                                 navigation_goalrating_timeout_force(this);
1163                                 this.ignoregoal = this.goalcurrent;
1164                                 this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
1165                         }
1166                 }
1167
1168                 dodge = havocbot_dodge(this);
1169                 if (dodge)
1170                         dodge *= bound(0, 0.5 + (skill + this.bot_dodgeskill) * 0.1, 1);
1171                 if (this.enemy)
1172                 {
1173                         traceline(this.origin, (this.enemy.absmin + this.enemy.absmax) * 0.5, true, NULL);
1174                         if (IS_PLAYER(trace_ent))
1175                                 dodge_enemy_factor = bound(0, (skill + this.bot_dodgeskill) / 7, 1);
1176                 }
1177         //      this.bot_dodgevector = dir;
1178         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
1179         }
1180
1181         float ladder_zdir = 0;
1182         if(this.ladder_entity)
1183         {
1184                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
1185                 {
1186                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
1187                                 ladder_zdir = 1;
1188                 }
1189                 else
1190                 {
1191                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
1192                                 ladder_zdir = -1;
1193                 }
1194                 if (ladder_zdir)
1195                 {
1196                         if (vdist(vec2(diff), <, 40))
1197                                 dir.z = ladder_zdir * 4;
1198                         else
1199                                 dir.z = ladder_zdir * 2;
1200                         dir = normalize(dir);
1201                 }
1202         }
1203
1204         if (this.goalcurrent.wpisbox
1205                 && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin, this.origin))
1206         {
1207                 // bot is inside teleport waypoint but hasn't touched the real teleport yet
1208                 // head to teleport origin
1209                 dir = (this.goalcurrent.origin - this.origin);
1210                 dir.z = 0;
1211                 dir = normalize(dir);
1212         }
1213
1214         // already executed when bot targets an enemy
1215         if (!this.bot_aimdir_executed)
1216         {
1217                 if (time < this.bot_stop_moving_timeout)
1218                         bot_aimdir(this, normalize(this.goalcurrent.origin - this.origin), 0);
1219                 else
1220                         bot_aimdir(this, dir, 0);
1221         }
1222
1223         vector evadedanger = '0 0 0';
1224         if (!ladder_zdir)
1225         {
1226                 dir *= dodge_enemy_factor;
1227                 if (danger_detected && vdist(this.velocity, >, maxspeed * 0.8) && this.goalcurrent_prev
1228                         && this.goalcurrent.classname == "waypoint")
1229                 {
1230                         vector p = this.origin + this.velocity * 0.2;
1231                         vector evadedanger = point_line_vec(p, vec2(this.goalcurrent_prev.origin) + eZ * p.z,
1232                                 vec2(destorg - this.goalcurrent_prev.origin));
1233                         if (vdist(evadedanger, >, 20))
1234                         {
1235                                 if (vdist(evadedanger, >, 40))
1236                                         do_break = normalize(this.velocity) * -1;
1237                                 evadedanger = normalize(evadedanger);
1238                                 evadedanger *= bound(1, 3 - (skill + this.bot_dodgeskill), 3); // Noobs fear dangers a lot and take more distance from them
1239                         }
1240                         else
1241                                 evadedanger = '0 0 0';
1242                 }
1243                 dir = normalize(dir + dodge + do_break + evadedanger);
1244         }
1245
1246         makevectors(this.v_angle);
1247         //dir = this.bot_dodgevector;
1248         //if (this.bot_dodgevector_jumpbutton)
1249         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
1250         CS(this).movement_x = dir * v_forward * maxspeed;
1251         CS(this).movement_y = dir * v_right * maxspeed;
1252         CS(this).movement_z = dir * v_up * maxspeed;
1253
1254         // Emulate keyboard interface
1255         if (skill < 10)
1256                 havocbot_keyboard_movement(this, destorg);
1257
1258         // Bunnyhop!
1259         if (!bunnyhop_forbidden && !evadedanger && !do_break && skill + this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
1260                 havocbot_bunnyhop(this, dir);
1261
1262         if (dir * v_up >= autocvar_sv_jumpvelocity * 0.5 && IS_ONGROUND(this))
1263                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1264         if (dodge)
1265         {
1266                 if (dodge * v_up > 0 && random() * frametime >= 0.2 * bound(0, (10 - skill - this.bot_dodgeskill) * 0.1, 1))
1267                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1268                 if (dodge * v_up < 0 && random() * frametime >= 0.5 * bound(0, (10 - skill - this.bot_dodgeskill) * 0.1, 1))
1269                         this.havocbot_ducktime = time + 0.3 / bound(0.1, skill + this.bot_dodgeskill, 10);
1270         }
1271 }
1272
1273 entity havocbot_gettarget(entity this, bool secondary)
1274 {
1275         entity best = NULL;
1276         vector eye = CENTER_OR_VIEWOFS(this);
1277         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
1278         {
1279                 vector v = CENTER_OR_VIEWOFS(it);
1280                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1281                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
1282                 if(bot_shouldattack(this, it))
1283                 {
1284                         traceline(eye, v, true, this);
1285                         if (trace_ent == it || trace_fraction >= 1)
1286                                 best = it;
1287                 }
1288         });
1289
1290         return best;
1291 }
1292
1293 void havocbot_chooseenemy(entity this)
1294 {
1295         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
1296         {
1297                 this.enemy = NULL;
1298                 return;
1299         }
1300
1301         if (this.enemy)
1302         {
1303                 if (!bot_shouldattack(this, this.enemy))
1304                 {
1305                         // enemy died or something, find a new target
1306                         this.enemy = NULL;
1307                         this.havocbot_chooseenemy_finished = time;
1308                 }
1309                 else if (this.havocbot_stickenemy_time && time < this.havocbot_stickenemy_time)
1310                 {
1311                         // tracking last chosen enemy
1312                         vector targ_pos = (this.enemy.absmin + this.enemy.absmax) * 0.5;
1313                         traceline(this.origin + this.view_ofs, targ_pos, false, NULL);
1314                         if (trace_ent == this.enemy || trace_fraction == 1)
1315                         if (vdist(targ_pos - this.origin, <, 1000))
1316                         {
1317                                 // remain tracking him for a shot while (case he went after a small corner or pilar
1318                                 this.havocbot_chooseenemy_finished = time + 0.5;
1319                                 return;
1320                         }
1321
1322                         // stop preferring this enemy
1323                         this.havocbot_stickenemy_time = 0;
1324                 }
1325         }
1326         if (time < this.havocbot_chooseenemy_finished)
1327                 return;
1328         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
1329         vector eye = this.origin + this.view_ofs;
1330         entity best = NULL;
1331         float bestrating = autocvar_bot_ai_enemydetectionradius ** 2;
1332
1333         // Backup hit flags
1334         int hf = this.dphitcontentsmask;
1335
1336         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
1337
1338         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
1339
1340         bool scan_transparent = false;
1341         bool scan_secondary_targets = false;
1342         bool have_secondary_targets = false;
1343         while(true)
1344         {
1345                 scan_secondary_targets = false;
1346 LABEL(scan_targets)
1347                 IL_EACH(g_bot_targets, it.bot_attack,
1348                 {
1349                         if(!scan_secondary_targets)
1350                         {
1351                                 if(it.classname == "misc_breakablemodel")
1352                                 {
1353                                         have_secondary_targets = true;
1354                                         continue;
1355                                 }
1356                         }
1357                         else if(it.classname != "misc_breakablemodel")
1358                                 continue;
1359
1360                         vector v = (it.absmin + it.absmax) * 0.5;
1361                         float rating = vlen2(v - eye);
1362                         if (rating < bestrating && bot_shouldattack(this, it))
1363                         {
1364                                 traceline(eye, v, true, this);
1365                                 if (trace_ent == it || trace_fraction >= 1)
1366                                 {
1367                                         best = it;
1368                                         bestrating = rating;
1369                                 }
1370                         }
1371                 });
1372
1373                 if(!best && have_secondary_targets && !scan_secondary_targets)
1374                 {
1375                         scan_secondary_targets = true;
1376                         // restart the loop
1377                         bestrating = autocvar_bot_ai_enemydetectionradius ** 2;
1378                         goto scan_targets;
1379                 }
1380
1381                 // I want to do a second scan if no enemy was found or I don't have weapons
1382                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1383                 if(best || STAT(WEAPONS, this)) // || this.weapon == WEP_RIFLE.m_id
1384                         break;
1385                 if(scan_transparent)
1386                         break;
1387
1388                 // Set flags to see through transparent objects
1389                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1390
1391                 scan_transparent = true;
1392         }
1393
1394         // Restore hit flags
1395         this.dphitcontentsmask = hf;
1396
1397         this.enemy = best;
1398         this.havocbot_stickenemy_time = time + autocvar_bot_ai_enemydetectioninterval_stickingtoenemy;
1399         if(best && best.classname == "misc_breakablemodel")
1400                 this.havocbot_stickenemy_time = 0;
1401 }
1402
1403 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1404 {
1405         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1406         // so skip this for them, or they'll never get to reload their weapons at all.
1407         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1408         if(skill < 5)
1409                 return false;
1410
1411         // if this weapon is scheduled for reloading, don't switch to it during combat
1412         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1413         {
1414                 FOREACH(Weapons, it != WEP_Null, {
1415                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1416                                 return true; // other weapon available
1417                 });
1418         }
1419
1420         return false;
1421 }
1422
1423 void havocbot_chooseweapon(entity this, .entity weaponentity)
1424 {
1425         int i;
1426
1427         // ;)
1428         if(g_weaponarena_weapons == WEPSET(TUBA))
1429         {
1430                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1431                 return;
1432         }
1433
1434         // TODO: clean this up by moving it to weapon code
1435         if(this.enemy==NULL)
1436         {
1437                 // If no weapon was chosen get the first available weapon
1438                 if(this.(weaponentity).m_weapon==WEP_Null)
1439                 FOREACH(Weapons, it != WEP_Null, {
1440                         if(client_hasweapon(this, it, weaponentity, true, false))
1441                         {
1442                                 this.(weaponentity).m_switchweapon = it;
1443                                 return;
1444                         }
1445                 });
1446                 return;
1447         }
1448
1449         // Do not change weapon during the next second after a combo
1450         float f = time - this.lastcombotime;
1451         if(f < 1)
1452                 return;
1453
1454         float w;
1455         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1456
1457         // Should it do a weapon combo?
1458         float af, ct, combo_time, combo;
1459
1460         af = ATTACK_FINISHED(this, weaponentity);
1461         ct = autocvar_bot_ai_weapon_combo_threshold;
1462
1463         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1464         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1465         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1466
1467         combo = false;
1468
1469         if(autocvar_bot_ai_weapon_combo)
1470         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1471         if(af > combo_time)
1472         {
1473                 combo = true;
1474                 this.lastcombotime = time;
1475         }
1476
1477         distance *= (2 ** this.bot_rangepreference);
1478
1479         // Custom weapon list based on distance to the enemy
1480         if(bot_custom_weapon){
1481
1482                 // Choose weapons for far distance
1483                 if ( distance > bot_distance_far ) {
1484                         for(i=0; i < REGISTRY_COUNT(Weapons) && bot_weapons_far[i] != -1 ; ++i){
1485                                 w = bot_weapons_far[i];
1486                                 if ( client_hasweapon(this, REGISTRY_GET(Weapons, w), weaponentity, true, false) )
1487                                 {
1488                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1489                                                 continue;
1490                                         this.(weaponentity).m_switchweapon = REGISTRY_GET(Weapons, w);
1491                                         return;
1492                                 }
1493                         }
1494                 }
1495
1496                 // Choose weapons for mid distance
1497                 if ( distance > bot_distance_close) {
1498                         for(i=0; i < REGISTRY_COUNT(Weapons) && bot_weapons_mid[i] != -1 ; ++i){
1499                                 w = bot_weapons_mid[i];
1500                                 if ( client_hasweapon(this, REGISTRY_GET(Weapons, w), weaponentity, true, false) )
1501                                 {
1502                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1503                                                 continue;
1504                                         this.(weaponentity).m_switchweapon = REGISTRY_GET(Weapons, w);
1505                                         return;
1506                                 }
1507                         }
1508                 }
1509
1510                 // Choose weapons for close distance
1511                 for(i=0; i < REGISTRY_COUNT(Weapons) && bot_weapons_close[i] != -1 ; ++i){
1512                         w = bot_weapons_close[i];
1513                         if ( client_hasweapon(this, REGISTRY_GET(Weapons, w), weaponentity, true, false) )
1514                         {
1515                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1516                                         continue;
1517                                 this.(weaponentity).m_switchweapon = REGISTRY_GET(Weapons, w);
1518                                 return;
1519                         }
1520                 }
1521         }
1522 }
1523
1524 void havocbot_aim(entity this)
1525 {
1526         if (time < this.nextaim)
1527                 return;
1528         this.nextaim = time + 0.1;
1529         vector myvel = this.velocity;
1530         if (!this.waterlevel)
1531                 myvel.z = 0;
1532         if(MUTATOR_CALLHOOK(HavocBot_Aim, this)) { /* do nothing */ }
1533         else if (this.enemy)
1534         {
1535                 vector enemyvel = this.enemy.velocity;
1536                 if (!this.enemy.waterlevel)
1537                         enemyvel.z = 0;
1538                 lag_additem(this, time + CS(this).ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1539         }
1540         else
1541                 lag_additem(this, time + CS(this).ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1542 }
1543
1544 bool havocbot_moveto_refresh_route(entity this)
1545 {
1546         // Refresh path to goal if necessary
1547         entity wp;
1548         wp = this.havocbot_personal_waypoint;
1549         navigation_goalrating_start(this);
1550         navigation_routerating(this, wp, 10000, 10000);
1551         navigation_goalrating_end(this);
1552         return (this.goalentity != NULL);
1553 }
1554
1555 float havocbot_moveto(entity this, vector pos)
1556 {
1557         entity wp;
1558
1559         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1560         {
1561                 // Step 4: Move to waypoint
1562                 if(this.havocbot_personal_waypoint==NULL)
1563                 {
1564                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1565                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1566                         return CMD_STATUS_ERROR;
1567                 }
1568
1569                 if (!bot_strategytoken_taken)
1570                 if(this.havocbot_personal_waypoint_searchtime<time)
1571                 {
1572                         bot_strategytoken_taken = true;
1573                         if(havocbot_moveto_refresh_route(this))
1574                         {
1575                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1576                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1577                                 this.havocbot_personal_waypoint_failcounter = 0;
1578                         }
1579                         else
1580                         {
1581                                 this.havocbot_personal_waypoint_failcounter += 1;
1582                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1583                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1584                                 {
1585                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1586                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1587                                         delete(this.havocbot_personal_waypoint);
1588                                         return CMD_STATUS_ERROR;
1589                                 }
1590                                 else
1591                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1592                         }
1593                 }
1594
1595                 if(autocvar_bot_debug_goalstack)
1596                         debuggoalstack(this);
1597
1598
1599                 // Go!
1600                 havocbot_movetogoal(this);
1601
1602                 if (!this.bot_aimdir_executed && this.goalcurrent)
1603                 {
1604                         // Heading
1605                         vector dir = get_closer_dest(this.goalcurrent, this.origin);
1606                         dir -= this.origin + this.view_ofs;
1607                         dir.z = 0;
1608                         bot_aimdir(this, dir, 0);
1609                 }
1610
1611                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1612                 {
1613                         // Step 5: Waypoint reached
1614                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1615                         waypoint_remove(this.havocbot_personal_waypoint);
1616                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1617                         return CMD_STATUS_FINISHED;
1618                 }
1619
1620                 return CMD_STATUS_EXECUTING;
1621         }
1622
1623         // Step 2: Linking waypoint
1624         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1625         {
1626                 // Wait until it is linked
1627                 if(!this.havocbot_personal_waypoint.wplinked)
1628                 {
1629                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1630                         return CMD_STATUS_EXECUTING;
1631                 }
1632
1633                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1634                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1635                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1636
1637                 // Step 3: Route to waypoint
1638                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1639
1640                 return CMD_STATUS_EXECUTING;
1641         }
1642
1643         // Step 1: Spawning waypoint
1644         wp = waypoint_spawnpersonal(this, pos);
1645         if(wp==NULL)
1646         {
1647                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1648                 return CMD_STATUS_ERROR;
1649         }
1650
1651         this.havocbot_personal_waypoint = wp;
1652         this.havocbot_personal_waypoint_failcounter = 0;
1653         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1654
1655         // if pos is inside a teleport, then let's mark it as teleport waypoint
1656         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1657         {
1658                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1659                 this.lastteleporttime = 0;
1660         });
1661
1662 /*
1663         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1664                 print("routing to a teleporter\n");
1665         else
1666                 print("routing to a non-teleporter\n");
1667 */
1668
1669         return CMD_STATUS_EXECUTING;
1670 }
1671
1672 float havocbot_resetgoal(entity this)
1673 {
1674         navigation_clearroute(this);
1675         return CMD_STATUS_FINISHED;
1676 }
1677
1678 void havocbot_setupbot(entity this)
1679 {
1680         this.bot_ai = havocbot_ai;
1681         this.cmd_moveto = havocbot_moveto;
1682         this.cmd_resetgoal = havocbot_resetgoal;
1683
1684         // NOTE: bot is not player yet
1685         havocbot_chooserole(this);
1686 }
1687
1688 vector havocbot_dodge(entity this)
1689 {
1690         // LordHavoc: disabled because this is too expensive
1691         return '0 0 0';
1692 #if 0
1693         entity head;
1694         vector dodge, v, n;
1695         float danger, bestdanger, vl, d;
1696         dodge = '0 0 0';
1697         bestdanger = -20;
1698         // check for dangerous objects near bot or approaching bot
1699         head = findchainfloat(bot_dodge, true);
1700         while(head)
1701         {
1702                 if (head.owner != this)
1703                 {
1704                         vl = vlen(head.velocity);
1705                         if (vl > autocvar_sv_maxspeed * 0.3)
1706                         {
1707                                 n = normalize(head.velocity);
1708                                 v = this.origin - head.origin;
1709                                 d = v * n;
1710                                 if (d > (0 - head.bot_dodgerating))
1711                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1712                                 {
1713                                         // calculate direction and distance from the flight path, by removing the forward axis
1714                                         v = v - (n * (v * n));
1715                                         danger = head.bot_dodgerating - vlen(v);
1716                                         if (bestdanger < danger)
1717                                         {
1718                                                 bestdanger = danger;
1719                                                 // dodge to the side of the object
1720                                                 dodge = normalize(v);
1721                                         }
1722                                 }
1723                         }
1724                         else
1725                         {
1726                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1727                                 if (bestdanger < danger)
1728                                 {
1729                                         bestdanger = danger;
1730                                         dodge = normalize(this.origin - head.origin);
1731                                 }
1732                         }
1733                 }
1734                 head = head.chain;
1735         }
1736         return dodge;
1737 #endif
1738 }