qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include <common/constants.qh>
   4 #include <common/impulses/all.qh>
   5 #include <common/items/_mod.qh>
   6 #include <common/mapobjects/func/ladder.qh>
   7 #include <common/mapobjects/teleporters.qh>
   8 #include <common/mapobjects/trigger/hurt.qh>
   9 #include <common/mapobjects/trigger/jumppads.qh>
  10 #include <common/mutators/mutator/powerups/_mod.qh>
  11 #include <common/mutators/mutator/status_effects/_mod.qh>
  12 #include <common/net_linked.qh>
  13 #include <common/physics/player.qh>
  14 #include <common/state.qh>
  15 #include <common/stats.qh>
  16 #include <common/weapons/_all.qh>
  17 #include <common/wepent.qh>
  18 #include <lib/warpzone/common.qh>
  19 #include <server/bot/api.qh>
  20 #include <server/bot/default/aim.qh>
  21 #include <server/bot/default/bot.qh>
  22 #include <server/bot/default/cvars.qh>
  23 #include <server/bot/default/havocbot/roles.qh>
  24 #include <server/bot/default/navigation.qh>
  25 #include <server/bot/default/scripting.qh>
  26 #include <server/bot/default/waypoints.qh>
  27 #include <server/client.qh>
  28 #include <server/damage.qh>
  29 #include <server/items/items.qh>
  30 #include <server/mutators/_mod.qh>
  31 #include <server/weapons/selection.qh>
  32 #include <server/weapons/weaponsystem.qh>
  33 #include <server/world.qh>
  34
  35 void havocbot_ai(entity this)
  36 {
  37         if(this.draggedby)
  38                 return;
  39
  40         this.bot_aimdir_executed = false;
  41         // lock aim if teleported or passing through a warpzone
  42         if (this.lastteleporttime && !this.jumppadcount)
  43                 this.bot_aimdir_executed = true;
  44
  45         if(bot_execute_commands(this))
  46                 return;
  47
  48         // after bot_execute_commands otherwise bots can't be unpaused
  49         if (bot_ispaused(this))
  50                 return;
  51
  52         if (bot_strategytoken == this && !bot_strategytoken_taken)
  53         {
  54                 if(this.havocbot_blockhead)
  55                 {
  56                         this.havocbot_blockhead = false;
  57                 }
  58                 else
  59                 {
  60                         if (!this.jumppadcount && !STAT(FROZEN, this)
  61                                 && !(this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP) && !IS_ONGROUND(this)))
  62                         {
  63                                 // find a new goal
  64                                 this.havocbot_role(this); // little too far down the rabbit hole
  65                         }
  66                 }
  67
  68                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  69                 if(!(IS_DEAD(this) || STAT(FROZEN, this)))
  70                 if(!this.goalcurrent)
  71                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  72                 {
  73                         // Look for the closest waypoint out of water
  74                         entity newgoal = NULL;
  75                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  76                         {
  77                                 if(it.origin.z < this.origin.z)
  78                                         continue;
  79
  80                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  81                                         continue;
  82
  83                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  84                                         continue;
  85
  86                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  87
  88                                 if(trace_fraction < 1)
  89                                         continue;
  90
  91                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  92                                         newgoal = it;
  93                         });
  94
  95                         if(newgoal)
  96                         {
  97                         //      te_wizspike(newgoal.origin);
  98                                 navigation_pushroute(this, newgoal);
  99                         }
 100                 }
 101
 102                 // token has been used this frame
 103                 bot_strategytoken_taken = true;
 104         }
 105
 106         if (this.goalcurrent && wasfreed(this.goalcurrent))
 107         {
 108                 navigation_clearroute(this);
 109                 navigation_goalrating_timeout_force(this);
 110                 return;
 111         }
 112
 113         if(IS_DEAD(this) || STAT(FROZEN, this))
 114         {
 115                 if (this.goalcurrent)
 116                         navigation_clearroute(this);
 117                 this.enemy = NULL;
 118                 return;
 119         }
 120
 121         havocbot_chooseenemy(this);
 122
 123         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 124         {
 125                 .entity weaponentity = weaponentities[slot];
 126                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
 127                 if(this.(weaponentity).bot_chooseweapontime < time)
 128                 {
 129                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
 130                         havocbot_chooseweapon(this, weaponentity);
 131                 }
 132         }
 133         havocbot_aim(this);
 134
 135         if (this.enemy)
 136         {
 137                 this.aistatus |= AI_STATUS_ATTACKING;
 138                 this.aistatus &= ~AI_STATUS_ROAMING;
 139
 140                 if(STAT(WEAPONS, this))
 141                 {
 142                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 143                         {
 144                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 145                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 146                         }
 147                         else
 148                         {
 149                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 150                                 {
 151                                         .entity weaponentity = weaponentities[slot];
 152                                         Weapon w = this.(weaponentity).m_weapon;
 153                                         if(w == WEP_Null && slot != 0)
 154                                                 continue;
 155                                         w.wr_aim(w, this, weaponentity);
 156                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
 157                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 158                                 }
 159                         }
 160                 }
 161                 else
 162                 {
 163                         if(IS_PLAYER(this.enemy))
 164                                 bot_aimdir(this, this.enemy.origin + this.enemy.view_ofs - this.origin - this.view_ofs, 0);
 165                 }
 166         }
 167         else if (this.goalcurrent)
 168         {
 169                 this.aistatus |= AI_STATUS_ROAMING;
 170                 this.aistatus &= ~AI_STATUS_ATTACKING;
 171         }
 172
 173         havocbot_movetogoal(this);
 174         if (!this.bot_aimdir_executed && this.goalcurrent)
 175         {
 176                 // Heading
 177                 vector dir = get_closer_dest(this.goalcurrent, this.origin);
 178                 dir -= this.origin + this.view_ofs;
 179                 dir.z = 0;
 180                 bot_aimdir(this, dir, 0);
 181         }
 182
 183         // if the bot is not attacking, consider reloading weapons
 184         if (!(this.aistatus & AI_STATUS_ATTACKING))
 185         {
 186                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 187                 {
 188                         .entity weaponentity = weaponentities[slot];
 189
 190                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 191                                 continue;
 192
 193                         // we are currently holding a weapon that's not fully loaded, reload it
 194                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 195                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
 196                                 CS(this).impulse = IMP_weapon_reload.impulse; // not sure if this is done right
 197
 198                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 199                         // the code above executes next frame, starting the reloading then
 200                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
 201                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
 202                         {
 203                                 FOREACH(Weapons, it != WEP_Null, {
 204                                         if((STAT(WEAPONS, this) & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
 205                                         {
 206                                                 this.(weaponentity).m_switchweapon = it;
 207                                                 break;
 208                                         }
 209                                 });
 210                         }
 211                 }
 212         }
 213 }
 214
 215 void havocbot_bunnyhop(entity this, vector dir)
 216 {
 217         bool can_run = false;
 218         if (!(this.aistatus & AI_STATUS_ATTACKING) && this.goalcurrent && !IS_PLAYER(this.goalcurrent)
 219                 && vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed) && !(this.aistatus & AI_STATUS_DANGER_AHEAD)
 220                 && this.waterlevel <= WATERLEVEL_WETFEET && !IS_DUCKED(this)
 221                 && IS_ONGROUND(this) && !(this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)))
 222         {
 223                 vector vel_angles = vectoangles(this.velocity);
 224                 vector deviation = vel_angles - vectoangles(dir);
 225                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 226                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 227                 if (fabs(deviation.y) < autocvar_bot_ai_bunnyhop_dir_deviation_max)
 228                 {
 229                         vector gco = get_closer_dest(this.goalcurrent, this.origin);
 230                         float vel = vlen(vec2(this.velocity));
 231
 232                         // with the current physics, jump distance grows linearly with the speed
 233                         float jump_distance = 52.661 + 0.606 * vel;
 234                         jump_distance += this.origin.z - gco.z; // roughly take into account vertical distance too
 235                         if (vdist(vec2(gco - this.origin), >, max(0, jump_distance)))
 236                                 can_run = true;
 237                         else if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_JUMP)
 238                                 && !(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 239                                 && this.goalstack01 && !wasfreed(this.goalstack01) && !(this.goalstack01.wpflags & WAYPOINTFLAG_JUMP)
 240                                 && vdist(vec2(gco - this.goalstack01.origin), >, 70))
 241                         {
 242                                 vector gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 243                                 vector ang = vectoangles(gco - this.origin);
 244                                 deviation = vectoangles(gno - gco) - vel_angles;
 245                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 246                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 247
 248                                 float max_turn_angle = autocvar_bot_ai_bunnyhop_turn_angle_max;
 249                                 max_turn_angle -= autocvar_bot_ai_bunnyhop_turn_angle_reduction * ((vel - autocvar_sv_maxspeed) / autocvar_sv_maxspeed);
 250                                 if ((ang.x < 90 || ang.x > 360 - autocvar_bot_ai_bunnyhop_downward_pitch_max)
 251                                         && fabs(deviation.y) < max(autocvar_bot_ai_bunnyhop_turn_angle_min, max_turn_angle))
 252                                 {
 253                                         can_run = true;
 254                                 }
 255                         }
 256                 }
 257         }
 258
 259         if (can_run)
 260         {
 261                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 262                 this.bot_jump_time = time;
 263                 this.aistatus |= AI_STATUS_RUNNING;
 264         }
 265         else
 266         {
 267                 if (IS_ONGROUND(this) || this.waterlevel > WATERLEVEL_WETFEET)
 268                         this.aistatus &= ~AI_STATUS_RUNNING;
 269         }
 270 }
 271
 272 void havocbot_keyboard_movement(entity this, vector destorg)
 273 {
 274         if(time <= this.havocbot_keyboardtime)
 275                 return;
 276
 277         float sk = skill + this.bot_moveskill;
 278         this.havocbot_keyboardtime =
 279                 max(
 280                         this.havocbot_keyboardtime
 281                                 + 0.05 / max(1, sk + this.havocbot_keyboardskill)
 282                                 + random() * 0.025 / max(0.00025, skill + this.havocbot_keyboardskill)
 283                 , time);
 284         vector keyboard = CS(this).movement / autocvar_sv_maxspeed;
 285
 286         float trigger = autocvar_bot_ai_keyboard_threshold;
 287
 288         // categorize forward movement
 289         // at skill < 1.5 only forward
 290         // at skill < 2.5 only individual directions
 291         // at skill < 4.5 only individual directions, and forward diagonals
 292         // at skill >= 4.5, all cases allowed
 293         if (keyboard.x > trigger)
 294         {
 295                 keyboard.x = 1;
 296                 if (sk < 2.5)
 297                         keyboard.y = 0;
 298         }
 299         else if (keyboard.x < -trigger && sk > 1.5)
 300         {
 301                 keyboard.x = -1;
 302                 if (sk < 4.5)
 303                         keyboard.y = 0;
 304         }
 305         else
 306         {
 307                 keyboard.x = 0;
 308                 if (sk < 1.5)
 309                         keyboard.y = 0;
 310         }
 311         if (sk < 4.5)
 312                 keyboard.z = 0;
 313
 314         if (keyboard.y > trigger)
 315                 keyboard.y = 1;
 316         else if (keyboard.y < -trigger)
 317                 keyboard.y = -1;
 318         else
 319                 keyboard.y = 0;
 320
 321         if (keyboard.z > trigger)
 322                 keyboard.z = 1;
 323         else if (keyboard.z < -trigger)
 324                 keyboard.z = -1;
 325         else
 326                 keyboard.z = 0;
 327
 328         // make sure bots don't get stuck if havocbot_keyboardtime is very high
 329         if (keyboard == '0 0 0')
 330                 this.havocbot_keyboardtime = min(this.havocbot_keyboardtime, time + 0.2);
 331
 332         this.havocbot_keyboard = keyboard * autocvar_sv_maxspeed;
 333         if (this.havocbot_ducktime > time)
 334                 PHYS_INPUT_BUTTON_CROUCH(this) = true;
 335
 336         keyboard = this.havocbot_keyboard;
 337         float blend = bound(0, vlen(destorg - this.origin) / autocvar_bot_ai_keyboard_distance, 1); // When getting close move with 360 degree
 338         //dprint("movement ", vtos(CS(this).movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 339         CS(this).movement = CS(this).movement + (keyboard - CS(this).movement) * blend;
 340 }
 341
 342 // return true when bot isn't getting closer to the current goal
 343 bool havocbot_checkgoaldistance(entity this, vector gco)
 344 {
 345         if (this.bot_stop_moving_timeout > time)
 346                 return false;
 347         float curr_dist_z = max(20, fabs(this.origin.z - gco.z));
 348         float curr_dist_2d = max(20, vlen(vec2(this.origin - gco)));
 349         float distance_time = this.goalcurrent_distance_time;
 350         if(distance_time < 0)
 351                 distance_time = -distance_time;
 352         if(curr_dist_z >= this.goalcurrent_distance_z && curr_dist_2d >= this.goalcurrent_distance_2d)
 353         {
 354                 if(!distance_time)
 355                         this.goalcurrent_distance_time = time;
 356                 else if (time - distance_time > 0.5)
 357                         return true;
 358         }
 359         else
 360         {
 361                 // reduce it a little bit so it works even with very small approaches to the goal
 362                 this.goalcurrent_distance_z = max(20, curr_dist_z - 10);
 363                 this.goalcurrent_distance_2d = max(20, curr_dist_2d - 10);
 364                 this.goalcurrent_distance_time = 0;
 365         }
 366         return false;
 367 }
 368
 369 entity havocbot_select_an_item_of_group(entity this, int gr)
 370 {
 371         entity selected = NULL;
 372         float selected_dist2 = 0;
 373         // select farthest item of this group from bot's position
 374         IL_EACH(g_items, it.item_group == gr && it.solid,
 375         {
 376                 float dist2 = vlen2(this.origin - it.origin);
 377                 if (dist2 < 600 ** 2 && dist2 > selected_dist2)
 378                 {
 379                         selected = it;
 380                         selected_dist2 = vlen2(this.origin - selected.origin);
 381                 }
 382         });
 383
 384         if (!selected)
 385                 return NULL;
 386
 387         set_tracewalk_dest(selected, this.origin, false);
 388         if (!tracewalk(this, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this),
 389                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
 390         {
 391                 return NULL;
 392         }
 393
 394         return selected;
 395 }
 396
 397 void havocbot_movetogoal(entity this)
 398 {
 399         vector diff;
 400         vector dir;
 401         vector flatdir;
 402         float dodge_enemy_factor = 1;
 403         float maxspeed;
 404         //float dist;
 405         vector dodge;
 406         //if (this.goalentity)
 407         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 408         CS(this).movement = '0 0 0';
 409         maxspeed = autocvar_sv_maxspeed;
 410
 411         PHYS_INPUT_BUTTON_CROUCH(this) = boolean(this.goalcurrent.wpflags & WAYPOINTFLAG_CROUCH);
 412
 413         PHYS_INPUT_BUTTON_JETPACK(this) = false;
 414         // Jetpack navigation
 415         if(this.navigation_jetpack_goal)
 416         if(this.goalcurrent==this.navigation_jetpack_goal)
 417         if(GetResource(this, RES_FUEL))
 418         {
 419                 if(autocvar_bot_debug_goalstack)
 420                 {
 421                         debuggoalstack(this);
 422                         te_wizspike(this.navigation_jetpack_point);
 423                 }
 424
 425                 // Take off
 426                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 427                 {
 428                         // Brake almost completely so it can get a good direction
 429                         if(vdist(this.velocity, >, 10))
 430                                 return;
 431                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 432                 }
 433
 434                 makevectors(this.v_angle.y * '0 1 0');
 435                 dir = normalize(this.navigation_jetpack_point - this.origin);
 436
 437                 // Landing
 438                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 439                 {
 440                         // Calculate brake distance in xy
 441                         float d = vlen(vec2(this.origin - (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5));
 442                         float vel2 = vlen2(vec2(this.velocity));
 443                         float db = (vel2 / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 444                         //LOG_INFOF("distance %d, velocity %d, brake at %d ", ceil(d), ceil(v), ceil(db));
 445                         if(d < db || d < 500)
 446                         {
 447                                 // Brake
 448                                 if (vel2 > (maxspeed * 0.3) ** 2)
 449                                 {
 450                                         CS(this).movement_x = dir * v_forward * -maxspeed;
 451                                         return;
 452                                 }
 453                                 // Switch to normal mode
 454                                 this.navigation_jetpack_goal = NULL;
 455                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 456                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 457                                 return;
 458                         }
 459                 }
 460                 else if(checkpvs(this.origin,this.goalcurrent))
 461                 {
 462                         // If I can see the goal switch to landing code
 463                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 464                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 465                         return;
 466                 }
 467
 468                 // Flying
 469                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 470                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
 471                 {
 472                         CS(this).movement_x = dir * v_forward * maxspeed;
 473                         CS(this).movement_y = dir * v_right * maxspeed;
 474                 }
 475                 return;
 476         }
 477
 478         // Handling of jump pads
 479         if(this.jumppadcount)
 480         {
 481                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 482                 {
 483                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 484                         if(navigation_poptouchedgoals(this))
 485                                 return;
 486                 }
 487                 else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 488                 {
 489                         // If got stuck on the jump pad try to reach the farthest visible waypoint
 490                         // but with some randomness so it can try out different paths
 491                         if(!this.goalcurrent)
 492                         {
 493                                 entity newgoal = NULL;
 494                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 495                                 {
 496                                         if(it.wpflags & WAYPOINTFLAG_TELEPORT)
 497                                         if(it.origin.z < this.origin.z - 100 && vdist(vec2(it.origin - this.origin), <, 100))
 498                                                 continue;
 499
 500                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 501
 502                                         if(trace_fraction < 1)
 503                                                 continue;
 504
 505                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
 506                                                 newgoal = it;
 507                                 });
 508
 509                                 if(newgoal)
 510                                 {
 511                                         this.ignoregoal = this.goalcurrent;
 512                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 513                                         navigation_clearroute(this);
 514                                         navigation_routetogoal(this, newgoal, this.origin);
 515                                         if(autocvar_bot_debug_goalstack)
 516                                                 debuggoalstack(this);
 517                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 518                                 }
 519                         }
 520                         else //if (this.goalcurrent)
 521                         {
 522                                 if (this.goalcurrent.bot_pickup)
 523                                 {
 524                                         entity jumppad_wp = this.goalcurrent_prev;
 525                                         navigation_poptouchedgoals(this);
 526                                         if(!this.goalcurrent && jumppad_wp.wp00)
 527                                         {
 528                                                 // head to the jumppad destination once bot reaches the goal item
 529                                                 navigation_pushroute(this, jumppad_wp.wp00);
 530                                         }
 531                                 }
 532                                 vector gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 533                                 if (this.origin.z > gco.z && vdist(vec2(this.velocity), <, autocvar_sv_maxspeed))
 534                                 {
 535                                         if (this.velocity.z < 0)
 536                                                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 537                                 }
 538                                 else if(havocbot_checkgoaldistance(this, gco))
 539                                 {
 540                                         navigation_clearroute(this);
 541                                         navigation_goalrating_timeout_force(this);
 542                                 }
 543                                 else
 544                                         return;
 545                         }
 546                 }
 547                 else //if (!(this.aistatus & AI_STATUS_OUT_JUMPPAD))
 548                 {
 549                         if(this.velocity.z > 0 && this.origin.z - this.lastteleport_origin.z > (this.maxs.z - this.mins.z) * 0.5)
 550                         {
 551                                 vector velxy = this.velocity; velxy_z = 0;
 552                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
 553                                 {
 554                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 555                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 556                                 }
 557                                 return;
 558                         }
 559
 560                         // Don't chase players while using a jump pad
 561                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 562                                 return;
 563                 }
 564         }
 565         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 566                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 567
 568         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 569         if (skill > 6 && !(IS_ONGROUND(this)))
 570         {
 571                 #define ROCKETJUMP_DAMAGE() WEP_CVAR(devastator, damage) * 0.8 \
 572                         * ((StatusEffects_active(STATUSEFFECT_Strength, this)) ? autocvar_g_balance_powerup_strength_selfdamage : 1) \
 573                         * ((StatusEffects_active(STATUSEFFECT_Shield, this)) ? autocvar_g_balance_powerup_invincible_takedamage : 1)
 574
 575                 // save some CPU cycles by checking trigger_hurt after checking
 576                 // that something can be done to evade it (cheaper checks)
 577                 int action_for_trigger_hurt = 0;
 578                 if (this.items & IT_JETPACK)
 579                         action_for_trigger_hurt = 1;
 580                 else if (!this.jumppadcount && !waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
 581                         && !(this.goalcurrent_prev && this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)
 582                         && GetResource(this, RES_HEALTH) + GetResource(this, RES_ARMOR) > ROCKETJUMP_DAMAGE())
 583                 {
 584                         action_for_trigger_hurt = 2;
 585                 }
 586                 else if (!this.goalcurrent)
 587                         action_for_trigger_hurt = 3;
 588
 589                 if (action_for_trigger_hurt)
 590                 {
 591                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 592                         if(!tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos))
 593                                 action_for_trigger_hurt = 0;
 594                 }
 595
 596                 if(action_for_trigger_hurt == 1) // jetpack
 597                 {
 598                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 599                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 600                         {
 601                                 if(this.velocity.z<0)
 602                                         PHYS_INPUT_BUTTON_JETPACK(this) = true;
 603                         }
 604                         else
 605                                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 606
 607                         // If there is no goal try to move forward
 608
 609                         if(this.goalcurrent==NULL)
 610                                 dir = v_forward;
 611                         else
 612                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 613
 614                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 615                         float xyspeed = xyvelocity * dir;
 616
 617                         if(xyspeed < (maxspeed / 2))
 618                         {
 619                                 makevectors(this.v_angle.y * '0 1 0');
 620                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 621                                 if(trace_fraction==1)
 622                                 {
 623                                         CS(this).movement_x = dir * v_forward * maxspeed;
 624                                         CS(this).movement_y = dir * v_right * maxspeed;
 625                                         if (skill < 10)
 626                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 627                                 }
 628                         }
 629
 630                         this.havocbot_blockhead = true;
 631
 632                         return;
 633                 }
 634                 else if(action_for_trigger_hurt == 2) // rocketjump
 635                 {
 636                         if(this.velocity.z < 0)
 637                         {
 638                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 639                                 {
 640                                         .entity weaponentity = weaponentities[slot];
 641
 642                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 643                                                 continue;
 644
 645                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
 646                                         {
 647                                                 CS(this).movement_x = maxspeed;
 648
 649                                                 if(this.rocketjumptime)
 650                                                 {
 651                                                         if(time > this.rocketjumptime)
 652                                                         {
 653                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 654                                                                 this.rocketjumptime = 0;
 655                                                         }
 656                                                         return;
 657                                                 }
 658
 659                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 660                                                 this.v_angle_x = 90;
 661                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 662                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 663                                                 return;
 664                                         }
 665                                 }
 666                         }
 667                 }
 668                 else if(action_for_trigger_hurt == 3) // no goal
 669                 {
 670                         // If there is no goal try to move forward
 671                         CS(this).movement_x = maxspeed;
 672                 }
 673         }
 674
 675         // If we are under water with no goals, swim up
 676         if(this.waterlevel && !this.goalcurrent)
 677         {
 678                 dir = '0 0 0';
 679                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 680                         dir.z = 1;
 681                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 682                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 683                 makevectors(this.v_angle.y * '0 1 0');
 684                 vector v = dir * maxspeed;
 685                 CS(this).movement.x = v * v_forward;
 686                 CS(this).movement.y = v * v_right;
 687                 CS(this).movement.z = v * v_up;
 688         }
 689
 690         // if there is nowhere to go, exit
 691         if (this.goalcurrent == NULL)
 692                 return;
 693
 694
 695         bool locked_goal = false;
 696         if((this.goalentity && wasfreed(this.goalentity))
 697                 || (this.goalcurrent == this.goalentity && this.goalentity.tag_entity))
 698         {
 699                 navigation_clearroute(this);
 700                 navigation_goalrating_timeout_force(this);
 701                 return;
 702         }
 703         else if(this.goalentity.tag_entity)
 704         {
 705                 navigation_goalrating_timeout_expire(this, 2);
 706         }
 707         else if(this.goalentity.bot_pickup)
 708         {
 709                 if(this.goalentity.bot_pickup_respawning)
 710                 {
 711                         if(this.goalentity.solid) // item respawned
 712                                 this.goalentity.bot_pickup_respawning = false;
 713                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
 714                         {
 715                                 if(checkpvs(this.origin, this.goalentity))
 716                                 {
 717                                         this.goalentity.bot_pickup_respawning = false;
 718                                         navigation_goalrating_timeout_expire(this, random());
 719                                 }
 720                                 locked_goal = true; // wait for item to respawn
 721                         }
 722                         else if(this.goalentity == this.goalcurrent)
 723                                 locked_goal = true; // wait for item to respawn
 724                 }
 725                 else if(!this.goalentity.solid && !boxesoverlap(this.goalentity.absmin, this.goalentity.absmax, this.absmin, this.absmax))
 726                 {
 727                         if(checkpvs(this.origin, this.goalentity))
 728                         {
 729                                 navigation_goalrating_timeout_expire(this, random());
 730                         }
 731                 }
 732         }
 733         if (this.goalcurrent == this.goalentity && this.goalentity_lock_timeout > time)
 734                 locked_goal = true;
 735
 736         if (navigation_shortenpath(this))
 737         {
 738                 if (vdist(this.origin - this.goalcurrent_prev.origin, <, 50)
 739                         && navigation_goalrating_timeout_can_be_anticipated(this))
 740                 {
 741                         navigation_goalrating_timeout_force(this);
 742                 }
 743         }
 744
 745         bool goalcurrent_can_be_removed = false;
 746         if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 747         {
 748                 bool freeze_state_changed = (boolean(STAT(FROZEN, this.goalentity)) != this.goalentity_shouldbefrozen);
 749                 if (IS_DEAD(this.goalcurrent) || (this.goalentity == this.goalcurrent && freeze_state_changed))
 750                 {
 751                         goalcurrent_can_be_removed = true;
 752                         // don't remove if not visible
 753                         if (checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 754                         {
 755                                 if (IS_DEAD(this.goalcurrent))
 756                                 {
 757                                         IL_EACH(g_items, it.enemy == this.goalcurrent && Item_IsLoot(it),
 758                                         {
 759                                                 if (vdist(it.origin - this.goalcurrent.death_origin, <, 50))
 760                                                 {
 761                                                         navigation_clearroute(this);
 762                                                         navigation_pushroute(this, it);
 763                                                         // loot can't be immediately rated since it isn't on ground yet
 764                                                         // it will be rated after a second when on ground, meanwhile head to it
 765                                                         navigation_goalrating_timeout_expire(this, 1);
 766                                                         return;
 767                                                 }
 768                                         });
 769                                 }
 770                                 if (!Item_IsLoot(this.goalcurrent))
 771                                 {
 772                                         navigation_goalrating_timeout_force(this);
 773                                         return;
 774                                 }
 775                         }
 776                 }
 777                 else if (!(STAT(FROZEN, this.goalentity)) && this.bot_tracewalk_time < time)
 778                 {
 779                         set_tracewalk_dest(this.goalcurrent, this.origin, true);
 780                         if (!(trace_ent == this || tracewalk(this, this.origin, this.mins, this.maxs,
 781                                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode)))
 782                         {
 783                                 navigation_goalrating_timeout_force(this);
 784                                 return;
 785                         }
 786                         this.bot_tracewalk_time = max(time, this.bot_tracewalk_time) + 0.25;
 787                 }
 788         }
 789
 790         if(!locked_goal)
 791         {
 792                 // optimize path finding by anticipating goalrating when bot is near a waypoint;
 793                 // in this case path finding can start directly from a waypoint instead of
 794                 // looking for all the reachable waypoints up to a certain distance
 795                 if (navigation_poptouchedgoals(this))
 796                 {
 797                         if (this.goalcurrent)
 798                         {
 799                                 if (goalcurrent_can_be_removed)
 800                                 {
 801                                         // remove even if not visible
 802                                         navigation_goalrating_timeout_force(this);
 803                                         return;
 804                                 }
 805                                 else if (navigation_goalrating_timeout_can_be_anticipated(this))
 806                                         navigation_goalrating_timeout_force(this);
 807                         }
 808                         else
 809                         {
 810                                 entity old_goal = this.goalcurrent_prev;
 811                                 if (old_goal.item_group && this.item_group != old_goal.item_group)
 812                                 {
 813                                         // Avoid multiple costly calls of path finding code that selects one of the closest
 814                                         // item of the group by telling the bot to head directly to the farthest item.
 815                                         // Next time we let the bot select a goal as usual which can be another item
 816                                         // of this group (the closest one) and so on
 817                                         this.item_group = old_goal.item_group;
 818                                         entity new_goal = havocbot_select_an_item_of_group(this, old_goal.item_group);
 819                                         if (new_goal)
 820                                                 navigation_pushroute(this, new_goal);
 821                                 }
 822                         }
 823                 }
 824         }
 825
 826         // if ran out of goals try to use an alternative goal or get a new strategy asap
 827         if(this.goalcurrent == NULL)
 828         {
 829                 navigation_goalrating_timeout_force(this);
 830                 return;
 831         }
 832
 833
 834         if(autocvar_bot_debug_goalstack)
 835                 debuggoalstack(this);
 836
 837         bool bunnyhop_forbidden = false;
 838         vector destorg = get_closer_dest(this.goalcurrent, this.origin);
 839         if (this.jumppadcount && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 840         {
 841                 // if bot used the jumppad, push towards jumppad origin until jumppad waypoint gets removed
 842                 destorg = this.goalcurrent.origin;
 843         }
 844         else if (this.goalcurrent.wpisbox)
 845         {
 846                 // if bot is inside the teleport waypoint, head to teleport origin until teleport gets used
 847                 // do it even if bot is on a ledge above a teleport/jumppad so it doesn't get stuck
 848                 if (boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin + eZ * this.mins.z, this.origin + eZ * this.maxs.z)
 849                         || (this.absmin.z > destorg.z && destorg.x == this.origin.x && destorg.y == this.origin.y))
 850                 {
 851                         bunnyhop_forbidden = true;
 852                         destorg = this.goalcurrent.origin;
 853                         if(destorg.z > this.origin.z)
 854                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 855                 }
 856         }
 857
 858         diff = destorg - this.origin;
 859
 860         if (time < this.bot_stop_moving_timeout
 861                 || (this.goalcurrent == this.goalentity && time < this.goalentity_lock_timeout && vdist(diff, <, 10)))
 862         {
 863                 // stop if the locked goal has been reached
 864                 destorg = this.origin;
 865                 diff = dir = '0 0 0';
 866         }
 867         else if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 868         {
 869                 if (vdist(diff, <, 80))
 870                 {
 871                         // stop if too close to target player (even if frozen)
 872                         destorg = this.origin;
 873                         diff = dir = '0 0 0';
 874                 }
 875                 else
 876                 {
 877                         // move destorg out of target players, otherwise bot will consider them
 878                         // an obstacle that needs to be jumped (especially if frozen)
 879                         dir = normalize(diff);
 880                         destorg -= dir * PL_MAX_CONST.x * M_SQRT2;
 881                         diff = destorg - this.origin;
 882                 }
 883         }
 884         else
 885                 dir = normalize(diff);
 886         flatdir = (diff.z == 0) ? dir : normalize(vec2(diff));
 887
 888         bool danger_detected = false;
 889         vector do_break = '0 0 0';
 890
 891         //if (this.bot_dodgevector_time < time)
 892         {
 893                 //this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 894                 //this.bot_dodgevector_jumpbutton = 1;
 895
 896                 this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 897                 makevectors(this.v_angle.y * '0 1 0');
 898                 if (this.waterlevel > WATERLEVEL_WETFEET)
 899                 {
 900                         if (this.waterlevel > WATERLEVEL_SWIMMING)
 901                         {
 902                                 if(!this.goalcurrent)
 903                                         this.aistatus |= AI_STATUS_OUT_WATER;
 904                                 else if(destorg.z > this.origin.z)
 905                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 906                         }
 907                         else
 908                         {
 909                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && destorg.z < this.origin.z) &&
 910                                         (this.aistatus & AI_STATUS_OUT_WATER))
 911                                 {
 912                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 913                                         dir = flatdir;
 914                                 }
 915                                 else
 916                                 {
 917                                         if (destorg.z > this.origin.z)
 918                                                 dir = flatdir;
 919                                 }
 920                         }
 921                 }
 922                 else
 923                 {
 924                         float s;
 925                         vector offset;
 926                         if(this.aistatus & AI_STATUS_OUT_WATER)
 927                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 928
 929                         // jump if going toward an obstacle that doesn't look like stairs we
 930                         // can walk up directly
 931                         vector deviation = '0 0 0';
 932                         float current_speed = vlen(vec2(this.velocity));
 933                         if (current_speed < maxspeed * 0.2)
 934                                 current_speed = maxspeed * 0.2;
 935                         else
 936                         {
 937                                 deviation = vectoangles(diff) - vectoangles(this.velocity);
 938                                 while (deviation.y < -180) deviation.y += 360;
 939                                 while (deviation.y > 180) deviation.y -= 360;
 940                         }
 941                         float turning = false;
 942                         vector flat_diff = vec2(diff);
 943                         offset = max(32, current_speed * cos(deviation.y * DEG2RAD) * 0.3) * flatdir;
 944                         vector actual_destorg = this.origin + offset;
 945                         if (this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP))
 946                         {
 947                                 if (time > this.bot_stop_moving_timeout
 948                                         && fabs(deviation.y) > 20 && current_speed > maxspeed * 0.4
 949                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), <, 50))
 950                                 {
 951                                         this.bot_stop_moving_timeout = time + 0.1;
 952                                 }
 953                                 if (current_speed > autocvar_sv_maxspeed * 0.9
 954                                         && vlen2(flat_diff) < vlen2(vec2(this.goalcurrent_prev.origin - destorg))
 955                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), >, 50)
 956                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), <, 150)
 957                                 )
 958                                 {
 959                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 960                                         this.bot_jump_time = time;
 961                                 }
 962                         }
 963                         else if (!this.goalstack01 || (this.goalcurrent.wpflags & (WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_LADDER)))
 964                         {
 965                                 if (vlen2(flat_diff) < vlen2(offset))
 966                                 {
 967                                         if ((this.goalcurrent.wpflags & WAYPOINTFLAG_JUMP) && this.goalstack01)
 968                                         {
 969                                                 // oblique warpzones need a jump otherwise bots gets stuck
 970                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 971                                         }
 972                                         else
 973                                         {
 974                                                 actual_destorg.x = destorg.x;
 975                                                 actual_destorg.y = destorg.y;
 976                                         }
 977                                 }
 978                         }
 979                         else if (vdist(flat_diff, <, 32) && diff.z < -16) // destination is under the bot
 980                         {
 981                                 actual_destorg.x = destorg.x;
 982                                 actual_destorg.y = destorg.y;
 983                         }
 984                         else if (vlen2(flat_diff) < vlen2(offset))
 985                         {
 986                                 vector next_goal_org = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 987                                 vector next_dir = normalize(vec2(next_goal_org - destorg));
 988                                 float dist = vlen(vec2(this.origin + offset - destorg));
 989                                 // if current and next goal are close to each other make sure
 990                                 // actual_destorg isn't set beyond next_goal_org
 991                                 if (dist ** 2 > vlen2(vec2(next_goal_org - destorg)))
 992                                         actual_destorg = next_goal_org;
 993                                 else
 994                                         actual_destorg = vec2(destorg) + dist * next_dir;
 995                                 actual_destorg.z = this.origin.z;
 996                                 turning = true;
 997                         }
 998
 999                         LABEL(jumpobstacle_check);
1000                         dir = flatdir = normalize(actual_destorg - this.origin);
1001
1002                         bool jump_forbidden = false;
1003                         if (!turning && fabs(deviation.y) > 50)
1004                                 jump_forbidden = true;
1005                         else if (IS_DUCKED(this))
1006                         {
1007                                 tracebox(this.origin, PL_MIN_CONST, PL_MAX_CONST, this.origin, false, this);
1008                                 if (trace_startsolid)
1009                                         jump_forbidden = true;
1010                         }
1011
1012                         if (!jump_forbidden)
1013                         {
1014                                 tracebox(this.origin, this.mins, this.maxs, actual_destorg, false, this);
1015                                 if (trace_fraction < 1 && trace_plane_normal.z < 0.7)
1016                                 {
1017                                         s = trace_fraction;
1018                                         tracebox(this.origin + stepheightvec, this.mins, this.maxs, actual_destorg + stepheightvec, false, this);
1019                                         if (trace_fraction < s + 0.01 && trace_plane_normal.z < 0.7)
1020                                         {
1021                                                 // found an obstacle
1022                                                 if (turning && fabs(deviation.y) > 5)
1023                                                 {
1024                                                         // check if the obstacle is still there without turning
1025                                                         actual_destorg = destorg;
1026                                                         turning = false;
1027                                                         this.bot_tracewalk_time = time + 0.25;
1028                                                         goto jumpobstacle_check;
1029                                                 }
1030                                                 s = trace_fraction;
1031                                                 // don't artificially reduce max jump height in real-time
1032                                                 // (jumpstepheightvec is reduced a bit to make the jumps easy in tracewalk)
1033                                                 vector jump_height = (IS_ONGROUND(this)) ? stepheightvec + jumpheight_vec : jumpstepheightvec;
1034                                                 tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1035                                                 if (trace_fraction > s)
1036                                                 {
1037                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1038                                                         this.bot_jump_time = time;
1039                                                 }
1040                                                 else
1041                                                 {
1042                                                         jump_height = stepheightvec + jumpheight_vec / 2;
1043                                                         tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1044                                                         if (trace_fraction > s)
1045                                                         {
1046                                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1047                                                                 this.bot_jump_time = time;
1048                                                         }
1049                                                 }
1050                                         }
1051                                 }
1052                         }
1053
1054                         // if bot for some reason doesn't get close to the current goal find another one
1055                         if(!this.jumppadcount && !IS_PLAYER(this.goalcurrent))
1056                         if(!(locked_goal && this.goalcurrent_distance_z < 50 && this.goalcurrent_distance_2d < 50))
1057                         if(havocbot_checkgoaldistance(this, destorg))
1058                         {
1059                                 if(this.goalcurrent_distance_time < 0) // can't get close for the second time
1060                                 {
1061                                         navigation_clearroute(this);
1062                                         navigation_goalrating_timeout_force(this);
1063                                         return;
1064                                 }
1065
1066                                 set_tracewalk_dest(this.goalcurrent, this.origin, false);
1067                                 if (!tracewalk(this, this.origin, this.mins, this.maxs,
1068                                         tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
1069                                 {
1070                                         navigation_clearroute(this);
1071                                         navigation_goalrating_timeout_force(this);
1072                                         return;
1073                                 }
1074
1075                                 // give bot only another chance to prevent bot getting stuck
1076                                 // in case it thinks it can walk but actually can't
1077                                 this.goalcurrent_distance_z = FLOAT_MAX;
1078                                 this.goalcurrent_distance_2d = FLOAT_MAX;
1079                                 this.goalcurrent_distance_time = -time; // mark second try
1080                         }
1081
1082                         if (skill + this.bot_moveskill <= 3 && time > this.bot_stop_moving_timeout
1083                                 && current_speed > maxspeed * 0.9 && fabs(deviation.y) > 70)
1084                         {
1085                                 this.bot_stop_moving_timeout = time + 0.4 + random() * 0.2;
1086                         }
1087
1088                         // Check for water/slime/lava and dangerous edges
1089                         // (only when the bot is on the ground or jumping intentionally)
1090
1091                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : flatdir * 32);
1092                         vector dst_ahead = this.origin + this.view_ofs + offset;
1093                         vector dst_down = dst_ahead - '0 0 3000';
1094                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
1095
1096                         bool unreachable = false;
1097                         s = CONTENT_SOLID;
1098                         if (trace_fraction == 1 && !this.jumppadcount
1099                                 && !waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
1100                                 && !(this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)))
1101                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
1102                         {
1103                                 // Look downwards
1104                                 traceline(dst_ahead , dst_down, true, NULL);
1105                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
1106                                 //te_lightning2(NULL, dst_ahead, trace_endpos); // Draw "downwards" look
1107                                 if(trace_endpos.z < this.origin.z + this.mins.z)
1108                                 {
1109                                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1110                                                 danger_detected = true;
1111                                         else if (trace_endpos.z < min(this.origin.z + this.mins.z, this.goalcurrent.origin.z) - 100)
1112                                                 danger_detected = true;
1113                                         else
1114                                         {
1115                                                 s = pointcontents(trace_endpos + '0 0 1');
1116                                                 if (s != CONTENT_SOLID)
1117                                                 {
1118                                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
1119                                                                 danger_detected = true;
1120                                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1121                                                         {
1122                                                                 // the traceline check isn't enough but is good as optimization,
1123                                                                 // when not true (most of the time) this tracebox call is avoided
1124                                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
1125                                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1126                                                                 {
1127                                                                         if (destorg.z > this.origin.z + jumpstepheightvec.z)
1128                                                                         {
1129                                                                                 // the goal is probably on an upper platform, assume bot can't get there
1130                                                                                 unreachable = true;
1131                                                                         }
1132                                                                         else
1133                                                                                 danger_detected = true;
1134                                                                 }
1135                                                         }
1136                                                 }
1137                                         }
1138                                 }
1139                         }
1140
1141                         dir = flatdir;
1142                         makevectors(this.v_angle.y * '0 1 0');
1143
1144                         if (danger_detected || (s == CONTENT_WATER))
1145                         {
1146                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
1147                                 if(IS_PLAYER(this.goalcurrent))
1148                                         unreachable = true;
1149                         }
1150
1151                         // slow down if bot is in the air and goal is under it
1152                         if (!waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
1153                                 && vdist(flat_diff, <, 250) && this.origin.z - destorg.z > 120
1154                                 && (!IS_ONGROUND(this) || vdist(vec2(this.velocity), >, maxspeed * 0.3)))
1155                         {
1156                                 // tracebox wouldn't work when bot is still on the ledge
1157                                 traceline(this.origin, this.origin - '0 0 200', true, this);
1158                                 if (this.origin.z - trace_endpos.z > 120)
1159                                         do_break = normalize(this.velocity) * -1;
1160                         }
1161
1162                         if(unreachable)
1163                         {
1164                                 navigation_clearroute(this);
1165                                 navigation_goalrating_timeout_force(this);
1166                                 this.ignoregoal = this.goalcurrent;
1167                                 this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
1168                         }
1169                 }
1170
1171                 dodge = havocbot_dodge(this);
1172                 if (dodge)
1173                         dodge *= bound(0, 0.5 + (skill + this.bot_dodgeskill) * 0.1, 1);
1174                 if (this.enemy)
1175                 {
1176                         traceline(this.origin, (this.enemy.absmin + this.enemy.absmax) * 0.5, true, NULL);
1177                         if (IS_PLAYER(trace_ent))
1178                                 dodge_enemy_factor = bound(0, (skill + this.bot_dodgeskill) / 7, 1);
1179                 }
1180         //      this.bot_dodgevector = dir;
1181         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
1182         }
1183
1184         float ladder_zdir = 0;
1185         if(this.ladder_entity)
1186         {
1187                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
1188                 {
1189                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
1190                                 ladder_zdir = 1;
1191                 }
1192                 else
1193                 {
1194                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
1195                                 ladder_zdir = -1;
1196                 }
1197                 if (ladder_zdir)
1198                 {
1199                         if (vdist(vec2(diff), <, 40))
1200                                 dir.z = ladder_zdir * 4;
1201                         else
1202                                 dir.z = ladder_zdir * 2;
1203                         dir = normalize(dir);
1204                 }
1205         }
1206
1207         if (this.goalcurrent.wpisbox
1208                 && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin, this.origin))
1209         {
1210                 // bot is inside teleport waypoint but hasn't touched the real teleport yet
1211                 // head to teleport origin
1212                 dir = (this.goalcurrent.origin - this.origin);
1213                 dir.z = 0;
1214                 dir = normalize(dir);
1215         }
1216
1217         // already executed when bot targets an enemy
1218         if (!this.bot_aimdir_executed)
1219         {
1220                 if (time < this.bot_stop_moving_timeout)
1221                         bot_aimdir(this, normalize(this.goalcurrent.origin - this.origin), 0);
1222                 else
1223                         bot_aimdir(this, dir, 0);
1224         }
1225
1226         vector evadedanger = '0 0 0';
1227         if (!ladder_zdir)
1228         {
1229                 dir *= dodge_enemy_factor;
1230                 if (danger_detected && vdist(this.velocity, >, maxspeed * 0.8) && this.goalcurrent_prev
1231                         && this.goalcurrent.classname == "waypoint")
1232                 {
1233                         vector p = this.origin + this.velocity * 0.2;
1234                         vector evadedanger = point_line_vec(p, vec2(this.goalcurrent_prev.origin) + eZ * p.z,
1235                                 vec2(destorg - this.goalcurrent_prev.origin));
1236                         if (vdist(evadedanger, >, 20))
1237                         {
1238                                 if (vdist(evadedanger, >, 40))
1239                                         do_break = normalize(this.velocity) * -1;
1240                                 evadedanger = normalize(evadedanger);
1241                                 evadedanger *= bound(1, 3 - (skill + this.bot_dodgeskill), 3); // Noobs fear dangers a lot and take more distance from them
1242                         }
1243                         else
1244                                 evadedanger = '0 0 0';
1245                 }
1246                 dir = normalize(dir + dodge + do_break + evadedanger);
1247         }
1248
1249         makevectors(this.v_angle);
1250         //dir = this.bot_dodgevector;
1251         //if (this.bot_dodgevector_jumpbutton)
1252         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
1253         CS(this).movement_x = dir * v_forward * maxspeed;
1254         CS(this).movement_y = dir * v_right * maxspeed;
1255         CS(this).movement_z = dir * v_up * maxspeed;
1256
1257         // Emulate keyboard interface
1258         if (skill < 10)
1259                 havocbot_keyboard_movement(this, destorg);
1260
1261         // Bunnyhop!
1262         if (!bunnyhop_forbidden && !evadedanger && !do_break && skill + this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
1263                 havocbot_bunnyhop(this, dir);
1264
1265         if (dir * v_up >= autocvar_sv_jumpvelocity * 0.5 && IS_ONGROUND(this))
1266                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1267         if (dodge)
1268         {
1269                 if (dodge * v_up > 0 && random() * frametime >= 0.2 * bound(0, (10 - skill - this.bot_dodgeskill) * 0.1, 1))
1270                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1271                 if (dodge * v_up < 0 && random() * frametime >= 0.5 * bound(0, (10 - skill - this.bot_dodgeskill) * 0.1, 1))
1272                         this.havocbot_ducktime = time + 0.3 / bound(0.1, skill + this.bot_dodgeskill, 10);
1273         }
1274 }
1275
1276 void havocbot_chooseenemy(entity this)
1277 {
1278         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
1279         {
1280                 this.enemy = NULL;
1281                 return;
1282         }
1283
1284         if (this.enemy)
1285         {
1286                 if (!bot_shouldattack(this, this.enemy))
1287                 {
1288                         // enemy died or something, find a new target
1289                         this.enemy = NULL;
1290                         this.havocbot_chooseenemy_finished = time;
1291                 }
1292                 else if (this.havocbot_stickenemy_time && time < this.havocbot_stickenemy_time)
1293                 {
1294                         // tracking last chosen enemy
1295                         vector targ_pos = (this.enemy.absmin + this.enemy.absmax) * 0.5;
1296                         traceline(this.origin + this.view_ofs, targ_pos, false, NULL);
1297                         if (trace_ent == this.enemy || trace_fraction == 1)
1298                         if (vdist(targ_pos - this.origin, <, 1000))
1299                         {
1300                                 // remain tracking them for a shot while (case they went after a small corner or pilar
1301                                 this.havocbot_chooseenemy_finished = time + 0.5;
1302                                 return;
1303                         }
1304
1305                         // stop preferring this enemy
1306                         this.havocbot_stickenemy_time = 0;
1307                 }
1308         }
1309         if (time < this.havocbot_chooseenemy_finished)
1310                 return;
1311         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
1312         vector eye = this.origin + this.view_ofs;
1313         entity best = NULL;
1314         float bestrating = autocvar_bot_ai_enemydetectionradius ** 2;
1315
1316         // Backup hit flags
1317         int hf = this.dphitcontentsmask;
1318
1319         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
1320
1321         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
1322
1323         bool scan_transparent = false;
1324         bool scan_secondary_targets = false;
1325         bool have_secondary_targets = false;
1326         while(true)
1327         {
1328                 scan_secondary_targets = false;
1329                 LABEL(scan_targets)
1330                 IL_EACH(g_bot_targets, it.bot_attack,
1331                 {
1332                         if(!scan_secondary_targets)
1333                         {
1334                                 if(it.classname == "misc_breakablemodel")
1335                                 {
1336                                         have_secondary_targets = true;
1337                                         continue;
1338                                 }
1339                         }
1340                         else if(it.classname != "misc_breakablemodel")
1341                                 continue;
1342
1343                         vector v = (it.absmin + it.absmax) * 0.5;
1344                         float rating = vlen2(v - eye);
1345                         if (rating < bestrating && bot_shouldattack(this, it))
1346                         {
1347                                 traceline(eye, v, true, this);
1348                                 if (trace_ent == it || trace_fraction >= 1)
1349                                 {
1350                                         best = it;
1351                                         bestrating = rating;
1352                                 }
1353                         }
1354                 });
1355
1356                 if(!best && have_secondary_targets && !scan_secondary_targets)
1357                 {
1358                         scan_secondary_targets = true;
1359                         // restart the loop
1360                         bestrating = autocvar_bot_ai_enemydetectionradius ** 2;
1361                         goto scan_targets;
1362                 }
1363
1364                 // I want to do a second scan if no enemy was found or I don't have weapons
1365                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1366                 if(best || STAT(WEAPONS, this)) // || this.weapon == WEP_RIFLE.m_id
1367                         break;
1368                 if(scan_transparent)
1369                         break;
1370
1371                 // Set flags to see through transparent objects
1372                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1373
1374                 scan_transparent = true;
1375         }
1376
1377         // Restore hit flags
1378         this.dphitcontentsmask = hf;
1379
1380         this.enemy = best;
1381         this.havocbot_stickenemy_time = time + autocvar_bot_ai_enemydetectioninterval_stickingtoenemy;
1382         if(best && best.classname == "misc_breakablemodel")
1383                 this.havocbot_stickenemy_time = 0;
1384 }
1385
1386 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1387 {
1388         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1389         // so skip this for them, or they'll never get to reload their weapons at all.
1390         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1391         if(skill < 5)
1392                 return false;
1393
1394         // if this weapon is scheduled for reloading, don't switch to it during combat
1395         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1396         {
1397                 FOREACH(Weapons, it != WEP_Null, {
1398                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1399                                 return true; // other weapon available
1400                 });
1401         }
1402
1403         return false;
1404 }
1405
1406 void havocbot_chooseweapon(entity this, .entity weaponentity)
1407 {
1408         int i;
1409
1410         // ;)
1411         if(g_weaponarena_weapons == WEPSET(TUBA))
1412         {
1413                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1414                 return;
1415         }
1416
1417         // TODO: clean this up by moving it to weapon code
1418         if(this.enemy==NULL)
1419         {
1420                 // If no weapon was chosen get the first available weapon
1421                 if(this.(weaponentity).m_weapon==WEP_Null)
1422                 FOREACH(Weapons, it != WEP_Null, {
1423                         if(client_hasweapon(this, it, weaponentity, true, false))
1424                         {
1425                                 this.(weaponentity).m_switchweapon = it;
1426                                 return;
1427                         }
1428                 });
1429                 return;
1430         }
1431
1432         // Do not change weapon during the next second after a combo
1433         float f = time - this.lastcombotime;
1434         if(f < 1)
1435                 return;
1436
1437         float w;
1438         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1439
1440         // Should it do a weapon combo?
1441         float af, ct, combo_time, combo;
1442
1443         af = ATTACK_FINISHED(this, weaponentity);
1444         ct = autocvar_bot_ai_weapon_combo_threshold;
1445
1446         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1447         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1448         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1449
1450         combo = false;
1451
1452         if(autocvar_bot_ai_weapon_combo)
1453         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1454         if(af > combo_time)
1455         {
1456                 combo = true;
1457                 this.lastcombotime = time;
1458         }
1459
1460         distance *= (2 ** this.bot_rangepreference);
1461
1462         // Custom weapon list based on distance to the enemy
1463         if(bot_custom_weapon){
1464
1465                 // Choose weapons for far distance
1466                 if ( distance > bot_distance_far ) {
1467                         for(i=0; i < REGISTRY_COUNT(Weapons) && bot_weapons_far[i] != -1 ; ++i){
1468                                 w = bot_weapons_far[i];
1469                                 if ( client_hasweapon(this, REGISTRY_GET(Weapons, w), weaponentity, true, false) )
1470                                 {
1471                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1472                                                 continue;
1473                                         this.(weaponentity).m_switchweapon = REGISTRY_GET(Weapons, w);
1474                                         return;
1475                                 }
1476                         }
1477                 }
1478
1479                 // Choose weapons for mid distance
1480                 if ( distance > bot_distance_close) {
1481                         for(i=0; i < REGISTRY_COUNT(Weapons) && bot_weapons_mid[i] != -1 ; ++i){
1482                                 w = bot_weapons_mid[i];
1483                                 if ( client_hasweapon(this, REGISTRY_GET(Weapons, w), weaponentity, true, false) )
1484                                 {
1485                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1486                                                 continue;
1487                                         this.(weaponentity).m_switchweapon = REGISTRY_GET(Weapons, w);
1488                                         return;
1489                                 }
1490                         }
1491                 }
1492
1493                 // Choose weapons for close distance
1494                 for(i=0; i < REGISTRY_COUNT(Weapons) && bot_weapons_close[i] != -1 ; ++i){
1495                         w = bot_weapons_close[i];
1496                         if ( client_hasweapon(this, REGISTRY_GET(Weapons, w), weaponentity, true, false) )
1497                         {
1498                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1499                                         continue;
1500                                 this.(weaponentity).m_switchweapon = REGISTRY_GET(Weapons, w);
1501                                 return;
1502                         }
1503                 }
1504         }
1505 }
1506
1507 void havocbot_aim(entity this)
1508 {
1509         // if aim rate is a multiple of think rate due to precision errors the sum of multiple think times
1510         // can be slightly greater than aim time and cause a jump of a whole think time (bot_netxtthink)
1511         // in that case this small tolerance time makes so that aim time snaps to think time
1512         if (time < this.nextaim - 0.01)
1513                 return;
1514         this.nextaim = time + 0.1;
1515
1516         vector myvel = this.velocity;
1517         if (!this.waterlevel)
1518                 myvel.z = 0;
1519         if(MUTATOR_CALLHOOK(HavocBot_Aim, this)) { /* do nothing */ }
1520         else if (this.enemy)
1521         {
1522                 vector enemyvel = this.enemy.velocity;
1523                 if (!this.enemy.waterlevel)
1524                         enemyvel.z = 0;
1525         }
1526 }
1527
1528 bool havocbot_moveto_refresh_route(entity this)
1529 {
1530         // Refresh path to goal if necessary
1531         entity wp;
1532         wp = this.havocbot_personal_waypoint;
1533         navigation_goalrating_start(this);
1534         navigation_routerating(this, wp, 10000, 10000);
1535         navigation_goalrating_end(this);
1536         return (this.goalentity != NULL);
1537 }
1538
1539 float havocbot_moveto(entity this, vector pos)
1540 {
1541         entity wp;
1542
1543         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1544         {
1545                 // Step 4: Move to waypoint
1546                 if(this.havocbot_personal_waypoint==NULL)
1547                 {
1548                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1549                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1550                         return CMD_STATUS_ERROR;
1551                 }
1552
1553                 if (!bot_strategytoken_taken)
1554                 if(this.havocbot_personal_waypoint_searchtime<time)
1555                 {
1556                         bot_strategytoken_taken = true;
1557                         if(havocbot_moveto_refresh_route(this))
1558                         {
1559                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1560                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1561                                 this.havocbot_personal_waypoint_failcounter = 0;
1562                         }
1563                         else
1564                         {
1565                                 this.havocbot_personal_waypoint_failcounter += 1;
1566                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1567                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1568                                 {
1569                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1570                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1571                                         delete(this.havocbot_personal_waypoint);
1572                                         return CMD_STATUS_ERROR;
1573                                 }
1574                                 else
1575                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1576                         }
1577                 }
1578
1579                 if(autocvar_bot_debug_goalstack)
1580                         debuggoalstack(this);
1581
1582
1583                 // Go!
1584                 havocbot_movetogoal(this);
1585
1586                 if (!this.bot_aimdir_executed && this.goalcurrent)
1587                 {
1588                         // Heading
1589                         vector dir = get_closer_dest(this.goalcurrent, this.origin);
1590                         dir -= this.origin + this.view_ofs;
1591                         dir.z = 0;
1592                         bot_aimdir(this, dir, 0);
1593                 }
1594
1595                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1596                 {
1597                         // Step 5: Waypoint reached
1598                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1599                         waypoint_remove(this.havocbot_personal_waypoint);
1600                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1601                         return CMD_STATUS_FINISHED;
1602                 }
1603
1604                 return CMD_STATUS_EXECUTING;
1605         }
1606
1607         // Step 2: Linking waypoint
1608         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1609         {
1610                 // Wait until it is linked
1611                 if(!this.havocbot_personal_waypoint.wplinked)
1612                 {
1613                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1614                         return CMD_STATUS_EXECUTING;
1615                 }
1616
1617                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1618                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1619                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1620
1621                 // Step 3: Route to waypoint
1622                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1623
1624                 return CMD_STATUS_EXECUTING;
1625         }
1626
1627         // Step 1: Spawning waypoint
1628         wp = waypoint_spawnpersonal(this, pos);
1629         if(wp==NULL)
1630         {
1631                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1632                 return CMD_STATUS_ERROR;
1633         }
1634
1635         this.havocbot_personal_waypoint = wp;
1636         this.havocbot_personal_waypoint_failcounter = 0;
1637         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1638
1639         // if pos is inside a teleport, then let's mark it as teleport waypoint
1640         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1641         {
1642                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1643                 this.lastteleporttime = 0;
1644         });
1645
1646 /*
1647         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1648                 print("routing to a teleporter\n");
1649         else
1650                 print("routing to a non-teleporter\n");
1651 */
1652
1653         return CMD_STATUS_EXECUTING;
1654 }
1655
1656 float havocbot_resetgoal(entity this)
1657 {
1658         navigation_clearroute(this);
1659         return CMD_STATUS_FINISHED;
1660 }
1661
1662 void havocbot_setupbot(entity this)
1663 {
1664         this.bot_ai = havocbot_ai;
1665         this.cmd_moveto = havocbot_moveto;
1666         this.cmd_resetgoal = havocbot_resetgoal;
1667
1668         // NOTE: bot is not player yet
1669         havocbot_chooserole(this);
1670 }
1671
1672 vector havocbot_dodge(entity this)
1673 {
1674         // LordHavoc: disabled because this is too expensive
1675         return '0 0 0';
1676 #if 0
1677         entity head;
1678         vector dodge, v, n;
1679         float danger, bestdanger, vl, d;
1680         dodge = '0 0 0';
1681         bestdanger = -20;
1682         // check for dangerous objects near bot or approaching bot
1683         head = findchainfloat(bot_dodge, true);
1684         while(head)
1685         {
1686                 if (head.owner != this)
1687                 {
1688                         vl = vlen(head.velocity);
1689                         if (vl > autocvar_sv_maxspeed * 0.3)
1690                         {
1691                                 n = normalize(head.velocity);
1692                                 v = this.origin - head.origin;
1693                                 d = v * n;
1694                                 if (d > (0 - head.bot_dodgerating))
1695                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1696                                 {
1697                                         // calculate direction and distance from the flight path, by removing the forward axis
1698                                         v = v - (n * (v * n));
1699                                         danger = head.bot_dodgerating - vlen(v);
1700                                         if (bestdanger < danger)
1701                                         {
1702                                                 bestdanger = danger;
1703                                                 // dodge to the side of the object
1704                                                 dodge = normalize(v);
1705                                         }
1706                                 }
1707                         }
1708                         else
1709                         {
1710                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1711                                 if (bestdanger < danger)
1712                                 {
1713                                         bestdanger = danger;
1714                                         dodge = normalize(this.origin - head.origin);
1715                                 }
1716                         }
1717                 }
1718                 head = head.chain;
1719         }
1720         return dodge;
1721 #endif
1722 }