qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include "roles.qh"
   4
   5 #include <server/defs.qh>
   6 #include <server/miscfunctions.qh>
   7 #include "../cvars.qh"
   8
   9 #include "../aim.qh"
  10 #include "../bot.qh"
  11 #include "../navigation.qh"
  12 #include "../scripting.qh"
  13 #include "../waypoints.qh"
  14
  15 #include <common/constants.qh>
  16 #include <common/impulses/all.qh>
  17 #include <common/net_linked.qh>
  18 #include <common/physics/player.qh>
  19 #include <common/state.qh>
  20 #include <common/items/_mod.qh>
  21 #include <common/wepent.qh>
  22
  23 #include <common/mapobjects/func/ladder.qh>
  24 #include <common/mapobjects/teleporters.qh>
  25 #include <common/mapobjects/trigger/jumppads.qh>
  26
  27 #include <lib/warpzone/common.qh>
  28
  29 void havocbot_ai(entity this)
  30 {
  31         if(this.draggedby)
  32                 return;
  33
  34         this.bot_aimdir_executed = false;
  35         // lock aim if teleported or passing through a warpzone
  36         if (this.lastteleporttime && !this.jumppadcount)
  37                 this.bot_aimdir_executed = true;
  38
  39         if(bot_execute_commands(this))
  40                 return;
  41
  42         if (bot_strategytoken == this && !bot_strategytoken_taken)
  43         {
  44                 if(this.havocbot_blockhead)
  45                 {
  46                         this.havocbot_blockhead = false;
  47                 }
  48                 else
  49                 {
  50                         if (!this.jumppadcount && !STAT(FROZEN, this)
  51                                 && !(this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)))
  52                         {
  53                                 // find a new goal
  54                                 this.havocbot_role(this); // little too far down the rabbit hole
  55                         }
  56                 }
  57
  58                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  59                 if(!(IS_DEAD(this) || STAT(FROZEN, this)))
  60                 if(!this.goalcurrent)
  61                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  62                 {
  63                         // Look for the closest waypoint out of water
  64                         entity newgoal = NULL;
  65                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  66                         {
  67                                 if(it.origin.z < this.origin.z)
  68                                         continue;
  69
  70                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  71                                         continue;
  72
  73                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  74                                         continue;
  75
  76                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  77
  78                                 if(trace_fraction < 1)
  79                                         continue;
  80
  81                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  82                                         newgoal = it;
  83                         });
  84
  85                         if(newgoal)
  86                         {
  87                         //      te_wizspike(newgoal.origin);
  88                                 navigation_pushroute(this, newgoal);
  89                         }
  90                 }
  91
  92                 // token has been used this frame
  93                 bot_strategytoken_taken = true;
  94         }
  95
  96         if (this.goalcurrent && wasfreed(this.goalcurrent))
  97         {
  98                 navigation_clearroute(this);
  99                 navigation_goalrating_timeout_force(this);
 100                 return;
 101         }
 102
 103         if(IS_DEAD(this) || STAT(FROZEN, this))
 104         {
 105                 if (this.goalcurrent)
 106                         navigation_clearroute(this);
 107                 return;
 108         }
 109
 110         havocbot_chooseenemy(this);
 111
 112         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 113         {
 114                 .entity weaponentity = weaponentities[slot];
 115                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
 116                 if(this.(weaponentity).bot_chooseweapontime < time)
 117                 {
 118                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
 119                         havocbot_chooseweapon(this, weaponentity);
 120                 }
 121         }
 122         havocbot_aim(this);
 123         lag_update(this);
 124
 125         if (this.bot_aimtarg)
 126         {
 127                 this.aistatus |= AI_STATUS_ATTACKING;
 128                 this.aistatus &= ~AI_STATUS_ROAMING;
 129
 130                 if(STAT(WEAPONS, this))
 131                 {
 132                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 133                         {
 134                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 135                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 136                         }
 137                         else
 138                         {
 139                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 140                                 {
 141                                         .entity weaponentity = weaponentities[slot];
 142                                         Weapon w = this.(weaponentity).m_weapon;
 143                                         if(w == WEP_Null && slot != 0)
 144                                                 continue;
 145                                         w.wr_aim(w, this, weaponentity);
 146                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
 147                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 148                                 }
 149                         }
 150                 }
 151                 else
 152                 {
 153                         if(IS_PLAYER(this.bot_aimtarg))
 154                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs, 0);
 155                 }
 156         }
 157         else if (this.goalcurrent)
 158         {
 159                 this.aistatus |= AI_STATUS_ROAMING;
 160                 this.aistatus &= ~AI_STATUS_ATTACKING;
 161         }
 162
 163         havocbot_movetogoal(this);
 164         if (!this.bot_aimdir_executed && this.goalcurrent)
 165         {
 166                 // Heading
 167                 vector dir = get_closer_dest(this.goalcurrent, this.origin);
 168                 dir -= this.origin + this.view_ofs;
 169                 dir.z = 0;
 170                 bot_aimdir(this, dir, 0);
 171         }
 172
 173         // if the bot is not attacking, consider reloading weapons
 174         if (!(this.aistatus & AI_STATUS_ATTACKING))
 175         {
 176                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 177                 {
 178                         .entity weaponentity = weaponentities[slot];
 179
 180                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 181                                 continue;
 182
 183                         // we are currently holding a weapon that's not fully loaded, reload it
 184                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 185                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
 186                                 CS(this).impulse = IMP_weapon_reload.impulse; // not sure if this is done right
 187
 188                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 189                         // the code above executes next frame, starting the reloading then
 190                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
 191                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
 192                         {
 193                                 FOREACH(Weapons, it != WEP_Null, {
 194                                         if((STAT(WEAPONS, this) & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
 195                                         {
 196                                                 this.(weaponentity).m_switchweapon = it;
 197                                                 break;
 198                                         }
 199                                 });
 200                         }
 201                 }
 202         }
 203 }
 204
 205 void havocbot_bunnyhop(entity this, vector dir)
 206 {
 207         bool can_run = false;
 208         if (!(this.aistatus & AI_STATUS_ATTACKING) && this.goalcurrent && !IS_PLAYER(this.goalcurrent)
 209                 && vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed) && !(this.aistatus & AI_STATUS_DANGER_AHEAD)
 210                 && this.waterlevel <= WATERLEVEL_WETFEET && !IS_DUCKED(this)
 211                 && IS_ONGROUND(this) && !(this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)))
 212         {
 213                 vector vel_angles = vectoangles(this.velocity);
 214                 vector deviation = vel_angles - vectoangles(dir);
 215                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 216                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 217                 if (fabs(deviation.y) < autocvar_bot_ai_bunnyhop_dir_deviation_max)
 218                 {
 219                         vector gco = get_closer_dest(this.goalcurrent, this.origin);
 220                         float vel = vlen(vec2(this.velocity));
 221
 222                         // with the current physics, jump distance grows linearly with the speed
 223                         float jump_distance = 52.661 + 0.606 * vel;
 224                         jump_distance += this.origin.z - gco.z; // roughly take into account vertical distance too
 225                         if (vdist(vec2(gco - this.origin), >, max(0, jump_distance)))
 226                                 can_run = true;
 227                         else if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_JUMP)
 228                                 && !(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 229                                 && this.goalstack01 && !wasfreed(this.goalstack01) && !(this.goalstack01.wpflags & WAYPOINTFLAG_JUMP)
 230                                 && vdist(vec2(gco - this.goalstack01.origin), >, 70))
 231                         {
 232                                 vector gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 233                                 vector ang = vectoangles(gco - this.origin);
 234                                 deviation = vectoangles(gno - gco) - vel_angles;
 235                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 236                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 237
 238                                 float max_turn_angle = autocvar_bot_ai_bunnyhop_turn_angle_max;
 239                                 max_turn_angle -= autocvar_bot_ai_bunnyhop_turn_angle_reduction * ((vel - autocvar_sv_maxspeed) / autocvar_sv_maxspeed);
 240                                 if ((ang.x < 90 || ang.x > 360 - autocvar_bot_ai_bunnyhop_downward_pitch_max)
 241                                         && fabs(deviation.y) < max(autocvar_bot_ai_bunnyhop_turn_angle_min, max_turn_angle))
 242                                 {
 243                                         can_run = true;
 244                                 }
 245                         }
 246                 }
 247         }
 248
 249         if (can_run)
 250         {
 251                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 252                 this.bot_jump_time = time;
 253                 this.aistatus |= AI_STATUS_RUNNING;
 254         }
 255         else
 256         {
 257                 if (IS_ONGROUND(this) || this.waterlevel > WATERLEVEL_WETFEET)
 258                         this.aistatus &= ~AI_STATUS_RUNNING;
 259         }
 260 }
 261
 262 void havocbot_keyboard_movement(entity this, vector destorg)
 263 {
 264         if(time <= this.havocbot_keyboardtime)
 265                 return;
 266
 267         float sk = skill + this.bot_moveskill;
 268         this.havocbot_keyboardtime =
 269                 max(
 270                         this.havocbot_keyboardtime
 271                                 + 0.05 / max(1, sk + this.havocbot_keyboardskill)
 272                                 + random() * 0.025 / max(0.00025, skill + this.havocbot_keyboardskill)
 273                 , time);
 274         vector keyboard = CS(this).movement / autocvar_sv_maxspeed;
 275
 276         float trigger = autocvar_bot_ai_keyboard_threshold;
 277
 278         // categorize forward movement
 279         // at skill < 1.5 only forward
 280         // at skill < 2.5 only individual directions
 281         // at skill < 4.5 only individual directions, and forward diagonals
 282         // at skill >= 4.5, all cases allowed
 283         if (keyboard.x > trigger)
 284         {
 285                 keyboard.x = 1;
 286                 if (sk < 2.5)
 287                         keyboard.y = 0;
 288         }
 289         else if (keyboard.x < -trigger && sk > 1.5)
 290         {
 291                 keyboard.x = -1;
 292                 if (sk < 4.5)
 293                         keyboard.y = 0;
 294         }
 295         else
 296         {
 297                 keyboard.x = 0;
 298                 if (sk < 1.5)
 299                         keyboard.y = 0;
 300         }
 301         if (sk < 4.5)
 302                 keyboard.z = 0;
 303
 304         if (keyboard.y > trigger)
 305                 keyboard.y = 1;
 306         else if (keyboard.y < -trigger)
 307                 keyboard.y = -1;
 308         else
 309                 keyboard.y = 0;
 310
 311         if (keyboard.z > trigger)
 312                 keyboard.z = 1;
 313         else if (keyboard.z < -trigger)
 314                 keyboard.z = -1;
 315         else
 316                 keyboard.z = 0;
 317
 318         // make sure bots don't get stuck if havocbot_keyboardtime is very high
 319         if (keyboard == '0 0 0')
 320                 this.havocbot_keyboardtime = min(this.havocbot_keyboardtime, time + 0.2);
 321
 322         this.havocbot_keyboard = keyboard * autocvar_sv_maxspeed;
 323         if (this.havocbot_ducktime > time)
 324                 PHYS_INPUT_BUTTON_CROUCH(this) = true;
 325
 326         keyboard = this.havocbot_keyboard;
 327         float blend = bound(0, vlen(destorg - this.origin) / autocvar_bot_ai_keyboard_distance, 1); // When getting close move with 360 degree
 328         //dprint("movement ", vtos(CS(this).movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 329         CS(this).movement = CS(this).movement + (keyboard - CS(this).movement) * blend;
 330 }
 331
 332 // return true when bot isn't getting closer to the current goal
 333 bool havocbot_checkgoaldistance(entity this, vector gco)
 334 {
 335         if (this.bot_stop_moving_timeout > time)
 336                 return false;
 337         float curr_dist_z = max(20, fabs(this.origin.z - gco.z));
 338         float curr_dist_2d = max(20, vlen(vec2(this.origin - gco)));
 339         float distance_time = this.goalcurrent_distance_time;
 340         if(distance_time < 0)
 341                 distance_time = -distance_time;
 342         if(curr_dist_z >= this.goalcurrent_distance_z && curr_dist_2d >= this.goalcurrent_distance_2d)
 343         {
 344                 if(!distance_time)
 345                         this.goalcurrent_distance_time = time;
 346                 else if (time - distance_time > 0.5)
 347                         return true;
 348         }
 349         else
 350         {
 351                 // reduce it a little bit so it works even with very small approaches to the goal
 352                 this.goalcurrent_distance_z = max(20, curr_dist_z - 10);
 353                 this.goalcurrent_distance_2d = max(20, curr_dist_2d - 10);
 354                 this.goalcurrent_distance_time = 0;
 355         }
 356         return false;
 357 }
 358
 359 entity havocbot_select_an_item_of_group(entity this, int gr)
 360 {
 361         entity selected = NULL;
 362         float selected_dist2 = 0;
 363         // select farthest item of this group from bot's position
 364         IL_EACH(g_items, it.item_group == gr && it.solid,
 365         {
 366                 float dist2 = vlen2(this.origin - it.origin);
 367                 if (dist2 < 600 ** 2 && dist2 > selected_dist2)
 368                 {
 369                         selected = it;
 370                         selected_dist2 = vlen2(this.origin - selected.origin);
 371                 }
 372         });
 373
 374         if (!selected)
 375                 return NULL;
 376
 377         set_tracewalk_dest(selected, this.origin, false);
 378         if (!tracewalk(this, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this),
 379                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
 380         {
 381                 return NULL;
 382         }
 383
 384         return selected;
 385 }
 386
 387 void havocbot_movetogoal(entity this)
 388 {
 389         vector diff;
 390         vector dir;
 391         vector flatdir;
 392         float dodge_enemy_factor = 1;
 393         float maxspeed;
 394         //float dist;
 395         vector dodge;
 396         //if (this.goalentity)
 397         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 398         CS(this).movement = '0 0 0';
 399         maxspeed = autocvar_sv_maxspeed;
 400
 401         PHYS_INPUT_BUTTON_CROUCH(this) = boolean(this.goalcurrent.wpflags & WAYPOINTFLAG_CROUCH);
 402
 403         PHYS_INPUT_BUTTON_JETPACK(this) = false;
 404         // Jetpack navigation
 405         if(this.navigation_jetpack_goal)
 406         if(this.goalcurrent==this.navigation_jetpack_goal)
 407         if(GetResource(this, RES_FUEL))
 408         {
 409                 if(autocvar_bot_debug_goalstack)
 410                 {
 411                         debuggoalstack(this);
 412                         te_wizspike(this.navigation_jetpack_point);
 413                 }
 414
 415                 // Take off
 416                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 417                 {
 418                         // Brake almost completely so it can get a good direction
 419                         if(vdist(this.velocity, >, 10))
 420                                 return;
 421                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 422                 }
 423
 424                 makevectors(this.v_angle.y * '0 1 0');
 425                 dir = normalize(this.navigation_jetpack_point - this.origin);
 426
 427                 // Landing
 428                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 429                 {
 430                         // Calculate brake distance in xy
 431                         float d = vlen(vec2(this.origin - (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5));
 432                         float vel2 = vlen2(vec2(this.velocity));
 433                         float db = (vel2 / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 434                         //LOG_INFOF("distance %d, velocity %d, brake at %d ", ceil(d), ceil(v), ceil(db));
 435                         if(d < db || d < 500)
 436                         {
 437                                 // Brake
 438                                 if (vel2 > (maxspeed * 0.3) ** 2)
 439                                 {
 440                                         CS(this).movement_x = dir * v_forward * -maxspeed;
 441                                         return;
 442                                 }
 443                                 // Switch to normal mode
 444                                 this.navigation_jetpack_goal = NULL;
 445                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 446                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 447                                 return;
 448                         }
 449                 }
 450                 else if(checkpvs(this.origin,this.goalcurrent))
 451                 {
 452                         // If I can see the goal switch to landing code
 453                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 454                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 455                         return;
 456                 }
 457
 458                 // Flying
 459                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 460                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
 461                 {
 462                         CS(this).movement_x = dir * v_forward * maxspeed;
 463                         CS(this).movement_y = dir * v_right * maxspeed;
 464                 }
 465                 return;
 466         }
 467
 468         // Handling of jump pads
 469         if(this.jumppadcount)
 470         {
 471                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 472                 {
 473                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 474                         if(navigation_poptouchedgoals(this))
 475                                 return;
 476                 }
 477                 else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 478                 {
 479                         // If got stuck on the jump pad try to reach the farthest visible waypoint
 480                         // but with some randomness so it can try out different paths
 481                         if(!this.goalcurrent)
 482                         {
 483                                 entity newgoal = NULL;
 484                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 485                                 {
 486                                         if(it.wpflags & WAYPOINTFLAG_TELEPORT)
 487                                         if(it.origin.z < this.origin.z - 100 && vdist(vec2(it.origin - this.origin), <, 100))
 488                                                 continue;
 489
 490                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 491
 492                                         if(trace_fraction < 1)
 493                                                 continue;
 494
 495                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
 496                                                 newgoal = it;
 497                                 });
 498
 499                                 if(newgoal)
 500                                 {
 501                                         this.ignoregoal = this.goalcurrent;
 502                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 503                                         navigation_clearroute(this);
 504                                         navigation_routetogoal(this, newgoal, this.origin);
 505                                         if(autocvar_bot_debug_goalstack)
 506                                                 debuggoalstack(this);
 507                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 508                                 }
 509                         }
 510                         else //if (this.goalcurrent)
 511                         {
 512                                 if (this.goalcurrent.bot_pickup)
 513                                 {
 514                                         entity jumppad_wp = this.goalcurrent_prev;
 515                                         navigation_poptouchedgoals(this);
 516                                         if(!this.goalcurrent && jumppad_wp.wp00)
 517                                         {
 518                                                 // head to the jumppad destination once bot reaches the goal item
 519                                                 navigation_pushroute(this, jumppad_wp.wp00);
 520                                         }
 521                                 }
 522                                 vector gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 523                                 if (this.origin.z > gco.z && vdist(vec2(this.velocity), <, autocvar_sv_maxspeed))
 524                                 {
 525                                         if (this.velocity.z < 0)
 526                                                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 527                                 }
 528                                 else if(havocbot_checkgoaldistance(this, gco))
 529                                 {
 530                                         navigation_clearroute(this);
 531                                         navigation_goalrating_timeout_force(this);
 532                                 }
 533                                 else
 534                                         return;
 535                         }
 536                 }
 537                 else //if (!(this.aistatus & AI_STATUS_OUT_JUMPPAD))
 538                 {
 539                         if(this.velocity.z > 0 && this.origin.z - this.lastteleport_origin.z > (this.maxs.z - this.mins.z) * 0.5)
 540                         {
 541                                 vector velxy = this.velocity; velxy_z = 0;
 542                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
 543                                 {
 544                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 545                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 546                                 }
 547                                 return;
 548                         }
 549
 550                         // Don't chase players while using a jump pad
 551                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 552                                 return;
 553                 }
 554         }
 555         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 556                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 557
 558         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 559         if (skill > 6 && !(IS_ONGROUND(this)))
 560         {
 561                 #define ROCKETJUMP_DAMAGE() WEP_CVAR(devastator, damage) * 0.8 \
 562                         * ((this.strength_finished > time) ? autocvar_g_balance_powerup_strength_selfdamage : 1) \
 563                         * ((this.invincible_finished > time) ? autocvar_g_balance_powerup_invincible_takedamage : 1)
 564
 565                 // save some CPU cycles by checking trigger_hurt after checking
 566                 // that something can be done to evade it (cheaper checks)
 567                 int action_for_trigger_hurt = 0;
 568                 if (this.items & IT_JETPACK)
 569                         action_for_trigger_hurt = 1;
 570                 else if (!this.jumppadcount && !waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
 571                         && !(this.goalcurrent_prev && this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)
 572                         && GetResource(this, RES_HEALTH) + GetResource(this, RES_ARMOR) > ROCKETJUMP_DAMAGE())
 573                 {
 574                         action_for_trigger_hurt = 2;
 575                 }
 576                 else if (!this.goalcurrent)
 577                         action_for_trigger_hurt = 3;
 578
 579                 if (action_for_trigger_hurt)
 580                 {
 581                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 582                         if(!tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos))
 583                                 action_for_trigger_hurt = 0;
 584                 }
 585
 586                 if(action_for_trigger_hurt == 1) // jetpack
 587                 {
 588                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 589                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 590                         {
 591                                 if(this.velocity.z<0)
 592                                         PHYS_INPUT_BUTTON_JETPACK(this) = true;
 593                         }
 594                         else
 595                                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 596
 597                         // If there is no goal try to move forward
 598
 599                         if(this.goalcurrent==NULL)
 600                                 dir = v_forward;
 601                         else
 602                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 603
 604                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 605                         float xyspeed = xyvelocity * dir;
 606
 607                         if(xyspeed < (maxspeed / 2))
 608                         {
 609                                 makevectors(this.v_angle.y * '0 1 0');
 610                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 611                                 if(trace_fraction==1)
 612                                 {
 613                                         CS(this).movement_x = dir * v_forward * maxspeed;
 614                                         CS(this).movement_y = dir * v_right * maxspeed;
 615                                         if (skill < 10)
 616                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 617                                 }
 618                         }
 619
 620                         this.havocbot_blockhead = true;
 621
 622                         return;
 623                 }
 624                 else if(action_for_trigger_hurt == 2) // rocketjump
 625                 {
 626                         if(this.velocity.z < 0)
 627                         {
 628                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 629                                 {
 630                                         .entity weaponentity = weaponentities[slot];
 631
 632                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 633                                                 continue;
 634
 635                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
 636                                         {
 637                                                 CS(this).movement_x = maxspeed;
 638
 639                                                 if(this.rocketjumptime)
 640                                                 {
 641                                                         if(time > this.rocketjumptime)
 642                                                         {
 643                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 644                                                                 this.rocketjumptime = 0;
 645                                                         }
 646                                                         return;
 647                                                 }
 648
 649                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 650                                                 this.v_angle_x = 90;
 651                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 652                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 653                                                 return;
 654                                         }
 655                                 }
 656                         }
 657                 }
 658                 else if(action_for_trigger_hurt == 3) // no goal
 659                 {
 660                         // If there is no goal try to move forward
 661                         CS(this).movement_x = maxspeed;
 662                 }
 663         }
 664
 665         // If we are under water with no goals, swim up
 666         if(this.waterlevel && !this.goalcurrent)
 667         {
 668                 dir = '0 0 0';
 669                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 670                         dir.z = 1;
 671                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 672                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 673                 makevectors(this.v_angle.y * '0 1 0');
 674                 vector v = dir * maxspeed;
 675                 CS(this).movement.x = v * v_forward;
 676                 CS(this).movement.y = v * v_right;
 677                 CS(this).movement.z = v * v_up;
 678         }
 679
 680         // if there is nowhere to go, exit
 681         if (this.goalcurrent == NULL)
 682                 return;
 683
 684
 685         bool locked_goal = false;
 686         if((this.goalentity && wasfreed(this.goalentity))
 687                 || (this.goalcurrent == this.goalentity && this.goalentity.tag_entity))
 688         {
 689                 navigation_clearroute(this);
 690                 navigation_goalrating_timeout_force(this);
 691                 return;
 692         }
 693         else if(this.goalentity.tag_entity)
 694         {
 695                 navigation_goalrating_timeout_expire(this, 2);
 696         }
 697         else if(this.goalentity.bot_pickup)
 698         {
 699                 if(this.goalentity.bot_pickup_respawning)
 700                 {
 701                         if(this.goalentity.solid) // item respawned
 702                                 this.goalentity.bot_pickup_respawning = false;
 703                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
 704                         {
 705                                 if(checkpvs(this.origin, this.goalentity))
 706                                 {
 707                                         this.goalentity.bot_pickup_respawning = false;
 708                                         navigation_goalrating_timeout_expire(this, random());
 709                                 }
 710                                 locked_goal = true; // wait for item to respawn
 711                         }
 712                         else if(this.goalentity == this.goalcurrent)
 713                                 locked_goal = true; // wait for item to respawn
 714                 }
 715                 else if(!this.goalentity.solid && !boxesoverlap(this.goalentity.absmin, this.goalentity.absmax, this.absmin, this.absmax))
 716                 {
 717                         if(checkpvs(this.origin, this.goalentity))
 718                         {
 719                                 navigation_goalrating_timeout_expire(this, random());
 720                         }
 721                 }
 722         }
 723         if (this.goalcurrent == this.goalentity && this.goalentity_lock_timeout > time)
 724                 locked_goal = true;
 725
 726         if (navigation_shortenpath(this))
 727         {
 728                 if (vdist(this.origin - this.goalcurrent_prev.origin, <, 50)
 729                         && navigation_goalrating_timeout_can_be_anticipated(this))
 730                 {
 731                         navigation_goalrating_timeout_force(this);
 732                 }
 733         }
 734
 735         bool goalcurrent_can_be_removed = false;
 736         if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 737         {
 738                 bool freeze_state_changed = (boolean(STAT(FROZEN, this.goalentity)) != this.goalentity_shouldbefrozen);
 739                 if (IS_DEAD(this.goalcurrent) || (this.goalentity == this.goalcurrent && freeze_state_changed))
 740                 {
 741                         goalcurrent_can_be_removed = true;
 742                         // don't remove if not visible
 743                         if (checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 744                         {
 745                                 if (IS_DEAD(this.goalcurrent))
 746                                 {
 747                                         IL_EACH(g_items, it.enemy == this.goalcurrent && Item_IsLoot(it),
 748                                         {
 749                                                 if (vdist(it.origin - this.goalcurrent.death_origin, <, 50))
 750                                                 {
 751                                                         navigation_clearroute(this);
 752                                                         navigation_pushroute(this, it);
 753                                                         // loot can't be immediately rated since it isn't on ground yet
 754                                                         // it will be rated after a second when on ground, meanwhile head to it
 755                                                         navigation_goalrating_timeout_expire(this, 1);
 756                                                         return;
 757                                                 }
 758                                         });
 759                                 }
 760                                 if (!Item_IsLoot(this.goalcurrent))
 761                                 {
 762                                         navigation_goalrating_timeout_force(this);
 763                                         return;
 764                                 }
 765                         }
 766                 }
 767                 else if (!(STAT(FROZEN, this.goalentity)) && this.bot_tracewalk_time < time)
 768                 {
 769                         set_tracewalk_dest(this.goalcurrent, this.origin, true);
 770                         if (!(trace_ent == this || tracewalk(this, this.origin, this.mins, this.maxs,
 771                                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode)))
 772                         {
 773                                 navigation_goalrating_timeout_force(this);
 774                                 return;
 775                         }
 776                         this.bot_tracewalk_time = max(time, this.bot_tracewalk_time) + 0.25;
 777                 }
 778         }
 779
 780         if(!locked_goal)
 781         {
 782                 // optimize path finding by anticipating goalrating when bot is near a waypoint;
 783                 // in this case path finding can start directly from a waypoint instead of
 784                 // looking for all the reachable waypoints up to a certain distance
 785                 if (navigation_poptouchedgoals(this))
 786                 {
 787                         if (this.goalcurrent)
 788                         {
 789                                 if (goalcurrent_can_be_removed)
 790                                 {
 791                                         // remove even if not visible
 792                                         navigation_goalrating_timeout_force(this);
 793                                         return;
 794                                 }
 795                                 else if (navigation_goalrating_timeout_can_be_anticipated(this))
 796                                         navigation_goalrating_timeout_force(this);
 797                         }
 798                         else
 799                         {
 800                                 entity old_goal = this.goalcurrent_prev;
 801                                 if (old_goal.item_group && this.item_group != old_goal.item_group)
 802                                 {
 803                                         // Avoid multiple costly calls of path finding code that selects one of the closest
 804                                         // item of the group by telling the bot to head directly to the farthest item.
 805                                         // Next time we let the bot select a goal as usual which can be another item
 806                                         // of this group (the closest one) and so on
 807                                         this.item_group = old_goal.item_group;
 808                                         entity new_goal = havocbot_select_an_item_of_group(this, old_goal.item_group);
 809                                         if (new_goal)
 810                                                 navigation_pushroute(this, new_goal);
 811                                 }
 812                         }
 813                 }
 814         }
 815
 816         // if ran out of goals try to use an alternative goal or get a new strategy asap
 817         if(this.goalcurrent == NULL)
 818         {
 819                 navigation_goalrating_timeout_force(this);
 820                 return;
 821         }
 822
 823
 824         if(autocvar_bot_debug_goalstack)
 825                 debuggoalstack(this);
 826
 827         bool bunnyhop_forbidden = false;
 828         vector destorg = get_closer_dest(this.goalcurrent, this.origin);
 829         if (this.jumppadcount && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 830         {
 831                 // if bot used the jumppad, push towards jumppad origin until jumppad waypoint gets removed
 832                 destorg = this.goalcurrent.origin;
 833         }
 834         else if (this.goalcurrent.wpisbox)
 835         {
 836                 // if bot is inside the teleport waypoint, head to teleport origin until teleport gets used
 837                 // do it even if bot is on a ledge above a teleport/jumppad so it doesn't get stuck
 838                 if (boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin + eZ * this.mins.z, this.origin + eZ * this.maxs.z)
 839                         || (this.absmin.z > destorg.z && destorg.x == this.origin.x && destorg.y == this.origin.y))
 840                 {
 841                         bunnyhop_forbidden = true;
 842                         destorg = this.goalcurrent.origin;
 843                         if(destorg.z > this.origin.z)
 844                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 845                 }
 846         }
 847
 848         diff = destorg - this.origin;
 849
 850         if (time < this.bot_stop_moving_timeout
 851                 || (this.goalcurrent == this.goalentity && time < this.goalentity_lock_timeout && vdist(diff, <, 10)))
 852         {
 853                 // stop if the locked goal has been reached
 854                 destorg = this.origin;
 855                 diff = dir = '0 0 0';
 856         }
 857         else if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 858         {
 859                 if (vdist(diff, <, 80))
 860                 {
 861                         // stop if too close to target player (even if frozen)
 862                         destorg = this.origin;
 863                         diff = dir = '0 0 0';
 864                 }
 865                 else
 866                 {
 867                         // move destorg out of target players, otherwise bot will consider them
 868                         // an obstacle that needs to be jumped (especially if frozen)
 869                         dir = normalize(diff);
 870                         destorg -= dir * PL_MAX_CONST.x * M_SQRT2;
 871                         diff = destorg - this.origin;
 872                 }
 873         }
 874         else
 875                 dir = normalize(diff);
 876         flatdir = (diff.z == 0) ? dir : normalize(vec2(diff));
 877
 878         vector evadedanger = '0 0 0';
 879
 880         //if (this.bot_dodgevector_time < time)
 881         {
 882                 //this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 883                 //this.bot_dodgevector_jumpbutton = 1;
 884
 885                 this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 886                 makevectors(this.v_angle.y * '0 1 0');
 887                 if (this.waterlevel > WATERLEVEL_WETFEET)
 888                 {
 889                         if (this.waterlevel > WATERLEVEL_SWIMMING)
 890                         {
 891                                 if(!this.goalcurrent)
 892                                         this.aistatus |= AI_STATUS_OUT_WATER;
 893                                 else if(destorg.z > this.origin.z)
 894                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 895                         }
 896                         else
 897                         {
 898                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && destorg.z < this.origin.z) &&
 899                                         (this.aistatus & AI_STATUS_OUT_WATER))
 900                                 {
 901                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 902                                         dir = flatdir;
 903                                 }
 904                                 else
 905                                 {
 906                                         if (destorg.z > this.origin.z)
 907                                                 dir = flatdir;
 908                                 }
 909                         }
 910                 }
 911                 else
 912                 {
 913                         float s;
 914                         vector offset;
 915                         if(this.aistatus & AI_STATUS_OUT_WATER)
 916                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 917
 918                         // jump if going toward an obstacle that doesn't look like stairs we
 919                         // can walk up directly
 920                         vector deviation = '0 0 0';
 921                         float current_speed = vlen(vec2(this.velocity));
 922                         if (current_speed < maxspeed * 0.2)
 923                                 current_speed = maxspeed * 0.2;
 924                         else
 925                         {
 926                                 deviation = vectoangles(diff) - vectoangles(this.velocity);
 927                                 while (deviation.y < -180) deviation.y += 360;
 928                                 while (deviation.y > 180) deviation.y -= 360;
 929                         }
 930                         float turning = false;
 931                         vector flat_diff = vec2(diff);
 932                         offset = max(32, current_speed * cos(deviation.y * DEG2RAD) * 0.3) * flatdir;
 933                         vector actual_destorg = this.origin + offset;
 934                         if (this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP))
 935                         {
 936                                 if (time > this.bot_stop_moving_timeout
 937                                         && fabs(deviation.y) > 20 && current_speed > maxspeed * 0.4
 938                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), <, 50))
 939                                 {
 940                                         this.bot_stop_moving_timeout = time + 0.1;
 941                                 }
 942                                 if (current_speed > autocvar_sv_maxspeed * 0.9
 943                                         && vlen2(flat_diff) < vlen2(vec2(this.goalcurrent_prev.origin - destorg))
 944                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), >, 50)
 945                                         && vdist(vec2(this.origin - this.goalcurrent_prev.origin), <, 150)
 946                                 )
 947                                 {
 948                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 949                                         this.bot_jump_time = time;
 950                                 }
 951                         }
 952                         else if (!this.goalstack01 || (this.goalcurrent.wpflags & (WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_LADDER)))
 953                         {
 954                                 if (vlen2(flat_diff) < vlen2(offset))
 955                                 {
 956                                         if (this.goalcurrent.wpflags & WAYPOINTFLAG_JUMP && this.goalstack01)
 957                                         {
 958                                                 // oblique warpzones need a jump otherwise bots gets stuck
 959                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 960                                         }
 961                                         else
 962                                         {
 963                                                 actual_destorg.x = destorg.x;
 964                                                 actual_destorg.y = destorg.y;
 965                                         }
 966                                 }
 967                         }
 968                         else if (vdist(flat_diff, <, 32) && diff.z < -16) // destination is under the bot
 969                         {
 970                                 actual_destorg.x = destorg.x;
 971                                 actual_destorg.y = destorg.y;
 972                         }
 973                         else if (vlen2(flat_diff) < vlen2(offset))
 974                         {
 975                                 vector next_goal_org = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 976                                 vector next_dir = normalize(vec2(next_goal_org - destorg));
 977                                 float dist = vlen(vec2(this.origin + offset - destorg));
 978                                 // if current and next goal are close to each other make sure
 979                                 // actual_destorg isn't set beyond next_goal_org
 980                                 if (dist ** 2 > vlen2(vec2(next_goal_org - destorg)))
 981                                         actual_destorg = next_goal_org;
 982                                 else
 983                                         actual_destorg = vec2(destorg) + dist * next_dir;
 984                                 actual_destorg.z = this.origin.z;
 985                                 turning = true;
 986                         }
 987
 988                         LABEL(jumpobstacle_check);
 989                         dir = flatdir = normalize(actual_destorg - this.origin);
 990
 991                         bool jump_forbidden = false;
 992                         if (!turning && fabs(deviation.y) > 50)
 993                                 jump_forbidden = true;
 994                         else if (IS_DUCKED(this))
 995                         {
 996                                 tracebox(this.origin, PL_MIN_CONST, PL_MAX_CONST, this.origin, false, this);
 997                                 if (trace_startsolid)
 998                                         jump_forbidden = true;
 999                         }
1000
1001                         if (!jump_forbidden)
1002                         {
1003                                 tracebox(this.origin, this.mins, this.maxs, actual_destorg, false, this);
1004                                 if (trace_fraction < 1 && trace_plane_normal.z < 0.7)
1005                                 {
1006                                         s = trace_fraction;
1007                                         tracebox(this.origin + stepheightvec, this.mins, this.maxs, actual_destorg + stepheightvec, false, this);
1008                                         if (trace_fraction < s + 0.01 && trace_plane_normal.z < 0.7)
1009                                         {
1010                                                 // found an obstacle
1011                                                 if (turning && fabs(deviation.y) > 5)
1012                                                 {
1013                                                         // check if the obstacle is still there without turning
1014                                                         actual_destorg = destorg;
1015                                                         turning = false;
1016                                                         this.bot_tracewalk_time = time + 0.25;
1017                                                         goto jumpobstacle_check;
1018                                                 }
1019                                                 s = trace_fraction;
1020                                                 // don't artificially reduce max jump height in real-time
1021                                                 // (jumpstepheightvec is reduced a bit to make the jumps easy in tracewalk)
1022                                                 vector jump_height = (IS_ONGROUND(this)) ? stepheightvec + jumpheight_vec : jumpstepheightvec;
1023                                                 tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1024                                                 if (trace_fraction > s)
1025                                                 {
1026                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1027                                                         this.bot_jump_time = time;
1028                                                 }
1029                                                 else
1030                                                 {
1031                                                         jump_height = stepheightvec + jumpheight_vec / 2;
1032                                                         tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1033                                                         if (trace_fraction > s)
1034                                                         {
1035                                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1036                                                                 this.bot_jump_time = time;
1037                                                         }
1038                                                 }
1039                                         }
1040                                 }
1041                         }
1042
1043                         // if bot for some reason doesn't get close to the current goal find another one
1044                         if(!this.jumppadcount && !IS_PLAYER(this.goalcurrent))
1045                         if(!(locked_goal && this.goalcurrent_distance_z < 50 && this.goalcurrent_distance_2d < 50))
1046                         if(havocbot_checkgoaldistance(this, destorg))
1047                         {
1048                                 if(this.goalcurrent_distance_time < 0) // can't get close for the second time
1049                                 {
1050                                         navigation_clearroute(this);
1051                                         navigation_goalrating_timeout_force(this);
1052                                         return;
1053                                 }
1054
1055                                 set_tracewalk_dest(this.goalcurrent, this.origin, false);
1056                                 if (!tracewalk(this, this.origin, this.mins, this.maxs,
1057                                         tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
1058                                 {
1059                                         navigation_clearroute(this);
1060                                         navigation_goalrating_timeout_force(this);
1061                                         return;
1062                                 }
1063
1064                                 // give bot only another chance to prevent bot getting stuck
1065                                 // in case it thinks it can walk but actually can't
1066                                 this.goalcurrent_distance_z = FLOAT_MAX;
1067                                 this.goalcurrent_distance_2d = FLOAT_MAX;
1068                                 this.goalcurrent_distance_time = -time; // mark second try
1069                         }
1070
1071                         if (skill + this.bot_moveskill <= 3 && time > this.bot_stop_moving_timeout
1072                                 && current_speed > maxspeed * 0.9 && fabs(deviation.y) > 70)
1073                         {
1074                                 this.bot_stop_moving_timeout = time + 0.4 + random() * 0.2;
1075                         }
1076
1077                         // Check for water/slime/lava and dangerous edges
1078                         // (only when the bot is on the ground or jumping intentionally)
1079
1080                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : flatdir * 32);
1081                         vector dst_ahead = this.origin + this.view_ofs + offset;
1082                         vector dst_down = dst_ahead - '0 0 3000';
1083                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
1084
1085                         bool unreachable = false;
1086                         s = CONTENT_SOLID;
1087                         bool danger_detected = false;
1088                         if (trace_fraction == 1 && !this.jumppadcount
1089                                 && !waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
1090                                 && !(this.goalcurrent_prev && (this.goalcurrent_prev.wpflags & WAYPOINTFLAG_JUMP)))
1091                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
1092                         {
1093                                 // Look downwards
1094                                 traceline(dst_ahead , dst_down, true, NULL);
1095                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
1096                                 //te_lightning2(NULL, dst_ahead, trace_endpos); // Draw "downwards" look
1097                                 if(trace_endpos.z < this.origin.z + this.mins.z)
1098                                 {
1099                                         if (trace_dphitq3surfaceflags & Q3SURFACEFLAG_SKY)
1100                                                 danger_detected = true;
1101                                         else
1102                                         {
1103                                                 s = pointcontents(trace_endpos + '0 0 1');
1104                                                 if (s != CONTENT_SOLID)
1105                                                 {
1106                                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
1107                                                                 danger_detected = true;
1108                                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1109                                                         {
1110                                                                 // the traceline check isn't enough but is good as optimization,
1111                                                                 // when not true (most of the time) this tracebox call is avoided
1112                                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
1113                                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1114                                                                 {
1115                                                                         if (destorg.z > this.origin.z + jumpstepheightvec.z)
1116                                                                         {
1117                                                                                 // the goal is probably on an upper platform, assume bot can't get there
1118                                                                                 unreachable = true;
1119                                                                         }
1120                                                                         else
1121                                                                                 danger_detected = true;
1122                                                                 }
1123                                                         }
1124                                                 }
1125                                         }
1126                                 }
1127                         }
1128                         if (danger_detected && fabs(deviation.y) < 80
1129                                 && (fabs(deviation.y) > 5 || vdist(vec2(this.velocity), >, maxspeed * 1.5)))
1130                         {
1131                                 evadedanger = normalize(this.velocity) * -1;
1132                                 evadedanger.z = 0;
1133                         }
1134
1135                         dir = flatdir;
1136                         makevectors(this.v_angle.y * '0 1 0');
1137
1138                         if (danger_detected || (s == CONTENT_WATER))
1139                         {
1140                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
1141                                 if(IS_PLAYER(this.goalcurrent))
1142                                         unreachable = true;
1143                         }
1144
1145                         // slow down if bot is in the air and goal is under it
1146                         if (!waypoint_is_hardwiredlink(this.goalcurrent_prev, this.goalcurrent)
1147                                 && vdist(flat_diff, <, 250) && this.origin.z - destorg.z > 120
1148                                 && (!IS_ONGROUND(this) || vdist(vec2(this.velocity), >, maxspeed * 0.3)))
1149                         {
1150                                 // tracebox wouldn't work when bot is still on the ledge
1151                                 traceline(this.origin, this.origin - '0 0 200', true, this);
1152                                 if (this.origin.z - trace_endpos.z > 120)
1153                                         evadedanger = normalize(this.velocity) * -1;
1154                         }
1155
1156                         if(unreachable)
1157                         {
1158                                 navigation_clearroute(this);
1159                                 navigation_goalrating_timeout_force(this);
1160                                 this.ignoregoal = this.goalcurrent;
1161                                 this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
1162                         }
1163                 }
1164
1165                 dodge = havocbot_dodge(this);
1166                 if (dodge)
1167                         dodge *= bound(0, 0.5 + (skill + this.bot_dodgeskill) * 0.1, 1);
1168                 evadedanger *= bound(1, 3 - (skill + this.bot_dodgeskill), 3); // Noobs fear dangers a lot and take more distance from them
1169                 if (this.enemy)
1170                 {
1171                         traceline(this.origin, (this.enemy.absmin + this.enemy.absmax) * 0.5, true, NULL);
1172                         if (IS_PLAYER(trace_ent))
1173                                 dodge_enemy_factor = bound(0, (skill + this.bot_dodgeskill) / 7, 1);
1174                 }
1175         //      this.bot_dodgevector = dir;
1176         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
1177         }
1178
1179         float ladder_zdir = 0;
1180         if(time < this.ladder_time)
1181         {
1182                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
1183                 {
1184                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
1185                                 ladder_zdir = 1;
1186                 }
1187                 else
1188                 {
1189                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
1190                                 ladder_zdir = -1;
1191                 }
1192                 if (ladder_zdir)
1193                 {
1194                         if (vdist(vec2(diff), <, 40))
1195                                 dir.z = ladder_zdir * 4;
1196                         else
1197                                 dir.z = ladder_zdir * 2;
1198                         dir = normalize(dir);
1199                 }
1200         }
1201
1202         if (this.goalcurrent.wpisbox
1203                 && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin, this.origin))
1204         {
1205                 // bot is inside teleport waypoint but hasn't touched the real teleport yet
1206                 // head to teleport origin
1207                 dir = (this.goalcurrent.origin - this.origin);
1208                 dir.z = 0;
1209                 dir = normalize(dir);
1210         }
1211
1212         // already executed when bot targets an enemy
1213         if (!this.bot_aimdir_executed)
1214         {
1215                 if (time < this.bot_stop_moving_timeout)
1216                         bot_aimdir(this, normalize(this.goalcurrent.origin - this.origin), 0);
1217                 else
1218                         bot_aimdir(this, dir, 0);
1219         }
1220
1221         if (!ladder_zdir)
1222         {
1223                 dir *= dodge_enemy_factor;
1224                 dir = normalize(dir + dodge + evadedanger);
1225         }
1226
1227         makevectors(this.v_angle);
1228         //dir = this.bot_dodgevector;
1229         //if (this.bot_dodgevector_jumpbutton)
1230         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
1231         CS(this).movement_x = dir * v_forward * maxspeed;
1232         CS(this).movement_y = dir * v_right * maxspeed;
1233         CS(this).movement_z = dir * v_up * maxspeed;
1234
1235         // Emulate keyboard interface
1236         if (skill < 10)
1237                 havocbot_keyboard_movement(this, destorg);
1238
1239         // Bunnyhop!
1240         if (!bunnyhop_forbidden && skill + this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
1241                 havocbot_bunnyhop(this, dir);
1242
1243         if (dir * v_up >= autocvar_sv_jumpvelocity * 0.5 && IS_ONGROUND(this))
1244                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1245         if (dodge)
1246         {
1247                 if (dodge * v_up > 0 && random() * frametime >= 0.2 * bound(0, (10 - skill - this.bot_dodgeskill) * 0.1, 1))
1248                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1249                 if (dodge * v_up < 0 && random() * frametime >= 0.5 * bound(0, (10 - skill - this.bot_dodgeskill) * 0.1, 1))
1250                         this.havocbot_ducktime = time + 0.3 / bound(0.1, skill + this.bot_dodgeskill, 10);
1251         }
1252 }
1253
1254 entity havocbot_gettarget(entity this, bool secondary)
1255 {
1256         entity best = NULL;
1257         vector eye = CENTER_OR_VIEWOFS(this);
1258         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
1259         {
1260                 vector v = CENTER_OR_VIEWOFS(it);
1261                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1262                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
1263                 if(bot_shouldattack(this, it))
1264                 {
1265                         traceline(eye, v, true, this);
1266                         if (trace_ent == it || trace_fraction >= 1)
1267                                 best = it;
1268                 }
1269         });
1270
1271         return best;
1272 }
1273
1274 void havocbot_chooseenemy(entity this)
1275 {
1276         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
1277         {
1278                 this.enemy = NULL;
1279                 return;
1280         }
1281
1282         if (this.enemy)
1283         {
1284                 if (!bot_shouldattack(this, this.enemy))
1285                 {
1286                         // enemy died or something, find a new target
1287                         this.enemy = NULL;
1288                         this.havocbot_chooseenemy_finished = time;
1289                 }
1290                 else if (this.havocbot_stickenemy_time && time < this.havocbot_stickenemy_time)
1291                 {
1292                         // tracking last chosen enemy
1293                         vector targ_pos = (this.enemy.absmin + this.enemy.absmax) * 0.5;
1294                         traceline(this.origin + this.view_ofs, targ_pos, false, NULL);
1295                         if (trace_ent == this.enemy || trace_fraction == 1)
1296                         if (vdist(targ_pos - this.origin, <, 1000))
1297                         {
1298                                 // remain tracking him for a shot while (case he went after a small corner or pilar
1299                                 this.havocbot_chooseenemy_finished = time + 0.5;
1300                                 return;
1301                         }
1302
1303                         // stop preferring this enemy
1304                         this.havocbot_stickenemy_time = 0;
1305                 }
1306         }
1307         if (time < this.havocbot_chooseenemy_finished)
1308                 return;
1309         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
1310         vector eye = this.origin + this.view_ofs;
1311         entity best = NULL;
1312         float bestrating = autocvar_bot_ai_enemydetectionradius ** 2;
1313
1314         // Backup hit flags
1315         int hf = this.dphitcontentsmask;
1316
1317         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
1318
1319         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
1320
1321         bool scan_transparent = false;
1322         bool scan_secondary_targets = false;
1323         bool have_secondary_targets = false;
1324         while(true)
1325         {
1326                 scan_secondary_targets = false;
1327 LABEL(scan_targets)
1328                 IL_EACH(g_bot_targets, it.bot_attack,
1329                 {
1330                         if(!scan_secondary_targets)
1331                         {
1332                                 if(it.classname == "misc_breakablemodel")
1333                                 {
1334                                         have_secondary_targets = true;
1335                                         continue;
1336                                 }
1337                         }
1338                         else if(it.classname != "misc_breakablemodel")
1339                                 continue;
1340
1341                         vector v = (it.absmin + it.absmax) * 0.5;
1342                         float rating = vlen2(v - eye);
1343                         if (rating < bestrating && bot_shouldattack(this, it))
1344                         {
1345                                 traceline(eye, v, true, this);
1346                                 if (trace_ent == it || trace_fraction >= 1)
1347                                 {
1348                                         best = it;
1349                                         bestrating = rating;
1350                                 }
1351                         }
1352                 });
1353
1354                 if(!best && have_secondary_targets && !scan_secondary_targets)
1355                 {
1356                         scan_secondary_targets = true;
1357                         // restart the loop
1358                         bestrating = autocvar_bot_ai_enemydetectionradius ** 2;
1359                         goto scan_targets;
1360                 }
1361
1362                 // I want to do a second scan if no enemy was found or I don't have weapons
1363                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1364                 if(best || STAT(WEAPONS, this)) // || this.weapon == WEP_RIFLE.m_id
1365                         break;
1366                 if(scan_transparent)
1367                         break;
1368
1369                 // Set flags to see through transparent objects
1370                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1371
1372                 scan_transparent = true;
1373         }
1374
1375         // Restore hit flags
1376         this.dphitcontentsmask = hf;
1377
1378         this.enemy = best;
1379         this.havocbot_stickenemy_time = time + autocvar_bot_ai_enemydetectioninterval_stickingtoenemy;
1380         if(best && best.classname == "misc_breakablemodel")
1381                 this.havocbot_stickenemy_time = 0;
1382 }
1383
1384 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1385 {
1386         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1387         // so skip this for them, or they'll never get to reload their weapons at all.
1388         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1389         if(skill < 5)
1390                 return false;
1391
1392         // if this weapon is scheduled for reloading, don't switch to it during combat
1393         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1394         {
1395                 FOREACH(Weapons, it != WEP_Null, {
1396                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1397                                 return true; // other weapon available
1398                 });
1399         }
1400
1401         return false;
1402 }
1403
1404 void havocbot_chooseweapon(entity this, .entity weaponentity)
1405 {
1406         int i;
1407
1408         // ;)
1409         if(g_weaponarena_weapons == WEPSET(TUBA))
1410         {
1411                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1412                 return;
1413         }
1414
1415         // TODO: clean this up by moving it to weapon code
1416         if(this.enemy==NULL)
1417         {
1418                 // If no weapon was chosen get the first available weapon
1419                 if(this.(weaponentity).m_weapon==WEP_Null)
1420                 FOREACH(Weapons, it != WEP_Null, {
1421                         if(client_hasweapon(this, it, weaponentity, true, false))
1422                         {
1423                                 this.(weaponentity).m_switchweapon = it;
1424                                 return;
1425                         }
1426                 });
1427                 return;
1428         }
1429
1430         // Do not change weapon during the next second after a combo
1431         float f = time - this.lastcombotime;
1432         if(f < 1)
1433                 return;
1434
1435         float w;
1436         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1437
1438         // Should it do a weapon combo?
1439         float af, ct, combo_time, combo;
1440
1441         af = ATTACK_FINISHED(this, weaponentity);
1442         ct = autocvar_bot_ai_weapon_combo_threshold;
1443
1444         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1445         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1446         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1447
1448         combo = false;
1449
1450         if(autocvar_bot_ai_weapon_combo)
1451         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1452         if(af > combo_time)
1453         {
1454                 combo = true;
1455                 this.lastcombotime = time;
1456         }
1457
1458         distance *= (2 ** this.bot_rangepreference);
1459
1460         // Custom weapon list based on distance to the enemy
1461         if(bot_custom_weapon){
1462
1463                 // Choose weapons for far distance
1464                 if ( distance > bot_distance_far ) {
1465                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1466                                 w = bot_weapons_far[i];
1467                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1468                                 {
1469                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1470                                                 continue;
1471                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1472                                         return;
1473                                 }
1474                         }
1475                 }
1476
1477                 // Choose weapons for mid distance
1478                 if ( distance > bot_distance_close) {
1479                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1480                                 w = bot_weapons_mid[i];
1481                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1482                                 {
1483                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1484                                                 continue;
1485                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1486                                         return;
1487                                 }
1488                         }
1489                 }
1490
1491                 // Choose weapons for close distance
1492                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1493                         w = bot_weapons_close[i];
1494                         if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1495                         {
1496                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1497                                         continue;
1498                                 this.(weaponentity).m_switchweapon = Weapons_from(w);
1499                                 return;
1500                         }
1501                 }
1502         }
1503 }
1504
1505 void havocbot_aim(entity this)
1506 {
1507         if (time < this.nextaim)
1508                 return;
1509         this.nextaim = time + 0.1;
1510         vector myvel = this.velocity;
1511         if (!this.waterlevel)
1512                 myvel.z = 0;
1513         if(MUTATOR_CALLHOOK(HavocBot_Aim, this)) { /* do nothing */ }
1514         else if (this.enemy)
1515         {
1516                 vector enemyvel = this.enemy.velocity;
1517                 if (!this.enemy.waterlevel)
1518                         enemyvel.z = 0;
1519                 lag_additem(this, time + CS(this).ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1520         }
1521         else
1522                 lag_additem(this, time + CS(this).ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1523 }
1524
1525 bool havocbot_moveto_refresh_route(entity this)
1526 {
1527         // Refresh path to goal if necessary
1528         entity wp;
1529         wp = this.havocbot_personal_waypoint;
1530         navigation_goalrating_start(this);
1531         navigation_routerating(this, wp, 10000, 10000);
1532         navigation_goalrating_end(this);
1533         return (this.goalentity != NULL);
1534 }
1535
1536 float havocbot_moveto(entity this, vector pos)
1537 {
1538         entity wp;
1539
1540         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1541         {
1542                 // Step 4: Move to waypoint
1543                 if(this.havocbot_personal_waypoint==NULL)
1544                 {
1545                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1546                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1547                         return CMD_STATUS_ERROR;
1548                 }
1549
1550                 if (!bot_strategytoken_taken)
1551                 if(this.havocbot_personal_waypoint_searchtime<time)
1552                 {
1553                         bot_strategytoken_taken = true;
1554                         if(havocbot_moveto_refresh_route(this))
1555                         {
1556                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1557                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1558                                 this.havocbot_personal_waypoint_failcounter = 0;
1559                         }
1560                         else
1561                         {
1562                                 this.havocbot_personal_waypoint_failcounter += 1;
1563                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1564                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1565                                 {
1566                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1567                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1568                                         delete(this.havocbot_personal_waypoint);
1569                                         return CMD_STATUS_ERROR;
1570                                 }
1571                                 else
1572                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1573                         }
1574                 }
1575
1576                 if(autocvar_bot_debug_goalstack)
1577                         debuggoalstack(this);
1578
1579
1580                 // Go!
1581                 havocbot_movetogoal(this);
1582
1583                 if (!this.bot_aimdir_executed && this.goalcurrent)
1584                 {
1585                         // Heading
1586                         vector dir = get_closer_dest(this.goalcurrent, this.origin);
1587                         dir -= this.origin + this.view_ofs;
1588                         dir.z = 0;
1589                         bot_aimdir(this, dir, 0);
1590                 }
1591
1592                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1593                 {
1594                         // Step 5: Waypoint reached
1595                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1596                         waypoint_remove(this.havocbot_personal_waypoint);
1597                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1598                         return CMD_STATUS_FINISHED;
1599                 }
1600
1601                 return CMD_STATUS_EXECUTING;
1602         }
1603
1604         // Step 2: Linking waypoint
1605         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1606         {
1607                 // Wait until it is linked
1608                 if(!this.havocbot_personal_waypoint.wplinked)
1609                 {
1610                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1611                         return CMD_STATUS_EXECUTING;
1612                 }
1613
1614                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1615                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1616                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1617
1618                 // Step 3: Route to waypoint
1619                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1620
1621                 return CMD_STATUS_EXECUTING;
1622         }
1623
1624         // Step 1: Spawning waypoint
1625         wp = waypoint_spawnpersonal(this, pos);
1626         if(wp==NULL)
1627         {
1628                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1629                 return CMD_STATUS_ERROR;
1630         }
1631
1632         this.havocbot_personal_waypoint = wp;
1633         this.havocbot_personal_waypoint_failcounter = 0;
1634         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1635
1636         // if pos is inside a teleport, then let's mark it as teleport waypoint
1637         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1638         {
1639                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1640                 this.lastteleporttime = 0;
1641         });
1642
1643 /*
1644         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1645                 print("routing to a teleporter\n");
1646         else
1647                 print("routing to a non-teleporter\n");
1648 */
1649
1650         return CMD_STATUS_EXECUTING;
1651 }
1652
1653 float havocbot_resetgoal(entity this)
1654 {
1655         navigation_clearroute(this);
1656         return CMD_STATUS_FINISHED;
1657 }
1658
1659 void havocbot_setupbot(entity this)
1660 {
1661         this.bot_ai = havocbot_ai;
1662         this.cmd_moveto = havocbot_moveto;
1663         this.cmd_resetgoal = havocbot_resetgoal;
1664
1665         // NOTE: bot is not player yet
1666         havocbot_chooserole(this);
1667 }
1668
1669 vector havocbot_dodge(entity this)
1670 {
1671         // LordHavoc: disabled because this is too expensive
1672         return '0 0 0';
1673 #if 0
1674         entity head;
1675         vector dodge, v, n;
1676         float danger, bestdanger, vl, d;
1677         dodge = '0 0 0';
1678         bestdanger = -20;
1679         // check for dangerous objects near bot or approaching bot
1680         head = findchainfloat(bot_dodge, true);
1681         while(head)
1682         {
1683                 if (head.owner != this)
1684                 {
1685                         vl = vlen(head.velocity);
1686                         if (vl > autocvar_sv_maxspeed * 0.3)
1687                         {
1688                                 n = normalize(head.velocity);
1689                                 v = this.origin - head.origin;
1690                                 d = v * n;
1691                                 if (d > (0 - head.bot_dodgerating))
1692                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1693                                 {
1694                                         // calculate direction and distance from the flight path, by removing the forward axis
1695                                         v = v - (n * (v * n));
1696                                         danger = head.bot_dodgerating - vlen(v);
1697                                         if (bestdanger < danger)
1698                                         {
1699                                                 bestdanger = danger;
1700                                                 // dodge to the side of the object
1701                                                 dodge = normalize(v);
1702                                         }
1703                                 }
1704                         }
1705                         else
1706                         {
1707                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1708                                 if (bestdanger < danger)
1709                                 {
1710                                         bestdanger = danger;
1711                                         dodge = normalize(this.origin - head.origin);
1712                                 }
1713                         }
1714                 }
1715                 head = head.chain;
1716         }
1717         return dodge;
1718 #endif
1719 }