qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "../cvars.qh"
   6
   7 #include "../aim.qh"
   8 #include "../bot.qh"
   9 #include "../navigation.qh"
  10 #include "../scripting.qh"
  11 #include "../waypoints.qh"
  12
  13 #include <common/constants.qh>
  14 #include <common/impulses/all.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/physics/player.qh>
  17 #include <common/state.qh>
  18 #include <common/items/_mod.qh>
  19 #include <common/wepent.qh>
  20
  21 #include <common/triggers/teleporters.qh>
  22 #include <common/triggers/trigger/jumppads.qh>
  23
  24 #include <lib/warpzone/common.qh>
  25
  26 .float speed;
  27
  28 void havocbot_ai(entity this)
  29 {
  30         if(this.draggedby)
  31                 return;
  32
  33         if(bot_execute_commands(this))
  34                 return;
  35
  36         if (bot_strategytoken == this)
  37         if (!bot_strategytoken_taken)
  38         {
  39                 if(this.havocbot_blockhead)
  40                 {
  41                         this.havocbot_blockhead = false;
  42                 }
  43                 else
  44                 {
  45                         if (!this.jumppadcount && !STAT(FROZEN, this))
  46                                 this.havocbot_role(this); // little too far down the rabbit hole
  47                 }
  48
  49                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  50                 if(!(IS_DEAD(this) || STAT(FROZEN, this)))
  51                 if(!this.goalcurrent)
  52                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  53                 {
  54                         // Look for the closest waypoint out of water
  55                         entity newgoal = NULL;
  56                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  57                         {
  58                                 if(it.origin.z < this.origin.z)
  59                                         continue;
  60
  61                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  62                                         continue;
  63
  64                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  65                                         continue;
  66
  67                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  68
  69                                 if(trace_fraction < 1)
  70                                         continue;
  71
  72                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  73                                         newgoal = it;
  74                         });
  75
  76                         if(newgoal)
  77                         {
  78                         //      te_wizspike(newgoal.origin);
  79                                 navigation_pushroute(this, newgoal);
  80                         }
  81                 }
  82
  83                 // token has been used this frame
  84                 bot_strategytoken_taken = true;
  85         }
  86
  87         if(IS_DEAD(this) || STAT(FROZEN, this))
  88                 return;
  89
  90         havocbot_chooseenemy(this);
  91
  92         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
  93         {
  94                 .entity weaponentity = weaponentities[slot];
  95                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
  96                 if(this.(weaponentity).bot_chooseweapontime < time)
  97                 {
  98                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
  99                         havocbot_chooseweapon(this, weaponentity);
 100                 }
 101         }
 102         havocbot_aim(this);
 103         lag_update(this);
 104         if (this.bot_aimtarg)
 105         {
 106                 this.aistatus |= AI_STATUS_ATTACKING;
 107                 this.aistatus &= ~AI_STATUS_ROAMING;
 108
 109                 if(this.weapons)
 110                 {
 111                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 112                         {
 113                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 114                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 115                         }
 116                         else
 117                         {
 118                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 119                                 {
 120                                         .entity weaponentity = weaponentities[slot];
 121                                         Weapon w = this.(weaponentity).m_weapon;
 122                                         if(w == WEP_Null && slot != 0)
 123                                                 continue;
 124                                         w.wr_aim(w, this, weaponentity);
 125                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
 126                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 127                                 }
 128                         }
 129                 }
 130                 else
 131                 {
 132                         if(IS_PLAYER(this.bot_aimtarg))
 133                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs , -1);
 134                 }
 135         }
 136         else if (this.goalcurrent)
 137         {
 138                 this.aistatus |= AI_STATUS_ROAMING;
 139                 this.aistatus &= ~AI_STATUS_ATTACKING;
 140
 141                 vector v = '0 0 0', now, next;
 142                 float aimdistance,skillblend,distanceblend,blend;
 143
 144                 SET_DESTCOORDS(this.goalcurrent, this.origin, v);
 145                 if(this.goalcurrent.wpisbox)
 146                 {
 147                         // avoid a glitch when bot is teleported but teleport waypoint isn't removed yet
 148                         if(this.goalstack02 && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT
 149                         && this.lastteleporttime > 0 && time - this.lastteleporttime < 0.15)
 150                                 v = (this.goalstack02.absmin + this.goalstack02.absmax) * 0.5;
 151                         // aim to teleport origin if bot is inside teleport waypoint but hasn't touched the real teleport yet
 152                         else if(boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin, this.origin))
 153                                 v = this.goalcurrent.origin;
 154                 }
 155                 next = now = v - (this.origin + this.view_ofs);
 156                 aimdistance = vlen(now);
 157
 158                 //dprint(this.goalstack01.classname,etos(this.goalstack01),"\n");
 159                 if(
 160                         this.goalstack01 != this && this.goalstack01 && !wasfreed(this.goalstack01) && ((this.aistatus & AI_STATUS_RUNNING) == 0) &&
 161                         !(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 162                 )
 163                         next = ((this.goalstack01.absmin + this.goalstack01.absmax) * 0.5) - (this.origin + this.view_ofs);
 164
 165                 skillblend=bound(0,(skill+this.bot_moveskill-2.5)*0.5,1); //lower skill player can't preturn
 166                 distanceblend=bound(0,aimdistance/autocvar_bot_ai_keyboard_distance,1);
 167                 blend = skillblend * (1-distanceblend);
 168                 //v = (now * (distanceblend) + next * (1-distanceblend)) * (skillblend) + now * (1-skillblend);
 169                 //v = now * (distanceblend) * (skillblend) + next * (1-distanceblend) * (skillblend) + now * (1-skillblend);
 170                 //v = now * ((1-skillblend) + (distanceblend) * (skillblend)) + next * (1-distanceblend) * (skillblend);
 171                 v = now + blend * (next - now);
 172                 //dprint(etos(this), " ");
 173                 //dprint(vtos(now), ":", vtos(next), "=", vtos(v), " (blend ", ftos(blend), ")\n");
 174                 //v = now * (distanceblend) + next * (1-distanceblend);
 175                 if (this.waterlevel < WATERLEVEL_SWIMMING)
 176                         v.z = 0;
 177                 //dprint("walk at:", vtos(v), "\n");
 178                 //te_lightning2(NULL, this.origin, this.goalcurrent.origin);
 179                 bot_aimdir(this, v, -1);
 180         }
 181         havocbot_movetogoal(this);
 182
 183         // if the bot is not attacking, consider reloading weapons
 184         if (!(this.aistatus & AI_STATUS_ATTACKING))
 185         {
 186                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 187                 {
 188                         .entity weaponentity = weaponentities[slot];
 189
 190                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 191                                 continue;
 192
 193                         // we are currently holding a weapon that's not fully loaded, reload it
 194                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 195                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
 196                                 CS(this).impulse = IMP_weapon_reload.impulse; // not sure if this is done right
 197
 198                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 199                         // the code above executes next frame, starting the reloading then
 200                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
 201                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
 202                         {
 203                                 FOREACH(Weapons, it != WEP_Null, {
 204                                         if((this.weapons & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
 205                                         {
 206                                                 this.(weaponentity).m_switchweapon = it;
 207                                                 break;
 208                                         }
 209                                 });
 210                         }
 211                 }
 212         }
 213 }
 214
 215 void havocbot_keyboard_movement(entity this, vector destorg)
 216 {
 217         vector keyboard;
 218
 219         if (time > this.havocbot_keyboardtime)
 220         {
 221                 float sk = skill + this.bot_moveskill;
 222                 this.havocbot_keyboardtime =
 223                         max(
 224                                 this.havocbot_keyboardtime
 225                                         + 0.05 / max(1, sk + this.havocbot_keyboardskill)
 226                                         + random() * 0.025 / max(0.00025, skill + this.havocbot_keyboardskill)
 227                         , time);
 228                 keyboard = CS(this).movement / autocvar_sv_maxspeed;
 229
 230                 float trigger = autocvar_bot_ai_keyboard_threshold;
 231                 float trigger1 = -trigger;
 232
 233                 // categorize forward movement
 234                 // at skill < 1.5 only forward
 235                 // at skill < 2.5 only individual directions
 236                 // at skill < 4.5 only individual directions, and forward diagonals
 237                 // at skill >= 4.5, all cases allowed
 238                 if (keyboard.x > trigger)
 239                 {
 240                         keyboard.x = 1;
 241                         if (sk < 2.5)
 242                                 keyboard.y = 0;
 243                 }
 244                 else if (keyboard.x < trigger1 && sk > 1.5)
 245                 {
 246                         keyboard.x = -1;
 247                         if (sk < 4.5)
 248                                 keyboard.y = 0;
 249                 }
 250                 else
 251                 {
 252                         keyboard.x = 0;
 253                         if (sk < 1.5)
 254                                 keyboard.y = 0;
 255                 }
 256                 if (sk < 4.5)
 257                         keyboard.z = 0;
 258
 259                 if (keyboard.y > trigger)
 260                         keyboard.y = 1;
 261                 else if (keyboard.y < trigger1)
 262                         keyboard.y = -1;
 263                 else
 264                         keyboard.y = 0;
 265
 266                 if (keyboard.z > trigger)
 267                         keyboard.z = 1;
 268                 else if (keyboard.z < trigger1)
 269                         keyboard.z = -1;
 270                 else
 271                         keyboard.z = 0;
 272
 273                 this.havocbot_keyboard = keyboard * autocvar_sv_maxspeed;
 274                 if (this.havocbot_ducktime > time)
 275                         PHYS_INPUT_BUTTON_CROUCH(this) = true;
 276         }
 277
 278         keyboard = this.havocbot_keyboard;
 279         float blend = bound(0, vlen(destorg - this.origin) / autocvar_bot_ai_keyboard_distance, 1); // When getting close move with 360 degree
 280         //dprint("movement ", vtos(CS(this).movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 281         CS(this).movement = CS(this).movement + (keyboard - CS(this).movement) * blend;
 282 }
 283
 284 void havocbot_bunnyhop(entity this, vector dir)
 285 {
 286         float bunnyhopdistance;
 287         vector deviation;
 288         float maxspeed;
 289         vector gco = '0 0 0', gno;
 290
 291         // Don't jump when attacking
 292         if(this.aistatus & AI_STATUS_ATTACKING)
 293                 return;
 294
 295         if(IS_PLAYER(this.goalcurrent))
 296                 return;
 297
 298         maxspeed = autocvar_sv_maxspeed;
 299
 300         if(this.aistatus & AI_STATUS_RUNNING && vdist(this.velocity, <, autocvar_sv_maxspeed * 0.75)
 301                 || this.aistatus & AI_STATUS_DANGER_AHEAD)
 302         {
 303                 this.aistatus &= ~AI_STATUS_RUNNING;
 304                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 305                 this.bot_canruntogoal = 0;
 306                 this.bot_timelastseengoal = 0;
 307                 return;
 308         }
 309
 310         if(this.waterlevel > WATERLEVEL_WETFEET)
 311         {
 312                 this.aistatus &= ~AI_STATUS_RUNNING;
 313                 return;
 314         }
 315
 316         if(this.bot_lastseengoal != this.goalcurrent && !(this.aistatus & AI_STATUS_RUNNING))
 317         {
 318                 this.bot_canruntogoal = 0;
 319                 this.bot_timelastseengoal = 0;
 320         }
 321
 322         SET_DESTCOORDS(this.goalcurrent, this.origin, gco);
 323         bunnyhopdistance = vlen(this.origin - gco);
 324
 325         // Run only to visible goals
 326         if(IS_ONGROUND(this))
 327         if(vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed)) // if -really- running
 328         if(checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 329         {
 330                         this.bot_lastseengoal = this.goalcurrent;
 331
 332                         // seen it before
 333                         if(this.bot_timelastseengoal)
 334                         {
 335                                 // for a period of time
 336                                 if(time - this.bot_timelastseengoal > autocvar_bot_ai_bunnyhop_firstjumpdelay)
 337                                 {
 338                                         float checkdistance;
 339                                         checkdistance = true;
 340
 341                                         // don't run if it is too close
 342                                         if(this.bot_canruntogoal==0)
 343                                         {
 344                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_startdistance)
 345                                                         this.bot_canruntogoal = 1;
 346                                                 else
 347                                                         this.bot_canruntogoal = -1;
 348                                         }
 349
 350                                         if(this.bot_canruntogoal != 1)
 351                                                 return;
 352
 353                                         if(this.aistatus & AI_STATUS_ROAMING)
 354                                         if(this.goalcurrent.classname=="waypoint")
 355                                         if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL))
 356                                         if(fabs(gco.z - this.origin.z) < this.maxs.z - this.mins.z)
 357                                         if(this.goalstack01 && !wasfreed(this.goalstack01))
 358                                         {
 359                                                 gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 360                                                 deviation = vectoangles(gno - this.origin) - vectoangles(gco - this.origin);
 361                                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 362                                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 363
 364                                                 if(fabs(deviation.y) < 20)
 365                                                 if(bunnyhopdistance < vlen(this.origin - gno))
 366                                                 if(fabs(gno.z - gco.z) < this.maxs.z - this.mins.z)
 367                                                 {
 368                                                         if(vdist(gco - gno, >, autocvar_bot_ai_bunnyhop_startdistance))
 369                                                         if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
 370                                                         {
 371                                                                 checkdistance = false;
 372                                                         }
 373                                                 }
 374                                         }
 375
 376                                         if(checkdistance)
 377                                         {
 378                                                 this.aistatus &= ~AI_STATUS_RUNNING;
 379                                                 // increase stop distance in case the goal is on a slope or a lower platform
 380                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_stopdistance + (this.origin.z - gco.z))
 381                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 382                                         }
 383                                         else
 384                                         {
 385                                                 this.aistatus |= AI_STATUS_RUNNING;
 386                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 387                                         }
 388                                 }
 389                         }
 390                         else
 391                         {
 392                                 this.bot_timelastseengoal = time;
 393                         }
 394         }
 395         else
 396         {
 397                 this.bot_timelastseengoal = 0;
 398         }
 399
 400 #if 0
 401         // Release jump button
 402         if(!cvar("sv_pogostick"))
 403         if((IS_ONGROUND(this)) == 0)
 404         {
 405                 if(this.velocity.z < 0 || vlen(this.velocity)<maxspeed)
 406                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 407
 408                 // Strafe
 409                 if(this.aistatus & AI_STATUS_RUNNING)
 410                 if(vlen(this.velocity)>maxspeed)
 411                 {
 412                         deviation = vectoangles(dir) - vectoangles(this.velocity);
 413                         while (deviation.y < -180) deviation.y = deviation.y + 360;
 414                         while (deviation.y > 180) deviation.y = deviation.y - 360;
 415
 416                         if(fabs(deviation.y)>10)
 417                                 CS(this).movement_x = 0;
 418
 419                         if(deviation.y>10)
 420                                 CS(this).movement_y = maxspeed * -1;
 421                         else if(deviation.y<10)
 422                                 CS(this).movement_y = maxspeed;
 423
 424                 }
 425         }
 426 #endif
 427 }
 428
 429 // return true when bot isn't getting closer to the current goal
 430 bool havocbot_checkgoaldistance(entity this, vector gco)
 431 {
 432         float curr_dist = vlen(this.origin - gco);
 433         float curr_dist_2d = vlen(vec2(this.origin - gco));
 434         if(curr_dist > this.goalcurrent_distance && curr_dist_2d > this.goalcurrent_distance_2d)
 435         {
 436                 if(!this.goalcurrent_distance_time)
 437                         this.goalcurrent_distance_time = time;
 438                 else if (time - this.goalcurrent_distance_time > 0.5)
 439                         return true;
 440         }
 441         else
 442         {
 443                 // reduce it a little bit so it works even with very small approaches to the goal
 444                 this.goalcurrent_distance = max(20, curr_dist - 10);
 445                 this.goalcurrent_distance_2d = max(20, curr_dist_2d - 10);
 446                 this.goalcurrent_distance_time = 0;
 447         }
 448         return false;
 449 }
 450
 451 void havocbot_movetogoal(entity this)
 452 {
 453         vector destorg = '0 0 0';
 454         vector diff;
 455         vector dir;
 456         vector flatdir;
 457         vector evadeobstacle;
 458         vector evadelava;
 459         float maxspeed;
 460         vector gco;
 461         //float dist;
 462         vector dodge;
 463         //if (this.goalentity)
 464         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 465         CS(this).movement = '0 0 0';
 466         maxspeed = autocvar_sv_maxspeed;
 467
 468         PHYS_INPUT_BUTTON_JETPACK(this) = false;
 469         // Jetpack navigation
 470         if(this.goalcurrent)
 471         if(this.navigation_jetpack_goal)
 472         if(this.goalcurrent==this.navigation_jetpack_goal)
 473         if(this.ammo_fuel)
 474         {
 475                 if(autocvar_bot_debug_goalstack)
 476                 {
 477                         debuggoalstack(this);
 478                         te_wizspike(this.navigation_jetpack_point);
 479                 }
 480
 481                 // Take off
 482                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 483                 {
 484                         // Brake almost completely so it can get a good direction
 485                         if(vdist(this.velocity, >, 10))
 486                                 return;
 487                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 488                 }
 489
 490                 makevectors(this.v_angle.y * '0 1 0');
 491                 dir = normalize(this.navigation_jetpack_point - this.origin);
 492
 493                 // Landing
 494                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 495                 {
 496                         // Calculate brake distance in xy
 497                         float db, v, d;
 498                         vector dxy;
 499
 500                         dxy = this.origin - ( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ); dxy.z = 0;
 501                         d = vlen(dxy);
 502                         v = vlen(this.velocity -  this.velocity.z * '0 0 1');
 503                         db = ((v ** 2) / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 504                 //      dprint("distance ", ftos(ceil(d)), " velocity ", ftos(ceil(v)), " brake at ", ftos(ceil(db)), "\n");
 505                         if(d < db || d < 500)
 506                         {
 507                                 // Brake
 508                                 if(fabs(this.velocity.x)>maxspeed*0.3)
 509                                 {
 510                                         CS(this).movement_x = dir * v_forward * -maxspeed;
 511                                         return;
 512                                 }
 513                                 // Switch to normal mode
 514                                 this.navigation_jetpack_goal = NULL;
 515                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 516                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 517                                 return;
 518                         }
 519                 }
 520                 else if(checkpvs(this.origin,this.goalcurrent))
 521                 {
 522                         // If I can see the goal switch to landing code
 523                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 524                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 525                         return;
 526                 }
 527
 528                 // Flying
 529                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 530                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
 531                 {
 532                         CS(this).movement_x = dir * v_forward * maxspeed;
 533                         CS(this).movement_y = dir * v_right * maxspeed;
 534                 }
 535                 return;
 536         }
 537
 538         // Handling of jump pads
 539         if(this.jumppadcount)
 540         {
 541                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 542                 {
 543                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 544                         navigation_poptouchedgoals(this);
 545                         return;
 546                 }
 547                 else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 548                 {
 549                         // If got stuck on the jump pad try to reach the farthest visible waypoint
 550                         // but with some randomness so it can try out different paths
 551                         if(!this.goalcurrent)
 552                         {
 553                                 entity newgoal = NULL;
 554                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 555                                 {
 556                                         if(it.wpflags & WAYPOINTFLAG_TELEPORT)
 557                                         if(it.origin.z < this.origin.z - 100 && vdist(vec2(it.origin - this.origin), <, 100))
 558                                                 continue;
 559
 560                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 561
 562                                         if(trace_fraction < 1)
 563                                                 continue;
 564
 565                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
 566                                                 newgoal = it;
 567                                 });
 568
 569                                 if(newgoal)
 570                                 {
 571                                         this.ignoregoal = this.goalcurrent;
 572                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 573                                         navigation_clearroute(this);
 574                                         navigation_routetogoal(this, newgoal, this.origin);
 575                                         if(autocvar_bot_debug_goalstack)
 576                                                 debuggoalstack(this);
 577                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 578                                 }
 579                         }
 580                         else
 581                         {
 582                                 gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 583                                 if (this.origin.z > gco.z && vdist(vec2(this.velocity), <, autocvar_sv_maxspeed))
 584                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 585                                 else if(havocbot_checkgoaldistance(this, gco))
 586                                 {
 587                                         navigation_clearroute(this);
 588                                         navigation_goalrating_timeout_force(this);
 589                                 }
 590                                 else
 591                                         return;
 592                         }
 593                 }
 594                 else
 595                 {
 596                         if(time - this.lastteleporttime > 0.2 && this.velocity.z > 0)
 597                         {
 598                                 vector velxy = this.velocity; velxy_z = 0;
 599                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
 600                                 {
 601                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 602                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 603                                 }
 604                                 return;
 605                         }
 606
 607                         // Don't chase players while using a jump pad
 608                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 609                                 return;
 610                 }
 611         }
 612         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 613                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 614
 615         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 616         if (skill > 6 && !(IS_ONGROUND(this)))
 617         {
 618                 #define ROCKETJUMP_DAMAGE() WEP_CVAR(devastator, damage) * 0.8 \
 619                         * ((this.strength_finished < time) ? autocvar_g_balance_powerup_strength_selfdamage : 1) \
 620                         * ((this.invincible_finished < time) ? autocvar_g_balance_powerup_invincible_takedamage : 1)
 621
 622                 tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 623                 if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos ))
 624                 if(this.items & IT_JETPACK)
 625                 {
 626                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 627                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 628                         {
 629                                 if(this.velocity.z<0)
 630                                         PHYS_INPUT_BUTTON_JETPACK(this) = true;
 631                         }
 632                         else
 633                                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 634
 635                         // If there is no goal try to move forward
 636
 637                         if(this.goalcurrent==NULL)
 638                                 dir = v_forward;
 639                         else
 640                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 641
 642                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 643                         float xyspeed = xyvelocity * dir;
 644
 645                         if(xyspeed < (maxspeed / 2))
 646                         {
 647                                 makevectors(this.v_angle.y * '0 1 0');
 648                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 649                                 if(trace_fraction==1)
 650                                 {
 651                                         CS(this).movement_x = dir * v_forward * maxspeed;
 652                                         CS(this).movement_y = dir * v_right * maxspeed;
 653                                         if (skill < 10)
 654                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 655                                 }
 656                         }
 657
 658                         this.havocbot_blockhead = true;
 659
 660                         return;
 661                 }
 662                 else if(this.health + this.armorvalue > ROCKETJUMP_DAMAGE())
 663                 {
 664                         if(this.velocity.z < 0)
 665                         {
 666                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 667                                 {
 668                                         .entity weaponentity = weaponentities[slot];
 669
 670                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 671                                                 continue;
 672
 673                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
 674                                         {
 675                                                 CS(this).movement_x = maxspeed;
 676
 677                                                 if(this.rocketjumptime)
 678                                                 {
 679                                                         if(time > this.rocketjumptime)
 680                                                         {
 681                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 682                                                                 this.rocketjumptime = 0;
 683                                                         }
 684                                                         return;
 685                                                 }
 686
 687                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 688                                                 this.v_angle_x = 90;
 689                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 690                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 691                                                 return;
 692                                         }
 693                                 }
 694                         }
 695                 }
 696                 else
 697                 {
 698                         // If there is no goal try to move forward
 699                         if(this.goalcurrent==NULL)
 700                                 CS(this).movement_x = maxspeed;
 701                 }
 702         }
 703
 704         // If we are under water with no goals, swim up
 705         if(this.waterlevel)
 706         if(this.goalcurrent==NULL)
 707         {
 708                 dir = '0 0 0';
 709                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 710                         dir.z = 1;
 711                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 712                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 713                 else
 714                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 715                 makevectors(this.v_angle.y * '0 1 0');
 716                 CS(this).movement_x = dir * v_forward * maxspeed;
 717                 CS(this).movement_y = dir * v_right * maxspeed;
 718                 CS(this).movement_z = dir * v_up * maxspeed;
 719         }
 720
 721         // if there is nowhere to go, exit
 722         if (this.goalcurrent == NULL)
 723                 return;
 724
 725
 726         bool locked_goal = false;
 727         if(this.goalentity && wasfreed(this.goalentity))
 728         {
 729                 navigation_clearroute(this);
 730                 navigation_goalrating_timeout_force(this);
 731                 return;
 732         }
 733         else if(this.goalentity.bot_pickup)
 734         {
 735                 if(this.goalentity.bot_pickup_respawning)
 736                 {
 737                         if(this.goalentity.solid) // item respawned
 738                                 this.goalentity.bot_pickup_respawning = false;
 739                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
 740                         {
 741                                 if(checkpvs(this.origin, this.goalentity))
 742                                 {
 743                                         this.goalentity.bot_pickup_respawning = false;
 744                                         navigation_clearroute(this);
 745                                         navigation_goalrating_timeout_force(this);
 746                                         return;
 747                                 }
 748                         }
 749                         else if(this.goalentity == this.goalcurrent)
 750                                 locked_goal = true; // wait for item to respawn
 751                 }
 752                 else if(!this.goalentity.solid && !boxesoverlap(this.goalentity.absmin, this.goalentity.absmax, this.absmin, this.absmax))
 753                 {
 754                         if(checkpvs(this.origin, this.goalentity))
 755                         {
 756                                 navigation_clearroute(this);
 757                                 navigation_goalrating_timeout_force(this);
 758                                 return;
 759                         }
 760                 }
 761         }
 762         if(!locked_goal)
 763         {
 764                 if(navigation_poptouchedgoals(this) && this.bot_strategytime < time + 1)
 765                         navigation_goalrating_timeout_force(this);
 766         }
 767
 768         // if ran out of goals try to use an alternative goal or get a new strategy asap
 769         if(this.goalcurrent == NULL)
 770         {
 771                 navigation_goalrating_timeout_force(this);
 772                 return;
 773         }
 774
 775
 776         if(autocvar_bot_debug_goalstack)
 777                 debuggoalstack(this);
 778
 779         bool bunnyhop_forbidden = false;;
 780         SET_DESTCOORDS(this.goalcurrent, this.origin, destorg);
 781
 782         // in case bot ends up inside the teleport waypoint without touching
 783         // the teleport itself, head to the teleport origin
 784         if(this.goalcurrent.wpisbox && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin + eZ * this.mins.z, this.origin + eZ * this.maxs.z))
 785         {
 786                 bunnyhop_forbidden = true;
 787                 destorg = this.goalcurrent.origin;
 788                 if(destorg.z > this.origin.z)
 789                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 790         }
 791
 792         diff = destorg - this.origin;
 793         //dist = vlen(diff);
 794         dir = normalize(diff);
 795         flatdir = diff;flatdir.z = 0;
 796         flatdir = normalize(flatdir);
 797         gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 798
 799         //if (this.bot_dodgevector_time < time)
 800         {
 801                 //this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 802                 //this.bot_dodgevector_jumpbutton = 1;
 803                 evadeobstacle = '0 0 0';
 804                 evadelava = '0 0 0';
 805
 806                 this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 807                 makevectors(this.v_angle.y * '0 1 0');
 808                 if (this.waterlevel)
 809                 {
 810                         if(this.waterlevel>WATERLEVEL_SWIMMING)
 811                         {
 812                                 if(!this.goalcurrent)
 813                                         this.aistatus |= AI_STATUS_OUT_WATER;
 814                                 else if(gco.z > this.origin.z)
 815                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 816                         }
 817                         else
 818                         {
 819                                 dir = flatdir;
 820                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && gco.z < this.origin.z) &&
 821                                         ( !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER) || this.aistatus & AI_STATUS_OUT_WATER))
 822                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 823                                 else
 824                                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 825                         }
 826                 }
 827                 else
 828                 {
 829                         float s;
 830                         vector offset;
 831                         if(this.aistatus & AI_STATUS_OUT_WATER)
 832                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 833
 834                         // jump if going toward an obstacle that doesn't look like stairs we
 835                         // can walk up directly
 836                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : v_forward * 32);
 837                         tracebox(this.origin, this.mins, this.maxs, this.origin + offset, false, this);
 838                         if (trace_fraction < 1)
 839                         if (trace_plane_normal.z < 0.7)
 840                         {
 841                                 s = trace_fraction;
 842                                 tracebox(this.origin + stepheightvec, this.mins, this.maxs, this.origin + offset + stepheightvec, false, this);
 843                                 if (trace_fraction < s + 0.01)
 844                                 if (trace_plane_normal.z < 0.7)
 845                                 {
 846                                         s = trace_fraction;
 847                                         tracebox(this.origin + jumpstepheightvec, this.mins, this.maxs, this.origin + offset + jumpstepheightvec, false, this);
 848                                         if (trace_fraction > s)
 849                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 850                                 }
 851                         }
 852
 853                         // if bot for some reason doesn't get close to the current goal find another one
 854                         if(!this.jumppadcount && !IS_PLAYER(this.goalcurrent) && !(this.goalcurrent.bot_pickup_respawning && this.goalcurrent_distance < 50))
 855                         if(havocbot_checkgoaldistance(this, gco))
 856                         {
 857                                 navigation_clearroute(this);
 858                                 navigation_goalrating_timeout_force(this);
 859                                 return;
 860                         }
 861
 862                         // Check for water/slime/lava and dangerous edges
 863                         // (only when the bot is on the ground or jumping intentionally)
 864
 865                         vector dst_ahead = this.origin + this.view_ofs + offset;
 866                         vector dst_down = dst_ahead - '0 0 3000';
 867                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
 868
 869                         bool unreachable = false;
 870                         s = CONTENT_SOLID;
 871                         if(trace_fraction == 1 && this.jumppadcount == 0 && !this.goalcurrent.wphardwired )
 872                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
 873                         {
 874                                 // Look downwards
 875                                 traceline(dst_ahead , dst_down, true, NULL);
 876                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
 877                                 //te_lightning2(NULL, dst_ahead, dst_down); // Draw "downwards" look
 878                                 if(trace_endpos.z < this.origin.z + this.mins.z)
 879                                 {
 880                                         s = pointcontents(trace_endpos + '0 0 1');
 881                                         if (s != CONTENT_SOLID)
 882                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
 883                                                 evadelava = normalize(this.velocity) * -1;
 884                                         else if (s == CONTENT_SKY)
 885                                                 evadeobstacle = normalize(this.velocity) * -1;
 886                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
 887                                         {
 888                                                 // the traceline check isn't enough but is good as optimization,
 889                                                 // when not true (most of the time) this tracebox call is avoided
 890                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
 891                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
 892                                                 {
 893                                                         if (gco.z > this.origin.z + jumpstepheightvec.z)
 894                                                         {
 895                                                                 // the goal is probably on an upper platform, assume bot can't get there
 896                                                                 unreachable = true;
 897                                                         }
 898                                                         else
 899                                                                 evadelava = normalize(this.velocity) * -1;
 900                                                 }
 901                                         }
 902                                 }
 903                         }
 904
 905                         dir = flatdir;
 906                         evadeobstacle.z = 0;
 907                         evadelava.z = 0;
 908                         makevectors(this.v_angle.y * '0 1 0');
 909
 910                         if(evadeobstacle || evadelava || (s == CONTENT_WATER))
 911                         {
 912                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
 913                                 if(IS_PLAYER(this.goalcurrent))
 914                                         unreachable = true;
 915                         }
 916                         if(unreachable)
 917                         {
 918                                 navigation_clearroute(this);
 919                                 navigation_goalrating_timeout_force(this);
 920                         }
 921                 }
 922
 923                 dodge = havocbot_dodge(this);
 924                 dodge = dodge * bound(0,0.5+(skill+this.bot_dodgeskill)*0.1,1);
 925                 evadelava = evadelava * bound(1,3-(skill+this.bot_dodgeskill),3); //Noobs fear lava a lot and take more distance from it
 926                 traceline(this.origin, ( ( this.enemy.absmin + this.enemy.absmax ) * 0.5 ), true, NULL);
 927                 if(IS_PLAYER(trace_ent))
 928                         dir = dir * bound(0,(skill+this.bot_dodgeskill)/7,1);
 929
 930                 dir = normalize(dir + dodge + evadeobstacle + evadelava);
 931         //      this.bot_dodgevector = dir;
 932         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
 933         }
 934
 935         if(time < this.ladder_time)
 936         {
 937                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
 938                 {
 939                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
 940                                 dir.z = 1;
 941                 }
 942                 else
 943                 {
 944                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
 945                                 dir.z = -1;
 946                 }
 947         }
 948
 949         //dir = this.bot_dodgevector;
 950         //if (this.bot_dodgevector_jumpbutton)
 951         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
 952         CS(this).movement_x = dir * v_forward * maxspeed;
 953         CS(this).movement_y = dir * v_right * maxspeed;
 954         CS(this).movement_z = dir * v_up * maxspeed;
 955
 956         // Emulate keyboard interface
 957         if (skill < 10)
 958                 havocbot_keyboard_movement(this, destorg);
 959
 960         // Bunnyhop!
 961         //if(this.aistatus & AI_STATUS_ROAMING)
 962         if(!bunnyhop_forbidden && this.goalcurrent)
 963         if(skill+this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
 964                 havocbot_bunnyhop(this, dir);
 965
 966         if ((dir * v_up) >= autocvar_sv_jumpvelocity*0.5 && (IS_ONGROUND(this))) PHYS_INPUT_BUTTON_JUMP(this) = true;
 967         if (((dodge * v_up) > 0) && random()*frametime >= 0.2*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) PHYS_INPUT_BUTTON_JUMP(this) = true;
 968         if (((dodge * v_up) < 0) && random()*frametime >= 0.5*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) this.havocbot_ducktime=time+0.3/bound(0.1,skill+this.bot_dodgeskill,10);
 969 }
 970
 971 entity havocbot_gettarget(entity this, bool secondary)
 972 {
 973         entity best = NULL;
 974         vector eye = CENTER_OR_VIEWOFS(this);
 975         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
 976         {
 977                 vector v = CENTER_OR_VIEWOFS(it);
 978                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
 979                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
 980                 if(bot_shouldattack(this, it))
 981                 {
 982                         traceline(eye, v, true, this);
 983                         if (trace_ent == it || trace_fraction >= 1)
 984                                 best = it;
 985                 }
 986         });
 987
 988         return best;
 989 }
 990
 991 void havocbot_chooseenemy(entity this)
 992 {
 993         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 994         {
 995                 this.enemy = NULL;
 996                 return;
 997         }
 998         if (this.enemy)
 999         {
1000                 if (!bot_shouldattack(this, this.enemy))
1001                 {
1002                         // enemy died or something, find a new target
1003                         this.enemy = NULL;
1004                         this.havocbot_chooseenemy_finished = time;
1005                 }
1006                 else if (this.havocbot_stickenemy)
1007                 {
1008                         // tracking last chosen enemy
1009                         // if enemy is visible
1010                         // and not really really far away
1011                         // and we're not severely injured
1012                         // then keep tracking for a half second into the future
1013                         traceline(this.origin+this.view_ofs, ( this.enemy.absmin + this.enemy.absmax ) * 0.5,false,NULL);
1014                         if (trace_ent == this.enemy || trace_fraction == 1)
1015                         if (vdist(((this.enemy.absmin + this.enemy.absmax) * 0.5) - this.origin, <, 1000))
1016                         if (this.health > 30)
1017                         {
1018                                 // remain tracking him for a shot while (case he went after a small corner or pilar
1019                                 this.havocbot_chooseenemy_finished = time + 0.5;
1020                                 return;
1021                         }
1022                         // enemy isn't visible, or is far away, or we're injured severely
1023                         // so stop preferring this enemy
1024                         // (it will still take a half second until a new one is chosen)
1025                         this.havocbot_stickenemy = 0;
1026                 }
1027         }
1028         if (time < this.havocbot_chooseenemy_finished)
1029                 return;
1030         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
1031         vector eye = this.origin + this.view_ofs;
1032         entity best = NULL;
1033         float bestrating = 100000000;
1034
1035         // Backup hit flags
1036         int hf = this.dphitcontentsmask;
1037
1038         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
1039
1040         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
1041
1042         bool scan_transparent = false;
1043         bool scan_secondary_targets = false;
1044         bool have_secondary_targets = false;
1045         while(true)
1046         {
1047                 scan_secondary_targets = false;
1048 LABEL(scan_targets)
1049                 IL_EACH(g_bot_targets, it.bot_attack,
1050                 {
1051                         if(!scan_secondary_targets)
1052                         {
1053                                 if(it.classname == "misc_breakablemodel")
1054                                 {
1055                                         have_secondary_targets = true;
1056                                         continue;
1057                                 }
1058                         }
1059                         else if(it.classname != "misc_breakablemodel")
1060                                 continue;
1061
1062                         vector v = (it.absmin + it.absmax) * 0.5;
1063                         float rating = vlen2(v - eye);
1064                         if (vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1065                         if (bestrating > rating)
1066                         if (bot_shouldattack(this, it))
1067                         {
1068                                 traceline(eye, v, true, this);
1069                                 if (trace_ent == it || trace_fraction >= 1)
1070                                 {
1071                                         best = it;
1072                                         bestrating = rating;
1073                                 }
1074                         }
1075                 });
1076
1077                 if(!best && have_secondary_targets && !scan_secondary_targets)
1078                 {
1079                         scan_secondary_targets = true;
1080                         // restart the loop
1081                         bestrating = 100000000;
1082                         goto scan_targets;
1083                 }
1084
1085                 // I want to do a second scan if no enemy was found or I don't have weapons
1086                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1087                 if(best || this.weapons) // || this.weapon == WEP_RIFLE.m_id
1088                         break;
1089                 if(scan_transparent)
1090                         break;
1091
1092                 // Set flags to see through transparent objects
1093                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1094
1095                 scan_transparent = true;
1096         }
1097
1098         // Restore hit flags
1099         this.dphitcontentsmask = hf;
1100
1101         this.enemy = best;
1102         this.havocbot_stickenemy = true;
1103         if(best && best.classname == "misc_breakablemodel")
1104                 this.havocbot_stickenemy = false;
1105 }
1106
1107 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1108 {
1109         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1110         // so skip this for them, or they'll never get to reload their weapons at all.
1111         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1112         if(skill < 5)
1113                 return false;
1114
1115         // if this weapon is scheduled for reloading, don't switch to it during combat
1116         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1117         {
1118                 FOREACH(Weapons, it != WEP_Null, {
1119                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1120                                 return true; // other weapon available
1121                 });
1122         }
1123
1124         return false;
1125 }
1126
1127 void havocbot_chooseweapon(entity this, .entity weaponentity)
1128 {
1129         int i;
1130
1131         // ;)
1132         if(g_weaponarena_weapons == WEPSET(TUBA))
1133         {
1134                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1135                 return;
1136         }
1137
1138         // TODO: clean this up by moving it to weapon code
1139         if(this.enemy==NULL)
1140         {
1141                 // If no weapon was chosen get the first available weapon
1142                 if(this.(weaponentity).m_weapon==WEP_Null)
1143                 FOREACH(Weapons, it != WEP_Null, {
1144                         if(client_hasweapon(this, it, weaponentity, true, false))
1145                         {
1146                                 this.(weaponentity).m_switchweapon = it;
1147                                 return;
1148                         }
1149                 });
1150                 return;
1151         }
1152
1153         // Do not change weapon during the next second after a combo
1154         float f = time - this.lastcombotime;
1155         if(f < 1)
1156                 return;
1157
1158         float w;
1159         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1160
1161         // Should it do a weapon combo?
1162         float af, ct, combo_time, combo;
1163
1164         af = ATTACK_FINISHED(this, 0);
1165         ct = autocvar_bot_ai_weapon_combo_threshold;
1166
1167         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1168         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1169         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1170
1171         combo = false;
1172
1173         if(autocvar_bot_ai_weapon_combo)
1174         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1175         if(af > combo_time)
1176         {
1177                 combo = true;
1178                 this.lastcombotime = time;
1179         }
1180
1181         distance *= (2 ** this.bot_rangepreference);
1182
1183         // Custom weapon list based on distance to the enemy
1184         if(bot_custom_weapon){
1185
1186                 // Choose weapons for far distance
1187                 if ( distance > bot_distance_far ) {
1188                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1189                                 w = bot_weapons_far[i];
1190                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1191                                 {
1192                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1193                                                 continue;
1194                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1195                                         return;
1196                                 }
1197                         }
1198                 }
1199
1200                 // Choose weapons for mid distance
1201                 if ( distance > bot_distance_close) {
1202                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1203                                 w = bot_weapons_mid[i];
1204                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1205                                 {
1206                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1207                                                 continue;
1208                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1209                                         return;
1210                                 }
1211                         }
1212                 }
1213
1214                 // Choose weapons for close distance
1215                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1216                         w = bot_weapons_close[i];
1217                         if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1218                         {
1219                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1220                                         continue;
1221                                 this.(weaponentity).m_switchweapon = Weapons_from(w);
1222                                 return;
1223                         }
1224                 }
1225         }
1226 }
1227
1228 void havocbot_aim(entity this)
1229 {
1230         if (time < this.nextaim)
1231                 return;
1232         this.nextaim = time + 0.1;
1233         vector myvel = this.velocity;
1234         if (!this.waterlevel)
1235                 myvel.z = 0;
1236         if(MUTATOR_CALLHOOK(HavocBot_Aim, this)) { /* do nothing */ }
1237         else if (this.enemy)
1238         {
1239                 vector enemyvel = this.enemy.velocity;
1240                 if (!this.enemy.waterlevel)
1241                         enemyvel.z = 0;
1242                 lag_additem(this, time + CS(this).ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1243         }
1244         else
1245                 lag_additem(this, time + CS(this).ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1246 }
1247
1248 bool havocbot_moveto_refresh_route(entity this)
1249 {
1250         // Refresh path to goal if necessary
1251         entity wp;
1252         wp = this.havocbot_personal_waypoint;
1253         navigation_goalrating_start(this);
1254         navigation_routerating(this, wp, 10000, 10000);
1255         navigation_goalrating_end(this);
1256         return (this.goalentity != NULL);
1257 }
1258
1259 float havocbot_moveto(entity this, vector pos)
1260 {
1261         entity wp;
1262
1263         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1264         {
1265                 // Step 4: Move to waypoint
1266                 if(this.havocbot_personal_waypoint==NULL)
1267                 {
1268                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1269                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1270                         return CMD_STATUS_ERROR;
1271                 }
1272
1273                 if (!bot_strategytoken_taken)
1274                 if(this.havocbot_personal_waypoint_searchtime<time)
1275                 {
1276                         bot_strategytoken_taken = true;
1277                         if(havocbot_moveto_refresh_route(this))
1278                         {
1279                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1280                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1281                                 this.havocbot_personal_waypoint_failcounter = 0;
1282                         }
1283                         else
1284                         {
1285                                 this.havocbot_personal_waypoint_failcounter += 1;
1286                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1287                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1288                                 {
1289                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1290                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1291                                         delete(this.havocbot_personal_waypoint);
1292                                         return CMD_STATUS_ERROR;
1293                                 }
1294                                 else
1295                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1296                         }
1297                 }
1298
1299                 if(autocvar_bot_debug_goalstack)
1300                         debuggoalstack(this);
1301
1302                 // Heading
1303                 vector dir = '0 0 0';
1304                 SET_DESTCOORDS(this.goalcurrent, this.origin, dir);
1305                 dir = dir - (this.origin + this.view_ofs);
1306                 dir.z = 0;
1307                 bot_aimdir(this, dir, -1);
1308
1309                 // Go!
1310                 havocbot_movetogoal(this);
1311
1312                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1313                 {
1314                         // Step 5: Waypoint reached
1315                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1316                         delete(this.havocbot_personal_waypoint);
1317                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1318                         return CMD_STATUS_FINISHED;
1319                 }
1320
1321                 return CMD_STATUS_EXECUTING;
1322         }
1323
1324         // Step 2: Linking waypoint
1325         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1326         {
1327                 // Wait until it is linked
1328                 if(!this.havocbot_personal_waypoint.wplinked)
1329                 {
1330                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1331                         return CMD_STATUS_EXECUTING;
1332                 }
1333
1334                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1335                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1336                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1337
1338                 // Step 3: Route to waypoint
1339                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1340
1341                 return CMD_STATUS_EXECUTING;
1342         }
1343
1344         // Step 1: Spawning waypoint
1345         wp = waypoint_spawnpersonal(this, pos);
1346         if(wp==NULL)
1347         {
1348                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1349                 return CMD_STATUS_ERROR;
1350         }
1351
1352         this.havocbot_personal_waypoint = wp;
1353         this.havocbot_personal_waypoint_failcounter = 0;
1354         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1355
1356         // if pos is inside a teleport, then let's mark it as teleport waypoint
1357         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1358         {
1359                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1360                 this.lastteleporttime = 0;
1361         });
1362
1363 /*
1364         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1365                 print("routing to a teleporter\n");
1366         else
1367                 print("routing to a non-teleporter\n");
1368 */
1369
1370         return CMD_STATUS_EXECUTING;
1371 }
1372
1373 float havocbot_resetgoal(entity this)
1374 {
1375         navigation_clearroute(this);
1376         return CMD_STATUS_FINISHED;
1377 }
1378
1379 void havocbot_setupbot(entity this)
1380 {
1381         this.bot_ai = havocbot_ai;
1382         this.cmd_moveto = havocbot_moveto;
1383         this.cmd_resetgoal = havocbot_resetgoal;
1384
1385         havocbot_chooserole(this);
1386 }
1387
1388 vector havocbot_dodge(entity this)
1389 {
1390         // LordHavoc: disabled because this is too expensive
1391         return '0 0 0';
1392 #if 0
1393         entity head;
1394         vector dodge, v, n;
1395         float danger, bestdanger, vl, d;
1396         dodge = '0 0 0';
1397         bestdanger = -20;
1398         // check for dangerous objects near bot or approaching bot
1399         head = findchainfloat(bot_dodge, true);
1400         while(head)
1401         {
1402                 if (head.owner != this)
1403                 {
1404                         vl = vlen(head.velocity);
1405                         if (vl > autocvar_sv_maxspeed * 0.3)
1406                         {
1407                                 n = normalize(head.velocity);
1408                                 v = this.origin - head.origin;
1409                                 d = v * n;
1410                                 if (d > (0 - head.bot_dodgerating))
1411                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1412                                 {
1413                                         // calculate direction and distance from the flight path, by removing the forward axis
1414                                         v = v - (n * (v * n));
1415                                         danger = head.bot_dodgerating - vlen(v);
1416                                         if (bestdanger < danger)
1417                                         {
1418                                                 bestdanger = danger;
1419                                                 // dodge to the side of the object
1420                                                 dodge = normalize(v);
1421                                         }
1422                                 }
1423                         }
1424                         else
1425                         {
1426                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1427                                 if (bestdanger < danger)
1428                                 {
1429                                         bestdanger = danger;
1430                                         dodge = normalize(this.origin - head.origin);
1431                                 }
1432                         }
1433                 }
1434                 head = head.chain;
1435         }
1436         return dodge;
1437 #endif
1438 }