qcsrc/server/bot/default/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "../cvars.qh"
   6
   7 #include "../aim.qh"
   8 #include "../bot.qh"
   9 #include "../navigation.qh"
  10 #include "../scripting.qh"
  11 #include "../waypoints.qh"
  12
  13 #include <common/constants.qh>
  14 #include <common/impulses/all.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/physics/player.qh>
  17 #include <common/state.qh>
  18 #include <common/items/_mod.qh>
  19 #include <common/wepent.qh>
  20
  21 #include <common/mapobjects/func/ladder.qh>
  22 #include <common/mapobjects/teleporters.qh>
  23 #include <common/mapobjects/trigger/jumppads.qh>
  24
  25 #include <lib/warpzone/common.qh>
  26
  27 .float speed;
  28
  29 void havocbot_ai(entity this)
  30 {
  31         if(this.draggedby)
  32                 return;
  33
  34         this.bot_aimdir_executed = false;
  35         // lock aim if teleported or passing through a warpzone
  36         if (this.lastteleporttime && !this.jumppadcount)
  37                 this.bot_aimdir_executed = true;
  38
  39         if(bot_execute_commands(this))
  40                 return;
  41
  42         if (bot_strategytoken == this && !bot_strategytoken_taken)
  43         {
  44                 if(this.havocbot_blockhead)
  45                 {
  46                         this.havocbot_blockhead = false;
  47                 }
  48                 else
  49                 {
  50                         if (!this.jumppadcount && !STAT(FROZEN, this))
  51                                 this.havocbot_role(this); // little too far down the rabbit hole
  52                 }
  53
  54                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  55                 if(!(IS_DEAD(this) || STAT(FROZEN, this)))
  56                 if(!this.goalcurrent)
  57                 if(this.waterlevel == WATERLEVEL_SWIMMING || (this.aistatus & AI_STATUS_OUT_WATER))
  58                 {
  59                         // Look for the closest waypoint out of water
  60                         entity newgoal = NULL;
  61                         IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 10000),
  62                         {
  63                                 if(it.origin.z < this.origin.z)
  64                                         continue;
  65
  66                                 if(it.origin.z - this.origin.z - this.view_ofs.z > 100)
  67                                         continue;
  68
  69                                 if (pointcontents(it.origin + it.maxs + '0 0 1') != CONTENT_EMPTY)
  70                                         continue;
  71
  72                                 traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
  73
  74                                 if(trace_fraction < 1)
  75                                         continue;
  76
  77                                 if(!newgoal || vlen2(it.origin - this.origin) < vlen2(newgoal.origin - this.origin))
  78                                         newgoal = it;
  79                         });
  80
  81                         if(newgoal)
  82                         {
  83                         //      te_wizspike(newgoal.origin);
  84                                 navigation_pushroute(this, newgoal);
  85                         }
  86                 }
  87
  88                 // token has been used this frame
  89                 bot_strategytoken_taken = true;
  90         }
  91
  92         if(IS_DEAD(this) || STAT(FROZEN, this))
  93         {
  94                 if (this.goalcurrent)
  95                         navigation_clearroute(this);
  96                 return;
  97         }
  98
  99         havocbot_chooseenemy(this);
 100
 101         for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 102         {
 103                 .entity weaponentity = weaponentities[slot];
 104                 if(this.(weaponentity).m_weapon != WEP_Null || slot == 0)
 105                 if(this.(weaponentity).bot_chooseweapontime < time)
 106                 {
 107                         this.(weaponentity).bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
 108                         havocbot_chooseweapon(this, weaponentity);
 109                 }
 110         }
 111         havocbot_aim(this);
 112         lag_update(this);
 113
 114         if (this.bot_aimtarg)
 115         {
 116                 this.aistatus |= AI_STATUS_ATTACKING;
 117                 this.aistatus &= ~AI_STATUS_ROAMING;
 118
 119                 if(STAT(WEAPONS, this))
 120                 {
 121                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
 122                         {
 123                                 PHYS_INPUT_BUTTON_ATCK(this) = false;
 124                                 PHYS_INPUT_BUTTON_ATCK2(this) = false;
 125                         }
 126                         else
 127                         {
 128                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 129                                 {
 130                                         .entity weaponentity = weaponentities[slot];
 131                                         Weapon w = this.(weaponentity).m_weapon;
 132                                         if(w == WEP_Null && slot != 0)
 133                                                 continue;
 134                                         w.wr_aim(w, this, weaponentity);
 135                                         if(PHYS_INPUT_BUTTON_ATCK(this) || PHYS_INPUT_BUTTON_ATCK2(this)) // TODO: what if we didn't fire this weapon, but the previous?
 136                                                 this.(weaponentity).lastfiredweapon = this.(weaponentity).m_weapon.m_id;
 137                                 }
 138                         }
 139                 }
 140                 else
 141                 {
 142                         if(IS_PLAYER(this.bot_aimtarg))
 143                                 bot_aimdir(this, this.bot_aimtarg.origin + this.bot_aimtarg.view_ofs - this.origin - this.view_ofs, 0);
 144                 }
 145         }
 146         else if (this.goalcurrent)
 147         {
 148                 this.aistatus |= AI_STATUS_ROAMING;
 149                 this.aistatus &= ~AI_STATUS_ATTACKING;
 150         }
 151
 152         havocbot_movetogoal(this);
 153         if (!this.bot_aimdir_executed && this.goalcurrent)
 154         {
 155                 // Heading
 156                 vector dir = get_closer_dest(this.goalcurrent, this.origin);
 157                 dir -= this.origin + this.view_ofs;
 158                 dir.z = 0;
 159                 bot_aimdir(this, dir, 0);
 160         }
 161
 162         // if the bot is not attacking, consider reloading weapons
 163         if (!(this.aistatus & AI_STATUS_ATTACKING))
 164         {
 165                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 166                 {
 167                         .entity weaponentity = weaponentities[slot];
 168
 169                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 170                                 continue;
 171
 172                         // we are currently holding a weapon that's not fully loaded, reload it
 173                         if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 174                         if(this.(weaponentity).clip_load < this.(weaponentity).clip_size)
 175                                 CS(this).impulse = IMP_weapon_reload.impulse; // not sure if this is done right
 176
 177                         // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 178                         // the code above executes next frame, starting the reloading then
 179                         if(skill >= 5) // bots can only look for unloaded weapons past this skill
 180                         if(this.(weaponentity).clip_load >= 0) // only if we're not reloading a weapon already
 181                         {
 182                                 FOREACH(Weapons, it != WEP_Null, {
 183                                         if((STAT(WEAPONS, this) & (it.m_wepset)) && (it.spawnflags & WEP_FLAG_RELOADABLE) && (this.(weaponentity).weapon_load[it.m_id] < it.reloading_ammo))
 184                                         {
 185                                                 this.(weaponentity).m_switchweapon = it;
 186                                                 break;
 187                                         }
 188                                 });
 189                         }
 190                 }
 191         }
 192 }
 193
 194 void havocbot_keyboard_movement(entity this, vector destorg)
 195 {
 196         vector keyboard;
 197
 198         if (time > this.havocbot_keyboardtime)
 199         {
 200                 float sk = skill + this.bot_moveskill;
 201                 this.havocbot_keyboardtime =
 202                         max(
 203                                 this.havocbot_keyboardtime
 204                                         + 0.05 / max(1, sk + this.havocbot_keyboardskill)
 205                                         + random() * 0.025 / max(0.00025, skill + this.havocbot_keyboardskill)
 206                         , time);
 207                 keyboard = CS(this).movement / autocvar_sv_maxspeed;
 208
 209                 float trigger = autocvar_bot_ai_keyboard_threshold;
 210
 211                 // categorize forward movement
 212                 // at skill < 1.5 only forward
 213                 // at skill < 2.5 only individual directions
 214                 // at skill < 4.5 only individual directions, and forward diagonals
 215                 // at skill >= 4.5, all cases allowed
 216                 if (keyboard.x > trigger)
 217                 {
 218                         keyboard.x = 1;
 219                         if (sk < 2.5)
 220                                 keyboard.y = 0;
 221                 }
 222                 else if (keyboard.x < -trigger && sk > 1.5)
 223                 {
 224                         keyboard.x = -1;
 225                         if (sk < 4.5)
 226                                 keyboard.y = 0;
 227                 }
 228                 else
 229                 {
 230                         keyboard.x = 0;
 231                         if (sk < 1.5)
 232                                 keyboard.y = 0;
 233                 }
 234                 if (sk < 4.5)
 235                         keyboard.z = 0;
 236
 237                 if (keyboard.y > trigger)
 238                         keyboard.y = 1;
 239                 else if (keyboard.y < -trigger)
 240                         keyboard.y = -1;
 241                 else
 242                         keyboard.y = 0;
 243
 244                 if (keyboard.z > trigger)
 245                         keyboard.z = 1;
 246                 else if (keyboard.z < -trigger)
 247                         keyboard.z = -1;
 248                 else
 249                         keyboard.z = 0;
 250
 251                 // make sure bots don't get stuck if havocbot_keyboardtime is very high
 252                 if (keyboard == '0 0 0')
 253                         this.havocbot_keyboardtime = min(this.havocbot_keyboardtime, time + 0.2);
 254
 255                 this.havocbot_keyboard = keyboard * autocvar_sv_maxspeed;
 256                 if (this.havocbot_ducktime > time)
 257                         PHYS_INPUT_BUTTON_CROUCH(this) = true;
 258
 259                 keyboard = this.havocbot_keyboard;
 260                 float blend = bound(0, vlen(destorg - this.origin) / autocvar_bot_ai_keyboard_distance, 1); // When getting close move with 360 degree
 261                 //dprint("movement ", vtos(CS(this).movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 262                 CS(this).movement = CS(this).movement + (keyboard - CS(this).movement) * blend;
 263         }
 264 }
 265
 266 void havocbot_bunnyhop(entity this, vector dir)
 267 {
 268         float bunnyhopdistance;
 269         vector deviation;
 270         float maxspeed;
 271
 272         // Don't jump when attacking
 273         if(this.aistatus & AI_STATUS_ATTACKING)
 274                 return;
 275
 276         if(IS_PLAYER(this.goalcurrent))
 277                 return;
 278
 279         maxspeed = autocvar_sv_maxspeed;
 280
 281         if(this.aistatus & AI_STATUS_RUNNING && vdist(this.velocity, <, autocvar_sv_maxspeed * 0.75)
 282                 || this.aistatus & AI_STATUS_DANGER_AHEAD)
 283         {
 284                 this.aistatus &= ~AI_STATUS_RUNNING;
 285                 PHYS_INPUT_BUTTON_JUMP(this) = false;
 286                 this.bot_canruntogoal = 0;
 287                 this.bot_timelastseengoal = 0;
 288                 return;
 289         }
 290
 291         if(this.waterlevel > WATERLEVEL_WETFEET)
 292         {
 293                 this.aistatus &= ~AI_STATUS_RUNNING;
 294                 return;
 295         }
 296
 297         if(this.bot_lastseengoal != this.goalcurrent && !(this.aistatus & AI_STATUS_RUNNING))
 298         {
 299                 this.bot_canruntogoal = 0;
 300                 this.bot_timelastseengoal = 0;
 301         }
 302
 303         vector gco = get_closer_dest(this.goalcurrent, this.origin);
 304         bunnyhopdistance = vlen(this.origin - gco);
 305
 306         // Run only to visible goals
 307         if(IS_ONGROUND(this))
 308         if(vdist(vec2(this.velocity), >=, autocvar_sv_maxspeed)) // if -really- running
 309         if(checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 310         {
 311                         this.bot_lastseengoal = this.goalcurrent;
 312
 313                         // seen it before
 314                         if(this.bot_timelastseengoal)
 315                         {
 316                                 // for a period of time
 317                                 if(time - this.bot_timelastseengoal > autocvar_bot_ai_bunnyhop_firstjumpdelay)
 318                                 {
 319                                         float checkdistance;
 320                                         checkdistance = true;
 321
 322                                         // don't run if it is too close
 323                                         if(this.bot_canruntogoal==0)
 324                                         {
 325                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_startdistance)
 326                                                         this.bot_canruntogoal = 1;
 327                                                 else
 328                                                         this.bot_canruntogoal = -1;
 329                                         }
 330
 331                                         if(this.bot_canruntogoal != 1)
 332                                                 return;
 333
 334                                         if(this.aistatus & AI_STATUS_ROAMING)
 335                                         if(this.goalcurrent.classname=="waypoint")
 336                                         if (!(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL))
 337                                         if(fabs(gco.z - this.origin.z) < this.maxs.z - this.mins.z)
 338                                         if(this.goalstack01 && !wasfreed(this.goalstack01))
 339                                         {
 340                                                 vector gno = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
 341                                                 deviation = vectoangles(gno - this.origin) - vectoangles(gco - this.origin);
 342                                                 while (deviation.y < -180) deviation.y = deviation.y + 360;
 343                                                 while (deviation.y > 180) deviation.y = deviation.y - 360;
 344
 345                                                 if(fabs(deviation.y) < 20)
 346                                                 if(bunnyhopdistance < vlen(this.origin - gno))
 347                                                 if(fabs(gno.z - gco.z) < this.maxs.z - this.mins.z)
 348                                                 {
 349                                                         if(vdist(gco - gno, >, autocvar_bot_ai_bunnyhop_startdistance))
 350                                                         if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
 351                                                         {
 352                                                                 checkdistance = false;
 353                                                         }
 354                                                 }
 355                                         }
 356
 357                                         if(checkdistance)
 358                                         {
 359                                                 this.aistatus &= ~AI_STATUS_RUNNING;
 360                                                 // increase stop distance in case the goal is on a slope or a lower platform
 361                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_stopdistance + (this.origin.z - gco.z))
 362                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 363                                         }
 364                                         else
 365                                         {
 366                                                 this.aistatus |= AI_STATUS_RUNNING;
 367                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 368                                         }
 369                                 }
 370                         }
 371                         else
 372                         {
 373                                 this.bot_timelastseengoal = time;
 374                         }
 375         }
 376         else
 377         {
 378                 this.bot_timelastseengoal = 0;
 379         }
 380
 381 #if 0
 382         // Release jump button
 383         if(!cvar("sv_pogostick"))
 384         if((IS_ONGROUND(this)) == 0)
 385         {
 386                 if(this.velocity.z < 0 || vlen(this.velocity)<maxspeed)
 387                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 388
 389                 // Strafe
 390                 if(this.aistatus & AI_STATUS_RUNNING)
 391                 if(vlen(this.velocity)>maxspeed)
 392                 {
 393                         deviation = vectoangles(dir) - vectoangles(this.velocity);
 394                         while (deviation.y < -180) deviation.y = deviation.y + 360;
 395                         while (deviation.y > 180) deviation.y = deviation.y - 360;
 396
 397                         if(fabs(deviation.y)>10)
 398                                 CS(this).movement_x = 0;
 399
 400                         if(deviation.y>10)
 401                                 CS(this).movement_y = maxspeed * -1;
 402                         else if(deviation.y<10)
 403                                 CS(this).movement_y = maxspeed;
 404
 405                 }
 406         }
 407 #endif
 408 }
 409
 410 // return true when bot isn't getting closer to the current goal
 411 bool havocbot_checkgoaldistance(entity this, vector gco)
 412 {
 413         float curr_dist_z = max(20, fabs(this.origin.z - gco.z));
 414         float curr_dist_2d = max(20, vlen(vec2(this.origin - gco)));
 415         float distance_time = this.goalcurrent_distance_time;
 416         if(distance_time < 0)
 417                 distance_time = -distance_time;
 418         if(curr_dist_z >= this.goalcurrent_distance_z && curr_dist_2d >= this.goalcurrent_distance_2d)
 419         {
 420                 if(!distance_time)
 421                         this.goalcurrent_distance_time = time;
 422                 else if (time - distance_time > 0.5)
 423                         return true;
 424         }
 425         else
 426         {
 427                 // reduce it a little bit so it works even with very small approaches to the goal
 428                 this.goalcurrent_distance_z = max(20, curr_dist_z - 10);
 429                 this.goalcurrent_distance_2d = max(20, curr_dist_2d - 10);
 430                 this.goalcurrent_distance_time = 0;
 431         }
 432         return false;
 433 }
 434
 435 entity havocbot_select_an_item_of_group(entity this, int gr)
 436 {
 437         entity selected = NULL;
 438         float selected_dist2 = 0;
 439         // select farthest item of this group from bot's position
 440         IL_EACH(g_items, it.item_group == gr && it.solid,
 441         {
 442                 float dist2 = vlen2(this.origin - it.origin);
 443                 if (dist2 < 600 ** 2 && dist2 > selected_dist2)
 444                 {
 445                         selected = it;
 446                         selected_dist2 = vlen2(this.origin - selected.origin);
 447                 }
 448         });
 449
 450         if (!selected)
 451                 return NULL;
 452
 453         set_tracewalk_dest(selected, this.origin, false);
 454         if (!tracewalk(this, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this),
 455                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
 456         {
 457                 return NULL;
 458         }
 459
 460         return selected;
 461 }
 462
 463 void havocbot_movetogoal(entity this)
 464 {
 465         vector diff;
 466         vector dir;
 467         vector flatdir;
 468         vector evadeobstacle;
 469         vector evadelava;
 470         float dodge_enemy_factor = 1;
 471         float maxspeed;
 472         //float dist;
 473         vector dodge;
 474         //if (this.goalentity)
 475         //      te_lightning2(this, this.origin, (this.goalentity.absmin + this.goalentity.absmax) * 0.5);
 476         CS(this).movement = '0 0 0';
 477         maxspeed = autocvar_sv_maxspeed;
 478
 479         PHYS_INPUT_BUTTON_JETPACK(this) = false;
 480         // Jetpack navigation
 481         if(this.navigation_jetpack_goal)
 482         if(this.goalcurrent==this.navigation_jetpack_goal)
 483         if(GetResource(this, RES_FUEL))
 484         {
 485                 if(autocvar_bot_debug_goalstack)
 486                 {
 487                         debuggoalstack(this);
 488                         te_wizspike(this.navigation_jetpack_point);
 489                 }
 490
 491                 // Take off
 492                 if (!(this.aistatus & AI_STATUS_JETPACK_FLYING))
 493                 {
 494                         // Brake almost completely so it can get a good direction
 495                         if(vdist(this.velocity, >, 10))
 496                                 return;
 497                         this.aistatus |= AI_STATUS_JETPACK_FLYING;
 498                 }
 499
 500                 makevectors(this.v_angle.y * '0 1 0');
 501                 dir = normalize(this.navigation_jetpack_point - this.origin);
 502
 503                 // Landing
 504                 if(this.aistatus & AI_STATUS_JETPACK_LANDING)
 505                 {
 506                         // Calculate brake distance in xy
 507                         float d = vlen(vec2(this.origin - (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5));
 508                         float vel2 = vlen2(vec2(this.velocity));
 509                         float db = (vel2 / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 510                         //LOG_INFOF("distance %d, velocity %d, brake at %d ", ceil(d), ceil(v), ceil(db));
 511                         if(d < db || d < 500)
 512                         {
 513                                 // Brake
 514                                 if (vel2 > (maxspeed * 0.3) ** 2)
 515                                 {
 516                                         CS(this).movement_x = dir * v_forward * -maxspeed;
 517                                         return;
 518                                 }
 519                                 // Switch to normal mode
 520                                 this.navigation_jetpack_goal = NULL;
 521                                 this.aistatus &= ~AI_STATUS_JETPACK_LANDING;
 522                                 this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 523                                 return;
 524                         }
 525                 }
 526                 else if(checkpvs(this.origin,this.goalcurrent))
 527                 {
 528                         // If I can see the goal switch to landing code
 529                         this.aistatus &= ~AI_STATUS_JETPACK_FLYING;
 530                         this.aistatus |= AI_STATUS_JETPACK_LANDING;
 531                         return;
 532                 }
 533
 534                 // Flying
 535                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 536                 if(this.navigation_jetpack_point.z - STAT(PL_MAX, this).z + STAT(PL_MIN, this).z < this.origin.z)
 537                 {
 538                         CS(this).movement_x = dir * v_forward * maxspeed;
 539                         CS(this).movement_y = dir * v_right * maxspeed;
 540                 }
 541                 return;
 542         }
 543
 544         // Handling of jump pads
 545         if(this.jumppadcount)
 546         {
 547                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 548                 {
 549                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 550                         if(navigation_poptouchedgoals(this))
 551                                 return;
 552                 }
 553                 else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 554                 {
 555                         // If got stuck on the jump pad try to reach the farthest visible waypoint
 556                         // but with some randomness so it can try out different paths
 557                         if(!this.goalcurrent)
 558                         {
 559                                 entity newgoal = NULL;
 560                                 IL_EACH(g_waypoints, vdist(it.origin - this.origin, <=, 1000),
 561                                 {
 562                                         if(it.wpflags & WAYPOINTFLAG_TELEPORT)
 563                                         if(it.origin.z < this.origin.z - 100 && vdist(vec2(it.origin - this.origin), <, 100))
 564                                                 continue;
 565
 566                                         traceline(this.origin + this.view_ofs, ((it.absmin + it.absmax) * 0.5), true, this);
 567
 568                                         if(trace_fraction < 1)
 569                                                 continue;
 570
 571                                         if(!newgoal || ((random() < 0.8) && vlen2(it.origin - this.origin) > vlen2(newgoal.origin - this.origin)))
 572                                                 newgoal = it;
 573                                 });
 574
 575                                 if(newgoal)
 576                                 {
 577                                         this.ignoregoal = this.goalcurrent;
 578                                         this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 579                                         navigation_clearroute(this);
 580                                         navigation_routetogoal(this, newgoal, this.origin);
 581                                         if(autocvar_bot_debug_goalstack)
 582                                                 debuggoalstack(this);
 583                                         this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 584                                 }
 585                         }
 586                         else //if (this.goalcurrent)
 587                         {
 588                                 if (this.goalcurrent.bot_pickup)
 589                                 {
 590                                         entity jumppad_wp = this.goalcurrent_prev;
 591                                         navigation_poptouchedgoals(this);
 592                                         if(!this.goalcurrent && jumppad_wp.wp00)
 593                                         {
 594                                                 // head to the jumppad destination once bot reaches the goal item
 595                                                 navigation_pushroute(this, jumppad_wp.wp00);
 596                                         }
 597                                 }
 598                                 vector gco = (this.goalcurrent.absmin + this.goalcurrent.absmax) * 0.5;
 599                                 if (this.origin.z > gco.z && vdist(vec2(this.velocity), <, autocvar_sv_maxspeed))
 600                                 {
 601                                         if (this.velocity.z < 0)
 602                                                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 603                                 }
 604                                 else if(havocbot_checkgoaldistance(this, gco))
 605                                 {
 606                                         navigation_clearroute(this);
 607                                         navigation_goalrating_timeout_force(this);
 608                                 }
 609                                 else
 610                                         return;
 611                         }
 612                 }
 613                 else //if (!(this.aistatus & AI_STATUS_OUT_JUMPPAD))
 614                 {
 615                         if(this.velocity.z > 0 && this.origin.z - this.lastteleport_origin.z > (this.maxs.z - this.mins.z) * 0.5)
 616                         {
 617                                 vector velxy = this.velocity; velxy_z = 0;
 618                                 if(vdist(velxy, <, autocvar_sv_maxspeed * 0.2))
 619                                 {
 620                                         LOG_TRACE("Warning: ", this.netname, " got stuck on a jumppad (velocity in xy is ", vtos(velxy), "), trying to get out of it now");
 621                                         this.aistatus |= AI_STATUS_OUT_JUMPPAD;
 622                                 }
 623                                 return;
 624                         }
 625
 626                         // Don't chase players while using a jump pad
 627                         if(IS_PLAYER(this.goalcurrent) || IS_PLAYER(this.goalstack01))
 628                                 return;
 629                 }
 630         }
 631         else if(this.aistatus & AI_STATUS_OUT_JUMPPAD)
 632                 this.aistatus &= ~AI_STATUS_OUT_JUMPPAD;
 633
 634         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 635         if (skill > 6 && !(IS_ONGROUND(this)))
 636         {
 637                 #define ROCKETJUMP_DAMAGE() WEP_CVAR(devastator, damage) * 0.8 \
 638                         * ((this.strength_finished > time) ? autocvar_g_balance_powerup_strength_selfdamage : 1) \
 639                         * ((this.invincible_finished > time) ? autocvar_g_balance_powerup_invincible_takedamage : 1)
 640
 641                 tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 -65536', MOVE_NOMONSTERS, this);
 642                 if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos ))
 643                 if(this.items & IT_JETPACK)
 644                 {
 645                         tracebox(this.origin, this.mins, this.maxs, this.origin + '0 0 65536', MOVE_NOMONSTERS, this);
 646                         if(tracebox_hits_trigger_hurt(this.origin, this.mins, this.maxs, trace_endpos + '0 0 1' ))
 647                         {
 648                                 if(this.velocity.z<0)
 649                                         PHYS_INPUT_BUTTON_JETPACK(this) = true;
 650                         }
 651                         else
 652                                 PHYS_INPUT_BUTTON_JETPACK(this) = true;
 653
 654                         // If there is no goal try to move forward
 655
 656                         if(this.goalcurrent==NULL)
 657                                 dir = v_forward;
 658                         else
 659                                 dir = normalize(( ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5 ) - this.origin);
 660
 661                         vector xyvelocity = this.velocity; xyvelocity_z = 0;
 662                         float xyspeed = xyvelocity * dir;
 663
 664                         if(xyspeed < (maxspeed / 2))
 665                         {
 666                                 makevectors(this.v_angle.y * '0 1 0');
 667                                 tracebox(this.origin, this.mins, this.maxs, this.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, this);
 668                                 if(trace_fraction==1)
 669                                 {
 670                                         CS(this).movement_x = dir * v_forward * maxspeed;
 671                                         CS(this).movement_y = dir * v_right * maxspeed;
 672                                         if (skill < 10)
 673                                                 havocbot_keyboard_movement(this, this.origin + dir * 100);
 674                                 }
 675                         }
 676
 677                         this.havocbot_blockhead = true;
 678
 679                         return;
 680                 }
 681                 else if(!this.jumppadcount && !this.goalcurrent.wphardwired
 682                         && GetResource(this, RES_HEALTH) + GetResource(this, RES_ARMOR) > ROCKETJUMP_DAMAGE())
 683                 {
 684                         if(this.velocity.z < 0)
 685                         {
 686                                 for(int slot = 0; slot < MAX_WEAPONSLOTS; ++slot)
 687                                 {
 688                                         .entity weaponentity = weaponentities[slot];
 689
 690                                         if(this.(weaponentity).m_weapon == WEP_Null && slot != 0)
 691                                                 continue;
 692
 693                                         if(client_hasweapon(this, WEP_DEVASTATOR, weaponentity, true, false))
 694                                         {
 695                                                 CS(this).movement_x = maxspeed;
 696
 697                                                 if(this.rocketjumptime)
 698                                                 {
 699                                                         if(time > this.rocketjumptime)
 700                                                         {
 701                                                                 PHYS_INPUT_BUTTON_ATCK2(this) = true;
 702                                                                 this.rocketjumptime = 0;
 703                                                         }
 704                                                         return;
 705                                                 }
 706
 707                                                 this.(weaponentity).m_switchweapon = WEP_DEVASTATOR;
 708                                                 this.v_angle_x = 90;
 709                                                 PHYS_INPUT_BUTTON_ATCK(this) = true;
 710                                                 this.rocketjumptime = time + WEP_CVAR(devastator, detonatedelay);
 711                                                 return;
 712                                         }
 713                                 }
 714                         }
 715                 }
 716                 else
 717                 {
 718                         // If there is no goal try to move forward
 719                         if(this.goalcurrent==NULL)
 720                                 CS(this).movement_x = maxspeed;
 721                 }
 722         }
 723
 724         // If we are under water with no goals, swim up
 725         if(this.waterlevel && !this.goalcurrent)
 726         {
 727                 dir = '0 0 0';
 728                 if(this.waterlevel>WATERLEVEL_SWIMMING)
 729                         dir.z = 1;
 730                 else if(this.velocity.z >= 0 && !(this.waterlevel == WATERLEVEL_WETFEET && this.watertype == CONTENT_WATER))
 731                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 732                 else
 733                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 734                 makevectors(this.v_angle.y * '0 1 0');
 735                 vector v = dir * maxspeed;
 736                 CS(this).movement.x = v * v_forward;
 737                 CS(this).movement.y = v * v_right;
 738                 CS(this).movement.z = v * v_up;
 739         }
 740
 741         // if there is nowhere to go, exit
 742         if (this.goalcurrent == NULL)
 743                 return;
 744
 745
 746         bool locked_goal = false;
 747         if((this.goalentity && wasfreed(this.goalentity))
 748                 || (this.goalcurrent == this.goalentity && this.goalentity.tag_entity))
 749         {
 750                 navigation_clearroute(this);
 751                 navigation_goalrating_timeout_force(this);
 752                 return;
 753         }
 754         else if(this.goalentity.tag_entity)
 755         {
 756                 navigation_goalrating_timeout_expire(this, 2);
 757         }
 758         else if(this.goalentity.bot_pickup)
 759         {
 760                 if(this.goalentity.bot_pickup_respawning)
 761                 {
 762                         if(this.goalentity.solid) // item respawned
 763                                 this.goalentity.bot_pickup_respawning = false;
 764                         else if(time < this.goalentity.scheduledrespawntime - 10) // item already taken (by someone else)
 765                         {
 766                                 if(checkpvs(this.origin, this.goalentity))
 767                                 {
 768                                         this.goalentity.bot_pickup_respawning = false;
 769                                         navigation_goalrating_timeout_expire(this, random());
 770                                 }
 771                                 locked_goal = true; // wait for item to respawn
 772                         }
 773                         else if(this.goalentity == this.goalcurrent)
 774                                 locked_goal = true; // wait for item to respawn
 775                 }
 776                 else if(!this.goalentity.solid && !boxesoverlap(this.goalentity.absmin, this.goalentity.absmax, this.absmin, this.absmax))
 777                 {
 778                         if(checkpvs(this.origin, this.goalentity))
 779                         {
 780                                 navigation_goalrating_timeout_expire(this, random());
 781                         }
 782                 }
 783         }
 784         if (this.goalcurrent == this.goalentity && this.goalentity_lock_timeout > time)
 785                 locked_goal = true;
 786
 787         if (navigation_shortenpath(this))
 788         {
 789                 if (vdist(this.origin - this.goalcurrent_prev.origin, <, 50)
 790                         && navigation_goalrating_timeout_can_be_anticipated(this))
 791                 {
 792                         navigation_goalrating_timeout_force(this);
 793                 }
 794         }
 795
 796         bool goalcurrent_can_be_removed = false;
 797         if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 798         {
 799                 bool freeze_state_changed = (boolean(STAT(FROZEN, this.goalentity)) != this.goalentity_shouldbefrozen);
 800                 if (IS_DEAD(this.goalcurrent) || (this.goalentity == this.goalcurrent && freeze_state_changed))
 801                 {
 802                         goalcurrent_can_be_removed = true;
 803                         // don't remove if not visible
 804                         if (checkpvs(this.origin + this.view_ofs, this.goalcurrent))
 805                         {
 806                                 if (IS_DEAD(this.goalcurrent))
 807                                 {
 808                                         IL_EACH(g_items, it.enemy == this.goalcurrent && Item_IsLoot(it),
 809                                         {
 810                                                 if (vdist(it.origin - this.goalcurrent.death_origin, <, 50))
 811                                                 {
 812                                                         navigation_clearroute(this);
 813                                                         navigation_pushroute(this, it);
 814                                                         // loot can't be immediately rated since it isn't on ground yet
 815                                                         // it will be rated after a second when on ground, meanwhile head to it
 816                                                         navigation_goalrating_timeout_expire(this, 1);
 817                                                         return;
 818                                                 }
 819                                         });
 820                                 }
 821                                 if (!Item_IsLoot(this.goalcurrent))
 822                                 {
 823                                         navigation_goalrating_timeout_force(this);
 824                                         return;
 825                                 }
 826                         }
 827                 }
 828                 else if (!(STAT(FROZEN, this.goalentity)) && this.bot_tracewalk_time < time)
 829                 {
 830                         set_tracewalk_dest(this.goalcurrent, this.origin, true);
 831                         if (!(trace_ent == this || tracewalk(this, this.origin, this.mins, this.maxs,
 832                                 tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode)))
 833                         {
 834                                 navigation_goalrating_timeout_force(this);
 835                                 return;
 836                         }
 837                         this.bot_tracewalk_time = max(time, this.bot_tracewalk_time) + 0.25;
 838                 }
 839         }
 840
 841         if(!locked_goal)
 842         {
 843                 // optimize path finding by anticipating goalrating when bot is near a waypoint;
 844                 // in this case path finding can start directly from a waypoint instead of
 845                 // looking for all the reachable waypoints up to a certain distance
 846                 if (navigation_poptouchedgoals(this))
 847                 {
 848                         if (this.goalcurrent)
 849                         {
 850                                 if (goalcurrent_can_be_removed)
 851                                 {
 852                                         // remove even if not visible
 853                                         navigation_goalrating_timeout_force(this);
 854                                         return;
 855                                 }
 856                                 else if (navigation_goalrating_timeout_can_be_anticipated(this))
 857                                         navigation_goalrating_timeout_force(this);
 858                         }
 859                         else
 860                         {
 861                                 entity old_goal = this.goalcurrent_prev;
 862                                 if (old_goal.item_group && this.item_group != old_goal.item_group)
 863                                 {
 864                                         // Avoid multiple costly calls of path finding code that selects one of the closest
 865                                         // item of the group by telling the bot to head directly to the farthest item.
 866                                         // Next time we let the bot select a goal as usual which can be another item
 867                                         // of this group (the closest one) and so on
 868                                         this.item_group = old_goal.item_group;
 869                                         entity new_goal = havocbot_select_an_item_of_group(this, old_goal.item_group);
 870                                         if (new_goal)
 871                                                 navigation_pushroute(this, new_goal);
 872                                 }
 873                         }
 874                 }
 875         }
 876
 877         // if ran out of goals try to use an alternative goal or get a new strategy asap
 878         if(this.goalcurrent == NULL)
 879         {
 880                 navigation_goalrating_timeout_force(this);
 881                 return;
 882         }
 883
 884
 885         if(autocvar_bot_debug_goalstack)
 886                 debuggoalstack(this);
 887
 888         bool bunnyhop_forbidden = false;
 889         vector destorg = get_closer_dest(this.goalcurrent, this.origin);
 890         if (this.jumppadcount && this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 891         {
 892                 // if bot used the jumppad, push towards jumppad origin until jumppad waypoint gets removed
 893                 destorg = this.goalcurrent.origin;
 894         }
 895         else if (this.goalcurrent.wpisbox)
 896         {
 897                 // if bot is inside the teleport waypoint, head to teleport origin until teleport gets used
 898                 // do it even if bot is on a ledge above a teleport/jumppad so it doesn't get stuck
 899                 if (boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin + eZ * this.mins.z, this.origin + eZ * this.maxs.z)
 900                         || (this.absmin.z > destorg.z && destorg.x == this.origin.x && destorg.y == this.origin.y))
 901                 {
 902                         bunnyhop_forbidden = true;
 903                         destorg = this.goalcurrent.origin;
 904                         if(destorg.z > this.origin.z)
 905                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
 906                 }
 907         }
 908
 909         diff = destorg - this.origin;
 910
 911         if (time < this.bot_stop_moving_timeout
 912                 || (this.goalcurrent == this.goalentity && time < this.goalentity_lock_timeout && vdist(diff, <, 10)))
 913         {
 914                 // stop if the locked goal has been reached
 915                 destorg = this.origin;
 916                 diff = dir = '0 0 0';
 917         }
 918         else if (IS_PLAYER(this.goalcurrent) || IS_MONSTER(this.goalcurrent))
 919         {
 920                 if (vdist(diff, <, 80))
 921                 {
 922                         // stop if too close to target player (even if frozen)
 923                         destorg = this.origin;
 924                         diff = dir = '0 0 0';
 925                 }
 926                 else
 927                 {
 928                         // move destorg out of target players, otherwise bot will consider them
 929                         // an obstacle that needs to be jumped (especially if frozen)
 930                         dir = normalize(diff);
 931                         destorg -= dir * PL_MAX_CONST.x * M_SQRT2;
 932                         diff = destorg - this.origin;
 933                 }
 934         }
 935         else
 936                 dir = normalize(diff);
 937         flatdir = (diff.z == 0) ? dir : normalize(vec2(diff));
 938
 939         //if (this.bot_dodgevector_time < time)
 940         {
 941                 //this.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 942                 //this.bot_dodgevector_jumpbutton = 1;
 943                 evadeobstacle = '0 0 0';
 944                 evadelava = '0 0 0';
 945
 946                 this.aistatus &= ~AI_STATUS_DANGER_AHEAD;
 947                 makevectors(this.v_angle.y * '0 1 0');
 948                 if (this.waterlevel > WATERLEVEL_WETFEET)
 949                 {
 950                         if (this.waterlevel > WATERLEVEL_SWIMMING)
 951                         {
 952                                 if(!this.goalcurrent)
 953                                         this.aistatus |= AI_STATUS_OUT_WATER;
 954                                 else if(destorg.z > this.origin.z)
 955                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 956                         }
 957                         else
 958                         {
 959                                 if(this.velocity.z >= 0 && !(this.watertype == CONTENT_WATER && destorg.z < this.origin.z) &&
 960                                         (this.aistatus & AI_STATUS_OUT_WATER))
 961                                 {
 962                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
 963                                         dir = flatdir;
 964                                 }
 965                                 else
 966                                 {
 967                                         PHYS_INPUT_BUTTON_JUMP(this) = false;
 968                                         if (destorg.z > this.origin.z)
 969                                                 dir = flatdir;
 970                                 }
 971                         }
 972                 }
 973                 else
 974                 {
 975                         float s;
 976                         vector offset;
 977                         if(this.aistatus & AI_STATUS_OUT_WATER)
 978                                 this.aistatus &= ~AI_STATUS_OUT_WATER;
 979
 980                         // jump if going toward an obstacle that doesn't look like stairs we
 981                         // can walk up directly
 982                         vector deviation = '0 0 0';
 983                         float current_speed = vlen(vec2(this.velocity));
 984                         if (current_speed < maxspeed * 0.2)
 985                                 current_speed = maxspeed * 0.2;
 986                         else
 987                         {
 988                                 deviation = vectoangles(diff) - vectoangles(this.velocity);
 989                                 while (deviation.y < -180) deviation.y += 360;
 990                                 while (deviation.y > 180) deviation.y -= 360;
 991                         }
 992                         float turning = false;
 993                         vector flat_diff = vec2(diff);
 994                         offset = max(32, current_speed * cos(deviation.y * DEG2RAD) * 0.3) * flatdir;
 995                         vector actual_destorg = this.origin + offset;
 996                         if (!this.goalstack01 || this.goalcurrent.wpflags & (WAYPOINTFLAG_TELEPORT | WAYPOINTFLAG_LADDER))
 997                         {
 998                                 if (vlen2(flat_diff) < vlen2(offset))
 999                                 {
1000                                         if (this.goalcurrent.wpflags & WAYPOINTFLAG_JUMP && this.goalstack01)
1001                                         {
1002                                                 // oblique warpzones need a jump otherwise bots gets stuck
1003                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1004                                         }
1005                                         else
1006                                         {
1007                                                 actual_destorg.x = destorg.x;
1008                                                 actual_destorg.y = destorg.y;
1009                                         }
1010                                 }
1011                         }
1012                         else if (vdist(flat_diff, <, 32) && diff.z < -16) // destination is under the bot
1013                         {
1014                                 actual_destorg.x = destorg.x;
1015                                 actual_destorg.y = destorg.y;
1016                         }
1017                         else if (vlen2(flat_diff) < vlen2(offset))
1018                         {
1019                                 vector next_goal_org = (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5;
1020                                 vector next_dir = normalize(vec2(next_goal_org - destorg));
1021                                 float dist = vlen(vec2(this.origin + offset - destorg));
1022                                 // if current and next goal are close to each other make sure
1023                                 // actual_destorg isn't set beyond next_goal_org
1024                                 if (dist ** 2 > vlen2(vec2(next_goal_org - destorg)))
1025                                         actual_destorg = next_goal_org;
1026                                 else
1027                                         actual_destorg = vec2(destorg) + dist * next_dir;
1028                                 actual_destorg.z = this.origin.z;
1029                                 turning = true;
1030                         }
1031
1032                         LABEL(jump_check);
1033                         dir = flatdir = normalize(actual_destorg - this.origin);
1034
1035                         if (turning || fabs(deviation.y) < 50) // don't even try to jump if deviation is too high
1036                         {
1037                                 tracebox(this.origin, this.mins, this.maxs, actual_destorg, false, this);
1038                                 if (trace_fraction < 1 && trace_plane_normal.z < 0.7)
1039                                 {
1040                                         s = trace_fraction;
1041                                         tracebox(this.origin + stepheightvec, this.mins, this.maxs, actual_destorg + stepheightvec, false, this);
1042                                         if (trace_fraction < s + 0.01 && trace_plane_normal.z < 0.7)
1043                                         {
1044                                                 // found an obstacle
1045                                                 if (turning && fabs(deviation.y) > 5)
1046                                                 {
1047                                                         // check if the obstacle is still there without turning
1048                                                         actual_destorg = destorg;
1049                                                         turning = false;
1050                                                         this.bot_tracewalk_time = time + 0.25;
1051                                                         goto jump_check;
1052                                                 }
1053                                                 s = trace_fraction;
1054                                                 // don't artificially reduce max jump height in real-time
1055                                                 // (jumpstepheightvec is reduced a bit to make the jumps easy in tracewalk)
1056                                                 vector jump_height = (IS_ONGROUND(this)) ? stepheightvec + jumpheight_vec : jumpstepheightvec;
1057                                                 tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1058                                                 if (trace_fraction > s)
1059                                                         PHYS_INPUT_BUTTON_JUMP(this) = true;
1060                                                 else
1061                                                 {
1062                                                         jump_height = stepheightvec + jumpheight_vec / 2;
1063                                                         tracebox(this.origin + jump_height, this.mins, this.maxs, actual_destorg + jump_height, false, this);
1064                                                         if (trace_fraction > s)
1065                                                                 PHYS_INPUT_BUTTON_JUMP(this) = true;
1066                                                 }
1067                                         }
1068                                 }
1069                         }
1070
1071                         // if bot for some reason doesn't get close to the current goal find another one
1072                         if(!this.jumppadcount && !IS_PLAYER(this.goalcurrent))
1073                         if(!(locked_goal && this.goalcurrent_distance_z < 50 && this.goalcurrent_distance_2d < 50))
1074                         if(havocbot_checkgoaldistance(this, destorg))
1075                         {
1076                                 if(this.goalcurrent_distance_time < 0) // can't get close for the second time
1077                                 {
1078                                         navigation_clearroute(this);
1079                                         navigation_goalrating_timeout_force(this);
1080                                         return;
1081                                 }
1082
1083                                 set_tracewalk_dest(this.goalcurrent, this.origin, false);
1084                                 if (!tracewalk(this, this.origin, this.mins, this.maxs,
1085                                         tracewalk_dest, tracewalk_dest_height, bot_navigation_movemode))
1086                                 {
1087                                         navigation_clearroute(this);
1088                                         navigation_goalrating_timeout_force(this);
1089                                         return;
1090                                 }
1091
1092                                 // give bot only another chance to prevent bot getting stuck
1093                                 // in case it thinks it can walk but actually can't
1094                                 this.goalcurrent_distance_z = FLOAT_MAX;
1095                                 this.goalcurrent_distance_2d = FLOAT_MAX;
1096                                 this.goalcurrent_distance_time = -time; // mark second try
1097                         }
1098
1099                         // Check for water/slime/lava and dangerous edges
1100                         // (only when the bot is on the ground or jumping intentionally)
1101
1102                         if (skill + this.bot_moveskill <= 3 && time > this.bot_stop_moving_timeout
1103                                 && current_speed > maxspeed * 0.9 && fabs(deviation.y) > 70)
1104                         {
1105                                 this.bot_stop_moving_timeout = time + 0.4 + random() * 0.2;
1106                         }
1107
1108                         offset = (vdist(this.velocity, >, 32) ? this.velocity * 0.2 : flatdir * 32);
1109                         vector dst_ahead = this.origin + this.view_ofs + offset;
1110                         vector dst_down = dst_ahead - '0 0 3000';
1111                         traceline(this.origin + this.view_ofs, dst_ahead, true, NULL);
1112
1113                         bool unreachable = false;
1114                         s = CONTENT_SOLID;
1115                         if(trace_fraction == 1 && this.jumppadcount == 0 && !this.goalcurrent.wphardwired )
1116                         if((IS_ONGROUND(this)) || (this.aistatus & AI_STATUS_RUNNING) || (this.aistatus & AI_STATUS_ROAMING) || PHYS_INPUT_BUTTON_JUMP(this))
1117                         {
1118                                 // Look downwards
1119                                 traceline(dst_ahead , dst_down, true, NULL);
1120                                 //te_lightning2(NULL, this.origin + this.view_ofs, dst_ahead); // Draw "ahead" look
1121                                 //te_lightning2(NULL, dst_ahead, trace_endpos); // Draw "downwards" look
1122                                 if(trace_endpos.z < this.origin.z + this.mins.z)
1123                                 {
1124                                         s = pointcontents(trace_endpos + '0 0 1');
1125                                         if (s != CONTENT_SOLID)
1126                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
1127                                                 evadelava = normalize(this.velocity) * -1;
1128                                         else if (s == CONTENT_SKY)
1129                                                 evadeobstacle = normalize(this.velocity) * -1;
1130                                         else if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1131                                         {
1132                                                 // the traceline check isn't enough but is good as optimization,
1133                                                 // when not true (most of the time) this tracebox call is avoided
1134                                                 tracebox(dst_ahead, this.mins, this.maxs, dst_down, true, this);
1135                                                 if (tracebox_hits_trigger_hurt(dst_ahead, this.mins, this.maxs, trace_endpos))
1136                                                 {
1137                                                         if (destorg.z > this.origin.z + jumpstepheightvec.z)
1138                                                         {
1139                                                                 // the goal is probably on an upper platform, assume bot can't get there
1140                                                                 unreachable = true;
1141                                                         }
1142                                                         else
1143                                                                 evadelava = normalize(this.velocity) * -1;
1144                                                 }
1145                                         }
1146                                 }
1147                         }
1148
1149                         dir = flatdir;
1150                         evadeobstacle.z = 0;
1151                         evadelava.z = 0;
1152                         makevectors(this.v_angle.y * '0 1 0');
1153
1154                         if(evadeobstacle || evadelava || (s == CONTENT_WATER))
1155                         {
1156                                 this.aistatus |= AI_STATUS_DANGER_AHEAD;
1157                                 if(IS_PLAYER(this.goalcurrent))
1158                                         unreachable = true;
1159                         }
1160
1161                         // slow down if bot is in the air and goal is under it
1162                         if (!this.goalcurrent.wphardwired
1163                                 && vdist(flat_diff, <, 250) && this.origin.z - destorg.z > 120
1164                                 && (!IS_ONGROUND(this) || vdist(vec2(this.velocity), >, maxspeed * 0.3)))
1165                         {
1166                                 // tracebox wouldn't work when bot is still on the ledge
1167                                 traceline(this.origin, this.origin - '0 0 200', true, this);
1168                                 if (this.origin.z - trace_endpos.z > 120)
1169                                         evadeobstacle = normalize(this.velocity) * -1;
1170                         }
1171
1172                         if(unreachable)
1173                         {
1174                                 navigation_clearroute(this);
1175                                 navigation_goalrating_timeout_force(this);
1176                                 this.ignoregoal = this.goalcurrent;
1177                                 this.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
1178                         }
1179                 }
1180
1181                 dodge = havocbot_dodge(this);
1182                 if (dodge)
1183                         dodge *= bound(0, 0.5 + (skill + this.bot_dodgeskill) * 0.1, 1);
1184                 dodge += evadeobstacle + evadelava;
1185                 evadelava = evadelava * bound(1,3-(skill+this.bot_dodgeskill),3); //Noobs fear lava a lot and take more distance from it
1186                 if (this.enemy)
1187                 {
1188                         traceline(this.origin, (this.enemy.absmin + this.enemy.absmax) * 0.5, true, NULL);
1189                         if (IS_PLAYER(trace_ent))
1190                                 dodge_enemy_factor = bound(0, (skill + this.bot_dodgeskill) / 7, 1);
1191                 }
1192         //      this.bot_dodgevector = dir;
1193         //      this.bot_dodgevector_jumpbutton = PHYS_INPUT_BUTTON_JUMP(this);
1194         }
1195
1196         float ladder_zdir = 0;
1197         if(time < this.ladder_time)
1198         {
1199                 if(this.goalcurrent.origin.z + this.goalcurrent.mins.z > this.origin.z + this.mins.z)
1200                 {
1201                         if(this.origin.z + this.mins.z  < this.ladder_entity.origin.z + this.ladder_entity.maxs.z)
1202                                 ladder_zdir = 1;
1203                 }
1204                 else
1205                 {
1206                         if(this.origin.z + this.mins.z  > this.ladder_entity.origin.z + this.ladder_entity.mins.z)
1207                                 ladder_zdir = -1;
1208                 }
1209                 if (ladder_zdir)
1210                 {
1211                         if (vdist(vec2(diff), <, 40))
1212                                 dir.z = ladder_zdir * 4;
1213                         else
1214                                 dir.z = ladder_zdir * 2;
1215                         dir = normalize(dir);
1216                 }
1217         }
1218
1219         if (this.goalcurrent.wpisbox
1220                 && boxesoverlap(this.goalcurrent.absmin, this.goalcurrent.absmax, this.origin, this.origin))
1221         {
1222                 // bot is inside teleport waypoint but hasn't touched the real teleport yet
1223                 // head to teleport origin
1224                 dir = (this.goalcurrent.origin - this.origin);
1225                 dir.z = 0;
1226                 dir = normalize(dir);
1227         }
1228
1229         // already executed when bot targets an enemy
1230         if (!this.bot_aimdir_executed)
1231         {
1232                 if (time < this.bot_stop_moving_timeout)
1233                         bot_aimdir(this, normalize(this.goalcurrent.origin - this.origin), 0);
1234                 else
1235                         bot_aimdir(this, dir, 0);
1236         }
1237
1238         if (!ladder_zdir)
1239         {
1240                 dir *= dodge_enemy_factor;
1241                 dir = normalize(dir + dodge);
1242         }
1243
1244         makevectors(this.v_angle);
1245         //dir = this.bot_dodgevector;
1246         //if (this.bot_dodgevector_jumpbutton)
1247         //      PHYS_INPUT_BUTTON_JUMP(this) = true;
1248         CS(this).movement_x = dir * v_forward * maxspeed;
1249         CS(this).movement_y = dir * v_right * maxspeed;
1250         CS(this).movement_z = dir * v_up * maxspeed;
1251
1252         // Emulate keyboard interface
1253         if (skill < 10)
1254                 havocbot_keyboard_movement(this, destorg);
1255
1256         // Bunnyhop!
1257         //if(this.aistatus & AI_STATUS_ROAMING)
1258         if(!bunnyhop_forbidden && this.goalcurrent)
1259         if(skill+this.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
1260                 havocbot_bunnyhop(this, dir);
1261
1262         if ((dir * v_up) >= autocvar_sv_jumpvelocity*0.5 && (IS_ONGROUND(this))) PHYS_INPUT_BUTTON_JUMP(this) = true;
1263         if (((dodge * v_up) > 0) && random()*frametime >= 0.2*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) PHYS_INPUT_BUTTON_JUMP(this) = true;
1264         if (((dodge * v_up) < 0) && random()*frametime >= 0.5*bound(0,(10-skill-this.bot_dodgeskill)*0.1,1)) this.havocbot_ducktime=time+0.3/bound(0.1,skill+this.bot_dodgeskill,10);
1265 }
1266
1267 entity havocbot_gettarget(entity this, bool secondary)
1268 {
1269         entity best = NULL;
1270         vector eye = CENTER_OR_VIEWOFS(this);
1271         IL_EACH(g_bot_targets, boolean((secondary) ? it.classname == "misc_breakablemodel" : it.classname != "misc_breakablemodel"),
1272         {
1273                 vector v = CENTER_OR_VIEWOFS(it);
1274                 if(vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1275                 if(!best || vlen2(CENTER_OR_VIEWOFS(best) - eye) > vlen2(v - eye))
1276                 if(bot_shouldattack(this, it))
1277                 {
1278                         traceline(eye, v, true, this);
1279                         if (trace_ent == it || trace_fraction >= 1)
1280                                 best = it;
1281                 }
1282         });
1283
1284         return best;
1285 }
1286
1287 void havocbot_chooseenemy(entity this)
1288 {
1289         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(this))
1290         {
1291                 this.enemy = NULL;
1292                 return;
1293         }
1294         if (this.enemy)
1295         {
1296                 if (!bot_shouldattack(this, this.enemy))
1297                 {
1298                         // enemy died or something, find a new target
1299                         this.enemy = NULL;
1300                         this.havocbot_chooseenemy_finished = time;
1301                 }
1302                 else if (this.havocbot_stickenemy)
1303                 {
1304                         // tracking last chosen enemy
1305                         // if enemy is visible
1306                         // and not really really far away
1307                         // and we're not severely injured
1308                         // then keep tracking for a half second into the future
1309                         traceline(this.origin+this.view_ofs, ( this.enemy.absmin + this.enemy.absmax ) * 0.5,false,NULL);
1310                         if (trace_ent == this.enemy || trace_fraction == 1)
1311                         if (vdist(((this.enemy.absmin + this.enemy.absmax) * 0.5) - this.origin, <, 1000))
1312                         if (GetResource(this, RES_HEALTH) > 30)
1313                         {
1314                                 // remain tracking him for a shot while (case he went after a small corner or pilar
1315                                 this.havocbot_chooseenemy_finished = time + 0.5;
1316                                 return;
1317                         }
1318                         // enemy isn't visible, or is far away, or we're injured severely
1319                         // so stop preferring this enemy
1320                         // (it will still take a half second until a new one is chosen)
1321                         this.havocbot_stickenemy = 0;
1322                 }
1323         }
1324         if (time < this.havocbot_chooseenemy_finished)
1325                 return;
1326         this.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
1327         vector eye = this.origin + this.view_ofs;
1328         entity best = NULL;
1329         float bestrating = 100000000;
1330
1331         // Backup hit flags
1332         int hf = this.dphitcontentsmask;
1333
1334         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
1335
1336         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_CORPSE;
1337
1338         bool scan_transparent = false;
1339         bool scan_secondary_targets = false;
1340         bool have_secondary_targets = false;
1341         while(true)
1342         {
1343                 scan_secondary_targets = false;
1344 LABEL(scan_targets)
1345                 IL_EACH(g_bot_targets, it.bot_attack,
1346                 {
1347                         if(!scan_secondary_targets)
1348                         {
1349                                 if(it.classname == "misc_breakablemodel")
1350                                 {
1351                                         have_secondary_targets = true;
1352                                         continue;
1353                                 }
1354                         }
1355                         else if(it.classname != "misc_breakablemodel")
1356                                 continue;
1357
1358                         vector v = (it.absmin + it.absmax) * 0.5;
1359                         float rating = vlen2(v - eye);
1360                         if (vdist(v - eye, <, autocvar_bot_ai_enemydetectionradius))
1361                         if (bestrating > rating)
1362                         if (bot_shouldattack(this, it))
1363                         {
1364                                 traceline(eye, v, true, this);
1365                                 if (trace_ent == it || trace_fraction >= 1)
1366                                 {
1367                                         best = it;
1368                                         bestrating = rating;
1369                                 }
1370                         }
1371                 });
1372
1373                 if(!best && have_secondary_targets && !scan_secondary_targets)
1374                 {
1375                         scan_secondary_targets = true;
1376                         // restart the loop
1377                         bestrating = 100000000;
1378                         goto scan_targets;
1379                 }
1380
1381                 // I want to do a second scan if no enemy was found or I don't have weapons
1382                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
1383                 if(best || STAT(WEAPONS, this)) // || this.weapon == WEP_RIFLE.m_id
1384                         break;
1385                 if(scan_transparent)
1386                         break;
1387
1388                 // Set flags to see through transparent objects
1389                 this.dphitcontentsmask |= DPCONTENTS_OPAQUE;
1390
1391                 scan_transparent = true;
1392         }
1393
1394         // Restore hit flags
1395         this.dphitcontentsmask = hf;
1396
1397         this.enemy = best;
1398         this.havocbot_stickenemy = true;
1399         if(best && best.classname == "misc_breakablemodel")
1400                 this.havocbot_stickenemy = false;
1401 }
1402
1403 float havocbot_chooseweapon_checkreload(entity this, .entity weaponentity, int new_weapon)
1404 {
1405         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
1406         // so skip this for them, or they'll never get to reload their weapons at all.
1407         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
1408         if(skill < 5)
1409                 return false;
1410
1411         // if this weapon is scheduled for reloading, don't switch to it during combat
1412         if (this.(weaponentity).weapon_load[new_weapon] < 0)
1413         {
1414                 FOREACH(Weapons, it != WEP_Null, {
1415                         if(it.wr_checkammo1(it, this, weaponentity) + it.wr_checkammo2(it, this, weaponentity))
1416                                 return true; // other weapon available
1417                 });
1418         }
1419
1420         return false;
1421 }
1422
1423 void havocbot_chooseweapon(entity this, .entity weaponentity)
1424 {
1425         int i;
1426
1427         // ;)
1428         if(g_weaponarena_weapons == WEPSET(TUBA))
1429         {
1430                 this.(weaponentity).m_switchweapon = WEP_TUBA;
1431                 return;
1432         }
1433
1434         // TODO: clean this up by moving it to weapon code
1435         if(this.enemy==NULL)
1436         {
1437                 // If no weapon was chosen get the first available weapon
1438                 if(this.(weaponentity).m_weapon==WEP_Null)
1439                 FOREACH(Weapons, it != WEP_Null, {
1440                         if(client_hasweapon(this, it, weaponentity, true, false))
1441                         {
1442                                 this.(weaponentity).m_switchweapon = it;
1443                                 return;
1444                         }
1445                 });
1446                 return;
1447         }
1448
1449         // Do not change weapon during the next second after a combo
1450         float f = time - this.lastcombotime;
1451         if(f < 1)
1452                 return;
1453
1454         float w;
1455         float distance; distance=bound(10,vlen(this.origin-this.enemy.origin)-200,10000);
1456
1457         // Should it do a weapon combo?
1458         float af, ct, combo_time, combo;
1459
1460         af = ATTACK_FINISHED(this, weaponentity);
1461         ct = autocvar_bot_ai_weapon_combo_threshold;
1462
1463         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1464         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1465         combo_time = time + ct + (ct * ((-0.3*(skill+this.bot_weaponskill))+3));
1466
1467         combo = false;
1468
1469         if(autocvar_bot_ai_weapon_combo)
1470         if(this.(weaponentity).m_weapon.m_id == this.(weaponentity).lastfiredweapon)
1471         if(af > combo_time)
1472         {
1473                 combo = true;
1474                 this.lastcombotime = time;
1475         }
1476
1477         distance *= (2 ** this.bot_rangepreference);
1478
1479         // Custom weapon list based on distance to the enemy
1480         if(bot_custom_weapon){
1481
1482                 // Choose weapons for far distance
1483                 if ( distance > bot_distance_far ) {
1484                         for(i=0; i < Weapons_COUNT && bot_weapons_far[i] != -1 ; ++i){
1485                                 w = bot_weapons_far[i];
1486                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1487                                 {
1488                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1489                                                 continue;
1490                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1491                                         return;
1492                                 }
1493                         }
1494                 }
1495
1496                 // Choose weapons for mid distance
1497                 if ( distance > bot_distance_close) {
1498                         for(i=0; i < Weapons_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1499                                 w = bot_weapons_mid[i];
1500                                 if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1501                                 {
1502                                         if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1503                                                 continue;
1504                                         this.(weaponentity).m_switchweapon = Weapons_from(w);
1505                                         return;
1506                                 }
1507                         }
1508                 }
1509
1510                 // Choose weapons for close distance
1511                 for(i=0; i < Weapons_COUNT && bot_weapons_close[i] != -1 ; ++i){
1512                         w = bot_weapons_close[i];
1513                         if ( client_hasweapon(this, Weapons_from(w), weaponentity, true, false) )
1514                         {
1515                                 if ((this.(weaponentity).m_weapon.m_id == w && combo) || havocbot_chooseweapon_checkreload(this, weaponentity, w))
1516                                         continue;
1517                                 this.(weaponentity).m_switchweapon = Weapons_from(w);
1518                                 return;
1519                         }
1520                 }
1521         }
1522 }
1523
1524 void havocbot_aim(entity this)
1525 {
1526         if (time < this.nextaim)
1527                 return;
1528         this.nextaim = time + 0.1;
1529         vector myvel = this.velocity;
1530         if (!this.waterlevel)
1531                 myvel.z = 0;
1532         if(MUTATOR_CALLHOOK(HavocBot_Aim, this)) { /* do nothing */ }
1533         else if (this.enemy)
1534         {
1535                 vector enemyvel = this.enemy.velocity;
1536                 if (!this.enemy.waterlevel)
1537                         enemyvel.z = 0;
1538                 lag_additem(this, time + CS(this).ping, 0, 0, this.enemy, this.origin, myvel, (this.enemy.absmin + this.enemy.absmax) * 0.5, enemyvel);
1539         }
1540         else
1541                 lag_additem(this, time + CS(this).ping, 0, 0, NULL, this.origin, myvel, ( this.goalcurrent.absmin + this.goalcurrent.absmax ) * 0.5, '0 0 0');
1542 }
1543
1544 bool havocbot_moveto_refresh_route(entity this)
1545 {
1546         // Refresh path to goal if necessary
1547         entity wp;
1548         wp = this.havocbot_personal_waypoint;
1549         navigation_goalrating_start(this);
1550         navigation_routerating(this, wp, 10000, 10000);
1551         navigation_goalrating_end(this);
1552         return (this.goalentity != NULL);
1553 }
1554
1555 float havocbot_moveto(entity this, vector pos)
1556 {
1557         entity wp;
1558
1559         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1560         {
1561                 // Step 4: Move to waypoint
1562                 if(this.havocbot_personal_waypoint==NULL)
1563                 {
1564                         LOG_TRACE("Error: ", this.netname, " trying to walk to a non existent personal waypoint");
1565                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1566                         return CMD_STATUS_ERROR;
1567                 }
1568
1569                 if (!bot_strategytoken_taken)
1570                 if(this.havocbot_personal_waypoint_searchtime<time)
1571                 {
1572                         bot_strategytoken_taken = true;
1573                         if(havocbot_moveto_refresh_route(this))
1574                         {
1575                                 LOG_TRACE(this.netname, " walking to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts)");
1576                                 this.havocbot_personal_waypoint_searchtime = time + 10;
1577                                 this.havocbot_personal_waypoint_failcounter = 0;
1578                         }
1579                         else
1580                         {
1581                                 this.havocbot_personal_waypoint_failcounter += 1;
1582                                 this.havocbot_personal_waypoint_searchtime = time + 2;
1583                                 if(this.havocbot_personal_waypoint_failcounter >= 30)
1584                                 {
1585                                         LOG_TRACE("Warning: can't walk to the personal waypoint located at ", vtos(this.havocbot_personal_waypoint.origin));
1586                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1587                                         delete(this.havocbot_personal_waypoint);
1588                                         return CMD_STATUS_ERROR;
1589                                 }
1590                                 else
1591                                         LOG_TRACE(this.netname, " can't walk to its personal waypoint (after ", ftos(this.havocbot_personal_waypoint_failcounter), " failed attempts), trying later");
1592                         }
1593                 }
1594
1595                 if(autocvar_bot_debug_goalstack)
1596                         debuggoalstack(this);
1597
1598
1599                 // Go!
1600                 havocbot_movetogoal(this);
1601
1602                 if (!this.bot_aimdir_executed && this.goalcurrent)
1603                 {
1604                         // Heading
1605                         vector dir = get_closer_dest(this.goalcurrent, this.origin);
1606                         dir -= this.origin + this.view_ofs;
1607                         dir.z = 0;
1608                         bot_aimdir(this, dir, 0);
1609                 }
1610
1611                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1612                 {
1613                         // Step 5: Waypoint reached
1614                         LOG_TRACE(this.netname, "'s personal waypoint reached");
1615                         waypoint_remove(this.havocbot_personal_waypoint);
1616                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1617                         return CMD_STATUS_FINISHED;
1618                 }
1619
1620                 return CMD_STATUS_EXECUTING;
1621         }
1622
1623         // Step 2: Linking waypoint
1624         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1625         {
1626                 // Wait until it is linked
1627                 if(!this.havocbot_personal_waypoint.wplinked)
1628                 {
1629                         LOG_TRACE(this.netname, " waiting for personal waypoint to be linked");
1630                         return CMD_STATUS_EXECUTING;
1631                 }
1632
1633                 this.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1634                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1635                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1636
1637                 // Step 3: Route to waypoint
1638                 LOG_TRACE(this.netname, " walking to its personal waypoint");
1639
1640                 return CMD_STATUS_EXECUTING;
1641         }
1642
1643         // Step 1: Spawning waypoint
1644         wp = waypoint_spawnpersonal(this, pos);
1645         if(wp==NULL)
1646         {
1647                 LOG_TRACE("Error: Can't spawn personal waypoint at ",vtos(pos));
1648                 return CMD_STATUS_ERROR;
1649         }
1650
1651         this.havocbot_personal_waypoint = wp;
1652         this.havocbot_personal_waypoint_failcounter = 0;
1653         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1654
1655         // if pos is inside a teleport, then let's mark it as teleport waypoint
1656         IL_EACH(g_teleporters, WarpZoneLib_BoxTouchesBrush(pos, pos, it, NULL),
1657         {
1658                 wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1659                 this.lastteleporttime = 0;
1660         });
1661
1662 /*
1663         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1664                 print("routing to a teleporter\n");
1665         else
1666                 print("routing to a non-teleporter\n");
1667 */
1668
1669         return CMD_STATUS_EXECUTING;
1670 }
1671
1672 float havocbot_resetgoal(entity this)
1673 {
1674         navigation_clearroute(this);
1675         return CMD_STATUS_FINISHED;
1676 }
1677
1678 void havocbot_setupbot(entity this)
1679 {
1680         this.bot_ai = havocbot_ai;
1681         this.cmd_moveto = havocbot_moveto;
1682         this.cmd_resetgoal = havocbot_resetgoal;
1683
1684         // NOTE: bot is not player yet
1685         havocbot_chooserole(this);
1686 }
1687
1688 vector havocbot_dodge(entity this)
1689 {
1690         // LordHavoc: disabled because this is too expensive
1691         return '0 0 0';
1692 #if 0
1693         entity head;
1694         vector dodge, v, n;
1695         float danger, bestdanger, vl, d;
1696         dodge = '0 0 0';
1697         bestdanger = -20;
1698         // check for dangerous objects near bot or approaching bot
1699         head = findchainfloat(bot_dodge, true);
1700         while(head)
1701         {
1702                 if (head.owner != this)
1703                 {
1704                         vl = vlen(head.velocity);
1705                         if (vl > autocvar_sv_maxspeed * 0.3)
1706                         {
1707                                 n = normalize(head.velocity);
1708                                 v = this.origin - head.origin;
1709                                 d = v * n;
1710                                 if (d > (0 - head.bot_dodgerating))
1711                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1712                                 {
1713                                         // calculate direction and distance from the flight path, by removing the forward axis
1714                                         v = v - (n * (v * n));
1715                                         danger = head.bot_dodgerating - vlen(v);
1716                                         if (bestdanger < danger)
1717                                         {
1718                                                 bestdanger = danger;
1719                                                 // dodge to the side of the object
1720                                                 dodge = normalize(v);
1721                                         }
1722                                 }
1723                         }
1724                         else
1725                         {
1726                                 danger = head.bot_dodgerating - vlen(head.origin - this.origin);
1727                                 if (bestdanger < danger)
1728                                 {
1729                                         bestdanger = danger;
1730                                         dodge = normalize(this.origin - head.origin);
1731                                 }
1732                         }
1733                 }
1734                 head = head.chain;
1735         }
1736         return dodge;
1737 #endif
1738 }