qcsrc/server/bot/default/havocbot/roles.qc

   1 #include "roles.qh"
   2
   3 #include "havocbot.qh"
   4
   5 #include "../cvars.qh"
   6
   7 #include "../bot.qh"
   8 #include "../navigation.qh"
   9
  10 .float max_armorvalue;
  11 .float havocbot_role_timeout;
  12
  13 .void(entity this) havocbot_previous_role;
  14 .void(entity this) havocbot_role;
  15
  16 void havocbot_goalrating_items(entity this, float ratingscale, vector org, float sradius)
  17 {
  18         float rating, d, discard, friend_distance, enemy_distance;
  19         vector o;
  20         ratingscale = ratingscale * 0.0001; // items are rated around 10000 already
  21
  22         IL_EACH(g_items, it.bot_pickup,
  23         {
  24                 rating = 0;
  25
  26                 o = (it.absmin + it.absmax) * 0.5;
  27                 if(!it.solid || vdist(o - org, >, sradius) || (it == this.ignoregoal && time < this.ignoregoaltime) )
  28                         continue;
  29
  30                 // Check if the item can be picked up safely
  31                 if(it.classname == "droppedweapon")
  32                 {
  33                         traceline(o, o + '0 0 -1500', true, NULL);
  34
  35                         d = pointcontents(trace_endpos + '0 0 1');
  36                         if(d == CONTENT_WATER || d == CONTENT_SLIME || d == CONTENT_LAVA)
  37                                 continue;
  38                         // this tracebox_hits_trigger_hurt call isn't needed:
  39                         // dropped weapons are removed as soon as they fall on a trigger_hurt
  40                         // and can't be rated while they are in the air
  41                         //if(tracebox_hits_trigger_hurt(it.origin, it.mins, it.maxs, trace_endpos))
  42                         //      continue;
  43                 }
  44                 else
  45                 {
  46                         // Ignore items under water
  47                         traceline(it.origin + it.maxs, it.origin + it.maxs, MOVE_NORMAL, it);
  48                         if(trace_dpstartcontents & DPCONTENTS_LIQUIDSMASK)
  49                                 continue;
  50                 }
  51
  52                 if(teamplay)
  53                 {
  54                         friend_distance = 10000; enemy_distance = 10000;
  55                         discard = false;
  56
  57                         entity picker = it;
  58                         FOREACH_CLIENT(IS_PLAYER(it) && it != this && !IS_DEAD(it),
  59                         {
  60                                 d = vlen(it.origin - o); // distance between player and item
  61
  62                                 if ( it.team == this.team )
  63                                 {
  64                                         if ( !IS_REAL_CLIENT(it) || discard )
  65                                                 continue;
  66
  67                                         if( d > friend_distance)
  68                                                 continue;
  69
  70                                         friend_distance = d;
  71                                         discard = true;
  72
  73                                         if (picker.health && it.health > this.health) continue;
  74                                         if (picker.armorvalue && it.armorvalue > this.armorvalue) continue;
  75
  76                                         if (picker.weapons && (picker.weapons & ~it.weapons)) continue;
  77
  78                                         if (picker.ammo_shells && it.ammo_shells > this.ammo_shells) continue;
  79                                         if (picker.ammo_nails && it.ammo_nails > this.ammo_nails) continue;
  80                                         if (picker.ammo_rockets && it.ammo_rockets > this.ammo_rockets) continue;
  81                                         if (picker.ammo_cells && it.ammo_cells > this.ammo_cells) continue;
  82                                         if (picker.ammo_plasma && it.ammo_plasma > this.ammo_plasma) continue;
  83
  84                                         discard = false;
  85                                 }
  86                                 else
  87                                 {
  88                                         // If enemy only track distances
  89                                         // TODO: track only if visible ?
  90                                         if( d < enemy_distance )
  91                                                 enemy_distance = d;
  92                                 }
  93                         });
  94
  95                         // Rate the item only if no one needs it, or if an enemy is closer to it
  96                         if ( (enemy_distance < friend_distance && vdist(o - org, <, enemy_distance)) ||
  97                                 (friend_distance > autocvar_bot_ai_friends_aware_pickup_radius ) || !discard )
  98                                 rating = it.bot_pickupevalfunc(this, it);
  99                 }
 100                 else
 101                         rating = it.bot_pickupevalfunc(this, it);
 102
 103                 if(rating > 0)
 104                         navigation_routerating(this, it, rating * ratingscale, 2000);
 105         });
 106 }
 107
 108 void havocbot_goalrating_enemyplayers(entity this, float ratingscale, vector org, float sradius)
 109 {
 110         if (autocvar_bot_nofire)
 111                 return;
 112
 113         // don't chase players if we're under water
 114         if(this.waterlevel>WATERLEVEL_WETFEET)
 115                 return;
 116
 117         int t;
 118
 119         FOREACH_CLIENT(IS_PLAYER(it) && bot_shouldattack(this, it), LAMBDA(
 120                 // TODO: Merge this logic with the bot_shouldattack function
 121                 if(vdist(it.origin - org, <, 100) || vdist(it.origin - org, >, sradius))
 122                         continue;
 123
 124                 // rate only visible enemies
 125                 /*
 126                 traceline(this.origin + this.view_ofs, it.origin, MOVE_NOMONSTERS, this);
 127                 if (trace_fraction < 1 || trace_ent != it)
 128                         continue;
 129                 */
 130
 131                 if((it.flags & FL_INWATER) || (it.flags & FL_PARTIALGROUND))
 132                         continue;
 133
 134                 // not falling
 135                 if(!IS_ONGROUND(it))
 136                 {
 137                         traceline(it.origin, it.origin + '0 0 -1500', true, NULL);
 138                         t = pointcontents(trace_endpos + '0 0 1');
 139                         if(t != CONTENT_SOLID )
 140                         if(t == CONTENT_WATER || t == CONTENT_SLIME || t == CONTENT_LAVA)
 141                                 continue;
 142                         if(tracebox_hits_trigger_hurt(it.origin, it.mins, it.maxs, trace_endpos))
 143                                 continue;
 144                 }
 145
 146                 // TODO: rate waypoints near the targeted player at that moment, instead of the player itself
 147                 //               adding a player as a goal seems to be quite dangerous, especially on space maps
 148                 //               remove hack in navigation_poptouchedgoals() after performing this change
 149
 150                 t = (this.health + this.armorvalue ) / (it.health + it.armorvalue );
 151                 navigation_routerating(this, it, t * ratingscale, 2000);
 152         ));
 153 }
 154
 155 // legacy bot role for standard gamemodes
 156 // go to best items
 157 void havocbot_role_generic(entity this)
 158 {
 159         if(IS_DEAD(this))
 160                 return;
 161
 162         if (this.bot_strategytime < time)
 163         {
 164                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
 165                 navigation_goalrating_start(this);
 166                 havocbot_goalrating_items(this, 10000, this.origin, 10000);
 167                 havocbot_goalrating_enemyplayers(this, 20000, this.origin, 10000);
 168                 //havocbot_goalrating_waypoints(1, this.origin, 1000);
 169                 navigation_goalrating_end(this);
 170         }
 171 }
 172
 173 void havocbot_chooserole_generic(entity this)
 174 {
 175         this.havocbot_role = havocbot_role_generic;
 176 }
 177
 178 void havocbot_chooserole(entity this)
 179 {
 180         LOG_TRACE("choosing a role...");
 181         this.bot_strategytime = 0;
 182         if(!MUTATOR_CALLHOOK(HavocBot_ChooseRole, this))
 183                 havocbot_chooserole_generic(this);
 184 }