qcsrc/server/bot/default/navigation.qc

   1 #include "navigation.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "bot.qh"
   6 #include "waypoints.qh"
   7
   8 #include <common/t_items.qh>
   9
  10 #include <common/items/_mod.qh>
  11
  12 #include <common/constants.qh>
  13 #include <common/net_linked.qh>
  14 #include <common/triggers/trigger/jumppads.qh>
  15
  16 .float speed;
  17
  18 void navigation_dynamicgoal_init(entity this, bool initially_static)
  19 {
  20         this.navigation_dynamicgoal = true;
  21         this.bot_basewaypoint = this.nearestwaypoint;
  22         if(initially_static)
  23                 this.nearestwaypointtimeout = -1;
  24         else
  25                 this.nearestwaypointtimeout = time;
  26 }
  27
  28 void navigation_dynamicgoal_set(entity this)
  29 {
  30         this.nearestwaypointtimeout = time;
  31 }
  32
  33 void navigation_dynamicgoal_unset(entity this)
  34 {
  35         if(this.bot_basewaypoint)
  36                 this.nearestwaypoint = this.bot_basewaypoint;
  37         this.nearestwaypointtimeout = -1;
  38 }
  39
  40 // rough simulation of walking from one point to another to test if a path
  41 // can be traveled, used for waypoint linking and havocbot
  42
  43 bool tracewalk(entity e, vector start, vector m1, vector m2, vector end, float movemode)
  44 {
  45         vector org;
  46         vector move;
  47         vector dir;
  48         float dist;
  49         float totaldist;
  50         float stepdist;
  51         float ignorehazards;
  52         float swimming;
  53
  54         if(autocvar_bot_debug_tracewalk)
  55         {
  56                 debugresetnodes();
  57                 debugnode(e, start);
  58         }
  59
  60         move = end - start;
  61         move.z = 0;
  62         org = start;
  63         dist = totaldist = vlen(move);
  64         dir = normalize(move);
  65         stepdist = 32;
  66         ignorehazards = false;
  67         swimming = false;
  68
  69         // Analyze starting point
  70         traceline(start, start, MOVE_NORMAL, e);
  71         if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
  72                 ignorehazards = true;
  73         else
  74         {
  75                 traceline( start, start + '0 0 -65536', MOVE_NORMAL, e);
  76                 if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
  77                 {
  78                         ignorehazards = true;
  79                         swimming = true;
  80                 }
  81         }
  82         tracebox(start, m1, m2, start, MOVE_NOMONSTERS, e);
  83         if (trace_startsolid)
  84         {
  85                 // Bad start
  86                 if(autocvar_bot_debug_tracewalk)
  87                         debugnodestatus(start, DEBUG_NODE_FAIL);
  88
  89                 //print("tracewalk: ", vtos(start), " is a bad start\n");
  90                 return false;
  91         }
  92
  93         // Movement loop
  94         move = end - org;
  95         for (;;)
  96         {
  97                 if (boxesoverlap(end, end, org + m1 + '-1 -1 -1', org + m2 + '1 1 1'))
  98                 {
  99                         // Succeeded
 100                         if(autocvar_bot_debug_tracewalk)
 101                                 debugnodestatus(org, DEBUG_NODE_SUCCESS);
 102
 103                         //print("tracewalk: ", vtos(start), " can reach ", vtos(end), "\n");
 104                         return true;
 105                 }
 106                 if(autocvar_bot_debug_tracewalk)
 107                         debugnode(e, org);
 108
 109                 if (dist <= 0)
 110                         break;
 111                 if (stepdist > dist)
 112                         stepdist = dist;
 113                 dist = dist - stepdist;
 114                 traceline(org, org, MOVE_NORMAL, e);
 115                 if (!ignorehazards)
 116                 {
 117                         if (trace_dpstartcontents & (DPCONTENTS_SLIME | DPCONTENTS_LAVA))
 118                         {
 119                                 // hazards blocking path
 120                                 if(autocvar_bot_debug_tracewalk)
 121                                         debugnodestatus(org, DEBUG_NODE_FAIL);
 122
 123                                 //print("tracewalk: ", vtos(start), " hits a hazard when trying to reach ", vtos(end), "\n");
 124                                 return false;
 125                         }
 126                 }
 127                 if (trace_dpstartcontents & DPCONTENTS_LIQUIDSMASK)
 128                 {
 129                         move = normalize(end - org);
 130                         tracebox(org, m1, m2, org + move * stepdist, movemode, e);
 131
 132                         if(autocvar_bot_debug_tracewalk)
 133                                 debugnode(e, trace_endpos);
 134
 135                         if (trace_fraction < 1)
 136                         {
 137                                 swimming = true;
 138                                 org = trace_endpos + normalize(org - trace_endpos) * stepdist;
 139                                 for (; org.z < end.z + e.maxs.z; org.z += stepdist)
 140                                 {
 141                                         if(autocvar_bot_debug_tracewalk)
 142                                                 debugnode(e, org);
 143
 144                                         if(pointcontents(org) == CONTENT_EMPTY)
 145                                                 break;
 146                                 }
 147
 148                                 if(pointcontents(org + '0 0 1') != CONTENT_EMPTY)
 149                                 {
 150                                         if(autocvar_bot_debug_tracewalk)
 151                                                 debugnodestatus(org, DEBUG_NODE_FAIL);
 152
 153                                         return false;
 154                                         //print("tracewalk: ", vtos(start), " failed under water\n");
 155                                 }
 156                                 continue;
 157
 158                         }
 159                         else
 160                                 org = trace_endpos;
 161                 }
 162                 else
 163                 {
 164                         move = dir * stepdist + org;
 165                         tracebox(org, m1, m2, move, movemode, e);
 166
 167                         if(autocvar_bot_debug_tracewalk)
 168                                 debugnode(e, trace_endpos);
 169
 170                         // hit something
 171                         if (trace_fraction < 1)
 172                         {
 173                                 // check if we can walk over this obstacle, possibly by jumpstepping
 174                                 tracebox(org + stepheightvec, m1, m2, move + stepheightvec, movemode, e);
 175                                 if (trace_fraction < 1 || trace_startsolid)
 176                                 {
 177                                         tracebox(org + jumpstepheightvec, m1, m2, move + jumpstepheightvec, movemode, e);
 178                                         if (trace_fraction < 1 || trace_startsolid)
 179                                         {
 180                                                 bool ladder_found = false;
 181                                                 FOREACH_ENTITY_CLASS("func_ladder", boxesoverlap(trace_endpos + m1 + '-1 -1 -1', trace_endpos + m2 + '1 1 1', it.absmin, it.absmax),
 182                                                 {
 183                                                         if(boxesoverlap(end, end, it.absmin + (m1 - eZ * m1.z - '1 1 0'), it.absmax + (m2 - eZ * m2.z + '1 1 0')))
 184                                                                 ladder_found = true; // can't return here ("Loop mutex held by tracewalk" error)
 185                                                 });
 186                                                 if(ladder_found)
 187                                                 {
 188                                                         if(autocvar_bot_debug_tracewalk)
 189                                                                 debugnodestatus(org, DEBUG_NODE_SUCCESS);
 190
 191                                                         //print("tracewalk: ", vtos(start), " can reach ", vtos(end), "\n");
 192                                                         return true;
 193                                                 }
 194
 195                                                 if(autocvar_bot_debug_tracewalk)
 196                                                         debugnodestatus(trace_endpos, DEBUG_NODE_WARNING);
 197
 198                                                 traceline( org, move, movemode, e);
 199
 200                                                 if ( trace_ent.classname == "door_rotating" || trace_ent.classname == "door")
 201                                                 {
 202                                                         vector nextmove;
 203                                                         move = trace_endpos;
 204                                                         while(trace_ent.classname == "door_rotating" || trace_ent.classname == "door")
 205                                                         {
 206                                                                 nextmove = move + (dir * stepdist);
 207                                                                 traceline( move, nextmove, movemode, e);
 208                                                                 move = nextmove;
 209                                                         }
 210                                                 }
 211                                                 else
 212                                                 {
 213                                                         if(autocvar_bot_debug_tracewalk)
 214                                                                 debugnodestatus(trace_endpos, DEBUG_NODE_FAIL);
 215
 216                                                         //print("tracewalk: ", vtos(start), " hit something when trying to reach ", vtos(end), "\n");
 217                                                         //te_explosion(trace_endpos);
 218                                                         //print(ftos(e.dphitcontentsmask), "\n");
 219                                                         return false; // failed
 220                                                 }
 221                                         }
 222                                         else
 223                                                 move = trace_endpos;
 224                                 }
 225                                 else
 226                                         move = trace_endpos;
 227                         }
 228                         else
 229                                 move = trace_endpos;
 230
 231                         // trace down from stepheight as far as possible and move there,
 232                         // if this starts in solid we try again without the stepup, and
 233                         // if that also fails we assume it is a wall
 234                         // (this is the same logic as the Quake walkmove function used)
 235                         tracebox(move, m1, m2, move + '0 0 -65536', movemode, e);
 236
 237                         // moved successfully
 238                         if(swimming)
 239                         {
 240                                 float c;
 241                                 c = pointcontents(org + '0 0 1');
 242                                 if (!(c == CONTENT_WATER || c == CONTENT_LAVA || c == CONTENT_SLIME))
 243                                         swimming = false;
 244                                 else
 245                                         continue;
 246                         }
 247
 248                         org = trace_endpos;
 249                 }
 250         }
 251
 252         //print("tracewalk: ", vtos(start), " did not arrive at ", vtos(end), " but at ", vtos(org), "\n");
 253
 254         // moved but didn't arrive at the intended destination
 255         if(autocvar_bot_debug_tracewalk)
 256                 debugnodestatus(org, DEBUG_NODE_FAIL);
 257
 258         return false;
 259 }
 260
 261 /////////////////////////////////////////////////////////////////////////////
 262 // goal stack
 263 /////////////////////////////////////////////////////////////////////////////
 264
 265 // completely empty the goal stack, used when deciding where to go
 266 void navigation_clearroute(entity this)
 267 {
 268         //print("bot ", etos(this), " clear\n");
 269         this.goalentity = NULL;
 270         this.goalcurrent = NULL;
 271         this.goalstack01 = NULL;
 272         this.goalstack02 = NULL;
 273         this.goalstack03 = NULL;
 274         this.goalstack04 = NULL;
 275         this.goalstack05 = NULL;
 276         this.goalstack06 = NULL;
 277         this.goalstack07 = NULL;
 278         this.goalstack08 = NULL;
 279         this.goalstack09 = NULL;
 280         this.goalstack10 = NULL;
 281         this.goalstack11 = NULL;
 282         this.goalstack12 = NULL;
 283         this.goalstack13 = NULL;
 284         this.goalstack14 = NULL;
 285         this.goalstack15 = NULL;
 286         this.goalstack16 = NULL;
 287         this.goalstack17 = NULL;
 288         this.goalstack18 = NULL;
 289         this.goalstack19 = NULL;
 290         this.goalstack20 = NULL;
 291         this.goalstack21 = NULL;
 292         this.goalstack22 = NULL;
 293         this.goalstack23 = NULL;
 294         this.goalstack24 = NULL;
 295         this.goalstack25 = NULL;
 296         this.goalstack26 = NULL;
 297         this.goalstack27 = NULL;
 298         this.goalstack28 = NULL;
 299         this.goalstack29 = NULL;
 300         this.goalstack30 = NULL;
 301         this.goalstack31 = NULL;
 302 }
 303
 304 // add a new goal at the beginning of the stack
 305 // (in other words: add a new prerequisite before going to the later goals)
 306 // NOTE: when a waypoint is added, the WP gets pushed first, then the
 307 // next-closest WP on the shortest path to the WP
 308 // That means, if the stack overflows, the bot will know how to do the FIRST 32
 309 // steps to the goal, and then recalculate the path.
 310 void navigation_pushroute(entity this, entity e)
 311 {
 312         //print("bot ", etos(this), " push ", etos(e), "\n");
 313         if(this.goalstack31 == this.goalentity)
 314                 this.goalentity = NULL;
 315         this.goalstack31 = this.goalstack30;
 316         this.goalstack30 = this.goalstack29;
 317         this.goalstack29 = this.goalstack28;
 318         this.goalstack28 = this.goalstack27;
 319         this.goalstack27 = this.goalstack26;
 320         this.goalstack26 = this.goalstack25;
 321         this.goalstack25 = this.goalstack24;
 322         this.goalstack24 = this.goalstack23;
 323         this.goalstack23 = this.goalstack22;
 324         this.goalstack22 = this.goalstack21;
 325         this.goalstack21 = this.goalstack20;
 326         this.goalstack20 = this.goalstack19;
 327         this.goalstack19 = this.goalstack18;
 328         this.goalstack18 = this.goalstack17;
 329         this.goalstack17 = this.goalstack16;
 330         this.goalstack16 = this.goalstack15;
 331         this.goalstack15 = this.goalstack14;
 332         this.goalstack14 = this.goalstack13;
 333         this.goalstack13 = this.goalstack12;
 334         this.goalstack12 = this.goalstack11;
 335         this.goalstack11 = this.goalstack10;
 336         this.goalstack10 = this.goalstack09;
 337         this.goalstack09 = this.goalstack08;
 338         this.goalstack08 = this.goalstack07;
 339         this.goalstack07 = this.goalstack06;
 340         this.goalstack06 = this.goalstack05;
 341         this.goalstack05 = this.goalstack04;
 342         this.goalstack04 = this.goalstack03;
 343         this.goalstack03 = this.goalstack02;
 344         this.goalstack02 = this.goalstack01;
 345         this.goalstack01 = this.goalcurrent;
 346         this.goalcurrent = e;
 347 }
 348
 349 // remove first goal from stack
 350 // (in other words: remove a prerequisite for reaching the later goals)
 351 // (used when a spawnfunc_waypoint is reached)
 352 void navigation_poproute(entity this)
 353 {
 354         //print("bot ", etos(this), " pop\n");
 355         if(this.goalcurrent == this.goalentity)
 356                 this.goalentity = NULL;
 357         this.goalcurrent = this.goalstack01;
 358         this.goalstack01 = this.goalstack02;
 359         this.goalstack02 = this.goalstack03;
 360         this.goalstack03 = this.goalstack04;
 361         this.goalstack04 = this.goalstack05;
 362         this.goalstack05 = this.goalstack06;
 363         this.goalstack06 = this.goalstack07;
 364         this.goalstack07 = this.goalstack08;
 365         this.goalstack08 = this.goalstack09;
 366         this.goalstack09 = this.goalstack10;
 367         this.goalstack10 = this.goalstack11;
 368         this.goalstack11 = this.goalstack12;
 369         this.goalstack12 = this.goalstack13;
 370         this.goalstack13 = this.goalstack14;
 371         this.goalstack14 = this.goalstack15;
 372         this.goalstack15 = this.goalstack16;
 373         this.goalstack16 = this.goalstack17;
 374         this.goalstack17 = this.goalstack18;
 375         this.goalstack18 = this.goalstack19;
 376         this.goalstack19 = this.goalstack20;
 377         this.goalstack20 = this.goalstack21;
 378         this.goalstack21 = this.goalstack22;
 379         this.goalstack22 = this.goalstack23;
 380         this.goalstack23 = this.goalstack24;
 381         this.goalstack24 = this.goalstack25;
 382         this.goalstack25 = this.goalstack26;
 383         this.goalstack26 = this.goalstack27;
 384         this.goalstack27 = this.goalstack28;
 385         this.goalstack28 = this.goalstack29;
 386         this.goalstack29 = this.goalstack30;
 387         this.goalstack30 = this.goalstack31;
 388         this.goalstack31 = NULL;
 389 }
 390
 391 float navigation_waypoint_will_link(vector v, vector org, entity ent, float walkfromwp, float bestdist)
 392 {
 393         float dist;
 394         dist = vlen(v - org);
 395         if (bestdist > dist)
 396         {
 397                 traceline(v, org, true, ent);
 398                 if (trace_fraction == 1)
 399                 {
 400                         if (walkfromwp)
 401                         {
 402                                 if (tracewalk(ent, v, PL_MIN_CONST, PL_MAX_CONST, org, bot_navigation_movemode))
 403                                         return true;
 404                         }
 405                         else
 406                         {
 407                                 if (tracewalk(ent, org, PL_MIN_CONST, PL_MAX_CONST, v, bot_navigation_movemode))
 408                                         return true;
 409                         }
 410                 }
 411         }
 412         return false;
 413 }
 414
 415 // find the spawnfunc_waypoint near a dynamic goal such as a dropped weapon
 416 entity navigation_findnearestwaypoint_withdist_except(entity ent, float walkfromwp, float bestdist, entity except)
 417 {
 418         vector pm1 = ent.origin + ent.mins;
 419         vector pm2 = ent.origin + ent.maxs;
 420
 421         // do two scans, because box test is cheaper
 422         IL_EACH(g_waypoints, it != ent && it != except,
 423         {
 424                 if(boxesoverlap(pm1, pm2, it.absmin, it.absmax))
 425                         return it;
 426         });
 427
 428         vector org = ent.origin + 0.5 * (ent.mins + ent.maxs);
 429         org.z = ent.origin.z + ent.mins.z - PL_MIN_CONST.z; // player height
 430         // TODO possibly make other code have the same support for bboxes
 431         if(ent.tag_entity)
 432                 org = org + ent.tag_entity.origin;
 433         if (navigation_testtracewalk)
 434                 te_plasmaburn(org);
 435
 436         entity best = NULL;
 437         vector v;
 438
 439         if(!autocvar_g_waypointeditor && !ent.navigation_dynamicgoal)
 440         {
 441                 waypoint_clearlinks(ent); // initialize wpXXmincost fields
 442                 IL_EACH(g_waypoints, it != ent,
 443                 {
 444                         if(it.wpisbox)
 445                         {
 446                                 vector wm1 = it.absmin;
 447                                 vector wm2 = it.absmax;
 448                                 v.x = bound(wm1_x, org.x, wm2_x);
 449                                 v.y = bound(wm1_y, org.y, wm2_y);
 450                                 v.z = bound(wm1_z, org.z, wm2_z);
 451                         }
 452                         else
 453                                 v = it.origin;
 454                         if(navigation_waypoint_will_link(v, org, ent, walkfromwp, 1050))
 455                                 navigation_item_addlink(it, ent);
 456                 });
 457         }
 458
 459         // box check failed, try walk
 460         IL_EACH(g_waypoints, it != ent,
 461         {
 462                 if(it.wpisbox)
 463                 {
 464                         vector wm1 = it.origin + it.mins;
 465                         vector wm2 = it.origin + it.maxs;
 466                         v.x = bound(wm1_x, org.x, wm2_x);
 467                         v.y = bound(wm1_y, org.y, wm2_y);
 468                         v.z = bound(wm1_z, org.z, wm2_z);
 469                 }
 470                 else
 471                         v = it.origin;
 472                 if(navigation_waypoint_will_link(v, org, ent, walkfromwp, bestdist))
 473                 {
 474                         bestdist = vlen(v - org);
 475                         best = it;
 476                 }
 477         });
 478         return best;
 479 }
 480 entity navigation_findnearestwaypoint(entity ent, float walkfromwp)
 481 {
 482         entity wp = navigation_findnearestwaypoint_withdist_except(ent, walkfromwp, 1050, NULL);
 483         if (autocvar_g_waypointeditor_auto)
 484         {
 485                 entity wp2 = navigation_findnearestwaypoint_withdist_except(ent, walkfromwp, 1050, wp);
 486                 if (wp && !wp2)
 487                         wp.wpflags |= WAYPOINTFLAG_PROTECTED;
 488         }
 489         return wp;
 490 }
 491
 492 // finds the waypoints near the bot initiating a navigation query
 493 float navigation_markroutes_nearestwaypoints(entity this, float maxdist)
 494 {
 495         vector v, m1, m2;
 496 //      navigation_testtracewalk = true;
 497         int c = 0;
 498         IL_EACH(g_waypoints, !it.wpconsidered,
 499         {
 500                 if (it.wpisbox)
 501                 {
 502                         m1 = it.origin + it.mins;
 503                         m2 = it.origin + it.maxs;
 504                         v = this.origin;
 505                         v.x = bound(m1_x, v.x, m2_x);
 506                         v.y = bound(m1_y, v.y, m2_y);
 507                         v.z = bound(m1_z, v.z, m2_z);
 508                 }
 509                 else
 510                         v = it.origin;
 511                 vector diff = v - this.origin;
 512                 diff.z = max(0, diff.z);
 513                 if(vdist(diff, <, maxdist))
 514                 {
 515                         it.wpconsidered = true;
 516                         if (tracewalk(this, this.origin, this.mins, this.maxs, v, bot_navigation_movemode))
 517                         {
 518                                 it.wpnearestpoint = v;
 519                                 it.wpcost = waypoint_getdistancecost(this.origin, v) + it.dmg;
 520                                 it.wpfire = 1;
 521                                 it.enemy = NULL;
 522                                 c = c + 1;
 523                         }
 524                 }
 525         });
 526         //navigation_testtracewalk = false;
 527         return c;
 528 }
 529
 530 // updates a path link if a spawnfunc_waypoint link is better than the current one
 531 void navigation_markroutes_checkwaypoint(entity w, entity wp, float cost2, vector p)
 532 {
 533         vector m1;
 534         vector m2;
 535         vector v;
 536         if (wp.wpisbox)
 537         {
 538                 m1 = wp.absmin;
 539                 m2 = wp.absmax;
 540                 v.x = bound(m1_x, p.x, m2_x);
 541                 v.y = bound(m1_y, p.y, m2_y);
 542                 v.z = bound(m1_z, p.z, m2_z);
 543         }
 544         else
 545                 v = wp.origin;
 546         cost2 += waypoint_getdistancecost(p, v);
 547         if (wp.wpcost > cost2)
 548         {
 549                 wp.wpcost = cost2;
 550                 wp.enemy = w;
 551                 wp.wpfire = 1;
 552                 wp.wpnearestpoint = v;
 553         }
 554 }
 555
 556 // queries the entire spawnfunc_waypoint network for pathes leading away from the bot
 557 void navigation_markroutes(entity this, entity fixed_source_waypoint)
 558 {
 559         float cost, cost2;
 560         vector p;
 561
 562         IL_EACH(g_waypoints, true,
 563         {
 564                 it.wpconsidered = false;
 565                 it.wpnearestpoint = '0 0 0';
 566                 it.wpcost = 10000000;
 567                 it.wpfire = 0;
 568                 it.enemy = NULL;
 569         });
 570
 571         if(fixed_source_waypoint)
 572         {
 573                 fixed_source_waypoint.wpconsidered = true;
 574                 fixed_source_waypoint.wpnearestpoint = fixed_source_waypoint.origin + 0.5 * (fixed_source_waypoint.mins + fixed_source_waypoint.maxs);
 575                 fixed_source_waypoint.wpcost = fixed_source_waypoint.dmg;
 576                 fixed_source_waypoint.wpfire = 1;
 577                 fixed_source_waypoint.enemy = NULL;
 578         }
 579         else
 580         {
 581                 // try a short range search for the nearest waypoints, and expand the search repeatedly if none are found
 582                 // as this search is expensive we will use lower values if the bot is on the air
 583                 float increment, maxdistance;
 584                 if(IS_ONGROUND(this))
 585                 {
 586                         increment = 750;
 587                         maxdistance = 50000;
 588                 }
 589                 else
 590                 {
 591                         increment = 500;
 592                         maxdistance = 1500;
 593                 }
 594
 595                 for(int j = increment; !navigation_markroutes_nearestwaypoints(this, j) && j < maxdistance; j += increment);
 596         }
 597
 598         bool searching = true;
 599         while (searching)
 600         {
 601                 searching = false;
 602                 IL_EACH(g_waypoints, it.wpfire,
 603                 {
 604                         searching = true;
 605                         it.wpfire = 0;
 606                         cost = it.wpcost;
 607                         p = it.wpnearestpoint;
 608                         entity wp;
 609                         wp = it.wp00;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp00mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 610                         wp = it.wp01;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp01mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 611                         wp = it.wp02;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp02mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 612                         wp = it.wp03;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp03mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 613                         wp = it.wp04;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp04mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 614                         wp = it.wp05;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp05mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 615                         wp = it.wp06;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp06mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 616                         wp = it.wp07;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp07mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 617                         wp = it.wp08;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp08mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 618                         wp = it.wp09;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp09mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 619                         wp = it.wp10;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp10mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 620                         wp = it.wp11;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp11mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 621                         wp = it.wp12;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp12mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 622                         wp = it.wp13;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp13mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 623                         wp = it.wp14;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp14mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 624                         wp = it.wp15;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp15mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 625                         wp = it.wp16;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp16mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 626                         wp = it.wp17;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp17mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 627                         wp = it.wp18;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp18mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 628                         wp = it.wp19;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp19mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 629                         wp = it.wp20;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp20mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 630                         wp = it.wp21;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp21mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 631                         wp = it.wp22;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp22mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 632                         wp = it.wp23;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp23mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 633                         wp = it.wp24;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp24mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 634                         wp = it.wp25;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp25mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 635                         wp = it.wp26;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp26mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 636                         wp = it.wp27;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp27mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 637                         wp = it.wp28;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp28mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 638                         wp = it.wp29;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp29mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 639                         wp = it.wp30;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp30mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 640                         wp = it.wp31;if (wp){cost2 = cost + wp.dmg;if (wp.wpcost > cost2 + it.wp31mincost) navigation_markroutes_checkwaypoint(it, wp, cost2, p);
 641                         }}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}}
 642                 });
 643         }
 644 }
 645
 646 // queries the entire spawnfunc_waypoint network for pathes leading to the bot
 647 void navigation_markroutes_inverted(entity fixed_source_waypoint)
 648 {
 649         float cost, cost2;
 650         vector p;
 651         IL_EACH(g_waypoints, true,
 652         {
 653                 it.wpconsidered = false;
 654                 it.wpnearestpoint = '0 0 0';
 655                 it.wpcost = 10000000;
 656                 it.wpfire = 0;
 657                 it.enemy = NULL;
 658         });
 659
 660         if(fixed_source_waypoint)
 661         {
 662                 fixed_source_waypoint.wpconsidered = true;
 663                 fixed_source_waypoint.wpnearestpoint = fixed_source_waypoint.origin + 0.5 * (fixed_source_waypoint.mins + fixed_source_waypoint.maxs);
 664                 fixed_source_waypoint.wpcost = fixed_source_waypoint.dmg; // the cost to get from X to fixed_source_waypoint
 665                 fixed_source_waypoint.wpfire = 1;
 666                 fixed_source_waypoint.enemy = NULL;
 667         }
 668         else
 669         {
 670                 error("need to start with a waypoint\n");
 671         }
 672
 673         bool searching = true;
 674         while (searching)
 675         {
 676                 searching = false;
 677                 IL_EACH(g_waypoints, it.wpfire,
 678                 {
 679                         searching = true;
 680                         it.wpfire = 0;
 681                         cost = it.wpcost; // cost to walk from it to home
 682                         p = it.wpnearestpoint;
 683                         entity wp = it;
 684                         IL_EACH(g_waypoints, it != wp,
 685                         {
 686                                 if(!waypoint_islinked(it, wp))
 687                                         continue;
 688                                 cost2 = cost + it.dmg;
 689                                 navigation_markroutes_checkwaypoint(wp, it, cost2, p);
 690                         });
 691                 });
 692         }
 693 }
 694
 695 // updates the best goal according to a weighted calculation of travel cost and item value of a new proposed item
 696 void navigation_routerating(entity this, entity e, float f, float rangebias)
 697 {
 698         if (!e)
 699                 return;
 700
 701         if(e.blacklisted)
 702                 return;
 703
 704         rangebias = waypoint_getdistancecost_simple(rangebias);
 705         f = waypoint_getdistancecost_simple(f);
 706
 707         if (IS_PLAYER(e))
 708         {
 709                 bool rate_wps = false;
 710                 if((e.flags & FL_INWATER) || (e.flags & FL_PARTIALGROUND))
 711                         rate_wps = true;
 712
 713                 if(!IS_ONGROUND(e))
 714                 {
 715                         traceline(e.origin, e.origin + '0 0 -1500', true, NULL);
 716                         int t = pointcontents(trace_endpos + '0 0 1');
 717                         if(t != CONTENT_SOLID )
 718                         {
 719                                 if(t == CONTENT_WATER || t == CONTENT_SLIME || t == CONTENT_LAVA)
 720                                         rate_wps = true;
 721                                 else if(tracebox_hits_trigger_hurt(e.origin, e.mins, e.maxs, trace_endpos))
 722                                         return;
 723                         }
 724                 }
 725
 726                 if(rate_wps)
 727                 {
 728                         entity theEnemy = e;
 729                         entity best_wp = NULL;
 730                         float best_dist = 10000;
 731                         IL_EACH(g_waypoints, vdist(it.origin - theEnemy.origin, <, 500)
 732                                 && vdist(it.origin - this.origin, >, 100)
 733                                 && !(it.wpflags & WAYPOINTFLAG_TELEPORT),
 734                         {
 735                                 float dist = vlen(it.origin - theEnemy.origin);
 736                                 if (dist < best_dist)
 737                                 {
 738                                         best_wp = it;
 739                                         best_dist = dist;
 740                                 }
 741                         });
 742                         if (!best_wp)
 743                                 return;
 744                         e = best_wp;
 745                 }
 746         }
 747
 748         vector o = (e.absmin + e.absmax) * 0.5;
 749
 750         //print("routerating ", etos(e), " = ", ftos(f), " - ", ftos(rangebias), "\n");
 751
 752         // Evaluate path using jetpack
 753         if(g_jetpack)
 754         if(this.items & IT_JETPACK)
 755         if(autocvar_bot_ai_navigation_jetpack)
 756         if(vdist(this.origin - o, >, autocvar_bot_ai_navigation_jetpack_mindistance))
 757         {
 758                 vector pointa, pointb;
 759
 760                 LOG_DEBUG("jetpack ai: evaluating path for ", e.classname);
 761
 762                 // Point A
 763                 traceline(this.origin, this.origin + '0 0 65535', MOVE_NORMAL, this);
 764                 pointa = trace_endpos - '0 0 1';
 765
 766                 // Point B
 767                 traceline(o, o + '0 0 65535', MOVE_NORMAL, e);
 768                 pointb = trace_endpos - '0 0 1';
 769
 770                 // Can I see these two points from the sky?
 771                 traceline(pointa, pointb, MOVE_NORMAL, this);
 772
 773                 if(trace_fraction==1)
 774                 {
 775                         LOG_DEBUG("jetpack ai: can bridge these two points");
 776
 777                         // Lower the altitude of these points as much as possible
 778                         float zdistance, xydistance, cost, t, fuel;
 779                         vector down, npa, npb;
 780
 781                         down = '0 0 -1' * (STAT(PL_MAX, this).z - STAT(PL_MIN, this).z) * 10;
 782
 783                         do{
 784                                 npa = pointa + down;
 785                                 npb = pointb + down;
 786
 787                                 if(npa.z<=this.absmax.z)
 788                                         break;
 789
 790                                 if(npb.z<=e.absmax.z)
 791                                         break;
 792
 793                                 traceline(npa, npb, MOVE_NORMAL, this);
 794                                 if(trace_fraction==1)
 795                                 {
 796                                         pointa = npa;
 797                                         pointb = npb;
 798                                 }
 799                         }
 800                         while(trace_fraction == 1);
 801
 802
 803                         // Rough estimation of fuel consumption
 804                         // (ignores acceleration and current xyz velocity)
 805                         xydistance = vlen(pointa - pointb);
 806                         zdistance = fabs(pointa.z - this.origin.z);
 807
 808                         t = zdistance / autocvar_g_jetpack_maxspeed_up;
 809                         t += xydistance / autocvar_g_jetpack_maxspeed_side;
 810                         fuel = t * autocvar_g_jetpack_fuel * 0.8;
 811
 812                         LOG_DEBUG("jetpack ai: required fuel ", ftos(fuel), " this.ammo_fuel ", ftos(this.ammo_fuel));
 813
 814                         // enough fuel ?
 815                         if(this.ammo_fuel>fuel)
 816                         {
 817                                 // Estimate cost
 818                                 // (as onground costs calculation is mostly based on distances, here we do the same establishing some relationship
 819                                 //  - between air and ground speeds)
 820
 821                                 cost = xydistance / (autocvar_g_jetpack_maxspeed_side/autocvar_sv_maxspeed);
 822                                 cost += zdistance / (autocvar_g_jetpack_maxspeed_up/autocvar_sv_maxspeed);
 823                                 cost *= 1.5;
 824
 825                                 // Compare against other goals
 826                                 f = f * rangebias / (rangebias + cost);
 827
 828                                 if (navigation_bestrating < f)
 829                                 {
 830                                         LOG_DEBUG("jetpack path: added goal ", e.classname, " (with rating ", ftos(f), ")");
 831                                         navigation_bestrating = f;
 832                                         navigation_bestgoal = e;
 833                                         this.navigation_jetpack_goal = e;
 834                                         this.navigation_jetpack_point = pointb;
 835                                 }
 836                                 return;
 837                         }
 838                 }
 839         }
 840
 841         entity nwp;
 842         //te_wizspike(e.origin);
 843         //bprint(etos(e));
 844         //bprint("\n");
 845         // update the cached spawnfunc_waypoint link on a dynamic item entity
 846         if(e.classname == "waypoint" && !(e.wpflags & WAYPOINTFLAG_PERSONAL))
 847         {
 848                 nwp = e;
 849         }
 850         else
 851         {
 852                 if(autocvar_g_waypointeditor && e.nearestwaypointtimeout >= 0 && time > e.nearestwaypointtimeout)
 853                         e.nearestwaypoint = NULL;
 854
 855                 if ((!e.nearestwaypoint || e.navigation_dynamicgoal)
 856                         && e.nearestwaypointtimeout >= 0 && time > e.nearestwaypointtimeout)
 857                 {
 858                         nwp = navigation_findnearestwaypoint(e, true);
 859                         if(nwp)
 860                         {
 861                                 e.nearestwaypoint = nwp;
 862
 863                                 vector m1 = nwp.absmin, m2 = nwp.absmax;
 864                                 m1.x = nwp.origin.x; m1.y = nwp.origin.y;
 865                                 m2.x = nwp.origin.x; m2.y = nwp.origin.y;
 866                                 vector ve = (e.absmin - e.absmax) * 0.5;
 867                                 ve.x = bound(m1.x, ve.x, m2.x);
 868                                 ve.y = bound(m1.y, ve.y, m2.y);
 869                                 ve.z = bound(m1.z, ve.z, m2.z);
 870
 871                                 m1 = e.absmin; m2 = e.absmax;
 872                                 m1.x = e.origin.x; m1.y = e.origin.y;
 873                                 m2.x = e.origin.x; m2.y = e.origin.y;
 874                                 vector vnwp = nwp.origin;
 875                                 vnwp.x = bound(m1.x, vnwp.x, m2.x);
 876                                 vnwp.y = bound(m1.y, vnwp.y, m2.y);
 877                                 vnwp.z = bound(m1.z, vnwp.z, m2.z);
 878                                 e.nearestwaypoint_dist = vlen(ve - vnwp);
 879                         }
 880                         else
 881                         {
 882                                 LOG_DEBUG("FAILED to find a nearest waypoint to '", e.classname, "' #", etos(e));
 883
 884                                 if(!e.navigation_dynamicgoal)
 885                                         e.blacklisted = true;
 886
 887                                 if(e.blacklisted)
 888                                 {
 889                                         LOG_DEBUG("The entity '", e.classname, "' is going to be excluded from path finding during this match");
 890                                         return;
 891                                 }
 892                         }
 893
 894                         if(e.navigation_dynamicgoal)
 895                                 e.nearestwaypointtimeout = time + 2;
 896                         else if(autocvar_g_waypointeditor)
 897                                 e.nearestwaypointtimeout = time + 3 + random() * 2;
 898                 }
 899                 nwp = e.nearestwaypoint;
 900         }
 901
 902         LOG_DEBUG("-- checking ", e.classname, " (with cost ", ftos(nwp.wpcost), ")");
 903         if (nwp)
 904         if (nwp.wpcost < 10000000)
 905         {
 906                 //te_wizspike(nwp.wpnearestpoint);
 907                 LOG_DEBUG(e.classname, " ", ftos(f), "/(1+", ftos((nwp.wpcost + vlen(e.origin - nwp.wpnearestpoint))), "/", ftos(rangebias), ") = ");
 908                 f = f * rangebias / (rangebias + (nwp.wpcost + vlen(o - nwp.wpnearestpoint)));
 909                 LOG_DEBUG("considering ", e.classname, " (with rating ", ftos(f), ")");
 910                 if (navigation_bestrating < f)
 911                 {
 912                         LOG_DEBUG("ground path: added goal ", e.classname, " (with rating ", ftos(f), ")");
 913                         navigation_bestrating = f;
 914                         navigation_bestgoal = e;
 915                 }
 916         }
 917 }
 918
 919 // adds an item to the the goal stack with the path to a given item
 920 bool navigation_routetogoal(entity this, entity e, vector startposition)
 921 {
 922         // if there is no goal, just exit
 923         if (!e)
 924                 return false;
 925
 926         this.goalentity = e;
 927
 928         // put the entity on the goal stack
 929         //print("routetogoal ", etos(e), "\n");
 930         navigation_pushroute(this, e);
 931
 932         if(e.classname == "waypoint" && !(e.wpflags & WAYPOINTFLAG_PERSONAL))
 933         {
 934                 this.wp_goal_prev1 = this.wp_goal_prev0;
 935                 this.wp_goal_prev0 = e;
 936         }
 937
 938         if(g_jetpack)
 939         if(e==this.navigation_jetpack_goal)
 940                 return true;
 941
 942         // if it can reach the goal there is nothing more to do
 943         if (tracewalk(this, startposition, STAT(PL_MIN, this), STAT(PL_MAX, this), (e.absmin + e.absmax) * 0.5, bot_navigation_movemode))
 944                 return true;
 945
 946         entity nearest_wp = NULL;
 947         // see if there are waypoints describing a path to the item
 948         if(e.classname != "waypoint" || (e.wpflags & WAYPOINTFLAG_PERSONAL))
 949         {
 950                 e = e.nearestwaypoint;
 951                 nearest_wp = e;
 952         }
 953         else
 954                 e = e.enemy; // we already have added it, so...
 955
 956         if(e == NULL)
 957                 return false;
 958
 959         if(nearest_wp && nearest_wp.enemy)
 960         {
 961                 // often path can be optimized by not adding the nearest waypoint
 962                 if (this.goalentity.nearestwaypoint_dist < 8
 963                         || (!this.goalentity.navigation_dynamicgoal && navigation_item_islinked(nearest_wp.enemy, this.goalentity))
 964                         || (this.goalentity.navigation_dynamicgoal && tracewalk(this, nearest_wp.enemy.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), (this.goalentity.absmin + this.goalentity.absmax) * 0.5, bot_navigation_movemode)))
 965                         e = nearest_wp.enemy;
 966         }
 967
 968         for (;;)
 969         {
 970                 // add the spawnfunc_waypoint to the path
 971                 navigation_pushroute(this, e);
 972                 e = e.enemy;
 973
 974                 if(e==NULL)
 975                         break;
 976         }
 977
 978         return false;
 979 }
 980
 981 // removes any currently touching waypoints from the goal stack
 982 // (this is how bots detect if they reached a goal)
 983 void navigation_poptouchedgoals(entity this)
 984 {
 985         vector org, m1, m2;
 986         org = this.origin;
 987         m1 = org + this.mins;
 988         m2 = org + this.maxs;
 989
 990         if(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 991         {
 992                 // make sure jumppad is really hit, don't rely on distance based checks
 993                 // as they may report a touch even if it didn't really happen
 994                 if(this.lastteleporttime>0)
 995                 if(time - this.lastteleporttime < ((this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL) ? 2 : 0.15))
 996                 {
 997                         if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
 998                         if(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && this.goalcurrent.owner==this)
 999                         {
1000                                 this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1001                                 this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1002                         }
1003                         navigation_poproute(this);
1004                         return;
1005                 }
1006         }
1007
1008         // If for some reason the bot is closer to the next goal, pop the current one
1009         if(this.goalstack01 && !wasfreed(this.goalstack01))
1010         if(vlen2(this.goalcurrent.origin - this.origin) > vlen2(this.goalstack01.origin - this.origin))
1011         if(checkpvs(this.origin + this.view_ofs, this.goalstack01))
1012         if(tracewalk(this, this.origin, this.mins, this.maxs, (this.goalstack01.absmin + this.goalstack01.absmax) * 0.5, bot_navigation_movemode))
1013         {
1014                 LOG_DEBUG("path optimized for ", this.netname, ", removed a goal from the queue");
1015                 navigation_poproute(this);
1016                 // TODO this may also be a nice idea to do "early" (e.g. by
1017                 // manipulating the vlen() comparisons) to shorten paths in
1018                 // general - this would make bots walk more "on rails" than
1019                 // "zigzagging" which they currently do with sufficiently
1020                 // random-like waypoints, and thus can make a nice bot
1021                 // personality property
1022         }
1023
1024         // Loose goal touching check when running
1025         if(this.aistatus & AI_STATUS_RUNNING)
1026         if(this.goalcurrent.classname=="waypoint")
1027         if(!(this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT))
1028         if(vlen(this.velocity - eZ * this.velocity.z) >= autocvar_sv_maxspeed) // if -really- running
1029         {
1030                 if(vdist(this.origin - this.goalcurrent.origin, <, 150))
1031                 {
1032                         traceline(this.origin + this.view_ofs , this.goalcurrent.origin, true, NULL);
1033                         if(trace_fraction==1)
1034                         {
1035                                 // Detect personal waypoints
1036                                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1037                                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && this.goalcurrent.owner==this)
1038                                 {
1039                                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1040                                         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1041                                 }
1042
1043                                 navigation_poproute(this);
1044                         }
1045                 }
1046         }
1047
1048         while (this.goalcurrent && !IS_PLAYER(this.goalcurrent))
1049         {
1050                 vector gc_min = this.goalcurrent.absmin;
1051                 vector gc_max = this.goalcurrent.absmax;
1052                 if(this.goalcurrent.classname == "waypoint" && !this.goalcurrent.wpisbox)
1053                 {
1054                         gc_min = this.goalcurrent.origin - '1 1 1' * 12;
1055                         gc_max = this.goalcurrent.origin + '1 1 1' * 12;
1056                 }
1057                 if(!boxesoverlap(m1, m2, gc_min, gc_max))
1058                         break;
1059
1060                 if((this.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT))
1061                         break;
1062
1063                 // Detect personal waypoints
1064                 if(this.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1065                 if(this.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL && this.goalcurrent.owner==this)
1066                 {
1067                         this.aistatus &= ~AI_STATUS_WAYPOINT_PERSONAL_GOING;
1068                         this.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1069                 }
1070
1071                 navigation_poproute(this);
1072         }
1073 }
1074
1075 // begin a goal selection session (queries spawnfunc_waypoint network)
1076 void navigation_goalrating_start(entity this)
1077 {
1078         if(this.aistatus & AI_STATUS_STUCK)
1079                 return;
1080
1081         this.navigation_jetpack_goal = NULL;
1082         navigation_bestrating = -1;
1083         navigation_clearroute(this);
1084         navigation_bestgoal = NULL;
1085         navigation_markroutes(this, NULL);
1086 }
1087
1088 // ends a goal selection session (updates goal stack to the best goal)
1089 void navigation_goalrating_end(entity this)
1090 {
1091         if(this.aistatus & AI_STATUS_STUCK)
1092                 return;
1093
1094         navigation_routetogoal(this, navigation_bestgoal, this.origin);
1095         LOG_DEBUG("best goal ", this.goalcurrent.classname);
1096
1097         // If the bot got stuck then try to reach the farthest waypoint
1098         if (!this.goalentity && autocvar_bot_wander_enable)
1099         {
1100                 if (!(this.aistatus & AI_STATUS_STUCK))
1101                 {
1102                         LOG_DEBUG(this.netname, " cannot walk to any goal");
1103                         this.aistatus |= AI_STATUS_STUCK;
1104                 }
1105         }
1106 }
1107
1108 void botframe_updatedangerousobjects(float maxupdate)
1109 {
1110         vector m1, m2, v, o;
1111         float c, d, danger;
1112         c = 0;
1113         IL_EACH(g_waypoints, true,
1114         {
1115                 danger = 0;
1116                 m1 = it.absmin;
1117                 m2 = it.absmax;
1118                 IL_EACH(g_bot_dodge, it.bot_dodge,
1119                 {
1120                         v = it.origin;
1121                         v.x = bound(m1_x, v.x, m2_x);
1122                         v.y = bound(m1_y, v.y, m2_y);
1123                         v.z = bound(m1_z, v.z, m2_z);
1124                         o = (it.absmin + it.absmax) * 0.5;
1125                         d = waypoint_getdistancecost_simple(it.bot_dodgerating) - waypoint_getdistancecost(o, v);
1126                         if (d > 0)
1127                         {
1128                                 traceline(o, v, true, NULL);
1129                                 if (trace_fraction == 1)
1130                                         danger = danger + d;
1131                         }
1132                 });
1133                 it.dmg = danger;
1134                 c = c + 1;
1135                 if (c >= maxupdate)
1136                         break;
1137         });
1138 }
1139
1140 void navigation_unstuck(entity this)
1141 {
1142         float search_radius = 1000;
1143
1144         if (!autocvar_bot_wander_enable)
1145                 return;
1146
1147         if (!bot_waypoint_queue_owner)
1148         {
1149                 LOG_DEBUG(this.netname, " stuck, taking over the waypoints queue");
1150                 bot_waypoint_queue_owner = this;
1151                 bot_waypoint_queue_bestgoal = NULL;
1152                 bot_waypoint_queue_bestgoalrating = 0;
1153         }
1154
1155         if(bot_waypoint_queue_owner!=this)
1156                 return;
1157
1158         if (bot_waypoint_queue_goal)
1159         {
1160                 // evaluate the next goal on the queue
1161                 float d = vlen2(this.origin - bot_waypoint_queue_goal.origin);
1162                 LOG_DEBUG(this.netname, " evaluating ", bot_waypoint_queue_goal.classname, " with distance ", ftos(d));
1163                 if(tracewalk(bot_waypoint_queue_goal, this.origin, STAT(PL_MIN, this), STAT(PL_MAX, this), bot_waypoint_queue_goal.origin, bot_navigation_movemode))
1164                 {
1165                         if( d > bot_waypoint_queue_bestgoalrating)
1166                         {
1167                                 bot_waypoint_queue_bestgoalrating = d;
1168                                 bot_waypoint_queue_bestgoal = bot_waypoint_queue_goal;
1169                         }
1170                 }
1171                 bot_waypoint_queue_goal = bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal;
1172
1173                 if (!bot_waypoint_queue_goal)
1174                 {
1175                         if (bot_waypoint_queue_bestgoal)
1176                         {
1177                                 LOG_DEBUG(this.netname, " stuck, reachable waypoint found, heading to it");
1178                                 navigation_routetogoal(this, bot_waypoint_queue_bestgoal, this.origin);
1179                                 this.bot_strategytime = time + autocvar_bot_ai_strategyinterval;
1180                                 this.aistatus &= ~AI_STATUS_STUCK;
1181                         }
1182                         else
1183                         {
1184                                 LOG_DEBUG(this.netname, " stuck, cannot walk to any waypoint at all");
1185                         }
1186
1187                         bot_waypoint_queue_owner = NULL;
1188                 }
1189         }
1190         else
1191         {
1192                 if(bot_strategytoken!=this)
1193                         return;
1194
1195                 // build a new queue
1196                 LOG_DEBUG(this.netname, " stuck, scanning reachable waypoints within ", ftos(search_radius)," qu");
1197
1198                 entity first = NULL;
1199
1200                 FOREACH_ENTITY_RADIUS(this.origin, search_radius, it.classname == "waypoint" && !(it.wpflags & WAYPOINTFLAG_GENERATED),
1201                 {
1202                         if(bot_waypoint_queue_goal)
1203                                 bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal = it;
1204                         else
1205                                 first = it;
1206
1207                         bot_waypoint_queue_goal = it;
1208                         bot_waypoint_queue_goal.bot_waypoint_queue_nextgoal = NULL;
1209                 });
1210
1211                 if (first)
1212                         bot_waypoint_queue_goal = first;
1213                 else
1214                 {
1215                         LOG_DEBUG(this.netname, " stuck, cannot walk to any waypoint at all");
1216                         bot_waypoint_queue_owner = NULL;
1217                 }
1218         }
1219 }
1220
1221 // Support for debugging tracewalk visually
1222
1223 void debugresetnodes()
1224 {
1225         debuglastnode = '0 0 0';
1226 }
1227
1228 void debugnode(entity this, vector node)
1229 {
1230         if (!IS_PLAYER(this))
1231                 return;
1232
1233         if(debuglastnode=='0 0 0')
1234         {
1235                 debuglastnode = node;
1236                 return;
1237         }
1238
1239         te_lightning2(NULL, node, debuglastnode);
1240         debuglastnode = node;
1241 }
1242
1243 void debugnodestatus(vector position, float status)
1244 {
1245         vector c;
1246
1247         switch (status)
1248         {
1249                 case DEBUG_NODE_SUCCESS:
1250                         c = '0 15 0';
1251                         break;
1252                 case DEBUG_NODE_WARNING:
1253                         c = '15 15 0';
1254                         break;
1255                 case DEBUG_NODE_FAIL:
1256                         c = '15 0 0';
1257                         break;
1258                 default:
1259                         c = '15 15 15';
1260         }
1261
1262         te_customflash(position, 40,  2, c);
1263 }
1264
1265 // Support for debugging the goal stack visually
1266
1267 .float goalcounter;
1268 .vector lastposition;
1269
1270 // Debug the goal stack visually
1271 void debuggoalstack(entity this)
1272 {
1273         entity goal;
1274         vector org, go;
1275
1276         if(this.goalcounter==0)goal=this.goalcurrent;
1277         else if(this.goalcounter==1)goal=this.goalstack01;
1278         else if(this.goalcounter==2)goal=this.goalstack02;
1279         else if(this.goalcounter==3)goal=this.goalstack03;
1280         else if(this.goalcounter==4)goal=this.goalstack04;
1281         else if(this.goalcounter==5)goal=this.goalstack05;
1282         else if(this.goalcounter==6)goal=this.goalstack06;
1283         else if(this.goalcounter==7)goal=this.goalstack07;
1284         else if(this.goalcounter==8)goal=this.goalstack08;
1285         else if(this.goalcounter==9)goal=this.goalstack09;
1286         else if(this.goalcounter==10)goal=this.goalstack10;
1287         else if(this.goalcounter==11)goal=this.goalstack11;
1288         else if(this.goalcounter==12)goal=this.goalstack12;
1289         else if(this.goalcounter==13)goal=this.goalstack13;
1290         else if(this.goalcounter==14)goal=this.goalstack14;
1291         else if(this.goalcounter==15)goal=this.goalstack15;
1292         else if(this.goalcounter==16)goal=this.goalstack16;
1293         else if(this.goalcounter==17)goal=this.goalstack17;
1294         else if(this.goalcounter==18)goal=this.goalstack18;
1295         else if(this.goalcounter==19)goal=this.goalstack19;
1296         else if(this.goalcounter==20)goal=this.goalstack20;
1297         else if(this.goalcounter==21)goal=this.goalstack21;
1298         else if(this.goalcounter==22)goal=this.goalstack22;
1299         else if(this.goalcounter==23)goal=this.goalstack23;
1300         else if(this.goalcounter==24)goal=this.goalstack24;
1301         else if(this.goalcounter==25)goal=this.goalstack25;
1302         else if(this.goalcounter==26)goal=this.goalstack26;
1303         else if(this.goalcounter==27)goal=this.goalstack27;
1304         else if(this.goalcounter==28)goal=this.goalstack28;
1305         else if(this.goalcounter==29)goal=this.goalstack29;
1306         else if(this.goalcounter==30)goal=this.goalstack30;
1307         else if(this.goalcounter==31)goal=this.goalstack31;
1308         else goal=NULL;
1309
1310         if(goal==NULL)
1311         {
1312                 this.goalcounter = 0;
1313                 this.lastposition='0 0 0';
1314                 return;
1315         }
1316
1317         if(this.lastposition=='0 0 0')
1318                 org = this.origin;
1319         else
1320                 org = this.lastposition;
1321
1322
1323         go = ( goal.absmin + goal.absmax ) * 0.5;
1324         te_lightning2(NULL, org, go);
1325         this.lastposition = go;
1326
1327         this.goalcounter++;
1328 }