qcsrc/server/bot/default/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "bot.qh"
   6 #include "navigation.qh"
   7
   8 #include <common/state.qh>
   9
  10 #include "../../antilag.qh"
  11
  12 #include <common/constants.qh>
  13 #include <common/net_linked.qh>
  14 #include <common/physics/player.qh>
  15
  16 #include <lib/warpzone/common.qh>
  17 #include <lib/warpzone/util_server.qh>
  18
  19 .entity spawnpointmodel;
  20 void waypoint_unreachable(entity pl)
  21 {
  22         IL_EACH(g_waypoints, true,
  23         {
  24                 it.colormod = '0.5 0.5 0.5';
  25                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  26         });
  27
  28         entity e2 = navigation_findnearestwaypoint(pl, false);
  29         if(!e2)
  30         {
  31                 LOG_INFOF("Can't find any waypoint nearby\n");
  32                 return;
  33         }
  34
  35         navigation_markroutes(pl, e2);
  36
  37         int j = 0;
  38         int m = 0;
  39         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  40         {
  41                 LOG_INFO("unreachable: ", etos(it), " ", vtos(it.origin), "\n");
  42                 it.colormod_z = 8;
  43                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
  44                 j++;
  45                 m++;
  46         });
  47         if (j) LOG_INFOF("%d waypoints cannot be reached from here in any way (marked with blue light)\n", j);
  48         navigation_markroutes_inverted(e2);
  49
  50         j = 0;
  51         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  52         {
  53                 LOG_INFO("cannot reach me: ", etos(it), " ", vtos(it.origin), "\n");
  54                 it.colormod_x = 8;
  55                 if (!(it.effects & EF_NODEPTHTEST))  // not already reported before
  56                         m++;
  57                 it.effects |= EF_NODEPTHTEST | EF_RED;
  58                 j++;
  59         });
  60         if (j) LOG_INFOF("%d waypoints cannot walk to here in any way (marked with red light)\n", j);
  61         if (m) LOG_INFOF("%d waypoints have been marked total\n", m);
  62
  63         j = 0;
  64         IL_EACH(g_spawnpoints, true,
  65         {
  66                 if (navigation_findnearestwaypoint(it, false))
  67                 {
  68                         if(it.spawnpointmodel)
  69                         {
  70                                 delete(it.spawnpointmodel);
  71                                 it.spawnpointmodel = NULL;
  72                         }
  73                 }
  74                 else
  75                 {
  76                         if(!it.spawnpointmodel)
  77                         {
  78                                 tracebox(it.origin, PL_MIN_CONST, PL_MAX_CONST, it.origin - '0 0 512', MOVE_NOMONSTERS, NULL);
  79                                 entity e = new(spawnpointmodel);
  80                                 vector org = trace_endpos + eZ;
  81                                 setorigin(e, org);
  82                                 e.solid = SOLID_TRIGGER;
  83                                 it.spawnpointmodel = e;
  84                         }
  85                         LOG_INFO("spawn without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
  86                         it.spawnpointmodel.effects |= EF_NODEPTHTEST;
  87                         _setmodel(it.spawnpointmodel, pl.model);
  88                         it.spawnpointmodel.frame = pl.frame;
  89                         it.spawnpointmodel.skin = pl.skin;
  90                         it.spawnpointmodel.colormap = pl.colormap;
  91                         it.spawnpointmodel.colormod = pl.colormod;
  92                         it.spawnpointmodel.glowmod = pl.glowmod;
  93                         setsize(it.spawnpointmodel, PL_MIN_CONST, PL_MAX_CONST);
  94                         j++;
  95                 }
  96         });
  97         if (j) LOG_INFOF("%d spawnpoints have no nearest waypoint (marked by player model)\n", j);
  98
  99         j = 0;
 100         IL_EACH(g_items, true,
 101         {
 102                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
 103                 it.colormod = '0.5 0.5 0.5';
 104         });
 105         IL_EACH(g_items, true,
 106         {
 107                 if (navigation_findnearestwaypoint(it, false))
 108                         continue;
 109                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 110                 it.effects |= EF_NODEPTHTEST | EF_RED;
 111                 it.colormod_x = 8;
 112                 j++;
 113         });
 114         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked away from (marked with red light)\n", j);
 115
 116         j = 0;
 117         IL_EACH(g_items, true,
 118         {
 119                 if (navigation_findnearestwaypoint(it, true))
 120                         continue;
 121                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 122                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
 123                 it.colormod_z = 8;
 124                 j++;
 125         });
 126         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked to (marked with blue light)\n", j);
 127 }
 128
 129 vector waypoint_getSymmetricalOrigin(vector org, int ctf_flags)
 130 {
 131         vector new_org = org;
 132         if (fabs(autocvar_g_waypointeditor_symmetrical) == 1)
 133         {
 134                 vector map_center = havocbot_middlepoint;
 135                 if (autocvar_g_waypointeditor_symmetrical == -1)
 136                         map_center = autocvar_g_waypointeditor_symmetrical_origin;
 137
 138                 new_org = Rotate(org - map_center, 360 * DEG2RAD / ctf_flags) + map_center;
 139         }
 140         else if (fabs(autocvar_g_waypointeditor_symmetrical) == 2)
 141         {
 142                 float m = havocbot_symmetryaxis_equation.x;
 143                 float q = havocbot_symmetryaxis_equation.y;
 144                 if (autocvar_g_waypointeditor_symmetrical == -2)
 145                 {
 146                         m = autocvar_g_waypointeditor_symmetrical_axis.x;
 147                         q = autocvar_g_waypointeditor_symmetrical_axis.y;
 148                 }
 149
 150                 new_org.x = (1 / (1 + m*m)) * ((1 - m*m) * org.x + 2 * m * org.y - 2 * m * q);
 151                 new_org.y = (1 / (1 + m*m)) * (2 * m * org.x + (m*m - 1) * org.y + 2 * q);
 152         }
 153         new_org.z = org.z;
 154         return new_org;
 155 }
 156
 157 void waypoint_setupmodel(entity wp)
 158 {
 159         if (autocvar_g_waypointeditor)
 160         {
 161                 // TODO: add some sort of visible box in edit mode for box waypoints
 162                 vector m1 = wp.mins;
 163                 vector m2 = wp.maxs;
 164                 setmodel(wp, MDL_WAYPOINT);
 165                 setsize(wp, m1, m2);
 166                 wp.effects = EF_LOWPRECISION;
 167                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 168                         wp.colormod = '1 0 0';
 169                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 170                         wp.colormod = '1 1 0';
 171                 else
 172                         wp.colormod = '1 1 1';
 173         }
 174         else
 175                 wp.model = "";
 176 }
 177
 178 // create a new spawnfunc_waypoint and automatically link it to other waypoints, and link
 179 // them back to it as well
 180 // (suitable for spawnfunc_waypoint editor)
 181 entity waypoint_spawn(vector m1, vector m2, float f)
 182 {
 183         if(!(f & WAYPOINTFLAG_PERSONAL))
 184         {
 185                 vector em1 = m1;
 186                 vector em2 = m2;
 187                 if (m1 == m2)
 188                 {
 189                         em1 = m1 - '8 8 8';
 190                         em2 = m2 + '8 8 8';
 191                 }
 192                 IL_EACH(g_waypoints, boxesoverlap(em1, em2, it.absmin, it.absmax),
 193                 {
 194                         return it;
 195                 });
 196         }
 197
 198         entity w = new(waypoint);
 199         IL_PUSH(g_waypoints, w);
 200         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 201         w.wpflags = f;
 202         w.solid = SOLID_TRIGGER;
 203         setorigin(w, (m1 + m2) * 0.5);
 204         setsize(w, m1 - w.origin, m2 - w.origin);
 205         if (w.size)
 206                 w.wpisbox = true;
 207
 208         if(!w.wpisbox)
 209         {
 210                 setsize(w, PL_MIN_CONST - '1 1 0', PL_MAX_CONST + '1 1 0');
 211                 if(!move_out_of_solid(w))
 212                 {
 213                         if(!(f & WAYPOINTFLAG_GENERATED))
 214                         {
 215                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin));
 216                                 delete(w);
 217                                 return NULL;
 218                         }
 219                         else
 220                         {
 221                                 if(autocvar_developer)
 222                                 {
 223                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin), "\n");
 224                                         backtrace("Waypoint stuck");
 225                                 }
 226                         }
 227                 }
 228                 setsize(w, '0 0 0', '0 0 0');
 229         }
 230
 231         waypoint_clearlinks(w);
 232         //waypoint_schedulerelink(w);
 233
 234         waypoint_setupmodel(w);
 235
 236         return w;
 237 }
 238
 239 void waypoint_spawn_fromeditor(entity pl)
 240 {
 241         entity e;
 242         vector org = pl.origin;
 243         int ctf_flags = havocbot_symmetryaxis_equation.z;
 244         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 245                    || (autocvar_g_waypointeditor_symmetrical < 0));
 246         int order = ctf_flags;
 247         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 248         {
 249                 order = autocvar_g_waypointeditor_symmetrical_order;
 250                 ctf_flags = order;
 251         }
 252
 253         if(!PHYS_INPUT_BUTTON_CROUCH(pl))
 254         {
 255                 // snap waypoint to item's origin if close enough
 256                 IL_EACH(g_items, true,
 257                 {
 258                         vector item_org = (it.absmin + it.absmax) * 0.5;
 259                         item_org.z = it.absmin.z - PL_MIN_CONST.z;
 260                         if(vlen(item_org - org) < 30)
 261                         {
 262                                 org = item_org;
 263                                 break;
 264                         }
 265                 });
 266         }
 267
 268         LABEL(add_wp);
 269         e = waypoint_spawn(org, org, 0);
 270         waypoint_schedulerelink(e);
 271         bprint(strcat("Waypoint spawned at ", vtos(org), "\n"));
 272         if(sym)
 273         {
 274                 org = waypoint_getSymmetricalOrigin(e.origin, ctf_flags);
 275                 if (vdist(org - pl.origin, >, 32))
 276                 {
 277                         if(order > 2)
 278                                 order--;
 279                         else
 280                                 sym = false;
 281                         goto add_wp;
 282                 }
 283         }
 284 }
 285
 286 void waypoint_remove(entity wp)
 287 {
 288         // tell all waypoints linked to wp that they need to relink
 289         IL_EACH(g_waypoints, it != wp,
 290         {
 291                 if (waypoint_islinked(it, wp))
 292                         waypoint_removelink(it, wp);
 293         });
 294         delete(wp);
 295 }
 296
 297 void waypoint_remove_fromeditor(entity pl)
 298 {
 299         entity e = navigation_findnearestwaypoint(pl, false);
 300
 301         int ctf_flags = havocbot_symmetryaxis_equation.z;
 302         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 303                    || (autocvar_g_waypointeditor_symmetrical < 0));
 304         int order = ctf_flags;
 305         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 306         {
 307                 order = autocvar_g_waypointeditor_symmetrical_order;
 308                 ctf_flags = order;
 309         }
 310
 311         LABEL(remove_wp);
 312         if (!e) return;
 313         if (e.wpflags & WAYPOINTFLAG_GENERATED) return;
 314
 315         if (e.wphardwired)
 316         {
 317                 LOG_INFO("^1Warning: ^7Removal of hardwired waypoints is not allowed in the editor. Please remove links from/to this waypoint (", vtos(e.origin), ") by hand from maps/", mapname, ".waypoints.hardwired\n");
 318                 return;
 319         }
 320
 321         entity wp_sym = NULL;
 322         if (sym)
 323         {
 324                 vector org = waypoint_getSymmetricalOrigin(e.origin, ctf_flags);
 325                 FOREACH_ENTITY_CLASS("waypoint", !(it.wpflags & WAYPOINTFLAG_GENERATED), {
 326                         if(vdist(org - it.origin, <, 3))
 327                         {
 328                                 wp_sym = it;
 329                                 break;
 330                         }
 331                 });
 332         }
 333
 334         bprint(strcat("Waypoint removed at ", vtos(e.origin), "\n"));
 335         waypoint_remove(e);
 336
 337         if (sym && wp_sym)
 338         {
 339                 e = wp_sym;
 340                 if(order > 2)
 341                         order--;
 342                 else
 343                         sym = false;
 344                 goto remove_wp;
 345         }
 346 }
 347
 348 void waypoint_removelink(entity from, entity to)
 349 {
 350         if (from == to || (from.wpflags & WAYPOINTFLAG_NORELINK))
 351                 return;
 352
 353         bool found = false;
 354         if (!found && from.wp00 == to) found = true; if (found) {from.wp00 = from.wp01; from.wp00mincost = from.wp01mincost;}
 355         if (!found && from.wp01 == to) found = true; if (found) {from.wp01 = from.wp02; from.wp01mincost = from.wp02mincost;}
 356         if (!found && from.wp02 == to) found = true; if (found) {from.wp02 = from.wp03; from.wp02mincost = from.wp03mincost;}
 357         if (!found && from.wp03 == to) found = true; if (found) {from.wp03 = from.wp04; from.wp03mincost = from.wp04mincost;}
 358         if (!found && from.wp04 == to) found = true; if (found) {from.wp04 = from.wp05; from.wp04mincost = from.wp05mincost;}
 359         if (!found && from.wp05 == to) found = true; if (found) {from.wp05 = from.wp06; from.wp05mincost = from.wp06mincost;}
 360         if (!found && from.wp06 == to) found = true; if (found) {from.wp06 = from.wp07; from.wp06mincost = from.wp07mincost;}
 361         if (!found && from.wp07 == to) found = true; if (found) {from.wp07 = from.wp08; from.wp07mincost = from.wp08mincost;}
 362         if (!found && from.wp08 == to) found = true; if (found) {from.wp08 = from.wp09; from.wp08mincost = from.wp09mincost;}
 363         if (!found && from.wp09 == to) found = true; if (found) {from.wp09 = from.wp10; from.wp09mincost = from.wp10mincost;}
 364         if (!found && from.wp10 == to) found = true; if (found) {from.wp10 = from.wp11; from.wp10mincost = from.wp11mincost;}
 365         if (!found && from.wp11 == to) found = true; if (found) {from.wp11 = from.wp12; from.wp11mincost = from.wp12mincost;}
 366         if (!found && from.wp12 == to) found = true; if (found) {from.wp12 = from.wp13; from.wp12mincost = from.wp13mincost;}
 367         if (!found && from.wp13 == to) found = true; if (found) {from.wp13 = from.wp14; from.wp13mincost = from.wp14mincost;}
 368         if (!found && from.wp14 == to) found = true; if (found) {from.wp14 = from.wp15; from.wp14mincost = from.wp15mincost;}
 369         if (!found && from.wp15 == to) found = true; if (found) {from.wp15 = from.wp16; from.wp15mincost = from.wp16mincost;}
 370         if (!found && from.wp16 == to) found = true; if (found) {from.wp16 = from.wp17; from.wp16mincost = from.wp17mincost;}
 371         if (!found && from.wp17 == to) found = true; if (found) {from.wp17 = from.wp18; from.wp17mincost = from.wp18mincost;}
 372         if (!found && from.wp18 == to) found = true; if (found) {from.wp18 = from.wp19; from.wp18mincost = from.wp19mincost;}
 373         if (!found && from.wp19 == to) found = true; if (found) {from.wp19 = from.wp20; from.wp19mincost = from.wp20mincost;}
 374         if (!found && from.wp20 == to) found = true; if (found) {from.wp20 = from.wp21; from.wp20mincost = from.wp21mincost;}
 375         if (!found && from.wp21 == to) found = true; if (found) {from.wp21 = from.wp22; from.wp21mincost = from.wp22mincost;}
 376         if (!found && from.wp22 == to) found = true; if (found) {from.wp22 = from.wp23; from.wp22mincost = from.wp23mincost;}
 377         if (!found && from.wp23 == to) found = true; if (found) {from.wp23 = from.wp24; from.wp23mincost = from.wp24mincost;}
 378         if (!found && from.wp24 == to) found = true; if (found) {from.wp24 = from.wp25; from.wp24mincost = from.wp25mincost;}
 379         if (!found && from.wp25 == to) found = true; if (found) {from.wp25 = from.wp26; from.wp25mincost = from.wp26mincost;}
 380         if (!found && from.wp26 == to) found = true; if (found) {from.wp26 = from.wp27; from.wp26mincost = from.wp27mincost;}
 381         if (!found && from.wp27 == to) found = true; if (found) {from.wp27 = from.wp28; from.wp27mincost = from.wp28mincost;}
 382         if (!found && from.wp28 == to) found = true; if (found) {from.wp28 = from.wp29; from.wp28mincost = from.wp29mincost;}
 383         if (!found && from.wp29 == to) found = true; if (found) {from.wp29 = from.wp30; from.wp29mincost = from.wp30mincost;}
 384         if (!found && from.wp30 == to) found = true; if (found) {from.wp30 = from.wp31; from.wp30mincost = from.wp31mincost;}
 385         if (found) {from.wp31 = NULL; from.wp31mincost = 10000000;}
 386 }
 387
 388 bool waypoint_islinked(entity from, entity to)
 389 {
 390         if (from.wp00 == to) return true;if (from.wp01 == to) return true;if (from.wp02 == to) return true;if (from.wp03 == to) return true;
 391         if (from.wp04 == to) return true;if (from.wp05 == to) return true;if (from.wp06 == to) return true;if (from.wp07 == to) return true;
 392         if (from.wp08 == to) return true;if (from.wp09 == to) return true;if (from.wp10 == to) return true;if (from.wp11 == to) return true;
 393         if (from.wp12 == to) return true;if (from.wp13 == to) return true;if (from.wp14 == to) return true;if (from.wp15 == to) return true;
 394         if (from.wp16 == to) return true;if (from.wp17 == to) return true;if (from.wp18 == to) return true;if (from.wp19 == to) return true;
 395         if (from.wp20 == to) return true;if (from.wp21 == to) return true;if (from.wp22 == to) return true;if (from.wp23 == to) return true;
 396         if (from.wp24 == to) return true;if (from.wp25 == to) return true;if (from.wp26 == to) return true;if (from.wp27 == to) return true;
 397         if (from.wp28 == to) return true;if (from.wp29 == to) return true;if (from.wp30 == to) return true;if (from.wp31 == to) return true;
 398         return false;
 399 }
 400
 401 void waypoint_updatecost_foralllinks()
 402 {
 403         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_TELEPORT),
 404         {
 405                 if(it.wp00) it.wp00mincost = waypoint_getlinkcost(it, it.wp00);
 406                 if(it.wp01) it.wp01mincost = waypoint_getlinkcost(it, it.wp01);
 407                 if(it.wp02) it.wp02mincost = waypoint_getlinkcost(it, it.wp02);
 408                 if(it.wp03) it.wp03mincost = waypoint_getlinkcost(it, it.wp03);
 409                 if(it.wp04) it.wp04mincost = waypoint_getlinkcost(it, it.wp04);
 410                 if(it.wp05) it.wp05mincost = waypoint_getlinkcost(it, it.wp05);
 411                 if(it.wp06) it.wp06mincost = waypoint_getlinkcost(it, it.wp06);
 412                 if(it.wp07) it.wp07mincost = waypoint_getlinkcost(it, it.wp07);
 413                 if(it.wp08) it.wp08mincost = waypoint_getlinkcost(it, it.wp08);
 414                 if(it.wp09) it.wp09mincost = waypoint_getlinkcost(it, it.wp09);
 415                 if(it.wp10) it.wp10mincost = waypoint_getlinkcost(it, it.wp10);
 416                 if(it.wp11) it.wp11mincost = waypoint_getlinkcost(it, it.wp11);
 417                 if(it.wp12) it.wp12mincost = waypoint_getlinkcost(it, it.wp12);
 418                 if(it.wp13) it.wp13mincost = waypoint_getlinkcost(it, it.wp13);
 419                 if(it.wp14) it.wp14mincost = waypoint_getlinkcost(it, it.wp14);
 420                 if(it.wp15) it.wp15mincost = waypoint_getlinkcost(it, it.wp15);
 421                 if(it.wp16) it.wp16mincost = waypoint_getlinkcost(it, it.wp16);
 422                 if(it.wp17) it.wp17mincost = waypoint_getlinkcost(it, it.wp17);
 423                 if(it.wp18) it.wp18mincost = waypoint_getlinkcost(it, it.wp18);
 424                 if(it.wp19) it.wp19mincost = waypoint_getlinkcost(it, it.wp19);
 425                 if(it.wp20) it.wp20mincost = waypoint_getlinkcost(it, it.wp20);
 426                 if(it.wp21) it.wp21mincost = waypoint_getlinkcost(it, it.wp21);
 427                 if(it.wp22) it.wp22mincost = waypoint_getlinkcost(it, it.wp22);
 428                 if(it.wp23) it.wp23mincost = waypoint_getlinkcost(it, it.wp23);
 429                 if(it.wp24) it.wp24mincost = waypoint_getlinkcost(it, it.wp24);
 430                 if(it.wp25) it.wp25mincost = waypoint_getlinkcost(it, it.wp25);
 431                 if(it.wp26) it.wp26mincost = waypoint_getlinkcost(it, it.wp26);
 432                 if(it.wp27) it.wp27mincost = waypoint_getlinkcost(it, it.wp27);
 433                 if(it.wp28) it.wp28mincost = waypoint_getlinkcost(it, it.wp28);
 434                 if(it.wp29) it.wp29mincost = waypoint_getlinkcost(it, it.wp29);
 435                 if(it.wp30) it.wp30mincost = waypoint_getlinkcost(it, it.wp30);
 436                 if(it.wp31) it.wp31mincost = waypoint_getlinkcost(it, it.wp31);
 437         });
 438 }
 439
 440 float waypoint_getdistancecost_simple(float dist)
 441 {
 442         if(skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 443                 return dist / (autocvar_sv_maxspeed * 1.25);
 444         return dist / autocvar_sv_maxspeed;
 445 }
 446
 447 float waypoint_getdistancecost(vector from, vector to)
 448 {
 449         float c = waypoint_getdistancecost_simple(vlen(to - from));
 450
 451         float height = from.z - to.z;
 452         if(height > jumpheight_vec.z && autocvar_sv_gravity > 0)
 453         {
 454                 float height_cost = sqrt(height / (autocvar_sv_gravity / 2));
 455                 c = waypoint_getdistancecost_simple(vlen(vec2(to - from))); // xy distance cost
 456                 if(height_cost > c)
 457                         c = height_cost;
 458         }
 459         return c;
 460 }
 461
 462 float waypoint_getlinkcost(entity from, entity to)
 463 {
 464         vector v1 = from.origin;
 465         vector v2 = to.origin;
 466         if (from.wpisbox)
 467         {
 468                 vector m1 = to.absmin, m2 = to.absmax;
 469                 v1_x = bound(m1_x, v1_x, m2_x);
 470                 v1_y = bound(m1_y, v1_y, m2_y);
 471                 v1_z = bound(m1_z, v1_z, m2_z);
 472         }
 473         if (to.wpisbox)
 474         {
 475                 vector m1 = from.absmin, m2 = from.absmax;
 476                 v2_x = bound(m1_x, v2_x, m2_x);
 477                 v2_y = bound(m1_y, v2_y, m2_y);
 478                 v2_z = bound(m1_z, v2_z, m2_z);
 479         }
 480         return waypoint_getdistancecost(v1, v2);
 481 }
 482
 483 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
 484 // if c == -1 automatically determine cost of the link
 485 void waypoint_addlink_customcost(entity from, entity to, float c)
 486 {
 487         if (from == to || waypoint_islinked(from, to))
 488                 return;
 489         if (c == -1 && (from.wpflags & WAYPOINTFLAG_NORELINK))
 490                 return;
 491
 492         if(c == -1)
 493                 c = waypoint_getlinkcost(from, to);
 494
 495         if (from.wp31mincost < c) return;
 496         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 497         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 498         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 499         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 500         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 501         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 502         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 503         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 504         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 505         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 506         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 507         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 508         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 509         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 510         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 511         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 512         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 513         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 514         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 515         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 516         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 517         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 518         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 519         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 520         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 521         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 522         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 523         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 524         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 525         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 526         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 527         from.wp00 = to;from.wp00mincost = c;return;
 528 }
 529
 530 void waypoint_addlink(entity from, entity to)
 531 {
 532         waypoint_addlink_customcost(from, to, -1);
 533 }
 534
 535 // relink this spawnfunc_waypoint
 536 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
 537 // (SLOW!)
 538 void waypoint_think(entity this)
 539 {
 540         vector sv, sm1, sm2, ev, em1, em2, dv;
 541
 542         bot_calculate_stepheightvec();
 543
 544         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 545
 546         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
 547         sm1 = this.origin + this.mins;
 548         sm2 = this.origin + this.maxs;
 549         IL_EACH(g_waypoints, this != it,
 550         {
 551                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
 552                 {
 553                         waypoint_addlink(this, it);
 554                         waypoint_addlink(it, this);
 555                 }
 556                 else
 557                 {
 558                         ++relink_total;
 559                         if(!checkpvs(this.origin, it))
 560                         {
 561                                 ++relink_pvsculled;
 562                                 continue;
 563                         }
 564                         sv = it.origin;
 565                         sv.x = bound(sm1_x, sv.x, sm2_x);
 566                         sv.y = bound(sm1_y, sv.y, sm2_y);
 567                         sv.z = bound(sm1_z, sv.z, sm2_z);
 568                         ev = this.origin;
 569                         em1 = it.origin + it.mins;
 570                         em2 = it.origin + it.maxs;
 571                         ev.x = bound(em1_x, ev.x, em2_x);
 572                         ev.y = bound(em1_y, ev.y, em2_y);
 573                         ev.z = bound(em1_z, ev.z, em2_z);
 574                         dv = ev - sv;
 575                         dv.z = 0;
 576                         if(vdist(dv, >=, 1050)) // max search distance in XY
 577                         {
 578                                 ++relink_lengthculled;
 579                                 continue;
 580                         }
 581                         float sv_deviation = 0;
 582                         float ev_deviation = 0;
 583                         navigation_testtracewalk = 0;
 584                         if (!this.wpisbox)
 585                         {
 586                                 tracebox(sv - PL_MIN_CONST.z * '0 0 1', PL_MIN_CONST, PL_MAX_CONST, sv, false, this);
 587                                 if (!trace_startsolid)
 588                                 {
 589                                         //dprint("sv deviation", vtos(trace_endpos - sv), "\n");
 590                                         sv_deviation = trace_endpos.z + 1 - sv.z;
 591                                         sv = trace_endpos + '0 0 1';
 592                                 }
 593                         }
 594                         if (!it.wpisbox)
 595                         {
 596                                 tracebox(ev - PL_MIN_CONST.z * '0 0 1', PL_MIN_CONST, PL_MAX_CONST, ev, false, it);
 597                                 if (!trace_startsolid)
 598                                 {
 599                                         //dprint("ev deviation", vtos(trace_endpos - ev), "\n");
 600                                         ev_deviation = trace_endpos.z + 1 - ev.z;
 601                                         ev = trace_endpos + '0 0 1';
 602                                 }
 603                         }
 604                         //traceline(this.origin, it.origin, false, NULL);
 605                         //if (trace_fraction == 1)
 606                         if (this.wpisbox)
 607                                 relink_walkculled += 0.5;
 608                         else
 609                         {
 610                                 vector dest = ev;
 611                                 dest.z = em1.z + ev_deviation;
 612                                 float dest_height = em2.z - em1.z;
 613                                 if(tracewalk(this, sv, PL_MIN_CONST, PL_MAX_CONST, dest, dest_height, MOVE_NOMONSTERS))
 614                                         waypoint_addlink(this, it);
 615                                 else
 616                                         relink_walkculled += 0.5;
 617                         }
 618
 619                         if (it.wpisbox)
 620                                 relink_walkculled += 0.5;
 621                         else
 622                         {
 623                                 vector dest = sv;
 624                                 dest.z = sm1.z + sv_deviation;
 625                                 float dest_height = sm2.z - sm1.z;
 626                                 if(tracewalk(it, ev, PL_MIN_CONST, PL_MAX_CONST, dest, dest_height, MOVE_NOMONSTERS))
 627                                         waypoint_addlink(it, this);
 628                                 else
 629                                         relink_walkculled += 0.5;
 630                         }
 631                 }
 632         });
 633         navigation_testtracewalk = 0;
 634         this.wplinked = true;
 635 }
 636
 637 void waypoint_clearlinks(entity wp)
 638 {
 639         // clear links to other waypoints
 640         float f = 10000000;
 641         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
 642         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
 643         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
 644         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
 645
 646         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
 647         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
 648         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
 649         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
 650
 651         wp.wplinked = false;
 652 }
 653
 654 // tell a spawnfunc_waypoint to relink
 655 void waypoint_schedulerelink(entity wp)
 656 {
 657         if (wp == NULL)
 658                 return;
 659
 660         waypoint_setupmodel(wp);
 661         wp.wpisbox = vdist(wp.size, >, 0);
 662         wp.enemy = NULL;
 663         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
 664                 wp.owner = NULL;
 665         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
 666                 waypoint_clearlinks(wp);
 667         // schedule an actual relink on next frame
 668         setthink(wp, waypoint_think);
 669         wp.nextthink = time;
 670         wp.effects = EF_LOWPRECISION;
 671 }
 672
 673 // spawnfunc_waypoint map entity
 674 spawnfunc(waypoint)
 675 {
 676         IL_PUSH(g_waypoints, this);
 677
 678         setorigin(this, this.origin);
 679         // schedule a relink after other waypoints have had a chance to spawn
 680         waypoint_clearlinks(this);
 681         //waypoint_schedulerelink(this);
 682 }
 683
 684 // tell all waypoints to relink
 685 // actually this is useful only to update relink_* stats
 686 void waypoint_schedulerelinkall()
 687 {
 688         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
 689         IL_EACH(g_waypoints, true,
 690         {
 691                 waypoint_schedulerelink(it);
 692         });
 693         waypoint_load_links_hardwired();
 694 }
 695
 696 // Load waypoint links from file
 697 bool waypoint_load_links()
 698 {
 699         string filename, s;
 700         float file, tokens, c = 0, found;
 701         entity wp_from = NULL, wp_to;
 702         vector wp_to_pos, wp_from_pos;
 703         filename = strcat("maps/", mapname);
 704         filename = strcat(filename, ".waypoints.cache");
 705         file = fopen(filename, FILE_READ);
 706
 707         if (file < 0)
 708         {
 709                 LOG_TRACE("waypoint links load from ");
 710                 LOG_TRACE(filename);
 711                 LOG_TRACE(" failed");
 712                 return false;
 713         }
 714
 715         while ((s = fgets(file)))
 716         {
 717                 tokens = tokenizebyseparator(s, "*");
 718
 719                 if (tokens!=2)
 720                 {
 721                         // bad file format
 722                         fclose(file);
 723                         return false;
 724                 }
 725
 726                 wp_from_pos     = stov(argv(0));
 727                 wp_to_pos       = stov(argv(1));
 728
 729                 // Search "from" waypoint
 730                 if(!wp_from || wp_from.origin!=wp_from_pos)
 731                 {
 732                         wp_from = findradius(wp_from_pos, 1);
 733                         found = false;
 734                         while(wp_from)
 735                         {
 736                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
 737                                 if(wp_from.classname == "waypoint")
 738                                 {
 739                                         found = true;
 740                                         break;
 741                                 }
 742                                 wp_from = wp_from.chain;
 743                         }
 744
 745                         if(!found)
 746                         {
 747                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from_pos));
 748                                 continue;
 749                         }
 750
 751                 }
 752
 753                 // Search "to" waypoint
 754                 wp_to = findradius(wp_to_pos, 1);
 755                 found = false;
 756                 while(wp_to)
 757                 {
 758                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
 759                         if(wp_to.classname == "waypoint")
 760                         {
 761                                 found = true;
 762                                 break;
 763                         }
 764                         wp_to = wp_to.chain;
 765                 }
 766
 767                 if(!found)
 768                 {
 769                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to_pos));
 770                         continue;
 771                 }
 772
 773                 ++c;
 774                 waypoint_addlink(wp_from, wp_to);
 775         }
 776
 777         fclose(file);
 778
 779         LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.cache");
 780
 781         botframe_cachedwaypointlinks = true;
 782         return true;
 783 }
 784
 785 void waypoint_load_or_remove_links_hardwired(bool removal_mode)
 786 {
 787         string filename, s;
 788         float file, tokens, c = 0, found;
 789         entity wp_from = NULL, wp_to;
 790         vector wp_to_pos, wp_from_pos;
 791         filename = strcat("maps/", mapname);
 792         filename = strcat(filename, ".waypoints.hardwired");
 793         file = fopen(filename, FILE_READ);
 794
 795         botframe_loadedforcedlinks = true;
 796
 797         if (file < 0)
 798         {
 799                 if(!removal_mode)
 800                         LOG_TRACE("waypoint links load from ", filename, " failed");
 801                 return;
 802         }
 803
 804         while ((s = fgets(file)))
 805         {
 806                 if(substring(s, 0, 2)=="//")
 807                         continue;
 808
 809                 if(substring(s, 0, 1)=="#")
 810                         continue;
 811
 812                 tokens = tokenizebyseparator(s, "*");
 813
 814                 if (tokens!=2)
 815                         continue;
 816
 817                 wp_from_pos     = stov(argv(0));
 818                 wp_to_pos       = stov(argv(1));
 819
 820                 // Search "from" waypoint
 821                 if(!wp_from || wp_from.origin!=wp_from_pos)
 822                 {
 823                         wp_from = findradius(wp_from_pos, 5);
 824                         found = false;
 825                         while(wp_from)
 826                         {
 827                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
 828                                 if(wp_from.classname == "waypoint")
 829                                 {
 830                                         found = true;
 831                                         break;
 832                                 }
 833                                 wp_from = wp_from.chain;
 834                         }
 835
 836                         if(!found)
 837                         {
 838                                 if(!removal_mode)
 839                                         LOG_INFO(strcat("NOTICE: Can not find waypoint at ", vtos(wp_from_pos), ". Path skipped\n"));
 840                                 continue;
 841                         }
 842                 }
 843
 844                 // Search "to" waypoint
 845                 wp_to = findradius(wp_to_pos, 5);
 846                 found = false;
 847                 while(wp_to)
 848                 {
 849                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
 850                         if(wp_to.classname == "waypoint")
 851                         {
 852                                 found = true;
 853                                 break;
 854                         }
 855                         wp_to = wp_to.chain;
 856                 }
 857
 858                 if(!found)
 859                 {
 860                         if(!removal_mode)
 861                                 LOG_INFO(strcat("NOTICE: Can not find waypoint at ", vtos(wp_to_pos), ". Path skipped\n"));
 862                         continue;
 863                 }
 864
 865                 ++c;
 866                 if(removal_mode)
 867                 {
 868                         waypoint_removelink(wp_from, wp_to);
 869                         continue;
 870                 }
 871
 872                 waypoint_addlink(wp_from, wp_to);
 873                 wp_from.wphardwired = true;
 874                 wp_to.wphardwired = true;
 875         }
 876
 877         fclose(file);
 878
 879         if(!removal_mode)
 880                 LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired");
 881 }
 882
 883 void waypoint_load_links_hardwired() { waypoint_load_or_remove_links_hardwired(false); }
 884 void waypoint_remove_links_hardwired() { waypoint_load_or_remove_links_hardwired(true); }
 885
 886 entity waypoint_get_link(entity w, float i)
 887 {
 888         switch(i)
 889         {
 890                 case  0:return w.wp00;
 891                 case  1:return w.wp01;
 892                 case  2:return w.wp02;
 893                 case  3:return w.wp03;
 894                 case  4:return w.wp04;
 895                 case  5:return w.wp05;
 896                 case  6:return w.wp06;
 897                 case  7:return w.wp07;
 898                 case  8:return w.wp08;
 899                 case  9:return w.wp09;
 900                 case 10:return w.wp10;
 901                 case 11:return w.wp11;
 902                 case 12:return w.wp12;
 903                 case 13:return w.wp13;
 904                 case 14:return w.wp14;
 905                 case 15:return w.wp15;
 906                 case 16:return w.wp16;
 907                 case 17:return w.wp17;
 908                 case 18:return w.wp18;
 909                 case 19:return w.wp19;
 910                 case 20:return w.wp20;
 911                 case 21:return w.wp21;
 912                 case 22:return w.wp22;
 913                 case 23:return w.wp23;
 914                 case 24:return w.wp24;
 915                 case 25:return w.wp25;
 916                 case 26:return w.wp26;
 917                 case 27:return w.wp27;
 918                 case 28:return w.wp28;
 919                 case 29:return w.wp29;
 920                 case 30:return w.wp30;
 921                 case 31:return w.wp31;
 922                 default:return NULL;
 923         }
 924 }
 925
 926 // Save all waypoint links to a file
 927 void waypoint_save_links()
 928 {
 929         // temporarily remove hardwired links so they don't get saved among normal links
 930         waypoint_remove_links_hardwired();
 931
 932         string filename = sprintf("maps/%s.waypoints.cache", mapname);
 933         int file = fopen(filename, FILE_WRITE);
 934         if (file < 0)
 935         {
 936                 LOG_INFOF("waypoint link save to %s failed\n", filename);
 937                 return;
 938         }
 939
 940         int c = 0;
 941         IL_EACH(g_waypoints, true,
 942         {
 943                 for(int j = 0; j < 32; ++j)
 944                 {
 945                         entity link = waypoint_get_link(it, j);
 946                         if(link)
 947                         {
 948                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
 949                                 fputs(file, s);
 950                                 ++c;
 951                         }
 952                 }
 953         });
 954         fclose(file);
 955         botframe_cachedwaypointlinks = true;
 956
 957         LOG_INFOF("saved %d waypoint links to maps/%s.waypoints.cache\n", c, mapname);
 958
 959         waypoint_load_links_hardwired();
 960 }
 961
 962 // save waypoints to gamedir/data/maps/mapname.waypoints
 963 void waypoint_saveall()
 964 {
 965         string filename = sprintf("maps/%s.waypoints", mapname);
 966         int file = fopen(filename, FILE_WRITE);
 967         if (file < 0)
 968         {
 969                 waypoint_save_links(); // save anyway?
 970                 botframe_loadedforcedlinks = false;
 971
 972                 LOG_INFOF("waypoint links: save to %s failed\n", filename);
 973                 return;
 974         }
 975
 976         int c = 0;
 977         IL_EACH(g_waypoints, true,
 978         {
 979                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
 980                         continue;
 981
 982                 string s;
 983                 s = strcat(vtos(it.origin + it.mins), "\n");
 984                 s = strcat(s, vtos(it.origin + it.maxs));
 985                 s = strcat(s, "\n");
 986                 s = strcat(s, ftos(it.wpflags));
 987                 s = strcat(s, "\n");
 988                 fputs(file, s);
 989                 c++;
 990         });
 991         fclose(file);
 992         waypoint_save_links();
 993         botframe_loadedforcedlinks = false;
 994
 995         LOG_INFOF("saved %d waypoints to maps/%s.waypoints\n", c, mapname);
 996 }
 997
 998 // load waypoints from file
 999 float waypoint_loadall()
1000 {
1001         string filename, s;
1002         float file, cwp, cwb, fl;
1003         vector m1, m2;
1004         cwp = 0;
1005         cwb = 0;
1006         filename = strcat("maps/", mapname);
1007         filename = strcat(filename, ".waypoints");
1008         file = fopen(filename, FILE_READ);
1009         if (file >= 0)
1010         {
1011                 while ((s = fgets(file)))
1012                 {
1013                         m1 = stov(s);
1014                         s = fgets(file);
1015                         if (!s)
1016                                 break;
1017                         m2 = stov(s);
1018                         s = fgets(file);
1019                         if (!s)
1020                                 break;
1021                         fl = stof(s);
1022                         waypoint_spawn(m1, m2, fl);
1023                         if (m1 == m2)
1024                                 cwp = cwp + 1;
1025                         else
1026                                 cwb = cwb + 1;
1027                 }
1028                 fclose(file);
1029                 LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints");
1030         }
1031         else
1032         {
1033                 LOG_TRACE("waypoint load from ", filename, " failed");
1034         }
1035         return cwp + cwb;
1036 }
1037
1038 vector waypoint_fixorigin(vector position)
1039 {
1040         tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z), PL_MIN_CONST, PL_MAX_CONST, position + '0 0 -512', MOVE_NOMONSTERS, NULL);
1041         if(trace_fraction < 1)
1042                 position = trace_endpos;
1043         //traceline(position, position + '0 0 -512', MOVE_NOMONSTERS, NULL);
1044         //print("position is ", ftos(trace_endpos_z - position_z), " above solid\n");
1045         return position;
1046 }
1047
1048 void waypoint_spawnforitem_force(entity e, vector org)
1049 {
1050         // Fix the waypoint altitude if necessary
1051         org = waypoint_fixorigin(org);
1052
1053         // don't spawn an item spawnfunc_waypoint if it already exists
1054         IL_EACH(g_waypoints, true,
1055         {
1056                 if(it.wpisbox)
1057                 {
1058                         if(boxesoverlap(org, org, it.absmin, it.absmax))
1059                         {
1060                                 e.nearestwaypoint = it;
1061                                 return;
1062                         }
1063                 }
1064                 else
1065                 {
1066                         if(vdist(it.origin - org, <, 16))
1067                         {
1068                                 e.nearestwaypoint = it;
1069                                 return;
1070                         }
1071                 }
1072         });
1073
1074         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
1075 }
1076
1077 void waypoint_spawnforitem(entity e)
1078 {
1079         if(!bot_waypoints_for_items)
1080                 return;
1081
1082         waypoint_spawnforitem_force(e, e.origin);
1083 }
1084
1085 void waypoint_spawnforteleporter_boxes(entity e, int teleport_flag, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
1086 {
1087         entity w;
1088         entity dw;
1089         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | teleport_flag | WAYPOINTFLAG_NORELINK);
1090         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
1091         // one way link to the destination
1092         w.wp00 = dw;
1093         w.wp00mincost = timetaken; // this is just for jump pads
1094         // the teleporter's nearest spawnfunc_waypoint is this one
1095         // (teleporters are not goals, so this is probably useless)
1096         e.nearestwaypoint = w;
1097         e.nearestwaypointtimeout = -1;
1098 }
1099
1100 void waypoint_spawnforteleporter_v(entity e, vector org, vector destination, float timetaken)
1101 {
1102         org = waypoint_fixorigin(org);
1103         destination = waypoint_fixorigin(destination);
1104         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, org, org, destination, destination, timetaken);
1105 }
1106
1107 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken)
1108 {
1109         destination = waypoint_fixorigin(destination);
1110         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, e.absmin, e.absmax, destination, destination, timetaken);
1111 }
1112
1113 entity waypoint_spawnpersonal(entity this, vector position)
1114 {
1115         entity w;
1116
1117         // drop the waypoint to a proper location:
1118         //   first move it up by a player height
1119         //   then move it down to hit the floor with player bbox size
1120         position = waypoint_fixorigin(position);
1121
1122         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
1123         w.nearestwaypoint = NULL;
1124         w.nearestwaypointtimeout = 0;
1125         w.owner = this;
1126
1127         waypoint_schedulerelink(w);
1128
1129         return w;
1130 }
1131
1132 void waypoint_showlink(entity wp1, entity wp2, int display_type)
1133 {
1134         if (!(wp1 && wp2))
1135                 return;
1136
1137         if (wp1.wphardwired && wp2.wphardwired)
1138                 te_beam(NULL, wp1.origin, wp2.origin);
1139         else if (display_type == 1)
1140                 te_lightning2(NULL, wp1.origin, wp2.origin);
1141 }
1142
1143 void waypoint_showlinks_to(entity wp, int display_type)
1144 {
1145         IL_EACH(g_waypoints, it != wp,
1146         {
1147                 if (waypoint_islinked(it, wp))
1148                         waypoint_showlink(it, wp, display_type);
1149         });
1150 }
1151
1152 void waypoint_showlinks_from(entity wp, int display_type)
1153 {
1154         waypoint_showlink(wp.wp00, wp, display_type); waypoint_showlink(wp.wp16, wp, display_type);
1155         waypoint_showlink(wp.wp01, wp, display_type); waypoint_showlink(wp.wp17, wp, display_type);
1156         waypoint_showlink(wp.wp02, wp, display_type); waypoint_showlink(wp.wp18, wp, display_type);
1157         waypoint_showlink(wp.wp03, wp, display_type); waypoint_showlink(wp.wp19, wp, display_type);
1158         waypoint_showlink(wp.wp04, wp, display_type); waypoint_showlink(wp.wp20, wp, display_type);
1159         waypoint_showlink(wp.wp05, wp, display_type); waypoint_showlink(wp.wp21, wp, display_type);
1160         waypoint_showlink(wp.wp06, wp, display_type); waypoint_showlink(wp.wp22, wp, display_type);
1161         waypoint_showlink(wp.wp07, wp, display_type); waypoint_showlink(wp.wp23, wp, display_type);
1162         waypoint_showlink(wp.wp08, wp, display_type); waypoint_showlink(wp.wp24, wp, display_type);
1163         waypoint_showlink(wp.wp09, wp, display_type); waypoint_showlink(wp.wp25, wp, display_type);
1164         waypoint_showlink(wp.wp10, wp, display_type); waypoint_showlink(wp.wp26, wp, display_type);
1165         waypoint_showlink(wp.wp11, wp, display_type); waypoint_showlink(wp.wp27, wp, display_type);
1166         waypoint_showlink(wp.wp12, wp, display_type); waypoint_showlink(wp.wp28, wp, display_type);
1167         waypoint_showlink(wp.wp13, wp, display_type); waypoint_showlink(wp.wp29, wp, display_type);
1168         waypoint_showlink(wp.wp14, wp, display_type); waypoint_showlink(wp.wp30, wp, display_type);
1169         waypoint_showlink(wp.wp15, wp, display_type); waypoint_showlink(wp.wp31, wp, display_type);
1170 }
1171
1172 void botframe_showwaypointlinks()
1173 {
1174         if (time < botframe_waypointeditorlightningtime)
1175                 return;
1176         botframe_waypointeditorlightningtime = time + 0.5;
1177         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
1178         {
1179                 int display_type = 0;
1180                 entity head = navigation_findnearestwaypoint(it, false);
1181                 if (IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE)
1182                         display_type = 1; // default
1183                 else if(head && (head.wphardwired))
1184                         display_type = 2; // only hardwired
1185
1186                 if (display_type)
1187                 {
1188                         //navigation_testtracewalk = true;
1189                         //print("currently selected WP is ", etos(head), "\n");
1190                         //navigation_testtracewalk = false;
1191                         if (head)
1192                         {
1193                                 te_lightning2(NULL, head.origin, it.origin);
1194                                 if(PHYS_INPUT_BUTTON_CROUCH(it))
1195                                         waypoint_showlinks_to(head, display_type);
1196                                 else
1197                                         waypoint_showlinks_from(head, display_type);
1198                         }
1199                 }
1200         });
1201 }
1202
1203 float botframe_autowaypoints_fixdown(vector v)
1204 {
1205         tracebox(v, PL_MIN_CONST, PL_MAX_CONST, v + '0 0 -64', MOVE_NOMONSTERS, NULL);
1206         if(trace_fraction >= 1)
1207                 return 0;
1208         return 1;
1209 }
1210
1211 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
1212 {
1213         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
1214         {
1215                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
1216                 return 0;
1217         });
1218
1219         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
1220         return 1;
1221 }
1222
1223 // return value:
1224 //    1 = WP created
1225 //    0 = no action needed
1226 //   -1 = temp fail, try from world too
1227 //   -2 = permanent fail, do not retry
1228 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
1229 {
1230         // make it possible to go from p to wp, if we can
1231         // if wp is NULL, nearest is chosen
1232
1233         entity w;
1234         vector porg;
1235         float t, tmin, tmax;
1236         vector o;
1237         vector save;
1238
1239         if(!botframe_autowaypoints_fixdown(p.origin))
1240                 return -2;
1241         porg = trace_endpos;
1242
1243         if(wp)
1244         {
1245                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
1246
1247                 // if wp -> porg, then OK
1248                 float maxdist;
1249                 if(navigation_waypoint_will_link(wp.origin, porg, p, walkfromwp, 1050))
1250                 {
1251                         // we may find a better one
1252                         maxdist = vlen(wp.origin - porg);
1253                 }
1254                 else
1255                 {
1256                         // accept any "good"
1257                         maxdist = 2100;
1258                 }
1259
1260                 float bestdist = maxdist;
1261                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WAYPOINTFLAG_NORELINK),
1262                 {
1263                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
1264                         if(d < bestdist)
1265                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, walkfromwp, 1050))
1266                         if(navigation_waypoint_will_link(it.origin, porg, p, walkfromwp, 1050))
1267                         {
1268                                 bestdist = d;
1269                                 p.(fld) = it;
1270                         }
1271                 });
1272                 if(bestdist < maxdist)
1273                 {
1274                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)), "\n");
1275                         return 0;
1276                 }
1277
1278                 if(bestdist < 2100)
1279                 {
1280                         // we know maxdist < 2100
1281                         // so wp -> porg is still valid
1282                         // all is good
1283                         p.(fld) = wp;
1284                         return 0;
1285                 }
1286
1287                 // otherwise, no existing WP can fix our issues
1288         }
1289         else
1290         {
1291                 save = p.origin;
1292                 setorigin(p, porg);
1293                 w = navigation_findnearestwaypoint(p, walkfromwp);
1294                 setorigin(p, save);
1295                 if(w)
1296                 {
1297                         p.(fld) = w;
1298                         return 0;
1299                 }
1300         }
1301
1302         tmin = 0;
1303         tmax = 1;
1304         for (;;)
1305         {
1306                 if(tmax - tmin < 0.001)
1307                 {
1308                         // did not get a good candidate
1309                         return -1;
1310                 }
1311
1312                 t = (tmin + tmax) * 0.5;
1313                 o = antilag_takebackorigin(p, CS(p), time - t);
1314                 if(!botframe_autowaypoints_fixdown(o))
1315                         return -2;
1316                 o = trace_endpos;
1317
1318                 if(wp)
1319                 {
1320                         if(!navigation_waypoint_will_link(wp.origin, o, p, walkfromwp, 1050))
1321                         {
1322                                 // we cannot walk from wp.origin to o
1323                                 // get closer to tmax
1324                                 tmin = t;
1325                                 continue;
1326                         }
1327                 }
1328                 else
1329                 {
1330                         save = p.origin;
1331                         setorigin(p, o);
1332                         w = navigation_findnearestwaypoint(p, walkfromwp);
1333                         setorigin(p, save);
1334                         if(!w)
1335                         {
1336                                 // we cannot walk from any WP to o
1337                                 // get closer to tmax
1338                                 tmin = t;
1339                                 continue;
1340                         }
1341                 }
1342
1343                 // if we get here, o is valid regarding waypoints
1344                 // check if o is connected right to the player
1345                 // we break if it succeeds, as that means o is a good waypoint location
1346                 if(navigation_waypoint_will_link(o, porg, p, walkfromwp, 1050))
1347                         break;
1348
1349                 // o is no good, we need to get closer to the player
1350                 tmax = t;
1351         }
1352
1353         LOG_INFO("spawning a waypoint for connecting to ", etos(wp), "\n");
1354         botframe_autowaypoints_createwp(o, p, fld, 0);
1355         return 1;
1356 }
1357
1358 // automatically create missing waypoints
1359 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
1360 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
1361 {
1362         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
1363         if(r != -1)
1364                 return;
1365         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
1366         if(r != -1)
1367                 return;
1368
1369         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain\n");
1370         if(!botframe_autowaypoints_fixdown(p.origin))
1371                 return; // shouldn't happen, caught above
1372         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
1373 }
1374
1375 void botframe_deleteuselesswaypoints()
1376 {
1377         IL_EACH(g_items, it.bot_pickup,
1378         {
1379                 // NOTE: this protects waypoints if they're the ONLY nearest
1380                 // waypoint. That's the intention.
1381                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
1382                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
1383         });
1384         IL_EACH(g_waypoints, true,
1385         {
1386                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
1387                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
1388                 // WP is useful if:
1389                 if (it.wpflags & WAYPOINTFLAG_ITEM)
1390                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1391                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
1392                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1393                 if (it.wpflags & WAYPOINTFLAG_LADDER)
1394                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1395                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
1396                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1397                 // b) WP is closest WP for an item/spawnpoint/other entity
1398                 //    This has been done above by protecting these WPs.
1399         });
1400         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
1401         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
1402         {
1403                 for (int m = 0; m < 32; ++m)
1404                 {
1405                         entity w = waypoint_get_link(it, m);
1406                         if (!w)
1407                                 break;
1408                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
1409                                 continue;
1410                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
1411                                 continue;
1412                         for (int j = 0; j < 32; ++j)
1413                         {
1414                                 entity w2 = waypoint_get_link(w, j);
1415                                 if (!w2)
1416                                         break;
1417                                 if (it == w2)
1418                                         continue;
1419                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
1420                                         continue;
1421                                 // If we got here, it != w2 exist with it -> w
1422                                 // and w -> w2. That means the waypoint is not
1423                                 // a dead end.
1424                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
1425                                 for (int k = 0; k < 32; ++k)
1426                                 {
1427                                         if (waypoint_get_link(it, k) == w2)
1428                                                 continue;
1429                                         // IF WE GET HERE, w is proven useful
1430                                         // to get from it to w2!
1431                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1432                                         goto next;
1433                                 }
1434                         }
1435 LABEL(next)
1436                 }
1437         });
1438         // d) The waypoint is a dead end. Dead end waypoints must be kept as
1439         //     they are needed to complete routes while autowaypointing.
1440
1441         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
1442         {
1443                 LOG_INFOF("Removed a waypoint at %v. Try again for more!\n", it.origin);
1444                 te_explosion(it.origin);
1445                 waypoint_remove(it);
1446                 break;
1447         });
1448
1449         IL_EACH(g_waypoints, true,
1450         {
1451                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
1452         });
1453 }
1454
1455 void botframe_autowaypoints()
1456 {
1457         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), LAMBDA(
1458                 // going back is broken, so only fix waypoints to walk TO the player
1459                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
1460                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
1461                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
1462         ));
1463
1464         if (autocvar_g_waypointeditor_auto >= 2) {
1465                 botframe_deleteuselesswaypoints();
1466         }
1467 }
1468