qcsrc/server/bot/default/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "cvars.qh"
   6
   7 #include "bot.qh"
   8 #include "navigation.qh"
   9
  10 #include <common/state.qh>
  11
  12 #include "../../antilag.qh"
  13
  14 #include <common/constants.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/physics/player.qh>
  17
  18 #include <lib/warpzone/common.qh>
  19 #include <lib/warpzone/util_server.qh>
  20
  21 .entity spawnpointmodel;
  22 void waypoint_unreachable(entity pl)
  23 {
  24         IL_EACH(g_waypoints, true,
  25         {
  26                 it.colormod = '0.5 0.5 0.5';
  27                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  28         });
  29
  30         entity e2 = navigation_findnearestwaypoint(pl, false);
  31         if(!e2)
  32         {
  33                 LOG_INFOF("Can't find any waypoint nearby\n");
  34                 return;
  35         }
  36
  37         navigation_markroutes(pl, e2);
  38
  39         int j = 0;
  40         int m = 0;
  41         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  42         {
  43                 LOG_INFO("unreachable: ", etos(it), " ", vtos(it.origin), "\n");
  44                 it.colormod_z = 8;
  45                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
  46                 j++;
  47                 m++;
  48         });
  49         if (j) LOG_INFOF("%d waypoints cannot be reached from here in any way (marked with blue light)\n", j);
  50         navigation_markroutes_inverted(e2);
  51
  52         j = 0;
  53         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  54         {
  55                 LOG_INFO("cannot reach me: ", etos(it), " ", vtos(it.origin), "\n");
  56                 it.colormod_x = 8;
  57                 if (!(it.effects & EF_NODEPTHTEST))  // not already reported before
  58                         m++;
  59                 it.effects |= EF_NODEPTHTEST | EF_RED;
  60                 j++;
  61         });
  62         if (j) LOG_INFOF("%d waypoints cannot walk to here in any way (marked with red light)\n", j);
  63         if (m) LOG_INFOF("%d waypoints have been marked total\n", m);
  64
  65         j = 0;
  66         IL_EACH(g_spawnpoints, true,
  67         {
  68                 if (navigation_findnearestwaypoint(it, false))
  69                 {
  70                         if(it.spawnpointmodel)
  71                         {
  72                                 delete(it.spawnpointmodel);
  73                                 it.spawnpointmodel = NULL;
  74                         }
  75                 }
  76                 else
  77                 {
  78                         if(!it.spawnpointmodel)
  79                         {
  80                                 tracebox(it.origin, PL_MIN_CONST, PL_MAX_CONST, it.origin - '0 0 512', MOVE_NOMONSTERS, NULL);
  81                                 entity e = new(spawnpointmodel);
  82                                 vector org = trace_endpos + eZ;
  83                                 setorigin(e, org);
  84                                 e.solid = SOLID_TRIGGER;
  85                                 it.spawnpointmodel = e;
  86                         }
  87                         LOG_INFO("spawn without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
  88                         it.spawnpointmodel.effects |= EF_NODEPTHTEST;
  89                         _setmodel(it.spawnpointmodel, pl.model);
  90                         it.spawnpointmodel.frame = pl.frame;
  91                         it.spawnpointmodel.skin = pl.skin;
  92                         it.spawnpointmodel.colormap = pl.colormap;
  93                         it.spawnpointmodel.colormod = pl.colormod;
  94                         it.spawnpointmodel.glowmod = pl.glowmod;
  95                         setsize(it.spawnpointmodel, PL_MIN_CONST, PL_MAX_CONST);
  96                         j++;
  97                 }
  98         });
  99         if (j) LOG_INFOF("%d spawnpoints have no nearest waypoint (marked by player model)\n", j);
 100
 101         j = 0;
 102         IL_EACH(g_items, true,
 103         {
 104                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
 105                 it.colormod = '0.5 0.5 0.5';
 106         });
 107         IL_EACH(g_items, true,
 108         {
 109                 if (navigation_findnearestwaypoint(it, false))
 110                         continue;
 111                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 112                 it.effects |= EF_NODEPTHTEST | EF_RED;
 113                 it.colormod_x = 8;
 114                 j++;
 115         });
 116         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked away from (marked with red light)\n", j);
 117
 118         j = 0;
 119         IL_EACH(g_items, true,
 120         {
 121                 if (navigation_findnearestwaypoint(it, true))
 122                         continue;
 123                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 124                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
 125                 it.colormod_z = 8;
 126                 j++;
 127         });
 128         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked to (marked with blue light)\n", j);
 129 }
 130
 131 vector waypoint_getSymmetricalOrigin(vector org, int ctf_flags)
 132 {
 133         vector new_org = org;
 134         if (fabs(autocvar_g_waypointeditor_symmetrical) == 1)
 135         {
 136                 vector map_center = havocbot_middlepoint;
 137                 if (autocvar_g_waypointeditor_symmetrical == -1)
 138                         map_center = autocvar_g_waypointeditor_symmetrical_origin;
 139
 140                 new_org = Rotate(org - map_center, 360 * DEG2RAD / ctf_flags) + map_center;
 141         }
 142         else if (fabs(autocvar_g_waypointeditor_symmetrical) == 2)
 143         {
 144                 float m = havocbot_symmetryaxis_equation.x;
 145                 float q = havocbot_symmetryaxis_equation.y;
 146                 if (autocvar_g_waypointeditor_symmetrical == -2)
 147                 {
 148                         m = autocvar_g_waypointeditor_symmetrical_axis.x;
 149                         q = autocvar_g_waypointeditor_symmetrical_axis.y;
 150                 }
 151
 152                 new_org.x = (1 / (1 + m*m)) * ((1 - m*m) * org.x + 2 * m * org.y - 2 * m * q);
 153                 new_org.y = (1 / (1 + m*m)) * (2 * m * org.x + (m*m - 1) * org.y + 2 * q);
 154         }
 155         new_org.z = org.z;
 156         return new_org;
 157 }
 158
 159 void waypoint_setupmodel(entity wp)
 160 {
 161         if (autocvar_g_waypointeditor)
 162         {
 163                 // TODO: add some sort of visible box in edit mode for box waypoints
 164                 vector m1 = wp.mins;
 165                 vector m2 = wp.maxs;
 166                 setmodel(wp, MDL_WAYPOINT);
 167                 setsize(wp, m1, m2);
 168                 wp.effects = EF_LOWPRECISION;
 169                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 170                         wp.colormod = '1 0 0';
 171                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 172                         wp.colormod = '1 1 0';
 173                 else if (wp.wphardwired)
 174                         wp.colormod = '0.5 0 1';
 175                 else
 176                         wp.colormod = '1 1 1';
 177         }
 178         else
 179                 wp.model = "";
 180 }
 181
 182 // create a new spawnfunc_waypoint and automatically link it to other waypoints, and link
 183 // them back to it as well
 184 // (suitable for spawnfunc_waypoint editor)
 185 entity waypoint_spawn(vector m1, vector m2, float f)
 186 {
 187         if(!(f & (WAYPOINTFLAG_PERSONAL | WAYPOINTFLAG_GENERATED)) && m1 == m2)
 188         {
 189                 vector em1 = m1 - '8 8 8';
 190                 vector em2 = m2 + '8 8 8';
 191                 IL_EACH(g_waypoints, boxesoverlap(em1, em2, it.absmin, it.absmax),
 192                 {
 193                         return it;
 194                 });
 195         }
 196
 197         entity w = new(waypoint);
 198         IL_PUSH(g_waypoints, w);
 199         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 200         w.wpflags = f;
 201         w.solid = SOLID_TRIGGER;
 202         setorigin(w, (m1 + m2) * 0.5);
 203         setsize(w, m1 - w.origin, m2 - w.origin);
 204         if (w.size)
 205                 w.wpisbox = true;
 206
 207         if(!w.wpisbox)
 208         {
 209                 setsize(w, PL_MIN_CONST - '1 1 0', PL_MAX_CONST + '1 1 0');
 210                 if(!move_out_of_solid(w))
 211                 {
 212                         if(!(f & WAYPOINTFLAG_GENERATED))
 213                         {
 214                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin));
 215                                 delete(w);
 216                                 return NULL;
 217                         }
 218                         else
 219                         {
 220                                 if(autocvar_developer)
 221                                 {
 222                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin));
 223                                         backtrace("Waypoint stuck");
 224                                 }
 225                         }
 226                 }
 227                 setsize(w, '0 0 0', '0 0 0');
 228         }
 229
 230         waypoint_clearlinks(w);
 231         //waypoint_schedulerelink(w);
 232
 233         waypoint_setupmodel(w);
 234
 235         return w;
 236 }
 237
 238 void waypoint_spawn_fromeditor(entity pl)
 239 {
 240         entity e;
 241         vector org = pl.origin;
 242         int ctf_flags = havocbot_symmetryaxis_equation.z;
 243         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 244                    || (autocvar_g_waypointeditor_symmetrical < 0));
 245         int order = ctf_flags;
 246         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 247         {
 248                 order = autocvar_g_waypointeditor_symmetrical_order;
 249                 ctf_flags = order;
 250         }
 251
 252         if(!PHYS_INPUT_BUTTON_CROUCH(pl))
 253         {
 254                 // snap waypoint to item's origin if close enough
 255                 IL_EACH(g_items, true,
 256                 {
 257                         vector item_org = (it.absmin + it.absmax) * 0.5;
 258                         item_org.z = it.absmin.z - PL_MIN_CONST.z;
 259                         if(vlen(item_org - org) < 30)
 260                         {
 261                                 org = item_org;
 262                                 break;
 263                         }
 264                 });
 265         }
 266
 267         LABEL(add_wp);
 268         e = waypoint_spawn(org, org, 0);
 269         if(!e)
 270         {
 271                 LOG_INFOF("Couldn't spawn waypoint at %v\n", org);
 272                 return;
 273         }
 274         waypoint_schedulerelink(e);
 275         bprint(strcat("Waypoint spawned at ", vtos(e.origin), "\n"));
 276         if(sym)
 277         {
 278                 org = waypoint_getSymmetricalOrigin(e.origin, ctf_flags);
 279                 if (vdist(org - pl.origin, >, 32))
 280                 {
 281                         if(order > 2)
 282                                 order--;
 283                         else
 284                                 sym = false;
 285                         goto add_wp;
 286                 }
 287         }
 288 }
 289
 290 void waypoint_remove(entity wp)
 291 {
 292         // tell all waypoints linked to wp that they need to relink
 293         IL_EACH(g_waypoints, it != wp,
 294         {
 295                 if (waypoint_islinked(it, wp))
 296                         waypoint_removelink(it, wp);
 297         });
 298         delete(wp);
 299 }
 300
 301 void waypoint_remove_fromeditor(entity pl)
 302 {
 303         entity e = navigation_findnearestwaypoint(pl, false);
 304
 305         int ctf_flags = havocbot_symmetryaxis_equation.z;
 306         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 307                    || (autocvar_g_waypointeditor_symmetrical < 0));
 308         int order = ctf_flags;
 309         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 310         {
 311                 order = autocvar_g_waypointeditor_symmetrical_order;
 312                 ctf_flags = order;
 313         }
 314
 315         LABEL(remove_wp);
 316         if (!e) return;
 317         if (e.wpflags & WAYPOINTFLAG_GENERATED) return;
 318
 319         if (e.wphardwired)
 320         {
 321                 LOG_INFO("^1Warning: ^7Removal of hardwired waypoints is not allowed in the editor. Please remove links from/to this waypoint (", vtos(e.origin), ") by hand from maps/", mapname, ".waypoints.hardwired\n");
 322                 return;
 323         }
 324
 325         entity wp_sym = NULL;
 326         if (sym)
 327         {
 328                 vector org = waypoint_getSymmetricalOrigin(e.origin, ctf_flags);
 329                 FOREACH_ENTITY_CLASS("waypoint", !(it.wpflags & WAYPOINTFLAG_GENERATED), {
 330                         if(vdist(org - it.origin, <, 3))
 331                         {
 332                                 wp_sym = it;
 333                                 break;
 334                         }
 335                 });
 336         }
 337
 338         bprint(strcat("Waypoint removed at ", vtos(e.origin), "\n"));
 339         waypoint_remove(e);
 340
 341         if (sym && wp_sym)
 342         {
 343                 e = wp_sym;
 344                 if(order > 2)
 345                         order--;
 346                 else
 347                         sym = false;
 348                 goto remove_wp;
 349         }
 350 }
 351
 352 void waypoint_removelink(entity from, entity to)
 353 {
 354         if (from == to || (from.wpflags & WAYPOINTFLAG_NORELINK))
 355                 return;
 356
 357         bool found = false;
 358         if (!found && from.wp00 == to) found = true; if (found) {from.wp00 = from.wp01; from.wp00mincost = from.wp01mincost;}
 359         if (!found && from.wp01 == to) found = true; if (found) {from.wp01 = from.wp02; from.wp01mincost = from.wp02mincost;}
 360         if (!found && from.wp02 == to) found = true; if (found) {from.wp02 = from.wp03; from.wp02mincost = from.wp03mincost;}
 361         if (!found && from.wp03 == to) found = true; if (found) {from.wp03 = from.wp04; from.wp03mincost = from.wp04mincost;}
 362         if (!found && from.wp04 == to) found = true; if (found) {from.wp04 = from.wp05; from.wp04mincost = from.wp05mincost;}
 363         if (!found && from.wp05 == to) found = true; if (found) {from.wp05 = from.wp06; from.wp05mincost = from.wp06mincost;}
 364         if (!found && from.wp06 == to) found = true; if (found) {from.wp06 = from.wp07; from.wp06mincost = from.wp07mincost;}
 365         if (!found && from.wp07 == to) found = true; if (found) {from.wp07 = from.wp08; from.wp07mincost = from.wp08mincost;}
 366         if (!found && from.wp08 == to) found = true; if (found) {from.wp08 = from.wp09; from.wp08mincost = from.wp09mincost;}
 367         if (!found && from.wp09 == to) found = true; if (found) {from.wp09 = from.wp10; from.wp09mincost = from.wp10mincost;}
 368         if (!found && from.wp10 == to) found = true; if (found) {from.wp10 = from.wp11; from.wp10mincost = from.wp11mincost;}
 369         if (!found && from.wp11 == to) found = true; if (found) {from.wp11 = from.wp12; from.wp11mincost = from.wp12mincost;}
 370         if (!found && from.wp12 == to) found = true; if (found) {from.wp12 = from.wp13; from.wp12mincost = from.wp13mincost;}
 371         if (!found && from.wp13 == to) found = true; if (found) {from.wp13 = from.wp14; from.wp13mincost = from.wp14mincost;}
 372         if (!found && from.wp14 == to) found = true; if (found) {from.wp14 = from.wp15; from.wp14mincost = from.wp15mincost;}
 373         if (!found && from.wp15 == to) found = true; if (found) {from.wp15 = from.wp16; from.wp15mincost = from.wp16mincost;}
 374         if (!found && from.wp16 == to) found = true; if (found) {from.wp16 = from.wp17; from.wp16mincost = from.wp17mincost;}
 375         if (!found && from.wp17 == to) found = true; if (found) {from.wp17 = from.wp18; from.wp17mincost = from.wp18mincost;}
 376         if (!found && from.wp18 == to) found = true; if (found) {from.wp18 = from.wp19; from.wp18mincost = from.wp19mincost;}
 377         if (!found && from.wp19 == to) found = true; if (found) {from.wp19 = from.wp20; from.wp19mincost = from.wp20mincost;}
 378         if (!found && from.wp20 == to) found = true; if (found) {from.wp20 = from.wp21; from.wp20mincost = from.wp21mincost;}
 379         if (!found && from.wp21 == to) found = true; if (found) {from.wp21 = from.wp22; from.wp21mincost = from.wp22mincost;}
 380         if (!found && from.wp22 == to) found = true; if (found) {from.wp22 = from.wp23; from.wp22mincost = from.wp23mincost;}
 381         if (!found && from.wp23 == to) found = true; if (found) {from.wp23 = from.wp24; from.wp23mincost = from.wp24mincost;}
 382         if (!found && from.wp24 == to) found = true; if (found) {from.wp24 = from.wp25; from.wp24mincost = from.wp25mincost;}
 383         if (!found && from.wp25 == to) found = true; if (found) {from.wp25 = from.wp26; from.wp25mincost = from.wp26mincost;}
 384         if (!found && from.wp26 == to) found = true; if (found) {from.wp26 = from.wp27; from.wp26mincost = from.wp27mincost;}
 385         if (!found && from.wp27 == to) found = true; if (found) {from.wp27 = from.wp28; from.wp27mincost = from.wp28mincost;}
 386         if (!found && from.wp28 == to) found = true; if (found) {from.wp28 = from.wp29; from.wp28mincost = from.wp29mincost;}
 387         if (!found && from.wp29 == to) found = true; if (found) {from.wp29 = from.wp30; from.wp29mincost = from.wp30mincost;}
 388         if (!found && from.wp30 == to) found = true; if (found) {from.wp30 = from.wp31; from.wp30mincost = from.wp31mincost;}
 389         if (found) {from.wp31 = NULL; from.wp31mincost = 10000000;}
 390 }
 391
 392 bool waypoint_islinked(entity from, entity to)
 393 {
 394         if (from.wp00 == to) return true;if (from.wp01 == to) return true;if (from.wp02 == to) return true;if (from.wp03 == to) return true;
 395         if (from.wp04 == to) return true;if (from.wp05 == to) return true;if (from.wp06 == to) return true;if (from.wp07 == to) return true;
 396         if (from.wp08 == to) return true;if (from.wp09 == to) return true;if (from.wp10 == to) return true;if (from.wp11 == to) return true;
 397         if (from.wp12 == to) return true;if (from.wp13 == to) return true;if (from.wp14 == to) return true;if (from.wp15 == to) return true;
 398         if (from.wp16 == to) return true;if (from.wp17 == to) return true;if (from.wp18 == to) return true;if (from.wp19 == to) return true;
 399         if (from.wp20 == to) return true;if (from.wp21 == to) return true;if (from.wp22 == to) return true;if (from.wp23 == to) return true;
 400         if (from.wp24 == to) return true;if (from.wp25 == to) return true;if (from.wp26 == to) return true;if (from.wp27 == to) return true;
 401         if (from.wp28 == to) return true;if (from.wp29 == to) return true;if (from.wp30 == to) return true;if (from.wp31 == to) return true;
 402         return false;
 403 }
 404
 405 void waypoint_updatecost_foralllinks()
 406 {
 407         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_TELEPORT),
 408         {
 409                 if(it.wp00) it.wp00mincost = waypoint_getlinkcost(it, it.wp00);
 410                 if(it.wp01) it.wp01mincost = waypoint_getlinkcost(it, it.wp01);
 411                 if(it.wp02) it.wp02mincost = waypoint_getlinkcost(it, it.wp02);
 412                 if(it.wp03) it.wp03mincost = waypoint_getlinkcost(it, it.wp03);
 413                 if(it.wp04) it.wp04mincost = waypoint_getlinkcost(it, it.wp04);
 414                 if(it.wp05) it.wp05mincost = waypoint_getlinkcost(it, it.wp05);
 415                 if(it.wp06) it.wp06mincost = waypoint_getlinkcost(it, it.wp06);
 416                 if(it.wp07) it.wp07mincost = waypoint_getlinkcost(it, it.wp07);
 417                 if(it.wp08) it.wp08mincost = waypoint_getlinkcost(it, it.wp08);
 418                 if(it.wp09) it.wp09mincost = waypoint_getlinkcost(it, it.wp09);
 419                 if(it.wp10) it.wp10mincost = waypoint_getlinkcost(it, it.wp10);
 420                 if(it.wp11) it.wp11mincost = waypoint_getlinkcost(it, it.wp11);
 421                 if(it.wp12) it.wp12mincost = waypoint_getlinkcost(it, it.wp12);
 422                 if(it.wp13) it.wp13mincost = waypoint_getlinkcost(it, it.wp13);
 423                 if(it.wp14) it.wp14mincost = waypoint_getlinkcost(it, it.wp14);
 424                 if(it.wp15) it.wp15mincost = waypoint_getlinkcost(it, it.wp15);
 425                 if(it.wp16) it.wp16mincost = waypoint_getlinkcost(it, it.wp16);
 426                 if(it.wp17) it.wp17mincost = waypoint_getlinkcost(it, it.wp17);
 427                 if(it.wp18) it.wp18mincost = waypoint_getlinkcost(it, it.wp18);
 428                 if(it.wp19) it.wp19mincost = waypoint_getlinkcost(it, it.wp19);
 429                 if(it.wp20) it.wp20mincost = waypoint_getlinkcost(it, it.wp20);
 430                 if(it.wp21) it.wp21mincost = waypoint_getlinkcost(it, it.wp21);
 431                 if(it.wp22) it.wp22mincost = waypoint_getlinkcost(it, it.wp22);
 432                 if(it.wp23) it.wp23mincost = waypoint_getlinkcost(it, it.wp23);
 433                 if(it.wp24) it.wp24mincost = waypoint_getlinkcost(it, it.wp24);
 434                 if(it.wp25) it.wp25mincost = waypoint_getlinkcost(it, it.wp25);
 435                 if(it.wp26) it.wp26mincost = waypoint_getlinkcost(it, it.wp26);
 436                 if(it.wp27) it.wp27mincost = waypoint_getlinkcost(it, it.wp27);
 437                 if(it.wp28) it.wp28mincost = waypoint_getlinkcost(it, it.wp28);
 438                 if(it.wp29) it.wp29mincost = waypoint_getlinkcost(it, it.wp29);
 439                 if(it.wp30) it.wp30mincost = waypoint_getlinkcost(it, it.wp30);
 440                 if(it.wp31) it.wp31mincost = waypoint_getlinkcost(it, it.wp31);
 441         });
 442 }
 443
 444 float waypoint_getlinearcost(float dist)
 445 {
 446         if(skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 447                 return dist / (autocvar_sv_maxspeed * 1.25);
 448         return dist / autocvar_sv_maxspeed;
 449 }
 450 float waypoint_getlinearcost_underwater(float dist)
 451 {
 452         // NOTE: this value is hardcoded on the engine too, see SV_WaterMove
 453         return dist / (autocvar_sv_maxspeed * 0.7);
 454 }
 455
 456 float waypoint_gettravelcost(vector from, vector to, entity from_ent, entity to_ent)
 457 {
 458         bool submerged_from = navigation_check_submerged_state(from_ent, from);
 459         bool submerged_to = navigation_check_submerged_state(to_ent, to);
 460
 461         if (submerged_from && submerged_to)
 462                 return waypoint_getlinearcost_underwater(vlen(to - from));
 463
 464         float c = waypoint_getlinearcost(vlen(to - from));
 465
 466         float height = from.z - to.z;
 467         if(height > jumpheight_vec.z && autocvar_sv_gravity > 0)
 468         {
 469                 float height_cost = sqrt(height / (autocvar_sv_gravity / 2));
 470                 c = waypoint_getlinearcost(vlen(vec2(to - from))); // xy distance cost
 471                 if(height_cost > c)
 472                         c = height_cost;
 473         }
 474
 475         if (submerged_from || submerged_to)
 476                 return (c + waypoint_getlinearcost_underwater(vlen(to - from))) / 2;
 477         return c;
 478 }
 479
 480 float waypoint_getlinkcost(entity from, entity to)
 481 {
 482         vector v1 = from.origin;
 483         vector v2 = to.origin;
 484         if (from.wpisbox)
 485         {
 486                 vector m1 = from.absmin, m2 = from.absmax;
 487                 v1.x = bound(m1.x, v2.x, m2.x);
 488                 v1.y = bound(m1.y, v2.y, m2.y);
 489                 v1.z = bound(m1.z, v2.z, m2.z);
 490         }
 491         if (to.wpisbox)
 492         {
 493                 vector m1 = to.absmin, m2 = to.absmax;
 494                 v2.x = bound(m1.x, v1.x, m2.x);
 495                 v2.y = bound(m1.y, v1.y, m2.y);
 496                 v2.z = bound(m1.z, v1.z, m2.z);
 497         }
 498         return waypoint_gettravelcost(v1, v2, from, to);
 499 }
 500
 501 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
 502 // if c == -1 automatically determine cost of the link
 503 void waypoint_addlink_customcost(entity from, entity to, float c)
 504 {
 505         if (from == to || waypoint_islinked(from, to))
 506                 return;
 507         if (c == -1 && (from.wpflags & WAYPOINTFLAG_NORELINK))
 508                 return;
 509
 510         if(c == -1)
 511                 c = waypoint_getlinkcost(from, to);
 512
 513         if (from.wp31mincost < c) return;
 514         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 515         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 516         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 517         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 518         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 519         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 520         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 521         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 522         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 523         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 524         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 525         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 526         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 527         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 528         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 529         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 530         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 531         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 532         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 533         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 534         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 535         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 536         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 537         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 538         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 539         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 540         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 541         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 542         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 543         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 544         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 545         from.wp00 = to;from.wp00mincost = c;return;
 546 }
 547
 548 void waypoint_addlink(entity from, entity to)
 549 {
 550         waypoint_addlink_customcost(from, to, -1);
 551 }
 552
 553 // relink this spawnfunc_waypoint
 554 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
 555 // (SLOW!)
 556 void waypoint_think(entity this)
 557 {
 558         vector sv = '0 0 0', sv2 = '0 0 0', ev = '0 0 0', ev2 = '0 0 0', dv;
 559         float sv2_height = 0, ev2_height = 0;
 560
 561         bot_calculate_stepheightvec();
 562
 563         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 564
 565         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
 566         IL_EACH(g_waypoints, this != it,
 567         {
 568                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
 569                 {
 570                         waypoint_addlink(this, it);
 571                         waypoint_addlink(it, this);
 572                 }
 573                 else
 574                 {
 575                         ++relink_total;
 576                         if(!checkpvs(this.origin, it))
 577                         {
 578                                 ++relink_pvsculled;
 579                                 continue;
 580                         }
 581
 582                         SET_TRACEWALK_DESTCOORDS_2(this, it.origin, sv, sv2, sv2_height);
 583                         SET_TRACEWALK_DESTCOORDS_2(it, this.origin, ev, ev2, ev2_height);
 584
 585                         dv = ev - sv;
 586                         dv.z = 0;
 587                         if(vdist(dv, >=, 1050)) // max search distance in XY
 588                         {
 589                                 ++relink_lengthculled;
 590                                 continue;
 591                         }
 592
 593                         navigation_testtracewalk = 0;
 594
 595                         //traceline(this.origin, it.origin, false, NULL);
 596                         //if (trace_fraction == 1)
 597                         if (this.wpisbox)
 598                                 relink_walkculled += 0.5;
 599                         else
 600                         {
 601                                 if (tracewalk(this, sv, PL_MIN_CONST, PL_MAX_CONST, ev2, ev2_height, MOVE_NOMONSTERS))
 602                                         waypoint_addlink(this, it);
 603                                 else
 604                                         relink_walkculled += 0.5;
 605                         }
 606
 607                         if (it.wpisbox)
 608                                 relink_walkculled += 0.5;
 609                         else
 610                         {
 611                                 if (tracewalk(it, ev, PL_MIN_CONST, PL_MAX_CONST, sv2, sv2_height, MOVE_NOMONSTERS))
 612                                         waypoint_addlink(it, this);
 613                                 else
 614                                         relink_walkculled += 0.5;
 615                         }
 616                 }
 617         });
 618         navigation_testtracewalk = 0;
 619         this.wplinked = true;
 620 }
 621
 622 void waypoint_clearlinks(entity wp)
 623 {
 624         // clear links to other waypoints
 625         float f = 10000000;
 626         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
 627         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
 628         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
 629         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
 630
 631         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
 632         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
 633         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
 634         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
 635
 636         wp.wplinked = false;
 637 }
 638
 639 // tell a spawnfunc_waypoint to relink
 640 void waypoint_schedulerelink(entity wp)
 641 {
 642         if (wp == NULL)
 643                 return;
 644
 645         waypoint_setupmodel(wp);
 646         wp.wpisbox = vdist(wp.size, >, 0);
 647         wp.enemy = NULL;
 648         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
 649                 wp.owner = NULL;
 650         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
 651                 waypoint_clearlinks(wp);
 652         // schedule an actual relink on next frame
 653         setthink(wp, waypoint_think);
 654         wp.nextthink = time;
 655         wp.effects = EF_LOWPRECISION;
 656 }
 657
 658 // spawnfunc_waypoint map entity
 659 spawnfunc(waypoint)
 660 {
 661         IL_PUSH(g_waypoints, this);
 662
 663         setorigin(this, this.origin);
 664         // schedule a relink after other waypoints have had a chance to spawn
 665         waypoint_clearlinks(this);
 666         //waypoint_schedulerelink(this);
 667 }
 668
 669 // tell all waypoints to relink
 670 // actually this is useful only to update relink_* stats
 671 void waypoint_schedulerelinkall()
 672 {
 673         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
 674         IL_EACH(g_waypoints, true,
 675         {
 676                 waypoint_schedulerelink(it);
 677         });
 678         waypoint_load_links_hardwired();
 679 }
 680
 681 #define GET_GAMETYPE_EXTENSION() ((g_race) ? ".race" : "")
 682
 683 // Load waypoint links from file
 684 bool waypoint_load_links()
 685 {
 686         string s;
 687         float file, tokens, c = 0, found;
 688         entity wp_from = NULL, wp_to;
 689         vector wp_to_pos, wp_from_pos;
 690
 691         string gt_ext = GET_GAMETYPE_EXTENSION();
 692
 693         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
 694         file = fopen(filename, FILE_READ);
 695
 696         if (gt_ext != "" && file < 0)
 697         {
 698                 // if race waypoint file doesn't exist load the default one
 699                 filename = sprintf("maps/%s.waypoints.cache", mapname);
 700                 file = fopen(filename, FILE_READ);
 701         }
 702
 703         if (file < 0)
 704         {
 705                 LOG_TRACE("waypoint links load from ");
 706                 LOG_TRACE(filename);
 707                 LOG_TRACE(" failed");
 708                 return false;
 709         }
 710
 711         bool parse_comments = true;
 712         float ver = 0;
 713
 714         while ((s = fgets(file)))
 715         {
 716                 if(parse_comments)
 717                 {
 718                         if(substring(s, 0, 2) == "//")
 719                         {
 720                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
 721                                         ver = stof(substring(s, 19, -1));
 722                                 continue;
 723                         }
 724                         else
 725                         {
 726                                 if(ver < WAYPOINT_VERSION)
 727                                         return false;
 728                                 parse_comments = false;
 729                         }
 730                 }
 731
 732                 tokens = tokenizebyseparator(s, "*");
 733
 734                 if (tokens!=2)
 735                 {
 736                         // bad file format
 737                         fclose(file);
 738                         return false;
 739                 }
 740
 741                 wp_from_pos     = stov(argv(0));
 742                 wp_to_pos       = stov(argv(1));
 743
 744                 // Search "from" waypoint
 745                 if(!wp_from || wp_from.origin!=wp_from_pos)
 746                 {
 747                         wp_from = findradius(wp_from_pos, 1);
 748                         found = false;
 749                         while(wp_from)
 750                         {
 751                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
 752                                 if(wp_from.classname == "waypoint")
 753                                 {
 754                                         found = true;
 755                                         break;
 756                                 }
 757                                 wp_from = wp_from.chain;
 758                         }
 759
 760                         if(!found)
 761                         {
 762                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from_pos));
 763                                 continue;
 764                         }
 765                 }
 766
 767                 // Search "to" waypoint
 768                 wp_to = findradius(wp_to_pos, 1);
 769                 found = false;
 770                 while(wp_to)
 771                 {
 772                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
 773                         if(wp_to.classname == "waypoint")
 774                         {
 775                                 found = true;
 776                                 break;
 777                         }
 778                         wp_to = wp_to.chain;
 779                 }
 780
 781                 if(!found)
 782                 {
 783                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to_pos));
 784                         continue;
 785                 }
 786
 787                 ++c;
 788                 waypoint_addlink(wp_from, wp_to);
 789         }
 790
 791         fclose(file);
 792
 793         LOG_TRACE("loaded ", ftos(c), " waypoint links from ", filename);
 794
 795         botframe_cachedwaypointlinks = true;
 796         return true;
 797 }
 798
 799 void waypoint_load_or_remove_links_hardwired(bool removal_mode)
 800 {
 801         string s;
 802         float file, tokens, c = 0, found;
 803         entity wp_from = NULL, wp_to;
 804         vector wp_to_pos, wp_from_pos;
 805
 806         string gt_ext = GET_GAMETYPE_EXTENSION();
 807
 808         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
 809         file = fopen(filename, FILE_READ);
 810
 811         if (gt_ext != "" && file < 0)
 812         {
 813                 // if race waypoint file doesn't exist load the default one
 814                 filename = sprintf("maps/%s.waypoints.hardwired", mapname);
 815                 file = fopen(filename, FILE_READ);
 816         }
 817
 818         botframe_loadedforcedlinks = true;
 819
 820         if (file < 0)
 821         {
 822                 if(!removal_mode)
 823                         LOG_TRACE("waypoint links load from ", filename, " failed");
 824                 return;
 825         }
 826
 827         while ((s = fgets(file)))
 828         {
 829                 if(substring(s, 0, 2)=="//")
 830                         continue;
 831
 832                 if(substring(s, 0, 1)=="#")
 833                         continue;
 834
 835                 tokens = tokenizebyseparator(s, "*");
 836
 837                 if (tokens!=2)
 838                         continue;
 839
 840                 wp_from_pos     = stov(argv(0));
 841                 wp_to_pos       = stov(argv(1));
 842
 843                 // Search "from" waypoint
 844                 if(!wp_from || wp_from.origin!=wp_from_pos)
 845                 {
 846                         wp_from = findradius(wp_from_pos, 5);
 847                         found = false;
 848                         while(wp_from)
 849                         {
 850                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
 851                                 if(wp_from.classname == "waypoint")
 852                                 {
 853                                         found = true;
 854                                         break;
 855                                 }
 856                                 wp_from = wp_from.chain;
 857                         }
 858
 859                         if(!found)
 860                         {
 861                                 if(!removal_mode)
 862                                         LOG_INFO("NOTICE: Can not find waypoint at ", vtos(wp_from_pos), ". Path skipped");
 863                                 continue;
 864                         }
 865                 }
 866
 867                 // Search "to" waypoint
 868                 wp_to = findradius(wp_to_pos, 5);
 869                 found = false;
 870                 while(wp_to)
 871                 {
 872                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
 873                         if(wp_to.classname == "waypoint")
 874                         {
 875                                 found = true;
 876                                 break;
 877                         }
 878                         wp_to = wp_to.chain;
 879                 }
 880
 881                 if(!found)
 882                 {
 883                         if(!removal_mode)
 884                                 LOG_INFO("NOTICE: Can not find waypoint at ", vtos(wp_to_pos), ". Path skipped");
 885                         continue;
 886                 }
 887
 888                 ++c;
 889                 if(removal_mode)
 890                 {
 891                         waypoint_removelink(wp_from, wp_to);
 892                         continue;
 893                 }
 894
 895                 waypoint_addlink(wp_from, wp_to);
 896                 wp_from.wphardwired = true;
 897                 wp_to.wphardwired = true;
 898                 waypoint_setupmodel(wp_from);
 899                 waypoint_setupmodel(wp_to);
 900         }
 901
 902         fclose(file);
 903
 904         if(!removal_mode)
 905                 LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired");
 906 }
 907
 908 entity waypoint_get_link(entity w, float i)
 909 {
 910         switch(i)
 911         {
 912                 case  0:return w.wp00;
 913                 case  1:return w.wp01;
 914                 case  2:return w.wp02;
 915                 case  3:return w.wp03;
 916                 case  4:return w.wp04;
 917                 case  5:return w.wp05;
 918                 case  6:return w.wp06;
 919                 case  7:return w.wp07;
 920                 case  8:return w.wp08;
 921                 case  9:return w.wp09;
 922                 case 10:return w.wp10;
 923                 case 11:return w.wp11;
 924                 case 12:return w.wp12;
 925                 case 13:return w.wp13;
 926                 case 14:return w.wp14;
 927                 case 15:return w.wp15;
 928                 case 16:return w.wp16;
 929                 case 17:return w.wp17;
 930                 case 18:return w.wp18;
 931                 case 19:return w.wp19;
 932                 case 20:return w.wp20;
 933                 case 21:return w.wp21;
 934                 case 22:return w.wp22;
 935                 case 23:return w.wp23;
 936                 case 24:return w.wp24;
 937                 case 25:return w.wp25;
 938                 case 26:return w.wp26;
 939                 case 27:return w.wp27;
 940                 case 28:return w.wp28;
 941                 case 29:return w.wp29;
 942                 case 30:return w.wp30;
 943                 case 31:return w.wp31;
 944                 default:return NULL;
 945         }
 946 }
 947
 948 // Save all waypoint links to a file
 949 void waypoint_save_links()
 950 {
 951         // temporarily remove hardwired links so they don't get saved among normal links
 952         waypoint_remove_links_hardwired();
 953
 954         string gt_ext = GET_GAMETYPE_EXTENSION();
 955
 956         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
 957         int file = fopen(filename, FILE_WRITE);
 958         if (file < 0)
 959         {
 960                 LOG_INFOF("waypoint link save to %s failed", filename);
 961                 return;
 962         }
 963
 964         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
 965
 966         int c = 0;
 967         IL_EACH(g_waypoints, true,
 968         {
 969                 for(int j = 0; j < 32; ++j)
 970                 {
 971                         entity link = waypoint_get_link(it, j);
 972                         if(link)
 973                         {
 974                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
 975                                 fputs(file, s);
 976                                 ++c;
 977                         }
 978                 }
 979         });
 980         fclose(file);
 981
 982         botframe_cachedwaypointlinks = true;
 983
 984         LOG_INFOF("saved %d waypoint links to %s", c, filename);
 985
 986         waypoint_load_links_hardwired();
 987 }
 988
 989 // save waypoints to gamedir/data/maps/mapname.waypoints
 990 void waypoint_saveall()
 991 {
 992         string gt_ext = GET_GAMETYPE_EXTENSION();
 993
 994         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
 995         int file = fopen(filename, FILE_WRITE);
 996         if (file < 0)
 997         {
 998                 waypoint_save_links(); // save anyway?
 999                 botframe_loadedforcedlinks = false;
1000
1001                 LOG_INFOF("waypoint links: save to %s failed", filename);
1002                 return;
1003         }
1004
1005         // add 3 comments to not break compatibility with older Xonotic versions
1006         // (they are read as a waypoint with origin '0 0 0' and flag 0 though)
1007         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1008         fputs(file, strcat("//", "\n"));
1009         fputs(file, strcat("//", "\n"));
1010
1011         int c = 0;
1012         IL_EACH(g_waypoints, true,
1013         {
1014                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
1015                         continue;
1016
1017                 string s;
1018                 s = strcat(vtos(it.origin + it.mins), "\n");
1019                 s = strcat(s, vtos(it.origin + it.maxs));
1020                 s = strcat(s, "\n");
1021                 s = strcat(s, ftos(it.wpflags));
1022                 s = strcat(s, "\n");
1023                 fputs(file, s);
1024                 c++;
1025         });
1026         fclose(file);
1027         waypoint_save_links();
1028         botframe_loadedforcedlinks = false;
1029
1030         LOG_INFOF("saved %d waypoints to %s", c, filename);
1031 }
1032
1033 // load waypoints from file
1034 float waypoint_loadall()
1035 {
1036         string s;
1037         float file, cwp, cwb, fl;
1038         vector m1, m2;
1039         cwp = 0;
1040         cwb = 0;
1041
1042         string gt_ext = GET_GAMETYPE_EXTENSION();
1043
1044         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1045         file = fopen(filename, FILE_READ);
1046
1047         if (gt_ext != "" && file < 0)
1048         {
1049                 // if race waypoint file doesn't exist load the default one
1050                 filename = sprintf("maps/%s.waypoints", mapname);
1051                 file = fopen(filename, FILE_READ);
1052         }
1053
1054         if (file < 0)
1055         {
1056                 LOG_TRACE("waypoint load from ", filename, " failed");
1057                 return 0;
1058         }
1059
1060         bool parse_comments = true;
1061         float ver = 0;
1062
1063         while ((s = fgets(file)))
1064         {
1065                 if(parse_comments)
1066                 {
1067                         if(substring(s, 0, 2) == "//")
1068                         {
1069                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1070                                         ver = stof(substring(s, 19, -1));
1071                                 continue;
1072                         }
1073                         else
1074                         {
1075                                 if(floor(ver) < floor(WAYPOINT_VERSION))
1076                                         LOG_TRACE("waypoints for this map are outdated");
1077                                 parse_comments = false;
1078                         }
1079                 }
1080                 m1 = stov(s);
1081                 s = fgets(file);
1082                 if (!s)
1083                         break;
1084                 m2 = stov(s);
1085                 s = fgets(file);
1086                 if (!s)
1087                         break;
1088                 fl = stof(s);
1089                 waypoint_spawn(m1, m2, fl);
1090                 if (m1 == m2)
1091                         cwp = cwp + 1;
1092                 else
1093                         cwb = cwb + 1;
1094         }
1095         fclose(file);
1096         LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints");
1097
1098         return cwp + cwb;
1099 }
1100
1101 #define waypoint_fixorigin(position, tracetest_ent) \
1102         waypoint_fixorigin_down_dir(position, tracetest_ent, '0 0 -1')
1103
1104 vector waypoint_fixorigin_down_dir(vector position, entity tracetest_ent, vector down_dir)
1105 {
1106         tracebox(position + '0 0 1', PL_MIN_CONST, PL_MAX_CONST, position + down_dir * 3000, MOVE_NOMONSTERS, tracetest_ent);
1107         if(trace_startsolid)
1108                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z / 2), PL_MIN_CONST, PL_MAX_CONST, position + down_dir * 3000, MOVE_NOMONSTERS, tracetest_ent);
1109         if(trace_startsolid)
1110                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z), PL_MIN_CONST, PL_MAX_CONST, position + down_dir * 3000, MOVE_NOMONSTERS, tracetest_ent);
1111         if(trace_fraction < 1)
1112                 position = trace_endpos;
1113         return position;
1114 }
1115
1116 void waypoint_spawnforitem_force(entity e, vector org)
1117 {
1118         // Fix the waypoint altitude if necessary
1119         org = waypoint_fixorigin(org, NULL);
1120
1121         // don't spawn an item spawnfunc_waypoint if it already exists
1122         IL_EACH(g_waypoints, true,
1123         {
1124                 if(it.wpisbox)
1125                 {
1126                         if(boxesoverlap(org, org, it.absmin, it.absmax))
1127                         {
1128                                 e.nearestwaypoint = it;
1129                                 return;
1130                         }
1131                 }
1132                 else
1133                 {
1134                         if(vdist(it.origin - org, <, 16))
1135                         {
1136                                 e.nearestwaypoint = it;
1137                                 return;
1138                         }
1139                 }
1140         });
1141
1142         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
1143 }
1144
1145 void waypoint_spawnforitem(entity e)
1146 {
1147         if(!bot_waypoints_for_items)
1148                 return;
1149
1150         waypoint_spawnforitem_force(e, e.origin);
1151 }
1152
1153 void waypoint_spawnforteleporter_boxes(entity e, int teleport_flag, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
1154 {
1155         entity w;
1156         entity dw;
1157         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | teleport_flag | WAYPOINTFLAG_NORELINK);
1158         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
1159         // one way link to the destination
1160         w.wp00 = dw;
1161         w.wp00mincost = timetaken; // this is just for jump pads
1162         // the teleporter's nearest spawnfunc_waypoint is this one
1163         // (teleporters are not goals, so this is probably useless)
1164         e.nearestwaypoint = w;
1165         e.nearestwaypointtimeout = -1;
1166 }
1167
1168 void waypoint_spawnforteleporter_wz(entity e, vector org, vector destination, float timetaken, vector down_dir, entity tracetest_ent)
1169 {
1170         // warpzones with oblique warp plane rely on down_dir to snap waypoints
1171         // to the ground without leaving the warp plane
1172         // warpzones with horizontal warp plane (down_dir.x == -1) generate
1173         // destination waypoint snapped to the ground (leaving warpzone), source
1174         // waypoint in the center of the warp plane
1175         if(down_dir.x != -1)
1176                 org = waypoint_fixorigin_down_dir(org, tracetest_ent, down_dir);
1177         if(down_dir.x == -1)
1178                 down_dir = '0 0 -1';
1179         destination = waypoint_fixorigin_down_dir(destination, tracetest_ent, down_dir);
1180         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, org, org, destination, destination, timetaken);
1181 }
1182
1183 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken, entity tracetest_ent)
1184 {
1185         destination = waypoint_fixorigin(destination, tracetest_ent);
1186         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, e.absmin - PL_MAX_CONST + '1 1 1', e.absmax - PL_MIN_CONST + '-1 -1 -1', destination, destination, timetaken);
1187 }
1188
1189 entity waypoint_spawnpersonal(entity this, vector position)
1190 {
1191         entity w;
1192
1193         // drop the waypoint to a proper location:
1194         //   first move it up by a player height
1195         //   then move it down to hit the floor with player bbox size
1196         position = waypoint_fixorigin(position, this);
1197
1198         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
1199         w.nearestwaypoint = NULL;
1200         w.nearestwaypointtimeout = 0;
1201         w.owner = this;
1202
1203         waypoint_schedulerelink(w);
1204
1205         return w;
1206 }
1207
1208 void waypoint_showlink(entity wp1, entity wp2, int display_type)
1209 {
1210         if (!(wp1 && wp2))
1211                 return;
1212
1213         if (wp1.wphardwired && wp2.wphardwired)
1214                 te_beam(NULL, wp1.origin, wp2.origin);
1215         else if (display_type == 1)
1216                 te_lightning2(NULL, wp1.origin, wp2.origin);
1217 }
1218
1219 void waypoint_showlinks_to(entity wp, int display_type)
1220 {
1221         IL_EACH(g_waypoints, it != wp,
1222         {
1223                 if (waypoint_islinked(it, wp))
1224                         waypoint_showlink(it, wp, display_type);
1225         });
1226 }
1227
1228 void waypoint_showlinks_from(entity wp, int display_type)
1229 {
1230         waypoint_showlink(wp.wp00, wp, display_type); waypoint_showlink(wp.wp16, wp, display_type);
1231         waypoint_showlink(wp.wp01, wp, display_type); waypoint_showlink(wp.wp17, wp, display_type);
1232         waypoint_showlink(wp.wp02, wp, display_type); waypoint_showlink(wp.wp18, wp, display_type);
1233         waypoint_showlink(wp.wp03, wp, display_type); waypoint_showlink(wp.wp19, wp, display_type);
1234         waypoint_showlink(wp.wp04, wp, display_type); waypoint_showlink(wp.wp20, wp, display_type);
1235         waypoint_showlink(wp.wp05, wp, display_type); waypoint_showlink(wp.wp21, wp, display_type);
1236         waypoint_showlink(wp.wp06, wp, display_type); waypoint_showlink(wp.wp22, wp, display_type);
1237         waypoint_showlink(wp.wp07, wp, display_type); waypoint_showlink(wp.wp23, wp, display_type);
1238         waypoint_showlink(wp.wp08, wp, display_type); waypoint_showlink(wp.wp24, wp, display_type);
1239         waypoint_showlink(wp.wp09, wp, display_type); waypoint_showlink(wp.wp25, wp, display_type);
1240         waypoint_showlink(wp.wp10, wp, display_type); waypoint_showlink(wp.wp26, wp, display_type);
1241         waypoint_showlink(wp.wp11, wp, display_type); waypoint_showlink(wp.wp27, wp, display_type);
1242         waypoint_showlink(wp.wp12, wp, display_type); waypoint_showlink(wp.wp28, wp, display_type);
1243         waypoint_showlink(wp.wp13, wp, display_type); waypoint_showlink(wp.wp29, wp, display_type);
1244         waypoint_showlink(wp.wp14, wp, display_type); waypoint_showlink(wp.wp30, wp, display_type);
1245         waypoint_showlink(wp.wp15, wp, display_type); waypoint_showlink(wp.wp31, wp, display_type);
1246 }
1247
1248 void botframe_showwaypointlinks()
1249 {
1250         if (time < botframe_waypointeditorlightningtime)
1251                 return;
1252         botframe_waypointeditorlightningtime = time + 0.5;
1253         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
1254         {
1255                 int display_type = 0;
1256                 entity head = navigation_findnearestwaypoint(it, false);
1257                 if (IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE)
1258                         display_type = 1; // default
1259                 else if(head && (head.wphardwired))
1260                         display_type = 2; // only hardwired
1261
1262                 if (display_type)
1263                 {
1264                         //navigation_testtracewalk = true;
1265                         //print("currently selected WP is ", etos(head), "\n");
1266                         //navigation_testtracewalk = false;
1267                         if (head)
1268                         {
1269                                 te_lightning2(NULL, head.origin, it.origin);
1270                                 if(PHYS_INPUT_BUTTON_CROUCH(it))
1271                                         waypoint_showlinks_to(head, display_type);
1272                                 else
1273                                         waypoint_showlinks_from(head, display_type);
1274                         }
1275                 }
1276         });
1277 }
1278
1279 float botframe_autowaypoints_fixdown(vector v)
1280 {
1281         tracebox(v, PL_MIN_CONST, PL_MAX_CONST, v + '0 0 -64', MOVE_NOMONSTERS, NULL);
1282         if(trace_fraction >= 1)
1283                 return 0;
1284         return 1;
1285 }
1286
1287 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
1288 {
1289         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
1290         {
1291                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
1292                 return 0;
1293         });
1294
1295         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
1296         return 1;
1297 }
1298
1299 // return value:
1300 //    1 = WP created
1301 //    0 = no action needed
1302 //   -1 = temp fail, try from world too
1303 //   -2 = permanent fail, do not retry
1304 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
1305 {
1306         // make it possible to go from p to wp, if we can
1307         // if wp is NULL, nearest is chosen
1308
1309         entity w;
1310         vector porg;
1311         float t, tmin, tmax;
1312         vector o;
1313         vector save;
1314
1315         if(!botframe_autowaypoints_fixdown(p.origin))
1316                 return -2;
1317         porg = trace_endpos;
1318
1319         if(wp)
1320         {
1321                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
1322
1323                 // if wp -> porg, then OK
1324                 float maxdist;
1325                 if(navigation_waypoint_will_link(wp.origin, porg, p, porg, 0, wp.origin, 0, walkfromwp, 1050))
1326                 {
1327                         // we may find a better one
1328                         maxdist = vlen(wp.origin - porg);
1329                 }
1330                 else
1331                 {
1332                         // accept any "good"
1333                         maxdist = 2100;
1334                 }
1335
1336                 float bestdist = maxdist;
1337                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WAYPOINTFLAG_NORELINK),
1338                 {
1339                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
1340                         if(d < bestdist)
1341                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, it.origin, 0, wp.origin, 0, walkfromwp, 1050))
1342                         if(navigation_waypoint_will_link(it.origin, porg, p, porg, 0, it.origin, 0, walkfromwp, 1050))
1343                         {
1344                                 bestdist = d;
1345                                 p.(fld) = it;
1346                         }
1347                 });
1348                 if(bestdist < maxdist)
1349                 {
1350                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)));
1351                         return 0;
1352                 }
1353
1354                 if(bestdist < 2100)
1355                 {
1356                         // we know maxdist < 2100
1357                         // so wp -> porg is still valid
1358                         // all is good
1359                         p.(fld) = wp;
1360                         return 0;
1361                 }
1362
1363                 // otherwise, no existing WP can fix our issues
1364         }
1365         else
1366         {
1367                 save = p.origin;
1368                 setorigin(p, porg);
1369                 w = navigation_findnearestwaypoint(p, walkfromwp);
1370                 setorigin(p, save);
1371                 if(w)
1372                 {
1373                         p.(fld) = w;
1374                         return 0;
1375                 }
1376         }
1377
1378         tmin = 0;
1379         tmax = 1;
1380         for (;;)
1381         {
1382                 if(tmax - tmin < 0.001)
1383                 {
1384                         // did not get a good candidate
1385                         return -1;
1386                 }
1387
1388                 t = (tmin + tmax) * 0.5;
1389                 o = antilag_takebackorigin(p, CS(p), time - t);
1390                 if(!botframe_autowaypoints_fixdown(o))
1391                         return -2;
1392                 o = trace_endpos;
1393
1394                 if(wp)
1395                 {
1396                         if(!navigation_waypoint_will_link(wp.origin, o, p, o, 0, wp.origin, 0, walkfromwp, 1050))
1397                         {
1398                                 // we cannot walk from wp.origin to o
1399                                 // get closer to tmax
1400                                 tmin = t;
1401                                 continue;
1402                         }
1403                 }
1404                 else
1405                 {
1406                         save = p.origin;
1407                         setorigin(p, o);
1408                         w = navigation_findnearestwaypoint(p, walkfromwp);
1409                         setorigin(p, save);
1410                         if(!w)
1411                         {
1412                                 // we cannot walk from any WP to o
1413                                 // get closer to tmax
1414                                 tmin = t;
1415                                 continue;
1416                         }
1417                 }
1418
1419                 // if we get here, o is valid regarding waypoints
1420                 // check if o is connected right to the player
1421                 // we break if it succeeds, as that means o is a good waypoint location
1422                 if(navigation_waypoint_will_link(o, porg, p, porg, 0, o, 0, walkfromwp, 1050))
1423                         break;
1424
1425                 // o is no good, we need to get closer to the player
1426                 tmax = t;
1427         }
1428
1429         LOG_INFO("spawning a waypoint for connecting to ", etos(wp));
1430         botframe_autowaypoints_createwp(o, p, fld, 0);
1431         return 1;
1432 }
1433
1434 // automatically create missing waypoints
1435 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
1436 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
1437 {
1438         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
1439         if(r != -1)
1440                 return;
1441         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
1442         if(r != -1)
1443                 return;
1444
1445         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain");
1446         if(!botframe_autowaypoints_fixdown(p.origin))
1447                 return; // shouldn't happen, caught above
1448         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
1449 }
1450
1451 void botframe_deleteuselesswaypoints()
1452 {
1453         IL_EACH(g_items, it.bot_pickup,
1454         {
1455                 // NOTE: this protects waypoints if they're the ONLY nearest
1456                 // waypoint. That's the intention.
1457                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
1458                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
1459         });
1460         IL_EACH(g_waypoints, true,
1461         {
1462                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
1463                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
1464                 // WP is useful if:
1465                 if (it.wpflags & WAYPOINTFLAG_ITEM)
1466                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1467                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
1468                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1469                 if (it.wpflags & WAYPOINTFLAG_LADDER)
1470                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1471                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
1472                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1473                 // b) WP is closest WP for an item/spawnpoint/other entity
1474                 //    This has been done above by protecting these WPs.
1475         });
1476         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
1477         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
1478         {
1479                 for (int m = 0; m < 32; ++m)
1480                 {
1481                         entity w = waypoint_get_link(it, m);
1482                         if (!w)
1483                                 break;
1484                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
1485                                 continue;
1486                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
1487                                 continue;
1488                         for (int j = 0; j < 32; ++j)
1489                         {
1490                                 entity w2 = waypoint_get_link(w, j);
1491                                 if (!w2)
1492                                         break;
1493                                 if (it == w2)
1494                                         continue;
1495                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
1496                                         continue;
1497                                 // If we got here, it != w2 exist with it -> w
1498                                 // and w -> w2. That means the waypoint is not
1499                                 // a dead end.
1500                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
1501                                 for (int k = 0; k < 32; ++k)
1502                                 {
1503                                         if (waypoint_get_link(it, k) == w2)
1504                                                 continue;
1505                                         // IF WE GET HERE, w is proven useful
1506                                         // to get from it to w2!
1507                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1508                                         goto next;
1509                                 }
1510                         }
1511 LABEL(next)
1512                 }
1513         });
1514         // d) The waypoint is a dead end. Dead end waypoints must be kept as
1515         //     they are needed to complete routes while autowaypointing.
1516
1517         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
1518         {
1519                 LOG_INFOF("Removed a waypoint at %v. Try again for more!", it.origin);
1520                 te_explosion(it.origin);
1521                 waypoint_remove(it);
1522                 break;
1523         });
1524
1525         IL_EACH(g_waypoints, true,
1526         {
1527                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
1528         });
1529 }
1530
1531 void botframe_autowaypoints()
1532 {
1533         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), {
1534                 // going back is broken, so only fix waypoints to walk TO the player
1535                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
1536                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
1537                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
1538         });
1539
1540         if (autocvar_g_waypointeditor_auto >= 2) {
1541                 botframe_deleteuselesswaypoints();
1542         }
1543 }
1544