qcsrc/server/bot/default/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "bot.qh"
   6 #include "navigation.qh"
   7
   8 #include <common/state.qh>
   9
  10 #include "../../antilag.qh"
  11
  12 #include <common/constants.qh>
  13 #include <common/net_linked.qh>
  14 #include <common/physics/player.qh>
  15
  16 #include <lib/warpzone/common.qh>
  17 #include <lib/warpzone/util_server.qh>
  18
  19 .entity spawnpointmodel;
  20 void waypoint_unreachable(entity pl)
  21 {
  22         IL_EACH(g_waypoints, true,
  23         {
  24                 it.colormod = '0.5 0.5 0.5';
  25                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  26         });
  27         entity e2 = navigation_findnearestwaypoint(pl, false);
  28         navigation_markroutes(pl, e2);
  29
  30         int j = 0;
  31         int m = 0;
  32         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  33         {
  34                 LOG_INFO("unreachable: ", etos(it), " ", vtos(it.origin), "\n");
  35                 it.colormod_z = 8;
  36                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
  37                 j++;
  38                 m++;
  39         });
  40         if (j) LOG_INFOF("%d waypoints cannot be reached from here in any way (marked with blue light)\n", j);
  41         navigation_markroutes_inverted(e2);
  42
  43         j = 0;
  44         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  45         {
  46                 LOG_INFO("cannot reach me: ", etos(it), " ", vtos(it.origin), "\n");
  47                 it.colormod_x = 8;
  48                 if (!(it.effects & EF_NODEPTHTEST))  // not already reported before
  49                         m++;
  50                 it.effects |= EF_NODEPTHTEST | EF_RED;
  51                 j++;
  52         });
  53         if (j) LOG_INFOF("%d waypoints cannot walk to here in any way (marked with red light)\n", j);
  54         if (m) LOG_INFOF("%d waypoints have been marked total\n", m);
  55
  56         j = 0;
  57         IL_EACH(g_spawnpoints, true,
  58         {
  59                 if (navigation_findnearestwaypoint(it, false))
  60                 {
  61                         if(it.spawnpointmodel)
  62                         {
  63                                 delete(it.spawnpointmodel);
  64                                 it.spawnpointmodel = NULL;
  65                         }
  66                 }
  67                 else
  68                 {
  69                         if(!it.spawnpointmodel)
  70                         {
  71                                 tracebox(it.origin, PL_MIN_CONST, PL_MAX_CONST, it.origin - '0 0 512', MOVE_NOMONSTERS, NULL);
  72                                 entity e = new(spawnpointmodel);
  73                                 vector org = trace_endpos + eZ;
  74                                 setorigin(e, org);
  75                                 e.solid = SOLID_TRIGGER;
  76                                 it.spawnpointmodel = e;
  77                         }
  78                         LOG_INFO("spawn without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
  79                         it.spawnpointmodel.effects |= EF_NODEPTHTEST;
  80                         _setmodel(it.spawnpointmodel, pl.model);
  81                         it.spawnpointmodel.frame = pl.frame;
  82                         it.spawnpointmodel.skin = pl.skin;
  83                         it.spawnpointmodel.colormap = pl.colormap;
  84                         it.spawnpointmodel.colormod = pl.colormod;
  85                         it.spawnpointmodel.glowmod = pl.glowmod;
  86                         setsize(it.spawnpointmodel, PL_MIN_CONST, PL_MAX_CONST);
  87                         j++;
  88                 }
  89         });
  90         if (j) LOG_INFOF("%d spawnpoints have no nearest waypoint (marked by player model)\n", j);
  91
  92         j = 0;
  93         IL_EACH(g_items, true,
  94         {
  95                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  96                 it.colormod = '0.5 0.5 0.5';
  97         });
  98         IL_EACH(g_items, true,
  99         {
 100                 if (navigation_findnearestwaypoint(it, false))
 101                         continue;
 102                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 103                 it.effects |= EF_NODEPTHTEST | EF_RED;
 104                 it.colormod_x = 8;
 105                 j++;
 106         });
 107         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked away from (marked with red light)\n", j);
 108
 109         j = 0;
 110         IL_EACH(g_items, true,
 111         {
 112                 if (navigation_findnearestwaypoint(it, true))
 113                         continue;
 114                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 115                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
 116                 it.colormod_z = 8;
 117                 j++;
 118         });
 119         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked to (marked with blue light)\n", j);
 120 }
 121
 122 vector waypoint_getSymmetricalOrigin(vector org, int ctf_flags)
 123 {
 124         vector new_org = org;
 125         if (fabs(autocvar_g_waypointeditor_symmetrical) == 1)
 126         {
 127                 vector map_center = havocbot_middlepoint;
 128                 if (autocvar_g_waypointeditor_symmetrical == -1)
 129                         map_center = autocvar_g_waypointeditor_symmetrical_origin;
 130
 131                 new_org = Rotate(org - map_center, 360 * DEG2RAD / ctf_flags) + map_center;
 132         }
 133         else if (fabs(autocvar_g_waypointeditor_symmetrical) == 2)
 134         {
 135                 float m = havocbot_symmetryaxis_equation.x;
 136                 float q = havocbot_symmetryaxis_equation.y;
 137                 if (autocvar_g_waypointeditor_symmetrical == -2)
 138                 {
 139                         m = autocvar_g_waypointeditor_symmetrical_axis.x;
 140                         q = autocvar_g_waypointeditor_symmetrical_axis.y;
 141                 }
 142
 143                 new_org.x = (1 / (1 + m*m)) * ((1 - m*m) * org.x + 2 * m * org.y - 2 * m * q);
 144                 new_org.y = (1 / (1 + m*m)) * (2 * m * org.x + (m*m - 1) * org.y + 2 * q);
 145         }
 146         new_org.z = org.z;
 147         return new_org;
 148 }
 149
 150 void waypoint_setupmodel(entity wp)
 151 {
 152         if (autocvar_g_waypointeditor)
 153         {
 154                 // TODO: add some sort of visible box in edit mode for box waypoints
 155                 vector m1 = wp.mins;
 156                 vector m2 = wp.maxs;
 157                 setmodel(wp, MDL_WAYPOINT);
 158                 setsize(wp, m1, m2);
 159                 wp.effects = EF_LOWPRECISION;
 160                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 161                         wp.colormod = '1 0 0';
 162                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 163                         wp.colormod = '1 1 0';
 164                 else
 165                         wp.colormod = '1 1 1';
 166         }
 167         else
 168                 wp.model = "";
 169 }
 170
 171 // create a new spawnfunc_waypoint and automatically link it to other waypoints, and link
 172 // them back to it as well
 173 // (suitable for spawnfunc_waypoint editor)
 174 entity waypoint_spawn(vector m1, vector m2, float f)
 175 {
 176         if(!(f & WAYPOINTFLAG_PERSONAL))
 177         {
 178                 vector em1 = m1;
 179                 vector em2 = m2;
 180                 if (m1 == m2)
 181                 {
 182                         em1 = m1 - '8 8 8';
 183                         em2 = m2 + '8 8 8';
 184                 }
 185                 IL_EACH(g_waypoints, boxesoverlap(em1, em2, it.absmin, it.absmax),
 186                 {
 187                         return it;
 188                 });
 189         }
 190
 191         entity w = new(waypoint);
 192         IL_PUSH(g_waypoints, w);
 193         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 194         w.wpflags = f;
 195         w.solid = SOLID_TRIGGER;
 196         setorigin(w, (m1 + m2) * 0.5);
 197         setsize(w, m1 - w.origin, m2 - w.origin);
 198         if (w.size)
 199                 w.wpisbox = true;
 200
 201         if(!w.wpisbox)
 202         {
 203                 setsize(w, PL_MIN_CONST - '1 1 0', PL_MAX_CONST + '1 1 0');
 204                 if(!move_out_of_solid(w))
 205                 {
 206                         if(!(f & WAYPOINTFLAG_GENERATED))
 207                         {
 208                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin));
 209                                 delete(w);
 210                                 return NULL;
 211                         }
 212                         else
 213                         {
 214                                 if(autocvar_developer)
 215                                 {
 216                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin), "\n");
 217                                         backtrace("Waypoint stuck");
 218                                 }
 219                         }
 220                 }
 221                 setsize(w, '0 0 0', '0 0 0');
 222         }
 223
 224         waypoint_clearlinks(w);
 225         //waypoint_schedulerelink(w);
 226
 227         waypoint_setupmodel(w);
 228
 229         return w;
 230 }
 231
 232 void waypoint_spawn_fromeditor(entity pl)
 233 {
 234         entity e;
 235         vector org = pl.origin;
 236         int ctf_flags = havocbot_symmetryaxis_equation.z;
 237         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 238                    || (autocvar_g_waypointeditor_symmetrical < 0));
 239         int order = ctf_flags;
 240         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 241         {
 242                 order = autocvar_g_waypointeditor_symmetrical_order;
 243                 ctf_flags = order;
 244         }
 245
 246         if(!PHYS_INPUT_BUTTON_CROUCH(pl))
 247         {
 248                 // snap waypoint to item's origin if close enough
 249                 IL_EACH(g_items, true,
 250                 {
 251                         vector item_org = (it.absmin + it.absmax) * 0.5;
 252                         item_org.z = it.absmin.z - PL_MIN_CONST.z;
 253                         if(vlen(item_org - org) < 30)
 254                         {
 255                                 org = item_org;
 256                                 break;
 257                         }
 258                 });
 259         }
 260
 261         LABEL(add_wp);
 262         e = waypoint_spawn(org, org, 0);
 263         waypoint_schedulerelink(e);
 264         bprint(strcat("Waypoint spawned at ", vtos(org), "\n"));
 265         if(sym)
 266         {
 267                 org = waypoint_getSymmetricalOrigin(e.origin, ctf_flags);
 268                 if (vdist(org - pl.origin, >, 32))
 269                 {
 270                         if(order > 2)
 271                                 order--;
 272                         else
 273                                 sym = false;
 274                         goto add_wp;
 275                 }
 276         }
 277 }
 278
 279 void waypoint_remove(entity wp)
 280 {
 281         // tell all waypoints linked to wp that they need to relink
 282         IL_EACH(g_waypoints, it != wp,
 283         {
 284                 if (waypoint_islinked(it, wp))
 285                         waypoint_removelink(it, wp);
 286         });
 287         delete(wp);
 288 }
 289
 290 void waypoint_remove_fromeditor(entity pl)
 291 {
 292         entity e = navigation_findnearestwaypoint(pl, false);
 293
 294         int ctf_flags = havocbot_symmetryaxis_equation.z;
 295         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 296                    || (autocvar_g_waypointeditor_symmetrical < 0));
 297         int order = ctf_flags;
 298         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 299         {
 300                 order = autocvar_g_waypointeditor_symmetrical_order;
 301                 ctf_flags = order;
 302         }
 303
 304         LABEL(remove_wp);
 305         if (!e) return;
 306         if (e.wpflags & WAYPOINTFLAG_GENERATED) return;
 307
 308         if (e.wphardwired)
 309         {
 310                 LOG_INFO("^1Warning: ^7Removal of hardwired waypoints is not allowed in the editor. Please remove links from/to this waypoint (", vtos(e.origin), ") by hand from maps/", mapname, ".waypoints.hardwired\n");
 311                 return;
 312         }
 313
 314         entity wp_sym = NULL;
 315         if (sym)
 316         {
 317                 vector org = waypoint_getSymmetricalOrigin(e.origin, ctf_flags);
 318                 FOREACH_ENTITY_CLASS("waypoint", !(it.wpflags & WAYPOINTFLAG_GENERATED), {
 319                         if(vdist(org - it.origin, <, 3))
 320                         {
 321                                 wp_sym = it;
 322                                 break;
 323                         }
 324                 });
 325         }
 326
 327         bprint(strcat("Waypoint removed at ", vtos(e.origin), "\n"));
 328         waypoint_remove(e);
 329
 330         if (sym && wp_sym)
 331         {
 332                 e = wp_sym;
 333                 if(order > 2)
 334                         order--;
 335                 else
 336                         sym = false;
 337                 goto remove_wp;
 338         }
 339 }
 340
 341 void waypoint_removelink(entity from, entity to)
 342 {
 343         if (from == to || (from.wpflags & WAYPOINTFLAG_NORELINK))
 344                 return;
 345
 346         bool found = false;
 347         if (!found && from.wp00 == to) found = true; if (found) {from.wp00 = from.wp01; from.wp00mincost = from.wp01mincost;}
 348         if (!found && from.wp01 == to) found = true; if (found) {from.wp01 = from.wp02; from.wp01mincost = from.wp02mincost;}
 349         if (!found && from.wp02 == to) found = true; if (found) {from.wp02 = from.wp03; from.wp02mincost = from.wp03mincost;}
 350         if (!found && from.wp03 == to) found = true; if (found) {from.wp03 = from.wp04; from.wp03mincost = from.wp04mincost;}
 351         if (!found && from.wp04 == to) found = true; if (found) {from.wp04 = from.wp05; from.wp04mincost = from.wp05mincost;}
 352         if (!found && from.wp05 == to) found = true; if (found) {from.wp05 = from.wp06; from.wp05mincost = from.wp06mincost;}
 353         if (!found && from.wp06 == to) found = true; if (found) {from.wp06 = from.wp07; from.wp06mincost = from.wp07mincost;}
 354         if (!found && from.wp07 == to) found = true; if (found) {from.wp07 = from.wp08; from.wp07mincost = from.wp08mincost;}
 355         if (!found && from.wp08 == to) found = true; if (found) {from.wp08 = from.wp09; from.wp08mincost = from.wp09mincost;}
 356         if (!found && from.wp09 == to) found = true; if (found) {from.wp09 = from.wp10; from.wp09mincost = from.wp10mincost;}
 357         if (!found && from.wp10 == to) found = true; if (found) {from.wp10 = from.wp11; from.wp10mincost = from.wp11mincost;}
 358         if (!found && from.wp11 == to) found = true; if (found) {from.wp11 = from.wp12; from.wp11mincost = from.wp12mincost;}
 359         if (!found && from.wp12 == to) found = true; if (found) {from.wp12 = from.wp13; from.wp12mincost = from.wp13mincost;}
 360         if (!found && from.wp13 == to) found = true; if (found) {from.wp13 = from.wp14; from.wp13mincost = from.wp14mincost;}
 361         if (!found && from.wp14 == to) found = true; if (found) {from.wp14 = from.wp15; from.wp14mincost = from.wp15mincost;}
 362         if (!found && from.wp15 == to) found = true; if (found) {from.wp15 = from.wp16; from.wp15mincost = from.wp16mincost;}
 363         if (!found && from.wp16 == to) found = true; if (found) {from.wp16 = from.wp17; from.wp16mincost = from.wp17mincost;}
 364         if (!found && from.wp17 == to) found = true; if (found) {from.wp17 = from.wp18; from.wp17mincost = from.wp18mincost;}
 365         if (!found && from.wp18 == to) found = true; if (found) {from.wp18 = from.wp19; from.wp18mincost = from.wp19mincost;}
 366         if (!found && from.wp19 == to) found = true; if (found) {from.wp19 = from.wp20; from.wp19mincost = from.wp20mincost;}
 367         if (!found && from.wp20 == to) found = true; if (found) {from.wp20 = from.wp21; from.wp20mincost = from.wp21mincost;}
 368         if (!found && from.wp21 == to) found = true; if (found) {from.wp21 = from.wp22; from.wp21mincost = from.wp22mincost;}
 369         if (!found && from.wp22 == to) found = true; if (found) {from.wp22 = from.wp23; from.wp22mincost = from.wp23mincost;}
 370         if (!found && from.wp23 == to) found = true; if (found) {from.wp23 = from.wp24; from.wp23mincost = from.wp24mincost;}
 371         if (!found && from.wp24 == to) found = true; if (found) {from.wp24 = from.wp25; from.wp24mincost = from.wp25mincost;}
 372         if (!found && from.wp25 == to) found = true; if (found) {from.wp25 = from.wp26; from.wp25mincost = from.wp26mincost;}
 373         if (!found && from.wp26 == to) found = true; if (found) {from.wp26 = from.wp27; from.wp26mincost = from.wp27mincost;}
 374         if (!found && from.wp27 == to) found = true; if (found) {from.wp27 = from.wp28; from.wp27mincost = from.wp28mincost;}
 375         if (!found && from.wp28 == to) found = true; if (found) {from.wp28 = from.wp29; from.wp28mincost = from.wp29mincost;}
 376         if (!found && from.wp29 == to) found = true; if (found) {from.wp29 = from.wp30; from.wp29mincost = from.wp30mincost;}
 377         if (!found && from.wp30 == to) found = true; if (found) {from.wp30 = from.wp31; from.wp30mincost = from.wp31mincost;}
 378         if (found) {from.wp31 = NULL; from.wp31mincost = 10000000;}
 379 }
 380
 381 bool waypoint_islinked(entity from, entity to)
 382 {
 383         if (from.wp00 == to) return true;if (from.wp01 == to) return true;if (from.wp02 == to) return true;if (from.wp03 == to) return true;
 384         if (from.wp04 == to) return true;if (from.wp05 == to) return true;if (from.wp06 == to) return true;if (from.wp07 == to) return true;
 385         if (from.wp08 == to) return true;if (from.wp09 == to) return true;if (from.wp10 == to) return true;if (from.wp11 == to) return true;
 386         if (from.wp12 == to) return true;if (from.wp13 == to) return true;if (from.wp14 == to) return true;if (from.wp15 == to) return true;
 387         if (from.wp16 == to) return true;if (from.wp17 == to) return true;if (from.wp18 == to) return true;if (from.wp19 == to) return true;
 388         if (from.wp20 == to) return true;if (from.wp21 == to) return true;if (from.wp22 == to) return true;if (from.wp23 == to) return true;
 389         if (from.wp24 == to) return true;if (from.wp25 == to) return true;if (from.wp26 == to) return true;if (from.wp27 == to) return true;
 390         if (from.wp28 == to) return true;if (from.wp29 == to) return true;if (from.wp30 == to) return true;if (from.wp31 == to) return true;
 391         return false;
 392 }
 393
 394 float waypoint_getdistancecost_simple(float dist)
 395 {
 396         return dist / autocvar_sv_maxspeed;
 397 }
 398
 399 float waypoint_getdistancecost(vector from, vector to)
 400 {
 401         float c = waypoint_getdistancecost_simple(vlen(to - from));
 402
 403         float height = from.z - to.z;
 404         if(height > 0 && autocvar_sv_gravity > 0)
 405         {
 406                 float height_cost = sqrt(height / (autocvar_sv_gravity / 2));
 407                 float xydist = vlen(vec2(to - from));
 408                 float xydist_cost = xydist / autocvar_sv_maxspeed;
 409                 if(max(height_cost, xydist_cost) < c)
 410                         c = max(height_cost, xydist_cost);
 411         }
 412         return c;
 413 }
 414
 415 float waypoint_getlinkcost(entity from, entity to)
 416 {
 417         vector v1 = from.origin;
 418         vector v2 = to.origin;
 419         if (from.wpisbox)
 420         {
 421                 vector m1 = to.absmin, m2 = to.absmax;
 422                 v1_x = bound(m1_x, v1_x, m2_x);
 423                 v1_y = bound(m1_y, v1_y, m2_y);
 424                 v1_z = bound(m1_z, v1_z, m2_z);
 425         }
 426         if (to.wpisbox)
 427         {
 428                 vector m1 = from.absmin, m2 = from.absmax;
 429                 v2_x = bound(m1_x, v2_x, m2_x);
 430                 v2_y = bound(m1_y, v2_y, m2_y);
 431                 v2_z = bound(m1_z, v2_z, m2_z);
 432         }
 433         return waypoint_getdistancecost(v1, v2);
 434 }
 435
 436 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
 437 // if c == -1 automatically determine cost of the link
 438 void waypoint_addlink_customcost(entity from, entity to, float c)
 439 {
 440         if (from == to || waypoint_islinked(from, to))
 441                 return;
 442         if (c == -1 && (from.wpflags & WAYPOINTFLAG_NORELINK))
 443                 return;
 444
 445         if(c == -1)
 446                 c = waypoint_getlinkcost(from, to);
 447
 448         if (from.wp31mincost < c) return;
 449         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 450         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 451         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 452         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 453         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 454         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 455         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 456         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 457         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 458         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 459         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 460         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 461         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 462         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 463         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 464         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 465         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 466         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 467         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 468         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 469         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 470         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 471         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 472         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 473         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 474         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 475         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 476         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 477         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 478         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 479         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 480         from.wp00 = to;from.wp00mincost = c;return;
 481 }
 482
 483 void waypoint_addlink(entity from, entity to)
 484 {
 485         waypoint_addlink_customcost(from, to, -1);
 486 }
 487
 488 // relink this spawnfunc_waypoint
 489 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
 490 // (SLOW!)
 491 void waypoint_think(entity this)
 492 {
 493         vector sv, sm1, sm2, ev, em1, em2, dv;
 494
 495         bot_calculate_stepheightvec();
 496
 497         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 498
 499         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
 500         sm1 = this.origin + this.mins;
 501         sm2 = this.origin + this.maxs;
 502         IL_EACH(g_waypoints, this != it,
 503         {
 504                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
 505                 {
 506                         waypoint_addlink(this, it);
 507                         waypoint_addlink(it, this);
 508                 }
 509                 else
 510                 {
 511                         ++relink_total;
 512                         if(!checkpvs(this.origin, it))
 513                         {
 514                                 ++relink_pvsculled;
 515                                 continue;
 516                         }
 517                         sv = it.origin;
 518                         sv.x = bound(sm1_x, sv.x, sm2_x);
 519                         sv.y = bound(sm1_y, sv.y, sm2_y);
 520                         sv.z = bound(sm1_z, sv.z, sm2_z);
 521                         ev = this.origin;
 522                         em1 = it.origin + it.mins;
 523                         em2 = it.origin + it.maxs;
 524                         ev.x = bound(em1_x, ev.x, em2_x);
 525                         ev.y = bound(em1_y, ev.y, em2_y);
 526                         ev.z = bound(em1_z, ev.z, em2_z);
 527                         dv = ev - sv;
 528                         dv.z = 0;
 529                         if(vdist(dv, >=, 1050)) // max search distance in XY
 530                         {
 531                                 ++relink_lengthculled;
 532                                 continue;
 533                         }
 534                         navigation_testtracewalk = 0;
 535                         if (!this.wpisbox)
 536                         {
 537                                 tracebox(sv - PL_MIN_CONST.z * '0 0 1', PL_MIN_CONST, PL_MAX_CONST, sv, false, this);
 538                                 if (!trace_startsolid)
 539                                 {
 540                                         //dprint("sv deviation", vtos(trace_endpos - sv), "\n");
 541                                         sv = trace_endpos + '0 0 1';
 542                                 }
 543                         }
 544                         if (!it.wpisbox)
 545                         {
 546                                 tracebox(ev - PL_MIN_CONST.z * '0 0 1', PL_MIN_CONST, PL_MAX_CONST, ev, false, it);
 547                                 if (!trace_startsolid)
 548                                 {
 549                                         //dprint("ev deviation", vtos(trace_endpos - ev), "\n");
 550                                         ev = trace_endpos + '0 0 1';
 551                                 }
 552                         }
 553                         //traceline(this.origin, it.origin, false, NULL);
 554                         //if (trace_fraction == 1)
 555                         if (!this.wpisbox && tracewalk(this, sv, PL_MIN_CONST, PL_MAX_CONST, ev, MOVE_NOMONSTERS))
 556                                 waypoint_addlink(this, it);
 557                         else
 558                                 relink_walkculled += 0.5;
 559                         if (!it.wpisbox && tracewalk(it, ev, PL_MIN_CONST, PL_MAX_CONST, sv, MOVE_NOMONSTERS))
 560                                 waypoint_addlink(it, this);
 561                         else
 562                                 relink_walkculled += 0.5;
 563                 }
 564         });
 565         navigation_testtracewalk = 0;
 566         this.wplinked = true;
 567 }
 568
 569 void waypoint_clearlinks(entity wp)
 570 {
 571         // clear links to other waypoints
 572         float f = 10000000;
 573         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
 574         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
 575         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
 576         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
 577
 578         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
 579         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
 580         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
 581         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
 582
 583         wp.wplinked = false;
 584 }
 585
 586 // tell a spawnfunc_waypoint to relink
 587 void waypoint_schedulerelink(entity wp)
 588 {
 589         if (wp == NULL)
 590                 return;
 591
 592         waypoint_setupmodel(wp);
 593         wp.wpisbox = vdist(wp.size, >, 0);
 594         wp.enemy = NULL;
 595         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
 596                 wp.owner = NULL;
 597         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
 598                 waypoint_clearlinks(wp);
 599         // schedule an actual relink on next frame
 600         setthink(wp, waypoint_think);
 601         wp.nextthink = time;
 602         wp.effects = EF_LOWPRECISION;
 603 }
 604
 605 // spawnfunc_waypoint map entity
 606 spawnfunc(waypoint)
 607 {
 608         IL_PUSH(g_waypoints, this);
 609
 610         setorigin(this, this.origin);
 611         // schedule a relink after other waypoints have had a chance to spawn
 612         waypoint_clearlinks(this);
 613         //waypoint_schedulerelink(this);
 614 }
 615
 616 // tell all waypoints to relink
 617 // actually this is useful only to update relink_* stats
 618 void waypoint_schedulerelinkall()
 619 {
 620         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
 621         IL_EACH(g_waypoints, true,
 622         {
 623                 waypoint_schedulerelink(it);
 624         });
 625         waypoint_load_links_hardwired();
 626 }
 627
 628 // Load waypoint links from file
 629 bool waypoint_load_links()
 630 {
 631         string filename, s;
 632         float file, tokens, c = 0, found;
 633         entity wp_from = NULL, wp_to;
 634         vector wp_to_pos, wp_from_pos;
 635         filename = strcat("maps/", mapname);
 636         filename = strcat(filename, ".waypoints.cache");
 637         file = fopen(filename, FILE_READ);
 638
 639         if (file < 0)
 640         {
 641                 LOG_TRACE("waypoint links load from ");
 642                 LOG_TRACE(filename);
 643                 LOG_TRACE(" failed");
 644                 return false;
 645         }
 646
 647         while ((s = fgets(file)))
 648         {
 649                 tokens = tokenizebyseparator(s, "*");
 650
 651                 if (tokens!=2)
 652                 {
 653                         // bad file format
 654                         fclose(file);
 655                         return false;
 656                 }
 657
 658                 wp_from_pos     = stov(argv(0));
 659                 wp_to_pos       = stov(argv(1));
 660
 661                 // Search "from" waypoint
 662                 if(!wp_from || wp_from.origin!=wp_from_pos)
 663                 {
 664                         wp_from = findradius(wp_from_pos, 1);
 665                         found = false;
 666                         while(wp_from)
 667                         {
 668                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
 669                                 if(wp_from.classname == "waypoint")
 670                                 {
 671                                         found = true;
 672                                         break;
 673                                 }
 674                                 wp_from = wp_from.chain;
 675                         }
 676
 677                         if(!found)
 678                         {
 679                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from_pos));
 680                                 continue;
 681                         }
 682
 683                 }
 684
 685                 // Search "to" waypoint
 686                 wp_to = findradius(wp_to_pos, 1);
 687                 found = false;
 688                 while(wp_to)
 689                 {
 690                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
 691                         if(wp_to.classname == "waypoint")
 692                         {
 693                                 found = true;
 694                                 break;
 695                         }
 696                         wp_to = wp_to.chain;
 697                 }
 698
 699                 if(!found)
 700                 {
 701                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to_pos));
 702                         continue;
 703                 }
 704
 705                 ++c;
 706                 waypoint_addlink(wp_from, wp_to);
 707         }
 708
 709         fclose(file);
 710
 711         LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.cache");
 712
 713         botframe_cachedwaypointlinks = true;
 714         return true;
 715 }
 716
 717 void waypoint_load_or_remove_links_hardwired(bool removal_mode)
 718 {
 719         string filename, s;
 720         float file, tokens, c = 0, found;
 721         entity wp_from = NULL, wp_to;
 722         vector wp_to_pos, wp_from_pos;
 723         filename = strcat("maps/", mapname);
 724         filename = strcat(filename, ".waypoints.hardwired");
 725         file = fopen(filename, FILE_READ);
 726
 727         botframe_loadedforcedlinks = true;
 728
 729         if (file < 0)
 730         {
 731                 if(!removal_mode)
 732                         LOG_TRACE("waypoint links load from ", filename, " failed");
 733                 return;
 734         }
 735
 736         while ((s = fgets(file)))
 737         {
 738                 if(substring(s, 0, 2)=="//")
 739                         continue;
 740
 741                 if(substring(s, 0, 1)=="#")
 742                         continue;
 743
 744                 tokens = tokenizebyseparator(s, "*");
 745
 746                 if (tokens!=2)
 747                         continue;
 748
 749                 wp_from_pos     = stov(argv(0));
 750                 wp_to_pos       = stov(argv(1));
 751
 752                 // Search "from" waypoint
 753                 if(!wp_from || wp_from.origin!=wp_from_pos)
 754                 {
 755                         wp_from = findradius(wp_from_pos, 5);
 756                         found = false;
 757                         while(wp_from)
 758                         {
 759                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
 760                                 if(wp_from.classname == "waypoint")
 761                                 {
 762                                         found = true;
 763                                         break;
 764                                 }
 765                                 wp_from = wp_from.chain;
 766                         }
 767
 768                         if(!found)
 769                         {
 770                                 if(!removal_mode)
 771                                         LOG_INFO(strcat("NOTICE: Can not find waypoint at ", vtos(wp_from_pos), ". Path skipped\n"));
 772                                 continue;
 773                         }
 774                 }
 775
 776                 // Search "to" waypoint
 777                 wp_to = findradius(wp_to_pos, 5);
 778                 found = false;
 779                 while(wp_to)
 780                 {
 781                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
 782                         if(wp_to.classname == "waypoint")
 783                         {
 784                                 found = true;
 785                                 break;
 786                         }
 787                         wp_to = wp_to.chain;
 788                 }
 789
 790                 if(!found)
 791                 {
 792                         if(!removal_mode)
 793                                 LOG_INFO(strcat("NOTICE: Can not find waypoint at ", vtos(wp_to_pos), ". Path skipped\n"));
 794                         continue;
 795                 }
 796
 797                 ++c;
 798                 if(removal_mode)
 799                 {
 800                         waypoint_removelink(wp_from, wp_to);
 801                         continue;
 802                 }
 803
 804                 waypoint_addlink(wp_from, wp_to);
 805                 wp_from.wphardwired = true;
 806                 wp_to.wphardwired = true;
 807         }
 808
 809         fclose(file);
 810
 811         if(!removal_mode)
 812                 LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired");
 813 }
 814
 815 void waypoint_load_links_hardwired() { waypoint_load_or_remove_links_hardwired(false); }
 816 void waypoint_remove_links_hardwired() { waypoint_load_or_remove_links_hardwired(true); }
 817
 818 entity waypoint_get_link(entity w, float i)
 819 {
 820         switch(i)
 821         {
 822                 case  0:return w.wp00;
 823                 case  1:return w.wp01;
 824                 case  2:return w.wp02;
 825                 case  3:return w.wp03;
 826                 case  4:return w.wp04;
 827                 case  5:return w.wp05;
 828                 case  6:return w.wp06;
 829                 case  7:return w.wp07;
 830                 case  8:return w.wp08;
 831                 case  9:return w.wp09;
 832                 case 10:return w.wp10;
 833                 case 11:return w.wp11;
 834                 case 12:return w.wp12;
 835                 case 13:return w.wp13;
 836                 case 14:return w.wp14;
 837                 case 15:return w.wp15;
 838                 case 16:return w.wp16;
 839                 case 17:return w.wp17;
 840                 case 18:return w.wp18;
 841                 case 19:return w.wp19;
 842                 case 20:return w.wp20;
 843                 case 21:return w.wp21;
 844                 case 22:return w.wp22;
 845                 case 23:return w.wp23;
 846                 case 24:return w.wp24;
 847                 case 25:return w.wp25;
 848                 case 26:return w.wp26;
 849                 case 27:return w.wp27;
 850                 case 28:return w.wp28;
 851                 case 29:return w.wp29;
 852                 case 30:return w.wp30;
 853                 case 31:return w.wp31;
 854                 default:return NULL;
 855         }
 856 }
 857
 858 // Save all waypoint links to a file
 859 void waypoint_save_links()
 860 {
 861         // temporarily remove hardwired links so they don't get saved among normal links
 862         waypoint_remove_links_hardwired();
 863
 864         string filename = sprintf("maps/%s.waypoints.cache", mapname);
 865         int file = fopen(filename, FILE_WRITE);
 866         if (file < 0)
 867         {
 868                 LOG_INFOF("waypoint link save to %s failed\n", filename);
 869                 return;
 870         }
 871
 872         int c = 0;
 873         IL_EACH(g_waypoints, true,
 874         {
 875                 for(int j = 0; j < 32; ++j)
 876                 {
 877                         entity link = waypoint_get_link(it, j);
 878                         if(link)
 879                         {
 880                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
 881                                 fputs(file, s);
 882                                 ++c;
 883                         }
 884                 }
 885         });
 886         fclose(file);
 887         botframe_cachedwaypointlinks = true;
 888
 889         LOG_INFOF("saved %d waypoint links to maps/%s.waypoints.cache\n", c, mapname);
 890
 891         waypoint_load_links_hardwired();
 892 }
 893
 894 // save waypoints to gamedir/data/maps/mapname.waypoints
 895 void waypoint_saveall()
 896 {
 897         string filename = sprintf("maps/%s.waypoints", mapname);
 898         int file = fopen(filename, FILE_WRITE);
 899         if (file < 0)
 900         {
 901                 waypoint_save_links(); // save anyway?
 902                 botframe_loadedforcedlinks = false;
 903
 904                 LOG_INFOF("waypoint links: save to %s failed\n", filename);
 905                 return;
 906         }
 907
 908         int c = 0;
 909         IL_EACH(g_waypoints, true,
 910         {
 911                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
 912                         continue;
 913
 914                 string s;
 915                 s = strcat(vtos(it.origin + it.mins), "\n");
 916                 s = strcat(s, vtos(it.origin + it.maxs));
 917                 s = strcat(s, "\n");
 918                 s = strcat(s, ftos(it.wpflags));
 919                 s = strcat(s, "\n");
 920                 fputs(file, s);
 921                 c++;
 922         });
 923         fclose(file);
 924         waypoint_save_links();
 925         botframe_loadedforcedlinks = false;
 926
 927         LOG_INFOF("saved %d waypoints to maps/%s.waypoints\n", c, mapname);
 928 }
 929
 930 // load waypoints from file
 931 float waypoint_loadall()
 932 {
 933         string filename, s;
 934         float file, cwp, cwb, fl;
 935         vector m1, m2;
 936         cwp = 0;
 937         cwb = 0;
 938         filename = strcat("maps/", mapname);
 939         filename = strcat(filename, ".waypoints");
 940         file = fopen(filename, FILE_READ);
 941         if (file >= 0)
 942         {
 943                 while ((s = fgets(file)))
 944                 {
 945                         m1 = stov(s);
 946                         s = fgets(file);
 947                         if (!s)
 948                                 break;
 949                         m2 = stov(s);
 950                         s = fgets(file);
 951                         if (!s)
 952                                 break;
 953                         fl = stof(s);
 954                         waypoint_spawn(m1, m2, fl);
 955                         if (m1 == m2)
 956                                 cwp = cwp + 1;
 957                         else
 958                                 cwb = cwb + 1;
 959                 }
 960                 fclose(file);
 961                 LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints");
 962         }
 963         else
 964         {
 965                 LOG_TRACE("waypoint load from ", filename, " failed");
 966         }
 967         return cwp + cwb;
 968 }
 969
 970 vector waypoint_fixorigin(vector position)
 971 {
 972         tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z), PL_MIN_CONST, PL_MAX_CONST, position + '0 0 -512', MOVE_NOMONSTERS, NULL);
 973         if(trace_fraction < 1)
 974                 position = trace_endpos;
 975         //traceline(position, position + '0 0 -512', MOVE_NOMONSTERS, NULL);
 976         //print("position is ", ftos(trace_endpos_z - position_z), " above solid\n");
 977         return position;
 978 }
 979
 980 void waypoint_spawnforitem_force(entity e, vector org)
 981 {
 982         // Fix the waypoint altitude if necessary
 983         org = waypoint_fixorigin(org);
 984
 985         // don't spawn an item spawnfunc_waypoint if it already exists
 986         IL_EACH(g_waypoints, true,
 987         {
 988                 if(it.wpisbox)
 989                 {
 990                         if(boxesoverlap(org, org, it.absmin, it.absmax))
 991                         {
 992                                 e.nearestwaypoint = it;
 993                                 return;
 994                         }
 995                 }
 996                 else
 997                 {
 998                         if(vdist(it.origin - org, <, 16))
 999                         {
1000                                 e.nearestwaypoint = it;
1001                                 return;
1002                         }
1003                 }
1004         });
1005
1006         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
1007 }
1008
1009 void waypoint_spawnforitem(entity e)
1010 {
1011         if(!bot_waypoints_for_items)
1012                 return;
1013
1014         waypoint_spawnforitem_force(e, e.origin);
1015 }
1016
1017 void waypoint_spawnforteleporter_boxes(entity e, int teleport_flag, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
1018 {
1019         entity w;
1020         entity dw;
1021         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | teleport_flag | WAYPOINTFLAG_NORELINK);
1022         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
1023         // one way link to the destination
1024         w.wp00 = dw;
1025         w.wp00mincost = timetaken; // this is just for jump pads
1026         // the teleporter's nearest spawnfunc_waypoint is this one
1027         // (teleporters are not goals, so this is probably useless)
1028         e.nearestwaypoint = w;
1029         e.nearestwaypointtimeout = -1;
1030 }
1031
1032 void waypoint_spawnforteleporter_v(entity e, vector org, vector destination, float timetaken)
1033 {
1034         org = waypoint_fixorigin(org);
1035         destination = waypoint_fixorigin(destination);
1036         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, org, org, destination, destination, timetaken);
1037 }
1038
1039 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken)
1040 {
1041         destination = waypoint_fixorigin(destination);
1042         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, e.absmin, e.absmax, destination, destination, timetaken);
1043 }
1044
1045 entity waypoint_spawnpersonal(entity this, vector position)
1046 {
1047         entity w;
1048
1049         // drop the waypoint to a proper location:
1050         //   first move it up by a player height
1051         //   then move it down to hit the floor with player bbox size
1052         position = waypoint_fixorigin(position);
1053
1054         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
1055         w.nearestwaypoint = NULL;
1056         w.nearestwaypointtimeout = 0;
1057         w.owner = this;
1058
1059         waypoint_schedulerelink(w);
1060
1061         return w;
1062 }
1063
1064 void waypoint_showlink(entity wp1, entity wp2, int display_type)
1065 {
1066         if (!(wp1 && wp2))
1067                 return;
1068
1069         if (wp1.wphardwired && wp2.wphardwired)
1070                 te_beam(NULL, wp1.origin, wp2.origin);
1071         else if (display_type == 1)
1072                 te_lightning2(NULL, wp1.origin, wp2.origin);
1073 }
1074
1075 void waypoint_showlinks_to(entity wp, int display_type)
1076 {
1077         IL_EACH(g_waypoints, it != wp,
1078         {
1079                 if (waypoint_islinked(it, wp))
1080                         waypoint_showlink(it, wp, display_type);
1081         });
1082 }
1083
1084 void waypoint_showlinks_from(entity wp, int display_type)
1085 {
1086         waypoint_showlink(wp.wp00, wp, display_type); waypoint_showlink(wp.wp16, wp, display_type);
1087         waypoint_showlink(wp.wp01, wp, display_type); waypoint_showlink(wp.wp17, wp, display_type);
1088         waypoint_showlink(wp.wp02, wp, display_type); waypoint_showlink(wp.wp18, wp, display_type);
1089         waypoint_showlink(wp.wp03, wp, display_type); waypoint_showlink(wp.wp19, wp, display_type);
1090         waypoint_showlink(wp.wp04, wp, display_type); waypoint_showlink(wp.wp20, wp, display_type);
1091         waypoint_showlink(wp.wp05, wp, display_type); waypoint_showlink(wp.wp21, wp, display_type);
1092         waypoint_showlink(wp.wp06, wp, display_type); waypoint_showlink(wp.wp22, wp, display_type);
1093         waypoint_showlink(wp.wp07, wp, display_type); waypoint_showlink(wp.wp23, wp, display_type);
1094         waypoint_showlink(wp.wp08, wp, display_type); waypoint_showlink(wp.wp24, wp, display_type);
1095         waypoint_showlink(wp.wp09, wp, display_type); waypoint_showlink(wp.wp25, wp, display_type);
1096         waypoint_showlink(wp.wp10, wp, display_type); waypoint_showlink(wp.wp26, wp, display_type);
1097         waypoint_showlink(wp.wp11, wp, display_type); waypoint_showlink(wp.wp27, wp, display_type);
1098         waypoint_showlink(wp.wp12, wp, display_type); waypoint_showlink(wp.wp28, wp, display_type);
1099         waypoint_showlink(wp.wp13, wp, display_type); waypoint_showlink(wp.wp29, wp, display_type);
1100         waypoint_showlink(wp.wp14, wp, display_type); waypoint_showlink(wp.wp30, wp, display_type);
1101         waypoint_showlink(wp.wp15, wp, display_type); waypoint_showlink(wp.wp31, wp, display_type);
1102 }
1103
1104 void botframe_showwaypointlinks()
1105 {
1106         if (time < botframe_waypointeditorlightningtime)
1107                 return;
1108         botframe_waypointeditorlightningtime = time + 0.5;
1109         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
1110         {
1111                 int display_type = 0;
1112                 entity head = navigation_findnearestwaypoint(it, false);
1113                 if (IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE)
1114                         display_type = 1; // default
1115                 else if(head && (head.wphardwired))
1116                         display_type = 2; // only hardwired
1117
1118                 if (display_type)
1119                 {
1120                         //navigation_testtracewalk = true;
1121                         //print("currently selected WP is ", etos(head), "\n");
1122                         //navigation_testtracewalk = false;
1123                         if (head)
1124                         {
1125                                 te_lightning2(NULL, head.origin, it.origin);
1126                                 if(PHYS_INPUT_BUTTON_CROUCH(it))
1127                                         waypoint_showlinks_to(head, display_type);
1128                                 else
1129                                         waypoint_showlinks_from(head, display_type);
1130                         }
1131                 }
1132         });
1133 }
1134
1135 float botframe_autowaypoints_fixdown(vector v)
1136 {
1137         tracebox(v, PL_MIN_CONST, PL_MAX_CONST, v + '0 0 -64', MOVE_NOMONSTERS, NULL);
1138         if(trace_fraction >= 1)
1139                 return 0;
1140         return 1;
1141 }
1142
1143 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
1144 {
1145         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
1146         {
1147                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
1148                 return 0;
1149         });
1150
1151         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
1152         return 1;
1153 }
1154
1155 // return value:
1156 //    1 = WP created
1157 //    0 = no action needed
1158 //   -1 = temp fail, try from world too
1159 //   -2 = permanent fail, do not retry
1160 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
1161 {
1162         // make it possible to go from p to wp, if we can
1163         // if wp is NULL, nearest is chosen
1164
1165         entity w;
1166         vector porg;
1167         float t, tmin, tmax;
1168         vector o;
1169         vector save;
1170
1171         if(!botframe_autowaypoints_fixdown(p.origin))
1172                 return -2;
1173         porg = trace_endpos;
1174
1175         if(wp)
1176         {
1177                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
1178
1179                 // if wp -> porg, then OK
1180                 float maxdist;
1181                 if(navigation_waypoint_will_link(wp.origin, porg, p, walkfromwp, 1050))
1182                 {
1183                         // we may find a better one
1184                         maxdist = vlen(wp.origin - porg);
1185                 }
1186                 else
1187                 {
1188                         // accept any "good"
1189                         maxdist = 2100;
1190                 }
1191
1192                 float bestdist = maxdist;
1193                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WAYPOINTFLAG_NORELINK),
1194                 {
1195                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
1196                         if(d < bestdist)
1197                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, walkfromwp, 1050))
1198                         if(navigation_waypoint_will_link(it.origin, porg, p, walkfromwp, 1050))
1199                         {
1200                                 bestdist = d;
1201                                 p.(fld) = it;
1202                         }
1203                 });
1204                 if(bestdist < maxdist)
1205                 {
1206                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)), "\n");
1207                         return 0;
1208                 }
1209
1210                 if(bestdist < 2100)
1211                 {
1212                         // we know maxdist < 2100
1213                         // so wp -> porg is still valid
1214                         // all is good
1215                         p.(fld) = wp;
1216                         return 0;
1217                 }
1218
1219                 // otherwise, no existing WP can fix our issues
1220         }
1221         else
1222         {
1223                 save = p.origin;
1224                 setorigin(p, porg);
1225                 w = navigation_findnearestwaypoint(p, walkfromwp);
1226                 setorigin(p, save);
1227                 if(w)
1228                 {
1229                         p.(fld) = w;
1230                         return 0;
1231                 }
1232         }
1233
1234         tmin = 0;
1235         tmax = 1;
1236         for (;;)
1237         {
1238                 if(tmax - tmin < 0.001)
1239                 {
1240                         // did not get a good candidate
1241                         return -1;
1242                 }
1243
1244                 t = (tmin + tmax) * 0.5;
1245                 o = antilag_takebackorigin(p, CS(p), time - t);
1246                 if(!botframe_autowaypoints_fixdown(o))
1247                         return -2;
1248                 o = trace_endpos;
1249
1250                 if(wp)
1251                 {
1252                         if(!navigation_waypoint_will_link(wp.origin, o, p, walkfromwp, 1050))
1253                         {
1254                                 // we cannot walk from wp.origin to o
1255                                 // get closer to tmax
1256                                 tmin = t;
1257                                 continue;
1258                         }
1259                 }
1260                 else
1261                 {
1262                         save = p.origin;
1263                         setorigin(p, o);
1264                         w = navigation_findnearestwaypoint(p, walkfromwp);
1265                         setorigin(p, save);
1266                         if(!w)
1267                         {
1268                                 // we cannot walk from any WP to o
1269                                 // get closer to tmax
1270                                 tmin = t;
1271                                 continue;
1272                         }
1273                 }
1274
1275                 // if we get here, o is valid regarding waypoints
1276                 // check if o is connected right to the player
1277                 // we break if it succeeds, as that means o is a good waypoint location
1278                 if(navigation_waypoint_will_link(o, porg, p, walkfromwp, 1050))
1279                         break;
1280
1281                 // o is no good, we need to get closer to the player
1282                 tmax = t;
1283         }
1284
1285         LOG_INFO("spawning a waypoint for connecting to ", etos(wp), "\n");
1286         botframe_autowaypoints_createwp(o, p, fld, 0);
1287         return 1;
1288 }
1289
1290 // automatically create missing waypoints
1291 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
1292 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
1293 {
1294         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
1295         if(r != -1)
1296                 return;
1297         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
1298         if(r != -1)
1299                 return;
1300
1301         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain\n");
1302         if(!botframe_autowaypoints_fixdown(p.origin))
1303                 return; // shouldn't happen, caught above
1304         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
1305 }
1306
1307 void botframe_deleteuselesswaypoints()
1308 {
1309         IL_EACH(g_items, it.bot_pickup,
1310         {
1311                 // NOTE: this protects waypoints if they're the ONLY nearest
1312                 // waypoint. That's the intention.
1313                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
1314                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
1315         });
1316         IL_EACH(g_waypoints, true,
1317         {
1318                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
1319                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
1320                 // WP is useful if:
1321                 if (it.wpflags & WAYPOINTFLAG_ITEM)
1322                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1323                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
1324                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1325                 if (it.wpflags & WAYPOINTFLAG_LADDER)
1326                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1327                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
1328                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1329                 // b) WP is closest WP for an item/spawnpoint/other entity
1330                 //    This has been done above by protecting these WPs.
1331         });
1332         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
1333         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
1334         {
1335                 for (int m = 0; m < 32; ++m)
1336                 {
1337                         entity w = waypoint_get_link(it, m);
1338                         if (!w)
1339                                 break;
1340                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
1341                                 continue;
1342                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
1343                                 continue;
1344                         for (int j = 0; j < 32; ++j)
1345                         {
1346                                 entity w2 = waypoint_get_link(w, j);
1347                                 if (!w2)
1348                                         break;
1349                                 if (it == w2)
1350                                         continue;
1351                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
1352                                         continue;
1353                                 // If we got here, it != w2 exist with it -> w
1354                                 // and w -> w2. That means the waypoint is not
1355                                 // a dead end.
1356                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
1357                                 for (int k = 0; k < 32; ++k)
1358                                 {
1359                                         if (waypoint_get_link(it, k) == w2)
1360                                                 continue;
1361                                         // IF WE GET HERE, w is proven useful
1362                                         // to get from it to w2!
1363                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1364                                         goto next;
1365                                 }
1366                         }
1367 LABEL(next)
1368                 }
1369         });
1370         // d) The waypoint is a dead end. Dead end waypoints must be kept as
1371         //     they are needed to complete routes while autowaypointing.
1372
1373         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
1374         {
1375                 LOG_INFOF("Removed a waypoint at %v. Try again for more!\n", it.origin);
1376                 te_explosion(it.origin);
1377                 waypoint_remove(it);
1378                 break;
1379         });
1380
1381         IL_EACH(g_waypoints, true,
1382         {
1383                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
1384         });
1385 }
1386
1387 void botframe_autowaypoints()
1388 {
1389         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), LAMBDA(
1390                 // going back is broken, so only fix waypoints to walk TO the player
1391                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
1392                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
1393                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
1394         ));
1395
1396         if (autocvar_g_waypointeditor_auto >= 2) {
1397                 botframe_deleteuselesswaypoints();
1398         }
1399 }
1400