qcsrc/server/bot/default/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "bot.qh"
   6 #include "navigation.qh"
   7
   8 #include <common/state.qh>
   9
  10 #include "../../antilag.qh"
  11
  12 #include <common/constants.qh>
  13 #include <common/net_linked.qh>
  14 #include <common/physics/player.qh>
  15
  16 #include <lib/warpzone/common.qh>
  17 #include <lib/warpzone/util_server.qh>
  18
  19 .entity spawnpointmodel;
  20 void waypoint_unreachable(entity pl)
  21 {
  22         IL_EACH(g_waypoints, true,
  23         {
  24                 it.colormod = '0.5 0.5 0.5';
  25                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  26         });
  27         entity e2 = navigation_findnearestwaypoint(pl, false);
  28         navigation_markroutes(pl, e2);
  29
  30         int j = 0;
  31         int m = 0;
  32         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  33         {
  34                 LOG_INFO("unreachable: ", etos(it), " ", vtos(it.origin), "\n");
  35                 it.colormod_z = 8;
  36                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
  37                 j++;
  38                 m++;
  39         });
  40         if (j) LOG_INFOF("%d waypoints cannot be reached from here in any way (marked with blue light)\n", j);
  41         navigation_markroutes_inverted(e2);
  42
  43         j = 0;
  44         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  45         {
  46                 LOG_INFO("cannot reach me: ", etos(it), " ", vtos(it.origin), "\n");
  47                 it.colormod_x = 8;
  48                 if (!(it.effects & EF_NODEPTHTEST))  // not already reported before
  49                         m++;
  50                 it.effects |= EF_NODEPTHTEST | EF_RED;
  51                 j++;
  52         });
  53         if (j) LOG_INFOF("%d waypoints cannot walk to here in any way (marked with red light)\n", j);
  54         if (m) LOG_INFOF("%d waypoints have been marked total\n", m);
  55
  56         j = 0;
  57         IL_EACH(g_spawnpoints, true,
  58         {
  59                 if (navigation_findnearestwaypoint(it, false))
  60                 {
  61                         if(it.spawnpointmodel)
  62                         {
  63                                 delete(it.spawnpointmodel);
  64                                 it.spawnpointmodel = NULL;
  65                         }
  66                 }
  67                 else
  68                 {
  69                         if(!it.spawnpointmodel)
  70                         {
  71                                 tracebox(it.origin, PL_MIN_CONST, PL_MAX_CONST, it.origin - '0 0 512', MOVE_NOMONSTERS, NULL);
  72                                 entity e = new(spawnpointmodel);
  73                                 vector org = trace_endpos + eZ;
  74                                 setorigin(e, org);
  75                                 e.solid = SOLID_TRIGGER;
  76                                 it.spawnpointmodel = e;
  77                         }
  78                         LOG_INFO("spawn without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
  79                         it.spawnpointmodel.effects |= EF_NODEPTHTEST;
  80                         _setmodel(it.spawnpointmodel, pl.model);
  81                         it.spawnpointmodel.frame = pl.frame;
  82                         it.spawnpointmodel.skin = pl.skin;
  83                         it.spawnpointmodel.colormap = pl.colormap;
  84                         it.spawnpointmodel.colormod = pl.colormod;
  85                         it.spawnpointmodel.glowmod = pl.glowmod;
  86                         setsize(it.spawnpointmodel, PL_MIN_CONST, PL_MAX_CONST);
  87                         j++;
  88                 }
  89         });
  90         if (j) LOG_INFOF("%d spawnpoints have no nearest waypoint (marked by player model)\n", j);
  91
  92         j = 0;
  93         IL_EACH(g_items, true,
  94         {
  95                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  96                 it.colormod = '0.5 0.5 0.5';
  97         });
  98         IL_EACH(g_items, true,
  99         {
 100                 if (navigation_findnearestwaypoint(it, false))
 101                         continue;
 102                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 103                 it.effects |= EF_NODEPTHTEST | EF_RED;
 104                 it.colormod_x = 8;
 105                 j++;
 106         });
 107         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked away from (marked with red light)\n", j);
 108
 109         j = 0;
 110         IL_EACH(g_items, true,
 111         {
 112                 if (navigation_findnearestwaypoint(it, true))
 113                         continue;
 114                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 115                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
 116                 it.colormod_z = 8;
 117                 j++;
 118         });
 119         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked to (marked with blue light)\n", j);
 120 }
 121
 122 vector waypoint_getSymmetricalOrigin(vector org, int ctf_flags)
 123 {
 124         vector new_org = org;
 125         if (fabs(autocvar_g_waypointeditor_symmetrical) == 1)
 126         {
 127                 vector map_center = havocbot_middlepoint;
 128                 if (autocvar_g_waypointeditor_symmetrical == -1)
 129                         map_center = autocvar_g_waypointeditor_symmetrical_origin;
 130
 131                 new_org = Rotate(org - map_center, 360 * DEG2RAD / ctf_flags) + map_center;
 132         }
 133         else if (fabs(autocvar_g_waypointeditor_symmetrical) == 2)
 134         {
 135                 float m = havocbot_symmetryaxis_equation.x;
 136                 float q = havocbot_symmetryaxis_equation.y;
 137                 if (autocvar_g_waypointeditor_symmetrical == -2)
 138                 {
 139                         m = autocvar_g_waypointeditor_symmetrical_axis.x;
 140                         q = autocvar_g_waypointeditor_symmetrical_axis.y;
 141                 }
 142
 143                 new_org.x = (1 / (1 + m*m)) * ((1 - m*m) * org.x + 2 * m * org.y - 2 * m * q);
 144                 new_org.y = (1 / (1 + m*m)) * (2 * m * org.x + (m*m - 1) * org.y + 2 * q);
 145         }
 146         new_org.z = org.z;
 147         return new_org;
 148 }
 149
 150 void waypoint_setupmodel(entity wp)
 151 {
 152         if (autocvar_g_waypointeditor)
 153         {
 154                 // TODO: add some sort of visible box in edit mode for box waypoints
 155                 vector m1 = wp.mins;
 156                 vector m2 = wp.maxs;
 157                 setmodel(wp, MDL_WAYPOINT);
 158                 setsize(wp, m1, m2);
 159                 wp.effects = EF_LOWPRECISION;
 160                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 161                         wp.colormod = '1 0 0';
 162                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 163                         wp.colormod = '1 1 0';
 164                 else
 165                         wp.colormod = '1 1 1';
 166         }
 167         else
 168                 wp.model = "";
 169 }
 170
 171 // create a new spawnfunc_waypoint and automatically link it to other waypoints, and link
 172 // them back to it as well
 173 // (suitable for spawnfunc_waypoint editor)
 174 entity waypoint_spawn(vector m1, vector m2, float f)
 175 {
 176         if(!(f & WAYPOINTFLAG_PERSONAL))
 177         {
 178                 vector em1 = m1;
 179                 vector em2 = m2;
 180                 if (m1 == m2)
 181                 {
 182                         em1 = m1 - '8 8 8';
 183                         em2 = m2 + '8 8 8';
 184                 }
 185                 IL_EACH(g_waypoints, boxesoverlap(em1, em2, it.absmin, it.absmax),
 186                 {
 187                         return it;
 188                 });
 189         }
 190
 191         entity w = new(waypoint);
 192         IL_PUSH(g_waypoints, w);
 193         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 194         w.wpflags = f;
 195         w.solid = SOLID_TRIGGER;
 196         setorigin(w, (m1 + m2) * 0.5);
 197         setsize(w, m1 - w.origin, m2 - w.origin);
 198         if (w.size)
 199                 w.wpisbox = true;
 200
 201         if(!w.wpisbox)
 202         {
 203                 setsize(w, PL_MIN_CONST - '1 1 0', PL_MAX_CONST + '1 1 0');
 204                 if(!move_out_of_solid(w))
 205                 {
 206                         if(!(f & WAYPOINTFLAG_GENERATED))
 207                         {
 208                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin));
 209                                 delete(w);
 210                                 return NULL;
 211                         }
 212                         else
 213                         {
 214                                 if(autocvar_developer)
 215                                 {
 216                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin), "\n");
 217                                         backtrace("Waypoint stuck");
 218                                 }
 219                         }
 220                 }
 221                 setsize(w, '0 0 0', '0 0 0');
 222         }
 223
 224         waypoint_clearlinks(w);
 225         //waypoint_schedulerelink(w);
 226
 227         waypoint_setupmodel(w);
 228
 229         return w;
 230 }
 231
 232 void waypoint_spawn_fromeditor(entity pl)
 233 {
 234         entity e;
 235         vector org = pl.origin;
 236         int ctf_flags = havocbot_symmetryaxis_equation.z;
 237         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 238                    || (autocvar_g_waypointeditor_symmetrical < 0));
 239         int order = ctf_flags;
 240         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 241         {
 242                 order = autocvar_g_waypointeditor_symmetrical_order;
 243                 ctf_flags = order;
 244         }
 245
 246         if(!PHYS_INPUT_BUTTON_CROUCH(pl))
 247         {
 248                 // snap waypoint to item's origin if close enough
 249                 IL_EACH(g_items, true,
 250                 {
 251                         vector item_org = (it.absmin + it.absmax) * 0.5;
 252                         item_org.z = it.absmin.z - PL_MIN_CONST.z;
 253                         if(vlen(item_org - org) < 30)
 254                         {
 255                                 org = item_org;
 256                                 break;
 257                         }
 258                 });
 259         }
 260
 261         LABEL(add_wp);
 262         e = waypoint_spawn(org, org, 0);
 263         waypoint_schedulerelink(e);
 264         bprint(strcat("Waypoint spawned at ", vtos(org), "\n"));
 265         if(sym)
 266         {
 267                 org = waypoint_getSymmetricalOrigin(e.origin, ctf_flags);
 268                 if (vdist(org - pl.origin, >, 32))
 269                 {
 270                         if(order > 2)
 271                                 order--;
 272                         else
 273                                 sym = false;
 274                         goto add_wp;
 275                 }
 276         }
 277 }
 278
 279 void waypoint_remove(entity wp)
 280 {
 281         // tell all waypoints linked to wp that they need to relink
 282         IL_EACH(g_waypoints, it != wp,
 283         {
 284                 if (waypoint_islinked(it, wp))
 285                         waypoint_removelink(it, wp);
 286         });
 287         delete(wp);
 288 }
 289
 290 void waypoint_remove_fromeditor(entity pl)
 291 {
 292         entity e = navigation_findnearestwaypoint(pl, false);
 293
 294         int ctf_flags = havocbot_symmetryaxis_equation.z;
 295         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 296                    || (autocvar_g_waypointeditor_symmetrical < 0));
 297         int order = ctf_flags;
 298         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 299         {
 300                 order = autocvar_g_waypointeditor_symmetrical_order;
 301                 ctf_flags = order;
 302         }
 303
 304         LABEL(remove_wp);
 305         if (!e) return;
 306         if (e.wpflags & WAYPOINTFLAG_GENERATED) return;
 307
 308         if (e.wphardwired)
 309         {
 310                 LOG_INFO("^1Warning: ^7Removal of hardwired waypoints is not allowed in the editor. Please remove links from/to this waypoint (", vtos(e.origin), ") by hand from maps/", mapname, ".waypoints.hardwired\n");
 311                 return;
 312         }
 313
 314         entity wp_sym = NULL;
 315         if (sym)
 316         {
 317                 vector org = waypoint_getSymmetricalOrigin(e.origin, ctf_flags);
 318                 FOREACH_ENTITY_CLASS("waypoint", !(it.wpflags & WAYPOINTFLAG_GENERATED), {
 319                         if(vdist(org - it.origin, <, 3))
 320                         {
 321                                 wp_sym = it;
 322                                 break;
 323                         }
 324                 });
 325         }
 326
 327         bprint(strcat("Waypoint removed at ", vtos(e.origin), "\n"));
 328         waypoint_remove(e);
 329
 330         if (sym && wp_sym)
 331         {
 332                 e = wp_sym;
 333                 if(order > 2)
 334                         order--;
 335                 else
 336                         sym = false;
 337                 goto remove_wp;
 338         }
 339 }
 340
 341 void waypoint_removelink(entity from, entity to)
 342 {
 343         if (from == to || (from.wpflags & WAYPOINTFLAG_NORELINK))
 344                 return;
 345
 346         bool found = false;
 347         if (!found && from.wp00 == to) found = true; if (found) {from.wp00 = from.wp01; from.wp00mincost = from.wp01mincost;}
 348         if (!found && from.wp01 == to) found = true; if (found) {from.wp01 = from.wp02; from.wp01mincost = from.wp02mincost;}
 349         if (!found && from.wp02 == to) found = true; if (found) {from.wp02 = from.wp03; from.wp02mincost = from.wp03mincost;}
 350         if (!found && from.wp03 == to) found = true; if (found) {from.wp03 = from.wp04; from.wp03mincost = from.wp04mincost;}
 351         if (!found && from.wp04 == to) found = true; if (found) {from.wp04 = from.wp05; from.wp04mincost = from.wp05mincost;}
 352         if (!found && from.wp05 == to) found = true; if (found) {from.wp05 = from.wp06; from.wp05mincost = from.wp06mincost;}
 353         if (!found && from.wp06 == to) found = true; if (found) {from.wp06 = from.wp07; from.wp06mincost = from.wp07mincost;}
 354         if (!found && from.wp07 == to) found = true; if (found) {from.wp07 = from.wp08; from.wp07mincost = from.wp08mincost;}
 355         if (!found && from.wp08 == to) found = true; if (found) {from.wp08 = from.wp09; from.wp08mincost = from.wp09mincost;}
 356         if (!found && from.wp09 == to) found = true; if (found) {from.wp09 = from.wp10; from.wp09mincost = from.wp10mincost;}
 357         if (!found && from.wp10 == to) found = true; if (found) {from.wp10 = from.wp11; from.wp10mincost = from.wp11mincost;}
 358         if (!found && from.wp11 == to) found = true; if (found) {from.wp11 = from.wp12; from.wp11mincost = from.wp12mincost;}
 359         if (!found && from.wp12 == to) found = true; if (found) {from.wp12 = from.wp13; from.wp12mincost = from.wp13mincost;}
 360         if (!found && from.wp13 == to) found = true; if (found) {from.wp13 = from.wp14; from.wp13mincost = from.wp14mincost;}
 361         if (!found && from.wp14 == to) found = true; if (found) {from.wp14 = from.wp15; from.wp14mincost = from.wp15mincost;}
 362         if (!found && from.wp15 == to) found = true; if (found) {from.wp15 = from.wp16; from.wp15mincost = from.wp16mincost;}
 363         if (!found && from.wp16 == to) found = true; if (found) {from.wp16 = from.wp17; from.wp16mincost = from.wp17mincost;}
 364         if (!found && from.wp17 == to) found = true; if (found) {from.wp17 = from.wp18; from.wp17mincost = from.wp18mincost;}
 365         if (!found && from.wp18 == to) found = true; if (found) {from.wp18 = from.wp19; from.wp18mincost = from.wp19mincost;}
 366         if (!found && from.wp19 == to) found = true; if (found) {from.wp19 = from.wp20; from.wp19mincost = from.wp20mincost;}
 367         if (!found && from.wp20 == to) found = true; if (found) {from.wp20 = from.wp21; from.wp20mincost = from.wp21mincost;}
 368         if (!found && from.wp21 == to) found = true; if (found) {from.wp21 = from.wp22; from.wp21mincost = from.wp22mincost;}
 369         if (!found && from.wp22 == to) found = true; if (found) {from.wp22 = from.wp23; from.wp22mincost = from.wp23mincost;}
 370         if (!found && from.wp23 == to) found = true; if (found) {from.wp23 = from.wp24; from.wp23mincost = from.wp24mincost;}
 371         if (!found && from.wp24 == to) found = true; if (found) {from.wp24 = from.wp25; from.wp24mincost = from.wp25mincost;}
 372         if (!found && from.wp25 == to) found = true; if (found) {from.wp25 = from.wp26; from.wp25mincost = from.wp26mincost;}
 373         if (!found && from.wp26 == to) found = true; if (found) {from.wp26 = from.wp27; from.wp26mincost = from.wp27mincost;}
 374         if (!found && from.wp27 == to) found = true; if (found) {from.wp27 = from.wp28; from.wp27mincost = from.wp28mincost;}
 375         if (!found && from.wp28 == to) found = true; if (found) {from.wp28 = from.wp29; from.wp28mincost = from.wp29mincost;}
 376         if (!found && from.wp29 == to) found = true; if (found) {from.wp29 = from.wp30; from.wp29mincost = from.wp30mincost;}
 377         if (!found && from.wp30 == to) found = true; if (found) {from.wp30 = from.wp31; from.wp30mincost = from.wp31mincost;}
 378         if (found) {from.wp31 = NULL; from.wp31mincost = 10000000;}
 379 }
 380
 381 bool waypoint_islinked(entity from, entity to)
 382 {
 383         if (from.wp00 == to) return true;if (from.wp01 == to) return true;if (from.wp02 == to) return true;if (from.wp03 == to) return true;
 384         if (from.wp04 == to) return true;if (from.wp05 == to) return true;if (from.wp06 == to) return true;if (from.wp07 == to) return true;
 385         if (from.wp08 == to) return true;if (from.wp09 == to) return true;if (from.wp10 == to) return true;if (from.wp11 == to) return true;
 386         if (from.wp12 == to) return true;if (from.wp13 == to) return true;if (from.wp14 == to) return true;if (from.wp15 == to) return true;
 387         if (from.wp16 == to) return true;if (from.wp17 == to) return true;if (from.wp18 == to) return true;if (from.wp19 == to) return true;
 388         if (from.wp20 == to) return true;if (from.wp21 == to) return true;if (from.wp22 == to) return true;if (from.wp23 == to) return true;
 389         if (from.wp24 == to) return true;if (from.wp25 == to) return true;if (from.wp26 == to) return true;if (from.wp27 == to) return true;
 390         if (from.wp28 == to) return true;if (from.wp29 == to) return true;if (from.wp30 == to) return true;if (from.wp31 == to) return true;
 391         return false;
 392 }
 393
 394 float waypoint_getdistancecost_simple(float dist)
 395 {
 396         return dist / autocvar_sv_maxspeed;
 397 }
 398
 399 float waypoint_getdistancecost(vector from, vector to)
 400 {
 401         float c = waypoint_getdistancecost_simple(vlen(to - from));
 402
 403         float height = from.z - to.z;
 404         if(height > 0 && autocvar_sv_gravity > 0)
 405         {
 406                 float height_cost = sqrt(height / autocvar_sv_gravity);
 407                 float xydist = vlen(vec2(to - from));
 408                 float xydist_cost = xydist / autocvar_sv_maxspeed;
 409                 if(max(height_cost, xydist_cost) < c)
 410                         c = max(height_cost, xydist_cost);
 411         }
 412         return c;
 413 }
 414
 415 float waypoint_getlinkcost(entity from, entity to)
 416 {
 417         vector v1 = from.origin;
 418         vector v2 = to.origin;
 419         if (to.wpisbox || from.wpisbox)
 420         {
 421                 // if either is a box we have to find the nearest points on them to
 422                 // calculate the distance properly
 423                 vector m1, m2;
 424                 m1 = to.absmin;
 425                 m2 = to.absmax;
 426                 v1_x = bound(m1_x, v1_x, m2_x);
 427                 v1_y = bound(m1_y, v1_y, m2_y);
 428                 v1_z = bound(m1_z, v1_z, m2_z);
 429                 m1 = from.absmin;
 430                 m2 = from.absmax;
 431                 v2_x = bound(m1_x, v2_x, m2_x);
 432                 v2_y = bound(m1_y, v2_y, m2_y);
 433                 v2_z = bound(m1_z, v2_z, m2_z);
 434         }
 435         return waypoint_getdistancecost(v1, v2);
 436 }
 437
 438 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
 439 // if c == -1 automatically determine cost of the link
 440 void waypoint_addlink_customcost(entity from, entity to, float c)
 441 {
 442         if (from == to || waypoint_islinked(from, to))
 443                 return;
 444         if (c == -1 && (from.wpflags & WAYPOINTFLAG_NORELINK))
 445                 return;
 446
 447         if(c == -1)
 448                 c = waypoint_getlinkcost(from, to);
 449
 450         if (from.wp31mincost < c) return;
 451         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 452         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 453         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 454         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 455         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 456         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 457         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 458         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 459         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 460         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 461         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 462         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 463         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 464         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 465         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 466         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 467         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 468         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 469         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 470         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 471         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 472         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 473         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 474         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 475         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 476         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 477         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 478         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 479         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 480         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 481         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 482         from.wp00 = to;from.wp00mincost = c;return;
 483 }
 484
 485 void waypoint_addlink(entity from, entity to)
 486 {
 487         waypoint_addlink_customcost(from, to, -1);
 488 }
 489
 490 // relink this spawnfunc_waypoint
 491 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
 492 // (SLOW!)
 493 void waypoint_think(entity this)
 494 {
 495         vector sv, sm1, sm2, ev, em1, em2, dv;
 496
 497         bot_calculate_stepheightvec();
 498
 499         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 500
 501         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
 502         sm1 = this.origin + this.mins;
 503         sm2 = this.origin + this.maxs;
 504         IL_EACH(g_waypoints, this != it,
 505         {
 506                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
 507                 {
 508                         waypoint_addlink(this, it);
 509                         waypoint_addlink(it, this);
 510                 }
 511                 else
 512                 {
 513                         ++relink_total;
 514                         if(!checkpvs(this.origin, it))
 515                         {
 516                                 ++relink_pvsculled;
 517                                 continue;
 518                         }
 519                         sv = it.origin;
 520                         sv.x = bound(sm1_x, sv.x, sm2_x);
 521                         sv.y = bound(sm1_y, sv.y, sm2_y);
 522                         sv.z = bound(sm1_z, sv.z, sm2_z);
 523                         ev = this.origin;
 524                         em1 = it.origin + it.mins;
 525                         em2 = it.origin + it.maxs;
 526                         ev.x = bound(em1_x, ev.x, em2_x);
 527                         ev.y = bound(em1_y, ev.y, em2_y);
 528                         ev.z = bound(em1_z, ev.z, em2_z);
 529                         dv = ev - sv;
 530                         dv.z = 0;
 531                         if(vdist(dv, >=, 1050)) // max search distance in XY
 532                         {
 533                                 ++relink_lengthculled;
 534                                 continue;
 535                         }
 536                         navigation_testtracewalk = 0;
 537                         if (!this.wpisbox)
 538                         {
 539                                 tracebox(sv - PL_MIN_CONST.z * '0 0 1', PL_MIN_CONST, PL_MAX_CONST, sv, false, this);
 540                                 if (!trace_startsolid)
 541                                 {
 542                                         //dprint("sv deviation", vtos(trace_endpos - sv), "\n");
 543                                         sv = trace_endpos + '0 0 1';
 544                                 }
 545                         }
 546                         if (!it.wpisbox)
 547                         {
 548                                 tracebox(ev - PL_MIN_CONST.z * '0 0 1', PL_MIN_CONST, PL_MAX_CONST, ev, false, it);
 549                                 if (!trace_startsolid)
 550                                 {
 551                                         //dprint("ev deviation", vtos(trace_endpos - ev), "\n");
 552                                         ev = trace_endpos + '0 0 1';
 553                                 }
 554                         }
 555                         //traceline(this.origin, it.origin, false, NULL);
 556                         //if (trace_fraction == 1)
 557                         if (!this.wpisbox && tracewalk(this, sv, PL_MIN_CONST, PL_MAX_CONST, ev, MOVE_NOMONSTERS))
 558                                 waypoint_addlink(this, it);
 559                         else
 560                                 relink_walkculled += 0.5;
 561                         if (!it.wpisbox && tracewalk(it, ev, PL_MIN_CONST, PL_MAX_CONST, sv, MOVE_NOMONSTERS))
 562                                 waypoint_addlink(it, this);
 563                         else
 564                                 relink_walkculled += 0.5;
 565                 }
 566         });
 567         navigation_testtracewalk = 0;
 568         this.wplinked = true;
 569 }
 570
 571 void waypoint_clearlinks(entity wp)
 572 {
 573         // clear links to other waypoints
 574         float f = 10000000;
 575         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
 576         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
 577         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
 578         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
 579
 580         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
 581         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
 582         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
 583         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
 584
 585         wp.wplinked = false;
 586 }
 587
 588 // tell a spawnfunc_waypoint to relink
 589 void waypoint_schedulerelink(entity wp)
 590 {
 591         if (wp == NULL)
 592                 return;
 593
 594         waypoint_setupmodel(wp);
 595         wp.wpisbox = vdist(wp.size, >, 0);
 596         wp.enemy = NULL;
 597         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
 598                 wp.owner = NULL;
 599         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
 600                 waypoint_clearlinks(wp);
 601         // schedule an actual relink on next frame
 602         setthink(wp, waypoint_think);
 603         wp.nextthink = time;
 604         wp.effects = EF_LOWPRECISION;
 605 }
 606
 607 // spawnfunc_waypoint map entity
 608 spawnfunc(waypoint)
 609 {
 610         IL_PUSH(g_waypoints, this);
 611
 612         setorigin(this, this.origin);
 613         // schedule a relink after other waypoints have had a chance to spawn
 614         waypoint_clearlinks(this);
 615         //waypoint_schedulerelink(this);
 616 }
 617
 618 // tell all waypoints to relink
 619 // actually this is useful only to update relink_* stats
 620 void waypoint_schedulerelinkall()
 621 {
 622         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
 623         IL_EACH(g_waypoints, true,
 624         {
 625                 waypoint_schedulerelink(it);
 626         });
 627         waypoint_load_links_hardwired();
 628 }
 629
 630 // Load waypoint links from file
 631 bool waypoint_load_links()
 632 {
 633         string filename, s;
 634         float file, tokens, c = 0, found;
 635         entity wp_from = NULL, wp_to;
 636         vector wp_to_pos, wp_from_pos;
 637         filename = strcat("maps/", mapname);
 638         filename = strcat(filename, ".waypoints.cache");
 639         file = fopen(filename, FILE_READ);
 640
 641         if (file < 0)
 642         {
 643                 LOG_TRACE("waypoint links load from ");
 644                 LOG_TRACE(filename);
 645                 LOG_TRACE(" failed");
 646                 return false;
 647         }
 648
 649         while ((s = fgets(file)))
 650         {
 651                 tokens = tokenizebyseparator(s, "*");
 652
 653                 if (tokens!=2)
 654                 {
 655                         // bad file format
 656                         fclose(file);
 657                         return false;
 658                 }
 659
 660                 wp_from_pos     = stov(argv(0));
 661                 wp_to_pos       = stov(argv(1));
 662
 663                 // Search "from" waypoint
 664                 if(!wp_from || wp_from.origin!=wp_from_pos)
 665                 {
 666                         wp_from = findradius(wp_from_pos, 1);
 667                         found = false;
 668                         while(wp_from)
 669                         {
 670                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
 671                                 if(wp_from.classname == "waypoint")
 672                                 {
 673                                         found = true;
 674                                         break;
 675                                 }
 676                                 wp_from = wp_from.chain;
 677                         }
 678
 679                         if(!found)
 680                         {
 681                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from_pos));
 682                                 continue;
 683                         }
 684
 685                 }
 686
 687                 // Search "to" waypoint
 688                 wp_to = findradius(wp_to_pos, 1);
 689                 found = false;
 690                 while(wp_to)
 691                 {
 692                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
 693                         if(wp_to.classname == "waypoint")
 694                         {
 695                                 found = true;
 696                                 break;
 697                         }
 698                         wp_to = wp_to.chain;
 699                 }
 700
 701                 if(!found)
 702                 {
 703                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to_pos));
 704                         continue;
 705                 }
 706
 707                 ++c;
 708                 waypoint_addlink(wp_from, wp_to);
 709         }
 710
 711         fclose(file);
 712
 713         LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.cache");
 714
 715         botframe_cachedwaypointlinks = true;
 716         return true;
 717 }
 718
 719 void waypoint_load_or_remove_links_hardwired(bool removal_mode)
 720 {
 721         string filename, s;
 722         float file, tokens, c = 0, found;
 723         entity wp_from = NULL, wp_to;
 724         vector wp_to_pos, wp_from_pos;
 725         filename = strcat("maps/", mapname);
 726         filename = strcat(filename, ".waypoints.hardwired");
 727         file = fopen(filename, FILE_READ);
 728
 729         botframe_loadedforcedlinks = true;
 730
 731         if (file < 0)
 732         {
 733                 if(!removal_mode)
 734                         LOG_TRACE("waypoint links load from ", filename, " failed");
 735                 return;
 736         }
 737
 738         while ((s = fgets(file)))
 739         {
 740                 if(substring(s, 0, 2)=="//")
 741                         continue;
 742
 743                 if(substring(s, 0, 1)=="#")
 744                         continue;
 745
 746                 tokens = tokenizebyseparator(s, "*");
 747
 748                 if (tokens!=2)
 749                         continue;
 750
 751                 wp_from_pos     = stov(argv(0));
 752                 wp_to_pos       = stov(argv(1));
 753
 754                 // Search "from" waypoint
 755                 if(!wp_from || wp_from.origin!=wp_from_pos)
 756                 {
 757                         wp_from = findradius(wp_from_pos, 5);
 758                         found = false;
 759                         while(wp_from)
 760                         {
 761                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
 762                                 if(wp_from.classname == "waypoint")
 763                                 {
 764                                         found = true;
 765                                         break;
 766                                 }
 767                                 wp_from = wp_from.chain;
 768                         }
 769
 770                         if(!found)
 771                         {
 772                                 if(!removal_mode)
 773                                         LOG_INFO(strcat("NOTICE: Can not find waypoint at ", vtos(wp_from_pos), ". Path skipped\n"));
 774                                 continue;
 775                         }
 776                 }
 777
 778                 // Search "to" waypoint
 779                 wp_to = findradius(wp_to_pos, 5);
 780                 found = false;
 781                 while(wp_to)
 782                 {
 783                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
 784                         if(wp_to.classname == "waypoint")
 785                         {
 786                                 found = true;
 787                                 break;
 788                         }
 789                         wp_to = wp_to.chain;
 790                 }
 791
 792                 if(!found)
 793                 {
 794                         if(!removal_mode)
 795                                 LOG_INFO(strcat("NOTICE: Can not find waypoint at ", vtos(wp_to_pos), ". Path skipped\n"));
 796                         continue;
 797                 }
 798
 799                 ++c;
 800                 if(removal_mode)
 801                 {
 802                         waypoint_removelink(wp_from, wp_to);
 803                         continue;
 804                 }
 805
 806                 waypoint_addlink(wp_from, wp_to);
 807                 wp_from.wphardwired = true;
 808                 wp_to.wphardwired = true;
 809         }
 810
 811         fclose(file);
 812
 813         if(!removal_mode)
 814                 LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired");
 815 }
 816
 817 void waypoint_load_links_hardwired() { waypoint_load_or_remove_links_hardwired(false); }
 818 void waypoint_remove_links_hardwired() { waypoint_load_or_remove_links_hardwired(true); }
 819
 820 entity waypoint_get_link(entity w, float i)
 821 {
 822         switch(i)
 823         {
 824                 case  0:return w.wp00;
 825                 case  1:return w.wp01;
 826                 case  2:return w.wp02;
 827                 case  3:return w.wp03;
 828                 case  4:return w.wp04;
 829                 case  5:return w.wp05;
 830                 case  6:return w.wp06;
 831                 case  7:return w.wp07;
 832                 case  8:return w.wp08;
 833                 case  9:return w.wp09;
 834                 case 10:return w.wp10;
 835                 case 11:return w.wp11;
 836                 case 12:return w.wp12;
 837                 case 13:return w.wp13;
 838                 case 14:return w.wp14;
 839                 case 15:return w.wp15;
 840                 case 16:return w.wp16;
 841                 case 17:return w.wp17;
 842                 case 18:return w.wp18;
 843                 case 19:return w.wp19;
 844                 case 20:return w.wp20;
 845                 case 21:return w.wp21;
 846                 case 22:return w.wp22;
 847                 case 23:return w.wp23;
 848                 case 24:return w.wp24;
 849                 case 25:return w.wp25;
 850                 case 26:return w.wp26;
 851                 case 27:return w.wp27;
 852                 case 28:return w.wp28;
 853                 case 29:return w.wp29;
 854                 case 30:return w.wp30;
 855                 case 31:return w.wp31;
 856                 default:return NULL;
 857         }
 858 }
 859
 860 // Save all waypoint links to a file
 861 void waypoint_save_links()
 862 {
 863         // temporarily remove hardwired links so they don't get saved among normal links
 864         waypoint_remove_links_hardwired();
 865
 866         string filename = sprintf("maps/%s.waypoints.cache", mapname);
 867         int file = fopen(filename, FILE_WRITE);
 868         if (file < 0)
 869         {
 870                 LOG_INFOF("waypoint link save to %s failed\n", filename);
 871                 return;
 872         }
 873
 874         int c = 0;
 875         IL_EACH(g_waypoints, true,
 876         {
 877                 for(int j = 0; j < 32; ++j)
 878                 {
 879                         entity link = waypoint_get_link(it, j);
 880                         if(link)
 881                         {
 882                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
 883                                 fputs(file, s);
 884                                 ++c;
 885                         }
 886                 }
 887         });
 888         fclose(file);
 889         botframe_cachedwaypointlinks = true;
 890
 891         LOG_INFOF("saved %d waypoint links to maps/%s.waypoints.cache\n", c, mapname);
 892
 893         waypoint_load_links_hardwired();
 894 }
 895
 896 // save waypoints to gamedir/data/maps/mapname.waypoints
 897 void waypoint_saveall()
 898 {
 899         string filename = sprintf("maps/%s.waypoints", mapname);
 900         int file = fopen(filename, FILE_WRITE);
 901         if (file < 0)
 902         {
 903                 waypoint_save_links(); // save anyway?
 904                 botframe_loadedforcedlinks = false;
 905
 906                 LOG_INFOF("waypoint links: save to %s failed\n", filename);
 907                 return;
 908         }
 909
 910         int c = 0;
 911         IL_EACH(g_waypoints, true,
 912         {
 913                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
 914                         continue;
 915
 916                 string s;
 917                 s = strcat(vtos(it.origin + it.mins), "\n");
 918                 s = strcat(s, vtos(it.origin + it.maxs));
 919                 s = strcat(s, "\n");
 920                 s = strcat(s, ftos(it.wpflags));
 921                 s = strcat(s, "\n");
 922                 fputs(file, s);
 923                 c++;
 924         });
 925         fclose(file);
 926         waypoint_save_links();
 927         botframe_loadedforcedlinks = false;
 928
 929         LOG_INFOF("saved %d waypoints to maps/%s.waypoints\n", c, mapname);
 930 }
 931
 932 // load waypoints from file
 933 float waypoint_loadall()
 934 {
 935         string filename, s;
 936         float file, cwp, cwb, fl;
 937         vector m1, m2;
 938         cwp = 0;
 939         cwb = 0;
 940         filename = strcat("maps/", mapname);
 941         filename = strcat(filename, ".waypoints");
 942         file = fopen(filename, FILE_READ);
 943         if (file >= 0)
 944         {
 945                 while ((s = fgets(file)))
 946                 {
 947                         m1 = stov(s);
 948                         s = fgets(file);
 949                         if (!s)
 950                                 break;
 951                         m2 = stov(s);
 952                         s = fgets(file);
 953                         if (!s)
 954                                 break;
 955                         fl = stof(s);
 956                         waypoint_spawn(m1, m2, fl);
 957                         if (m1 == m2)
 958                                 cwp = cwp + 1;
 959                         else
 960                                 cwb = cwb + 1;
 961                 }
 962                 fclose(file);
 963                 LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints");
 964         }
 965         else
 966         {
 967                 LOG_TRACE("waypoint load from ", filename, " failed");
 968         }
 969         return cwp + cwb;
 970 }
 971
 972 vector waypoint_fixorigin(vector position)
 973 {
 974         tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z), PL_MIN_CONST, PL_MAX_CONST, position + '0 0 -512', MOVE_NOMONSTERS, NULL);
 975         if(trace_fraction < 1)
 976                 position = trace_endpos;
 977         //traceline(position, position + '0 0 -512', MOVE_NOMONSTERS, NULL);
 978         //print("position is ", ftos(trace_endpos_z - position_z), " above solid\n");
 979         return position;
 980 }
 981
 982 void waypoint_spawnforitem_force(entity e, vector org)
 983 {
 984         // Fix the waypoint altitude if necessary
 985         org = waypoint_fixorigin(org);
 986
 987         // don't spawn an item spawnfunc_waypoint if it already exists
 988         IL_EACH(g_waypoints, true,
 989         {
 990                 if(it.wpisbox)
 991                 {
 992                         if(boxesoverlap(org, org, it.absmin, it.absmax))
 993                         {
 994                                 e.nearestwaypoint = it;
 995                                 return;
 996                         }
 997                 }
 998                 else
 999                 {
1000                         if(vdist(it.origin - org, <, 16))
1001                         {
1002                                 e.nearestwaypoint = it;
1003                                 return;
1004                         }
1005                 }
1006         });
1007
1008         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
1009 }
1010
1011 void waypoint_spawnforitem(entity e)
1012 {
1013         if(!bot_waypoints_for_items)
1014                 return;
1015
1016         waypoint_spawnforitem_force(e, e.origin);
1017 }
1018
1019 void waypoint_spawnforteleporter_boxes(entity e, int teleport_flag, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
1020 {
1021         entity w;
1022         entity dw;
1023         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | teleport_flag | WAYPOINTFLAG_NORELINK);
1024         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
1025         // one way link to the destination
1026         w.wp00 = dw;
1027         w.wp00mincost = timetaken; // this is just for jump pads
1028         // the teleporter's nearest spawnfunc_waypoint is this one
1029         // (teleporters are not goals, so this is probably useless)
1030         e.nearestwaypoint = w;
1031         e.nearestwaypointtimeout = -1;
1032 }
1033
1034 void waypoint_spawnforteleporter_v(entity e, vector org, vector destination, float timetaken)
1035 {
1036         org = waypoint_fixorigin(org);
1037         destination = waypoint_fixorigin(destination);
1038         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, org, org, destination, destination, timetaken);
1039 }
1040
1041 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken)
1042 {
1043         destination = waypoint_fixorigin(destination);
1044         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, e.absmin, e.absmax, destination, destination, timetaken);
1045 }
1046
1047 entity waypoint_spawnpersonal(entity this, vector position)
1048 {
1049         entity w;
1050
1051         // drop the waypoint to a proper location:
1052         //   first move it up by a player height
1053         //   then move it down to hit the floor with player bbox size
1054         position = waypoint_fixorigin(position);
1055
1056         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
1057         w.nearestwaypoint = NULL;
1058         w.nearestwaypointtimeout = 0;
1059         w.owner = this;
1060
1061         waypoint_schedulerelink(w);
1062
1063         return w;
1064 }
1065
1066 void waypoint_showlink(entity wp1, entity wp2, int display_type)
1067 {
1068         if (!(wp1 && wp2))
1069                 return;
1070
1071         if (wp1.wphardwired && wp2.wphardwired)
1072                 te_beam(NULL, wp1.origin, wp2.origin);
1073         else if (display_type == 1)
1074                 te_lightning2(NULL, wp1.origin, wp2.origin);
1075 }
1076
1077 void waypoint_showlinks_to(entity wp, int display_type)
1078 {
1079         IL_EACH(g_waypoints, it != wp,
1080         {
1081                 if (waypoint_islinked(it, wp))
1082                         waypoint_showlink(it, wp, display_type);
1083         });
1084 }
1085
1086 void waypoint_showlinks_from(entity wp, int display_type)
1087 {
1088         waypoint_showlink(wp.wp00, wp, display_type); waypoint_showlink(wp.wp16, wp, display_type);
1089         waypoint_showlink(wp.wp01, wp, display_type); waypoint_showlink(wp.wp17, wp, display_type);
1090         waypoint_showlink(wp.wp02, wp, display_type); waypoint_showlink(wp.wp18, wp, display_type);
1091         waypoint_showlink(wp.wp03, wp, display_type); waypoint_showlink(wp.wp19, wp, display_type);
1092         waypoint_showlink(wp.wp04, wp, display_type); waypoint_showlink(wp.wp20, wp, display_type);
1093         waypoint_showlink(wp.wp05, wp, display_type); waypoint_showlink(wp.wp21, wp, display_type);
1094         waypoint_showlink(wp.wp06, wp, display_type); waypoint_showlink(wp.wp22, wp, display_type);
1095         waypoint_showlink(wp.wp07, wp, display_type); waypoint_showlink(wp.wp23, wp, display_type);
1096         waypoint_showlink(wp.wp08, wp, display_type); waypoint_showlink(wp.wp24, wp, display_type);
1097         waypoint_showlink(wp.wp09, wp, display_type); waypoint_showlink(wp.wp25, wp, display_type);
1098         waypoint_showlink(wp.wp10, wp, display_type); waypoint_showlink(wp.wp26, wp, display_type);
1099         waypoint_showlink(wp.wp11, wp, display_type); waypoint_showlink(wp.wp27, wp, display_type);
1100         waypoint_showlink(wp.wp12, wp, display_type); waypoint_showlink(wp.wp28, wp, display_type);
1101         waypoint_showlink(wp.wp13, wp, display_type); waypoint_showlink(wp.wp29, wp, display_type);
1102         waypoint_showlink(wp.wp14, wp, display_type); waypoint_showlink(wp.wp30, wp, display_type);
1103         waypoint_showlink(wp.wp15, wp, display_type); waypoint_showlink(wp.wp31, wp, display_type);
1104 }
1105
1106 void botframe_showwaypointlinks()
1107 {
1108         if (time < botframe_waypointeditorlightningtime)
1109                 return;
1110         botframe_waypointeditorlightningtime = time + 0.5;
1111         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
1112         {
1113                 int display_type = 0;
1114                 entity head = navigation_findnearestwaypoint(it, false);
1115                 if (IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE)
1116                         display_type = 1; // default
1117                 else if(head && (head.wphardwired))
1118                         display_type = 2; // only hardwired
1119
1120                 if (display_type)
1121                 {
1122                         //navigation_testtracewalk = true;
1123                         //print("currently selected WP is ", etos(head), "\n");
1124                         //navigation_testtracewalk = false;
1125                         if (head)
1126                         {
1127                                 te_lightning2(NULL, head.origin, it.origin);
1128                                 if(PHYS_INPUT_BUTTON_CROUCH(it))
1129                                         waypoint_showlinks_to(head, display_type);
1130                                 else
1131                                         waypoint_showlinks_from(head, display_type);
1132                         }
1133                 }
1134         });
1135 }
1136
1137 float botframe_autowaypoints_fixdown(vector v)
1138 {
1139         tracebox(v, PL_MIN_CONST, PL_MAX_CONST, v + '0 0 -64', MOVE_NOMONSTERS, NULL);
1140         if(trace_fraction >= 1)
1141                 return 0;
1142         return 1;
1143 }
1144
1145 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
1146 {
1147         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
1148         {
1149                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
1150                 return 0;
1151         });
1152
1153         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
1154         return 1;
1155 }
1156
1157 // return value:
1158 //    1 = WP created
1159 //    0 = no action needed
1160 //   -1 = temp fail, try from world too
1161 //   -2 = permanent fail, do not retry
1162 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
1163 {
1164         // make it possible to go from p to wp, if we can
1165         // if wp is NULL, nearest is chosen
1166
1167         entity w;
1168         vector porg;
1169         float t, tmin, tmax;
1170         vector o;
1171         vector save;
1172
1173         if(!botframe_autowaypoints_fixdown(p.origin))
1174                 return -2;
1175         porg = trace_endpos;
1176
1177         if(wp)
1178         {
1179                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
1180
1181                 // if wp -> porg, then OK
1182                 float maxdist;
1183                 if(navigation_waypoint_will_link(wp.origin, porg, p, walkfromwp, 1050))
1184                 {
1185                         // we may find a better one
1186                         maxdist = vlen(wp.origin - porg);
1187                 }
1188                 else
1189                 {
1190                         // accept any "good"
1191                         maxdist = 2100;
1192                 }
1193
1194                 float bestdist = maxdist;
1195                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WAYPOINTFLAG_NORELINK),
1196                 {
1197                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
1198                         if(d < bestdist)
1199                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, walkfromwp, 1050))
1200                         if(navigation_waypoint_will_link(it.origin, porg, p, walkfromwp, 1050))
1201                         {
1202                                 bestdist = d;
1203                                 p.(fld) = it;
1204                         }
1205                 });
1206                 if(bestdist < maxdist)
1207                 {
1208                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)), "\n");
1209                         return 0;
1210                 }
1211
1212                 if(bestdist < 2100)
1213                 {
1214                         // we know maxdist < 2100
1215                         // so wp -> porg is still valid
1216                         // all is good
1217                         p.(fld) = wp;
1218                         return 0;
1219                 }
1220
1221                 // otherwise, no existing WP can fix our issues
1222         }
1223         else
1224         {
1225                 save = p.origin;
1226                 setorigin(p, porg);
1227                 w = navigation_findnearestwaypoint(p, walkfromwp);
1228                 setorigin(p, save);
1229                 if(w)
1230                 {
1231                         p.(fld) = w;
1232                         return 0;
1233                 }
1234         }
1235
1236         tmin = 0;
1237         tmax = 1;
1238         for (;;)
1239         {
1240                 if(tmax - tmin < 0.001)
1241                 {
1242                         // did not get a good candidate
1243                         return -1;
1244                 }
1245
1246                 t = (tmin + tmax) * 0.5;
1247                 o = antilag_takebackorigin(p, CS(p), time - t);
1248                 if(!botframe_autowaypoints_fixdown(o))
1249                         return -2;
1250                 o = trace_endpos;
1251
1252                 if(wp)
1253                 {
1254                         if(!navigation_waypoint_will_link(wp.origin, o, p, walkfromwp, 1050))
1255                         {
1256                                 // we cannot walk from wp.origin to o
1257                                 // get closer to tmax
1258                                 tmin = t;
1259                                 continue;
1260                         }
1261                 }
1262                 else
1263                 {
1264                         save = p.origin;
1265                         setorigin(p, o);
1266                         w = navigation_findnearestwaypoint(p, walkfromwp);
1267                         setorigin(p, save);
1268                         if(!w)
1269                         {
1270                                 // we cannot walk from any WP to o
1271                                 // get closer to tmax
1272                                 tmin = t;
1273                                 continue;
1274                         }
1275                 }
1276
1277                 // if we get here, o is valid regarding waypoints
1278                 // check if o is connected right to the player
1279                 // we break if it succeeds, as that means o is a good waypoint location
1280                 if(navigation_waypoint_will_link(o, porg, p, walkfromwp, 1050))
1281                         break;
1282
1283                 // o is no good, we need to get closer to the player
1284                 tmax = t;
1285         }
1286
1287         LOG_INFO("spawning a waypoint for connecting to ", etos(wp), "\n");
1288         botframe_autowaypoints_createwp(o, p, fld, 0);
1289         return 1;
1290 }
1291
1292 // automatically create missing waypoints
1293 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
1294 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
1295 {
1296         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
1297         if(r != -1)
1298                 return;
1299         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
1300         if(r != -1)
1301                 return;
1302
1303         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain\n");
1304         if(!botframe_autowaypoints_fixdown(p.origin))
1305                 return; // shouldn't happen, caught above
1306         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
1307 }
1308
1309 void botframe_deleteuselesswaypoints()
1310 {
1311         IL_EACH(g_items, it.bot_pickup,
1312         {
1313                 // NOTE: this protects waypoints if they're the ONLY nearest
1314                 // waypoint. That's the intention.
1315                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
1316                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
1317         });
1318         IL_EACH(g_waypoints, true,
1319         {
1320                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
1321                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
1322                 // WP is useful if:
1323                 if (it.wpflags & WAYPOINTFLAG_ITEM)
1324                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1325                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
1326                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1327                 if (it.wpflags & WAYPOINTFLAG_LADDER)
1328                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1329                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
1330                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1331                 // b) WP is closest WP for an item/spawnpoint/other entity
1332                 //    This has been done above by protecting these WPs.
1333         });
1334         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
1335         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
1336         {
1337                 for (int m = 0; m < 32; ++m)
1338                 {
1339                         entity w = waypoint_get_link(it, m);
1340                         if (!w)
1341                                 break;
1342                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
1343                                 continue;
1344                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
1345                                 continue;
1346                         for (int j = 0; j < 32; ++j)
1347                         {
1348                                 entity w2 = waypoint_get_link(w, j);
1349                                 if (!w2)
1350                                         break;
1351                                 if (it == w2)
1352                                         continue;
1353                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
1354                                         continue;
1355                                 // If we got here, it != w2 exist with it -> w
1356                                 // and w -> w2. That means the waypoint is not
1357                                 // a dead end.
1358                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
1359                                 for (int k = 0; k < 32; ++k)
1360                                 {
1361                                         if (waypoint_get_link(it, k) == w2)
1362                                                 continue;
1363                                         // IF WE GET HERE, w is proven useful
1364                                         // to get from it to w2!
1365                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1366                                         goto next;
1367                                 }
1368                         }
1369 LABEL(next)
1370                 }
1371         });
1372         // d) The waypoint is a dead end. Dead end waypoints must be kept as
1373         //     they are needed to complete routes while autowaypointing.
1374
1375         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
1376         {
1377                 LOG_INFOF("Removed a waypoint at %v. Try again for more!\n", it.origin);
1378                 te_explosion(it.origin);
1379                 waypoint_remove(it);
1380                 break;
1381         });
1382
1383         IL_EACH(g_waypoints, true,
1384         {
1385                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
1386         });
1387 }
1388
1389 void botframe_autowaypoints()
1390 {
1391         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), LAMBDA(
1392                 // going back is broken, so only fix waypoints to walk TO the player
1393                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
1394                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
1395                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
1396         ));
1397
1398         if (autocvar_g_waypointeditor_auto >= 2) {
1399                 botframe_deleteuselesswaypoints();
1400         }
1401 }
1402