qcsrc/server/bot/default/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include "cvars.qh"
   4
   5 #include "bot.qh"
   6 #include "navigation.qh"
   7
   8 #include <common/state.qh>
   9
  10 #include "../../antilag.qh"
  11
  12 #include <common/constants.qh>
  13 #include <common/net_linked.qh>
  14 #include <common/physics/player.qh>
  15
  16 #include <lib/warpzone/common.qh>
  17 #include <lib/warpzone/util_server.qh>
  18
  19 .entity spawnpointmodel;
  20 void waypoint_unreachable(entity pl)
  21 {
  22         IL_EACH(g_waypoints, true,
  23         {
  24                 it.colormod = '0.5 0.5 0.5';
  25                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  26         });
  27
  28         entity e2 = navigation_findnearestwaypoint(pl, false);
  29         if(!e2)
  30         {
  31                 LOG_INFOF("Can't find any waypoint nearby\n");
  32                 return;
  33         }
  34
  35         navigation_markroutes(pl, e2);
  36
  37         int j = 0;
  38         int m = 0;
  39         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  40         {
  41                 LOG_INFO("unreachable: ", etos(it), " ", vtos(it.origin), "\n");
  42                 it.colormod_z = 8;
  43                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
  44                 j++;
  45                 m++;
  46         });
  47         if (j) LOG_INFOF("%d waypoints cannot be reached from here in any way (marked with blue light)\n", j);
  48         navigation_markroutes_inverted(e2);
  49
  50         j = 0;
  51         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  52         {
  53                 LOG_INFO("cannot reach me: ", etos(it), " ", vtos(it.origin), "\n");
  54                 it.colormod_x = 8;
  55                 if (!(it.effects & EF_NODEPTHTEST))  // not already reported before
  56                         m++;
  57                 it.effects |= EF_NODEPTHTEST | EF_RED;
  58                 j++;
  59         });
  60         if (j) LOG_INFOF("%d waypoints cannot walk to here in any way (marked with red light)\n", j);
  61         if (m) LOG_INFOF("%d waypoints have been marked total\n", m);
  62
  63         j = 0;
  64         IL_EACH(g_spawnpoints, true,
  65         {
  66                 if (navigation_findnearestwaypoint(it, false))
  67                 {
  68                         if(it.spawnpointmodel)
  69                         {
  70                                 delete(it.spawnpointmodel);
  71                                 it.spawnpointmodel = NULL;
  72                         }
  73                 }
  74                 else
  75                 {
  76                         if(!it.spawnpointmodel)
  77                         {
  78                                 tracebox(it.origin, PL_MIN_CONST, PL_MAX_CONST, it.origin - '0 0 512', MOVE_NOMONSTERS, NULL);
  79                                 entity e = new(spawnpointmodel);
  80                                 vector org = trace_endpos + eZ;
  81                                 setorigin(e, org);
  82                                 e.solid = SOLID_TRIGGER;
  83                                 it.spawnpointmodel = e;
  84                         }
  85                         LOG_INFO("spawn without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
  86                         it.spawnpointmodel.effects |= EF_NODEPTHTEST;
  87                         _setmodel(it.spawnpointmodel, pl.model);
  88                         it.spawnpointmodel.frame = pl.frame;
  89                         it.spawnpointmodel.skin = pl.skin;
  90                         it.spawnpointmodel.colormap = pl.colormap;
  91                         it.spawnpointmodel.colormod = pl.colormod;
  92                         it.spawnpointmodel.glowmod = pl.glowmod;
  93                         setsize(it.spawnpointmodel, PL_MIN_CONST, PL_MAX_CONST);
  94                         j++;
  95                 }
  96         });
  97         if (j) LOG_INFOF("%d spawnpoints have no nearest waypoint (marked by player model)\n", j);
  98
  99         j = 0;
 100         IL_EACH(g_items, true,
 101         {
 102                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
 103                 it.colormod = '0.5 0.5 0.5';
 104         });
 105         IL_EACH(g_items, true,
 106         {
 107                 if (navigation_findnearestwaypoint(it, false))
 108                         continue;
 109                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 110                 it.effects |= EF_NODEPTHTEST | EF_RED;
 111                 it.colormod_x = 8;
 112                 j++;
 113         });
 114         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked away from (marked with red light)\n", j);
 115
 116         j = 0;
 117         IL_EACH(g_items, true,
 118         {
 119                 if (navigation_findnearestwaypoint(it, true))
 120                         continue;
 121                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 122                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
 123                 it.colormod_z = 8;
 124                 j++;
 125         });
 126         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked to (marked with blue light)\n", j);
 127 }
 128
 129 vector waypoint_getSymmetricalOrigin(vector org, int ctf_flags)
 130 {
 131         vector new_org = org;
 132         if (fabs(autocvar_g_waypointeditor_symmetrical) == 1)
 133         {
 134                 vector map_center = havocbot_middlepoint;
 135                 if (autocvar_g_waypointeditor_symmetrical == -1)
 136                         map_center = autocvar_g_waypointeditor_symmetrical_origin;
 137
 138                 new_org = Rotate(org - map_center, 360 * DEG2RAD / ctf_flags) + map_center;
 139         }
 140         else if (fabs(autocvar_g_waypointeditor_symmetrical) == 2)
 141         {
 142                 float m = havocbot_symmetryaxis_equation.x;
 143                 float q = havocbot_symmetryaxis_equation.y;
 144                 if (autocvar_g_waypointeditor_symmetrical == -2)
 145                 {
 146                         m = autocvar_g_waypointeditor_symmetrical_axis.x;
 147                         q = autocvar_g_waypointeditor_symmetrical_axis.y;
 148                 }
 149
 150                 new_org.x = (1 / (1 + m*m)) * ((1 - m*m) * org.x + 2 * m * org.y - 2 * m * q);
 151                 new_org.y = (1 / (1 + m*m)) * (2 * m * org.x + (m*m - 1) * org.y + 2 * q);
 152         }
 153         new_org.z = org.z;
 154         return new_org;
 155 }
 156
 157 void waypoint_setupmodel(entity wp)
 158 {
 159         if (autocvar_g_waypointeditor)
 160         {
 161                 // TODO: add some sort of visible box in edit mode for box waypoints
 162                 vector m1 = wp.mins;
 163                 vector m2 = wp.maxs;
 164                 setmodel(wp, MDL_WAYPOINT);
 165                 setsize(wp, m1, m2);
 166                 wp.effects = EF_LOWPRECISION;
 167                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 168                         wp.colormod = '1 0 0';
 169                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 170                         wp.colormod = '1 1 0';
 171                 else if (wp.wphardwired)
 172                         wp.colormod = '0.5 0 1';
 173                 else
 174                         wp.colormod = '1 1 1';
 175         }
 176         else
 177                 wp.model = "";
 178 }
 179
 180 // create a new spawnfunc_waypoint and automatically link it to other waypoints, and link
 181 // them back to it as well
 182 // (suitable for spawnfunc_waypoint editor)
 183 entity waypoint_spawn(vector m1, vector m2, float f)
 184 {
 185         if(!(f & WAYPOINTFLAG_PERSONAL))
 186         {
 187                 vector em1 = m1;
 188                 vector em2 = m2;
 189                 if (m1 == m2)
 190                 {
 191                         em1 = m1 - '8 8 8';
 192                         em2 = m2 + '8 8 8';
 193                 }
 194                 IL_EACH(g_waypoints, boxesoverlap(em1, em2, it.absmin, it.absmax),
 195                 {
 196                         return it;
 197                 });
 198         }
 199
 200         entity w = new(waypoint);
 201         IL_PUSH(g_waypoints, w);
 202         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 203         w.wpflags = f;
 204         w.solid = SOLID_TRIGGER;
 205         setorigin(w, (m1 + m2) * 0.5);
 206         setsize(w, m1 - w.origin, m2 - w.origin);
 207         if (w.size)
 208                 w.wpisbox = true;
 209
 210         if(!w.wpisbox)
 211         {
 212                 setsize(w, PL_MIN_CONST - '1 1 0', PL_MAX_CONST + '1 1 0');
 213                 if(!move_out_of_solid(w))
 214                 {
 215                         if(!(f & WAYPOINTFLAG_GENERATED))
 216                         {
 217                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin));
 218                                 delete(w);
 219                                 return NULL;
 220                         }
 221                         else
 222                         {
 223                                 if(autocvar_developer)
 224                                 {
 225                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin), "\n");
 226                                         backtrace("Waypoint stuck");
 227                                 }
 228                         }
 229                 }
 230                 setsize(w, '0 0 0', '0 0 0');
 231         }
 232
 233         waypoint_clearlinks(w);
 234         //waypoint_schedulerelink(w);
 235
 236         waypoint_setupmodel(w);
 237
 238         return w;
 239 }
 240
 241 void waypoint_spawn_fromeditor(entity pl)
 242 {
 243         entity e;
 244         vector org = pl.origin;
 245         int ctf_flags = havocbot_symmetryaxis_equation.z;
 246         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 247                    || (autocvar_g_waypointeditor_symmetrical < 0));
 248         int order = ctf_flags;
 249         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 250         {
 251                 order = autocvar_g_waypointeditor_symmetrical_order;
 252                 ctf_flags = order;
 253         }
 254
 255         if(!PHYS_INPUT_BUTTON_CROUCH(pl))
 256         {
 257                 // snap waypoint to item's origin if close enough
 258                 IL_EACH(g_items, true,
 259                 {
 260                         vector item_org = (it.absmin + it.absmax) * 0.5;
 261                         item_org.z = it.absmin.z - PL_MIN_CONST.z;
 262                         if(vlen(item_org - org) < 30)
 263                         {
 264                                 org = item_org;
 265                                 break;
 266                         }
 267                 });
 268         }
 269
 270         LABEL(add_wp);
 271         e = waypoint_spawn(org, org, 0);
 272         waypoint_schedulerelink(e);
 273         bprint(strcat("Waypoint spawned at ", vtos(org), "\n"));
 274         if(sym)
 275         {
 276                 org = waypoint_getSymmetricalOrigin(e.origin, ctf_flags);
 277                 if (vdist(org - pl.origin, >, 32))
 278                 {
 279                         if(order > 2)
 280                                 order--;
 281                         else
 282                                 sym = false;
 283                         goto add_wp;
 284                 }
 285         }
 286 }
 287
 288 void waypoint_remove(entity wp)
 289 {
 290         // tell all waypoints linked to wp that they need to relink
 291         IL_EACH(g_waypoints, it != wp,
 292         {
 293                 if (waypoint_islinked(it, wp))
 294                         waypoint_removelink(it, wp);
 295         });
 296         delete(wp);
 297 }
 298
 299 void waypoint_remove_fromeditor(entity pl)
 300 {
 301         entity e = navigation_findnearestwaypoint(pl, false);
 302
 303         int ctf_flags = havocbot_symmetryaxis_equation.z;
 304         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 305                    || (autocvar_g_waypointeditor_symmetrical < 0));
 306         int order = ctf_flags;
 307         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 308         {
 309                 order = autocvar_g_waypointeditor_symmetrical_order;
 310                 ctf_flags = order;
 311         }
 312
 313         LABEL(remove_wp);
 314         if (!e) return;
 315         if (e.wpflags & WAYPOINTFLAG_GENERATED) return;
 316
 317         if (e.wphardwired)
 318         {
 319                 LOG_INFO("^1Warning: ^7Removal of hardwired waypoints is not allowed in the editor. Please remove links from/to this waypoint (", vtos(e.origin), ") by hand from maps/", mapname, ".waypoints.hardwired\n");
 320                 return;
 321         }
 322
 323         entity wp_sym = NULL;
 324         if (sym)
 325         {
 326                 vector org = waypoint_getSymmetricalOrigin(e.origin, ctf_flags);
 327                 FOREACH_ENTITY_CLASS("waypoint", !(it.wpflags & WAYPOINTFLAG_GENERATED), {
 328                         if(vdist(org - it.origin, <, 3))
 329                         {
 330                                 wp_sym = it;
 331                                 break;
 332                         }
 333                 });
 334         }
 335
 336         bprint(strcat("Waypoint removed at ", vtos(e.origin), "\n"));
 337         waypoint_remove(e);
 338
 339         if (sym && wp_sym)
 340         {
 341                 e = wp_sym;
 342                 if(order > 2)
 343                         order--;
 344                 else
 345                         sym = false;
 346                 goto remove_wp;
 347         }
 348 }
 349
 350 void waypoint_removelink(entity from, entity to)
 351 {
 352         if (from == to || (from.wpflags & WAYPOINTFLAG_NORELINK))
 353                 return;
 354
 355         bool found = false;
 356         if (!found && from.wp00 == to) found = true; if (found) {from.wp00 = from.wp01; from.wp00mincost = from.wp01mincost;}
 357         if (!found && from.wp01 == to) found = true; if (found) {from.wp01 = from.wp02; from.wp01mincost = from.wp02mincost;}
 358         if (!found && from.wp02 == to) found = true; if (found) {from.wp02 = from.wp03; from.wp02mincost = from.wp03mincost;}
 359         if (!found && from.wp03 == to) found = true; if (found) {from.wp03 = from.wp04; from.wp03mincost = from.wp04mincost;}
 360         if (!found && from.wp04 == to) found = true; if (found) {from.wp04 = from.wp05; from.wp04mincost = from.wp05mincost;}
 361         if (!found && from.wp05 == to) found = true; if (found) {from.wp05 = from.wp06; from.wp05mincost = from.wp06mincost;}
 362         if (!found && from.wp06 == to) found = true; if (found) {from.wp06 = from.wp07; from.wp06mincost = from.wp07mincost;}
 363         if (!found && from.wp07 == to) found = true; if (found) {from.wp07 = from.wp08; from.wp07mincost = from.wp08mincost;}
 364         if (!found && from.wp08 == to) found = true; if (found) {from.wp08 = from.wp09; from.wp08mincost = from.wp09mincost;}
 365         if (!found && from.wp09 == to) found = true; if (found) {from.wp09 = from.wp10; from.wp09mincost = from.wp10mincost;}
 366         if (!found && from.wp10 == to) found = true; if (found) {from.wp10 = from.wp11; from.wp10mincost = from.wp11mincost;}
 367         if (!found && from.wp11 == to) found = true; if (found) {from.wp11 = from.wp12; from.wp11mincost = from.wp12mincost;}
 368         if (!found && from.wp12 == to) found = true; if (found) {from.wp12 = from.wp13; from.wp12mincost = from.wp13mincost;}
 369         if (!found && from.wp13 == to) found = true; if (found) {from.wp13 = from.wp14; from.wp13mincost = from.wp14mincost;}
 370         if (!found && from.wp14 == to) found = true; if (found) {from.wp14 = from.wp15; from.wp14mincost = from.wp15mincost;}
 371         if (!found && from.wp15 == to) found = true; if (found) {from.wp15 = from.wp16; from.wp15mincost = from.wp16mincost;}
 372         if (!found && from.wp16 == to) found = true; if (found) {from.wp16 = from.wp17; from.wp16mincost = from.wp17mincost;}
 373         if (!found && from.wp17 == to) found = true; if (found) {from.wp17 = from.wp18; from.wp17mincost = from.wp18mincost;}
 374         if (!found && from.wp18 == to) found = true; if (found) {from.wp18 = from.wp19; from.wp18mincost = from.wp19mincost;}
 375         if (!found && from.wp19 == to) found = true; if (found) {from.wp19 = from.wp20; from.wp19mincost = from.wp20mincost;}
 376         if (!found && from.wp20 == to) found = true; if (found) {from.wp20 = from.wp21; from.wp20mincost = from.wp21mincost;}
 377         if (!found && from.wp21 == to) found = true; if (found) {from.wp21 = from.wp22; from.wp21mincost = from.wp22mincost;}
 378         if (!found && from.wp22 == to) found = true; if (found) {from.wp22 = from.wp23; from.wp22mincost = from.wp23mincost;}
 379         if (!found && from.wp23 == to) found = true; if (found) {from.wp23 = from.wp24; from.wp23mincost = from.wp24mincost;}
 380         if (!found && from.wp24 == to) found = true; if (found) {from.wp24 = from.wp25; from.wp24mincost = from.wp25mincost;}
 381         if (!found && from.wp25 == to) found = true; if (found) {from.wp25 = from.wp26; from.wp25mincost = from.wp26mincost;}
 382         if (!found && from.wp26 == to) found = true; if (found) {from.wp26 = from.wp27; from.wp26mincost = from.wp27mincost;}
 383         if (!found && from.wp27 == to) found = true; if (found) {from.wp27 = from.wp28; from.wp27mincost = from.wp28mincost;}
 384         if (!found && from.wp28 == to) found = true; if (found) {from.wp28 = from.wp29; from.wp28mincost = from.wp29mincost;}
 385         if (!found && from.wp29 == to) found = true; if (found) {from.wp29 = from.wp30; from.wp29mincost = from.wp30mincost;}
 386         if (!found && from.wp30 == to) found = true; if (found) {from.wp30 = from.wp31; from.wp30mincost = from.wp31mincost;}
 387         if (found) {from.wp31 = NULL; from.wp31mincost = 10000000;}
 388 }
 389
 390 bool waypoint_islinked(entity from, entity to)
 391 {
 392         if (from.wp00 == to) return true;if (from.wp01 == to) return true;if (from.wp02 == to) return true;if (from.wp03 == to) return true;
 393         if (from.wp04 == to) return true;if (from.wp05 == to) return true;if (from.wp06 == to) return true;if (from.wp07 == to) return true;
 394         if (from.wp08 == to) return true;if (from.wp09 == to) return true;if (from.wp10 == to) return true;if (from.wp11 == to) return true;
 395         if (from.wp12 == to) return true;if (from.wp13 == to) return true;if (from.wp14 == to) return true;if (from.wp15 == to) return true;
 396         if (from.wp16 == to) return true;if (from.wp17 == to) return true;if (from.wp18 == to) return true;if (from.wp19 == to) return true;
 397         if (from.wp20 == to) return true;if (from.wp21 == to) return true;if (from.wp22 == to) return true;if (from.wp23 == to) return true;
 398         if (from.wp24 == to) return true;if (from.wp25 == to) return true;if (from.wp26 == to) return true;if (from.wp27 == to) return true;
 399         if (from.wp28 == to) return true;if (from.wp29 == to) return true;if (from.wp30 == to) return true;if (from.wp31 == to) return true;
 400         return false;
 401 }
 402
 403 void waypoint_updatecost_foralllinks()
 404 {
 405         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_TELEPORT),
 406         {
 407                 if(it.wp00) it.wp00mincost = waypoint_getlinkcost(it, it.wp00);
 408                 if(it.wp01) it.wp01mincost = waypoint_getlinkcost(it, it.wp01);
 409                 if(it.wp02) it.wp02mincost = waypoint_getlinkcost(it, it.wp02);
 410                 if(it.wp03) it.wp03mincost = waypoint_getlinkcost(it, it.wp03);
 411                 if(it.wp04) it.wp04mincost = waypoint_getlinkcost(it, it.wp04);
 412                 if(it.wp05) it.wp05mincost = waypoint_getlinkcost(it, it.wp05);
 413                 if(it.wp06) it.wp06mincost = waypoint_getlinkcost(it, it.wp06);
 414                 if(it.wp07) it.wp07mincost = waypoint_getlinkcost(it, it.wp07);
 415                 if(it.wp08) it.wp08mincost = waypoint_getlinkcost(it, it.wp08);
 416                 if(it.wp09) it.wp09mincost = waypoint_getlinkcost(it, it.wp09);
 417                 if(it.wp10) it.wp10mincost = waypoint_getlinkcost(it, it.wp10);
 418                 if(it.wp11) it.wp11mincost = waypoint_getlinkcost(it, it.wp11);
 419                 if(it.wp12) it.wp12mincost = waypoint_getlinkcost(it, it.wp12);
 420                 if(it.wp13) it.wp13mincost = waypoint_getlinkcost(it, it.wp13);
 421                 if(it.wp14) it.wp14mincost = waypoint_getlinkcost(it, it.wp14);
 422                 if(it.wp15) it.wp15mincost = waypoint_getlinkcost(it, it.wp15);
 423                 if(it.wp16) it.wp16mincost = waypoint_getlinkcost(it, it.wp16);
 424                 if(it.wp17) it.wp17mincost = waypoint_getlinkcost(it, it.wp17);
 425                 if(it.wp18) it.wp18mincost = waypoint_getlinkcost(it, it.wp18);
 426                 if(it.wp19) it.wp19mincost = waypoint_getlinkcost(it, it.wp19);
 427                 if(it.wp20) it.wp20mincost = waypoint_getlinkcost(it, it.wp20);
 428                 if(it.wp21) it.wp21mincost = waypoint_getlinkcost(it, it.wp21);
 429                 if(it.wp22) it.wp22mincost = waypoint_getlinkcost(it, it.wp22);
 430                 if(it.wp23) it.wp23mincost = waypoint_getlinkcost(it, it.wp23);
 431                 if(it.wp24) it.wp24mincost = waypoint_getlinkcost(it, it.wp24);
 432                 if(it.wp25) it.wp25mincost = waypoint_getlinkcost(it, it.wp25);
 433                 if(it.wp26) it.wp26mincost = waypoint_getlinkcost(it, it.wp26);
 434                 if(it.wp27) it.wp27mincost = waypoint_getlinkcost(it, it.wp27);
 435                 if(it.wp28) it.wp28mincost = waypoint_getlinkcost(it, it.wp28);
 436                 if(it.wp29) it.wp29mincost = waypoint_getlinkcost(it, it.wp29);
 437                 if(it.wp30) it.wp30mincost = waypoint_getlinkcost(it, it.wp30);
 438                 if(it.wp31) it.wp31mincost = waypoint_getlinkcost(it, it.wp31);
 439         });
 440 }
 441
 442 float waypoint_getlinearcost(float dist)
 443 {
 444         if(skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 445                 return dist / (autocvar_sv_maxspeed * 1.25);
 446         return dist / autocvar_sv_maxspeed;
 447 }
 448
 449 float waypoint_gettravelcost(vector from, vector to)
 450 {
 451         float c = waypoint_getlinearcost(vlen(to - from));
 452
 453         float height = from.z - to.z;
 454         if(height > jumpheight_vec.z && autocvar_sv_gravity > 0)
 455         {
 456                 float height_cost = sqrt(height / (autocvar_sv_gravity / 2));
 457                 c = waypoint_getlinearcost(vlen(vec2(to - from))); // xy distance cost
 458                 if(height_cost > c)
 459                         c = height_cost;
 460         }
 461         return c;
 462 }
 463
 464 float waypoint_getlinkcost(entity from, entity to)
 465 {
 466         vector v1 = from.origin;
 467         vector v2 = to.origin;
 468         if (from.wpisbox)
 469         {
 470                 vector m1 = to.absmin, m2 = to.absmax;
 471                 v1_x = bound(m1_x, v1_x, m2_x);
 472                 v1_y = bound(m1_y, v1_y, m2_y);
 473                 v1_z = bound(m1_z, v1_z, m2_z);
 474         }
 475         if (to.wpisbox)
 476         {
 477                 vector m1 = from.absmin, m2 = from.absmax;
 478                 v2_x = bound(m1_x, v2_x, m2_x);
 479                 v2_y = bound(m1_y, v2_y, m2_y);
 480                 v2_z = bound(m1_z, v2_z, m2_z);
 481         }
 482         return waypoint_gettravelcost(v1, v2);
 483 }
 484
 485 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
 486 // if c == -1 automatically determine cost of the link
 487 void waypoint_addlink_customcost(entity from, entity to, float c)
 488 {
 489         if (from == to || waypoint_islinked(from, to))
 490                 return;
 491         if (c == -1 && (from.wpflags & WAYPOINTFLAG_NORELINK))
 492                 return;
 493
 494         if(c == -1)
 495                 c = waypoint_getlinkcost(from, to);
 496
 497         if (from.wp31mincost < c) return;
 498         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 499         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 500         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 501         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 502         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 503         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 504         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 505         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 506         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 507         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 508         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 509         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 510         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 511         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 512         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 513         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 514         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 515         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 516         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 517         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 518         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 519         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 520         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 521         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 522         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 523         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 524         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 525         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 526         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 527         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 528         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 529         from.wp00 = to;from.wp00mincost = c;return;
 530 }
 531
 532 void waypoint_addlink(entity from, entity to)
 533 {
 534         waypoint_addlink_customcost(from, to, -1);
 535 }
 536
 537 // relink this spawnfunc_waypoint
 538 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
 539 // (SLOW!)
 540 void waypoint_think(entity this)
 541 {
 542         vector sv, sm1, sm2, ev, em1, em2, dv;
 543
 544         bot_calculate_stepheightvec();
 545
 546         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 547
 548         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
 549         sm1 = this.origin + this.mins;
 550         sm2 = this.origin + this.maxs;
 551         IL_EACH(g_waypoints, this != it,
 552         {
 553                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
 554                 {
 555                         waypoint_addlink(this, it);
 556                         waypoint_addlink(it, this);
 557                 }
 558                 else
 559                 {
 560                         ++relink_total;
 561                         if(!checkpvs(this.origin, it))
 562                         {
 563                                 ++relink_pvsculled;
 564                                 continue;
 565                         }
 566                         sv = it.origin;
 567                         sv.x = bound(sm1_x, sv.x, sm2_x);
 568                         sv.y = bound(sm1_y, sv.y, sm2_y);
 569                         sv.z = bound(sm1_z, sv.z, sm2_z);
 570                         ev = this.origin;
 571                         em1 = it.origin + it.mins;
 572                         em2 = it.origin + it.maxs;
 573                         ev.x = bound(em1_x, ev.x, em2_x);
 574                         ev.y = bound(em1_y, ev.y, em2_y);
 575                         ev.z = bound(em1_z, ev.z, em2_z);
 576                         dv = ev - sv;
 577                         dv.z = 0;
 578                         if(vdist(dv, >=, 1050)) // max search distance in XY
 579                         {
 580                                 ++relink_lengthculled;
 581                                 continue;
 582                         }
 583                         float sv_deviation = 0;
 584                         float ev_deviation = 0;
 585                         navigation_testtracewalk = 0;
 586                         if (!this.wpisbox)
 587                         {
 588                                 tracebox(sv - PL_MIN_CONST.z * '0 0 1', PL_MIN_CONST, PL_MAX_CONST, sv, false, this);
 589                                 if (!trace_startsolid)
 590                                 {
 591                                         //dprint("sv deviation", vtos(trace_endpos - sv), "\n");
 592                                         sv_deviation = trace_endpos.z + 1 - sv.z;
 593                                         sv = trace_endpos + '0 0 1';
 594                                 }
 595                         }
 596                         if (!it.wpisbox)
 597                         {
 598                                 tracebox(ev - PL_MIN_CONST.z * '0 0 1', PL_MIN_CONST, PL_MAX_CONST, ev, false, it);
 599                                 if (!trace_startsolid)
 600                                 {
 601                                         //dprint("ev deviation", vtos(trace_endpos - ev), "\n");
 602                                         ev_deviation = trace_endpos.z + 1 - ev.z;
 603                                         ev = trace_endpos + '0 0 1';
 604                                 }
 605                         }
 606                         //traceline(this.origin, it.origin, false, NULL);
 607                         //if (trace_fraction == 1)
 608                         if (this.wpisbox)
 609                                 relink_walkculled += 0.5;
 610                         else
 611                         {
 612                                 vector dest = ev;
 613                                 dest.z = em1.z + ev_deviation;
 614                                 float dest_height = em2.z - em1.z;
 615                                 if(tracewalk(this, sv, PL_MIN_CONST, PL_MAX_CONST, dest, dest_height, MOVE_NOMONSTERS))
 616                                         waypoint_addlink(this, it);
 617                                 else
 618                                         relink_walkculled += 0.5;
 619                         }
 620
 621                         if (it.wpisbox)
 622                                 relink_walkculled += 0.5;
 623                         else
 624                         {
 625                                 vector dest = sv;
 626                                 dest.z = sm1.z + sv_deviation;
 627                                 float dest_height = sm2.z - sm1.z;
 628                                 if(tracewalk(it, ev, PL_MIN_CONST, PL_MAX_CONST, dest, dest_height, MOVE_NOMONSTERS))
 629                                         waypoint_addlink(it, this);
 630                                 else
 631                                         relink_walkculled += 0.5;
 632                         }
 633                 }
 634         });
 635         navigation_testtracewalk = 0;
 636         this.wplinked = true;
 637 }
 638
 639 void waypoint_clearlinks(entity wp)
 640 {
 641         // clear links to other waypoints
 642         float f = 10000000;
 643         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
 644         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
 645         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
 646         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
 647
 648         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
 649         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
 650         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
 651         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
 652
 653         wp.wplinked = false;
 654 }
 655
 656 // tell a spawnfunc_waypoint to relink
 657 void waypoint_schedulerelink(entity wp)
 658 {
 659         if (wp == NULL)
 660                 return;
 661
 662         waypoint_setupmodel(wp);
 663         wp.wpisbox = vdist(wp.size, >, 0);
 664         wp.enemy = NULL;
 665         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
 666                 wp.owner = NULL;
 667         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
 668                 waypoint_clearlinks(wp);
 669         // schedule an actual relink on next frame
 670         setthink(wp, waypoint_think);
 671         wp.nextthink = time;
 672         wp.effects = EF_LOWPRECISION;
 673 }
 674
 675 // spawnfunc_waypoint map entity
 676 spawnfunc(waypoint)
 677 {
 678         IL_PUSH(g_waypoints, this);
 679
 680         setorigin(this, this.origin);
 681         // schedule a relink after other waypoints have had a chance to spawn
 682         waypoint_clearlinks(this);
 683         //waypoint_schedulerelink(this);
 684 }
 685
 686 // tell all waypoints to relink
 687 // actually this is useful only to update relink_* stats
 688 void waypoint_schedulerelinkall()
 689 {
 690         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
 691         IL_EACH(g_waypoints, true,
 692         {
 693                 waypoint_schedulerelink(it);
 694         });
 695         waypoint_load_links_hardwired();
 696 }
 697
 698 // Load waypoint links from file
 699 bool waypoint_load_links()
 700 {
 701         string filename, s;
 702         float file, tokens, c = 0, found;
 703         entity wp_from = NULL, wp_to;
 704         vector wp_to_pos, wp_from_pos;
 705         filename = strcat("maps/", mapname);
 706         filename = strcat(filename, ".waypoints.cache");
 707         file = fopen(filename, FILE_READ);
 708
 709         if (file < 0)
 710         {
 711                 LOG_TRACE("waypoint links load from ");
 712                 LOG_TRACE(filename);
 713                 LOG_TRACE(" failed");
 714                 return false;
 715         }
 716
 717         while ((s = fgets(file)))
 718         {
 719                 tokens = tokenizebyseparator(s, "*");
 720
 721                 if (tokens!=2)
 722                 {
 723                         // bad file format
 724                         fclose(file);
 725                         return false;
 726                 }
 727
 728                 wp_from_pos     = stov(argv(0));
 729                 wp_to_pos       = stov(argv(1));
 730
 731                 // Search "from" waypoint
 732                 if(!wp_from || wp_from.origin!=wp_from_pos)
 733                 {
 734                         wp_from = findradius(wp_from_pos, 1);
 735                         found = false;
 736                         while(wp_from)
 737                         {
 738                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
 739                                 if(wp_from.classname == "waypoint")
 740                                 {
 741                                         found = true;
 742                                         break;
 743                                 }
 744                                 wp_from = wp_from.chain;
 745                         }
 746
 747                         if(!found)
 748                         {
 749                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from_pos));
 750                                 continue;
 751                         }
 752
 753                 }
 754
 755                 // Search "to" waypoint
 756                 wp_to = findradius(wp_to_pos, 1);
 757                 found = false;
 758                 while(wp_to)
 759                 {
 760                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
 761                         if(wp_to.classname == "waypoint")
 762                         {
 763                                 found = true;
 764                                 break;
 765                         }
 766                         wp_to = wp_to.chain;
 767                 }
 768
 769                 if(!found)
 770                 {
 771                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to_pos));
 772                         continue;
 773                 }
 774
 775                 ++c;
 776                 waypoint_addlink(wp_from, wp_to);
 777         }
 778
 779         fclose(file);
 780
 781         LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.cache");
 782
 783         botframe_cachedwaypointlinks = true;
 784         return true;
 785 }
 786
 787 void waypoint_load_or_remove_links_hardwired(bool removal_mode)
 788 {
 789         string filename, s;
 790         float file, tokens, c = 0, found;
 791         entity wp_from = NULL, wp_to;
 792         vector wp_to_pos, wp_from_pos;
 793         filename = strcat("maps/", mapname);
 794         filename = strcat(filename, ".waypoints.hardwired");
 795         file = fopen(filename, FILE_READ);
 796
 797         botframe_loadedforcedlinks = true;
 798
 799         if (file < 0)
 800         {
 801                 if(!removal_mode)
 802                         LOG_TRACE("waypoint links load from ", filename, " failed");
 803                 return;
 804         }
 805
 806         while ((s = fgets(file)))
 807         {
 808                 if(substring(s, 0, 2)=="//")
 809                         continue;
 810
 811                 if(substring(s, 0, 1)=="#")
 812                         continue;
 813
 814                 tokens = tokenizebyseparator(s, "*");
 815
 816                 if (tokens!=2)
 817                         continue;
 818
 819                 wp_from_pos     = stov(argv(0));
 820                 wp_to_pos       = stov(argv(1));
 821
 822                 // Search "from" waypoint
 823                 if(!wp_from || wp_from.origin!=wp_from_pos)
 824                 {
 825                         wp_from = findradius(wp_from_pos, 5);
 826                         found = false;
 827                         while(wp_from)
 828                         {
 829                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
 830                                 if(wp_from.classname == "waypoint")
 831                                 {
 832                                         found = true;
 833                                         break;
 834                                 }
 835                                 wp_from = wp_from.chain;
 836                         }
 837
 838                         if(!found)
 839                         {
 840                                 if(!removal_mode)
 841                                         LOG_INFO(strcat("NOTICE: Can not find waypoint at ", vtos(wp_from_pos), ". Path skipped\n"));
 842                                 continue;
 843                         }
 844                 }
 845
 846                 // Search "to" waypoint
 847                 wp_to = findradius(wp_to_pos, 5);
 848                 found = false;
 849                 while(wp_to)
 850                 {
 851                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
 852                         if(wp_to.classname == "waypoint")
 853                         {
 854                                 found = true;
 855                                 break;
 856                         }
 857                         wp_to = wp_to.chain;
 858                 }
 859
 860                 if(!found)
 861                 {
 862                         if(!removal_mode)
 863                                 LOG_INFO(strcat("NOTICE: Can not find waypoint at ", vtos(wp_to_pos), ". Path skipped\n"));
 864                         continue;
 865                 }
 866
 867                 ++c;
 868                 if(removal_mode)
 869                 {
 870                         waypoint_removelink(wp_from, wp_to);
 871                         continue;
 872                 }
 873
 874                 waypoint_addlink(wp_from, wp_to);
 875                 wp_from.wphardwired = true;
 876                 wp_to.wphardwired = true;
 877         }
 878
 879         fclose(file);
 880
 881         if(!removal_mode)
 882                 LOG_TRACE("loaded ", ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired");
 883 }
 884
 885 void waypoint_load_links_hardwired() { waypoint_load_or_remove_links_hardwired(false); }
 886 void waypoint_remove_links_hardwired() { waypoint_load_or_remove_links_hardwired(true); }
 887
 888 entity waypoint_get_link(entity w, float i)
 889 {
 890         switch(i)
 891         {
 892                 case  0:return w.wp00;
 893                 case  1:return w.wp01;
 894                 case  2:return w.wp02;
 895                 case  3:return w.wp03;
 896                 case  4:return w.wp04;
 897                 case  5:return w.wp05;
 898                 case  6:return w.wp06;
 899                 case  7:return w.wp07;
 900                 case  8:return w.wp08;
 901                 case  9:return w.wp09;
 902                 case 10:return w.wp10;
 903                 case 11:return w.wp11;
 904                 case 12:return w.wp12;
 905                 case 13:return w.wp13;
 906                 case 14:return w.wp14;
 907                 case 15:return w.wp15;
 908                 case 16:return w.wp16;
 909                 case 17:return w.wp17;
 910                 case 18:return w.wp18;
 911                 case 19:return w.wp19;
 912                 case 20:return w.wp20;
 913                 case 21:return w.wp21;
 914                 case 22:return w.wp22;
 915                 case 23:return w.wp23;
 916                 case 24:return w.wp24;
 917                 case 25:return w.wp25;
 918                 case 26:return w.wp26;
 919                 case 27:return w.wp27;
 920                 case 28:return w.wp28;
 921                 case 29:return w.wp29;
 922                 case 30:return w.wp30;
 923                 case 31:return w.wp31;
 924                 default:return NULL;
 925         }
 926 }
 927
 928 // Save all waypoint links to a file
 929 void waypoint_save_links()
 930 {
 931         // temporarily remove hardwired links so they don't get saved among normal links
 932         waypoint_remove_links_hardwired();
 933
 934         string filename = sprintf("maps/%s.waypoints.cache", mapname);
 935         int file = fopen(filename, FILE_WRITE);
 936         if (file < 0)
 937         {
 938                 LOG_INFOF("waypoint link save to %s failed\n", filename);
 939                 return;
 940         }
 941
 942         int c = 0;
 943         IL_EACH(g_waypoints, true,
 944         {
 945                 for(int j = 0; j < 32; ++j)
 946                 {
 947                         entity link = waypoint_get_link(it, j);
 948                         if(link)
 949                         {
 950                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
 951                                 fputs(file, s);
 952                                 ++c;
 953                         }
 954                 }
 955         });
 956         fclose(file);
 957         botframe_cachedwaypointlinks = true;
 958
 959         LOG_INFOF("saved %d waypoint links to maps/%s.waypoints.cache\n", c, mapname);
 960
 961         waypoint_load_links_hardwired();
 962 }
 963
 964 // save waypoints to gamedir/data/maps/mapname.waypoints
 965 void waypoint_saveall()
 966 {
 967         string filename = sprintf("maps/%s.waypoints", mapname);
 968         int file = fopen(filename, FILE_WRITE);
 969         if (file < 0)
 970         {
 971                 waypoint_save_links(); // save anyway?
 972                 botframe_loadedforcedlinks = false;
 973
 974                 LOG_INFOF("waypoint links: save to %s failed\n", filename);
 975                 return;
 976         }
 977
 978         int c = 0;
 979         IL_EACH(g_waypoints, true,
 980         {
 981                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
 982                         continue;
 983
 984                 string s;
 985                 s = strcat(vtos(it.origin + it.mins), "\n");
 986                 s = strcat(s, vtos(it.origin + it.maxs));
 987                 s = strcat(s, "\n");
 988                 s = strcat(s, ftos(it.wpflags));
 989                 s = strcat(s, "\n");
 990                 fputs(file, s);
 991                 c++;
 992         });
 993         fclose(file);
 994         waypoint_save_links();
 995         botframe_loadedforcedlinks = false;
 996
 997         LOG_INFOF("saved %d waypoints to maps/%s.waypoints\n", c, mapname);
 998 }
 999
1000 // load waypoints from file
1001 float waypoint_loadall()
1002 {
1003         string filename, s;
1004         float file, cwp, cwb, fl;
1005         vector m1, m2;
1006         cwp = 0;
1007         cwb = 0;
1008         filename = strcat("maps/", mapname);
1009         filename = strcat(filename, ".waypoints");
1010         file = fopen(filename, FILE_READ);
1011         if (file >= 0)
1012         {
1013                 while ((s = fgets(file)))
1014                 {
1015                         m1 = stov(s);
1016                         s = fgets(file);
1017                         if (!s)
1018                                 break;
1019                         m2 = stov(s);
1020                         s = fgets(file);
1021                         if (!s)
1022                                 break;
1023                         fl = stof(s);
1024                         waypoint_spawn(m1, m2, fl);
1025                         if (m1 == m2)
1026                                 cwp = cwp + 1;
1027                         else
1028                                 cwb = cwb + 1;
1029                 }
1030                 fclose(file);
1031                 LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints");
1032         }
1033         else
1034         {
1035                 LOG_TRACE("waypoint load from ", filename, " failed");
1036         }
1037         return cwp + cwb;
1038 }
1039
1040 vector waypoint_fixorigin(vector position)
1041 {
1042         tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z), PL_MIN_CONST, PL_MAX_CONST, position + '0 0 -512', MOVE_NOMONSTERS, NULL);
1043         if(trace_fraction < 1)
1044                 position = trace_endpos;
1045         //traceline(position, position + '0 0 -512', MOVE_NOMONSTERS, NULL);
1046         //print("position is ", ftos(trace_endpos_z - position_z), " above solid\n");
1047         return position;
1048 }
1049
1050 void waypoint_spawnforitem_force(entity e, vector org)
1051 {
1052         // Fix the waypoint altitude if necessary
1053         org = waypoint_fixorigin(org);
1054
1055         // don't spawn an item spawnfunc_waypoint if it already exists
1056         IL_EACH(g_waypoints, true,
1057         {
1058                 if(it.wpisbox)
1059                 {
1060                         if(boxesoverlap(org, org, it.absmin, it.absmax))
1061                         {
1062                                 e.nearestwaypoint = it;
1063                                 return;
1064                         }
1065                 }
1066                 else
1067                 {
1068                         if(vdist(it.origin - org, <, 16))
1069                         {
1070                                 e.nearestwaypoint = it;
1071                                 return;
1072                         }
1073                 }
1074         });
1075
1076         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
1077 }
1078
1079 void waypoint_spawnforitem(entity e)
1080 {
1081         if(!bot_waypoints_for_items)
1082                 return;
1083
1084         waypoint_spawnforitem_force(e, e.origin);
1085 }
1086
1087 void waypoint_spawnforteleporter_boxes(entity e, int teleport_flag, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
1088 {
1089         entity w;
1090         entity dw;
1091         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | teleport_flag | WAYPOINTFLAG_NORELINK);
1092         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
1093         // one way link to the destination
1094         w.wp00 = dw;
1095         w.wp00mincost = timetaken; // this is just for jump pads
1096         // the teleporter's nearest spawnfunc_waypoint is this one
1097         // (teleporters are not goals, so this is probably useless)
1098         e.nearestwaypoint = w;
1099         e.nearestwaypointtimeout = -1;
1100 }
1101
1102 void waypoint_spawnforteleporter_v(entity e, vector org, vector destination, float timetaken)
1103 {
1104         org = waypoint_fixorigin(org);
1105         destination = waypoint_fixorigin(destination);
1106         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, org, org, destination, destination, timetaken);
1107 }
1108
1109 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken)
1110 {
1111         destination = waypoint_fixorigin(destination);
1112         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, e.absmin, e.absmax, destination, destination, timetaken);
1113 }
1114
1115 entity waypoint_spawnpersonal(entity this, vector position)
1116 {
1117         entity w;
1118
1119         // drop the waypoint to a proper location:
1120         //   first move it up by a player height
1121         //   then move it down to hit the floor with player bbox size
1122         position = waypoint_fixorigin(position);
1123
1124         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
1125         w.nearestwaypoint = NULL;
1126         w.nearestwaypointtimeout = 0;
1127         w.owner = this;
1128
1129         waypoint_schedulerelink(w);
1130
1131         return w;
1132 }
1133
1134 void waypoint_showlink(entity wp1, entity wp2, int display_type)
1135 {
1136         if (!(wp1 && wp2))
1137                 return;
1138
1139         if (wp1.wphardwired && wp2.wphardwired)
1140                 te_beam(NULL, wp1.origin, wp2.origin);
1141         else if (display_type == 1)
1142                 te_lightning2(NULL, wp1.origin, wp2.origin);
1143 }
1144
1145 void waypoint_showlinks_to(entity wp, int display_type)
1146 {
1147         IL_EACH(g_waypoints, it != wp,
1148         {
1149                 if (waypoint_islinked(it, wp))
1150                         waypoint_showlink(it, wp, display_type);
1151         });
1152 }
1153
1154 void waypoint_showlinks_from(entity wp, int display_type)
1155 {
1156         waypoint_showlink(wp.wp00, wp, display_type); waypoint_showlink(wp.wp16, wp, display_type);
1157         waypoint_showlink(wp.wp01, wp, display_type); waypoint_showlink(wp.wp17, wp, display_type);
1158         waypoint_showlink(wp.wp02, wp, display_type); waypoint_showlink(wp.wp18, wp, display_type);
1159         waypoint_showlink(wp.wp03, wp, display_type); waypoint_showlink(wp.wp19, wp, display_type);
1160         waypoint_showlink(wp.wp04, wp, display_type); waypoint_showlink(wp.wp20, wp, display_type);
1161         waypoint_showlink(wp.wp05, wp, display_type); waypoint_showlink(wp.wp21, wp, display_type);
1162         waypoint_showlink(wp.wp06, wp, display_type); waypoint_showlink(wp.wp22, wp, display_type);
1163         waypoint_showlink(wp.wp07, wp, display_type); waypoint_showlink(wp.wp23, wp, display_type);
1164         waypoint_showlink(wp.wp08, wp, display_type); waypoint_showlink(wp.wp24, wp, display_type);
1165         waypoint_showlink(wp.wp09, wp, display_type); waypoint_showlink(wp.wp25, wp, display_type);
1166         waypoint_showlink(wp.wp10, wp, display_type); waypoint_showlink(wp.wp26, wp, display_type);
1167         waypoint_showlink(wp.wp11, wp, display_type); waypoint_showlink(wp.wp27, wp, display_type);
1168         waypoint_showlink(wp.wp12, wp, display_type); waypoint_showlink(wp.wp28, wp, display_type);
1169         waypoint_showlink(wp.wp13, wp, display_type); waypoint_showlink(wp.wp29, wp, display_type);
1170         waypoint_showlink(wp.wp14, wp, display_type); waypoint_showlink(wp.wp30, wp, display_type);
1171         waypoint_showlink(wp.wp15, wp, display_type); waypoint_showlink(wp.wp31, wp, display_type);
1172 }
1173
1174 void botframe_showwaypointlinks()
1175 {
1176         if (time < botframe_waypointeditorlightningtime)
1177                 return;
1178         botframe_waypointeditorlightningtime = time + 0.5;
1179         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
1180         {
1181                 int display_type = 0;
1182                 entity head = navigation_findnearestwaypoint(it, false);
1183                 if (IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE)
1184                         display_type = 1; // default
1185                 else if(head && (head.wphardwired))
1186                         display_type = 2; // only hardwired
1187
1188                 if (display_type)
1189                 {
1190                         //navigation_testtracewalk = true;
1191                         //print("currently selected WP is ", etos(head), "\n");
1192                         //navigation_testtracewalk = false;
1193                         if (head)
1194                         {
1195                                 te_lightning2(NULL, head.origin, it.origin);
1196                                 if(PHYS_INPUT_BUTTON_CROUCH(it))
1197                                         waypoint_showlinks_to(head, display_type);
1198                                 else
1199                                         waypoint_showlinks_from(head, display_type);
1200                         }
1201                 }
1202         });
1203 }
1204
1205 float botframe_autowaypoints_fixdown(vector v)
1206 {
1207         tracebox(v, PL_MIN_CONST, PL_MAX_CONST, v + '0 0 -64', MOVE_NOMONSTERS, NULL);
1208         if(trace_fraction >= 1)
1209                 return 0;
1210         return 1;
1211 }
1212
1213 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
1214 {
1215         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
1216         {
1217                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
1218                 return 0;
1219         });
1220
1221         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
1222         return 1;
1223 }
1224
1225 // return value:
1226 //    1 = WP created
1227 //    0 = no action needed
1228 //   -1 = temp fail, try from world too
1229 //   -2 = permanent fail, do not retry
1230 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
1231 {
1232         // make it possible to go from p to wp, if we can
1233         // if wp is NULL, nearest is chosen
1234
1235         entity w;
1236         vector porg;
1237         float t, tmin, tmax;
1238         vector o;
1239         vector save;
1240
1241         if(!botframe_autowaypoints_fixdown(p.origin))
1242                 return -2;
1243         porg = trace_endpos;
1244
1245         if(wp)
1246         {
1247                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
1248
1249                 // if wp -> porg, then OK
1250                 float maxdist;
1251                 if(navigation_waypoint_will_link(wp.origin, porg, p, walkfromwp, 1050))
1252                 {
1253                         // we may find a better one
1254                         maxdist = vlen(wp.origin - porg);
1255                 }
1256                 else
1257                 {
1258                         // accept any "good"
1259                         maxdist = 2100;
1260                 }
1261
1262                 float bestdist = maxdist;
1263                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WAYPOINTFLAG_NORELINK),
1264                 {
1265                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
1266                         if(d < bestdist)
1267                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, walkfromwp, 1050))
1268                         if(navigation_waypoint_will_link(it.origin, porg, p, walkfromwp, 1050))
1269                         {
1270                                 bestdist = d;
1271                                 p.(fld) = it;
1272                         }
1273                 });
1274                 if(bestdist < maxdist)
1275                 {
1276                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)), "\n");
1277                         return 0;
1278                 }
1279
1280                 if(bestdist < 2100)
1281                 {
1282                         // we know maxdist < 2100
1283                         // so wp -> porg is still valid
1284                         // all is good
1285                         p.(fld) = wp;
1286                         return 0;
1287                 }
1288
1289                 // otherwise, no existing WP can fix our issues
1290         }
1291         else
1292         {
1293                 save = p.origin;
1294                 setorigin(p, porg);
1295                 w = navigation_findnearestwaypoint(p, walkfromwp);
1296                 setorigin(p, save);
1297                 if(w)
1298                 {
1299                         p.(fld) = w;
1300                         return 0;
1301                 }
1302         }
1303
1304         tmin = 0;
1305         tmax = 1;
1306         for (;;)
1307         {
1308                 if(tmax - tmin < 0.001)
1309                 {
1310                         // did not get a good candidate
1311                         return -1;
1312                 }
1313
1314                 t = (tmin + tmax) * 0.5;
1315                 o = antilag_takebackorigin(p, CS(p), time - t);
1316                 if(!botframe_autowaypoints_fixdown(o))
1317                         return -2;
1318                 o = trace_endpos;
1319
1320                 if(wp)
1321                 {
1322                         if(!navigation_waypoint_will_link(wp.origin, o, p, walkfromwp, 1050))
1323                         {
1324                                 // we cannot walk from wp.origin to o
1325                                 // get closer to tmax
1326                                 tmin = t;
1327                                 continue;
1328                         }
1329                 }
1330                 else
1331                 {
1332                         save = p.origin;
1333                         setorigin(p, o);
1334                         w = navigation_findnearestwaypoint(p, walkfromwp);
1335                         setorigin(p, save);
1336                         if(!w)
1337                         {
1338                                 // we cannot walk from any WP to o
1339                                 // get closer to tmax
1340                                 tmin = t;
1341                                 continue;
1342                         }
1343                 }
1344
1345                 // if we get here, o is valid regarding waypoints
1346                 // check if o is connected right to the player
1347                 // we break if it succeeds, as that means o is a good waypoint location
1348                 if(navigation_waypoint_will_link(o, porg, p, walkfromwp, 1050))
1349                         break;
1350
1351                 // o is no good, we need to get closer to the player
1352                 tmax = t;
1353         }
1354
1355         LOG_INFO("spawning a waypoint for connecting to ", etos(wp), "\n");
1356         botframe_autowaypoints_createwp(o, p, fld, 0);
1357         return 1;
1358 }
1359
1360 // automatically create missing waypoints
1361 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
1362 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
1363 {
1364         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
1365         if(r != -1)
1366                 return;
1367         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
1368         if(r != -1)
1369                 return;
1370
1371         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain\n");
1372         if(!botframe_autowaypoints_fixdown(p.origin))
1373                 return; // shouldn't happen, caught above
1374         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
1375 }
1376
1377 void botframe_deleteuselesswaypoints()
1378 {
1379         IL_EACH(g_items, it.bot_pickup,
1380         {
1381                 // NOTE: this protects waypoints if they're the ONLY nearest
1382                 // waypoint. That's the intention.
1383                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
1384                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
1385         });
1386         IL_EACH(g_waypoints, true,
1387         {
1388                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
1389                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
1390                 // WP is useful if:
1391                 if (it.wpflags & WAYPOINTFLAG_ITEM)
1392                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1393                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
1394                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1395                 if (it.wpflags & WAYPOINTFLAG_LADDER)
1396                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1397                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
1398                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1399                 // b) WP is closest WP for an item/spawnpoint/other entity
1400                 //    This has been done above by protecting these WPs.
1401         });
1402         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
1403         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
1404         {
1405                 for (int m = 0; m < 32; ++m)
1406                 {
1407                         entity w = waypoint_get_link(it, m);
1408                         if (!w)
1409                                 break;
1410                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
1411                                 continue;
1412                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
1413                                 continue;
1414                         for (int j = 0; j < 32; ++j)
1415                         {
1416                                 entity w2 = waypoint_get_link(w, j);
1417                                 if (!w2)
1418                                         break;
1419                                 if (it == w2)
1420                                         continue;
1421                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
1422                                         continue;
1423                                 // If we got here, it != w2 exist with it -> w
1424                                 // and w -> w2. That means the waypoint is not
1425                                 // a dead end.
1426                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
1427                                 for (int k = 0; k < 32; ++k)
1428                                 {
1429                                         if (waypoint_get_link(it, k) == w2)
1430                                                 continue;
1431                                         // IF WE GET HERE, w is proven useful
1432                                         // to get from it to w2!
1433                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1434                                         goto next;
1435                                 }
1436                         }
1437 LABEL(next)
1438                 }
1439         });
1440         // d) The waypoint is a dead end. Dead end waypoints must be kept as
1441         //     they are needed to complete routes while autowaypointing.
1442
1443         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
1444         {
1445                 LOG_INFOF("Removed a waypoint at %v. Try again for more!\n", it.origin);
1446                 te_explosion(it.origin);
1447                 waypoint_remove(it);
1448                 break;
1449         });
1450
1451         IL_EACH(g_waypoints, true,
1452         {
1453                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
1454         });
1455 }
1456
1457 void botframe_autowaypoints()
1458 {
1459         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), LAMBDA(
1460                 // going back is broken, so only fix waypoints to walk TO the player
1461                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
1462                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
1463                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
1464         ));
1465
1466         if (autocvar_g_waypointeditor_auto >= 2) {
1467                 botframe_deleteuselesswaypoints();
1468         }
1469 }
1470