qcsrc/server/bot/default/waypoints.qc

   1 #include "waypoints.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include "cvars.qh"
   6
   7 #include "bot.qh"
   8 #include "navigation.qh"
   9
  10 #include <common/state.qh>
  11
  12 #include "../../antilag.qh"
  13
  14 #include <common/constants.qh>
  15 #include <common/net_linked.qh>
  16 #include <common/physics/player.qh>
  17
  18 #include <lib/warpzone/common.qh>
  19 #include <lib/warpzone/util_server.qh>
  20
  21 .entity spawnpointmodel;
  22 void waypoint_unreachable(entity pl)
  23 {
  24         IL_EACH(g_waypoints, true,
  25         {
  26                 it.colormod = '0.5 0.5 0.5';
  27                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
  28         });
  29
  30         entity e2 = navigation_findnearestwaypoint(pl, false);
  31         if(!e2)
  32         {
  33                 LOG_INFOF("Can't find any waypoint nearby\n");
  34                 return;
  35         }
  36
  37         navigation_markroutes(pl, e2);
  38
  39         int j = 0;
  40         int m = 0;
  41         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  42         {
  43                 LOG_INFO("unreachable: ", etos(it), " ", vtos(it.origin), "\n");
  44                 it.colormod_z = 8;
  45                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
  46                 j++;
  47                 m++;
  48         });
  49         if (j) LOG_INFOF("%d waypoints cannot be reached from here in any way (marked with blue light)\n", j);
  50         navigation_markroutes_inverted(e2);
  51
  52         j = 0;
  53         IL_EACH(g_waypoints, it.wpcost >= 10000000,
  54         {
  55                 LOG_INFO("cannot reach me: ", etos(it), " ", vtos(it.origin), "\n");
  56                 it.colormod_x = 8;
  57                 if (!(it.effects & EF_NODEPTHTEST))  // not already reported before
  58                         m++;
  59                 it.effects |= EF_NODEPTHTEST | EF_RED;
  60                 j++;
  61         });
  62         if (j) LOG_INFOF("%d waypoints cannot walk to here in any way (marked with red light)\n", j);
  63         if (m) LOG_INFOF("%d waypoints have been marked total\n", m);
  64
  65         j = 0;
  66         IL_EACH(g_spawnpoints, true,
  67         {
  68                 if (navigation_findnearestwaypoint(it, false))
  69                 {
  70                         if(it.spawnpointmodel)
  71                         {
  72                                 delete(it.spawnpointmodel);
  73                                 it.spawnpointmodel = NULL;
  74                         }
  75                 }
  76                 else
  77                 {
  78                         if(!it.spawnpointmodel)
  79                         {
  80                                 tracebox(it.origin, PL_MIN_CONST, PL_MAX_CONST, it.origin - '0 0 512', MOVE_NOMONSTERS, NULL);
  81                                 entity e = new(spawnpointmodel);
  82                                 vector org = trace_endpos + eZ;
  83                                 setorigin(e, org);
  84                                 e.solid = SOLID_TRIGGER;
  85                                 it.spawnpointmodel = e;
  86                         }
  87                         LOG_INFO("spawn without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
  88                         it.spawnpointmodel.effects |= EF_NODEPTHTEST;
  89                         _setmodel(it.spawnpointmodel, pl.model);
  90                         it.spawnpointmodel.frame = pl.frame;
  91                         it.spawnpointmodel.skin = pl.skin;
  92                         it.spawnpointmodel.colormap = pl.colormap;
  93                         it.spawnpointmodel.colormod = pl.colormod;
  94                         it.spawnpointmodel.glowmod = pl.glowmod;
  95                         setsize(it.spawnpointmodel, PL_MIN_CONST, PL_MAX_CONST);
  96                         j++;
  97                 }
  98         });
  99         if (j) LOG_INFOF("%d spawnpoints have no nearest waypoint (marked by player model)\n", j);
 100
 101         j = 0;
 102         IL_EACH(g_items, true,
 103         {
 104                 it.effects &= ~(EF_NODEPTHTEST | EF_RED | EF_BLUE);
 105                 it.colormod = '0.5 0.5 0.5';
 106         });
 107         IL_EACH(g_items, true,
 108         {
 109                 if (navigation_findnearestwaypoint(it, false))
 110                         continue;
 111                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 112                 it.effects |= EF_NODEPTHTEST | EF_RED;
 113                 it.colormod_x = 8;
 114                 j++;
 115         });
 116         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked away from (marked with red light)\n", j);
 117
 118         j = 0;
 119         IL_EACH(g_items, true,
 120         {
 121                 if (navigation_findnearestwaypoint(it, true))
 122                         continue;
 123                 LOG_INFO("item without waypoint: ", etos(it), " ", vtos(it.origin), "\n");
 124                 it.effects |= EF_NODEPTHTEST | EF_BLUE;
 125                 it.colormod_z = 8;
 126                 j++;
 127         });
 128         if (j) LOG_INFOF("%d items have no nearest waypoint and cannot be walked to (marked with blue light)\n", j);
 129 }
 130
 131 vector waypoint_getSymmetricalOrigin(vector org, int ctf_flags)
 132 {
 133         vector new_org = org;
 134         if (fabs(autocvar_g_waypointeditor_symmetrical) == 1)
 135         {
 136                 vector map_center = havocbot_middlepoint;
 137                 if (autocvar_g_waypointeditor_symmetrical == -1)
 138                         map_center = autocvar_g_waypointeditor_symmetrical_origin;
 139
 140                 new_org = Rotate(org - map_center, 360 * DEG2RAD / ctf_flags) + map_center;
 141         }
 142         else if (fabs(autocvar_g_waypointeditor_symmetrical) == 2)
 143         {
 144                 float m = havocbot_symmetry_axis_m;
 145                 float q = havocbot_symmetry_axis_q;
 146                 if (autocvar_g_waypointeditor_symmetrical == -2)
 147                 {
 148                         m = autocvar_g_waypointeditor_symmetrical_axis.x;
 149                         q = autocvar_g_waypointeditor_symmetrical_axis.y;
 150                 }
 151
 152                 new_org.x = (1 / (1 + m*m)) * ((1 - m*m) * org.x + 2 * m * org.y - 2 * m * q);
 153                 new_org.y = (1 / (1 + m*m)) * (2 * m * org.x + (m*m - 1) * org.y + 2 * q);
 154         }
 155         new_org.z = org.z;
 156         return new_org;
 157 }
 158
 159 void waypoint_setupmodel(entity wp)
 160 {
 161         if (autocvar_g_waypointeditor)
 162         {
 163                 // TODO: add some sort of visible box in edit mode for box waypoints
 164                 vector m1 = wp.mins;
 165                 vector m2 = wp.maxs;
 166                 setmodel(wp, MDL_WAYPOINT);
 167                 setsize(wp, m1, m2);
 168                 wp.effects = EF_LOWPRECISION;
 169                 if (wp.wpflags & WAYPOINTFLAG_ITEM)
 170                         wp.colormod = '1 0 0';
 171                 else if (wp.wpflags & WAYPOINTFLAG_GENERATED)
 172                         wp.colormod = '1 1 0';
 173                 else if (wp.wphardwired)
 174                         wp.colormod = '0.5 0 1';
 175                 else
 176                         wp.colormod = '1 1 1';
 177         }
 178         else
 179                 wp.model = "";
 180 }
 181
 182 entity waypoint_spawn(vector m1, vector m2, float f)
 183 {
 184         if(!(f & (WAYPOINTFLAG_PERSONAL | WAYPOINTFLAG_GENERATED)) && m1 == m2)
 185         {
 186                 vector em1 = m1 - '8 8 8';
 187                 vector em2 = m2 + '8 8 8';
 188                 IL_EACH(g_waypoints, boxesoverlap(em1, em2, it.absmin, it.absmax),
 189                 {
 190                         return it;
 191                 });
 192         }
 193         // spawn only one destination waypoint for teleports teleporting player to the exact same spot
 194         // otherwise links loaded from file would be applied only to the first destination
 195         // waypoint since link format doesn't specify waypoint entities but just positions
 196         if((f & WAYPOINTFLAG_GENERATED) && !(f & WAYPOINTFLAG_NORELINK) && m1 == m2)
 197         {
 198                 IL_EACH(g_waypoints, boxesoverlap(m1, m2, it.absmin, it.absmax),
 199                 {
 200                         return it;
 201                 });
 202         }
 203
 204         entity w = new(waypoint);
 205         IL_PUSH(g_waypoints, w);
 206         w.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 207         w.wpflags = f;
 208         w.solid = SOLID_TRIGGER;
 209         setorigin(w, (m1 + m2) * 0.5);
 210         setsize(w, m1 - w.origin, m2 - w.origin);
 211         if (w.size)
 212                 w.wpisbox = true;
 213
 214         if(!w.wpisbox)
 215         {
 216                 setsize(w, PL_MIN_CONST - '1 1 0', PL_MAX_CONST + '1 1 0');
 217                 if(!move_out_of_solid(w))
 218                 {
 219                         if(!(f & WAYPOINTFLAG_GENERATED))
 220                         {
 221                                 LOG_TRACE("Killed a waypoint that was stuck in solid at ", vtos(w.origin));
 222                                 delete(w);
 223                                 return NULL;
 224                         }
 225                         else
 226                         {
 227                                 if(autocvar_developer)
 228                                 {
 229                                         LOG_INFO("A generated waypoint is stuck in solid at ", vtos(w.origin));
 230                                         backtrace("Waypoint stuck");
 231                                 }
 232                         }
 233                 }
 234                 setsize(w, '0 0 0', '0 0 0');
 235         }
 236
 237         waypoint_clearlinks(w);
 238         //waypoint_schedulerelink(w);
 239
 240         waypoint_setupmodel(w);
 241
 242         return w;
 243 }
 244
 245 void waypoint_spawn_fromeditor(entity pl)
 246 {
 247         entity e;
 248         vector org = pl.origin;
 249         int ctf_flags = havocbot_symmetry_origin_order;
 250         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 251                    || (autocvar_g_waypointeditor_symmetrical < 0));
 252         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 253                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 254         int wp_num = ctf_flags;
 255
 256         if(!PHYS_INPUT_BUTTON_CROUCH(pl))
 257         {
 258                 // snap waypoint to item's origin if close enough
 259                 IL_EACH(g_items, true,
 260                 {
 261                         vector item_org = (it.absmin + it.absmax) * 0.5;
 262                         item_org.z = it.absmin.z - PL_MIN_CONST.z;
 263                         if (vlen(item_org - org) < 20)
 264                         {
 265                                 org = item_org;
 266                                 break;
 267                         }
 268                 });
 269         }
 270
 271         LABEL(add_wp);
 272         e = waypoint_spawn(org, org, 0);
 273         if(!e)
 274         {
 275                 LOG_INFOF("Couldn't spawn waypoint at %v\n", org);
 276                 return;
 277         }
 278         waypoint_schedulerelink(e);
 279         bprint(strcat("Waypoint spawned at ", vtos(e.origin), "\n"));
 280         if(sym)
 281         {
 282                 org = waypoint_getSymmetricalOrigin(e.origin, ctf_flags);
 283                 if (vdist(org - pl.origin, >, 32))
 284                 {
 285                         if(wp_num > 2)
 286                                 wp_num--;
 287                         else
 288                                 sym = false;
 289                         goto add_wp;
 290                 }
 291         }
 292 }
 293
 294 void waypoint_remove(entity wp)
 295 {
 296         // tell all waypoints linked to wp that they need to relink
 297         IL_EACH(g_waypoints, it != wp,
 298         {
 299                 if (waypoint_islinked(it, wp))
 300                         waypoint_removelink(it, wp);
 301         });
 302         delete(wp);
 303 }
 304
 305 void waypoint_remove_fromeditor(entity pl)
 306 {
 307         entity e = navigation_findnearestwaypoint(pl, false);
 308
 309         int ctf_flags = havocbot_symmetry_origin_order;
 310         bool sym = ((autocvar_g_waypointeditor_symmetrical > 0 && ctf_flags >= 2)
 311                    || (autocvar_g_waypointeditor_symmetrical < 0));
 312         if(autocvar_g_waypointeditor_symmetrical_order >= 2)
 313                 ctf_flags = autocvar_g_waypointeditor_symmetrical_order;
 314         int wp_num = ctf_flags;
 315
 316         LABEL(remove_wp);
 317         if (!e) return;
 318         if (e.wpflags & WAYPOINTFLAG_GENERATED) return;
 319
 320         if (e.wphardwired)
 321         {
 322                 LOG_INFO("^1Warning: ^7Removal of hardwired waypoints is not allowed in the editor. Please remove links from/to this waypoint (", vtos(e.origin), ") by hand from maps/", mapname, ".waypoints.hardwired\n");
 323                 return;
 324         }
 325
 326         entity wp_sym = NULL;
 327         if (sym)
 328         {
 329                 vector org = waypoint_getSymmetricalOrigin(e.origin, ctf_flags);
 330                 FOREACH_ENTITY_CLASS("waypoint", !(it.wpflags & WAYPOINTFLAG_GENERATED), {
 331                         if(vdist(org - it.origin, <, 3))
 332                         {
 333                                 wp_sym = it;
 334                                 break;
 335                         }
 336                 });
 337         }
 338
 339         bprint(strcat("Waypoint removed at ", vtos(e.origin), "\n"));
 340         waypoint_remove(e);
 341
 342         if (sym && wp_sym)
 343         {
 344                 e = wp_sym;
 345                 if(wp_num > 2)
 346                         wp_num--;
 347                 else
 348                         sym = false;
 349                 goto remove_wp;
 350         }
 351 }
 352
 353 void waypoint_removelink(entity from, entity to)
 354 {
 355         if (from == to || (from.wpflags & WAYPOINTFLAG_NORELINK))
 356                 return;
 357
 358         bool found = false;
 359         if (!found && from.wp00 == to) found = true; if (found) {from.wp00 = from.wp01; from.wp00mincost = from.wp01mincost;}
 360         if (!found && from.wp01 == to) found = true; if (found) {from.wp01 = from.wp02; from.wp01mincost = from.wp02mincost;}
 361         if (!found && from.wp02 == to) found = true; if (found) {from.wp02 = from.wp03; from.wp02mincost = from.wp03mincost;}
 362         if (!found && from.wp03 == to) found = true; if (found) {from.wp03 = from.wp04; from.wp03mincost = from.wp04mincost;}
 363         if (!found && from.wp04 == to) found = true; if (found) {from.wp04 = from.wp05; from.wp04mincost = from.wp05mincost;}
 364         if (!found && from.wp05 == to) found = true; if (found) {from.wp05 = from.wp06; from.wp05mincost = from.wp06mincost;}
 365         if (!found && from.wp06 == to) found = true; if (found) {from.wp06 = from.wp07; from.wp06mincost = from.wp07mincost;}
 366         if (!found && from.wp07 == to) found = true; if (found) {from.wp07 = from.wp08; from.wp07mincost = from.wp08mincost;}
 367         if (!found && from.wp08 == to) found = true; if (found) {from.wp08 = from.wp09; from.wp08mincost = from.wp09mincost;}
 368         if (!found && from.wp09 == to) found = true; if (found) {from.wp09 = from.wp10; from.wp09mincost = from.wp10mincost;}
 369         if (!found && from.wp10 == to) found = true; if (found) {from.wp10 = from.wp11; from.wp10mincost = from.wp11mincost;}
 370         if (!found && from.wp11 == to) found = true; if (found) {from.wp11 = from.wp12; from.wp11mincost = from.wp12mincost;}
 371         if (!found && from.wp12 == to) found = true; if (found) {from.wp12 = from.wp13; from.wp12mincost = from.wp13mincost;}
 372         if (!found && from.wp13 == to) found = true; if (found) {from.wp13 = from.wp14; from.wp13mincost = from.wp14mincost;}
 373         if (!found && from.wp14 == to) found = true; if (found) {from.wp14 = from.wp15; from.wp14mincost = from.wp15mincost;}
 374         if (!found && from.wp15 == to) found = true; if (found) {from.wp15 = from.wp16; from.wp15mincost = from.wp16mincost;}
 375         if (!found && from.wp16 == to) found = true; if (found) {from.wp16 = from.wp17; from.wp16mincost = from.wp17mincost;}
 376         if (!found && from.wp17 == to) found = true; if (found) {from.wp17 = from.wp18; from.wp17mincost = from.wp18mincost;}
 377         if (!found && from.wp18 == to) found = true; if (found) {from.wp18 = from.wp19; from.wp18mincost = from.wp19mincost;}
 378         if (!found && from.wp19 == to) found = true; if (found) {from.wp19 = from.wp20; from.wp19mincost = from.wp20mincost;}
 379         if (!found && from.wp20 == to) found = true; if (found) {from.wp20 = from.wp21; from.wp20mincost = from.wp21mincost;}
 380         if (!found && from.wp21 == to) found = true; if (found) {from.wp21 = from.wp22; from.wp21mincost = from.wp22mincost;}
 381         if (!found && from.wp22 == to) found = true; if (found) {from.wp22 = from.wp23; from.wp22mincost = from.wp23mincost;}
 382         if (!found && from.wp23 == to) found = true; if (found) {from.wp23 = from.wp24; from.wp23mincost = from.wp24mincost;}
 383         if (!found && from.wp24 == to) found = true; if (found) {from.wp24 = from.wp25; from.wp24mincost = from.wp25mincost;}
 384         if (!found && from.wp25 == to) found = true; if (found) {from.wp25 = from.wp26; from.wp25mincost = from.wp26mincost;}
 385         if (!found && from.wp26 == to) found = true; if (found) {from.wp26 = from.wp27; from.wp26mincost = from.wp27mincost;}
 386         if (!found && from.wp27 == to) found = true; if (found) {from.wp27 = from.wp28; from.wp27mincost = from.wp28mincost;}
 387         if (!found && from.wp28 == to) found = true; if (found) {from.wp28 = from.wp29; from.wp28mincost = from.wp29mincost;}
 388         if (!found && from.wp29 == to) found = true; if (found) {from.wp29 = from.wp30; from.wp29mincost = from.wp30mincost;}
 389         if (!found && from.wp30 == to) found = true; if (found) {from.wp30 = from.wp31; from.wp30mincost = from.wp31mincost;}
 390         if (found) {from.wp31 = NULL; from.wp31mincost = 10000000;}
 391 }
 392
 393 bool waypoint_islinked(entity from, entity to)
 394 {
 395         if (from.wp00 == to) return true;if (from.wp01 == to) return true;if (from.wp02 == to) return true;if (from.wp03 == to) return true;
 396         if (from.wp04 == to) return true;if (from.wp05 == to) return true;if (from.wp06 == to) return true;if (from.wp07 == to) return true;
 397         if (from.wp08 == to) return true;if (from.wp09 == to) return true;if (from.wp10 == to) return true;if (from.wp11 == to) return true;
 398         if (from.wp12 == to) return true;if (from.wp13 == to) return true;if (from.wp14 == to) return true;if (from.wp15 == to) return true;
 399         if (from.wp16 == to) return true;if (from.wp17 == to) return true;if (from.wp18 == to) return true;if (from.wp19 == to) return true;
 400         if (from.wp20 == to) return true;if (from.wp21 == to) return true;if (from.wp22 == to) return true;if (from.wp23 == to) return true;
 401         if (from.wp24 == to) return true;if (from.wp25 == to) return true;if (from.wp26 == to) return true;if (from.wp27 == to) return true;
 402         if (from.wp28 == to) return true;if (from.wp29 == to) return true;if (from.wp30 == to) return true;if (from.wp31 == to) return true;
 403         return false;
 404 }
 405
 406 void waypoint_updatecost_foralllinks()
 407 {
 408         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_TELEPORT),
 409         {
 410                 if(it.wp00) it.wp00mincost = waypoint_getlinkcost(it, it.wp00);
 411                 if(it.wp01) it.wp01mincost = waypoint_getlinkcost(it, it.wp01);
 412                 if(it.wp02) it.wp02mincost = waypoint_getlinkcost(it, it.wp02);
 413                 if(it.wp03) it.wp03mincost = waypoint_getlinkcost(it, it.wp03);
 414                 if(it.wp04) it.wp04mincost = waypoint_getlinkcost(it, it.wp04);
 415                 if(it.wp05) it.wp05mincost = waypoint_getlinkcost(it, it.wp05);
 416                 if(it.wp06) it.wp06mincost = waypoint_getlinkcost(it, it.wp06);
 417                 if(it.wp07) it.wp07mincost = waypoint_getlinkcost(it, it.wp07);
 418                 if(it.wp08) it.wp08mincost = waypoint_getlinkcost(it, it.wp08);
 419                 if(it.wp09) it.wp09mincost = waypoint_getlinkcost(it, it.wp09);
 420                 if(it.wp10) it.wp10mincost = waypoint_getlinkcost(it, it.wp10);
 421                 if(it.wp11) it.wp11mincost = waypoint_getlinkcost(it, it.wp11);
 422                 if(it.wp12) it.wp12mincost = waypoint_getlinkcost(it, it.wp12);
 423                 if(it.wp13) it.wp13mincost = waypoint_getlinkcost(it, it.wp13);
 424                 if(it.wp14) it.wp14mincost = waypoint_getlinkcost(it, it.wp14);
 425                 if(it.wp15) it.wp15mincost = waypoint_getlinkcost(it, it.wp15);
 426                 if(it.wp16) it.wp16mincost = waypoint_getlinkcost(it, it.wp16);
 427                 if(it.wp17) it.wp17mincost = waypoint_getlinkcost(it, it.wp17);
 428                 if(it.wp18) it.wp18mincost = waypoint_getlinkcost(it, it.wp18);
 429                 if(it.wp19) it.wp19mincost = waypoint_getlinkcost(it, it.wp19);
 430                 if(it.wp20) it.wp20mincost = waypoint_getlinkcost(it, it.wp20);
 431                 if(it.wp21) it.wp21mincost = waypoint_getlinkcost(it, it.wp21);
 432                 if(it.wp22) it.wp22mincost = waypoint_getlinkcost(it, it.wp22);
 433                 if(it.wp23) it.wp23mincost = waypoint_getlinkcost(it, it.wp23);
 434                 if(it.wp24) it.wp24mincost = waypoint_getlinkcost(it, it.wp24);
 435                 if(it.wp25) it.wp25mincost = waypoint_getlinkcost(it, it.wp25);
 436                 if(it.wp26) it.wp26mincost = waypoint_getlinkcost(it, it.wp26);
 437                 if(it.wp27) it.wp27mincost = waypoint_getlinkcost(it, it.wp27);
 438                 if(it.wp28) it.wp28mincost = waypoint_getlinkcost(it, it.wp28);
 439                 if(it.wp29) it.wp29mincost = waypoint_getlinkcost(it, it.wp29);
 440                 if(it.wp30) it.wp30mincost = waypoint_getlinkcost(it, it.wp30);
 441                 if(it.wp31) it.wp31mincost = waypoint_getlinkcost(it, it.wp31);
 442         });
 443 }
 444
 445 float waypoint_getlinearcost(float dist)
 446 {
 447         if(skill >= autocvar_bot_ai_bunnyhop_skilloffset)
 448                 return dist / (autocvar_sv_maxspeed * 1.25);
 449         return dist / autocvar_sv_maxspeed;
 450 }
 451 float waypoint_getlinearcost_underwater(float dist)
 452 {
 453         // NOTE: underwater speed factor is hardcoded in the engine too, see SV_WaterMove
 454         return dist / (autocvar_sv_maxspeed * 0.7);
 455 }
 456
 457 float waypoint_gettravelcost(vector from, vector to, entity from_ent, entity to_ent)
 458 {
 459         bool submerged_from = navigation_check_submerged_state(from_ent, from);
 460         bool submerged_to = navigation_check_submerged_state(to_ent, to);
 461
 462         if (submerged_from && submerged_to)
 463                 return waypoint_getlinearcost_underwater(vlen(to - from));
 464
 465         float c = waypoint_getlinearcost(vlen(to - from));
 466
 467         float height = from.z - to.z;
 468         if(height > jumpheight_vec.z && autocvar_sv_gravity > 0)
 469         {
 470                 float height_cost = sqrt(height / (autocvar_sv_gravity / 2));
 471                 c = waypoint_getlinearcost(vlen(vec2(to - from))); // xy distance cost
 472                 if(height_cost > c)
 473                         c = height_cost;
 474         }
 475
 476         if (submerged_from || submerged_to)
 477                 return (c + waypoint_getlinearcost_underwater(vlen(to - from))) / 2;
 478         return c;
 479 }
 480
 481 float waypoint_getlinkcost(entity from, entity to)
 482 {
 483         vector v1 = from.origin;
 484         vector v2 = to.origin;
 485         if (from.wpisbox)
 486         {
 487                 vector m1 = from.absmin, m2 = from.absmax;
 488                 v1.x = bound(m1.x, v2.x, m2.x);
 489                 v1.y = bound(m1.y, v2.y, m2.y);
 490                 v1.z = bound(m1.z, v2.z, m2.z);
 491         }
 492         if (to.wpisbox)
 493         {
 494                 vector m1 = to.absmin, m2 = to.absmax;
 495                 v2.x = bound(m1.x, v1.x, m2.x);
 496                 v2.y = bound(m1.y, v1.y, m2.y);
 497                 v2.z = bound(m1.z, v1.z, m2.z);
 498         }
 499         return waypoint_gettravelcost(v1, v2, from, to);
 500 }
 501
 502 // add a new link to the spawnfunc_waypoint, replacing the furthest link it already has
 503 // if c == -1 automatically determine cost of the link
 504 void waypoint_addlink_customcost(entity from, entity to, float c)
 505 {
 506         if (from == to || waypoint_islinked(from, to))
 507                 return;
 508         if (c == -1 && (from.wpflags & WAYPOINTFLAG_NORELINK))
 509                 return;
 510
 511         if(c == -1)
 512                 c = waypoint_getlinkcost(from, to);
 513
 514         if (from.wp31mincost < c) return;
 515         if (from.wp30mincost < c) {from.wp31 = to;from.wp31mincost = c;return;} from.wp31 = from.wp30;from.wp31mincost = from.wp30mincost;
 516         if (from.wp29mincost < c) {from.wp30 = to;from.wp30mincost = c;return;} from.wp30 = from.wp29;from.wp30mincost = from.wp29mincost;
 517         if (from.wp28mincost < c) {from.wp29 = to;from.wp29mincost = c;return;} from.wp29 = from.wp28;from.wp29mincost = from.wp28mincost;
 518         if (from.wp27mincost < c) {from.wp28 = to;from.wp28mincost = c;return;} from.wp28 = from.wp27;from.wp28mincost = from.wp27mincost;
 519         if (from.wp26mincost < c) {from.wp27 = to;from.wp27mincost = c;return;} from.wp27 = from.wp26;from.wp27mincost = from.wp26mincost;
 520         if (from.wp25mincost < c) {from.wp26 = to;from.wp26mincost = c;return;} from.wp26 = from.wp25;from.wp26mincost = from.wp25mincost;
 521         if (from.wp24mincost < c) {from.wp25 = to;from.wp25mincost = c;return;} from.wp25 = from.wp24;from.wp25mincost = from.wp24mincost;
 522         if (from.wp23mincost < c) {from.wp24 = to;from.wp24mincost = c;return;} from.wp24 = from.wp23;from.wp24mincost = from.wp23mincost;
 523         if (from.wp22mincost < c) {from.wp23 = to;from.wp23mincost = c;return;} from.wp23 = from.wp22;from.wp23mincost = from.wp22mincost;
 524         if (from.wp21mincost < c) {from.wp22 = to;from.wp22mincost = c;return;} from.wp22 = from.wp21;from.wp22mincost = from.wp21mincost;
 525         if (from.wp20mincost < c) {from.wp21 = to;from.wp21mincost = c;return;} from.wp21 = from.wp20;from.wp21mincost = from.wp20mincost;
 526         if (from.wp19mincost < c) {from.wp20 = to;from.wp20mincost = c;return;} from.wp20 = from.wp19;from.wp20mincost = from.wp19mincost;
 527         if (from.wp18mincost < c) {from.wp19 = to;from.wp19mincost = c;return;} from.wp19 = from.wp18;from.wp19mincost = from.wp18mincost;
 528         if (from.wp17mincost < c) {from.wp18 = to;from.wp18mincost = c;return;} from.wp18 = from.wp17;from.wp18mincost = from.wp17mincost;
 529         if (from.wp16mincost < c) {from.wp17 = to;from.wp17mincost = c;return;} from.wp17 = from.wp16;from.wp17mincost = from.wp16mincost;
 530         if (from.wp15mincost < c) {from.wp16 = to;from.wp16mincost = c;return;} from.wp16 = from.wp15;from.wp16mincost = from.wp15mincost;
 531         if (from.wp14mincost < c) {from.wp15 = to;from.wp15mincost = c;return;} from.wp15 = from.wp14;from.wp15mincost = from.wp14mincost;
 532         if (from.wp13mincost < c) {from.wp14 = to;from.wp14mincost = c;return;} from.wp14 = from.wp13;from.wp14mincost = from.wp13mincost;
 533         if (from.wp12mincost < c) {from.wp13 = to;from.wp13mincost = c;return;} from.wp13 = from.wp12;from.wp13mincost = from.wp12mincost;
 534         if (from.wp11mincost < c) {from.wp12 = to;from.wp12mincost = c;return;} from.wp12 = from.wp11;from.wp12mincost = from.wp11mincost;
 535         if (from.wp10mincost < c) {from.wp11 = to;from.wp11mincost = c;return;} from.wp11 = from.wp10;from.wp11mincost = from.wp10mincost;
 536         if (from.wp09mincost < c) {from.wp10 = to;from.wp10mincost = c;return;} from.wp10 = from.wp09;from.wp10mincost = from.wp09mincost;
 537         if (from.wp08mincost < c) {from.wp09 = to;from.wp09mincost = c;return;} from.wp09 = from.wp08;from.wp09mincost = from.wp08mincost;
 538         if (from.wp07mincost < c) {from.wp08 = to;from.wp08mincost = c;return;} from.wp08 = from.wp07;from.wp08mincost = from.wp07mincost;
 539         if (from.wp06mincost < c) {from.wp07 = to;from.wp07mincost = c;return;} from.wp07 = from.wp06;from.wp07mincost = from.wp06mincost;
 540         if (from.wp05mincost < c) {from.wp06 = to;from.wp06mincost = c;return;} from.wp06 = from.wp05;from.wp06mincost = from.wp05mincost;
 541         if (from.wp04mincost < c) {from.wp05 = to;from.wp05mincost = c;return;} from.wp05 = from.wp04;from.wp05mincost = from.wp04mincost;
 542         if (from.wp03mincost < c) {from.wp04 = to;from.wp04mincost = c;return;} from.wp04 = from.wp03;from.wp04mincost = from.wp03mincost;
 543         if (from.wp02mincost < c) {from.wp03 = to;from.wp03mincost = c;return;} from.wp03 = from.wp02;from.wp03mincost = from.wp02mincost;
 544         if (from.wp01mincost < c) {from.wp02 = to;from.wp02mincost = c;return;} from.wp02 = from.wp01;from.wp02mincost = from.wp01mincost;
 545         if (from.wp00mincost < c) {from.wp01 = to;from.wp01mincost = c;return;} from.wp01 = from.wp00;from.wp01mincost = from.wp00mincost;
 546         from.wp00 = to;from.wp00mincost = c;return;
 547 }
 548
 549 void waypoint_addlink(entity from, entity to)
 550 {
 551         waypoint_addlink_customcost(from, to, -1);
 552 }
 553
 554 // relink this spawnfunc_waypoint
 555 // (precompile a list of all reachable waypoints from this spawnfunc_waypoint)
 556 // (SLOW!)
 557 void waypoint_think(entity this)
 558 {
 559         vector sv = '0 0 0', sv2 = '0 0 0', ev = '0 0 0', ev2 = '0 0 0', dv;
 560         float sv2_height = 0, ev2_height = 0;
 561
 562         bot_calculate_stepheightvec();
 563
 564         int dphitcontentsmask_save = this.dphitcontentsmask;
 565         this.dphitcontentsmask = DPCONTENTS_SOLID | DPCONTENTS_BODY | DPCONTENTS_PLAYERCLIP | DPCONTENTS_BOTCLIP;
 566
 567         bot_navigation_movemode = ((autocvar_bot_navigation_ignoreplayers) ? MOVE_NOMONSTERS : MOVE_NORMAL);
 568
 569         //dprint("waypoint_think wpisbox = ", ftos(this.wpisbox), "\n");
 570         IL_EACH(g_waypoints, this != it,
 571         {
 572                 if (boxesoverlap(this.absmin, this.absmax, it.absmin, it.absmax))
 573                 {
 574                         waypoint_addlink(this, it);
 575                         waypoint_addlink(it, this);
 576                 }
 577                 else
 578                 {
 579                         ++relink_total;
 580                         if(!checkpvs(this.origin, it))
 581                         {
 582                                 ++relink_pvsculled;
 583                                 continue;
 584                         }
 585
 586                         sv = set_tracewalk_dest_2(this, it.origin);
 587                         sv2 = tracewalk_dest;
 588                         sv2_height = tracewalk_dest_height;
 589                         ev = set_tracewalk_dest_2(it, this.origin);
 590                         ev2 = tracewalk_dest;
 591                         ev2_height = tracewalk_dest_height;
 592
 593                         dv = ev - sv;
 594                         dv.z = 0;
 595                         if(vdist(dv, >=, 1050)) // max search distance in XY
 596                         {
 597                                 ++relink_lengthculled;
 598                                 continue;
 599                         }
 600
 601                         navigation_testtracewalk = 0;
 602
 603                         //traceline(this.origin, it.origin, false, NULL);
 604                         //if (trace_fraction == 1)
 605                         if (this.wpisbox)
 606                                 relink_walkculled += 0.5;
 607                         else
 608                         {
 609                                 if (tracewalk(this, sv, PL_MIN_CONST, PL_MAX_CONST, ev2, ev2_height, MOVE_NOMONSTERS))
 610                                         waypoint_addlink(this, it);
 611                                 else
 612                                         relink_walkculled += 0.5;
 613                         }
 614
 615                         if (it.wpisbox)
 616                                 relink_walkculled += 0.5;
 617                         else
 618                         {
 619                                 if (tracewalk(this, ev, PL_MIN_CONST, PL_MAX_CONST, sv2, sv2_height, MOVE_NOMONSTERS))
 620                                         waypoint_addlink(it, this);
 621                                 else
 622                                         relink_walkculled += 0.5;
 623                         }
 624                 }
 625         });
 626         navigation_testtracewalk = 0;
 627         this.wplinked = true;
 628         this.dphitcontentsmask = dphitcontentsmask_save;
 629 }
 630
 631 void waypoint_clearlinks(entity wp)
 632 {
 633         // clear links to other waypoints
 634         float f = 10000000;
 635         wp.wp00 = wp.wp01 = wp.wp02 = wp.wp03 = wp.wp04 = wp.wp05 = wp.wp06 = wp.wp07 = NULL;
 636         wp.wp08 = wp.wp09 = wp.wp10 = wp.wp11 = wp.wp12 = wp.wp13 = wp.wp14 = wp.wp15 = NULL;
 637         wp.wp16 = wp.wp17 = wp.wp18 = wp.wp19 = wp.wp20 = wp.wp21 = wp.wp22 = wp.wp23 = NULL;
 638         wp.wp24 = wp.wp25 = wp.wp26 = wp.wp27 = wp.wp28 = wp.wp29 = wp.wp30 = wp.wp31 = NULL;
 639
 640         wp.wp00mincost = wp.wp01mincost = wp.wp02mincost = wp.wp03mincost = wp.wp04mincost = wp.wp05mincost = wp.wp06mincost = wp.wp07mincost = f;
 641         wp.wp08mincost = wp.wp09mincost = wp.wp10mincost = wp.wp11mincost = wp.wp12mincost = wp.wp13mincost = wp.wp14mincost = wp.wp15mincost = f;
 642         wp.wp16mincost = wp.wp17mincost = wp.wp18mincost = wp.wp19mincost = wp.wp20mincost = wp.wp21mincost = wp.wp22mincost = wp.wp23mincost = f;
 643         wp.wp24mincost = wp.wp25mincost = wp.wp26mincost = wp.wp27mincost = wp.wp28mincost = wp.wp29mincost = wp.wp30mincost = wp.wp31mincost = f;
 644
 645         wp.wplinked = false;
 646 }
 647
 648 // tell a spawnfunc_waypoint to relink
 649 void waypoint_schedulerelink(entity wp)
 650 {
 651         if (wp == NULL)
 652                 return;
 653
 654         waypoint_setupmodel(wp);
 655         wp.wpisbox = vdist(wp.size, >, 0);
 656         wp.enemy = NULL;
 657         if (!(wp.wpflags & WAYPOINTFLAG_PERSONAL))
 658                 wp.owner = NULL;
 659         if (!(wp.wpflags & WAYPOINTFLAG_NORELINK))
 660                 waypoint_clearlinks(wp);
 661         // schedule an actual relink on next frame
 662         setthink(wp, waypoint_think);
 663         wp.nextthink = time;
 664         wp.effects = EF_LOWPRECISION;
 665 }
 666
 667 // spawnfunc_waypoint map entity
 668 spawnfunc(waypoint)
 669 {
 670         IL_PUSH(g_waypoints, this);
 671
 672         setorigin(this, this.origin);
 673         // schedule a relink after other waypoints have had a chance to spawn
 674         waypoint_clearlinks(this);
 675         //waypoint_schedulerelink(this);
 676 }
 677
 678 // tell all waypoints to relink
 679 // actually this is useful only to update relink_* stats
 680 void waypoint_schedulerelinkall()
 681 {
 682         relink_total = relink_walkculled = relink_pvsculled = relink_lengthculled = 0;
 683         IL_EACH(g_waypoints, true,
 684         {
 685                 waypoint_schedulerelink(it);
 686         });
 687         waypoint_load_links_hardwired();
 688 }
 689
 690 #define GET_GAMETYPE_EXTENSION() ((g_race) ? ".race" : "")
 691
 692 // Load waypoint links from file
 693 bool waypoint_load_links()
 694 {
 695         string s;
 696         float file, tokens, c = 0, found;
 697         entity wp_from = NULL, wp_to;
 698         vector wp_to_pos, wp_from_pos;
 699
 700         string gt_ext = GET_GAMETYPE_EXTENSION();
 701
 702         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
 703         file = fopen(filename, FILE_READ);
 704
 705         if (gt_ext != "" && file < 0)
 706         {
 707                 // if race waypoint file doesn't exist load the default one
 708                 filename = sprintf("maps/%s.waypoints.cache", mapname);
 709                 file = fopen(filename, FILE_READ);
 710         }
 711
 712         if (file < 0)
 713         {
 714                 LOG_TRACE("waypoint links load from ", filename, " failed");
 715                 waypoint_schedulerelinkall();
 716                 return false;
 717         }
 718
 719         bool parse_comments = true;
 720         float ver = 0;
 721         string links_time = string_null;
 722
 723         while ((s = fgets(file)))
 724         {
 725                 if(parse_comments)
 726                 {
 727                         if(substring(s, 0, 2) == "//")
 728                         {
 729                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
 730                                         ver = stof(substring(s, 19, -1));
 731                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
 732                                         links_time = substring(s, 16, -1);
 733                                 continue;
 734                         }
 735                         else
 736                         {
 737                                 if(ver < WAYPOINT_VERSION || links_time != waypoint_time)
 738                                 {
 739                                         if (links_time != waypoint_time)
 740                                                 LOG_TRACE("waypoint links for this map are not made for these waypoints.");
 741                                         else
 742                                                 LOG_TRACE("waypoint links for this map are outdated.");
 743                                         if (g_assault)
 744                                         {
 745                                                 LOG_TRACE("Assault waypoint links need to be manually updated in the editor");
 746                                         }
 747                                         else
 748                                         {
 749                                                 LOG_TRACE("automatically updating...");
 750                                                 waypoint_schedulerelinkall();
 751                                                 fclose(file);
 752                                                 return false;
 753                                         }
 754                                 }
 755                                 parse_comments = false;
 756                         }
 757                 }
 758
 759                 tokens = tokenizebyseparator(s, "*");
 760
 761                 if (tokens!=2)
 762                 {
 763                         // bad file format
 764                         fclose(file);
 765                         waypoint_schedulerelinkall(); // link all the autogenerated waypoints (teleporters)
 766                         return false;
 767                 }
 768
 769                 wp_from_pos     = stov(argv(0));
 770                 wp_to_pos       = stov(argv(1));
 771
 772                 // Search "from" waypoint
 773                 if(!wp_from || wp_from.origin!=wp_from_pos)
 774                 {
 775                         wp_from = findradius(wp_from_pos, 1);
 776                         found = false;
 777                         while(wp_from)
 778                         {
 779                                 if(vdist(wp_from.origin - wp_from_pos, <, 1))
 780                                 if(wp_from.classname == "waypoint")
 781                                 {
 782                                         found = true;
 783                                         break;
 784                                 }
 785                                 wp_from = wp_from.chain;
 786                         }
 787
 788                         if(!found)
 789                         {
 790                                 LOG_TRACE("waypoint_load_links: couldn't find 'from' waypoint at ", vtos(wp_from_pos));
 791                                 continue;
 792                         }
 793                 }
 794
 795                 // Search "to" waypoint
 796                 wp_to = findradius(wp_to_pos, 1);
 797                 found = false;
 798                 while(wp_to)
 799                 {
 800                         if(vdist(wp_to.origin - wp_to_pos, <, 1))
 801                         if(wp_to.classname == "waypoint")
 802                         {
 803                                 found = true;
 804                                 break;
 805                         }
 806                         wp_to = wp_to.chain;
 807                 }
 808
 809                 if(!found)
 810                 {
 811                         LOG_TRACE("waypoint_load_links: couldn't find 'to' waypoint at ", vtos(wp_to_pos));
 812                         continue;
 813                 }
 814
 815                 ++c;
 816                 waypoint_addlink(wp_from, wp_to);
 817         }
 818
 819         fclose(file);
 820
 821         LOG_TRACE("loaded ", ftos(c), " waypoint links from ", filename);
 822
 823         bool scheduled = false;
 824         IL_EACH(g_waypoints, it.wpflags & WAYPOINTFLAG_ITEM,
 825         {
 826                 if (!it.wp00)
 827                 {
 828                         waypoint_schedulerelink(it);
 829                         scheduled = true;
 830                 }
 831         });
 832         if (scheduled)
 833                 return false;
 834
 835         botframe_cachedwaypointlinks = true;
 836         return true;
 837 }
 838
 839 void waypoint_load_or_remove_links_hardwired(bool removal_mode)
 840 {
 841         string s;
 842         float file, tokens, c = 0, found;
 843         entity wp_from = NULL, wp_to;
 844         vector wp_to_pos, wp_from_pos;
 845
 846         string gt_ext = GET_GAMETYPE_EXTENSION();
 847
 848         string filename = sprintf("maps/%s.waypoints.hardwired", strcat(mapname, gt_ext));
 849         file = fopen(filename, FILE_READ);
 850
 851         if (gt_ext != "" && file < 0)
 852         {
 853                 // if race waypoint file doesn't exist load the default one
 854                 filename = sprintf("maps/%s.waypoints.hardwired", mapname);
 855                 file = fopen(filename, FILE_READ);
 856         }
 857
 858         botframe_loadedforcedlinks = true;
 859
 860         if (file < 0)
 861         {
 862                 if(!removal_mode)
 863                         LOG_TRACE("waypoint links load from ", filename, " failed");
 864                 return;
 865         }
 866
 867         while ((s = fgets(file)))
 868         {
 869                 if(substring(s, 0, 2)=="//")
 870                         continue;
 871
 872                 if(substring(s, 0, 1)=="#")
 873                         continue;
 874
 875                 tokens = tokenizebyseparator(s, "*");
 876
 877                 if (tokens!=2)
 878                         continue;
 879
 880                 wp_from_pos     = stov(argv(0));
 881                 wp_to_pos       = stov(argv(1));
 882
 883                 // Search "from" waypoint
 884                 if(!wp_from || wp_from.origin!=wp_from_pos)
 885                 {
 886                         wp_from = findradius(wp_from_pos, 5);
 887                         found = false;
 888                         while(wp_from)
 889                         {
 890                                 if(vdist(wp_from.origin - wp_from_pos, <, 5))
 891                                 if(wp_from.classname == "waypoint")
 892                                 {
 893                                         found = true;
 894                                         break;
 895                                 }
 896                                 wp_from = wp_from.chain;
 897                         }
 898
 899                         if(!found)
 900                         {
 901                                 if(!removal_mode)
 902                                         LOG_INFO("NOTICE: Can not find waypoint at ", vtos(wp_from_pos), ". Path skipped");
 903                                 continue;
 904                         }
 905                 }
 906
 907                 // Search "to" waypoint
 908                 wp_to = findradius(wp_to_pos, 5);
 909                 found = false;
 910                 while(wp_to)
 911                 {
 912                         if(vdist(wp_to.origin - wp_to_pos, <, 5))
 913                         if(wp_to.classname == "waypoint")
 914                         {
 915                                 found = true;
 916                                 break;
 917                         }
 918                         wp_to = wp_to.chain;
 919                 }
 920
 921                 if(!found)
 922                 {
 923                         if(!removal_mode)
 924                                 LOG_INFO("NOTICE: Can not find waypoint at ", vtos(wp_to_pos), ". Path skipped");
 925                         continue;
 926                 }
 927
 928                 ++c;
 929                 if(removal_mode)
 930                 {
 931                         waypoint_removelink(wp_from, wp_to);
 932                         continue;
 933                 }
 934
 935                 waypoint_addlink(wp_from, wp_to);
 936                 wp_from.wphardwired = true;
 937                 wp_to.wphardwired = true;
 938                 waypoint_setupmodel(wp_from);
 939                 waypoint_setupmodel(wp_to);
 940         }
 941
 942         fclose(file);
 943
 944         LOG_TRACE(((removal_mode) ? "unloaded " : "loaded "),
 945                 ftos(c), " waypoint links from maps/", mapname, ".waypoints.hardwired");
 946 }
 947
 948 entity waypoint_get_link(entity w, float i)
 949 {
 950         switch(i)
 951         {
 952                 case  0:return w.wp00;
 953                 case  1:return w.wp01;
 954                 case  2:return w.wp02;
 955                 case  3:return w.wp03;
 956                 case  4:return w.wp04;
 957                 case  5:return w.wp05;
 958                 case  6:return w.wp06;
 959                 case  7:return w.wp07;
 960                 case  8:return w.wp08;
 961                 case  9:return w.wp09;
 962                 case 10:return w.wp10;
 963                 case 11:return w.wp11;
 964                 case 12:return w.wp12;
 965                 case 13:return w.wp13;
 966                 case 14:return w.wp14;
 967                 case 15:return w.wp15;
 968                 case 16:return w.wp16;
 969                 case 17:return w.wp17;
 970                 case 18:return w.wp18;
 971                 case 19:return w.wp19;
 972                 case 20:return w.wp20;
 973                 case 21:return w.wp21;
 974                 case 22:return w.wp22;
 975                 case 23:return w.wp23;
 976                 case 24:return w.wp24;
 977                 case 25:return w.wp25;
 978                 case 26:return w.wp26;
 979                 case 27:return w.wp27;
 980                 case 28:return w.wp28;
 981                 case 29:return w.wp29;
 982                 case 30:return w.wp30;
 983                 case 31:return w.wp31;
 984                 default:return NULL;
 985         }
 986 }
 987
 988 // Save all waypoint links to a file
 989 void waypoint_save_links()
 990 {
 991         // temporarily remove hardwired links so they don't get saved among normal links
 992         waypoint_remove_links_hardwired();
 993
 994         string gt_ext = GET_GAMETYPE_EXTENSION();
 995
 996         string filename = sprintf("maps/%s.waypoints.cache", strcat(mapname, gt_ext));
 997         int file = fopen(filename, FILE_WRITE);
 998         if (file < 0)
 999         {
1000                 LOG_INFOF("waypoint link save to %s failed", filename);
1001                 return;
1002         }
1003
1004         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1005         if (waypoint_time != "")
1006                 fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1007
1008         int c = 0;
1009         IL_EACH(g_waypoints, true,
1010         {
1011                 for(int j = 0; j < 32; ++j)
1012                 {
1013                         entity link = waypoint_get_link(it, j);
1014                         if(link)
1015                         {
1016                                 string s = strcat(vtos(it.origin), "*", vtos(link.origin), "\n");
1017                                 fputs(file, s);
1018                                 ++c;
1019                         }
1020                 }
1021         });
1022         fclose(file);
1023
1024         botframe_cachedwaypointlinks = true;
1025
1026         LOG_INFOF("saved %d waypoint links to %s", c, filename);
1027
1028         waypoint_load_links_hardwired();
1029 }
1030
1031 // save waypoints to gamedir/data/maps/mapname.waypoints
1032 void waypoint_saveall()
1033 {
1034         string gt_ext = GET_GAMETYPE_EXTENSION();
1035
1036         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1037         int file = fopen(filename, FILE_WRITE);
1038         if (file < 0)
1039         {
1040                 waypoint_save_links(); // save anyway?
1041                 botframe_loadedforcedlinks = false;
1042
1043                 LOG_INFOF("waypoint links: save to %s failed", filename);
1044                 return;
1045         }
1046
1047         float sym = autocvar_g_waypointeditor_symmetrical;
1048         string sym_str = ftos(sym);
1049         if (sym == -1 || (sym == 1 && autocvar_g_waypointeditor_symmetrical_order >= 2))
1050         {
1051                 if (sym == 1)
1052                 {
1053                         sym_str = cons(sym_str, "-");
1054                         sym_str = cons(sym_str, "-");
1055                 }
1056                 else
1057                 {
1058                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.x));
1059                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_origin.y));
1060                 }
1061                 if (autocvar_g_waypointeditor_symmetrical_order >= 2)
1062                         sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_order));
1063         }
1064         else if (autocvar_g_waypointeditor_symmetrical == -2)
1065         {
1066                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.x));
1067                 sym_str = cons(sym_str, ftos(autocvar_g_waypointeditor_symmetrical_axis.y));
1068         }
1069
1070         // a group of 3 comments doesn't break compatibility with older Xonotic versions
1071         // (they are read as a waypoint with origin '0 0 0' and flag 0 though)
1072         fputs(file, strcat("//", "WAYPOINT_VERSION ", ftos_decimals(WAYPOINT_VERSION, 2), "\n"));
1073         fputs(file, strcat("//", "WAYPOINT_SYMMETRY ", sym_str, "\n"));
1074
1075         strcpy(waypoint_time, strftime(true, "%Y-%m-%d %H:%M:%S"));
1076         fputs(file, strcat("//", "WAYPOINT_TIME ", waypoint_time, "\n"));
1077         //fputs(file, strcat("//", "\n"));
1078         //fputs(file, strcat("//", "\n"));
1079         //fputs(file, strcat("//", "\n"));
1080
1081         int c = 0;
1082         IL_EACH(g_waypoints, true,
1083         {
1084                 if(it.wpflags & WAYPOINTFLAG_GENERATED)
1085                         continue;
1086
1087                 string s;
1088                 s = strcat(vtos(it.origin + it.mins), "\n");
1089                 s = strcat(s, vtos(it.origin + it.maxs));
1090                 s = strcat(s, "\n");
1091                 s = strcat(s, ftos(it.wpflags));
1092                 s = strcat(s, "\n");
1093                 fputs(file, s);
1094                 c++;
1095         });
1096         fclose(file);
1097         waypoint_save_links();
1098         botframe_loadedforcedlinks = false;
1099
1100         LOG_INFOF("saved %d waypoints to %s", c, filename);
1101 }
1102
1103 // load waypoints from file
1104 float waypoint_loadall()
1105 {
1106         string s;
1107         float file, cwp, cwb, fl;
1108         vector m1, m2;
1109         cwp = 0;
1110         cwb = 0;
1111
1112         string gt_ext = GET_GAMETYPE_EXTENSION();
1113
1114         string filename = sprintf("maps/%s.waypoints", strcat(mapname, gt_ext));
1115         file = fopen(filename, FILE_READ);
1116
1117         if (gt_ext != "" && file < 0)
1118         {
1119                 // if race waypoint file doesn't exist load the default one
1120                 filename = sprintf("maps/%s.waypoints", mapname);
1121                 file = fopen(filename, FILE_READ);
1122         }
1123
1124         if (file < 0)
1125         {
1126                 LOG_TRACE("waypoint load from ", filename, " failed");
1127                 return 0;
1128         }
1129
1130         bool parse_comments = true;
1131         float ver = 0;
1132         float sym = 0;
1133         float sym_param1 = 0, sym_param2 = 0, sym_param3 = 0;
1134
1135         while ((s = fgets(file)))
1136         {
1137                 if(parse_comments)
1138                 {
1139                         if(substring(s, 0, 2) == "//")
1140                         {
1141                                 if(substring(s, 2, 17) == "WAYPOINT_VERSION ")
1142                                         ver = stof(substring(s, 19, -1));
1143                                 else if(substring(s, 2, 18) == "WAYPOINT_SYMMETRY ")
1144                                 {
1145                                         int tokens = tokenizebyseparator(substring(s, 20, -1), " ");
1146                                         if (tokens) { sym = stof(argv(0)); }
1147                                         if (tokens > 1) { sym_param1 = stof(argv(1)); }
1148                                         if (tokens > 2) { sym_param2 = stof(argv(2)); }
1149                                         if (tokens > 3) { sym_param3 = stof(argv(3)); }
1150                                 }
1151                                 else if(substring(s, 2, 14) == "WAYPOINT_TIME ")
1152                                         strcpy(waypoint_time, substring(s, 16, -1));
1153                                 continue;
1154                         }
1155                         else
1156                         {
1157                                 if(floor(ver) < floor(WAYPOINT_VERSION))
1158                                 {
1159                                         LOG_TRACE("waypoints for this map are outdated");
1160                                         LOG_TRACE("please update them in the editor");
1161                                 }
1162                                 parse_comments = false;
1163                         }
1164                 }
1165                 m1 = stov(s);
1166                 s = fgets(file);
1167                 if (!s)
1168                         break;
1169                 m2 = stov(s);
1170                 s = fgets(file);
1171                 if (!s)
1172                         break;
1173                 fl = stof(s);
1174                 waypoint_spawn(m1, m2, fl);
1175                 if (m1 == m2)
1176                         cwp = cwp + 1;
1177                 else
1178                         cwb = cwb + 1;
1179         }
1180         fclose(file);
1181         LOG_TRACE("loaded ", ftos(cwp), " waypoints and ", ftos(cwb), " wayboxes from maps/", mapname, ".waypoints");
1182
1183         if (autocvar_g_waypointeditor && autocvar_g_waypointeditor_symmetrical_allowload)
1184         {
1185                 cvar_set("g_waypointeditor_symmetrical", ftos(sym));
1186                 if (sym == 1 && sym_param3 < 2)
1187                         cvar_set("g_waypointeditor_symmetrical_order", "0"); // make sure this is reset if not loaded
1188                 if (sym == -1 || (sym == 1 && sym_param3 >= 2))
1189                 {
1190                         string params;
1191                         if (sym == 1)
1192                                 params = cons("-", "-");
1193                         else
1194                         {
1195                                 params = cons(ftos(sym_param1), ftos(sym_param2));
1196                                 cvar_set("g_waypointeditor_symmetrical_origin", params);
1197                         }
1198                         cvar_set("g_waypointeditor_symmetrical_order", ftos(sym_param3));
1199                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with origin ", params, " and order ", ftos(sym_param3));
1200                 }
1201                 else if (sym == -2)
1202                 {
1203                         string params = strcat(ftos(sym_param1), " ", ftos(sym_param2));
1204                         cvar_set("g_waypointeditor_symmetrical_axis", params);
1205                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym), " with axis ", params);
1206                 }
1207                 else
1208                         LOG_INFO("Waypoint editor: loaded symmetry ", ftos(sym));
1209                 LOG_INFO(strcat("g_waypointeditor_symmetrical", " has been set to ", cvar_string("g_waypointeditor_symmetrical")));
1210         }
1211
1212         return cwp + cwb;
1213 }
1214
1215 #define waypoint_fixorigin(position, tracetest_ent) \
1216         waypoint_fixorigin_down_dir(position, tracetest_ent, '0 0 -1')
1217
1218 vector waypoint_fixorigin_down_dir(vector position, entity tracetest_ent, vector down_dir)
1219 {
1220         tracebox(position + '0 0 1', PL_MIN_CONST, PL_MAX_CONST, position + down_dir * 3000, MOVE_NOMONSTERS, tracetest_ent);
1221         if(trace_startsolid)
1222                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z / 2), PL_MIN_CONST, PL_MAX_CONST, position + down_dir * 3000, MOVE_NOMONSTERS, tracetest_ent);
1223         if(trace_startsolid)
1224                 tracebox(position + '0 0 1' * (1 - PL_MIN_CONST.z), PL_MIN_CONST, PL_MAX_CONST, position + down_dir * 3000, MOVE_NOMONSTERS, tracetest_ent);
1225         if(trace_fraction < 1)
1226                 position = trace_endpos;
1227         return position;
1228 }
1229
1230 void waypoint_spawnforitem_force(entity e, vector org)
1231 {
1232         // Fix the waypoint altitude if necessary
1233         org = waypoint_fixorigin(org, NULL);
1234
1235         // don't spawn an item spawnfunc_waypoint if it already exists
1236         IL_EACH(g_waypoints, true,
1237         {
1238                 if(it.wpisbox)
1239                 {
1240                         if(boxesoverlap(org, org, it.absmin, it.absmax))
1241                         {
1242                                 e.nearestwaypoint = it;
1243                                 return;
1244                         }
1245                 }
1246                 else
1247                 {
1248                         if(vdist(it.origin - org, <, 16))
1249                         {
1250                                 e.nearestwaypoint = it;
1251                                 return;
1252                         }
1253                 }
1254         });
1255
1256         e.nearestwaypoint = waypoint_spawn(org, org, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_ITEM);
1257 }
1258
1259 void waypoint_spawnforitem(entity e)
1260 {
1261         if(!bot_waypoints_for_items)
1262                 return;
1263
1264         waypoint_spawnforitem_force(e, e.origin);
1265 }
1266
1267 void waypoint_spawnforteleporter_boxes(entity e, int teleport_flag, vector org1, vector org2, vector destination1, vector destination2, float timetaken)
1268 {
1269         entity w;
1270         entity dw;
1271         w = waypoint_spawn(org1, org2, WAYPOINTFLAG_GENERATED | teleport_flag | WAYPOINTFLAG_NORELINK);
1272         dw = waypoint_spawn(destination1, destination2, WAYPOINTFLAG_GENERATED);
1273         // one way link to the destination
1274         w.wp00 = dw;
1275         w.wp00mincost = timetaken; // this is just for jump pads
1276         // the teleporter's nearest spawnfunc_waypoint is this one
1277         // (teleporters are not goals, so this is probably useless)
1278         e.nearestwaypoint = w;
1279         e.nearestwaypointtimeout = -1;
1280 }
1281
1282 void waypoint_spawnforteleporter_wz(entity e, vector org, vector destination, float timetaken, vector down_dir, entity tracetest_ent)
1283 {
1284         // warpzones with oblique warp plane rely on down_dir to snap waypoints
1285         // to the ground without leaving the warp plane
1286         // warpzones with horizontal warp plane (down_dir.x == -1) generate
1287         // destination waypoint snapped to the ground (leaving warpzone), source
1288         // waypoint in the center of the warp plane
1289         if(down_dir.x != -1)
1290                 org = waypoint_fixorigin_down_dir(org, tracetest_ent, down_dir);
1291         if(down_dir.x == -1)
1292                 down_dir = '0 0 -1';
1293         destination = waypoint_fixorigin_down_dir(destination, tracetest_ent, down_dir);
1294         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, org, org, destination, destination, timetaken);
1295 }
1296
1297 void waypoint_spawnforteleporter(entity e, vector destination, float timetaken, entity tracetest_ent)
1298 {
1299         destination = waypoint_fixorigin(destination, tracetest_ent);
1300         waypoint_spawnforteleporter_boxes(e, WAYPOINTFLAG_TELEPORT, e.absmin - PL_MAX_CONST + '1 1 1', e.absmax - PL_MIN_CONST + '-1 -1 -1', destination, destination, timetaken);
1301 }
1302
1303 entity waypoint_spawnpersonal(entity this, vector position)
1304 {
1305         entity w;
1306
1307         // drop the waypoint to a proper location:
1308         //   first move it up by a player height
1309         //   then move it down to hit the floor with player bbox size
1310         position = waypoint_fixorigin(position, this);
1311
1312         w = waypoint_spawn(position, position, WAYPOINTFLAG_GENERATED | WAYPOINTFLAG_PERSONAL);
1313         w.nearestwaypoint = NULL;
1314         w.nearestwaypointtimeout = 0;
1315         w.owner = this;
1316
1317         waypoint_schedulerelink(w);
1318
1319         return w;
1320 }
1321
1322 void waypoint_showlink(entity wp1, entity wp2, int display_type)
1323 {
1324         if (!(wp1 && wp2))
1325                 return;
1326
1327         if (wp1.wphardwired && wp2.wphardwired)
1328                 te_beam(NULL, wp1.origin, wp2.origin);
1329         else if (display_type == 1)
1330                 te_lightning2(NULL, wp1.origin, wp2.origin);
1331 }
1332
1333 void waypoint_showlinks_to(entity wp, int display_type)
1334 {
1335         IL_EACH(g_waypoints, it != wp,
1336         {
1337                 if (waypoint_islinked(it, wp))
1338                         waypoint_showlink(it, wp, display_type);
1339         });
1340 }
1341
1342 void waypoint_showlinks_from(entity wp, int display_type)
1343 {
1344         waypoint_showlink(wp.wp00, wp, display_type); waypoint_showlink(wp.wp16, wp, display_type);
1345         waypoint_showlink(wp.wp01, wp, display_type); waypoint_showlink(wp.wp17, wp, display_type);
1346         waypoint_showlink(wp.wp02, wp, display_type); waypoint_showlink(wp.wp18, wp, display_type);
1347         waypoint_showlink(wp.wp03, wp, display_type); waypoint_showlink(wp.wp19, wp, display_type);
1348         waypoint_showlink(wp.wp04, wp, display_type); waypoint_showlink(wp.wp20, wp, display_type);
1349         waypoint_showlink(wp.wp05, wp, display_type); waypoint_showlink(wp.wp21, wp, display_type);
1350         waypoint_showlink(wp.wp06, wp, display_type); waypoint_showlink(wp.wp22, wp, display_type);
1351         waypoint_showlink(wp.wp07, wp, display_type); waypoint_showlink(wp.wp23, wp, display_type);
1352         waypoint_showlink(wp.wp08, wp, display_type); waypoint_showlink(wp.wp24, wp, display_type);
1353         waypoint_showlink(wp.wp09, wp, display_type); waypoint_showlink(wp.wp25, wp, display_type);
1354         waypoint_showlink(wp.wp10, wp, display_type); waypoint_showlink(wp.wp26, wp, display_type);
1355         waypoint_showlink(wp.wp11, wp, display_type); waypoint_showlink(wp.wp27, wp, display_type);
1356         waypoint_showlink(wp.wp12, wp, display_type); waypoint_showlink(wp.wp28, wp, display_type);
1357         waypoint_showlink(wp.wp13, wp, display_type); waypoint_showlink(wp.wp29, wp, display_type);
1358         waypoint_showlink(wp.wp14, wp, display_type); waypoint_showlink(wp.wp30, wp, display_type);
1359         waypoint_showlink(wp.wp15, wp, display_type); waypoint_showlink(wp.wp31, wp, display_type);
1360 }
1361
1362 void botframe_showwaypointlinks()
1363 {
1364         if (time < botframe_waypointeditorlightningtime)
1365                 return;
1366         botframe_waypointeditorlightningtime = time + 0.5;
1367         FOREACH_CLIENT(IS_PLAYER(it) && !it.isbot,
1368         {
1369                 int display_type = 0;
1370                 entity head = navigation_findnearestwaypoint(it, false);
1371                 it.nearestwaypoint = head; // mainly useful for debug
1372                 it.nearestwaypointtimeout = time + 2; // while I'm at it...
1373                 if (IS_ONGROUND(it) || it.waterlevel > WATERLEVEL_NONE)
1374                         display_type = 1; // default
1375                 else if(head && (head.wphardwired))
1376                         display_type = 2; // only hardwired
1377
1378                 if (display_type)
1379                 {
1380                         //navigation_testtracewalk = true;
1381                         //print("currently selected WP is ", etos(head), "\n");
1382                         //navigation_testtracewalk = false;
1383                         if (head)
1384                         {
1385                                 te_lightning2(NULL, head.origin, it.origin);
1386                                 if(PHYS_INPUT_BUTTON_CROUCH(it))
1387                                         waypoint_showlinks_to(head, display_type);
1388                                 else
1389                                         waypoint_showlinks_from(head, display_type);
1390                         }
1391                 }
1392         });
1393 }
1394
1395 float botframe_autowaypoints_fixdown(vector v)
1396 {
1397         tracebox(v, PL_MIN_CONST, PL_MAX_CONST, v + '0 0 -64', MOVE_NOMONSTERS, NULL);
1398         if(trace_fraction >= 1)
1399                 return 0;
1400         return 1;
1401 }
1402
1403 float botframe_autowaypoints_createwp(vector v, entity p, .entity fld, float f)
1404 {
1405         IL_EACH(g_waypoints, boxesoverlap(v - '32 32 32', v + '32 32 32', it.absmin, it.absmax),
1406         {
1407                 // if a matching spawnfunc_waypoint already exists, don't add a duplicate
1408                 return 0;
1409         });
1410
1411         waypoint_schedulerelink(p.(fld) = waypoint_spawn(v, v, f));
1412         return 1;
1413 }
1414
1415 // return value:
1416 //    1 = WP created
1417 //    0 = no action needed
1418 //   -1 = temp fail, try from world too
1419 //   -2 = permanent fail, do not retry
1420 float botframe_autowaypoints_fix_from(entity p, float walkfromwp, entity wp, .entity fld)
1421 {
1422         // make it possible to go from p to wp, if we can
1423         // if wp is NULL, nearest is chosen
1424
1425         entity w;
1426         vector porg;
1427         float t, tmin, tmax;
1428         vector o;
1429         vector save;
1430
1431         if(!botframe_autowaypoints_fixdown(p.origin))
1432                 return -2;
1433         porg = trace_endpos;
1434
1435         if(wp)
1436         {
1437                 // if any WP w fulfills wp -> w -> porg and w is closer than wp, then switch from wp to w
1438
1439                 // if wp -> porg, then OK
1440                 float maxdist;
1441                 if(navigation_waypoint_will_link(wp.origin, porg, p, porg, 0, wp.origin, 0, walkfromwp, 1050))
1442                 {
1443                         // we may find a better one
1444                         maxdist = vlen(wp.origin - porg);
1445                 }
1446                 else
1447                 {
1448                         // accept any "good"
1449                         maxdist = 2100;
1450                 }
1451
1452                 float bestdist = maxdist;
1453                 IL_EACH(g_waypoints, it != wp && !(it.wpflags & WAYPOINTFLAG_NORELINK),
1454                 {
1455                         float d = vlen(wp.origin - it.origin) + vlen(it.origin - porg);
1456                         if(d < bestdist)
1457                         if(navigation_waypoint_will_link(wp.origin, it.origin, p, it.origin, 0, wp.origin, 0, walkfromwp, 1050))
1458                         if(navigation_waypoint_will_link(it.origin, porg, p, porg, 0, it.origin, 0, walkfromwp, 1050))
1459                         {
1460                                 bestdist = d;
1461                                 p.(fld) = it;
1462                         }
1463                 });
1464                 if(bestdist < maxdist)
1465                 {
1466                         LOG_INFO("update chain to new nearest WP ", etos(p.(fld)));
1467                         return 0;
1468                 }
1469
1470                 if(bestdist < 2100)
1471                 {
1472                         // we know maxdist < 2100
1473                         // so wp -> porg is still valid
1474                         // all is good
1475                         p.(fld) = wp;
1476                         return 0;
1477                 }
1478
1479                 // otherwise, no existing WP can fix our issues
1480         }
1481         else
1482         {
1483                 save = p.origin;
1484                 setorigin(p, porg);
1485                 w = navigation_findnearestwaypoint(p, walkfromwp);
1486                 setorigin(p, save);
1487                 if(w)
1488                 {
1489                         p.(fld) = w;
1490                         return 0;
1491                 }
1492         }
1493
1494         tmin = 0;
1495         tmax = 1;
1496         for (;;)
1497         {
1498                 if(tmax - tmin < 0.001)
1499                 {
1500                         // did not get a good candidate
1501                         return -1;
1502                 }
1503
1504                 t = (tmin + tmax) * 0.5;
1505                 o = antilag_takebackorigin(p, CS(p), time - t);
1506                 if(!botframe_autowaypoints_fixdown(o))
1507                         return -2;
1508                 o = trace_endpos;
1509
1510                 if(wp)
1511                 {
1512                         if(!navigation_waypoint_will_link(wp.origin, o, p, o, 0, wp.origin, 0, walkfromwp, 1050))
1513                         {
1514                                 // we cannot walk from wp.origin to o
1515                                 // get closer to tmax
1516                                 tmin = t;
1517                                 continue;
1518                         }
1519                 }
1520                 else
1521                 {
1522                         save = p.origin;
1523                         setorigin(p, o);
1524                         w = navigation_findnearestwaypoint(p, walkfromwp);
1525                         setorigin(p, save);
1526                         if(!w)
1527                         {
1528                                 // we cannot walk from any WP to o
1529                                 // get closer to tmax
1530                                 tmin = t;
1531                                 continue;
1532                         }
1533                 }
1534
1535                 // if we get here, o is valid regarding waypoints
1536                 // check if o is connected right to the player
1537                 // we break if it succeeds, as that means o is a good waypoint location
1538                 if(navigation_waypoint_will_link(o, porg, p, porg, 0, o, 0, walkfromwp, 1050))
1539                         break;
1540
1541                 // o is no good, we need to get closer to the player
1542                 tmax = t;
1543         }
1544
1545         LOG_INFO("spawning a waypoint for connecting to ", etos(wp));
1546         botframe_autowaypoints_createwp(o, p, fld, 0);
1547         return 1;
1548 }
1549
1550 // automatically create missing waypoints
1551 .entity botframe_autowaypoints_lastwp0, botframe_autowaypoints_lastwp1;
1552 void botframe_autowaypoints_fix(entity p, float walkfromwp, .entity fld)
1553 {
1554         float r = botframe_autowaypoints_fix_from(p, walkfromwp, p.(fld), fld);
1555         if(r != -1)
1556                 return;
1557         r = botframe_autowaypoints_fix_from(p, walkfromwp, NULL, fld);
1558         if(r != -1)
1559                 return;
1560
1561         LOG_INFO("emergency: got no good nearby WP to build a link from, starting a new chain");
1562         if(!botframe_autowaypoints_fixdown(p.origin))
1563                 return; // shouldn't happen, caught above
1564         botframe_autowaypoints_createwp(trace_endpos, p, fld, WAYPOINTFLAG_PROTECTED);
1565 }
1566
1567 void botframe_deleteuselesswaypoints()
1568 {
1569         IL_EACH(g_items, it.bot_pickup,
1570         {
1571                 // NOTE: this protects waypoints if they're the ONLY nearest
1572                 // waypoint. That's the intention.
1573                 navigation_findnearestwaypoint(it, false);  // Walk TO item.
1574                 navigation_findnearestwaypoint(it, true);  // Walk FROM item.
1575         });
1576         IL_EACH(g_waypoints, true,
1577         {
1578                 it.wpflags |= WAYPOINTFLAG_DEAD_END;
1579                 it.wpflags &= ~WAYPOINTFLAG_USEFUL;
1580                 // WP is useful if:
1581                 if (it.wpflags & WAYPOINTFLAG_ITEM)
1582                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1583                 if (it.wpflags & WAYPOINTFLAG_TELEPORT)
1584                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1585                 if (it.wpflags & WAYPOINTFLAG_LADDER)
1586                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1587                 if (it.wpflags & WAYPOINTFLAG_PROTECTED)
1588                         it.wpflags |= WAYPOINTFLAG_USEFUL;
1589                 // b) WP is closest WP for an item/spawnpoint/other entity
1590                 //    This has been done above by protecting these WPs.
1591         });
1592         // c) There are w1, w, w2 so that w1 -> w, w -> w2 and not w1 -> w2.
1593         IL_EACH(g_waypoints, !(it.wpflags & WAYPOINTFLAG_PERSONAL),
1594         {
1595                 for (int m = 0; m < 32; ++m)
1596                 {
1597                         entity w = waypoint_get_link(it, m);
1598                         if (!w)
1599                                 break;
1600                         if (w.wpflags & WAYPOINTFLAG_PERSONAL)
1601                                 continue;
1602                         if (w.wpflags & WAYPOINTFLAG_USEFUL)
1603                                 continue;
1604                         for (int j = 0; j < 32; ++j)
1605                         {
1606                                 entity w2 = waypoint_get_link(w, j);
1607                                 if (!w2)
1608                                         break;
1609                                 if (it == w2)
1610                                         continue;
1611                                 if (w2.wpflags & WAYPOINTFLAG_PERSONAL)
1612                                         continue;
1613                                 // If we got here, it != w2 exist with it -> w
1614                                 // and w -> w2. That means the waypoint is not
1615                                 // a dead end.
1616                                 w.wpflags &= ~WAYPOINTFLAG_DEAD_END;
1617                                 for (int k = 0; k < 32; ++k)
1618                                 {
1619                                         if (waypoint_get_link(it, k) == w2)
1620                                                 continue;
1621                                         // IF WE GET HERE, w is proven useful
1622                                         // to get from it to w2!
1623                                         w.wpflags |= WAYPOINTFLAG_USEFUL;
1624                                         goto next;
1625                                 }
1626                         }
1627 LABEL(next)
1628                 }
1629         });
1630         // d) The waypoint is a dead end. Dead end waypoints must be kept as
1631         //     they are needed to complete routes while autowaypointing.
1632
1633         IL_EACH(g_waypoints, !(it.wpflags & (WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END)),
1634         {
1635                 LOG_INFOF("Removed a waypoint at %v. Try again for more!", it.origin);
1636                 te_explosion(it.origin);
1637                 waypoint_remove(it);
1638                 break;
1639         });
1640
1641         IL_EACH(g_waypoints, true,
1642         {
1643                 it.wpflags &= ~(WAYPOINTFLAG_USEFUL | WAYPOINTFLAG_DEAD_END); // temp flag
1644         });
1645 }
1646
1647 void botframe_autowaypoints()
1648 {
1649         FOREACH_CLIENT(IS_PLAYER(it) && IS_REAL_CLIENT(it) && !IS_DEAD(it), {
1650                 // going back is broken, so only fix waypoints to walk TO the player
1651                 //botframe_autowaypoints_fix(p, false, botframe_autowaypoints_lastwp0);
1652                 botframe_autowaypoints_fix(it, true, botframe_autowaypoints_lastwp1);
1653                 //te_explosion(p.botframe_autowaypoints_lastwp0.origin);
1654         });
1655
1656         if (autocvar_g_waypointeditor_auto >= 2) {
1657                 botframe_deleteuselesswaypoints();
1658         }
1659 }
1660