qcsrc/server/bot/havocbot/havocbot.qc

   1 #include "havocbot.qh"
   2 #include "role_ctf.qc"
   3 #include "role_onslaught.qc"
   4 #include "role_keyhunt.qc"
   5 #include "role_keepaway.qc"
   6 #include "roles.qc"
   7
   8 void havocbot_ai()
   9 {
  10         if(self.draggedby)
  11                 return;
  12
  13         if(bot_execute_commands())
  14                 return;
  15
  16         if (bot_strategytoken == self)
  17         if (!bot_strategytoken_taken)
  18         {
  19                 if(self.havocbot_blockhead)
  20                 {
  21                         self.havocbot_blockhead = FALSE;
  22                 }
  23                 else
  24                 {
  25                         if not(self.jumppadcount)
  26                                 self.havocbot_role();
  27                 }
  28
  29                 // TODO: tracewalk() should take care of this job (better path finding under water)
  30                 // if we don't have a goal and we're under water look for a waypoint near the "shore" and push it
  31                 if(self.deadflag != DEAD_NO)
  32                 if(self.goalcurrent==world)
  33                 if(self.waterlevel==WATERLEVEL_SWIMMING || self.aistatus & AI_STATUS_OUT_WATER)
  34                 {
  35                         // Look for the closest waypoint out of water
  36                         local entity newgoal, head;
  37                         local float bestdistance, distance;
  38
  39                         newgoal = world;
  40                         bestdistance = 10000;
  41                         for (head = findchain(classname, "waypoint"); head; head = head.chain)
  42                         {
  43                                 distance = vlen(head.origin - self.origin);
  44                                 if(distance>10000)
  45                                         continue;
  46
  47                                 if(head.origin_z < self.origin_z)
  48                                         continue;
  49
  50                                 if(head.origin_z - self.origin_z - self.view_ofs_z > 100)
  51                                         continue;
  52
  53                                 if (pointcontents(head.origin + head.maxs + '0 0 1') != CONTENT_EMPTY)
  54                                         continue;
  55
  56                                 traceline(self.origin + self.view_ofs , head.origin, TRUE, head);
  57
  58                                 if(trace_fraction<1)
  59                                         continue;
  60
  61                                 if(distance<bestdistance)
  62                                 {
  63                                         newgoal = head;
  64                                         bestdistance = distance;
  65                                 }
  66                         }
  67
  68                         if(newgoal)
  69                         {
  70                         //      te_wizspike(newgoal.origin);
  71                                 navigation_pushroute(newgoal);
  72                         }
  73                 }
  74
  75                 // token has been used this frame
  76                 bot_strategytoken_taken = TRUE;
  77         }
  78
  79         if(self.deadflag != DEAD_NO)
  80                 return;
  81
  82         havocbot_chooseenemy();
  83         if (self.bot_chooseweapontime < time )
  84         {
  85                 self.bot_chooseweapontime = time + autocvar_bot_ai_chooseweaponinterval;
  86                 havocbot_chooseweapon();
  87         }
  88         havocbot_aim();
  89         lag_update();
  90         if (self.bot_aimtarg)
  91         {
  92                 self.aistatus |= AI_STATUS_ATTACKING;
  93                 self.aistatus &~= AI_STATUS_ROAMING;
  94
  95                 if(self.weapons)
  96                 {
  97                         weapon_action(self.weapon, WR_AIM);
  98                         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(self))
  99                         {
 100                                 self.BUTTON_ATCK = FALSE;
 101                                 self.BUTTON_ATCK2 = FALSE;
 102                         }
 103                         else
 104                         {
 105                                 if(self.BUTTON_ATCK||self.BUTTON_ATCK2)
 106                                         self.lastfiredweapon = self.weapon;
 107                         }
 108                 }
 109                 else
 110                 {
 111                         if(self.bot_aimtarg.classname=="player")
 112                                 bot_aimdir(self.bot_aimtarg.origin + self.bot_aimtarg.view_ofs - self.origin - self.view_ofs , -1);
 113                 }
 114         }
 115         else if (self.goalcurrent)
 116         {
 117                 self.aistatus |= AI_STATUS_ROAMING;
 118                 self.aistatus &~= AI_STATUS_ATTACKING;
 119
 120                 local vector now,v,next;//,heading;
 121                 local float aimdistance,skillblend,distanceblend,blend;
 122                 next = now = self.goalcurrent.origin - (self.origin + self.view_ofs);
 123                 aimdistance = vlen(now);
 124                 //heading = self.velocity;
 125                 //dprint(self.goalstack01.classname,etos(self.goalstack01),"\n");
 126                 if(
 127                         self.goalstack01 != self && self.goalstack01 != world && self.aistatus & AI_STATUS_RUNNING == 0 &&
 128                         !(self.goalcurrent.wpflags & WAYPOINTFLAG_TELEPORT)
 129                 )
 130                         next = self.goalstack01.origin - (self.origin + self.view_ofs);
 131
 132                 skillblend=bound(0,(skill+self.bot_moveskill-2.5)*0.5,1); //lower skill player can't preturn
 133                 distanceblend=bound(0,aimdistance/autocvar_bot_ai_keyboard_distance,1);
 134                 blend = skillblend * (1-distanceblend);
 135                 //v = (now * (distanceblend) + next * (1-distanceblend)) * (skillblend) + now * (1-skillblend);
 136                 //v = now * (distanceblend) * (skillblend) + next * (1-distanceblend) * (skillblend) + now * (1-skillblend);
 137                 //v = now * ((1-skillblend) + (distanceblend) * (skillblend)) + next * (1-distanceblend) * (skillblend);
 138                 v = now + blend * (next - now);
 139                 //dprint(etos(self), " ");
 140                 //dprint(vtos(now), ":", vtos(next), "=", vtos(v), " (blend ", ftos(blend), ")\n");
 141                 //v = now * (distanceblend) + next * (1-distanceblend);
 142                 if (self.waterlevel < WATERLEVEL_SWIMMING)
 143                         v_z = 0;
 144                 //dprint("walk at:", vtos(v), "\n");
 145                 //te_lightning2(world, self.origin, self.goalcurrent.origin);
 146                 bot_aimdir(v, -1);
 147         }
 148         havocbot_movetogoal();
 149
 150         // if the bot is not attacking, consider reloading weapons
 151         if not(self.aistatus & AI_STATUS_ATTACKING)
 152         {
 153                 float i;
 154                 entity e;
 155
 156                 // we are currently holding a weapon that's not fully loaded, reload it
 157                 if(skill >= 2) // bots can only reload the held weapon on purpose past this skill
 158                 if(self.clip_load < self.clip_size)
 159                         self.impulse = 20; // "press" the reload button, not sure if this is done right
 160
 161                 // if we're not reloading a weapon, switch to any weapon in our invnetory that's not fully loaded to reload it next
 162                 // the code above executes next frame, starting the reloading then
 163                 if(skill >= 5) // bots can only look for unloaded weapons past this skill
 164                 if(self.clip_load >= 0) // only if we're not reloading a weapon already
 165                 {
 166                         for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 167                         {
 168                                 e = get_weaponinfo(i);
 169                                 if ((e.spawnflags & WEP_FLAG_RELOADABLE) && (self.weapon_load[i] < cvar(strcat("g_balance_", e.netname, "_reload_ammo"))))
 170                                         self.switchweapon = i;
 171                         }
 172                 }
 173         }
 174 };
 175
 176 void havocbot_keyboard_movement(vector destorg)
 177 {
 178         local vector keyboard;
 179         local float blend, maxspeed;
 180         float sk;
 181
 182         sk = skill + self.bot_moveskill;
 183
 184         maxspeed = autocvar_sv_maxspeed;
 185
 186         if (time < self.havocbot_keyboardtime)
 187                 return;
 188
 189         self.havocbot_keyboardtime =
 190                 max(
 191                         self.havocbot_keyboardtime
 192                                 + 0.05/max(1, sk+self.havocbot_keyboardskill)
 193                                 + random()*0.025/max(0.00025, skill+self.havocbot_keyboardskill)
 194                 , time);
 195         keyboard = self.movement * (1.0 / maxspeed);
 196
 197         local float trigger, trigger1;
 198         blend = bound(0,sk*0.1,1);
 199         trigger = autocvar_bot_ai_keyboard_threshold;
 200         trigger1 = 0 - trigger;
 201
 202         // categorize forward movement
 203         // at skill < 1.5 only forward
 204         // at skill < 2.5 only individual directions
 205         // at skill < 4.5 only individual directions, and forward diagonals
 206         // at skill >= 4.5, all cases allowed
 207         if (keyboard_x > trigger)
 208         {
 209                 keyboard_x = 1;
 210                 if (sk < 2.5)
 211                         keyboard_y = 0;
 212         }
 213         else if (keyboard_x < trigger1 && sk > 1.5)
 214         {
 215                 keyboard_x = -1;
 216                 if (sk < 4.5)
 217                         keyboard_y = 0;
 218         }
 219         else
 220         {
 221                 keyboard_x = 0;
 222                 if (sk < 1.5)
 223                         keyboard_y = 0;
 224         }
 225         if (sk < 4.5)
 226                 keyboard_z = 0;
 227
 228         if (keyboard_y > trigger)
 229                 keyboard_y = 1;
 230         else if (keyboard_y < trigger1)
 231                 keyboard_y = -1;
 232         else
 233                 keyboard_y = 0;
 234
 235         if (keyboard_z > trigger)
 236                 keyboard_z = 1;
 237         else if (keyboard_z < trigger1)
 238                 keyboard_z = -1;
 239         else
 240                 keyboard_z = 0;
 241
 242         self.havocbot_keyboard = keyboard * maxspeed;
 243         if (self.havocbot_ducktime>time) self.BUTTON_CROUCH=TRUE;
 244
 245         keyboard = self.havocbot_keyboard;
 246         blend = bound(0,vlen(destorg-self.origin)/autocvar_bot_ai_keyboard_distance,1); // When getting close move with 360 degree
 247         //dprint("movement ", vtos(self.movement), " keyboard ", vtos(keyboard), " blend ", ftos(blend), "\n");
 248         self.movement = self.movement + (keyboard - self.movement) * blend;
 249 };
 250
 251 void havocbot_bunnyhop(vector dir)
 252 {
 253         local float bunnyhopdistance;
 254         local vector deviation;
 255         local float maxspeed;
 256
 257         if(autocvar_g_midair)
 258                 return;
 259
 260         // Don't jump when using some weapons
 261         /*
 262         if(self.aistatus & AI_STATUS_ATTACKING)
 263         if(self.weapon == WEP_RIFLE)
 264                 return;
 265
 266         if(self.goalcurrent.classname == "player")
 267                 return;
 268         */
 269
 270         maxspeed = autocvar_sv_maxspeed;
 271
 272         if(self.aistatus & AI_STATUS_DANGER_AHEAD)
 273         {
 274                 self.aistatus &~= AI_STATUS_RUNNING;
 275                 self.BUTTON_JUMP = FALSE;
 276                 self.bot_canruntogoal = 0;
 277                 self.bot_timelastseengoal = 0;
 278                 return;
 279         }
 280
 281         if(self.waterlevel > WATERLEVEL_WETFEET)
 282         {
 283                 self.aistatus &~= AI_STATUS_RUNNING;
 284                 return;
 285         }
 286
 287         if(self.bot_lastseengoal != self.goalcurrent && !(self.aistatus & AI_STATUS_RUNNING))
 288         {
 289                 self.bot_canruntogoal = 0;
 290                 self.bot_timelastseengoal = 0;
 291         }
 292
 293         bunnyhopdistance = vlen(self.origin - self.goalcurrent.origin);
 294
 295         // Run only to visible goals
 296         if(self.flags & FL_ONGROUND)
 297         if(self.speed==maxspeed)
 298         if(checkpvs(self.origin + self.view_ofs, self.goalcurrent))
 299         {
 300                         self.bot_lastseengoal = self.goalcurrent;
 301
 302                         // seen it before
 303                         if(self.bot_timelastseengoal)
 304                         {
 305                                 // for a period of time
 306                                 if(time - self.bot_timelastseengoal > autocvar_bot_ai_bunnyhop_firstjumpdelay)
 307                                 {
 308                                         local float checkdistance;
 309                                         checkdistance = TRUE;
 310
 311                                         // don't run if it is too close
 312                                         if(self.bot_canruntogoal==0)
 313                                         {
 314                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_startdistance)
 315                                                         self.bot_canruntogoal = 1;
 316                                                 else
 317                                                         self.bot_canruntogoal = -1;
 318                                         }
 319
 320                                         if(self.bot_canruntogoal != 1)
 321                                                 return;
 322
 323                                         if(self.aistatus & AI_STATUS_ROAMING)
 324                                         if(self.goalcurrent.classname=="waypoint")
 325                                         if not(self.goalcurrent.wpflags & WAYPOINTFLAG_PERSONAL)
 326                                         if(fabs(self.goalcurrent.origin_z - self.origin_z) < self.maxs_z - self.mins_z)
 327                                         if(self.goalstack01!=world)
 328                                         {
 329                                                 deviation = vectoangles(self.goalstack01.origin - self.origin) - vectoangles(self.goalcurrent.origin - self.origin);
 330                                                 while (deviation_y < -180) deviation_y = deviation_y + 360;
 331                                                 while (deviation_y > 180) deviation_y = deviation_y - 360;
 332
 333                                                 if(fabs(deviation_y) < 20)
 334                                                 if(bunnyhopdistance < vlen(self.origin - self.goalstack01.origin))
 335                                                 if(fabs(self.goalstack01.origin_z - self.goalcurrent.origin_z) < self.maxs_z - self.mins_z)
 336                                                 {
 337                                                         if(vlen(self.goalcurrent.origin - self.goalstack01.origin) > autocvar_bot_ai_bunnyhop_startdistance)
 338                                                         if(checkpvs(self.origin + self.view_ofs, self.goalstack01))
 339                                                         {
 340                                                                 checkdistance = FALSE;
 341                                                         }
 342                                                 }
 343                                         }
 344
 345                                         if(checkdistance)
 346                                         {
 347                                                 self.aistatus &~= AI_STATUS_RUNNING;
 348                                                 if(bunnyhopdistance > autocvar_bot_ai_bunnyhop_stopdistance)
 349                                                         self.BUTTON_JUMP = TRUE;
 350                                         }
 351                                         else
 352                                         {
 353                                                 self.aistatus |= AI_STATUS_RUNNING;
 354                                                 self.BUTTON_JUMP = TRUE;
 355                                         }
 356                                 }
 357                         }
 358                         else
 359                         {
 360                                 self.bot_timelastseengoal = time;
 361                         }
 362         }
 363         else
 364         {
 365                 self.bot_timelastseengoal = 0;
 366         }
 367
 368         // Release jump button
 369         if(!cvar("sv_pogostick"))
 370         if(self.flags & FL_ONGROUND == 0)
 371         {
 372                 if(self.velocity_z < 0 || vlen(self.velocity)<maxspeed)
 373                         self.BUTTON_JUMP = FALSE;
 374
 375                 // Strafe
 376                 if(self.aistatus & AI_STATUS_RUNNING)
 377                 if(vlen(self.velocity)>maxspeed)
 378                 {
 379                         deviation = vectoangles(dir) - vectoangles(self.velocity);
 380                         while (deviation_y < -180) deviation_y = deviation_y + 360;
 381                         while (deviation_y > 180) deviation_y = deviation_y - 360;
 382
 383                         if(fabs(deviation_y)>10)
 384                                 self.movement_x = 0;
 385
 386                         if(deviation_y>10)
 387                                 self.movement_y = maxspeed * -1;
 388                         else if(deviation_y<10)
 389                                 self.movement_y = maxspeed;
 390
 391                 }
 392         }
 393 };
 394
 395 void havocbot_movetogoal()
 396 {
 397         local vector destorg;
 398         local vector diff;
 399         local vector dir;
 400         local vector flatdir;
 401         local vector m1;
 402         local vector m2;
 403         local vector evadeobstacle;
 404         local vector evadelava;
 405         local float s;
 406         local float maxspeed;
 407         //local float dist;
 408         local vector dodge;
 409         //if (self.goalentity)
 410         //      te_lightning2(self, self.origin, (self.goalentity.absmin + self.goalentity.absmax) * 0.5);
 411         self.movement = '0 0 0';
 412         maxspeed = autocvar_sv_maxspeed;
 413
 414         // Jetpack navigation
 415         if(self.goalcurrent)
 416         if(self.navigation_jetpack_goal)
 417         if(self.goalcurrent==self.navigation_jetpack_goal)
 418         if(self.ammo_fuel)
 419         {
 420                 if(autocvar_bot_debug_goalstack)
 421                 {
 422                         debuggoalstack();
 423                         te_wizspike(self.navigation_jetpack_point);
 424                 }
 425
 426                 // Take off
 427                 if not(self.aistatus & AI_STATUS_JETPACK_FLYING)
 428                 {
 429                         // Brake almost completely so it can get a good direction
 430                         if(vlen(self.velocity)>10)
 431                                 return;
 432                         self.aistatus |= AI_STATUS_JETPACK_FLYING;
 433                 }
 434
 435                 makevectors(self.v_angle_y * '0 1 0');
 436                 dir = normalize(self.navigation_jetpack_point - self.origin);
 437
 438                 // Landing
 439                 if(self.aistatus & AI_STATUS_JETPACK_LANDING)
 440                 {
 441                         // Calculate brake distance in xy
 442                         float db, v, d;
 443                         vector dxy;
 444
 445                         dxy = self.origin - self.goalcurrent.origin; dxy_z = 0;
 446                         d = vlen(dxy);
 447                         v = vlen(self.velocity -  self.velocity_z * '0 0 1');
 448                         db = (pow(v,2) / (autocvar_g_jetpack_acceleration_side * 2)) + 100;
 449                 //      dprint("distance ", ftos(ceil(d)), " velocity ", ftos(ceil(v)), " brake at ", ftos(ceil(db)), "\n");
 450                         if(d < db || d < 500)
 451                         {
 452                                 // Brake
 453                                 if(fabs(self.velocity_x)>maxspeed*0.3)
 454                                 {
 455                                         self.movement_x = dir * v_forward * -maxspeed;
 456                                         return;
 457                                 }
 458                                 // Switch to normal mode
 459                                 self.navigation_jetpack_goal = world;
 460                                 self.aistatus &~= AI_STATUS_JETPACK_LANDING;
 461                                 self.aistatus &~= AI_STATUS_JETPACK_FLYING;
 462                                 return;
 463                         }
 464                 }
 465                 else if(checkpvs(self.origin,self.goalcurrent))
 466                 {
 467                         // If I can see the goal switch to landing code
 468                         self.aistatus &~= AI_STATUS_JETPACK_FLYING;
 469                         self.aistatus |= AI_STATUS_JETPACK_LANDING;
 470                         return;
 471                 }
 472
 473                 // Flying
 474                 self.BUTTON_HOOK = TRUE;
 475                 if(self.navigation_jetpack_point_z - PL_MAX_z + PL_MIN_z < self.origin_z)
 476                 {
 477                         self.movement_x = dir * v_forward * maxspeed;
 478                         self.movement_y = dir * v_right * maxspeed;
 479                 }
 480                 return;
 481         }
 482
 483         // Handling of jump pads
 484         if(self.jumppadcount)
 485         {
 486                 // If got stuck on the jump pad try to reach the farthest visible item
 487                 if(self.aistatus & AI_STATUS_OUT_JUMPPAD)
 488                 {
 489                         if(fabs(self.velocity_z)<50)
 490                         {
 491                                 local entity head, newgoal;
 492                                 local float distance, bestdistance;
 493
 494                                 for (head = findchainfloat(bot_pickup, TRUE); head; head = head.chain)
 495                                 {
 496                                         if(head.classname=="worldspawn")
 497                                                 continue;
 498
 499                                         distance = vlen(head.origin - self.origin);
 500                                         if(distance>1000)
 501                                                 continue;
 502
 503                                         traceline(self.origin + self.view_ofs , head.origin, TRUE, world);
 504
 505                                         if(trace_fraction<1)
 506                                                 continue;
 507
 508                                         if(distance>bestdistance)
 509                                         {
 510                                                 newgoal = head;
 511                                                 bestdistance = distance;
 512                                         }
 513                                 }
 514
 515                                 if(newgoal)
 516                                 {
 517                                         self.ignoregoal = self.goalcurrent;
 518                                         self.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 519                                         navigation_clearroute();
 520                                         navigation_routetogoal(newgoal, self.origin);
 521                                         self.aistatus &~= AI_STATUS_OUT_JUMPPAD;
 522                                 }
 523                         }
 524                         else
 525                                 return;
 526                 }
 527                 else
 528                 {
 529                         if(self.velocity_z>0)
 530                         {
 531                                 local float threshold;
 532                                 threshold = maxspeed * 0.2;
 533                                 if(fabs(self.velocity_x) < threshold  &&  fabs(self.velocity_y) < threshold)
 534                                 {
 535                                         dprint("Warning: ", self.netname, " got stuck on a jumppad, trying to get out of it now\n");
 536                                         self.aistatus |= AI_STATUS_OUT_JUMPPAD;
 537                                 }
 538                                 return;
 539                         }
 540
 541                         // Don't chase players while using a jump pad
 542                         if(self.goalcurrent.classname=="player" || self.goalstack01.classname=="player")
 543                                 return;
 544                 }
 545         }
 546         else if(self.aistatus & AI_STATUS_OUT_JUMPPAD)
 547                 self.aistatus &~= AI_STATUS_OUT_JUMPPAD;
 548
 549         // If there is a trigger_hurt right below try to use the jetpack or make a rocketjump
 550         if(skill>6)
 551         if not(self.flags & FL_ONGROUND)
 552         {
 553                 tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 -65536', MOVE_NOMONSTERS, self);
 554                 if(tracebox_hits_trigger_hurt(self.origin, self.mins, self.maxs, trace_endpos ))
 555                 if(self.items & IT_JETPACK)
 556                 {
 557                         tracebox(self.origin, self.mins, self.maxs, self.origin + '0 0 65536', MOVE_NOMONSTERS, self);
 558                         if(tracebox_hits_trigger_hurt(self.origin, self.mins, self.maxs, trace_endpos + '0 0 1' ))
 559                         {
 560                                 if(self.velocity_z<0)
 561                                 {
 562                                         self.BUTTON_HOOK = TRUE;
 563                                 }
 564                         }
 565                         else
 566                                 self.BUTTON_HOOK = TRUE;
 567
 568                         // If there is no goal try to move forward
 569
 570                         if(self.goalcurrent==world)
 571                                 dir = v_forward;
 572                         else
 573                                 dir = normalize(self.goalcurrent.origin - self.origin);
 574
 575                         local vector xyvelocity = self.velocity; xyvelocity_z = 0;
 576                         local float xyspeed = xyvelocity * dir;
 577
 578                         if(xyspeed < (maxspeed / 2))
 579                         {
 580                                 makevectors(self.v_angle_y * '0 1 0');
 581                                 tracebox(self.origin, self.mins, self.maxs, self.origin + (dir * maxspeed * 3), MOVE_NOMONSTERS, self);
 582                                 if(trace_fraction==1)
 583                                 {
 584                                         self.movement_x = dir * v_forward * maxspeed;
 585                                         self.movement_y = dir * v_right * maxspeed;
 586                                         if (skill < 10)
 587                                                 havocbot_keyboard_movement(self.origin + dir * 100);
 588                                 }
 589                         }
 590
 591                         self.havocbot_blockhead = TRUE;
 592
 593                         return;
 594                 }
 595                 else if(self.health>autocvar_g_balance_rocketlauncher_damage*0.5)
 596                 {
 597                         if(self.velocity_z < 0)
 598                         if(client_hasweapon(self, WEP_ROCKET_LAUNCHER, TRUE, FALSE))
 599                         {
 600                                 self.movement_x = maxspeed;
 601
 602                                 if(self.rocketjumptime)
 603                                 {
 604                                         if(time > self.rocketjumptime)
 605                                         {
 606                                                 self.BUTTON_ATCK2 = TRUE;
 607                                                 self.rocketjumptime = 0;
 608                                         }
 609                                         return;
 610                                 }
 611
 612                                 self.switchweapon = WEP_ROCKET_LAUNCHER;
 613                                 self.v_angle_x = 90;
 614                                 self.BUTTON_ATCK = TRUE;
 615                                 self.rocketjumptime = time + autocvar_g_balance_rocketlauncher_detonatedelay;
 616                                 return;
 617                         }
 618                 }
 619                 else
 620                 {
 621                         // If there is no goal try to move forward
 622                         if(self.goalcurrent==world)
 623                                 self.movement_x = maxspeed;
 624                 }
 625         }
 626
 627         // If we are under water with no goals, swim up
 628         if(self.waterlevel)
 629         if(self.goalcurrent==world)
 630         {
 631                 dir = '0 0 0';
 632                 if(self.waterlevel>WATERLEVEL_SWIMMING)
 633                         dir_z = 1;
 634                 else if(self.velocity_z >= 0 && !(self.waterlevel == WATERLEVEL_WETFEET && self.watertype == CONTENT_WATER))
 635                         self.BUTTON_JUMP = TRUE;
 636                 else
 637                         self.BUTTON_JUMP = FALSE;
 638                 makevectors(self.v_angle_y * '0 1 0');
 639                 self.movement_x = dir * v_forward * maxspeed;
 640                 self.movement_y = dir * v_right * maxspeed;
 641                 self.movement_z = dir * v_up * maxspeed;
 642         }
 643
 644         // if there is nowhere to go, exit
 645         if (self.goalcurrent == world)
 646                 return;
 647
 648         if (self.goalcurrent)
 649                 navigation_poptouchedgoals();
 650
 651         // if ran out of goals try to use an alternative goal or get a new strategy asap
 652         if(self.goalcurrent == world)
 653         {
 654                 self.bot_strategytime = 0;
 655                 return;
 656         }
 657
 658         if(autocvar_bot_debug_goalstack)
 659                 debuggoalstack();
 660
 661         m1 = self.goalcurrent.origin + self.goalcurrent.mins;
 662         m2 = self.goalcurrent.origin + self.goalcurrent.maxs;
 663         destorg = self.origin;
 664         destorg_x = bound(m1_x, destorg_x, m2_x);
 665         destorg_y = bound(m1_y, destorg_y, m2_y);
 666         destorg_z = bound(m1_z, destorg_z, m2_z);
 667         diff = destorg - self.origin;
 668         //dist = vlen(diff);
 669         dir = normalize(diff);
 670         flatdir = diff;flatdir_z = 0;
 671         flatdir = normalize(flatdir);
 672
 673         //if (self.bot_dodgevector_time < time)
 674         {
 675         //      self.bot_dodgevector_time = time + cvar("bot_ai_dodgeupdateinterval");
 676         //      self.bot_dodgevector_jumpbutton = 1;
 677                 evadeobstacle = '0 0 0';
 678                 evadelava = '0 0 0';
 679
 680                 if (self.waterlevel)
 681                 {
 682                         if(self.waterlevel>WATERLEVEL_SWIMMING)
 683                         {
 684                         //      flatdir_z = 1;
 685                                 self.aistatus |= AI_STATUS_OUT_WATER;
 686                         }
 687                         else
 688                         {
 689                                 if(self.velocity_z >= 0 && !(self.watertype == CONTENT_WATER && self.goalcurrent.origin_z < self.origin_z) &&
 690                                         ( !(self.waterlevel == WATERLEVEL_WETFEET && self.watertype == CONTENT_WATER) || self.aistatus & AI_STATUS_OUT_WATER))
 691                                         self.BUTTON_JUMP = TRUE;
 692                                 else
 693                                         self.BUTTON_JUMP = FALSE;
 694                         }
 695                         dir = normalize(flatdir);
 696                         makevectors(self.v_angle_y * '0 1 0');
 697                 }
 698                 else
 699                 {
 700                         if(self.aistatus & AI_STATUS_OUT_WATER)
 701                                 self.aistatus &~= AI_STATUS_OUT_WATER;
 702
 703                         // jump if going toward an obstacle that doesn't look like stairs we
 704                         // can walk up directly
 705                         tracebox(self.origin, self.mins, self.maxs, self.origin + self.velocity * 0.2, FALSE, self);
 706                         if (trace_fraction < 1)
 707                         if (trace_plane_normal_z < 0.7)
 708                         {
 709                                 s = trace_fraction;
 710                                 tracebox(self.origin + '0 0 16', self.mins, self.maxs, self.origin + self.velocity * 0.2 + '0 0 16', FALSE, self);
 711                                 if (trace_fraction < s + 0.01)
 712                                 if (trace_plane_normal_z < 0.7)
 713                                 {
 714                                         s = trace_fraction;
 715                                         tracebox(self.origin + '0 0 48', self.mins, self.maxs, self.origin + self.velocity * 0.2 + '0 0 48', FALSE, self);
 716                                         if (trace_fraction > s)
 717                                                 self.BUTTON_JUMP = 1;
 718                                 }
 719                         }
 720
 721                         // avoiding dangers and obstacles
 722                         local vector dst_ahead, dst_down;
 723                         makevectors(self.v_angle_y * '0 1 0');
 724                         dst_ahead = self.origin + self.view_ofs + (self.velocity * 0.4) + (v_forward * 32 * 3);
 725                         dst_down = dst_ahead + '0 0 -1500';
 726
 727                         // Look ahead
 728                         traceline(self.origin + self.view_ofs , dst_ahead, TRUE, world);
 729
 730                         // Check head-banging against walls
 731                         if(vlen(self.origin + self.view_ofs - trace_endpos) < 25 && !(self.aistatus & AI_STATUS_OUT_WATER))
 732                         {
 733                                 self.BUTTON_JUMP = TRUE;
 734                                 if(self.facingwalltime && time > self.facingwalltime)
 735                                 {
 736                                         self.ignoregoal = self.goalcurrent;
 737                                         self.ignoregoaltime = time + autocvar_bot_ai_ignoregoal_timeout;
 738                                         self.bot_strategytime = 0;
 739                                         return;
 740                                 }
 741                                 else
 742                                 {
 743                                         self.facingwalltime = time + 0.05;
 744                                 }
 745                         }
 746                         else
 747                         {
 748                                 self.facingwalltime = 0;
 749
 750                                 if(self.ignoregoal != world && time > self.ignoregoaltime)
 751                                 {
 752                                         self.ignoregoal = world;
 753                                         self.ignoregoaltime = 0;
 754                                 }
 755                         }
 756
 757                         // Check for water/slime/lava and dangerous edges
 758                         // (only when the bot is on the ground or jumping intentionally)
 759                         self.aistatus &~= AI_STATUS_DANGER_AHEAD;
 760
 761                         if(trace_fraction == 1 && self.jumppadcount == 0)
 762                         if(self.flags & FL_ONGROUND || self.aistatus & AI_STATUS_RUNNING || self.BUTTON_JUMP == TRUE)
 763                         {
 764                                 // Look downwards
 765                                 traceline(dst_ahead , dst_down, TRUE, world);
 766                         //      te_lightning2(world, self.origin, dst_ahead);   // Draw "ahead" look
 767                         //      te_lightning2(world, dst_ahead, dst_down);              // Draw "downwards" look
 768                                 if(trace_endpos_z < self.origin_z + self.mins_z)
 769                                 {
 770                                         s = pointcontents(trace_endpos + '0 0 1');
 771                                         if (s != CONTENT_SOLID)
 772                                         if (s == CONTENT_LAVA || s == CONTENT_SLIME)
 773                                                 evadelava = normalize(self.velocity) * -1;
 774                                         else if (s == CONTENT_SKY)
 775                                                 evadeobstacle = normalize(self.velocity) * -1;
 776                                         else if (!boxesoverlap(dst_ahead - self.view_ofs + self.mins, dst_ahead - self.view_ofs + self.maxs,
 777                                                                 self.goalcurrent.absmin, self.goalcurrent.absmax))
 778                                         {
 779                                                 // if ain't a safe goal with "holes" (like the jumpad on soylent)
 780                                                 // and there is a trigger_hurt below
 781                                                 if(tracebox_hits_trigger_hurt(dst_ahead, self.mins, self.maxs, trace_endpos))
 782                                                 {
 783                                                         // Remove dangerous dynamic goals from stack
 784                                                         if (self.goalcurrent.classname == "player" || self.goalcurrent.classname == "droppedweapon")
 785                                                                 navigation_poproute();
 786                                                         // try to stop
 787                                                         flatdir = '0 0 0';
 788                                                         evadeobstacle = normalize(self.velocity) * -1;
 789                                                 }
 790                                         }
 791                                 }
 792                         }
 793
 794                         dir = flatdir;
 795                         evadeobstacle_z = 0;
 796                         evadelava_z = 0;
 797                         makevectors(self.v_angle_y * '0 1 0');
 798
 799                         if(evadeobstacle!='0 0 0'||evadelava!='0 0 0')
 800                                 self.aistatus |= AI_STATUS_DANGER_AHEAD;
 801                 }
 802
 803                 dodge = havocbot_dodge();
 804                 dodge = dodge * bound(0,0.5+(skill+self.bot_dodgeskill)*0.1,1);
 805                 evadelava = evadelava * bound(1,3-(skill+self.bot_dodgeskill),3); //Noobs fear lava a lot and take more distance from it
 806                 traceline(self.origin, self.enemy.origin, TRUE, world);
 807                 if(trace_ent.classname == "player")
 808                         dir = dir * bound(0,(skill+self.bot_dodgeskill)/7,1);
 809
 810                 dir = normalize(dir + dodge + evadeobstacle + evadelava);
 811         //      self.bot_dodgevector = dir;
 812         //      self.bot_dodgevector_jumpbutton = self.BUTTON_JUMP;
 813         }
 814
 815         if(time < self.ladder_time)
 816         {
 817                 if(self.goalcurrent.origin_z + self.goalcurrent.mins_z > self.origin_z + self.mins_z)
 818                 {
 819                         if(self.origin_z + self.mins_z  < self.ladder_entity.origin_z + self.ladder_entity.maxs_z)
 820                                 dir_z = 1;
 821                 }
 822                 else
 823                 {
 824                         if(self.origin_z + self.mins_z  > self.ladder_entity.origin_z + self.ladder_entity.mins_z)
 825                                 dir_z = -1;
 826                 }
 827         }
 828
 829         //dir = self.bot_dodgevector;
 830         //if (self.bot_dodgevector_jumpbutton)
 831         //      self.BUTTON_JUMP = 1;
 832         self.movement_x = dir * v_forward * maxspeed;
 833         self.movement_y = dir * v_right * maxspeed;
 834         self.movement_z = dir * v_up * maxspeed;
 835
 836         // Emulate keyboard interface
 837         if (skill < 10)
 838                 havocbot_keyboard_movement(destorg);
 839
 840         // Bunnyhop!
 841 //      if(self.aistatus & AI_STATUS_ROAMING)
 842         if(self.goalcurrent)
 843         if(skill+self.bot_moveskill >= autocvar_bot_ai_bunnyhop_skilloffset)
 844                 havocbot_bunnyhop(dir);
 845
 846         if ((dir * v_up) >= autocvar_sv_jumpvelocity*0.5 && (self.flags & FL_ONGROUND)) self.BUTTON_JUMP=1;
 847         if (((dodge * v_up) > 0) && random()*frametime >= 0.2*bound(0,(10-skill-self.bot_dodgeskill)*0.1,1)) self.BUTTON_JUMP=TRUE;
 848         if (((dodge * v_up) < 0) && random()*frametime >= 0.5*bound(0,(10-skill-self.bot_dodgeskill)*0.1,1)) self.havocbot_ducktime=time+0.3/bound(0.1,skill+self.bot_dodgeskill,10);
 849 };
 850
 851 void havocbot_chooseenemy()
 852 {
 853         local entity head, best, head2;
 854         local float rating, bestrating, i, f;
 855         local vector eye, v;
 856         if (autocvar_bot_nofire || IS_INDEPENDENT_PLAYER(self))
 857         {
 858                 self.enemy = world;
 859                 return;
 860         }
 861         if (self.enemy)
 862         {
 863                 if (!bot_shouldattack(self.enemy))
 864                 {
 865                         // enemy died or something, find a new target
 866                         self.enemy = world;
 867                         self.havocbot_chooseenemy_finished = time;
 868                 }
 869                 else if (self.havocbot_stickenemy)
 870                 {
 871                         // tracking last chosen enemy
 872                         // if enemy is visible
 873                         // and not really really far away
 874                         // and we're not severely injured
 875                         // then keep tracking for a half second into the future
 876                         traceline(self.origin+self.view_ofs, self.enemy.origin+self.enemy.view_ofs*0.5,FALSE,world);
 877                         if (trace_ent == self.enemy || trace_fraction == 1)
 878                         if (vlen(self.enemy.origin - self.origin) < 1000)
 879                         if (self.health > 30)
 880                         {
 881                                 // remain tracking him for a shot while (case he went after a small corner or pilar
 882                                 self.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
 883                                 return;
 884                         }
 885                         // enemy isn't visible, or is far away, or we're injured severely
 886                         // so stop preferring this enemy
 887                         // (it will still take a half second until a new one is chosen)
 888                         self.havocbot_stickenemy = 0;
 889                 }
 890         }
 891         if (time < self.havocbot_chooseenemy_finished)
 892                 return;
 893         self.havocbot_chooseenemy_finished = time + autocvar_bot_ai_enemydetectioninterval;
 894         eye = self.origin + self.view_ofs;
 895         best = world;
 896         bestrating = 100000000;
 897         head = head2 = findchainfloat(bot_attack, TRUE);
 898
 899         // Search for enemies, if no enemy can be seen directly try to look through transparent objects
 900         for(;;)
 901         {
 902                 while (head)
 903                 {
 904                         v = (head.absmin + head.absmax) * 0.5;
 905                         rating = vlen(v - eye);
 906                         if (rating<autocvar_bot_ai_enemydetectionradius)
 907                         if (bestrating > rating)
 908                         if (bot_shouldattack(head))
 909                         {
 910                                 traceline(eye, v, TRUE, self);
 911                                 if (trace_ent == head || trace_fraction >= 1)
 912                                 {
 913                                         best = head;
 914                                         bestrating = rating;
 915                                 }
 916                         }
 917                         head = head.chain;
 918                 }
 919
 920                 // I want to do a second scan if no enemy was found or I don't have weapons
 921                 // TODO: Perform the scan when using the rifle (requires changes on the rifle code)
 922                 if(best || self.weapons) // || self.weapon == WEP_RIFLE
 923                         break;
 924                 if(i)
 925                         break;
 926
 927                 // Set flags to see through transparent objects
 928                 f = self.dphitcontentsmask;
 929                 self.dphitcontentsmask = DPCONTENTS_OPAQUE;
 930
 931                 head = head2;
 932                 ++i;
 933         }
 934
 935         // Restore hit flags if needed
 936         if(i)
 937                 self.dphitcontentsmask = f;
 938
 939         self.enemy = best;
 940         self.havocbot_stickenemy = TRUE;
 941 };
 942
 943 float havocbot_chooseweapon_checkreload(float new_weapon)
 944 {
 945         // bots under this skill cannot find unloaded weapons to reload idly when not in combat,
 946         // so skip this for them, or they'll never get to reload their weapons at all.
 947         // this also allows bots under this skill to be more stupid, and reload more often during combat :)
 948         if(skill < 5)
 949                 return FALSE;
 950
 951         // if this weapon is scheduled for reloading, don't switch to it during combat
 952         if (self.weapon_load[new_weapon] < 0)
 953         {
 954                 local float i, other_weapon_available;
 955                 for(i = WEP_FIRST; i <= WEP_LAST; ++i)
 956                 {
 957                         // if we are out of ammo for all other weapons, it's an emergency to switch to anything else
 958                         if (weapon_action(i, WR_CHECKAMMO1) + weapon_action(i, WR_CHECKAMMO2))
 959                                 other_weapon_available = TRUE;
 960                 }
 961                 if(other_weapon_available)
 962                         return TRUE;
 963         }
 964
 965         return FALSE;
 966 }
 967
 968 void havocbot_chooseweapon()
 969 {
 970         local float i;
 971
 972         // ;)
 973         if(g_weaponarena == WEPBIT_TUBA)
 974         {
 975                 self.switchweapon = WEP_TUBA;
 976                 return;
 977         }
 978
 979         // TODO: clean this up by moving it to weapon code
 980         if(self.enemy==world)
 981         {
 982                 // If no weapon was chosen get the first available weapon
 983                 if(self.weapon==0)
 984                 for(i=WEP_LASER + 1; i < WEP_COUNT ; ++i)
 985                 {
 986                         if(client_hasweapon(self, i, TRUE, FALSE))
 987                         {
 988                                 self.switchweapon = i;
 989                                 return;
 990                         }
 991                 }
 992                 return;
 993         }
 994
 995         // Do not change weapon during the next second after a combo
 996         i = time - self.lastcombotime;
 997         if(i < 1)
 998                 return;
 999
1000         local float w;
1001         local float distance; distance=bound(10,vlen(self.origin-self.enemy.origin)-200,10000);
1002
1003         // Should it do a weapon combo?
1004         local float af, ct, combo_time, combo;
1005
1006         af = ATTACK_FINISHED(self);
1007         ct = autocvar_bot_ai_weapon_combo_threshold;
1008
1009         // Bots with no skill will be 4 times more slower than "godlike" bots when doing weapon combos
1010         // Ideally this 4 should be calculated as longest_weapon_refire / bot_ai_weapon_combo_threshold
1011         combo_time = time + ct + (ct * ((-0.3*(skill+self.bot_weaponskill))+3));
1012
1013         combo = FALSE;
1014
1015         if(autocvar_bot_ai_weapon_combo)
1016         if(self.weapon == self.lastfiredweapon)
1017         if(af > combo_time)
1018         {
1019                 combo = TRUE;
1020                 self.lastcombotime = time;
1021         }
1022
1023         distance *= pow(2, self.bot_rangepreference);
1024
1025         // Custom weapon list based on distance to the enemy
1026         if(bot_custom_weapon){
1027
1028                 // Choose weapons for far distance
1029                 if ( distance > bot_distance_far ) {
1030                         for(i=0; i < WEP_COUNT && bot_weapons_far[i] != -1 ; ++i){
1031                                 w = bot_weapons_far[i];
1032                                 if ( client_hasweapon(self, w, TRUE, FALSE) )
1033                                 {
1034                                         if ((self.weapon == w && combo) || havocbot_chooseweapon_checkreload(w))
1035                                                 continue;
1036                                         self.switchweapon = w;
1037                                         return;
1038                                 }
1039                         }
1040                 }
1041
1042                 // Choose weapons for mid distance
1043                 if ( distance > bot_distance_close) {
1044                         for(i=0; i < WEP_COUNT && bot_weapons_mid[i] != -1 ; ++i){
1045                                 w = bot_weapons_mid[i];
1046                                 if ( client_hasweapon(self, w, TRUE, FALSE) )
1047                                 {
1048                                         if ((self.weapon == w && combo) || havocbot_chooseweapon_checkreload(w))
1049                                                 continue;
1050                                         self.switchweapon = w;
1051                                         return;
1052                                 }
1053                         }
1054                 }
1055
1056                 // Choose weapons for close distance
1057                 for(i=0; i < WEP_COUNT && bot_weapons_close[i] != -1 ; ++i){
1058                         w = bot_weapons_close[i];
1059                         if ( client_hasweapon(self, w, TRUE, FALSE) )
1060                         {
1061                                 if ((self.weapon == w && combo) || havocbot_chooseweapon_checkreload(w))
1062                                         continue;
1063                                 self.switchweapon = w;
1064                                 return;
1065                         }
1066                 }
1067         }
1068 };
1069
1070 void havocbot_aim()
1071 {
1072         local vector selfvel, enemyvel;
1073 //      if(self.flags & FL_INWATER)
1074 //              return;
1075         if (time < self.nextaim)
1076                 return;
1077         self.nextaim = time + 0.1;
1078         selfvel = self.velocity;
1079         if (!self.waterlevel)
1080                 selfvel_z = 0;
1081         if (self.enemy)
1082         {
1083                 enemyvel = self.enemy.velocity;
1084                 if (!self.enemy.waterlevel)
1085                         enemyvel_z = 0;
1086                 lag_additem(time + self.ping, 0, 0, self.enemy, self.origin, selfvel, self.enemy.origin, enemyvel);
1087         }
1088         else
1089                 lag_additem(time + self.ping, 0, 0, world, self.origin, selfvel, self.goalcurrent.origin, '0 0 0');
1090 };
1091
1092 float havocbot_moveto_refresh_route()
1093 {
1094         // Refresh path to goal if necessary
1095         entity wp;
1096         wp = self.havocbot_personal_waypoint;
1097         navigation_goalrating_start();
1098         navigation_routerating(wp, 10000, 10000);
1099         navigation_goalrating_end();
1100         return self.navigation_hasgoals;
1101 }
1102
1103 float havocbot_moveto(vector pos)
1104 {
1105         local entity wp;
1106
1107         if(self.aistatus & AI_STATUS_WAYPOINT_PERSONAL_GOING)
1108         {
1109                 // Step 4: Move to waypoint
1110                 if(self.havocbot_personal_waypoint==world)
1111                 {
1112                         dprint("Error: ", self.netname, " trying to walk to a non existent personal waypoint\n");
1113                         self.aistatus &~= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1114                         return CMD_STATUS_ERROR;
1115                 }
1116
1117                 if (!bot_strategytoken_taken)
1118                 if(self.havocbot_personal_waypoint_searchtime<time)
1119                 {
1120                         bot_strategytoken_taken = TRUE;
1121                         if(havocbot_moveto_refresh_route())
1122                         {
1123                                 dprint(self.netname, " walking to its personal waypoint (after ", ftos(self.havocbot_personal_waypoint_failcounter), " failed attempts)\n");
1124                                 self.havocbot_personal_waypoint_searchtime = time + 10;
1125                                 self.havocbot_personal_waypoint_failcounter = 0;
1126                         }
1127                         else
1128                         {
1129                                 self.havocbot_personal_waypoint_failcounter += 1;
1130                                 self.havocbot_personal_waypoint_searchtime = time + 2;
1131                                 if(self.havocbot_personal_waypoint_failcounter >= 30)
1132                                 {
1133                                         dprint("Warning: can't walk to the personal waypoint located at ", vtos(self.havocbot_personal_waypoint.origin),"\n");
1134                                         self.aistatus &~= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1135                                         remove(self.havocbot_personal_waypoint);
1136                                         return CMD_STATUS_ERROR;
1137                                 }
1138                                 else
1139                                         dprint(self.netname, " can't walk to its personal waypoint (after ", ftos(self.havocbot_personal_waypoint_failcounter), " failed attempts), trying later\n");
1140                         }
1141                 }
1142
1143                 if(autocvar_bot_debug_goalstack)
1144                         debuggoalstack();
1145
1146                 // Heading
1147                 local vector dir = self.goalcurrent.origin - (self.origin + self.view_ofs);
1148                 dir_z = 0;
1149                 bot_aimdir(dir, -1);
1150
1151                 // Go!
1152                 havocbot_movetogoal();
1153
1154                 if(self.aistatus & AI_STATUS_WAYPOINT_PERSONAL_REACHED)
1155                 {
1156                         // Step 5: Waypoint reached
1157                         dprint(self.netname, "'s personal waypoint reached\n");
1158                         remove(self.havocbot_personal_waypoint);
1159                         self.aistatus &~= AI_STATUS_WAYPOINT_PERSONAL_REACHED;
1160                         return CMD_STATUS_FINISHED;
1161                 }
1162
1163                 return CMD_STATUS_EXECUTING;
1164         }
1165
1166         // Step 2: Linking waypoint
1167         if(self.aistatus & AI_STATUS_WAYPOINT_PERSONAL_LINKING)
1168         {
1169                 // Wait until it is linked
1170                 if(!self.havocbot_personal_waypoint.wplinked)
1171                 {
1172                         dprint(self.netname, " waiting for personal waypoint to be linked\n");
1173                         return CMD_STATUS_EXECUTING;
1174                 }
1175
1176                 self.havocbot_personal_waypoint_searchtime = time; // so we set the route next frame
1177                 self.aistatus &~= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1178                 self.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_GOING;
1179
1180                 // Step 3: Route to waypoint
1181                 dprint(self.netname, " walking to its personal waypoint\n");
1182
1183                 return CMD_STATUS_EXECUTING;
1184         }
1185
1186         // Step 1: Spawning waypoint
1187         wp = waypoint_spawnpersonal(pos);
1188         if(wp==world)
1189         {
1190                 dprint("Error: Can't spawn personal waypoint at ",vtos(pos),"\n");
1191                 return CMD_STATUS_ERROR;
1192         }
1193
1194         self.havocbot_personal_waypoint = wp;
1195         self.havocbot_personal_waypoint_failcounter = 0;
1196         self.aistatus |= AI_STATUS_WAYPOINT_PERSONAL_LINKING;
1197
1198         // if pos is inside a teleport, then let's mark it as teleport waypoint
1199         entity head;
1200         for(head = world; (head = find(head, classname, "trigger_teleport")); )
1201         {
1202                 if(WarpZoneLib_BoxTouchesBrush(pos, pos, head, world))
1203                 {
1204                         wp.wpflags |= WAYPOINTFLAG_TELEPORT;
1205                         self.lastteleporttime = 0;
1206                 }
1207         }
1208
1209 /*
1210         if(wp.wpflags & WAYPOINTFLAG_TELEPORT)
1211                 print("routing to a teleporter\n");
1212         else
1213                 print("routing to a non-teleporter\n");
1214 */
1215
1216         return CMD_STATUS_EXECUTING;
1217 }
1218
1219 float havocbot_resetgoal()
1220 {
1221         navigation_clearroute();
1222         return CMD_STATUS_FINISHED;
1223 }
1224
1225 void havocbot_setupbot()
1226 {
1227         self.bot_ai = havocbot_ai;
1228         self.cmd_moveto = havocbot_moveto;
1229         self.cmd_resetgoal = havocbot_resetgoal;
1230
1231         havocbot_chooserole();
1232 }
1233
1234 vector havocbot_dodge()
1235 {
1236         // LordHavoc: disabled because this is too expensive
1237         return '0 0 0';
1238 #if 0
1239         local entity head;
1240         local vector dodge, v, n;
1241         local float danger, bestdanger, vl, d;
1242         dodge = '0 0 0';
1243         bestdanger = -20;
1244         // check for dangerous objects near bot or approaching bot
1245         head = findchainfloat(bot_dodge, TRUE);
1246         while(head)
1247         {
1248                 if (head.owner != self)
1249                 {
1250                         vl = vlen(head.velocity);
1251                         if (vl > autocvar_sv_maxspeed * 0.3)
1252                         {
1253                                 n = normalize(head.velocity);
1254                                 v = self.origin - head.origin;
1255                                 d = v * n;
1256                                 if (d > (0 - head.bot_dodgerating))
1257                                 if (d < (vl * 0.2 + head.bot_dodgerating))
1258                                 {
1259                                         // calculate direction and distance from the flight path, by removing the forward axis
1260                                         v = v - (n * (v * n));
1261                                         danger = head.bot_dodgerating - vlen(v);
1262                                         if (bestdanger < danger)
1263                                         {
1264                                                 bestdanger = danger;
1265                                                 // dodge to the side of the object
1266                                                 dodge = normalize(v);
1267                                         }
1268                                 }
1269                         }
1270                         else
1271                         {
1272                                 danger = head.bot_dodgerating - vlen(head.origin - self.origin);
1273                                 if (bestdanger < danger)
1274                                 {
1275                                         bestdanger = danger;
1276                                         dodge = normalize(self.origin - head.origin);
1277                                 }
1278                         }
1279                 }
1280                 head = head.chain;
1281         }
1282         return dodge;
1283 #endif
1284 };