qcsrc/server/bot/scripting.qc

   1 #include "scripting.qh"
   2
   3 #include "bot.qh"
   4
   5 .int state;
   6
   7 .float bot_cmdqueuebuf_allocated;
   8 .float bot_cmdqueuebuf;
   9 .float bot_cmdqueuebuf_start;
  10 .float bot_cmdqueuebuf_end;
  11
  12 void bot_clearqueue(entity bot)
  13 {
  14         if(!bot.bot_cmdqueuebuf_allocated)
  15                 return;
  16         buf_del(bot.bot_cmdqueuebuf);
  17         bot.bot_cmdqueuebuf_allocated = false;
  18         LOG_TRACE("bot ", bot.netname, " queue cleared\n");
  19 }
  20
  21 void bot_queuecommand(entity bot, string cmdstring)
  22 {
  23         if(!bot.bot_cmdqueuebuf_allocated)
  24         {
  25                 bot.bot_cmdqueuebuf = buf_create();
  26                 bot.bot_cmdqueuebuf_allocated = true;
  27                 bot.bot_cmdqueuebuf_start = 0;
  28                 bot.bot_cmdqueuebuf_end = 0;
  29         }
  30
  31         bufstr_set(bot.bot_cmdqueuebuf, bot.bot_cmdqueuebuf_end, cmdstring);
  32
  33         // if the command was a "sound" command, precache the sound NOW
  34         // this prevents lagging!
  35         {
  36                 float sp;
  37                 string parm;
  38                 string cmdstr;
  39
  40                 sp = strstrofs(cmdstring, " ", 0);
  41                 if(sp >= 0)
  42                 {
  43                         parm = substring(cmdstring, sp + 1, -1);
  44                         cmdstr = substring(cmdstring, 0, sp);
  45                         if(cmdstr == "sound")
  46                         {
  47                                 // find the LAST word
  48                                 for (;;)
  49                                 {
  50                                         sp = strstrofs(parm, " ", 0);
  51                                         if(sp < 0)
  52                                                 break;
  53                                         parm = substring(parm, sp + 1, -1);
  54                                 }
  55                                 precache_sound(parm);
  56                         }
  57                 }
  58         }
  59
  60         bot.bot_cmdqueuebuf_end += 1;
  61 }
  62
  63 void bot_dequeuecommand(entity bot, float idx)
  64 {
  65         if(!bot.bot_cmdqueuebuf_allocated)
  66                 error("dequeuecommand but no queue allocated");
  67         if(idx < bot.bot_cmdqueuebuf_start)
  68                 error("dequeueing a command in the past");
  69         if(idx >= bot.bot_cmdqueuebuf_end)
  70                 error("dequeueing a command in the future");
  71         bufstr_set(bot.bot_cmdqueuebuf, idx, "");
  72         if(idx == bot.bot_cmdqueuebuf_start)
  73                 bot.bot_cmdqueuebuf_start += 1;
  74         if(bot.bot_cmdqueuebuf_start >= bot.bot_cmdqueuebuf_end)
  75                 bot_clearqueue(bot);
  76 }
  77
  78 string bot_readcommand(entity bot, float idx)
  79 {
  80         if(!bot.bot_cmdqueuebuf_allocated)
  81                 error("readcommand but no queue allocated");
  82         if(idx < bot.bot_cmdqueuebuf_start)
  83                 error("reading a command in the past");
  84         if(idx >= bot.bot_cmdqueuebuf_end)
  85                 error("reading a command in the future");
  86         return bufstr_get(bot.bot_cmdqueuebuf, idx);
  87 }
  88
  89 float bot_havecommand(entity bot, float idx)
  90 {
  91         if(!bot.bot_cmdqueuebuf_allocated)
  92                 return 0;
  93         if(idx < bot.bot_cmdqueuebuf_start)
  94                 return 0;
  95         if(idx >= bot.bot_cmdqueuebuf_end)
  96                 return 0;
  97         return 1;
  98 }
  99
 100 const int MAX_BOT_PLACES = 4;
 101 .float bot_places_count;
 102 .entity bot_places[MAX_BOT_PLACES];
 103 .string bot_placenames[MAX_BOT_PLACES];
 104 entity bot_getplace(string placename)
 105 {SELFPARAM();
 106         entity e;
 107         if(substring(placename, 0, 1) == "@")
 108         {
 109                 int i, p;
 110                 placename = substring(placename, 1, -1);
 111                 string s, s2;
 112                 for(i = 0; i < self.bot_places_count; ++i)
 113                         if(self.(bot_placenames[i]) == placename)
 114                                 return self.(bot_places[i]);
 115                 // now: i == self.bot_places_count
 116                 s = s2 = cvar_string(placename);
 117                 p = strstrofs(s2, " ", 0);
 118                 if(p >= 0)
 119                 {
 120                         s = substring(s2, 0, p);
 121                         //print("places: ", placename, " -> ", cvar_string(placename), "\n");
 122                         cvar_set(placename, strcat(substring(s2, p+1, -1), " ", s));
 123                         //print("places: ", placename, " := ", cvar_string(placename), "\n");
 124                 }
 125                 e = find(world, targetname, s);
 126                 if(!e)
 127                         LOG_INFO("invalid place ", s, "\n");
 128                 if(i < MAX_BOT_PLACES)
 129                 {
 130                         self.(bot_placenames[i]) = strzone(placename);
 131                         self.(bot_places[i]) = e;
 132                         self.bot_places_count += 1;
 133                 }
 134                 return e;
 135         }
 136         else
 137         {
 138                 e = find(world, targetname, placename);
 139                 if(!e)
 140                         LOG_INFO("invalid place ", placename, "\n");
 141                 return e;
 142         }
 143 }
 144
 145
 146 // Initialize global commands list
 147 // NOTE: New commands should be initialized here
 148 void bot_commands_init()
 149 {
 150         bot_cmd_string[BOT_CMD_NULL] = "";
 151         bot_cmd_parm_type[BOT_CMD_NULL] = BOT_CMD_PARAMETER_NONE;
 152
 153         bot_cmd_string[BOT_CMD_PAUSE] = "pause";
 154         bot_cmd_parm_type[BOT_CMD_PAUSE] = BOT_CMD_PARAMETER_NONE;
 155
 156         bot_cmd_string[BOT_CMD_CONTINUE] = "continue";
 157         bot_cmd_parm_type[BOT_CMD_CONTINUE] = BOT_CMD_PARAMETER_NONE;
 158
 159         bot_cmd_string[BOT_CMD_WAIT] = "wait";
 160         bot_cmd_parm_type[BOT_CMD_WAIT] = BOT_CMD_PARAMETER_FLOAT;
 161
 162         bot_cmd_string[BOT_CMD_TURN] = "turn";
 163         bot_cmd_parm_type[BOT_CMD_TURN] = BOT_CMD_PARAMETER_FLOAT;
 164
 165         bot_cmd_string[BOT_CMD_MOVETO] = "moveto";
 166         bot_cmd_parm_type[BOT_CMD_MOVETO] = BOT_CMD_PARAMETER_VECTOR;
 167
 168         bot_cmd_string[BOT_CMD_MOVETOTARGET] = "movetotarget";
 169         bot_cmd_parm_type[BOT_CMD_MOVETOTARGET] = BOT_CMD_PARAMETER_STRING;
 170
 171         bot_cmd_string[BOT_CMD_RESETGOAL] = "resetgoal";
 172         bot_cmd_parm_type[BOT_CMD_RESETGOAL] = BOT_CMD_PARAMETER_NONE;
 173
 174         bot_cmd_string[BOT_CMD_CC] = "cc";
 175         bot_cmd_parm_type[BOT_CMD_CC] = BOT_CMD_PARAMETER_STRING;
 176
 177         bot_cmd_string[BOT_CMD_IF] = "if";
 178         bot_cmd_parm_type[BOT_CMD_IF] = BOT_CMD_PARAMETER_STRING;
 179
 180         bot_cmd_string[BOT_CMD_ELSE] = "else";
 181         bot_cmd_parm_type[BOT_CMD_ELSE] = BOT_CMD_PARAMETER_NONE;
 182
 183         bot_cmd_string[BOT_CMD_FI] = "fi";
 184         bot_cmd_parm_type[BOT_CMD_FI] = BOT_CMD_PARAMETER_NONE;
 185
 186         bot_cmd_string[BOT_CMD_RESETAIM] = "resetaim";
 187         bot_cmd_parm_type[BOT_CMD_RESETAIM] = BOT_CMD_PARAMETER_NONE;
 188
 189         bot_cmd_string[BOT_CMD_AIM] = "aim";
 190         bot_cmd_parm_type[BOT_CMD_AIM] = BOT_CMD_PARAMETER_STRING;
 191
 192         bot_cmd_string[BOT_CMD_AIMTARGET] = "aimtarget";
 193         bot_cmd_parm_type[BOT_CMD_AIMTARGET] = BOT_CMD_PARAMETER_STRING;
 194
 195         bot_cmd_string[BOT_CMD_PRESSKEY] = "presskey";
 196         bot_cmd_parm_type[BOT_CMD_PRESSKEY] = BOT_CMD_PARAMETER_STRING;
 197
 198         bot_cmd_string[BOT_CMD_RELEASEKEY] = "releasekey";
 199         bot_cmd_parm_type[BOT_CMD_RELEASEKEY] = BOT_CMD_PARAMETER_STRING;
 200
 201         bot_cmd_string[BOT_CMD_SELECTWEAPON] = "selectweapon";
 202         bot_cmd_parm_type[BOT_CMD_SELECTWEAPON] = BOT_CMD_PARAMETER_FLOAT;
 203
 204         bot_cmd_string[BOT_CMD_IMPULSE] = "impulse";
 205         bot_cmd_parm_type[BOT_CMD_IMPULSE] = BOT_CMD_PARAMETER_FLOAT;
 206
 207         bot_cmd_string[BOT_CMD_WAIT_UNTIL] = "wait_until";
 208         bot_cmd_parm_type[BOT_CMD_WAIT_UNTIL] = BOT_CMD_PARAMETER_FLOAT;
 209
 210         bot_cmd_string[BOT_CMD_BARRIER] = "barrier";
 211         bot_cmd_parm_type[BOT_CMD_BARRIER] = BOT_CMD_PARAMETER_NONE;
 212
 213         bot_cmd_string[BOT_CMD_CONSOLE] = "console";
 214         bot_cmd_parm_type[BOT_CMD_CONSOLE] = BOT_CMD_PARAMETER_STRING;
 215
 216         bot_cmd_string[BOT_CMD_SOUND] = "sound";
 217         bot_cmd_parm_type[BOT_CMD_SOUND] = BOT_CMD_PARAMETER_STRING;
 218
 219         bot_cmd_string[BOT_CMD_DEBUG_ASSERT_CANFIRE] = "debug_assert_canfire";
 220         bot_cmd_parm_type[BOT_CMD_DEBUG_ASSERT_CANFIRE] = BOT_CMD_PARAMETER_FLOAT;
 221
 222         bot_cmds_initialized = true;
 223 }
 224
 225 // Returns first bot with matching name
 226 entity find_bot_by_name(string name)
 227 {
 228         entity bot;
 229
 230         bot = findchainflags(flags, FL_CLIENT);
 231         while (bot)
 232         {
 233                 if(IS_BOT_CLIENT(bot))
 234                 if(bot.netname==name)
 235                         return bot;
 236
 237                 bot = bot.chain;
 238         }
 239
 240         return world;
 241 }
 242
 243 // Returns a bot by number on list
 244 entity find_bot_by_number(float number)
 245 {
 246         entity bot;
 247         float c = 0;
 248
 249         if(!number)
 250                 return world;
 251
 252         bot = findchainflags(flags, FL_CLIENT);
 253         while (bot)
 254         {
 255                 if(IS_BOT_CLIENT(bot))
 256                 {
 257                         if(++c==number)
 258                                 return bot;
 259                 }
 260                 bot = bot.chain;
 261         }
 262
 263         return world;
 264 }
 265
 266 float bot_decodecommand(string cmdstring)
 267 {
 268         float cmd_parm_type;
 269         float sp;
 270         string parm;
 271
 272         sp = strstrofs(cmdstring, " ", 0);
 273         if(sp < 0)
 274         {
 275                 parm = "";
 276         }
 277         else
 278         {
 279                 parm = substring(cmdstring, sp + 1, -1);
 280                 cmdstring = substring(cmdstring, 0, sp);
 281         }
 282
 283         if(!bot_cmds_initialized)
 284                 bot_commands_init();
 285
 286         int i;
 287         for(i=1;i<BOT_CMD_COUNTER;++i)
 288         {
 289                 if(bot_cmd_string[i]!=cmdstring)
 290                         continue;
 291
 292                 cmd_parm_type = bot_cmd_parm_type[i];
 293
 294                 if(cmd_parm_type!=BOT_CMD_PARAMETER_NONE&&parm=="")
 295                 {
 296                         LOG_INFO("ERROR: A parameter is required for this command\n");
 297                         return 0;
 298                 }
 299
 300                 // Load command into queue
 301                 bot_cmd.bot_cmd_type = i;
 302
 303                 // Attach parameter
 304                 switch(cmd_parm_type)
 305                 {
 306                         case BOT_CMD_PARAMETER_FLOAT:
 307                                 bot_cmd.bot_cmd_parm_float = stof(parm);
 308                                 break;
 309                         case BOT_CMD_PARAMETER_STRING:
 310                                 if(bot_cmd.bot_cmd_parm_string)
 311                                         strunzone(bot_cmd.bot_cmd_parm_string);
 312                                 bot_cmd.bot_cmd_parm_string = strzone(parm);
 313                                 break;
 314                         case BOT_CMD_PARAMETER_VECTOR:
 315                                 bot_cmd.bot_cmd_parm_vector = stov(parm);
 316                                 break;
 317                         default:
 318                                 break;
 319                 }
 320                 return 1;
 321         }
 322         LOG_INFO("ERROR: No such command '", cmdstring, "'\n");
 323         return 0;
 324 }
 325
 326 void bot_cmdhelp(string scmd)
 327 {
 328         int i, ntype;
 329         string stype;
 330
 331         if(!bot_cmds_initialized)
 332                 bot_commands_init();
 333
 334         for(i=1;i<BOT_CMD_COUNTER;++i)
 335         {
 336                 if(bot_cmd_string[i]!=scmd)
 337                         continue;
 338
 339                 ntype = bot_cmd_parm_type[i];
 340
 341                 switch(ntype)
 342                 {
 343                         case BOT_CMD_PARAMETER_FLOAT:
 344                                 stype = "float number";
 345                                 break;
 346                         case BOT_CMD_PARAMETER_STRING:
 347                                 stype = "string";
 348                                 break;
 349                         case BOT_CMD_PARAMETER_VECTOR:
 350                                 stype = "vector";
 351                                 break;
 352                         default:
 353                                 stype = "none";
 354                                 break;
 355                 }
 356
 357                 LOG_INFO(strcat("Command: ",bot_cmd_string[i],"\nParameter: <",stype,"> \n"));
 358
 359                 LOG_INFO("Description: ");
 360                 switch(i)
 361                 {
 362                         case BOT_CMD_PAUSE:
 363                                 LOG_INFO("Stops the bot completely. Any command other than 'continue' will be ignored.");
 364                                 break;
 365                         case BOT_CMD_CONTINUE:
 366                                 LOG_INFO("Disable paused status");
 367                                 break;
 368                         case BOT_CMD_WAIT:
 369                                 LOG_INFO("Pause command parsing and bot ai for N seconds. Pressed key will remain pressed");
 370                                 break;
 371                         case BOT_CMD_WAIT_UNTIL:
 372                                 LOG_INFO("Pause command parsing and bot ai until time is N from the last barrier. Pressed key will remain pressed");
 373                                 break;
 374                         case BOT_CMD_BARRIER:
 375                                 LOG_INFO("Waits till all bots that have a command queue reach this command. Pressed key will remain pressed");
 376                                 break;
 377                         case BOT_CMD_TURN:
 378                                 LOG_INFO("Look to the right or left N degrees. For turning to the left use positive numbers.");
 379                                 break;
 380                         case BOT_CMD_MOVETO:
 381                                 LOG_INFO("Walk to an specific coordinate on the map. Usage: moveto \"x y z\"");
 382                                 break;
 383                         case BOT_CMD_MOVETOTARGET:
 384                                 LOG_INFO("Walk to the specific target on the map");
 385                                 break;
 386                         case BOT_CMD_RESETGOAL:
 387                                 LOG_INFO("Resets the goal stack");
 388                                 break;
 389                         case BOT_CMD_CC:
 390                                 LOG_INFO("Execute client command. Examples: cc \"say something\"; cc god; cc \"name newnickname\"; cc kill;");
 391                                 break;
 392                         case BOT_CMD_IF:
 393                                 LOG_INFO("Perform simple conditional execution.\n");
 394                                 LOG_INFO("Syntax: \n");
 395                                 LOG_INFO("        sv_cmd .. if \"condition\"\n");
 396                                 LOG_INFO("        sv_cmd ..     <instruction if true>\n");
 397                                 LOG_INFO("        sv_cmd ..     <instruction if true>\n");
 398                                 LOG_INFO("        sv_cmd .. else\n");
 399                                 LOG_INFO("        sv_cmd ..     <instruction if false>\n");
 400                                 LOG_INFO("        sv_cmd ..     <instruction if false>\n");
 401                                 LOG_INFO("        sv_cmd .. fi\n");
 402                                 LOG_INFO("Conditions: a=b, a>b, a<b, a\t\t(spaces not allowed)\n");
 403                                 LOG_INFO("            Values in conditions can be numbers, cvars in the form cvar.cvar_string or special fields\n");
 404                                 LOG_INFO("Fields: health, speed, flagcarrier\n");
 405                                 LOG_INFO("Examples: if health>50; if health>cvar.g_balance_laser_primary_damage; if flagcarrier;");
 406                                 break;
 407                         case BOT_CMD_RESETAIM:
 408                                 LOG_INFO("Points the aim to the coordinates x,y 0,0");
 409                                 break;
 410                         case BOT_CMD_AIM:
 411                                 LOG_INFO("Move the aim x/y (horizontal/vertical) degrees relatives to the bot\n");
 412                                 LOG_INFO("There is a 3rd optional parameter telling in how many seconds the aim has to reach the new position\n");
 413                                 LOG_INFO("Examples: aim \"90 0\"        // Turn 90 degrees inmediately (positive numbers move to the left/up)\n");
 414                                 LOG_INFO("          aim \"0 90 2\"      // Will gradually look to the sky in the next two seconds");
 415                                 break;
 416                         case BOT_CMD_AIMTARGET:
 417                                 LOG_INFO("Points the aim to given target");
 418                                 break;
 419                         case BOT_CMD_PRESSKEY:
 420                                 LOG_INFO("Press one of the following keys: forward, backward, left, right, jump, crouch, attack1, attack2, use\n");
 421                                 LOG_INFO("Multiple keys can be pressed at time (with many presskey calls) and it will remain pressed until the command \"releasekey\" is called");
 422                                 LOG_INFO("Note: The script will not return the control to the bot ai until all keys are released");
 423                                 break;
 424                         case BOT_CMD_RELEASEKEY:
 425                                 LOG_INFO("Release previoulsy used keys. Use the parameter \"all\" to release all keys");
 426                                 break;
 427                         case BOT_CMD_SOUND:
 428                                 LOG_INFO("play sound file at bot location");
 429                                 break;
 430                         case BOT_CMD_DEBUG_ASSERT_CANFIRE:
 431                                 LOG_INFO("verify the state of the weapon entity");
 432                                 break;
 433                         default:
 434                                 LOG_INFO("This command has no description yet.");
 435                                 break;
 436                 }
 437                 LOG_INFO("\n");
 438         }
 439 }
 440
 441 void bot_list_commands()
 442 {
 443         int i;
 444         string ptype;
 445
 446         if(!bot_cmds_initialized)
 447                 bot_commands_init();
 448
 449         LOG_INFO("List of all available commands:\n");
 450         LOG_INFO("  Command - Parameter Type\n");
 451
 452         for(i=1;i<BOT_CMD_COUNTER;++i)
 453         {
 454                 switch(bot_cmd_parm_type[i])
 455                 {
 456                         case BOT_CMD_PARAMETER_FLOAT:
 457                                 ptype = "float number";
 458                                 break;
 459                         case BOT_CMD_PARAMETER_STRING:
 460                                 ptype = "string";
 461                                 break;
 462                         case BOT_CMD_PARAMETER_VECTOR:
 463                                 ptype = "vector";
 464                                 break;
 465                         default:
 466                                 ptype = "none";
 467                                 break;
 468                 }
 469                 LOG_INFO(strcat("  ",bot_cmd_string[i]," - <",ptype,"> \n"));
 470         }
 471 }
 472
 473 // Commands code
 474 .int bot_exec_status;
 475
 476 void SV_ParseClientCommand(string s);
 477 float bot_cmd_cc()
 478 {
 479         SV_ParseClientCommand(bot_cmd.bot_cmd_parm_string);
 480         return CMD_STATUS_FINISHED;
 481 }
 482
 483 float bot_cmd_impulse()
 484 {SELFPARAM();
 485         self.impulse = bot_cmd.bot_cmd_parm_float;
 486         return CMD_STATUS_FINISHED;
 487 }
 488
 489 float bot_cmd_continue()
 490 {SELFPARAM();
 491         self.bot_exec_status &= ~BOT_EXEC_STATUS_PAUSED;
 492         return CMD_STATUS_FINISHED;
 493 }
 494
 495 .float bot_cmd_wait_time;
 496 float bot_cmd_wait()
 497 {SELFPARAM();
 498         if(self.bot_exec_status & BOT_EXEC_STATUS_WAITING)
 499         {
 500                 if(time>=self.bot_cmd_wait_time)
 501                 {
 502                         self.bot_exec_status &= ~BOT_EXEC_STATUS_WAITING;
 503                         return CMD_STATUS_FINISHED;
 504                 }
 505                 else
 506                         return CMD_STATUS_EXECUTING;
 507         }
 508
 509         self.bot_cmd_wait_time = time + bot_cmd.bot_cmd_parm_float;
 510         self.bot_exec_status |= BOT_EXEC_STATUS_WAITING;
 511         return CMD_STATUS_EXECUTING;
 512 }
 513
 514 float bot_cmd_wait_until()
 515 {SELFPARAM();
 516         if(time < bot_cmd.bot_cmd_parm_float + bot_barriertime)
 517         {
 518                 self.bot_exec_status |= BOT_EXEC_STATUS_WAITING;
 519                 return CMD_STATUS_EXECUTING;
 520         }
 521         self.bot_exec_status &= ~BOT_EXEC_STATUS_WAITING;
 522         return CMD_STATUS_FINISHED;
 523 }
 524
 525 float bot_cmd_barrier()
 526 {SELFPARAM();
 527         entity cl;
 528
 529         // 0 = no barrier, 1 = waiting, 2 = waiting finished
 530
 531         if(self.bot_barrier == 0) // initialization
 532         {
 533                 self.bot_barrier = 1;
 534
 535                 //self.colormod = '4 4 0';
 536         }
 537
 538         if(self.bot_barrier == 1) // find other bots
 539         {
 540                 FOR_EACH_CLIENT(cl) if(cl.isbot)
 541                 {
 542                         if(cl.bot_cmdqueuebuf_allocated)
 543                                 if(cl.bot_barrier != 1)
 544                                         return CMD_STATUS_EXECUTING; // not all are at the barrier yet
 545                 }
 546
 547                 // all bots hit the barrier!
 548                 FOR_EACH_CLIENT(cl) if(cl.isbot)
 549                 {
 550                         cl.bot_barrier = 2; // acknowledge barrier
 551                 }
 552
 553                 bot_barriertime = time;
 554         }
 555
 556         // if we get here, the barrier is finished
 557         // so end it...
 558         self.bot_barrier = 0;
 559         //self.colormod = '0 0 0';
 560
 561         return CMD_STATUS_FINISHED;
 562 }
 563
 564 float bot_cmd_turn()
 565 {SELFPARAM();
 566         self.v_angle_y = self.v_angle.y + bot_cmd.bot_cmd_parm_float;
 567         self.v_angle_y = self.v_angle.y - floor(self.v_angle.y / 360) * 360;
 568         return CMD_STATUS_FINISHED;
 569 }
 570
 571 float bot_cmd_select_weapon()
 572 {SELFPARAM();
 573         float id = bot_cmd.bot_cmd_parm_float;
 574
 575         if(id < WEP_FIRST || id > WEP_LAST)
 576                 return CMD_STATUS_ERROR;
 577
 578         if(client_hasweapon(self, Weapons_from(id), true, false))
 579                 self.switchweapon = id;
 580         else
 581                 return CMD_STATUS_ERROR;
 582
 583         return CMD_STATUS_FINISHED;
 584 }
 585
 586 .int bot_cmd_condition_status;
 587
 588 const int CMD_CONDITION_NONE = 0;
 589 const int CMD_CONDITION_true = 1;
 590 const int CMD_CONDITION_false = 2;
 591 const int CMD_CONDITION_true_BLOCK = 4;
 592 const int CMD_CONDITION_false_BLOCK = 8;
 593
 594 float bot_cmd_eval(string expr)
 595 {SELFPARAM();
 596         // Search for numbers
 597         if(strstrofs("0123456789", substring(expr, 0, 1), 0) >= 0)
 598         {
 599                 return stof(expr);
 600         }
 601
 602         // Search for cvars
 603         if(substring(expr, 0, 5)=="cvar.")
 604         {
 605                 return cvar(substring(expr, 5, strlen(expr)));
 606         }
 607
 608         // Search for fields
 609         switch(expr)
 610         {
 611                 case "health":
 612                         return self.health;
 613                 case "speed":
 614                         return vlen(self.velocity);
 615                 case "flagcarrier":
 616                         return ((self.flagcarried!=world));
 617         }
 618
 619         LOG_INFO(strcat("ERROR: Unable to convert the expression '",expr,"' into a numeric value\n"));
 620         return 0;
 621 }
 622
 623 float bot_cmd_if()
 624 {SELFPARAM();
 625         string expr, val_a, val_b;
 626         float cmpofs;
 627
 628         if(self.bot_cmd_condition_status != CMD_CONDITION_NONE)
 629         {
 630                 // Only one "if" block is allowed at time
 631                 LOG_INFO("ERROR: Only one conditional block can be processed at time");
 632                 bot_clearqueue(self);
 633                 return CMD_STATUS_ERROR;
 634         }
 635
 636         self.bot_cmd_condition_status |= CMD_CONDITION_true_BLOCK;
 637
 638         // search for operators
 639         expr = bot_cmd.bot_cmd_parm_string;
 640
 641         cmpofs = strstrofs(expr,"=",0);
 642
 643         if(cmpofs>0)
 644         {
 645                 val_a = substring(expr,0,cmpofs);
 646                 val_b = substring(expr,cmpofs+1,strlen(expr));
 647
 648                 if(bot_cmd_eval(val_a)==bot_cmd_eval(val_b))
 649                         self.bot_cmd_condition_status |= CMD_CONDITION_true;
 650                 else
 651                         self.bot_cmd_condition_status |= CMD_CONDITION_false;
 652
 653                 return CMD_STATUS_FINISHED;
 654         }
 655
 656         cmpofs = strstrofs(expr,">",0);
 657
 658         if(cmpofs>0)
 659         {
 660                 val_a = substring(expr,0,cmpofs);
 661                 val_b = substring(expr,cmpofs+1,strlen(expr));
 662
 663                 if(bot_cmd_eval(val_a)>bot_cmd_eval(val_b))
 664                         self.bot_cmd_condition_status |= CMD_CONDITION_true;
 665                 else
 666                         self.bot_cmd_condition_status |= CMD_CONDITION_false;
 667
 668                 return CMD_STATUS_FINISHED;
 669         }
 670
 671         cmpofs = strstrofs(expr,"<",0);
 672
 673         if(cmpofs>0)
 674         {
 675                 val_a = substring(expr,0,cmpofs);
 676                 val_b = substring(expr,cmpofs+1,strlen(expr));
 677
 678                 if(bot_cmd_eval(val_a)<bot_cmd_eval(val_b))
 679                         self.bot_cmd_condition_status |= CMD_CONDITION_true;
 680                 else
 681                         self.bot_cmd_condition_status |= CMD_CONDITION_false;
 682
 683                 return CMD_STATUS_FINISHED;
 684         }
 685
 686         if(bot_cmd_eval(expr))
 687                 self.bot_cmd_condition_status |= CMD_CONDITION_true;
 688         else
 689                 self.bot_cmd_condition_status |= CMD_CONDITION_false;
 690
 691         return CMD_STATUS_FINISHED;
 692 }
 693
 694 float bot_cmd_else()
 695 {SELFPARAM();
 696         self.bot_cmd_condition_status &= ~CMD_CONDITION_true_BLOCK;
 697         self.bot_cmd_condition_status |= CMD_CONDITION_false_BLOCK;
 698         return CMD_STATUS_FINISHED;
 699 }
 700
 701 float bot_cmd_fi()
 702 {SELFPARAM();
 703         self.bot_cmd_condition_status = CMD_CONDITION_NONE;
 704         return CMD_STATUS_FINISHED;
 705 }
 706
 707 float bot_cmd_resetaim()
 708 {SELFPARAM();
 709         self.v_angle = '0 0 0';
 710         return CMD_STATUS_FINISHED;
 711 }
 712
 713 .float bot_cmd_aim_begintime;
 714 .float bot_cmd_aim_endtime;
 715 .vector bot_cmd_aim_begin;
 716 .vector bot_cmd_aim_end;
 717
 718 float bot_cmd_aim()
 719 {SELFPARAM();
 720         // Current direction
 721         if(self.bot_cmd_aim_endtime)
 722         {
 723                 float progress;
 724
 725                 progress = min(1 - (self.bot_cmd_aim_endtime - time) / (self.bot_cmd_aim_endtime - self.bot_cmd_aim_begintime),1);
 726                 self.v_angle = self.bot_cmd_aim_begin + ((self.bot_cmd_aim_end - self.bot_cmd_aim_begin) * progress);
 727
 728                 if(time>=self.bot_cmd_aim_endtime)
 729                 {
 730                         self.bot_cmd_aim_endtime = 0;
 731                         return CMD_STATUS_FINISHED;
 732                 }
 733                 else
 734                         return CMD_STATUS_EXECUTING;
 735         }
 736
 737         // New aiming direction
 738         string parms;
 739         float tokens, step;
 740
 741         parms = bot_cmd.bot_cmd_parm_string;
 742
 743         tokens = tokenizebyseparator(parms, " ");
 744
 745         if(tokens<2||tokens>3)
 746                 return CMD_STATUS_ERROR;
 747
 748         step = (tokens == 3) ? stof(argv(2)) : 0;
 749
 750         if(step == 0)
 751         {
 752                 self.v_angle_x -= stof(argv(1));
 753                 self.v_angle_y += stof(argv(0));
 754                 return CMD_STATUS_FINISHED;
 755         }
 756
 757         self.bot_cmd_aim_begin = self.v_angle;
 758
 759         self.bot_cmd_aim_end_x = self.v_angle.x - stof(argv(1));
 760         self.bot_cmd_aim_end_y = self.v_angle.y + stof(argv(0));
 761         self.bot_cmd_aim_end_z = 0;
 762
 763         self.bot_cmd_aim_begintime = time;
 764         self.bot_cmd_aim_endtime = time + step;
 765
 766         return CMD_STATUS_EXECUTING;
 767 }
 768
 769 float bot_cmd_aimtarget()
 770 {SELFPARAM();
 771         if(self.bot_cmd_aim_endtime)
 772         {
 773                 return bot_cmd_aim();
 774         }
 775
 776         entity e;
 777         string parms;
 778         vector v;
 779         float tokens, step;
 780
 781         parms = bot_cmd.bot_cmd_parm_string;
 782
 783         tokens = tokenizebyseparator(parms, " ");
 784
 785         e = bot_getplace(argv(0));
 786         if(!e)
 787                 return CMD_STATUS_ERROR;
 788
 789         v = e.origin + (e.mins + e.maxs) * 0.5;
 790
 791         if(tokens==1)
 792         {
 793                 self.v_angle = vectoangles(v - (self.origin + self.view_ofs));
 794                 self.v_angle_x = -self.v_angle.x;
 795                 return CMD_STATUS_FINISHED;
 796         }
 797
 798         if(tokens<1||tokens>2)
 799                 return CMD_STATUS_ERROR;
 800
 801         step = stof(argv(1));
 802
 803         self.bot_cmd_aim_begin = self.v_angle;
 804         self.bot_cmd_aim_end = vectoangles(v - (self.origin + self.view_ofs));
 805         self.bot_cmd_aim_end_x = -self.bot_cmd_aim_end.x;
 806
 807         self.bot_cmd_aim_begintime = time;
 808         self.bot_cmd_aim_endtime = time + step;
 809
 810         return CMD_STATUS_EXECUTING;
 811 }
 812
 813 .int bot_cmd_keys;
 814
 815 const int BOT_CMD_KEY_NONE              = 0;
 816 const int BOT_CMD_KEY_FORWARD   = BIT(0);
 817 const int BOT_CMD_KEY_BACKWARD  = BIT(1);
 818 const int BOT_CMD_KEY_RIGHT     = BIT(2);
 819 const int BOT_CMD_KEY_LEFT              = BIT(3);
 820 const int BOT_CMD_KEY_JUMP              = BIT(4);
 821 const int BOT_CMD_KEY_ATTACK1   = BIT(5);
 822 const int BOT_CMD_KEY_ATTACK2   = BIT(6);
 823 const int BOT_CMD_KEY_USE               = BIT(7);
 824 const int BOT_CMD_KEY_HOOK              = BIT(8);
 825 const int BOT_CMD_KEY_CROUCH    = BIT(9);
 826 const int BOT_CMD_KEY_CHAT              = BIT(10);
 827
 828 float bot_presskeys()
 829 {SELFPARAM();
 830         self.movement = '0 0 0';
 831         self.BUTTON_JUMP = false;
 832         self.BUTTON_CROUCH = false;
 833         self.BUTTON_ATCK = false;
 834         self.BUTTON_ATCK2 = false;
 835         self.BUTTON_USE = false;
 836         self.BUTTON_HOOK = false;
 837         self.BUTTON_CHAT = false;
 838
 839         if(self.bot_cmd_keys == BOT_CMD_KEY_NONE)
 840                 return false;
 841
 842         if(self.bot_cmd_keys & BOT_CMD_KEY_FORWARD)
 843                 self.movement_x = autocvar_sv_maxspeed;
 844         else if(self.bot_cmd_keys & BOT_CMD_KEY_BACKWARD)
 845                 self.movement_x = -autocvar_sv_maxspeed;
 846
 847         if(self.bot_cmd_keys & BOT_CMD_KEY_RIGHT)
 848                 self.movement_y = autocvar_sv_maxspeed;
 849         else if(self.bot_cmd_keys & BOT_CMD_KEY_LEFT)
 850                 self.movement_y = -autocvar_sv_maxspeed;
 851
 852         if(self.bot_cmd_keys & BOT_CMD_KEY_JUMP)
 853                 self.BUTTON_JUMP = true;
 854
 855         if(self.bot_cmd_keys & BOT_CMD_KEY_CROUCH)
 856                 self.BUTTON_CROUCH = true;
 857
 858         if(self.bot_cmd_keys & BOT_CMD_KEY_ATTACK1)
 859                 self.BUTTON_ATCK = true;
 860
 861         if(self.bot_cmd_keys & BOT_CMD_KEY_ATTACK2)
 862                 self.BUTTON_ATCK2 = true;
 863
 864         if(self.bot_cmd_keys & BOT_CMD_KEY_USE)
 865                 self.BUTTON_USE = true;
 866
 867         if(self.bot_cmd_keys & BOT_CMD_KEY_HOOK)
 868                 self.BUTTON_HOOK = true;
 869
 870         if(self.bot_cmd_keys & BOT_CMD_KEY_CHAT)
 871                 self.BUTTON_CHAT = true;
 872
 873         return true;
 874 }
 875
 876
 877 float bot_cmd_keypress_handler(string key, float enabled)
 878 {SELFPARAM();
 879         switch(key)
 880         {
 881                 case "all":
 882                         if(enabled)
 883                                 self.bot_cmd_keys = power2of(20) - 1; // >:)
 884                         else
 885                                 self.bot_cmd_keys = BOT_CMD_KEY_NONE;
 886                 case "forward":
 887                         if(enabled)
 888                         {
 889                                 self.bot_cmd_keys |= BOT_CMD_KEY_FORWARD;
 890                                 self.bot_cmd_keys &= ~BOT_CMD_KEY_BACKWARD;
 891                         }
 892                         else
 893                                 self.bot_cmd_keys &= ~BOT_CMD_KEY_FORWARD;
 894                         break;
 895                 case "backward":
 896                         if(enabled)
 897                         {
 898                                 self.bot_cmd_keys |= BOT_CMD_KEY_BACKWARD;
 899                                 self.bot_cmd_keys &= ~BOT_CMD_KEY_FORWARD;
 900                         }
 901                         else
 902                                 self.bot_cmd_keys &= ~BOT_CMD_KEY_BACKWARD;
 903                         break;
 904                 case "left":
 905                         if(enabled)
 906                         {
 907                                 self.bot_cmd_keys |= BOT_CMD_KEY_LEFT;
 908                                 self.bot_cmd_keys &= ~BOT_CMD_KEY_RIGHT;
 909                         }
 910                         else
 911                                 self.bot_cmd_keys &= ~BOT_CMD_KEY_LEFT;
 912                         break;
 913                 case "right":
 914                         if(enabled)
 915                         {
 916                                 self.bot_cmd_keys |= BOT_CMD_KEY_RIGHT;
 917                                 self.bot_cmd_keys &= ~BOT_CMD_KEY_LEFT;
 918                         }
 919                         else
 920                                 self.bot_cmd_keys &= ~BOT_CMD_KEY_RIGHT;
 921                         break;
 922                 case "jump":
 923                         if(enabled)
 924                                 self.bot_cmd_keys |= BOT_CMD_KEY_JUMP;
 925                         else
 926                                 self.bot_cmd_keys &= ~BOT_CMD_KEY_JUMP;
 927                         break;
 928                 case "crouch":
 929                         if(enabled)
 930                                 self.bot_cmd_keys |= BOT_CMD_KEY_CROUCH;
 931                         else
 932                                 self.bot_cmd_keys &= ~BOT_CMD_KEY_CROUCH;
 933                         break;
 934                 case "attack1":
 935                         if(enabled)
 936                                 self.bot_cmd_keys |= BOT_CMD_KEY_ATTACK1;
 937                         else
 938                                 self.bot_cmd_keys &= ~BOT_CMD_KEY_ATTACK1;
 939                         break;
 940                 case "attack2":
 941                         if(enabled)
 942                                 self.bot_cmd_keys |= BOT_CMD_KEY_ATTACK2;
 943                         else
 944                                 self.bot_cmd_keys &= ~BOT_CMD_KEY_ATTACK2;
 945                         break;
 946                 case "use":
 947                         if(enabled)
 948                                 self.bot_cmd_keys |= BOT_CMD_KEY_USE;
 949                         else
 950                                 self.bot_cmd_keys &= ~BOT_CMD_KEY_USE;
 951                         break;
 952                 case "hook":
 953                         if(enabled)
 954                                 self.bot_cmd_keys |= BOT_CMD_KEY_HOOK;
 955                         else
 956                                 self.bot_cmd_keys &= ~BOT_CMD_KEY_HOOK;
 957                         break;
 958                 case "chat":
 959                         if(enabled)
 960                                 self.bot_cmd_keys |= BOT_CMD_KEY_CHAT;
 961                         else
 962                                 self.bot_cmd_keys &= ~BOT_CMD_KEY_CHAT;
 963                         break;
 964                 default:
 965                         break;
 966         }
 967
 968         return CMD_STATUS_FINISHED;
 969 }
 970
 971 float bot_cmd_presskey()
 972 {
 973         string key;
 974
 975         key = bot_cmd.bot_cmd_parm_string;
 976
 977         bot_cmd_keypress_handler(key,true);
 978
 979         return CMD_STATUS_FINISHED;
 980 }
 981
 982 float bot_cmd_releasekey()
 983 {
 984         string key;
 985
 986         key = bot_cmd.bot_cmd_parm_string;
 987
 988         return bot_cmd_keypress_handler(key,false);
 989 }
 990
 991 float bot_cmd_pause()
 992 {SELFPARAM();
 993         self.button1        = 0;
 994         self.button8        = 0;
 995         self.BUTTON_USE     = 0;
 996         self.BUTTON_ATCK    = 0;
 997         self.BUTTON_JUMP    = 0;
 998         self.BUTTON_HOOK    = 0;
 999         self.BUTTON_CHAT    = 0;
1000         self.BUTTON_ATCK2   = 0;
1001         self.BUTTON_CROUCH  = 0;
1002
1003         self.movement = '0 0 0';
1004         self.bot_cmd_keys = BOT_CMD_KEY_NONE;
1005
1006         self.bot_exec_status |= BOT_EXEC_STATUS_PAUSED;
1007         return CMD_STATUS_FINISHED;
1008 }
1009
1010 float bot_cmd_moveto()
1011 {SELFPARAM();
1012         return self.cmd_moveto(bot_cmd.bot_cmd_parm_vector);
1013 }
1014
1015 float bot_cmd_movetotarget()
1016 {SELFPARAM();
1017         entity e;
1018         e = bot_getplace(bot_cmd.bot_cmd_parm_string);
1019         if(!e)
1020                 return CMD_STATUS_ERROR;
1021         return self.cmd_moveto(e.origin + (e.mins + e.maxs) * 0.5);
1022 }
1023
1024 float bot_cmd_resetgoal()
1025 {SELFPARAM();
1026         return self.cmd_resetgoal();
1027 }
1028
1029
1030 float bot_cmd_sound()
1031 {SELFPARAM();
1032         string f;
1033         f = bot_cmd.bot_cmd_parm_string;
1034
1035         float n = tokenizebyseparator(f, " ");
1036
1037         string sample = f;
1038         float chan = CH_WEAPON_B;
1039         float vol = VOL_BASE;
1040         float atten = ATTEN_MIN;
1041
1042         if(n >= 1)
1043                 sample = argv(n - 1);
1044         if(n >= 2)
1045                 chan = stof(argv(0));
1046         if(n >= 3)
1047                 vol = stof(argv(1));
1048         if(n >= 4)
1049                 atten = stof(argv(2));
1050
1051         precache_sound(f);
1052         _sound(self, chan, sample, vol, atten);
1053
1054         return CMD_STATUS_FINISHED;
1055 }
1056
1057 .entity tuba_note;
1058 float bot_cmd_debug_assert_canfire()
1059 {SELFPARAM();
1060         float f = bot_cmd.bot_cmd_parm_float;
1061
1062         int slot = 0;
1063         .entity weaponentity = weaponentities[slot];
1064         if(self.(weaponentity).state != WS_READY)
1065         {
1066                 if(f)
1067                 {
1068                         self.colormod = '0 8 8';
1069                         LOG_INFO("Bot ", self.netname, " using ", self.weaponname, " wants to fire, inhibited by weaponentity state\n");
1070                 }
1071         }
1072         else if(ATTACK_FINISHED(self, slot) > time)
1073         {
1074                 if(f)
1075                 {
1076                         self.colormod = '8 0 8';
1077                         LOG_INFO("Bot ", self.netname, " using ", self.weaponname, " wants to fire, inhibited by ATTACK_FINISHED (", ftos(ATTACK_FINISHED(self, slot) - time), " seconds left)\n");
1078                 }
1079         }
1080         else if(self.tuba_note)
1081         {
1082                 if(f)
1083                 {
1084                         self.colormod = '8 0 0';
1085                         LOG_INFO("Bot ", self.netname, " using ", self.weaponname, " wants to fire, bot still has an active tuba note\n");
1086                 }
1087         }
1088         else
1089         {
1090                 if(!f)
1091                 {
1092                         self.colormod = '8 8 0';
1093                         LOG_INFO("Bot ", self.netname, " using ", self.weaponname, " thinks it has fired, but apparently did not; ATTACK_FINISHED says ", ftos(ATTACK_FINISHED(self, slot) - time), " seconds left\n");
1094                 }
1095         }
1096
1097         return CMD_STATUS_FINISHED;
1098 }
1099
1100 //
1101
1102 void bot_command_executed(float rm)
1103 {SELFPARAM();
1104         entity cmd;
1105
1106         cmd = bot_cmd;
1107
1108         if(rm)
1109                 bot_dequeuecommand(self, self.bot_cmd_execution_index);
1110
1111         self.bot_cmd_execution_index++;
1112 }
1113
1114 void bot_setcurrentcommand()
1115 {SELFPARAM();
1116         bot_cmd = world;
1117
1118         if(!self.bot_cmd_current)
1119         {
1120                 self.bot_cmd_current = new(bot_cmd);
1121                 self.bot_cmd_current.is_bot_cmd = true;
1122         }
1123
1124         bot_cmd = self.bot_cmd_current;
1125         if(bot_cmd.bot_cmd_index != self.bot_cmd_execution_index || self.bot_cmd_execution_index == 0)
1126         {
1127                 if(bot_havecommand(self, self.bot_cmd_execution_index))
1128                 {
1129                         string cmdstring;
1130                         cmdstring = bot_readcommand(self, self.bot_cmd_execution_index);
1131                         if(bot_decodecommand(cmdstring))
1132                         {
1133                                 bot_cmd.owner = self;
1134                                 bot_cmd.bot_cmd_index = self.bot_cmd_execution_index;
1135                         }
1136                         else
1137                         {
1138                                 // Invalid command, remove from queue
1139                                 bot_cmd = world;
1140                                 bot_dequeuecommand(self, self.bot_cmd_execution_index);
1141                                 self.bot_cmd_execution_index++;
1142                         }
1143                 }
1144                 else
1145                         bot_cmd = world;
1146         }
1147 }
1148
1149 void bot_resetqueues()
1150 {
1151         entity cl;
1152
1153         FOR_EACH_CLIENT(cl) if(cl.isbot)
1154         {
1155                 cl.bot_cmd_execution_index = 0;
1156                 bot_clearqueue(cl);
1157                 // also, cancel all barriers
1158                 cl.bot_barrier = 0;
1159                 for(int i = 0; i < cl.bot_places_count; ++i)
1160                 {
1161                         strunzone(cl.(bot_placenames[i]));
1162                         cl.(bot_placenames[i]) = string_null;
1163                 }
1164                 cl.bot_places_count = 0;
1165         }
1166
1167         bot_barriertime = time;
1168 }
1169
1170 // Here we map commands to functions and deal with complex interactions between commands and execution states
1171 // NOTE: Of course you need to include your commands here too :)
1172 float bot_execute_commands_once()
1173 {SELFPARAM();
1174         float status, ispressingkey;
1175
1176         // Find command
1177         bot_setcurrentcommand();
1178
1179         // if we have no bot command, better return
1180         // old logic kept pressing previously pressed keys, but that has problems
1181         // (namely, it means you cannot make a bot "normal" ever again)
1182         // to keep a bot walking for a while, use the "wait" bot command
1183         if(bot_cmd == world)
1184                 return false;
1185
1186         // Ignore all commands except continue when the bot is paused
1187         if(self.bot_exec_status & BOT_EXEC_STATUS_PAUSED)
1188         if(bot_cmd.bot_cmd_type!=BOT_CMD_CONTINUE)
1189         {
1190                 if(bot_cmd.bot_cmd_type!=BOT_CMD_NULL)
1191                 {
1192                         bot_command_executed(true);
1193                         LOG_INFO( "WARNING: Commands are ignored while the bot is paused. Use the command 'continue' instead.\n");
1194                 }
1195                 return 1;
1196         }
1197
1198         // Keep pressing keys raised by the "presskey" command
1199         ispressingkey = boolean(bot_presskeys());
1200
1201         // Handle conditions
1202         if (!(bot_cmd.bot_cmd_type==BOT_CMD_FI||bot_cmd.bot_cmd_type==BOT_CMD_ELSE))
1203         if(self.bot_cmd_condition_status & CMD_CONDITION_true && self.bot_cmd_condition_status & CMD_CONDITION_false_BLOCK)
1204         {
1205                 bot_command_executed(true);
1206                 return -1;
1207         }
1208         else if(self.bot_cmd_condition_status & CMD_CONDITION_false && self.bot_cmd_condition_status & CMD_CONDITION_true_BLOCK)
1209         {
1210                 bot_command_executed(true);
1211                 return -1;
1212         }
1213
1214         // Map commands to functions
1215         switch(bot_cmd.bot_cmd_type)
1216         {
1217                 case BOT_CMD_NULL:
1218                         return ispressingkey;
1219                         //break;
1220                 case BOT_CMD_PAUSE:
1221                         status = bot_cmd_pause();
1222                         break;
1223                 case BOT_CMD_CONTINUE:
1224                         status = bot_cmd_continue();
1225                         break;
1226                 case BOT_CMD_WAIT:
1227                         status = bot_cmd_wait();
1228                         break;
1229                 case BOT_CMD_WAIT_UNTIL:
1230                         status = bot_cmd_wait_until();
1231                         break;
1232                 case BOT_CMD_TURN:
1233                         status = bot_cmd_turn();
1234                         break;
1235                 case BOT_CMD_MOVETO:
1236                         status = bot_cmd_moveto();
1237                         break;
1238                 case BOT_CMD_MOVETOTARGET:
1239                         status = bot_cmd_movetotarget();
1240                         break;
1241                 case BOT_CMD_RESETGOAL:
1242                         status = bot_cmd_resetgoal();
1243                         break;
1244                 case BOT_CMD_CC:
1245                         status = bot_cmd_cc();
1246                         break;
1247                 case BOT_CMD_IF:
1248                         status = bot_cmd_if();
1249                         break;
1250                 case BOT_CMD_ELSE:
1251                         status = bot_cmd_else();
1252                         break;
1253                 case BOT_CMD_FI:
1254                         status = bot_cmd_fi();
1255                         break;
1256                 case BOT_CMD_RESETAIM:
1257                         status = bot_cmd_resetaim();
1258                         break;
1259                 case BOT_CMD_AIM:
1260                         status = bot_cmd_aim();
1261                         break;
1262                 case BOT_CMD_AIMTARGET:
1263                         status = bot_cmd_aimtarget();
1264                         break;
1265                 case BOT_CMD_PRESSKEY:
1266                         status = bot_cmd_presskey();
1267                         break;
1268                 case BOT_CMD_RELEASEKEY:
1269                         status = bot_cmd_releasekey();
1270                         break;
1271                 case BOT_CMD_SELECTWEAPON:
1272                         status = bot_cmd_select_weapon();
1273                         break;
1274                 case BOT_CMD_IMPULSE:
1275                         status = bot_cmd_impulse();
1276                         break;
1277                 case BOT_CMD_BARRIER:
1278                         status = bot_cmd_barrier();
1279                         break;
1280                 case BOT_CMD_CONSOLE:
1281                         localcmd(strcat(bot_cmd.bot_cmd_parm_string, "\n"));
1282                         status = CMD_STATUS_FINISHED;
1283                         break;
1284                 case BOT_CMD_SOUND:
1285                         status = bot_cmd_sound();
1286                         break;
1287                 case BOT_CMD_DEBUG_ASSERT_CANFIRE:
1288                         status = bot_cmd_debug_assert_canfire();
1289                         break;
1290                 default:
1291                         LOG_INFO(strcat("ERROR: Invalid command on queue with id '",ftos(bot_cmd.bot_cmd_type),"'\n"));
1292                         return 0;
1293         }
1294
1295         if (status==CMD_STATUS_ERROR)
1296                 LOG_INFO(strcat("ERROR: The command '",bot_cmd_string[bot_cmd.bot_cmd_type],"' returned an error status\n"));
1297
1298         // Move execution pointer
1299         if(status==CMD_STATUS_EXECUTING)
1300         {
1301                 return 1;
1302         }
1303         else
1304         {
1305                 if(autocvar_g_debug_bot_commands)
1306                 {
1307                         string parms;
1308
1309                         switch(bot_cmd_parm_type[bot_cmd.bot_cmd_type])
1310                         {
1311                                 case BOT_CMD_PARAMETER_FLOAT:
1312                                         parms = ftos(bot_cmd.bot_cmd_parm_float);
1313                                         break;
1314                                 case BOT_CMD_PARAMETER_STRING:
1315                                         parms = bot_cmd.bot_cmd_parm_string;
1316                                         break;
1317                                 case BOT_CMD_PARAMETER_VECTOR:
1318                                         parms = vtos(bot_cmd.bot_cmd_parm_vector);
1319                                         break;
1320                                 default:
1321                                         parms = "";
1322                                         break;
1323                         }
1324                         clientcommand(self,strcat("say ^7", bot_cmd_string[bot_cmd.bot_cmd_type]," ",parms,"\n"));
1325                 }
1326
1327                 bot_command_executed(true);
1328         }
1329
1330         if(status == CMD_STATUS_FINISHED)
1331                 return -1;
1332
1333         return CMD_STATUS_ERROR;
1334 }
1335
1336 // This function should be (the only) called directly from the bot ai loop
1337 float bot_execute_commands()
1338 {
1339         float f;
1340         do
1341         {
1342                 f = bot_execute_commands_once();
1343         }
1344         while(f < 0);
1345         return f;
1346 }