qcsrc/server/cheats.qc

   1 #include "cheats.qh"
   2 #include "_all.qh"
   3
   4 #include "g_damage.qh"
   5 #include "race.qh"
   6 #include "../common/triggers/teleporters.qh"
   7
   8 #include "mutators/mutators_include.qh"
   9
  10 #include "weapons/tracing.qh"
  11
  12 #include "../common/constants.qh"
  13 #include "../common/deathtypes.qh"
  14 #include "../common/effects.qh"
  15 #include "../common/util.qh"
  16
  17 #include "../common/monsters/all.qh"
  18
  19 #include "../common/weapons/all.qh"
  20
  21 #include "../common/triggers/subs.qh"
  22
  23 #include "../common/triggers/func/breakable.qh"
  24
  25 #include "../csqcmodellib/sv_model.qh"
  26
  27 #include "../warpzonelib/anglestransform.qh"
  28 #include "../warpzonelib/util_server.qh"
  29
  30 void CopyBody(float keepvelocity);
  31
  32 #ifdef NOCHEATS
  33
  34 float CheatImpulse(float i) { return 0; }
  35 float CheatCommand(float argc) { return 0; }
  36 float CheatFrame() { return 0; }
  37 void CheatInit() { cheatcount_total = world.cheatcount; }
  38 void CheatShutdown() { }
  39 void CheatInitClient() { }
  40 void CheatShutdownClient() { }
  41 void Drag_MoveDrag(entity from, entity to) { }
  42
  43 #else
  44
  45 .float maycheat;
  46 float gamestart_sv_cheats;
  47
  48
  49
  50 void CheatInit()
  51 {
  52         gamestart_sv_cheats = autocvar_sv_cheats;
  53 }
  54
  55 void CheatShutdown()
  56 {
  57 }
  58
  59 void CheatInitClient()
  60 {
  61 }
  62
  63 void CheatShutdownClient()
  64 {
  65 }
  66
  67 float CheatsAllowed(float i, float argc, float fr) // the cheat gets passed as argument for possible future ACL checking
  68 {SELFPARAM();
  69         // dead people cannot cheat
  70         if(self.deadflag != DEAD_NO)
  71                 return 0;
  72         if(gamestart_sv_cheats < 2 && !IS_PLAYER(self))
  73                 return 0;
  74
  75         // sv_clones
  76         if(i == CHIMPULSE_CLONE_MOVING || i == CHIMPULSE_CLONE_STANDING)
  77                 if(self.lip < sv_clones)
  78                         return 1;
  79
  80         // haha
  81         if(self.maycheat)
  82                 return 1;
  83
  84         // sv_cheats
  85         if(gamestart_sv_cheats && autocvar_sv_cheats)
  86                 return 1;
  87
  88         // if we get here, player is not allowed to cheat. Log it.
  89         if(i)
  90                 bprintf("Player %s^7 tried to use cheat 'impulse %d'\n", self.netname, i);
  91         else if(argc)
  92                 bprintf("Player %s^7 tried to use cheat '%s'\n", self.netname, argv(0));
  93         else if(fr)
  94                 bprintf("Player %s^7 tried to use cheat frame %d\n", self.netname, fr);
  95         else
  96                 bprintf("Player %s^7 tried to use an unknown cheat\n", self.netname);
  97
  98         return 0;
  99 }
 100
 101 #define BEGIN_CHEAT_FUNCTION() \
 102         float cheating, attempting; \
 103         cheating = 0; attempting = 0
 104 #define DID_CHEAT() \
 105         ++cheating
 106 #define ADD_CHEATS(e,n) \
 107         cheatcount_total += n; \
 108         e.cheatcount += n
 109 #define END_CHEAT_FUNCTION() \
 110         ADD_CHEATS(self,cheating); \
 111         return attempting
 112 #define IS_CHEAT(i,argc,fr) \
 113         if((++attempting, !CheatsAllowed(i,argc,fr))) \
 114                 break
 115
 116 float num_autoscreenshot;
 117 void info_autoscreenshot_findtarget()
 118 {SELFPARAM();
 119         entity e;
 120         e = find(world, targetname, self.target);
 121         if(!e)
 122         {
 123                 objerror("Missing target. FAIL!");
 124                 return;
 125         }
 126         vector a = vectoangles(e.origin - self.origin);
 127         a.x = -a.x; // don't ask
 128         self.angles_x = a.x;
 129         self.angles_y = a.y;
 130         // we leave Rick Roll alone
 131 }
 132 void spawnfunc_info_autoscreenshot()
 133 {SELFPARAM();
 134         if(++num_autoscreenshot > autocvar_g_max_info_autoscreenshot)
 135         {
 136                 objerror("Too many info_autoscreenshot entitites. FAIL!");
 137                 return;
 138         }
 139         if(self.target != "")
 140                 InitializeEntity(self, info_autoscreenshot_findtarget, INITPRIO_FINDTARGET);
 141         // this one just has to exist
 142 }
 143
 144 float CheatImpulse(float i)
 145 {SELFPARAM();
 146         BEGIN_CHEAT_FUNCTION();
 147         switch(i)
 148         {
 149                 entity e, e2;
 150
 151                 case CHIMPULSE_SPEEDRUN_INIT: // deploy personal waypoint
 152                         // shared with regular waypoint init, so this is not a cheat by itself
 153                         if(!self.personal)
 154                         {
 155                                 self.personal = spawn();
 156                                 self.personal.classname = "personal_wp";
 157                         }
 158                         self.personal.origin = self.origin;
 159                         self.personal.v_angle = self.v_angle;
 160                         self.personal.velocity = self.velocity;
 161                         self.personal.ammo_rockets = self.ammo_rockets;
 162                         self.personal.ammo_nails = self.ammo_nails;
 163                         self.personal.ammo_cells = self.ammo_cells;
 164                         self.personal.ammo_plasma = self.ammo_plasma;
 165                         self.personal.ammo_shells = self.ammo_shells;
 166                         self.personal.ammo_fuel = self.ammo_fuel;
 167                         self.personal.health = self.health;
 168                         self.personal.armorvalue = self.armorvalue;
 169                         self.personal.weapons = self.weapons;
 170                         self.personal.items = self.items;
 171                         self.personal.pauserotarmor_finished = self.pauserotarmor_finished;
 172                         self.personal.pauserothealth_finished = self.pauserothealth_finished;
 173                         self.personal.pauserotfuel_finished = self.pauserotfuel_finished;
 174                         self.personal.pauseregen_finished = self.pauseregen_finished;
 175                         self.personal.strength_finished = self.strength_finished;
 176                         self.personal.invincible_finished = self.invincible_finished;
 177                         self.personal.teleport_time = time;
 178                         break; // this part itself doesn't cheat, so let's not count this
 179                 case CHIMPULSE_CLONE_MOVING:
 180                         IS_CHEAT(i, 0, 0);
 181                         makevectors (self.v_angle);
 182                         self.velocity = self.velocity + v_forward * 300;
 183                         CopyBody(1);
 184                         self.lip += 1;
 185                         self.velocity = self.velocity - v_forward * 300;
 186                         DID_CHEAT();
 187                         break;
 188                 case CHIMPULSE_CLONE_STANDING:
 189                         IS_CHEAT(i, 0, 0);
 190                         CopyBody(0);
 191                         self.lip += 1;
 192                         DID_CHEAT();
 193                         break;
 194                 case CHIMPULSE_GIVE_ALL:
 195                         IS_CHEAT(i, 0, 0);
 196                         CheatCommand(tokenize_console("give all"));
 197                         break; // already counted as cheat
 198                 case CHIMPULSE_SPEEDRUN:
 199                         IS_CHEAT(i, 0, 0);
 200                         if(self.personal)
 201                         {
 202                                 self.speedrunning = true;
 203                                 tracebox(self.personal.origin, self.mins, self.maxs, self.personal.origin, MOVE_WORLDONLY, self);
 204                                 if(trace_startsolid)
 205                                 {
 206                                         sprint(self, "Cannot move there, cheater - only waypoints set using g_waypointsprite_personal work\n");
 207                                 }
 208                                 else
 209                                 {
 210                                         // Abort speedrun, teleport back
 211                                         setorigin(self, self.personal.origin);
 212                                         self.oldvelocity = self.velocity = self.personal.velocity;
 213                                         self.angles = self.personal.v_angle;
 214                                         self.fixangle = true;
 215
 216                                         MUTATOR_CALLHOOK(AbortSpeedrun, self);
 217                                 }
 218
 219                                 self.ammo_rockets = self.personal.ammo_rockets;
 220                                 self.ammo_nails = self.personal.ammo_nails;
 221                                 self.ammo_cells = self.personal.ammo_cells;
 222                                 self.ammo_plasma = self.personal.ammo_plasma;
 223                                 self.ammo_shells = self.personal.ammo_shells;
 224                                 self.ammo_fuel = self.personal.ammo_fuel;
 225                                 self.health = self.personal.health;
 226                                 self.armorvalue = self.personal.armorvalue;
 227                                 self.weapons = self.personal.weapons;
 228                                 self.items = self.personal.items;
 229                                 self.pauserotarmor_finished = time + self.personal.pauserotarmor_finished - self.personal.teleport_time;
 230                                 self.pauserothealth_finished = time + self.personal.pauserothealth_finished - self.personal.teleport_time;
 231                                 self.pauserotfuel_finished = time + self.personal.pauserotfuel_finished - self.personal.teleport_time;
 232                                 self.pauseregen_finished = time + self.personal.pauseregen_finished - self.personal.teleport_time;
 233                                 self.strength_finished = time + self.personal.strength_finished - self.personal.teleport_time;
 234                                 self.invincible_finished = time + self.personal.invincible_finished - self.personal.teleport_time;
 235
 236                                 DID_CHEAT();
 237                                 break;
 238                         }
 239                         if(self.deadflag != DEAD_NO)
 240                                 sprint(self, "UR DEAD AHAHAH))\n");
 241                         else
 242                                 sprint(self, "No waypoint set, cheater (use g_waypointsprite_personal to set one)\n");
 243                         break;
 244                 case CHIMPULSE_TELEPORT:
 245                         IS_CHEAT(i, 0, 0);
 246                         if(self.movetype == MOVETYPE_NOCLIP)
 247                         {
 248                                 e = find(world, classname, "info_autoscreenshot");
 249                                 if(e)
 250                                 {
 251                                         sprint(self, "Emergency teleport used info_autoscreenshot location\n");
 252                                         setorigin(self, e.origin);
 253                                         self.angles = e.angles;
 254                                         remove(e);
 255                                         // should we? self.angles_x = -self.angles_x;
 256                                         self.fixangle = true;
 257                                         self.velocity = '0 0 0';
 258                                         DID_CHEAT();
 259                                         break;
 260                                 }
 261                         }
 262                         if(MoveToRandomMapLocation(self, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, ((gamestart_sv_cheats < 2) ? 100 : 100000), 384, 384))
 263                         {
 264                                 sprint(self, "Emergency teleport used random location\n");
 265                                 self.angles_x = -self.angles.x;
 266                                 self.fixangle = true;
 267                                 self.velocity = '0 0 0';
 268                                 DID_CHEAT();
 269                                 break;
 270                         }
 271                         sprint(self, "Emergency teleport could not find a good location, forget it!\n");
 272                         break;
 273                 case CHIMPULSE_R00T:
 274                         IS_CHEAT(i, 0, 0);
 275                         RandomSelection_Init();
 276                         FOR_EACH_PLAYER(e)
 277                                 if(e.deadflag == DEAD_NO)
 278                                         if(DIFF_TEAM(e, self))
 279                                                 RandomSelection_Add(e, 0, string_null, 1, 1);
 280                         if(RandomSelection_chosen_ent)
 281                                 e = RandomSelection_chosen_ent;
 282                         else
 283                                 e = self;
 284
 285                         Send_Effect(EFFECT_ROCKET_EXPLODE, e.origin, '0 0 0', 1);
 286                         sound(e, CH_SHOTS, W_Sound("rocket_impact"), VOL_BASE, ATTEN_NORM);
 287
 288                         e2 = spawn();
 289                         setorigin(e2, e.origin);
 290                         RadiusDamage(e2, self, 1000, 0, 128, world, world, 500, DEATH_CHEAT, e);
 291                         remove(e2);
 292
 293                         LOG_INFO("404 Sportsmanship not found.\n");
 294                         DID_CHEAT();
 295                         break;
 296         }
 297
 298         END_CHEAT_FUNCTION();
 299 }
 300
 301 void DragBox_Think();
 302 float drag_lastcnt;
 303 float CheatCommand(float argc)
 304 {SELFPARAM();
 305         BEGIN_CHEAT_FUNCTION();
 306         string cmd;
 307         cmd = argv(0);
 308         switch(cmd)
 309         {
 310                 float effectnum, f;
 311                 vector start, end;
 312                 entity oldself;
 313
 314                 case "pointparticles":
 315                         IS_CHEAT(0, argc, 0);
 316                         if(argc == 5)
 317                         {
 318                                 // arguments:
 319                                 //   effectname
 320                                 //   origin (0..1, on crosshair line)
 321                                 //   velocity
 322                                 //   howmany
 323                                 f = stof(argv(2));
 324                                 crosshair_trace(self);
 325                                 start = (1-f) * self.origin + f * trace_endpos;
 326                                 end = stov(argv(3));
 327                                 f = stof(argv(4));
 328                                 Send_Effect_(argv(1), start, end, f);
 329                                 DID_CHEAT();
 330                                 break;
 331                         }
 332                         sprint(self, "Usage: sv_cheats 1; restart; cmd pointparticles effectname position(0..1) velocityvector multiplier\n");
 333                         break;
 334                 case "trailparticles":
 335                         IS_CHEAT(0, argc, 0);
 336                         if(argc == 2)
 337                         {
 338                                 // arguments:
 339                                 //   effectname
 340                                 effectnum = _particleeffectnum(argv(1));
 341                                 W_SetupShot(self, false, false, "", CH_WEAPON_A, 0);
 342                                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
 343                                 trailparticles(self, effectnum, w_shotorg, trace_endpos);
 344                                 DID_CHEAT();
 345                                 break;
 346                         }
 347                         sprint(self, "Usage: sv_cheats 1; restart; cmd trailparticles effectname\n");
 348                         break;
 349                 case "make":
 350                         IS_CHEAT(0, argc, 0);
 351                         if(argc == 3)
 352                         {
 353                                 // arguments:
 354                                 //   modelname mode
 355                                 f = stof(argv(2));
 356                                 W_SetupShot(self, false, false, "", CH_WEAPON_A, 0);
 357                                 traceline(w_shotorg, w_shotorg + w_shotdir * 2048, MOVE_NORMAL, self);
 358                                 if((trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT) || trace_fraction == 1)
 359                                 {
 360                                         sprint(self, "cannot make stuff there (bad surface)\n");
 361                                 }
 362                                 else
 363                                 {
 364                                         entity e = spawn();
 365                                         e.model = strzone(argv(1));
 366                                         e.mdl = "rocket_explode";
 367                                         e.health = 1000;
 368                                         setorigin(e, trace_endpos);
 369                                         e.effects = EF_NOMODELFLAGS;
 370                                         if(f == 1)
 371                                         {
 372                                                 e.angles = fixedvectoangles2(trace_plane_normal, v_forward);
 373                                                 e.angles = AnglesTransform_ApplyToAngles(e.angles, '-90 0 0'); // so unrotated models work
 374                                         }
 375                                         SELFCALL(e, spawnfunc_func_breakable());
 376                                         SELFCALL_DONE();
 377                                         // now, is it valid?
 378                                         if(f == 0)
 379                                         {
 380                                                 tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_NORMAL, e);
 381                                                 if(trace_startsolid)
 382                                                 {
 383                                                         remove(e);
 384                                                         sprint(self, "cannot make stuff there (no space)\n");
 385                                                 }
 386                                                 else
 387                                                         DID_CHEAT();
 388                                         }
 389                                         else
 390                                                 DID_CHEAT();
 391                                 }
 392                         }
 393                         else
 394                                 sprint(self, "Usage: sv_cheats 1; restart; cmd make models/... 0/1/2\n");
 395                         break;
 396                 case "penalty":
 397                         IS_CHEAT(0, argc, 0);
 398                         if(argc == 3)
 399                         {
 400                                 race_ImposePenaltyTime(self, stof(argv(1)), argv(2));
 401                                 DID_CHEAT();
 402                                 break;
 403                         }
 404                         sprint(self, "Usage: sv_cheats 1; restart; cmd penalty 5.0 AHAHAHAHAHAHAH))\n");
 405                         break;
 406                 case "dragbox_spawn": {
 407                         IS_CHEAT(0, argc, 0);
 408                         entity e = spawn();
 409                         e.classname = "dragbox_box";
 410                         e.think = DragBox_Think;
 411                         e.nextthink = time;
 412                         e.solid = -1; // black
 413                         setmodel(e, "null"); // network it
 414                         if(argc == 4)
 415                                 e.cnt = stof(argv(1));
 416                         else
 417                                 e.cnt = max(0, drag_lastcnt);
 418
 419                         e.aiment = spawn();
 420                         e.aiment.classname = "dragbox_corner_1";
 421                         e.aiment.owner = e;
 422                         setmodel(e.aiment, "models/marker.md3");
 423                         e.aiment.skin = 0;
 424                         setsize(e.aiment, '0 0 0', '0 0 0');
 425                         if(argc == 4)
 426                                 setorigin(e.aiment, stov(argv(2)));
 427                         else
 428                         {
 429                                 crosshair_trace(self);
 430                                 setorigin(e.aiment, trace_endpos);
 431                         }
 432
 433                         e.enemy = spawn();
 434                         e.enemy.classname = "dragbox_corner_2";
 435                         e.enemy.owner = e;
 436                         setmodel(e.enemy, "models/marker.md3");
 437                         e.enemy.skin = 1;
 438                         setsize(e.enemy, '0 0 0', '0 0 0');
 439                         end = normalize(self.origin + self.view_ofs - e.aiment.origin);
 440                         end.x = (end.x > 0) * 2 - 1;
 441                         end.y = (end.y > 0) * 2 - 1;
 442                         end.z = (end.z > 0) * 2 - 1;
 443                         if(argc == 4)
 444                                 setorigin(e.enemy, stov(argv(3)));
 445                         else
 446                                 setorigin(e.enemy, e.aiment.origin + 32 * end);
 447
 448                         e.killindicator = spawn();
 449                         e.killindicator.classname = "drag_digit";
 450                         e.killindicator.owner = e;
 451                         setattachment(e.killindicator, e, "");
 452                         setorigin(e.killindicator, '0 0 -8');
 453                         e.killindicator.killindicator = spawn();
 454                         e.killindicator.killindicator.classname = "drag_digit";
 455                         e.killindicator.killindicator.owner = e;
 456                         setattachment(e.killindicator.killindicator, e, "");
 457                         setorigin(e.killindicator.killindicator, '0 0 8');
 458                         DID_CHEAT();
 459                         break;
 460                 }
 461                 case "dragpoint_spawn": {
 462                         IS_CHEAT(0, argc, 0);
 463                         entity e = spawn();
 464                         e.classname = "dragpoint";
 465                         e.think = DragBox_Think;
 466                         e.nextthink = time;
 467                         e.solid = 0; // nothing special
 468                         setmodel(e, "models/marker.md3");
 469                         setsize(e, PL_MIN, PL_MAX);
 470                         e.skin = 2;
 471                         if(argc == 3)
 472                                 e.cnt = stof(argv(1));
 473                         else
 474                                 e.cnt = drag_lastcnt;
 475                         if(argc == 3)
 476                                 setorigin(e, stov(argv(2)));
 477                         else
 478                         {
 479                                 crosshair_trace(self);
 480                                 setorigin(e, trace_endpos + normalize(self.origin + self.view_ofs - trace_endpos));
 481                                 move_out_of_solid(e);
 482                         }
 483
 484                         e.killindicator = spawn();
 485                         e.killindicator.classname = "drag_digit";
 486                         e.killindicator.owner = e;
 487                         setattachment(e.killindicator, e, "");
 488                         setorigin(e.killindicator, '0 0 40');
 489                         e.killindicator.killindicator = spawn();
 490                         e.killindicator.killindicator.classname = "drag_digit";
 491                         e.killindicator.killindicator.owner = e;
 492                         setattachment(e.killindicator.killindicator, e, "");
 493                         setorigin(e.killindicator.killindicator, '0 0 56');
 494                         DID_CHEAT();
 495                         break;
 496                 }
 497                 case "drag_remove":
 498                         IS_CHEAT(0, argc, 0);
 499                         RandomSelection_Init();
 500                         crosshair_trace(self);
 501                         for(entity e = world; (e = find(e, classname, "dragbox_box")); )
 502                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 503                         for(entity e = world; (e = find(e, classname, "dragpoint")); )
 504                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 505                         if(RandomSelection_chosen_ent)
 506                         {
 507                                 remove(RandomSelection_chosen_ent.killindicator.killindicator);
 508                                 remove(RandomSelection_chosen_ent.killindicator);
 509                                 if(RandomSelection_chosen_ent.aiment)
 510                                         remove(RandomSelection_chosen_ent.aiment);
 511                                 if(RandomSelection_chosen_ent.enemy)
 512                                         remove(RandomSelection_chosen_ent.enemy);
 513                                 remove(RandomSelection_chosen_ent);
 514                         }
 515                         DID_CHEAT();
 516                         break;
 517                 case "drag_setcnt":
 518                         IS_CHEAT(0, argc, 0);
 519                         if(argc == 2)
 520                         {
 521                                 RandomSelection_Init();
 522                                 crosshair_trace(self);
 523                                 for(entity e = world; (e = find(e, classname, "dragbox_box")); )
 524                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 525                                 for(entity e = world; (e = find(e, classname, "dragpoint")); )
 526                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 527                                 if(RandomSelection_chosen_ent)
 528                                 {
 529                                         if(substring(argv(1), 0, 1) == "*")
 530                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = RandomSelection_chosen_ent.cnt + stof(substring(argv(1), 1, -1));
 531                                         else
 532                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = stof(argv(1));
 533                                 }
 534                                 DID_CHEAT();
 535                                 break;
 536                         }
 537                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_setcnt cnt\n");
 538                         break;
 539                 case "drag_save":
 540                         IS_CHEAT(0, argc, 0);
 541                         if(argc == 2)
 542                         {
 543                                 f = fopen(argv(1), FILE_WRITE);
 544                                 fputs(f, "cmd drag_clear\n");
 545                                 for(entity e = world; (e = find(e, classname, "dragbox_box")); )
 546                                 {
 547                                         fputs(f, strcat("cmd dragbox_spawn ", ftos(e.cnt), " \"", vtos(e.aiment.origin), "\" \"", vtos(e.enemy.origin), "\"\n"));
 548                                 }
 549                                 for(entity e = world; (e = find(e, classname, "dragpoint")); )
 550                                 {
 551                                         fputs(f, strcat("cmd dragpoint_spawn ", ftos(e.cnt), " \"", vtos(e.origin), "\"\n"));
 552                                 }
 553                                 fclose(f);
 554                                 DID_CHEAT();
 555                                 break;
 556                         }
 557                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 558                         break;
 559                 case "drag_saveraceent":
 560                         IS_CHEAT(0, argc, 0);
 561                         if(argc == 2)
 562                         {
 563                                 f = fopen(argv(1), FILE_WRITE);
 564                                 for(entity e = world; (e = find(e, classname, "dragbox_box")); )
 565                                 {
 566                                         fputs(f, "{\n");
 567                                         fputs(f, "\"classname\" \"trigger_race_checkpoint\"\n");
 568                                         fputs(f, strcat("\"origin\" \"", ftos(e.absmin.x), " ", ftos(e.absmin.y), " ", ftos(e.absmin.z), "\"\n"));
 569                                         fputs(f, strcat("\"maxs\" \"", ftos(e.absmax.x - e.absmin.x), " ", ftos(e.absmax.y - e.absmin.y), " ", ftos(e.absmax.z - e.absmin.z), "\"\n"));
 570                                         fputs(f, strcat("\"cnt\" \"", ftos(e.cnt), "\"\n"));
 571                                         fputs(f, strcat("\"targetname\" \"checkpoint", ftos(e.cnt), "\"\n"));
 572                                         fputs(f, "}\n");
 573                                 }
 574                                 for(entity e = world; (e = find(e, classname, "dragpoint")); )
 575                                 {
 576                                         start = '0 0 0';
 577                                         effectnum = 0;
 578                                         for(oldself = world; (oldself = find(oldself, classname, "dragbox_box")); )
 579                                         {
 580                                                 if(e.cnt <= 0 && oldself.cnt == 0 || e.cnt == oldself.cnt)
 581                                                 {
 582                                                         start = start + oldself.origin;
 583                                                         ++effectnum;
 584                                                 }
 585                                         }
 586                                         start *= 1 / effectnum;
 587                                         fputs(f, "{\n");
 588                                         fputs(f, "\"classname\" \"info_player_race\"\n");
 589                                         fputs(f, strcat("\"angle\" \"", ftos(vectoyaw(start - e.origin)), "\"\n"));
 590                                         fputs(f, strcat("\"origin\" \"", ftos(e.origin.x), " ", ftos(e.origin.y), " ", ftos(e.origin.z), "\"\n"));
 591                                         if(e.cnt == -2)
 592                                         {
 593                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 594                                                 fputs(f, "\"race_place\" \"0\"\n");
 595                                         }
 596                                         else if(e.cnt == -1)
 597                                         {
 598                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 599                                                 fputs(f, "\"race_place\" \"-1\"\n");
 600                                         }
 601                                         else
 602                                         {
 603                                                 fputs(f, strcat("\"target\" \"checkpoint", ftos(e.cnt), "\"\n"));
 604                                                 if(e.cnt == 0)
 605                                                 {
 606                                                         // these need race_place
 607                                                         // counting...
 608                                                         effectnum = 1;
 609                                                         for(oldself = world; (oldself = find(oldself, classname, "dragpoint")); )
 610                                                         if(oldself.cnt == 0)
 611                                                         {
 612                                                                 if(vlen(oldself.origin - start) < vlen(e.origin - start))
 613                                                                         ++effectnum;
 614                                                                 else if(vlen(oldself.origin - start) == vlen(e.origin - start) && num_for_edict(oldself) < num_for_edict(e))
 615                                                                         ++effectnum;
 616                                                         }
 617                                                         fputs(f, strcat("\"race_place\" \"", ftos(effectnum), "\"\n"));
 618                                                 }
 619                                         }
 620                                         fputs(f, "}\n");
 621                                 }
 622                                 fclose(f);
 623                                 DID_CHEAT();
 624                                 break;
 625                         }
 626                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 627                         break;
 628                 case "drag_clear":
 629                         IS_CHEAT(0, argc, 0);
 630                         for(entity e = world; (e = find(e, classname, "dragbox_box")); )
 631                                 remove(e);
 632                         for(entity e = world; (e = find(e, classname, "dragbox_corner_1")); )
 633                                 remove(e);
 634                         for(entity e = world; (e = find(e, classname, "dragbox_corner_2")); )
 635                                 remove(e);
 636                         for(entity e = world; (e = find(e, classname, "dragpoint")); )
 637                                 remove(e);
 638                         for(entity e = world; (e = find(e, classname, "drag_digit")); )
 639                                 remove(e);
 640                         DID_CHEAT();
 641                         break;
 642                 case "god":
 643                         IS_CHEAT(0, argc, 0);
 644                         BITXOR_ASSIGN(self.flags, FL_GODMODE);
 645                         if(self.flags & FL_GODMODE)
 646                         {
 647                                 sprint(self, "godmode ON\n");
 648                                 DID_CHEAT();
 649                         }
 650                         else
 651                                 sprint(self, "godmode OFF\n");
 652                         break;
 653                 case "notarget":
 654                         IS_CHEAT(0, argc, 0);
 655                         BITXOR_ASSIGN(self.flags, FL_NOTARGET);
 656                         if(self.flags & FL_NOTARGET)
 657                         {
 658                                 sprint(self, "notarget ON\n");
 659                                 DID_CHEAT();
 660                         }
 661                         else
 662                                 sprint(self, "notarget OFF\n");
 663                         break;
 664                 case "noclip":
 665                         IS_CHEAT(0, argc, 0);
 666                         if(self.movetype != MOVETYPE_NOCLIP)
 667                         {
 668                                 self.movetype = MOVETYPE_NOCLIP;
 669                                 sprint(self, "noclip ON\n");
 670                                 DID_CHEAT();
 671                         }
 672                         else
 673                         {
 674                                 self.movetype = MOVETYPE_WALK;
 675                                 sprint(self, "noclip OFF\n");
 676                         }
 677                         break;
 678                 case "fly":
 679                         IS_CHEAT(0, argc, 0);
 680                         if(self.movetype != MOVETYPE_FLY)
 681                         {
 682                                 self.movetype = MOVETYPE_FLY;
 683                                 sprint(self, "flymode ON\n");
 684                                 DID_CHEAT();
 685                         }
 686                         else
 687                         {
 688                                 self.movetype = MOVETYPE_WALK;
 689                                 sprint(self, "flymode OFF\n");
 690                         }
 691                         break;
 692                 case "give":
 693                         IS_CHEAT(0, argc, 0);
 694                         if(GiveItems(self, 1, argc))
 695                                 DID_CHEAT();
 696                         break;
 697                 case "usetarget":
 698                         IS_CHEAT(0, argc, 0);
 699                         setself(spawn());
 700                         self.target = argv(1);
 701                         activator = this;
 702                         SUB_UseTargets();
 703                         remove(self);
 704                         setself(this);
 705                         DID_CHEAT();
 706                         break;
 707                 case "killtarget":
 708                         IS_CHEAT(0, argc, 0);
 709                         setself(spawn());
 710                         self.killtarget = argv(1);
 711                         activator = this;
 712                         SUB_UseTargets();
 713                         remove(self);
 714                         setself(this);
 715                         DID_CHEAT();
 716                         break;
 717                 case "teleporttotarget":
 718                         IS_CHEAT(0, argc, 0);
 719                         setself(spawn());
 720                         setorigin(self, self.origin);
 721                         self.classname = "cheattriggerteleport";
 722                         self.target = argv(1);
 723                         teleport_findtarget();
 724                         if(!wasfreed(self))
 725                         {
 726                                 Simple_TeleportPlayer(self, this);
 727                                 remove(self);
 728                                 DID_CHEAT();
 729                         }
 730                         setself(this);
 731                         break;
 732         }
 733
 734         END_CHEAT_FUNCTION();
 735 }
 736
 737 float Drag(float force_allow_pick, float ischeat);
 738 void Drag_Begin(entity dragger, entity draggee, vector touchpoint);
 739 void Drag_Finish(entity dragger);
 740 float Drag_IsDraggable(entity draggee);
 741 float Drag_MayChangeAngles(entity draggee);
 742 void Drag_MoveForward(entity dragger);
 743 void Drag_SetSpeed(entity dragger, float s);
 744 void Drag_MoveBackward(entity dragger);
 745 void Drag_Update(entity dragger);
 746 float Drag_CanDrag(entity dragger);
 747 float Drag_IsDragging(entity dragger);
 748 void Drag_MoveDrag(entity from, entity to);
 749 .entity dragentity;
 750
 751 float CheatFrame()
 752 {SELFPARAM();
 753         BEGIN_CHEAT_FUNCTION();
 754
 755         // Dragging can be used as either a cheat, or a function for some objects. If sv_cheats is active,
 756         // the cheat dragging is used (unlimited pickup range and any entity can be carried). If sv_cheats
 757         // is disabled, normal dragging is used (limited pickup range and only dragable objects can be carried),
 758         // grabbing itself no longer being accounted as cheating.
 759
 760         switch(0)
 761         {
 762                 default:
 763                         if(self.maycheat || (gamestart_sv_cheats && autocvar_sv_cheats))
 764                         {
 765                                 // use cheat dragging if cheats are enabled
 766                                 crosshair_trace_plusvisibletriggers(self);
 767                                 Drag(true, true);
 768                         }
 769                         else
 770                         {
 771                                 Drag(false, false); // execute dragging
 772                         }
 773                         break;
 774         }
 775
 776         END_CHEAT_FUNCTION();
 777 }
 778
 779
 780
 781
 782
 783 // ENTITY DRAGGING
 784
 785 // on dragger:
 786 .float draggravity;
 787 .float dragspeed; // speed of mouse wheel action
 788 .float dragdistance; // distance of dragentity's draglocalvector from view_ofs
 789 .vector draglocalvector; // local attachment vector of the dragentity
 790 .float draglocalangle;
 791 // on draggee:
 792 .entity draggedby;
 793 .float dragmovetype;
 794
 795 float Drag(float force_allow_pick, float ischeat)
 796 {SELFPARAM();
 797         BEGIN_CHEAT_FUNCTION();
 798
 799         // returns true when an entity has been picked up
 800         // If pick is true, the object can also be picked up if it's not being held already
 801         // If pick is false, only keep dragging the object if it's already being held
 802
 803         switch(0)
 804         {
 805                 default:
 806                         if(Drag_IsDragging(self))
 807                         {
 808                                 if(self.BUTTON_DRAG)
 809                                 {
 810                                         if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 811                                         {
 812                                                 Drag_MoveForward(self);
 813                                                 self.impulse = 0;
 814                                         }
 815                                         else if(self.impulse == 12 || self.impulse == 16 || self.impulse == 19)
 816                                         {
 817                                                 Drag_MoveBackward(self);
 818                                                 self.impulse = 0;
 819                                         }
 820                                         else if(self.impulse >= 1 && self.impulse <= 9)
 821                                         {
 822                                                 Drag_SetSpeed(self, self.impulse - 1);
 823                                         }
 824                                         else if(self.impulse == 14)
 825                                         {
 826                                                 Drag_SetSpeed(self, 9);
 827                                         }
 828
 829                                         if(frametime)
 830                                                 Drag_Update(self);
 831                                 }
 832                                 else
 833                                 {
 834                                         Drag_Finish(self);
 835                                 }
 836                         }
 837                         else
 838                         {
 839                                 if(Drag_CanDrag(self))
 840                                         if(self.BUTTON_DRAG)
 841                                         {
 842                                                 crosshair_trace_plusvisibletriggers(self);
 843                                                 entity e = trace_ent;
 844                                                 float pick = force_allow_pick;
 845                                                 if (e && !pick)
 846                                                 {
 847                                                         // pick is true if the object can be picked up. While an object is being carried, the Drag() function
 848                                                         // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 849                                                         // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 850                                                         // it goes out of range while slinging it around.
 851
 852                                                         if(vlen(self.origin - e.origin) <= autocvar_g_grab_range)
 853                                                         {
 854                                                                 switch(e.grab)
 855                                                                 {
 856                                                                         case 0: // can't grab
 857                                                                                 break;
 858                                                                         case 1: // owner can grab
 859                                                                                 if(e.owner == self || e.realowner == self)
 860                                                                                         pick = true;
 861                                                                                 break;
 862                                                                         case 2: // owner and team mates can grab
 863                                                                                 if(SAME_TEAM(e.owner, self) || SAME_TEAM(e.realowner, self) || e.team == self.team)
 864                                                                                         pick = true;
 865                                                                                 break;
 866                                                                         case 3: // anyone can grab
 867                                                                                 pick = true;
 868                                                                                 break;
 869                                                                         default:
 870                                                                                 break;
 871                                                                 }
 872                                                         }
 873                                                 }
 874                                                 // Find e and pick
 875                                                 if(e && pick)
 876                                                         if(Drag_IsDraggable(e))
 877                                                         {
 878                                                                 if(ischeat)
 879                                                                         IS_CHEAT(0, 0, CHRAME_DRAG);
 880                                                                 if(e.draggedby)
 881                                                                         Drag_Finish(e.draggedby);
 882                                                                 if(e.tag_entity)
 883                                                                         detach_sameorigin(e);
 884                                                                 Drag_Begin(self, e, trace_endpos);
 885                                                                 if(ischeat)
 886                                                                         DID_CHEAT();
 887                                                                 return true;
 888                                                         }
 889                                         }
 890                         }
 891                         break;
 892         }
 893         return false;
 894 }
 895
 896 void Drag_Begin(entity dragger, entity draggee, vector touchpoint)
 897 {
 898         float tagscale;
 899
 900         draggee.dragmovetype = draggee.movetype;
 901         draggee.draggravity = draggee.gravity;
 902         draggee.movetype = MOVETYPE_WALK;
 903         draggee.gravity = 0.00001;
 904         draggee.flags &= ~FL_ONGROUND;
 905         draggee.draggedby = dragger;
 906
 907         dragger.dragentity = draggee;
 908
 909         dragger.dragdistance = vlen(touchpoint - dragger.origin - dragger.view_ofs);
 910         dragger.draglocalangle = draggee.angles.y - dragger.v_angle.y;
 911         touchpoint = touchpoint - gettaginfo(draggee, 0);
 912         tagscale = pow(vlen(v_forward), -2);
 913         dragger.draglocalvector_x = touchpoint * v_forward * tagscale;
 914         dragger.draglocalvector_y = touchpoint * v_right * tagscale;
 915         dragger.draglocalvector_z = touchpoint * v_up * tagscale;
 916
 917         dragger.dragspeed = 64;
 918 }
 919
 920 void Drag_Finish(entity dragger)
 921 {
 922         entity draggee;
 923         draggee = dragger.dragentity;
 924         if(dragger)
 925                 dragger.dragentity = world;
 926         draggee.draggedby = world;
 927         draggee.movetype = draggee.dragmovetype;
 928         draggee.gravity = draggee.draggravity;
 929
 930         switch(draggee.movetype)
 931         {
 932                 case MOVETYPE_TOSS:
 933                 case MOVETYPE_WALK:
 934                 case MOVETYPE_STEP:
 935                 case MOVETYPE_FLYMISSILE:
 936                 case MOVETYPE_BOUNCE:
 937                 case MOVETYPE_BOUNCEMISSILE:
 938                 case MOVETYPE_PHYSICS:
 939                         break;
 940                 default:
 941                         draggee.velocity = '0 0 0';
 942                         break;
 943         }
 944
 945         if((draggee.flags & FL_ITEM) && (vlen(draggee.velocity) < 32))
 946         {
 947                 draggee.velocity = '0 0 0';
 948                 draggee.flags |= FL_ONGROUND; // floating items are FUN
 949         }
 950 }
 951
 952 float Drag_IsDraggable(entity draggee)
 953 {
 954         // TODO add more checks for bad stuff here
 955         if(draggee == world)
 956                 return false;
 957         if(draggee.classname == "func_bobbing")
 958                 return false;
 959         if(draggee.classname == "door") // FIXME find out why these must be excluded, or work around the problem (trying to drag these causes like 4 fps)
 960                 return false;
 961         if(draggee.classname == "plat")
 962                 return false;
 963         if(draggee.classname == "func_button")
 964                 return false;
 965 //      if(draggee.model == "")
 966 //              return false;
 967         if(IS_SPEC(draggee))
 968                 return false;
 969         if(IS_OBSERVER(draggee))
 970                 return false;
 971         if(draggee.classname == "exteriorweaponentity")
 972                 return false;
 973         if(draggee.classname == "weaponentity")
 974                 return false;
 975
 976         return true;
 977 }
 978
 979 float Drag_MayChangeAngles(entity draggee)
 980 {
 981         // TODO add more checks for bad stuff here
 982         if(substring(draggee.model, 0, 1) == "*")
 983                 return false;
 984         return true;
 985 }
 986
 987 void Drag_MoveForward(entity dragger)
 988 {
 989         dragger.dragdistance += dragger.dragspeed;
 990 }
 991
 992 void Drag_SetSpeed(entity dragger, float s)
 993 {
 994         dragger.dragspeed = pow(2, s);
 995 }
 996
 997 void Drag_MoveBackward(entity dragger)
 998 {
 999         dragger.dragdistance = max(0, dragger.dragdistance - dragger.dragspeed);
1000 }
1001
1002 void Drag_Update(entity dragger)
1003 {
1004         vector curorigin, neworigin, goodvelocity;
1005         float f;
1006         entity draggee;
1007
1008         draggee = dragger.dragentity;
1009         draggee.flags &= ~FL_ONGROUND;
1010
1011         curorigin = gettaginfo(draggee, 0);
1012         curorigin = curorigin + v_forward * dragger.draglocalvector.x + v_right * dragger.draglocalvector.y + v_up * dragger.draglocalvector.z;
1013         makevectors(dragger.v_angle);
1014         neworigin = dragger.origin + dragger.view_ofs + v_forward * dragger.dragdistance;
1015         goodvelocity = (neworigin - curorigin) * (1 / frametime);
1016
1017         while(draggee.angles.y - dragger.v_angle.y - dragger.draglocalangle > 180)
1018                 dragger.draglocalangle += 360;
1019         while(draggee.angles.y - dragger.v_angle.y - dragger.draglocalangle <= -180)
1020                 dragger.draglocalangle -= 360;
1021
1022         f = min(frametime * 10, 1);
1023         draggee.velocity = draggee.velocity * (1 - f) + goodvelocity * f;
1024
1025         if(Drag_MayChangeAngles(draggee))
1026                 draggee.angles_y = draggee.angles.y * (1 - f) + (dragger.v_angle.y + dragger.draglocalangle) * f;
1027
1028         draggee.ltime = max(servertime + serverframetime, draggee.ltime); // fixes func_train breakage
1029
1030         vector vecs = '0 0 0';
1031         if(dragger.weaponentity.movedir_x > 0)
1032                 vecs = dragger.weaponentity.movedir;
1033
1034         vector dv = v_right * -vecs_y + v_up * vecs_z;
1035
1036         te_lightning1(draggee, dragger.origin + dragger.view_ofs + dv, curorigin);
1037 }
1038
1039 float Drag_CanDrag(entity dragger)
1040 {
1041         return (dragger.deadflag == DEAD_NO) || (IS_PLAYER(dragger));
1042 }
1043
1044 float Drag_IsDragging(entity dragger)
1045 {
1046         if(!dragger.dragentity)
1047                 return false;
1048         if(wasfreed(dragger.dragentity) || dragger.dragentity.draggedby != dragger)
1049         {
1050                 dragger.dragentity = world;
1051                 return false;
1052         }
1053         if(!Drag_CanDrag(dragger) || !Drag_IsDraggable(dragger.dragentity))
1054         {
1055                 Drag_Finish(dragger);
1056                 return false;
1057         }
1058         return true;
1059 }
1060
1061 void Drag_MoveDrag(entity from, entity to)
1062 {
1063         if(from.draggedby)
1064         {
1065                 to.draggedby = from.draggedby;
1066                 to.draggedby.dragentity = to;
1067                 from.draggedby = world;
1068         }
1069 }
1070
1071 void DragBox_Think()
1072 {SELFPARAM();
1073         if(self.aiment && self.enemy)
1074         {
1075                 self.origin_x = (self.aiment.origin.x + self.enemy.origin.x) * 0.5;
1076                 self.origin_y = (self.aiment.origin.y + self.enemy.origin.y) * 0.5;
1077                 self.origin_z = (self.aiment.origin.z + self.enemy.origin.z) * 0.5;
1078                 self.maxs_x = fabs(self.aiment.origin.x - self.enemy.origin.x) * 0.5;
1079                 self.maxs_y = fabs(self.aiment.origin.y - self.enemy.origin.y) * 0.5;
1080                 self.maxs_z = fabs(self.aiment.origin.z - self.enemy.origin.z) * 0.5;
1081                 self.mins = -1 * self.maxs;
1082                 setorigin(self, self.origin); setsize(self, self.mins, self.maxs); // link edict
1083         }
1084
1085         if(self.cnt == -1) // actually race_place -1
1086         {
1087                 // show "10 10" for qualifying spawns
1088                 setmodel(self.killindicator, "models/sprites/10.spr32");
1089                 setmodel(self.killindicator.killindicator, "models/sprites/10.spr32");
1090         }
1091         else if(self.cnt == -2) // actually race_place 0
1092         {
1093                 // show "10 0" for loser spawns
1094                 setmodel(self.killindicator, "models/sprites/10.spr32");
1095                 setmodel(self.killindicator.killindicator, "models/sprites/0.spr32");
1096         }
1097         else
1098         {
1099                 setmodel(self.killindicator, strcat("models/sprites/", ftos(self.cnt % 10), ".spr32"));
1100                 setmodel(self.killindicator.killindicator, strcat("models/sprites/", ftos(floor(self.cnt / 10)), ".spr32"));
1101         }
1102
1103         self.nextthink = time;
1104 }
1105
1106 #endif