qcsrc/server/cheats.qc

   1 #include "cheats.qh"
   2
   3 #include <server/defs.qh>
   4 #include <server/miscfunctions.qh>
   5 #include <common/effects/all.qh>
   6 #include <server/resources.qh>
   7 #include <server/sv_main.qh>
   8
   9 #include "g_damage.qh"
  10 #include "clientkill.qh"
  11 #include "player.qh"
  12 #include "race.qh"
  13 #include "../common/mapobjects/teleporters.qh"
  14
  15 #include <server/mutators/_mod.qh>
  16
  17 #include "weapons/tracing.qh"
  18
  19 #include "../common/constants.qh"
  20 #include "../common/deathtypes/all.qh"
  21 #include "../common/util.qh"
  22
  23 #include <common/physics/player.qh>
  24
  25 #include "../common/monsters/_mod.qh"
  26
  27 #include <common/weapons/_all.qh>
  28
  29 #include "../common/mapobjects/subs.qh"
  30 #include <common/mapobjects/triggers.qh>
  31
  32 #include "../common/mapobjects/func/breakable.qh"
  33
  34 #include "../lib/csqcmodel/sv_model.qh"
  35
  36 #include "../lib/warpzone/anglestransform.qh"
  37 #include "../lib/warpzone/util_server.qh"
  38
  39 #ifdef NOCHEATS
  40
  41 float CheatImpulse(entity this, int imp) { return 0; }
  42 float CheatCommand(entity this, int argc) { return 0; }
  43 float CheatFrame(entity this) { return 0; }
  44 void CheatInit() { cheatcount_total = world.cheatcount; }
  45 void CheatShutdown() { }
  46 void Drag_MoveDrag(entity from, entity to) { }
  47
  48 #else
  49
  50 .bool maycheat;
  51 float gamestart_sv_cheats;
  52
  53
  54
  55 void CheatInit()
  56 {
  57         gamestart_sv_cheats = autocvar_sv_cheats;
  58 }
  59
  60 void CheatShutdown()
  61 {
  62 }
  63
  64 float CheatsAllowed(entity this, float i, int argc, float fr) // the cheat gets passed as argument for possible future ACL checking
  65 {
  66         if(IS_DEAD(this))
  67                 return 0;
  68         if(gamestart_sv_cheats < 2 && !IS_PLAYER(this))
  69                 return 0;
  70
  71         if(i == CHIMPULSE_CLONE_MOVING.impulse || i == CHIMPULSE_CLONE_STANDING.impulse)
  72                 if(this.lip < sv_clones)
  73                         return 1;
  74
  75         // haha
  76         if(this.maycheat)
  77                 return 1;
  78
  79         if(gamestart_sv_cheats && autocvar_sv_cheats)
  80                 return 1;
  81
  82         // if we get here, player is not allowed to cheat. Log it.
  83         if(i)
  84                 bprintf("Player %s^7 tried to use cheat 'impulse %d'\n", playername(this, false), i);
  85         else if(argc)
  86                 bprintf("Player %s^7 tried to use cheat '%s'\n", playername(this, false), argv(0));
  87         else if(fr)
  88                 bprintf("Player %s^7 tried to use cheat frame %d\n", playername(this, false), fr);
  89         else
  90                 bprintf("Player %s^7 tried to use an unknown cheat\n", playername(this, false));
  91
  92         return 0;
  93 }
  94
  95 #define BEGIN_CHEAT_FUNCTION() \
  96         float cheating = 0, attempting = 0
  97 #define DID_CHEAT() \
  98         ++cheating
  99 #define ADD_CHEATS(e,n) \
 100         cheatcount_total += n; \
 101         e.cheatcount += n
 102 #define END_CHEAT_FUNCTION() \
 103         ADD_CHEATS(this, cheating); \
 104         return attempting
 105 #define IS_CHEAT(ent,i,argc,fr) \
 106         if((++attempting, !CheatsAllowed(ent,i,argc,fr))) \
 107                 break
 108
 109 float num_autoscreenshot;
 110 void info_autoscreenshot_findtarget(entity this)
 111 {
 112         entity e;
 113         e = find(NULL, targetname, this.target);
 114         if(!e)
 115         {
 116                 objerror(this, "Missing target. FAIL!");
 117                 return;
 118         }
 119         vector a = vectoangles(e.origin - this.origin);
 120         a.x = -a.x; // don't ask
 121         this.angles_x = a.x;
 122         this.angles_y = a.y;
 123         // we leave Rick Roll alone
 124 }
 125 spawnfunc(info_autoscreenshot)
 126 {
 127         // this one just has to exist
 128         if(++num_autoscreenshot > autocvar_g_max_info_autoscreenshot)
 129         {
 130                 objerror(this, "Too many info_autoscreenshot entitites. FAIL!");
 131                 return;
 132         }
 133         if(this.target != "")
 134                 InitializeEntity(this, info_autoscreenshot_findtarget, INITPRIO_FINDTARGET);
 135 }
 136
 137 float CheatImpulse(entity this, int imp)
 138 {
 139         BEGIN_CHEAT_FUNCTION();
 140         switch(imp)
 141         {
 142                 entity e, e2;
 143
 144                 case CHIMPULSE_SPEEDRUN_INIT.impulse: // deploy personal waypoint
 145                         // shared with regular waypoint init, so this is not a cheat by itself
 146                         if(!this.personal)
 147                         {
 148                                 this.personal = new(personal_wp);
 149                         }
 150                         this.personal.origin = this.origin;
 151                         this.personal.v_angle = this.v_angle;
 152                         this.personal.velocity = this.velocity;
 153                         SetResource(this.personal, RES_ROCKETS, GetResource(this, RES_ROCKETS));
 154                         SetResource(this.personal, RES_BULLETS, GetResource(this, RES_BULLETS));
 155                         SetResource(this.personal, RES_CELLS, GetResource(this, RES_CELLS));
 156                         SetResource(this.personal, RES_PLASMA, GetResource(this, RES_PLASMA));
 157                         SetResource(this.personal, RES_SHELLS, GetResource(this, RES_SHELLS));
 158                         SetResource(this.personal, RES_FUEL, GetResource(this, RES_FUEL));
 159                         SetResource(this.personal, RES_HEALTH, max(1, GetResource(this, RES_HEALTH)));
 160                         SetResource(this.personal, RES_ARMOR, GetResource(this, RES_ARMOR));
 161                         STAT(WEAPONS, this.personal) = STAT(WEAPONS, this);
 162                         STAT(BUFFS, this.personal) = STAT(BUFFS, this);
 163                         STAT(BUFF_TIME, this.personal) = STAT(BUFF_TIME, this);
 164                         this.personal.items = this.items;
 165                         this.personal.pauserotarmor_finished = this.pauserotarmor_finished;
 166                         this.personal.pauserothealth_finished = this.pauserothealth_finished;
 167                         this.personal.pauserotfuel_finished = this.pauserotfuel_finished;
 168                         this.personal.pauseregen_finished = this.pauseregen_finished;
 169                         STAT(STRENGTH_FINISHED, this.personal) = STAT(STRENGTH_FINISHED, this);
 170                         STAT(INVINCIBLE_FINISHED, this.personal) = STAT(INVINCIBLE_FINISHED, this);
 171                         this.personal.teleport_time = time;
 172                         break; // this part itself doesn't cheat, so let's not count this
 173                 case CHIMPULSE_CLONE_MOVING.impulse:
 174                         IS_CHEAT(this, imp, 0, 0);
 175                         makevectors (this.v_angle);
 176                         this.velocity = this.velocity + v_forward * 300;
 177                         CopyBody(this, 1);
 178                         this.lip += 1;
 179                         this.velocity = this.velocity - v_forward * 300;
 180                         DID_CHEAT();
 181                         break;
 182                 case CHIMPULSE_CLONE_STANDING.impulse:
 183                         IS_CHEAT(this, imp, 0, 0);
 184                         CopyBody(this, 0);
 185                         this.lip += 1;
 186                         DID_CHEAT();
 187                         break;
 188                 case CHIMPULSE_GIVE_ALL.impulse:
 189                         IS_CHEAT(this, imp, 0, 0);
 190                         CheatCommand(this, tokenize_console("give all"));
 191                         break; // already counted as cheat
 192                 case CHIMPULSE_SPEEDRUN.impulse:
 193                         if(!autocvar_g_allow_checkpoints)
 194                                 IS_CHEAT(this, imp, 0, 0);
 195                         if(this.personal)
 196                         {
 197                                 this.speedrunning = true;
 198                                 tracebox(this.personal.origin, this.mins, this.maxs, this.personal.origin, MOVE_WORLDONLY, this);
 199                                 if(trace_startsolid)
 200                                 {
 201                                         sprint(this, "Cannot move there, cheater - only waypoints set using g_waypointsprite_personal work\n");
 202                                 }
 203                                 else
 204                                 {
 205                                         // Abort speedrun, teleport back
 206                                         setorigin(this, this.personal.origin);
 207                                         this.oldvelocity = this.velocity = this.personal.velocity;
 208                                         this.angles = this.personal.v_angle;
 209                                         this.fixangle = true;
 210
 211                                         MUTATOR_CALLHOOK(AbortSpeedrun, this);
 212                                 }
 213
 214                                 SetResource(this, RES_ROCKETS, GetResource(this.personal, RES_ROCKETS));
 215                                 SetResource(this, RES_BULLETS, GetResource(this.personal, RES_BULLETS));
 216                                 SetResource(this, RES_CELLS, GetResource(this.personal, RES_CELLS));
 217                                 SetResource(this, RES_PLASMA, GetResource(this.personal, RES_PLASMA));
 218                                 SetResource(this, RES_SHELLS, GetResource(this.personal, RES_SHELLS));
 219                                 SetResource(this, RES_FUEL, GetResource(this.personal, RES_FUEL));
 220                                 SetResource(this, RES_HEALTH, GetResource(this.personal, RES_HEALTH));
 221                                 SetResource(this, RES_ARMOR, GetResource(this.personal, RES_ARMOR));
 222                                 STAT(WEAPONS, this) = STAT(WEAPONS, this.personal);
 223                                 STAT(BUFFS, this) = STAT(BUFFS, this.personal);
 224                                 STAT(BUFF_TIME, this) = STAT(BUFF_TIME, this.personal);
 225                                 this.items = this.personal.items;
 226                                 this.pauserotarmor_finished = time + this.personal.pauserotarmor_finished - this.personal.teleport_time;
 227                                 this.pauserothealth_finished = time + this.personal.pauserothealth_finished - this.personal.teleport_time;
 228                                 this.pauserotfuel_finished = time + this.personal.pauserotfuel_finished - this.personal.teleport_time;
 229                                 this.pauseregen_finished = time + this.personal.pauseregen_finished - this.personal.teleport_time;
 230                                 STAT(STRENGTH_FINISHED, this) = time + STAT(STRENGTH_FINISHED, this.personal) - this.personal.teleport_time;
 231                                 STAT(INVINCIBLE_FINISHED, this) = time + STAT(INVINCIBLE_FINISHED, this.personal) - this.personal.teleport_time;
 232
 233                                 if(!autocvar_g_allow_checkpoints)
 234                                         DID_CHEAT();
 235                                 break;
 236                         }
 237                         if(IS_DEAD(this))
 238                                 sprint(this, "UR DEAD AHAHAH))\n");
 239                         else
 240                                 sprint(this, "No waypoint set, cheater (use g_waypointsprite_personal to set one)\n");
 241                         break;
 242                 case CHIMPULSE_TELEPORT.impulse:
 243                         IS_CHEAT(this, imp, 0, 0);
 244                         if(this.move_movetype == MOVETYPE_NOCLIP)
 245                         {
 246                                 e = find(NULL, classname, "info_autoscreenshot");
 247                                 if(e)
 248                                 {
 249                                         sprint(this, "Emergency teleport used info_autoscreenshot location\n");
 250                                         setorigin(this, e.origin);
 251                                         this.angles = e.angles;
 252                                         delete(e);
 253                                         // should we? this.angles_x = -this.angles_x;
 254                                         this.fixangle = true;
 255                                         this.velocity = '0 0 0';
 256                                         DID_CHEAT();
 257                                         break;
 258                                 }
 259                         }
 260                         if(MoveToRandomMapLocation(this, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, ((gamestart_sv_cheats < 2) ? 100 : 100000), 384, 384))
 261                         {
 262                                 sprint(this, "Emergency teleport used random location\n");
 263                                 this.angles_x = -this.angles.x;
 264                                 this.fixangle = true;
 265                                 this.velocity = '0 0 0';
 266                                 DID_CHEAT();
 267                                 break;
 268                         }
 269                         sprint(this, "Emergency teleport could not find a good location, forget it!\n");
 270                         break;
 271                 case CHIMPULSE_R00T.impulse:
 272                         IS_CHEAT(this, imp, 0, 0);
 273                         RandomSelection_Init();
 274                         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it) && DIFF_TEAM(it, this), { RandomSelection_AddEnt(it, 1, 1); });
 275                         if(RandomSelection_chosen_ent)
 276                                 e = RandomSelection_chosen_ent;
 277                         else
 278                                 e = this;
 279
 280                         Send_Effect(EFFECT_ROCKET_EXPLODE, e.origin, '0 0 0', 1);
 281                         sound(e, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 282
 283                         e2 = spawn();
 284                         setorigin(e2, e.origin);
 285                         RadiusDamage(e2, this, 1000, 0, 128, NULL, NULL, 500, DEATH_CHEAT.m_id, DMG_NOWEP, e);
 286                         delete(e2);
 287
 288                         LOG_INFO("404 Sportsmanship not found.");
 289                         DID_CHEAT();
 290                         break;
 291         }
 292
 293         END_CHEAT_FUNCTION();
 294 }
 295
 296 float drag_lastcnt;
 297 float CheatCommand(entity this, int argc)
 298 {
 299         BEGIN_CHEAT_FUNCTION();
 300         string cmd;
 301         cmd = argv(0);
 302         switch(cmd)
 303         {
 304                 float effectnum, f;
 305                 vector start, end;
 306
 307                 case "pointparticles":
 308                         IS_CHEAT(this, 0, argc, 0);
 309                         if(argc == 5)
 310                         {
 311                                 // arguments:
 312                                 //   effectname
 313                                 //   origin (0..1, on crosshair line)
 314                                 //   velocity
 315                                 //   howmany
 316                                 f = stof(argv(2));
 317                                 crosshair_trace(this);
 318                                 start = (1-f) * this.origin + f * trace_endpos;
 319                                 end = stov(argv(3));
 320                                 f = stof(argv(4));
 321                                 Send_Effect_(argv(1), start, end, f);
 322                                 DID_CHEAT();
 323                                 break;
 324                         }
 325                         sprint(this, "Usage: sv_cheats 1; restart; cmd pointparticles effectname position(0..1) velocityvector multiplier\n");
 326                         break;
 327                 case "trailparticles":
 328                         IS_CHEAT(this, 0, argc, 0);
 329                         if(argc == 2)
 330                         {
 331                                 // arguments:
 332                                 //   effectname
 333                                 effectnum = _particleeffectnum(argv(1));
 334                                 W_SetupShot(this, weaponentities[0], false, false, SND_Null, CH_WEAPON_A, 0, 0);
 335                                 traceline(w_shotorg, w_shotorg + w_shotdir * max_shot_distance, MOVE_NORMAL, this);
 336                                 __trailparticles(this, effectnum, w_shotorg, trace_endpos);
 337                                 DID_CHEAT();
 338                                 break;
 339                         }
 340                         sprint(this, "Usage: sv_cheats 1; restart; cmd trailparticles effectname\n");
 341                         break;
 342                 case "make":
 343                         IS_CHEAT(this, 0, argc, 0);
 344                         if(argc == 3)
 345                         {
 346                                 // arguments:
 347                                 //   modelname mode
 348                                 f = stof(argv(2));
 349                                 W_SetupShot(this, weaponentities[0], false, false, SND_Null, CH_WEAPON_A, 0, 0);
 350                                 traceline(w_shotorg, w_shotorg + w_shotdir * 2048, MOVE_NORMAL, this);
 351                                 if((trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT) || trace_fraction == 1)
 352                                 {
 353                                         sprint(this, "cannot make stuff there (bad surface)\n");
 354                                 }
 355                                 else
 356                                 {
 357                                         entity e = spawn();
 358                                         e.model = strzone(argv(1));
 359                                         e.mdl = "rocket_explode";
 360                                         SetResourceExplicit(e, RES_HEALTH, 1000);
 361                                         setorigin(e, trace_endpos);
 362                                         e.effects = EF_NOMODELFLAGS;
 363                                         if(f == 1)
 364                                         {
 365                                                 e.angles = fixedvectoangles2(trace_plane_normal, v_forward);
 366                                                 e.angles = AnglesTransform_ApplyToAngles(e.angles, '-90 0 0'); // so unrotated models work
 367                                         }
 368                                         spawnfunc_func_breakable(e);
 369                                         // now, is it valid?
 370                                         if(f == 0)
 371                                         {
 372                                                 tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_NORMAL, e);
 373                                                 if(trace_startsolid)
 374                                                 {
 375                                                         delete(e);
 376                                                         sprint(this, "cannot make stuff there (no space)\n");
 377                                                 }
 378                                                 else
 379                                                         DID_CHEAT();
 380                                         }
 381                                         else
 382                                                 DID_CHEAT();
 383                                 }
 384                         }
 385                         else
 386                                 sprint(this, "Usage: sv_cheats 1; restart; cmd make models/... 0/1/2\n");
 387                         break;
 388                 case "penalty":
 389                         IS_CHEAT(this, 0, argc, 0);
 390                         if(argc == 3)
 391                         {
 392                                 race_ImposePenaltyTime(this, stof(argv(1)), argv(2));
 393                                 DID_CHEAT();
 394                                 break;
 395                         }
 396                         sprint(this, "Usage: sv_cheats 1; restart; cmd penalty 5.0 AHAHAHAHAHAHAH))\n");
 397                         break;
 398                 case "dragbox_spawn": {
 399                         IS_CHEAT(this, 0, argc, 0);
 400                         entity e = new(dragbox_box);
 401                         setthink(e, DragBox_Think);
 402                         e.nextthink = time;
 403                         e.solid = -1; // black
 404                         setmodel(e, MDL_Null); // network it
 405                         if(argc == 4)
 406                                 e.cnt = stof(argv(1));
 407                         else
 408                                 e.cnt = max(0, drag_lastcnt);
 409
 410                         e.aiment = new(dragbox_corner_1);
 411                         e.aiment.owner = e;
 412                         setmodel(e.aiment, MDL_MARKER);
 413                         e.aiment.skin = 0;
 414                         setsize(e.aiment, '0 0 0', '0 0 0');
 415                         if(argc == 4)
 416                                 setorigin(e.aiment, stov(argv(2)));
 417                         else
 418                         {
 419                                 crosshair_trace(this);
 420                                 setorigin(e.aiment, trace_endpos);
 421                         }
 422
 423                         e.enemy = new(dragbox_corner_2);
 424                         e.enemy.owner = e;
 425                         setmodel(e.enemy, MDL_MARKER);
 426                         e.enemy.skin = 1;
 427                         setsize(e.enemy, '0 0 0', '0 0 0');
 428                         end = normalize(this.origin + this.view_ofs - e.aiment.origin);
 429                         end.x = (end.x > 0) * 2 - 1;
 430                         end.y = (end.y > 0) * 2 - 1;
 431                         end.z = (end.z > 0) * 2 - 1;
 432                         if(argc == 4)
 433                                 setorigin(e.enemy, stov(argv(3)));
 434                         else
 435                                 setorigin(e.enemy, e.aiment.origin + 32 * end);
 436
 437                         e.killindicator = new(drag_digit);
 438                         e.killindicator.owner = e;
 439                         setattachment(e.killindicator, e, "");
 440                         setorigin(e.killindicator, '0 0 -8');
 441                         e.killindicator.killindicator = new(drag_digit);
 442                         e.killindicator.killindicator.owner = e;
 443                         setattachment(e.killindicator.killindicator, e, "");
 444                         setorigin(e.killindicator.killindicator, '0 0 8');
 445                         DID_CHEAT();
 446                         break;
 447                 }
 448                 case "dragpoint_spawn": {
 449                         IS_CHEAT(this, 0, argc, 0);
 450                         entity e = new(dragpoint);
 451                         setthink(e, DragBox_Think);
 452                         e.nextthink = time;
 453                         e.solid = 0; // nothing special
 454                         setmodel(e, MDL_MARKER);
 455                         setsize(e, STAT(PL_MIN, this), STAT(PL_MAX, this));
 456                         e.skin = 2;
 457                         if(argc == 3)
 458                                 e.cnt = stof(argv(1));
 459                         else
 460                                 e.cnt = drag_lastcnt;
 461                         if(argc == 3)
 462                                 setorigin(e, stov(argv(2)));
 463                         else
 464                         {
 465                                 crosshair_trace(this);
 466                                 setorigin(e, trace_endpos + normalize(this.origin + this.view_ofs - trace_endpos));
 467                                 move_out_of_solid(e);
 468                         }
 469
 470                         e.killindicator = new(drag_digit);
 471                         e.killindicator.owner = e;
 472                         setattachment(e.killindicator, e, "");
 473                         setorigin(e.killindicator, '0 0 40');
 474                         e.killindicator.killindicator = new(drag_digit);
 475                         e.killindicator.killindicator.owner = e;
 476                         setattachment(e.killindicator.killindicator, e, "");
 477                         setorigin(e.killindicator.killindicator, '0 0 56');
 478                         DID_CHEAT();
 479                         break;
 480                 }
 481                 case "drag_remove":
 482                         IS_CHEAT(this, 0, argc, 0);
 483                         RandomSelection_Init();
 484                         crosshair_trace(this);
 485                         for(entity e = NULL; (e = find(e, classname, "dragbox_box")); )
 486                                 RandomSelection_AddEnt(e, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 487                         for(entity e = NULL; (e = find(e, classname, "dragpoint")); )
 488                                 RandomSelection_AddEnt(e, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 489                         if(RandomSelection_chosen_ent)
 490                         {
 491                                 delete(RandomSelection_chosen_ent.killindicator.killindicator);
 492                                 delete(RandomSelection_chosen_ent.killindicator);
 493                                 if(RandomSelection_chosen_ent.aiment)
 494                                         delete(RandomSelection_chosen_ent.aiment);
 495                                 if(RandomSelection_chosen_ent.enemy)
 496                                         delete(RandomSelection_chosen_ent.enemy);
 497                                 delete(RandomSelection_chosen_ent);
 498                         }
 499                         DID_CHEAT();
 500                         break;
 501                 case "drag_setcnt":
 502                         IS_CHEAT(this, 0, argc, 0);
 503                         if(argc == 2)
 504                         {
 505                                 RandomSelection_Init();
 506                                 crosshair_trace(this);
 507                                 for(entity e = NULL; (e = find(e, classname, "dragbox_box")); )
 508                                         RandomSelection_AddEnt(e, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 509                                 for(entity e = NULL; (e = find(e, classname, "dragpoint")); )
 510                                         RandomSelection_AddEnt(e, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 511                                 if(RandomSelection_chosen_ent)
 512                                 {
 513                                         if(substring(argv(1), 0, 1) == "*")
 514                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = RandomSelection_chosen_ent.cnt + stof(substring(argv(1), 1, -1));
 515                                         else
 516                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = stof(argv(1));
 517                                 }
 518                                 DID_CHEAT();
 519                                 break;
 520                         }
 521                         sprint(this, "Usage: sv_cheats 1; restart; cmd dragbox_setcnt cnt\n");
 522                         break;
 523                 case "drag_save":
 524                         IS_CHEAT(this, 0, argc, 0);
 525                         if(argc == 2)
 526                         {
 527                                 f = fopen(argv(1), FILE_WRITE);
 528                                 fputs(f, "cmd drag_clear\n");
 529                                 for(entity e = NULL; (e = find(e, classname, "dragbox_box")); )
 530                                 {
 531                                         fputs(f, strcat("cmd dragbox_spawn ", ftos(e.cnt), " \"", vtos(e.aiment.origin), "\" \"", vtos(e.enemy.origin), "\"\n"));
 532                                 }
 533                                 for(entity e = NULL; (e = find(e, classname, "dragpoint")); )
 534                                 {
 535                                         fputs(f, strcat("cmd dragpoint_spawn ", ftos(e.cnt), " \"", vtos(e.origin), "\"\n"));
 536                                 }
 537                                 fclose(f);
 538                                 DID_CHEAT();
 539                                 break;
 540                         }
 541                         sprint(this, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 542                         break;
 543                 case "drag_saveraceent":
 544                         IS_CHEAT(this, 0, argc, 0);
 545                         if(argc == 2)
 546                         {
 547                                 f = fopen(argv(1), FILE_WRITE);
 548                                 for(entity e = NULL; (e = find(e, classname, "dragbox_box")); )
 549                                 {
 550                                         fputs(f, "{\n");
 551                                         fputs(f, "\"classname\" \"trigger_race_checkpoint\"\n");
 552                                         fputs(f, strcat("\"origin\" \"", ftos(e.absmin.x), " ", ftos(e.absmin.y), " ", ftos(e.absmin.z), "\"\n"));
 553                                         fputs(f, strcat("\"maxs\" \"", ftos(e.absmax.x - e.absmin.x), " ", ftos(e.absmax.y - e.absmin.y), " ", ftos(e.absmax.z - e.absmin.z), "\"\n"));
 554                                         fputs(f, strcat("\"cnt\" \"", ftos(e.cnt), "\"\n"));
 555                                         fputs(f, strcat("\"targetname\" \"checkpoint", ftos(e.cnt), "\"\n"));
 556                                         fputs(f, "}\n");
 557                                 }
 558                                 for(entity e = NULL; (e = find(e, classname, "dragpoint")); )
 559                                 {
 560                                         start = '0 0 0';
 561                                         effectnum = 0;
 562                                         for(entity ent = NULL; (ent = find(ent, classname, "dragbox_box")); )
 563                                         {
 564                                                 if((e.cnt <= 0 && ent.cnt == 0) || e.cnt == ent.cnt)
 565                                                 {
 566                                                         start = start + ent.origin;
 567                                                         ++effectnum;
 568                                                 }
 569                                         }
 570                                         start *= 1 / effectnum;
 571                                         fputs(f, "{\n");
 572                                         fputs(f, "\"classname\" \"info_player_race\"\n");
 573                                         fputs(f, strcat("\"angle\" \"", ftos(vectoyaw(start - e.origin)), "\"\n"));
 574                                         fputs(f, strcat("\"origin\" \"", ftos(e.origin.x), " ", ftos(e.origin.y), " ", ftos(e.origin.z), "\"\n"));
 575                                         if(e.cnt == -2)
 576                                         {
 577                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 578                                                 fputs(f, "\"race_place\" \"0\"\n");
 579                                         }
 580                                         else if(e.cnt == -1)
 581                                         {
 582                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 583                                                 fputs(f, "\"race_place\" \"-1\"\n");
 584                                         }
 585                                         else
 586                                         {
 587                                                 fputs(f, strcat("\"target\" \"checkpoint", ftos(e.cnt), "\"\n"));
 588                                                 if(e.cnt == 0)
 589                                                 {
 590                                                         // these need race_place
 591                                                         // counting...
 592                                                         effectnum = 1;
 593                                                         for(entity ent = NULL; (ent = find(ent, classname, "dragpoint")); )
 594                                                         if(ent.cnt == 0)
 595                                                         {
 596                                                                 if(vlen2(ent.origin - start) < vlen2(e.origin - start))
 597                                                                         ++effectnum;
 598                                                                 else if(vlen2(ent.origin - start) == vlen2(e.origin - start) && etof(ent) < etof(e))
 599                                                                         ++effectnum;
 600                                                         }
 601                                                         fputs(f, strcat("\"race_place\" \"", ftos(effectnum), "\"\n"));
 602                                                 }
 603                                         }
 604                                         fputs(f, "}\n");
 605                                 }
 606                                 fclose(f);
 607                                 DID_CHEAT();
 608                                 break;
 609                         }
 610                         sprint(this, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 611                         break;
 612                 case "drag_clear":
 613                         IS_CHEAT(this, 0, argc, 0);
 614                         for(entity e = NULL; (e = find(e, classname, "dragbox_box")); )
 615                                 delete(e);
 616                         for(entity e = NULL; (e = find(e, classname, "dragbox_corner_1")); )
 617                                 delete(e);
 618                         for(entity e = NULL; (e = find(e, classname, "dragbox_corner_2")); )
 619                                 delete(e);
 620                         for(entity e = NULL; (e = find(e, classname, "dragpoint")); )
 621                                 delete(e);
 622                         for(entity e = NULL; (e = find(e, classname, "drag_digit")); )
 623                                 delete(e);
 624                         DID_CHEAT();
 625                         break;
 626                 case "god":
 627                         IS_CHEAT(this, 0, argc, 0);
 628                         BITXOR_ASSIGN(this.flags, FL_GODMODE);
 629                         if(this.flags & FL_GODMODE)
 630                         {
 631                                 sprint(this, "godmode ON\n");
 632                                 DID_CHEAT();
 633                         }
 634                         else
 635                                 sprint(this, "godmode OFF\n");
 636                         break;
 637                 case "notarget":
 638                         IS_CHEAT(this, 0, argc, 0);
 639                         BITXOR_ASSIGN(this.flags, FL_NOTARGET);
 640                         if(this.flags & FL_NOTARGET)
 641                         {
 642                                 sprint(this, "notarget ON\n");
 643                                 DID_CHEAT();
 644                         }
 645                         else
 646                                 sprint(this, "notarget OFF\n");
 647                         break;
 648                 case "noclip":
 649                         IS_CHEAT(this, 0, argc, 0);
 650                         if(this.move_movetype != MOVETYPE_NOCLIP)
 651                         {
 652                                 set_movetype(this, MOVETYPE_NOCLIP);
 653                                 sprint(this, "noclip ON\n");
 654                                 DID_CHEAT();
 655                         }
 656                         else
 657                         {
 658                                 set_movetype(this, MOVETYPE_WALK);
 659                                 sprint(this, "noclip OFF\n");
 660                         }
 661                         break;
 662                 case "fly":
 663                         IS_CHEAT(this, 0, argc, 0);
 664                         if(this.move_movetype != MOVETYPE_FLY)
 665                         {
 666                                 set_movetype(this, MOVETYPE_FLY);
 667                                 sprint(this, "flymode ON\n");
 668                                 DID_CHEAT();
 669                         }
 670                         else
 671                         {
 672                                 set_movetype(this, MOVETYPE_WALK);
 673                                 sprint(this, "flymode OFF\n");
 674                         }
 675                         break;
 676                 case "give":
 677                         IS_CHEAT(this, 0, argc, 0);
 678                         if(GiveItems(this, 1, argc))
 679                                 DID_CHEAT();
 680                         break;
 681                 case "usetarget":
 682                         IS_CHEAT(this, 0, argc, 0);
 683                         entity e = spawn();
 684                         e.target = argv(1);
 685                         SUB_UseTargets(e, this, NULL);
 686                         delete(e);
 687                         DID_CHEAT();
 688                         break;
 689                 case "killtarget":
 690                         IS_CHEAT(this, 0, argc, 0);
 691                         entity e2 = spawn();
 692                         e2.killtarget = argv(1);
 693                         SUB_UseTargets(e2, this, NULL);
 694                         delete(e2);
 695                         DID_CHEAT();
 696                         break;
 697                 case "teleporttotarget":
 698                         IS_CHEAT(this, 0, argc, 0);
 699                         entity ent = new(cheattriggerteleport);
 700                         setorigin(ent, ent.origin);
 701                         ent.target = argv(1);
 702                         teleport_findtarget(ent);
 703                         if(!wasfreed(ent))
 704                         {
 705                                 Simple_TeleportPlayer(ent, this);
 706                                 delete(ent);
 707                                 DID_CHEAT();
 708                         }
 709                         break;
 710         }
 711
 712         END_CHEAT_FUNCTION();
 713 }
 714
 715 .entity dragentity;
 716
 717 float CheatFrame(entity this)
 718 {
 719         BEGIN_CHEAT_FUNCTION();
 720
 721         // Dragging can be used as either a cheat, or a function for some objects. If sv_cheats is active,
 722         // the cheat dragging is used (unlimited pickup range and any entity can be carried). If sv_cheats
 723         // is disabled, normal dragging is used (limited pickup range and only dragable objects can be carried),
 724         // grabbing itself no longer being accounted as cheating.
 725
 726         switch(0)
 727         {
 728                 default:
 729                         if(this.maycheat || (gamestart_sv_cheats && autocvar_sv_cheats))
 730                         {
 731                                 // use cheat dragging if cheats are enabled
 732                                 //if(Drag_IsDragging(this))
 733                                         //crosshair_trace_plusvisibletriggers(this);
 734                                 Drag(this, true, true);
 735                         }
 736                         else
 737                         {
 738                                 Drag(this, false, false); // execute dragging
 739                         }
 740                         break;
 741         }
 742
 743         END_CHEAT_FUNCTION();
 744 }
 745
 746
 747
 748
 749
 750 // ENTITY DRAGGING
 751
 752 // on dragger:
 753 .float draggravity;
 754 .float dragspeed; // speed of mouse wheel action
 755 .float dragdistance; // distance of dragentity's draglocalvector from view_ofs
 756 .vector draglocalvector; // local attachment vector of the dragentity
 757 .float draglocalangle;
 758 // on draggee:
 759 .entity draggedby;
 760 .float dragmovetype;
 761
 762 float Drag(entity this, float force_allow_pick, float ischeat)
 763 {
 764         BEGIN_CHEAT_FUNCTION();
 765
 766         // returns true when an entity has been picked up
 767         // If pick is true, the object can also be picked up if it's not being held already
 768         // If pick is false, only keep dragging the object if it's already being held
 769
 770         switch(0)
 771         {
 772                 default:
 773                         if(Drag_IsDragging(this))
 774                         {
 775                                 if(PHYS_INPUT_BUTTON_DRAG(this))
 776                                 {
 777                                         if(CS(this).impulse == 10 || CS(this).impulse == 15 || CS(this).impulse == 18)
 778                                         {
 779                                                 Drag_MoveForward(this);
 780                                                 CS(this).impulse = 0;
 781                                         }
 782                                         else if(CS(this).impulse == 12 || CS(this).impulse == 16 || CS(this).impulse == 19)
 783                                         {
 784                                                 Drag_MoveBackward(this);
 785                                                 CS(this).impulse = 0;
 786                                         }
 787                                         else if(CS(this).impulse >= 1 && CS(this).impulse <= 9)
 788                                         {
 789                                                 Drag_SetSpeed(this, CS(this).impulse - 1);
 790                                         }
 791                                         else if(CS(this).impulse == 14)
 792                                         {
 793                                                 Drag_SetSpeed(this, 9);
 794                                         }
 795
 796                                         if(frametime)
 797                                                 Drag_Update(this);
 798                                 }
 799                                 else
 800                                 {
 801                                         Drag_Finish(this);
 802                                 }
 803                         }
 804                         else if(Drag_CanDrag(this) && PHYS_INPUT_BUTTON_DRAG(this))
 805                         {
 806                                 crosshair_trace_plusvisibletriggers(this);
 807                                 entity e = trace_ent;
 808                                 float pick = force_allow_pick;
 809                                 if (e && !pick && vdist(this.origin - e.origin, <=, autocvar_g_grab_range))
 810                                 {
 811                                         // pick is true if the object can be picked up. While an object is being carried, the Drag() function
 812                                         // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 813                                         // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 814                                         // it goes out of range while slinging it around.
 815
 816                                         switch(e.grab)
 817                                         {
 818                                                 case 0: // can't grab
 819                                                         break;
 820                                                 case 1: // owner can grab
 821                                                         if(e.owner == this || e.realowner == this)
 822                                                                 pick = true;
 823                                                         break;
 824                                                 case 2: // owner and team mates can grab
 825                                                         if(SAME_TEAM(e.owner, this) || SAME_TEAM(e.realowner, this) || e.team == this.team)
 826                                                                 pick = true;
 827                                                         break;
 828                                                 case 3: // anyone can grab
 829                                                         pick = true;
 830                                                         break;
 831                                                 default:
 832                                                         break;
 833                                         }
 834                                 }
 835                                 // Find e and pick
 836                                 if(e && pick && Drag_IsDraggable(e, this))
 837                                 {
 838                                         if(ischeat)
 839                                                 IS_CHEAT(this, 0, 0, CHRAME_DRAG);
 840                                         if(e.draggedby)
 841                                                 Drag_Finish(e.draggedby);
 842                                         if(e.tag_entity)
 843                                                 detach_sameorigin(e);
 844                                         Drag_Begin(this, e, trace_endpos);
 845                                         if(ischeat)
 846                                                 DID_CHEAT();
 847                                         return true;
 848                                 }
 849                         }
 850                         break;
 851         }
 852         return false;
 853 }
 854
 855 void Drag_Begin(entity dragger, entity draggee, vector touchpoint)
 856 {
 857         float tagscale;
 858
 859         draggee.dragmovetype = draggee.move_movetype;
 860         draggee.draggravity = draggee.gravity;
 861         set_movetype(draggee, MOVETYPE_WALK);
 862         draggee.gravity = 0.00001;
 863         UNSET_ONGROUND(draggee);
 864         draggee.draggedby = dragger;
 865
 866         dragger.dragentity = draggee;
 867
 868         dragger.dragdistance = vlen(touchpoint - dragger.origin - dragger.view_ofs);
 869         dragger.draglocalangle = draggee.angles.y - dragger.v_angle.y;
 870         touchpoint = touchpoint - gettaginfo(draggee, 0);
 871         tagscale = (vlen(v_forward) ** -2);
 872         dragger.draglocalvector_x = touchpoint * v_forward * tagscale;
 873         dragger.draglocalvector_y = touchpoint * v_right * tagscale;
 874         dragger.draglocalvector_z = touchpoint * v_up * tagscale;
 875
 876         dragger.dragspeed = 64;
 877 }
 878
 879 void Drag_Finish(entity dragger)
 880 {
 881         entity draggee;
 882         draggee = dragger.dragentity;
 883         if(dragger)
 884                 dragger.dragentity = NULL;
 885         draggee.draggedby = NULL;
 886         set_movetype(draggee, draggee.dragmovetype);
 887         draggee.gravity = draggee.draggravity;
 888
 889         switch(draggee.move_movetype)
 890         {
 891                 case MOVETYPE_TOSS:
 892                 case MOVETYPE_WALK:
 893                 case MOVETYPE_STEP:
 894                 case MOVETYPE_FLYMISSILE:
 895                 case MOVETYPE_BOUNCE:
 896                 case MOVETYPE_BOUNCEMISSILE:
 897                 case MOVETYPE_PHYSICS:
 898                         break;
 899                 default:
 900                         draggee.velocity = '0 0 0';
 901                         break;
 902         }
 903
 904         if((draggee.flags & FL_ITEM) && (vdist(draggee.velocity, <, 32)))
 905         {
 906                 draggee.velocity = '0 0 0';
 907                 SET_ONGROUND(draggee); // floating items are FUN
 908         }
 909 }
 910
 911 bool drag_undraggable(entity draggee, entity dragger)
 912 {
 913         // stuff probably shouldn't need this, we should figure out why they do!
 914         // exceptions of course are observers and weapon entities, where things mess up
 915         return false;
 916 }
 917
 918 float Drag_IsDraggable(entity draggee, entity dragger)
 919 {
 920         // TODO add more checks for bad stuff here
 921         if(draggee == NULL)
 922                 return false;
 923         if(draggee.classname == "door") // FIXME find out why these must be excluded, or work around the problem (trying to drag these causes like 4 fps)
 924                 return false; // probably due to BSP collision
 925         //if(draggee.model == "")
 926         //      return false;
 927
 928         return ((draggee.draggable) ? draggee.draggable(draggee, dragger) : true);
 929 }
 930
 931 float Drag_MayChangeAngles(entity draggee)
 932 {
 933         // TODO add more checks for bad stuff here
 934         if(substring(draggee.model, 0, 1) == "*")
 935                 return false;
 936         return true;
 937 }
 938
 939 void Drag_MoveForward(entity dragger)
 940 {
 941         dragger.dragdistance += dragger.dragspeed;
 942 }
 943
 944 void Drag_SetSpeed(entity dragger, float s)
 945 {
 946         dragger.dragspeed = (2 ** s);
 947 }
 948
 949 void Drag_MoveBackward(entity dragger)
 950 {
 951         dragger.dragdistance = max(0, dragger.dragdistance - dragger.dragspeed);
 952 }
 953
 954 void Drag_Update(entity dragger)
 955 {
 956         vector curorigin, neworigin, goodvelocity;
 957         float f;
 958         entity draggee;
 959
 960         draggee = dragger.dragentity;
 961         UNSET_ONGROUND(draggee);
 962
 963         curorigin = gettaginfo(draggee, 0);
 964         curorigin = curorigin + v_forward * dragger.draglocalvector.x + v_right * dragger.draglocalvector.y + v_up * dragger.draglocalvector.z;
 965         makevectors(dragger.v_angle);
 966         neworigin = dragger.origin + dragger.view_ofs + v_forward * dragger.dragdistance;
 967         goodvelocity = (neworigin - curorigin) * (1 / frametime);
 968
 969         while(draggee.angles.y - dragger.v_angle.y - dragger.draglocalangle > 180)
 970                 dragger.draglocalangle += 360;
 971         while(draggee.angles.y - dragger.v_angle.y - dragger.draglocalangle <= -180)
 972                 dragger.draglocalangle -= 360;
 973
 974         f = min(frametime * 10, 1);
 975         draggee.velocity = draggee.velocity * (1 - f) + goodvelocity * f;
 976
 977         if(Drag_MayChangeAngles(draggee))
 978                 draggee.angles_y = draggee.angles.y * (1 - f) + (dragger.v_angle.y + dragger.draglocalangle) * f;
 979
 980         draggee.ltime = max(servertime + serverframetime, draggee.ltime); // fixes func_train breakage
 981
 982         vector vecs = '0 0 0';
 983         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
 984         if(dragger.(weaponentity).movedir.x > 0)
 985                 vecs = dragger.(weaponentity).movedir;
 986
 987         vector dv = v_right * -vecs_y + v_up * vecs_z;
 988
 989         te_lightning1(draggee, dragger.origin + dragger.view_ofs + dv, curorigin);
 990 }
 991
 992 float Drag_CanDrag(entity dragger)
 993 {
 994         return (!IS_DEAD(dragger)) || (IS_PLAYER(dragger));
 995 }
 996
 997 float Drag_IsDragging(entity dragger)
 998 {
 999         if(!dragger.dragentity)
1000                 return false;
1001         if(wasfreed(dragger.dragentity) || dragger.dragentity.draggedby != dragger)
1002         {
1003                 dragger.dragentity = NULL;
1004                 return false;
1005         }
1006         if(!Drag_CanDrag(dragger) || !Drag_IsDraggable(dragger.dragentity, dragger))
1007         {
1008                 Drag_Finish(dragger);
1009                 return false;
1010         }
1011         return true;
1012 }
1013
1014 void Drag_MoveDrag(entity from, entity to)
1015 {
1016         if(from.draggedby)
1017         {
1018                 to.draggedby = from.draggedby;
1019                 to.draggedby.dragentity = to;
1020                 from.draggedby = NULL;
1021         }
1022 }
1023
1024 void DragBox_Think(entity this)
1025 {
1026         if(this.aiment && this.enemy)
1027         {
1028                 this.origin_x = (this.aiment.origin.x + this.enemy.origin.x) * 0.5;
1029                 this.origin_y = (this.aiment.origin.y + this.enemy.origin.y) * 0.5;
1030                 this.origin_z = (this.aiment.origin.z + this.enemy.origin.z) * 0.5;
1031                 this.maxs_x = fabs(this.aiment.origin.x - this.enemy.origin.x) * 0.5;
1032                 this.maxs_y = fabs(this.aiment.origin.y - this.enemy.origin.y) * 0.5;
1033                 this.maxs_z = fabs(this.aiment.origin.z - this.enemy.origin.z) * 0.5;
1034                 this.mins = -1 * this.maxs;
1035                 setorigin(this, this.origin);
1036                 setsize(this, this.mins, this.maxs); // link edict
1037         }
1038
1039         if(this.cnt == -1) // actually race_place -1
1040         {
1041                 // show "10 10" for qualifying spawns
1042                 setmodel(this.killindicator, MDL_NUM(10));
1043                 setmodel(this.killindicator.killindicator, MDL_NUM(10));
1044         }
1045         else if(this.cnt == -2) // actually race_place 0
1046         {
1047                 // show "10 0" for loser spawns
1048                 setmodel(this.killindicator, MDL_NUM(10));
1049                 setmodel(this.killindicator.killindicator, MDL_NUM(0));
1050         }
1051         else
1052         {
1053                 setmodel(this.killindicator, MDL_NUM(this.cnt % 10));
1054                 setmodel(this.killindicator.killindicator, MDL_NUM(floor(this.cnt / 10)));
1055         }
1056
1057         this.nextthink = time;
1058 }
1059
1060 #endif