qcsrc/server/cheats.qc

   1 void CopyBody(float keepvelocity);
   2
   3 #ifdef NOCHEATS
   4
   5 float CheatImpulse(float i) { return 0; }
   6 float CheatCommand(float argc) { return 0; }
   7 float CheatFrame() { return 0; }
   8 void CheatInit() { cheatcount_total = world.cheatcount; }
   9 void CheatShutdown() { }
  10 void CheatInitClient() { }
  11 void CheatShutdownClient() { }
  12 void Drag_MoveDrag(entity from, entity to) { }
  13
  14 #else
  15
  16 .float maycheat;
  17 float gamestart_sv_cheats;
  18
  19 #define CHIMPULSE_SPEEDRUN_INIT 30
  20 #define CHIMPULSE_GIVE_ALL 99
  21 #define CHIMPULSE_CLONE_MOVING 140
  22 #define CHIMPULSE_SPEEDRUN 141
  23 #define CHIMPULSE_CLONE_STANDING 142
  24 #define CHIMPULSE_TELEPORT 143
  25 #define CHIMPULSE_R00T 148
  26
  27 #define CHRAME_DRAG 8
  28
  29 void CheatInit()
  30 {
  31         gamestart_sv_cheats = autocvar_sv_cheats;
  32 }
  33
  34 void CheatShutdown()
  35 {
  36 }
  37
  38 void CheatInitClient()
  39 {
  40 }
  41
  42 void CheatShutdownClient()
  43 {
  44 }
  45
  46 float CheatsAllowed(float i, float argc, float fr) // the cheat gets passed as argument for possible future ACL checking
  47 {
  48         // dead people cannot cheat
  49         if(self.deadflag != DEAD_NO)
  50                 return 0;
  51         if(self.classname != "player")
  52                 return 0;
  53
  54         // sv_clones
  55         if(i == CHIMPULSE_CLONE_MOVING || i == CHIMPULSE_CLONE_STANDING)
  56                 if(self.lip < sv_clones)
  57                         return 1;
  58
  59         // haha
  60         if(self.maycheat)
  61                 return 1;
  62
  63         // sv_cheats
  64         if(gamestart_sv_cheats && autocvar_sv_cheats)
  65                 return 1;
  66
  67         // if we get here, player is not allowed to cheat. Log it.
  68         if(i)
  69                 bprint(sprintf("Player %s^7 tried to use cheat 'impulse %d'\n", self.netname, i));
  70         else if(argc)
  71                 bprint(sprintf("Player %s^7 tried to use cheat '%s'\n", self.netname, argv(0)));
  72         else if(fr)
  73                 bprint(sprintf("Player %s^7 tried to use cheat frame %d\n", self.netname, fr));
  74         else
  75                 bprint(sprintf("Player %s^7 tried to use an unknown cheat\n", self.netname));
  76
  77         return 0;
  78 }
  79
  80 #define BEGIN_CHEAT_FUNCTION() \
  81         float cheating, attempting; \
  82         cheating = 0; attempting = 0
  83 #define DID_CHEAT() \
  84         ++cheating
  85 #define ADD_CHEATS(e,n) \
  86         cheatcount_total += n; \
  87         e.cheatcount += n
  88 #define END_CHEAT_FUNCTION() \
  89         ADD_CHEATS(self,cheating); \
  90         return attempting
  91 #define IS_CHEAT(i,argc,fr) \
  92         if((++attempting, !CheatsAllowed(i,argc,fr))) \
  93                 break
  94
  95 void spawnfunc_info_autoscreenshot()
  96 {
  97         // empty spawnfunc just so this entity can exist
  98 }
  99
 100 float CheatImpulse(float i)
 101 {
 102         BEGIN_CHEAT_FUNCTION();
 103         switch(i)
 104         {
 105                 entity e, e2;
 106                 vector org;
 107
 108                 case CHIMPULSE_SPEEDRUN_INIT: // deploy personal waypoint
 109                         // shared with regular waypoint init, so this is not a cheat by itself
 110                         if(!self.personal)
 111                         {
 112                                 self.personal = spawn();
 113                                 self.personal.classname = "personal_wp";
 114                         }
 115                         self.personal.origin = self.origin;
 116                         self.personal.v_angle = self.v_angle;
 117                         self.personal.velocity = self.velocity;
 118                         self.personal.ammo_rockets = self.ammo_rockets;
 119                         self.personal.ammo_nails = self.ammo_nails;
 120                         self.personal.ammo_cells = self.ammo_cells;
 121                         self.personal.ammo_shells = self.ammo_shells;
 122                         self.personal.ammo_fuel = self.ammo_fuel;
 123                         self.personal.health = self.health;
 124                         self.personal.armorvalue = self.armorvalue;
 125                         self.personal.weapons = self.weapons;
 126                         self.personal.items = self.items;
 127                         self.personal.pauserotarmor_finished = self.pauserotarmor_finished;
 128                         self.personal.pauserothealth_finished = self.pauserothealth_finished;
 129                         self.personal.pauserotfuel_finished = self.pauserotfuel_finished;
 130                         self.personal.pauseregen_finished = self.pauseregen_finished;
 131                         self.personal.strength_finished = self.strength_finished;
 132                         self.personal.invincible_finished = self.invincible_finished;
 133                         self.personal.teleport_time = time;
 134                         break; // this part itself doesn't cheat, so let's not count this
 135                 case CHIMPULSE_CLONE_MOVING:
 136                         IS_CHEAT(i, 0, 0);
 137                         makevectors (self.v_angle);
 138                         self.velocity = self.velocity + v_forward * 300;
 139                         CopyBody(1);
 140                         self.lip += 1;
 141                         self.velocity = self.velocity - v_forward * 300;
 142                         DID_CHEAT();
 143                         break;
 144                 case CHIMPULSE_CLONE_STANDING:
 145                         IS_CHEAT(i, 0, 0);
 146                         CopyBody(0);
 147                         self.lip += 1;
 148                         DID_CHEAT();
 149                         break;
 150                 case CHIMPULSE_GIVE_ALL:
 151                         IS_CHEAT(i, 0, 0);
 152                         CheatCommand(tokenize_console("give all"));
 153                         break; // already counted as cheat
 154                 case CHIMPULSE_SPEEDRUN:
 155                         IS_CHEAT(i, 0, 0);
 156                         if(self.personal)
 157                         {
 158                                 self.speedrunning = TRUE;
 159                                 tracebox(self.personal.origin, self.mins, self.maxs, self.personal.origin, MOVE_WORLDONLY, self);
 160                                 if(trace_startsolid)
 161                                 {
 162                                         sprint(self, "Cannot move there, cheater - only waypoints set using g_waypointsprite_personal work\n");
 163                                 }
 164                                 else
 165                                 {
 166                                         // Abort speedrun, teleport back
 167                                         setorigin(self, self.personal.origin);
 168                                         self.oldvelocity = self.velocity = self.personal.velocity;
 169                                         self.angles = self.personal.v_angle;
 170                                         self.fixangle = TRUE;
 171                                         if(self.flagcarried)
 172                                         {
 173                                                 bprint("The ", self.flagcarried.netname, " was returned to base by its carrier\n");
 174                                                 ReturnFlag(self.flagcarried);
 175                                         }
 176                                 }
 177                                 if(g_ctf)
 178                                 {
 179                                         self.ammo_rockets = 999;
 180                                         self.ammo_nails = 999;
 181                                         self.ammo_cells = 999;
 182                                         self.ammo_shells = 999;
 183                                         self.ammo_fuel = 999;
 184                                         self.health = start_health;
 185                                         self.armorvalue = start_armorvalue;
 186                                         self.weapons |= weaponsInMap;
 187                                         self.pauserotarmor_finished = time + autocvar_g_balance_pause_armor_rot_spawn;
 188                                         self.pauserothealth_finished = time + autocvar_g_balance_pause_health_rot_spawn;
 189                                         self.pauserotfuel_finished = time + autocvar_g_balance_pause_fuel_rot_spawn;
 190                                         self.pauseregen_finished = time + autocvar_g_balance_pause_health_regen_spawn;
 191                                         self.strength_finished = 0;
 192                                         self.invincible_finished = 0;
 193                                 }
 194                                 else
 195                                 {
 196                                         self.ammo_rockets = self.personal.ammo_rockets;
 197                                         self.ammo_nails = self.personal.ammo_nails;
 198                                         self.ammo_cells = self.personal.ammo_cells;
 199                                         self.ammo_shells = self.personal.ammo_shells;
 200                                         self.ammo_fuel = self.personal.ammo_fuel;
 201                                         self.health = self.personal.health;
 202                                         self.armorvalue = self.personal.armorvalue;
 203                                         self.weapons = self.personal.weapons;
 204                                         self.items = self.personal.items;
 205                                         self.pauserotarmor_finished = time + self.personal.pauserotarmor_finished - self.personal.teleport_time;
 206                                         self.pauserothealth_finished = time + self.personal.pauserothealth_finished - self.personal.teleport_time;
 207                                         self.pauserotfuel_finished = time + self.personal.pauserotfuel_finished - self.personal.teleport_time;
 208                                         self.pauseregen_finished = time + self.personal.pauseregen_finished - self.personal.teleport_time;
 209                                         self.strength_finished = time + self.personal.strength_finished - self.personal.teleport_time;
 210                                         self.invincible_finished = time + self.personal.invincible_finished - self.personal.teleport_time;
 211                                 }
 212                                 DID_CHEAT();
 213                                 break;
 214                         }
 215                         if(self.deadflag != DEAD_NO)
 216                                 sprint(self, "UR DEAD AHAHAH))\n");
 217                         else
 218                                 sprint(self, "No waypoint set, cheater (use g_waypointsprite_personal to set one)\n");
 219                         break;
 220                 case CHIMPULSE_TELEPORT:
 221                         IS_CHEAT(i, 0, 0);
 222                         if(self.movetype == MOVETYPE_NOCLIP)
 223                         {
 224                                 entity e = find(world, classname, "info_autoscreenshot");
 225                                 if(e)
 226                                 {
 227                                         setorigin(self, e.origin);
 228                                         self.angles = e.angles;
 229                                         remove(e);
 230                                         // should we? self.angles_x = -self.angles_x;
 231                                         self.fixangle = TRUE;
 232                                         self.velocity = '0 0 0';
 233                                         DID_CHEAT();
 234                                         break;
 235                                 }
 236                         }
 237                         if(MoveToRandomMapLocation(self, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, ((gamestart_sv_cheats >= 2) ? 100000 : 100), 1024, 256))
 238                         {
 239                                 self.angles_x = -self.angles_x;
 240                                 self.fixangle = TRUE;
 241                                 self.velocity = '0 0 0';
 242                                 DID_CHEAT();
 243                                 break;
 244                         }
 245                         sprint(self, "Emergency teleport could not find a good location, forget it!\n");
 246                         break;
 247                 case CHIMPULSE_R00T:
 248                         IS_CHEAT(i, 0, 0);
 249                         FOR_EACH_PLAYER(e)
 250                         {
 251                                 get_model_parameters(e.playermodel, e.skin);
 252                                 if(get_model_parameters_sex == "Female")
 253                                 {
 254                                         makevectors(e.angles);
 255                                         traceline(e.origin, e.origin + v_right * 256, MOVE_NORMAL, e);
 256                                 }
 257                                 else
 258                                 {
 259                                         org_x = random();
 260                                         org_y = random();
 261                                         org_z = 0;
 262                                         org = normalize(org);
 263                                         traceline(e.origin, e.origin + org * 256, MOVE_NORMAL, e); // random direction
 264                                 }
 265
 266                                 org = findbetterlocation(trace_endpos, 12);
 267
 268                                 e2 = spawn();
 269                                 setorigin(e2, org);
 270                                 pointparticles(particleeffectnum("rocket_explode"), org, '0 0 0', 1);
 271                                 sound(e2, CH_SHOTS, "weapons/rocket_impact.wav", VOL_BASE, ATTN_NORM);
 272                                 RadiusDamage(e2, e, 1000, 0, 128, e, 500, DEATH_CHEAT, world);
 273                                 remove(e2);
 274                         }
 275                         print("404 Sportsmanship not found.\n");
 276                         DID_CHEAT();
 277                         break;
 278         }
 279
 280         END_CHEAT_FUNCTION();
 281 }
 282
 283 void DragBox_Think();
 284 float drag_lastcnt;
 285 float CheatCommand(float argc)
 286 {
 287         BEGIN_CHEAT_FUNCTION();
 288         string cmd;
 289         cmd = argv(0);
 290         switch(cmd)
 291         {
 292                 entity e;
 293                 float effectnum, f;
 294                 vector start, end;
 295                 entity oldself;
 296
 297                 case "pointparticles":
 298                         IS_CHEAT(0, argc, 0);
 299                         if(argc == 5)
 300                         {
 301                                 // arguments:
 302                                 //   effectname
 303                                 //   origin (0..1, on crosshair line)
 304                                 //   velocity
 305                                 //   howmany
 306                                 effectnum = particleeffectnum(argv(1));
 307                                 f = stof(argv(2));
 308                                 crosshair_trace(self);
 309                                 start = (1-f) * self.origin + f * trace_endpos;
 310                                 end = stov(argv(3));
 311                                 f = stof(argv(4));
 312                                 pointparticles(effectnum, start, end, f);
 313                                 DID_CHEAT();
 314                                 break;
 315                         }
 316                         sprint(self, "Usage: sv_cheats 1; restart; cmd pointparticles effectname position(0..1) velocityvector multiplier\n");
 317                         break;
 318                 case "trailparticles":
 319                         IS_CHEAT(0, argc, 0);
 320                         if(argc == 2)
 321                         {
 322                                 // arguments:
 323                                 //   effectname
 324                                 effectnum = particleeffectnum(argv(1));
 325                                 W_SetupShot(self, FALSE, FALSE, "", CH_WEAPON_A, 0);
 326                                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
 327                                 trailparticles(self, effectnum, w_shotorg, trace_endpos);
 328                                 DID_CHEAT();
 329                                 break;
 330                         }
 331                         sprint(self, "Usage: sv_cheats 1; restart; cmd trailparticles effectname\n");
 332                         break;
 333                 case "make":
 334                         IS_CHEAT(0, argc, 0);
 335                         if(argc == 3)
 336                         {
 337                                 // arguments:
 338                                 //   modelname mode
 339                                 f = stof(argv(2));
 340                                 W_SetupShot(self, FALSE, FALSE, "", CH_WEAPON_A, 0);
 341                                 traceline(w_shotorg, w_shotorg + w_shotdir * 2048, MOVE_NORMAL, self);
 342                                 if((trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT) || trace_fraction == 1)
 343                                 {
 344                                         sprint(self, "cannot make stuff there (bad surface)\n");
 345                                 }
 346                                 else
 347                                 {
 348                                         e = spawn();
 349                                         e.model = strzone(argv(1));
 350                                         e.mdl = "rocket_explode";
 351                                         e.health = 1000;
 352                                         setorigin(e, trace_endpos);
 353                                         e.effects = EF_NOMODELFLAGS;
 354                                         if(f == 1)
 355                                         {
 356                                                 e.angles = fixedvectoangles2(trace_plane_normal, v_forward);
 357                                                 e.angles = AnglesTransform_ApplyToAngles(e.angles, '-90 0 0'); // so unrotated models work
 358                                         }
 359                                         oldself = self;
 360                                         self = e;
 361                                         spawnfunc_func_breakable();
 362                                         self = oldself;
 363                                         // now, is it valid?
 364                                         if(f == 0)
 365                                         {
 366                                                 tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_NORMAL, e);
 367                                                 if(trace_startsolid)
 368                                                 {
 369                                                         remove(e);
 370                                                         sprint(self, "cannot make stuff there (no space)\n");
 371                                                 }
 372                                                 else
 373                                                         DID_CHEAT();
 374                                         }
 375                                         else
 376                                                 DID_CHEAT();
 377                                 }
 378                         }
 379                         else
 380                                 sprint(self, "Usage: sv_cheats 1; restart; cmd make models/... 0/1/2\n");
 381                         break;
 382                 case "penalty":
 383                         IS_CHEAT(0, argc, 0);
 384                         if(argc == 3)
 385                         {
 386                                 race_ImposePenaltyTime(self, stof(argv(1)), argv(2));
 387                                 DID_CHEAT();
 388                                 break;
 389                         }
 390                         sprint(self, "Usage: sv_cheats 1; restart; cmd penalty 5.0 AHAHAHAHAHAHAH))\n");
 391                         break;
 392                 case "dragbox_spawn":
 393                         IS_CHEAT(0, argc, 0);
 394                         e = spawn();
 395                         e.classname = "dragbox_box";
 396                         e.think = DragBox_Think;
 397                         e.nextthink = time;
 398                         e.solid = -1; // black
 399                         setmodel(e, "null"); // network it
 400                         if(argc == 4)
 401                                 e.cnt = stof(argv(1));
 402                         else
 403                                 e.cnt = max(0, drag_lastcnt);
 404
 405                         e.aiment = spawn();
 406                         e.aiment.classname = "dragbox_corner_1";
 407                         e.aiment.owner = e;
 408                         setmodel(e.aiment, "models/marker.md3");
 409                         e.aiment.skin = 0;
 410                         setsize(e.aiment, '0 0 0', '0 0 0');
 411                         if(argc == 4)
 412                                 setorigin(e.aiment, stov(argv(2)));
 413                         else
 414                         {
 415                                 crosshair_trace(self);
 416                                 setorigin(e.aiment, trace_endpos);
 417                         }
 418
 419                         e.enemy = spawn();
 420                         e.enemy.classname = "dragbox_corner_2";
 421                         e.enemy.owner = e;
 422                         setmodel(e.enemy, "models/marker.md3");
 423                         e.enemy.skin = 1;
 424                         setsize(e.enemy, '0 0 0', '0 0 0');
 425                         end = normalize(self.origin + self.view_ofs - e.aiment.origin);
 426                         end_x = (end_x > 0) * 2 - 1;
 427                         end_y = (end_y > 0) * 2 - 1;
 428                         end_z = (end_z > 0) * 2 - 1;
 429                         if(argc == 4)
 430                                 setorigin(e.enemy, stov(argv(3)));
 431                         else
 432                                 setorigin(e.enemy, e.aiment.origin + 32 * end);
 433
 434                         e.killindicator = spawn();
 435                         e.killindicator.classname = "drag_digit";
 436                         e.killindicator.owner = e;
 437                         setattachment(e.killindicator, e, "");
 438                         setorigin(e.killindicator, '0 0 -8');
 439                         e.killindicator.killindicator = spawn();
 440                         e.killindicator.killindicator.classname = "drag_digit";
 441                         e.killindicator.killindicator.owner = e;
 442                         setattachment(e.killindicator.killindicator, e, "");
 443                         setorigin(e.killindicator.killindicator, '0 0 8');
 444                         DID_CHEAT();
 445                         break;
 446                 case "dragpoint_spawn":
 447                         IS_CHEAT(0, argc, 0);
 448                         e = spawn();
 449                         e.classname = "dragpoint";
 450                         e.think = DragBox_Think;
 451                         e.nextthink = time;
 452                         e.solid = 0; // nothing special
 453                         setmodel(e, "models/marker.md3");
 454                         setsize(e, PL_MIN, PL_MAX);
 455                         e.skin = 2;
 456                         if(argc == 3)
 457                                 e.cnt = stof(argv(1));
 458                         else
 459                                 e.cnt = drag_lastcnt;
 460                         if(argc == 3)
 461                                 setorigin(e, stov(argv(2)));
 462                         else
 463                         {
 464                                 crosshair_trace(self);
 465                                 setorigin(e, trace_endpos + normalize(self.origin + self.view_ofs - trace_endpos));
 466                                 move_out_of_solid(e);
 467                         }
 468
 469                         e.killindicator = spawn();
 470                         e.killindicator.classname = "drag_digit";
 471                         e.killindicator.owner = e;
 472                         setattachment(e.killindicator, e, "");
 473                         setorigin(e.killindicator, '0 0 40');
 474                         e.killindicator.killindicator = spawn();
 475                         e.killindicator.killindicator.classname = "drag_digit";
 476                         e.killindicator.killindicator.owner = e;
 477                         setattachment(e.killindicator.killindicator, e, "");
 478                         setorigin(e.killindicator.killindicator, '0 0 56');
 479                         DID_CHEAT();
 480                         break;
 481                 case "drag_remove":
 482                         IS_CHEAT(0, argc, 0);
 483                         RandomSelection_Init();
 484                         crosshair_trace(self);
 485                         for(e = world; (e = find(e, classname, "dragbox_box")); )
 486                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 487                         for(e = world; (e = find(e, classname, "dragpoint")); )
 488                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 489                         if(RandomSelection_chosen_ent)
 490                         {
 491                                 remove(RandomSelection_chosen_ent.killindicator.killindicator);
 492                                 remove(RandomSelection_chosen_ent.killindicator);
 493                                 if(RandomSelection_chosen_ent.aiment)
 494                                         remove(RandomSelection_chosen_ent.aiment);
 495                                 if(RandomSelection_chosen_ent.enemy)
 496                                         remove(RandomSelection_chosen_ent.enemy);
 497                                 remove(RandomSelection_chosen_ent);
 498                         }
 499                         DID_CHEAT();
 500                         break;
 501                 case "drag_setcnt":
 502                         IS_CHEAT(0, argc, 0);
 503                         if(argc == 2)
 504                         {
 505                                 RandomSelection_Init();
 506                                 crosshair_trace(self);
 507                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 508                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 509                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 510                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 511                                 if(RandomSelection_chosen_ent)
 512                                 {
 513                                         if(substring(argv(1), 0, 1) == "*")
 514                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = RandomSelection_chosen_ent.cnt + stof(substring(argv(1), 1, -1));
 515                                         else
 516                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = stof(argv(1));
 517                                 }
 518                                 DID_CHEAT();
 519                                 break;
 520                         }
 521                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_setcnt cnt\n");
 522                         break;
 523                 case "drag_save":
 524                         IS_CHEAT(0, argc, 0);
 525                         if(argc == 2)
 526                         {
 527                                 f = fopen(argv(1), FILE_WRITE);
 528                                 fputs(f, "cmd drag_clear\n");
 529                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 530                                 {
 531                                         fputs(f, strcat("cmd dragbox_spawn ", ftos(e.cnt), " \"", vtos(e.aiment.origin), "\" \"", vtos(e.enemy.origin), "\"\n"));
 532                                 }
 533                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 534                                 {
 535                                         fputs(f, strcat("cmd dragpoint_spawn ", ftos(e.cnt), " \"", vtos(e.origin), "\"\n"));
 536                                 }
 537                                 fclose(f);
 538                                 DID_CHEAT();
 539                                 break;
 540                         }
 541                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 542                         break;
 543                 case "drag_saveraceent":
 544                         IS_CHEAT(0, argc, 0);
 545                         if(argc == 2)
 546                         {
 547                                 f = fopen(argv(1), FILE_WRITE);
 548                                 for(e = world; (e = find(e, classname, "dragbox_box")); )
 549                                 {
 550                                         fputs(f, "{\n");
 551                                         fputs(f, "\"classname\" \"trigger_race_checkpoint\"\n");
 552                                         fputs(f, strcat("\"origin\" \"", ftos(e.absmin_x), " ", ftos(e.absmin_y), " ", ftos(e.absmin_z), "\"\n"));
 553                                         fputs(f, strcat("\"maxs\" \"", ftos(e.absmax_x - e.absmin_x), " ", ftos(e.absmax_y - e.absmin_y), " ", ftos(e.absmax_z - e.absmin_z), "\"\n"));
 554                                         fputs(f, strcat("\"cnt\" \"", ftos(e.cnt), "\"\n"));
 555                                         fputs(f, strcat("\"targetname\" \"checkpoint", ftos(e.cnt), "\"\n"));
 556                                         fputs(f, "}\n");
 557                                 }
 558                                 for(e = world; (e = find(e, classname, "dragpoint")); )
 559                                 {
 560                                         start = '0 0 0';
 561                                         effectnum = 0;
 562                                         for(oldself = world; (oldself = find(oldself, classname, "dragbox_box")); )
 563                                         {
 564                                                 if(e.cnt <= 0 && oldself.cnt == 0 || e.cnt == oldself.cnt)
 565                                                 {
 566                                                         start = start + oldself.origin;
 567                                                         ++effectnum;
 568                                                 }
 569                                         }
 570                                         start *= 1 / effectnum;
 571                                         fputs(f, "{\n");
 572                                         fputs(f, "\"classname\" \"info_player_race\"\n");
 573                                         fputs(f, strcat("\"angle\" \"", ftos(vectoyaw(start - e.origin)), "\"\n"));
 574                                         fputs(f, strcat("\"origin\" \"", ftos(e.origin_x), " ", ftos(e.origin_y), " ", ftos(e.origin_z), "\"\n"));
 575                                         if(e.cnt == -2)
 576                                         {
 577                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 578                                                 fputs(f, "\"race_place\" \"0\"\n");
 579                                         }
 580                                         else if(e.cnt == -1)
 581                                         {
 582                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 583                                                 fputs(f, "\"race_place\" \"-1\"\n");
 584                                         }
 585                                         else
 586                                         {
 587                                                 fputs(f, strcat("\"target\" \"checkpoint", ftos(e.cnt), "\"\n"));
 588                                                 if(e.cnt == 0)
 589                                                 {
 590                                                         // these need race_place
 591                                                         // counting...
 592                                                         effectnum = 1;
 593                                                         for(oldself = world; (oldself = find(oldself, classname, "dragpoint")); )
 594                                                         if(oldself.cnt == 0)
 595                                                         {
 596                                                                 if(vlen(oldself.origin - start) < vlen(e.origin - start))
 597                                                                         ++effectnum;
 598                                                                 else if(vlen(oldself.origin - start) == vlen(e.origin - start) && num_for_edict(oldself) < num_for_edict(e))
 599                                                                         ++effectnum;
 600                                                         }
 601                                                         fputs(f, strcat("\"race_place\" \"", ftos(effectnum), "\"\n"));
 602                                                 }
 603                                         }
 604                                         fputs(f, "}\n");
 605                                 }
 606                                 fclose(f);
 607                                 DID_CHEAT();
 608                                 break;
 609                         }
 610                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 611                         break;
 612                 case "drag_clear":
 613                         IS_CHEAT(0, argc, 0);
 614                         for(e = world; (e = find(e, classname, "dragbox_box")); )
 615                                 remove(e);
 616                         for(e = world; (e = find(e, classname, "dragbox_corner_1")); )
 617                                 remove(e);
 618                         for(e = world; (e = find(e, classname, "dragbox_corner_2")); )
 619                                 remove(e);
 620                         for(e = world; (e = find(e, classname, "dragpoint")); )
 621                                 remove(e);
 622                         for(e = world; (e = find(e, classname, "drag_digit")); )
 623                                 remove(e);
 624                         DID_CHEAT();
 625                         break;
 626                 case "god":
 627                         IS_CHEAT(0, argc, 0);
 628                         BITXOR_ASSIGN(self.flags, FL_GODMODE);
 629                         if(self.flags & FL_GODMODE)
 630                         {
 631                                 sprint(self, "godmode ON\n");
 632                                 DID_CHEAT();
 633                         }
 634                         else
 635                                 sprint(self, "godmode OFF\n");
 636                         break;
 637                 case "notarget":
 638                         IS_CHEAT(0, argc, 0);
 639                         BITXOR_ASSIGN(self.flags, FL_NOTARGET);
 640                         if(self.flags & FL_NOTARGET)
 641                         {
 642                                 sprint(self, "notarget ON\n");
 643                                 DID_CHEAT();
 644                         }
 645                         else
 646                                 sprint(self, "notarget OFF\n");
 647                         break;
 648                 case "noclip":
 649                         IS_CHEAT(0, argc, 0);
 650                         if(self.movetype != MOVETYPE_NOCLIP)
 651                         {
 652                                 self.movetype = MOVETYPE_NOCLIP;
 653                                 sprint(self, "noclip ON\n");
 654                                 DID_CHEAT();
 655                         }
 656                         else
 657                         {
 658                                 self.movetype = MOVETYPE_WALK;
 659                                 sprint(self, "noclip OFF\n");
 660                         }
 661                         break;
 662                 case "fly":
 663                         IS_CHEAT(0, argc, 0);
 664                         if(self.movetype != MOVETYPE_FLY)
 665                         {
 666                                 self.movetype = MOVETYPE_FLY;
 667                                 sprint(self, "flymode ON\n");
 668                                 DID_CHEAT();
 669                         }
 670                         else
 671                         {
 672                                 self.movetype = MOVETYPE_WALK;
 673                                 sprint(self, "flymode OFF\n");
 674                         }
 675                         break;
 676                 case "give":
 677                         IS_CHEAT(0, argc, 0);
 678                         if(GiveItems(self, 1, argc))
 679                                 DID_CHEAT();
 680                         break;
 681         }
 682
 683         END_CHEAT_FUNCTION();
 684 }
 685
 686 float Drag(entity e, float grab, float ischeat);
 687 void Drag_Begin(entity dragger, entity draggee, vector touchpoint);
 688 void Drag_Finish(entity dragger);
 689 float Drag_IsDraggable(entity draggee);
 690 float Drag_MayChangeAngles(entity draggee);
 691 void Drag_MoveForward(entity dragger);
 692 void Drag_SetSpeed(entity dragger, float s);
 693 void Drag_MoveBackward(entity dragger);
 694 void Drag_Update(entity dragger);
 695 float Drag_CanDrag(entity dragger);
 696 float Drag_IsDragging(entity dragger);
 697 void Drag_MoveDrag(entity from, entity to);
 698 .entity dragentity;
 699
 700 float CheatFrame()
 701 {
 702         BEGIN_CHEAT_FUNCTION();
 703
 704         // Dragging can be used as either a cheat, or a function for some objects. If sv_cheats is active,
 705         // the cheat dragging is used (unlimited pickup range and any entity can be carried). If sv_cheats
 706         // is disabled, normal dragging is used (limited pickup range and only dragable objects can be carried),
 707         // grabbing itself no longer being accounted as cheating.
 708
 709         switch(0)
 710         {
 711                 default:
 712                         if(self.maycheat || (gamestart_sv_cheats && autocvar_sv_cheats))
 713                         {
 714                                 // use cheat dragging if cheats are enabled
 715                                 crosshair_trace_plusvisibletriggers(self);
 716                                 Drag(trace_ent, TRUE, TRUE);
 717                         }
 718                         else
 719                         {
 720                                 // drag is TRUE if the object can be picked up. While an object is being carried, the Drag() function
 721                                 // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 722                                 // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 723                                 // it goes out of range while slinging it around.
 724
 725                                 float drag;
 726                                 crosshair_trace_plusvisibletriggers(self);
 727                                 if(vlen(self.origin - trace_ent.origin) <= autocvar_g_grab_range)
 728                                 {
 729                                         switch(trace_ent.grab)
 730                                         {
 731                                                 case 0: // can't grab
 732                                                         break;
 733                                                 case 1: // owner can grab
 734                                                         if(trace_ent.owner == self || trace_ent.realowner == self)
 735                                                                 drag = TRUE;
 736                                                         break;
 737                                                 case 2: // owner and team mates can grab
 738                                                         if(!IsDifferentTeam(trace_ent.owner, self) || !IsDifferentTeam(trace_ent.realowner, self) || trace_ent.team == self.team)
 739                                                                 drag = TRUE;
 740                                                         break;
 741                                                 case 3: // anyone can grab
 742                                                         drag = TRUE;
 743                                                         break;
 744                                                 default:
 745                                                         break;
 746                                         }
 747                                 }
 748                                 Drag(trace_ent, drag, FALSE); // execute dragging
 749                         }
 750                         break;
 751         }
 752
 753         END_CHEAT_FUNCTION();
 754 }
 755
 756
 757
 758
 759
 760 // ENTITY DRAGGING
 761
 762 float Drag(entity e, float pick, float ischeat)
 763 {
 764         BEGIN_CHEAT_FUNCTION();
 765
 766         // returns TRUE when an entity has been picked up
 767         // If pick is TRUE, the object can also be picked up if it's not being held already
 768         // If pick is FALSE, only keep dragging the object if it's already being held
 769
 770         switch(0)
 771         {
 772                 default:
 773                         if(Drag_IsDragging(self))
 774                         {
 775                                 if(self.BUTTON_DRAG)
 776                                 {
 777                                         if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 778                                         {
 779                                                 Drag_MoveForward(self);
 780                                                 self.impulse = 0;
 781                                         }
 782                                         else if(self.impulse == 12 || self.impulse == 16 || self.impulse == 19)
 783                                         {
 784                                                 Drag_MoveBackward(self);
 785                                                 self.impulse = 0;
 786                                         }
 787                                         else if(self.impulse >= 1 && self.impulse <= 9)
 788                                         {
 789                                                 Drag_SetSpeed(self, self.impulse - 1);
 790                                         }
 791                                         else if(self.impulse == 14)
 792                                         {
 793                                                 Drag_SetSpeed(self, 9);
 794                                         }
 795
 796                                         if(frametime)
 797                                                 Drag_Update(self);
 798                                 }
 799                                 else
 800                                 {
 801                                         Drag_Finish(self);
 802                                 }
 803                         }
 804                         else
 805                         {
 806                                 if(Drag_CanDrag(self))
 807                                         if(self.BUTTON_DRAG && pick)
 808                                         {
 809                                                 if(e)
 810                                                         if(Drag_IsDraggable(e))
 811                                                         {
 812                                                                 if(ischeat)
 813                                                                         IS_CHEAT(0, 0, CHRAME_DRAG);
 814                                                                 if(e.draggedby)
 815                                                                         Drag_Finish(e.draggedby);
 816                                                                 if(e.tag_entity)
 817                                                                         detach_sameorigin(e);
 818                                                                 Drag_Begin(self, e, trace_endpos);
 819                                                                 if(ischeat)
 820                                                                         DID_CHEAT();
 821                                                                 return TRUE;
 822                                                         }
 823                                         }
 824                         }
 825                         break;
 826         }
 827         return FALSE;
 828 }
 829
 830 // on dragger:
 831 .float draggravity;
 832 .float dragspeed; // speed of mouse wheel action
 833 .float dragdistance; // distance of dragentity's draglocalvector from view_ofs
 834 .vector draglocalvector; // local attachment vector of the dragentity
 835 .float draglocalangle;
 836 // on draggee:
 837 .entity draggedby;
 838 .float dragmovetype;
 839 void Drag_Begin(entity dragger, entity draggee, vector touchpoint)
 840 {
 841         float tagscale;
 842
 843         draggee.dragmovetype = draggee.movetype;
 844         draggee.draggravity = draggee.gravity;
 845         draggee.movetype = MOVETYPE_WALK;
 846         draggee.gravity = 0.00001;
 847         draggee.flags &~= FL_ONGROUND;
 848         draggee.draggedby = dragger;
 849
 850         dragger.dragentity = draggee;
 851
 852         dragger.dragdistance = vlen(touchpoint - dragger.origin - dragger.view_ofs);
 853         dragger.draglocalangle = draggee.angles_y - dragger.v_angle_y;
 854         touchpoint = touchpoint - gettaginfo(draggee, 0);
 855         tagscale = pow(vlen(v_forward), -2);
 856         dragger.draglocalvector_x = touchpoint * v_forward * tagscale;
 857         dragger.draglocalvector_y = touchpoint * v_right * tagscale;
 858         dragger.draglocalvector_z = touchpoint * v_up * tagscale;
 859
 860         dragger.dragspeed = 64;
 861 }
 862
 863 void Drag_Finish(entity dragger)
 864 {
 865         entity draggee;
 866         draggee = dragger.dragentity;
 867         if(dragger)
 868                 dragger.dragentity = world;
 869         draggee.draggedby = world;
 870         draggee.movetype = draggee.dragmovetype;
 871         draggee.gravity = draggee.draggravity;
 872
 873         switch(draggee.movetype)
 874         {
 875                 case MOVETYPE_TOSS:
 876                 case MOVETYPE_WALK:
 877                 case MOVETYPE_STEP:
 878                 case MOVETYPE_FLYMISSILE:
 879                 case MOVETYPE_BOUNCE:
 880                 case MOVETYPE_BOUNCEMISSILE:
 881                 case MOVETYPE_PHYSICS:
 882                         break;
 883                 default:
 884                         draggee.velocity = '0 0 0';
 885                         break;
 886         }
 887
 888         if((draggee.flags & FL_ITEM) && (vlen(draggee.velocity) < 32))
 889         {
 890                 draggee.velocity = '0 0 0';
 891                 draggee.flags |= FL_ONGROUND; // floating items are FUN
 892         }
 893 }
 894
 895 float Drag_IsDraggable(entity draggee)
 896 {
 897         // TODO add more checks for bad stuff here
 898         if(draggee == world)
 899                 return FALSE;
 900         if(draggee.classname == "func_bobbing")
 901                 return FALSE;
 902         if(draggee.classname == "door") // FIXME find out why these must be excluded, or work around the problem (trying to drag these causes like 4 fps)
 903                 return FALSE;
 904         if(draggee.classname == "plat")
 905                 return FALSE;
 906         if(draggee.classname == "func_button")
 907                 return FALSE;
 908 //      if(draggee.model == "")
 909 //              return FALSE;
 910         if(draggee.classname == "spectator")
 911                 return FALSE;
 912         if(draggee.classname == "observer")
 913                 return FALSE;
 914         if(draggee.classname == "exteriorweaponentity")
 915                 return FALSE;
 916         if(draggee.classname == "weaponentity")
 917                 return FALSE;
 918
 919         return TRUE;
 920 }
 921
 922 float Drag_MayChangeAngles(entity draggee)
 923 {
 924         // TODO add more checks for bad stuff here
 925         if(substring(draggee.model, 0, 1) == "*")
 926                 return FALSE;
 927         return TRUE;
 928 }
 929
 930 void Drag_MoveForward(entity dragger)
 931 {
 932         dragger.dragdistance += dragger.dragspeed;
 933 }
 934
 935 void Drag_SetSpeed(entity dragger, float s)
 936 {
 937         dragger.dragspeed = pow(2, s);
 938 }
 939
 940 void Drag_MoveBackward(entity dragger)
 941 {
 942         dragger.dragdistance = max(0, dragger.dragdistance - dragger.dragspeed);
 943 }
 944
 945 void Drag_Update(entity dragger)
 946 {
 947         vector curorigin, neworigin, goodvelocity;
 948         float f;
 949         entity draggee;
 950
 951         draggee = dragger.dragentity;
 952         draggee.flags &~= FL_ONGROUND;
 953
 954         curorigin = gettaginfo(draggee, 0);
 955         curorigin = curorigin + v_forward * dragger.draglocalvector_x + v_right * dragger.draglocalvector_y + v_up * dragger.draglocalvector_z;
 956         makevectors(dragger.v_angle);
 957         neworigin = dragger.origin + dragger.view_ofs + v_forward * dragger.dragdistance;
 958         goodvelocity = (neworigin - curorigin) * (1 / frametime);
 959
 960         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle > 180)
 961                 dragger.draglocalangle += 360;
 962         while(draggee.angles_y - dragger.v_angle_y - dragger.draglocalangle <= -180)
 963                 dragger.draglocalangle -= 360;
 964
 965         f = min(frametime * 10, 1);
 966         draggee.velocity = draggee.velocity * (1 - f) + goodvelocity * f;
 967
 968         if(Drag_MayChangeAngles(draggee))
 969                 draggee.angles_y = draggee.angles_y * (1 - f) + (dragger.v_angle_y + dragger.draglocalangle) * f;
 970
 971         draggee.ltime = max(servertime + serverframetime, draggee.ltime); // fixes func_train breakage
 972
 973         te_lightning1(dragger, dragger.origin + dragger.view_ofs, curorigin);
 974 }
 975
 976 float Drag_CanDrag(entity dragger)
 977 {
 978         return (dragger.deadflag == DEAD_NO) || (dragger.classname == "player");
 979 }
 980
 981 float Drag_IsDragging(entity dragger)
 982 {
 983         if(!dragger.dragentity)
 984                 return FALSE;
 985         if(wasfreed(dragger.dragentity) || dragger.dragentity.draggedby != dragger)
 986         {
 987                 dragger.dragentity = world;
 988                 return FALSE;
 989         }
 990         if(!Drag_CanDrag(dragger) || !Drag_IsDraggable(dragger.dragentity))
 991         {
 992                 Drag_Finish(dragger);
 993                 return FALSE;
 994         }
 995         return TRUE;
 996 }
 997
 998 void Drag_MoveDrag(entity from, entity to)
 999 {
1000         if(from.draggedby)
1001         {
1002                 to.draggedby = from.draggedby;
1003                 to.draggedby.dragentity = to;
1004                 from.draggedby = world;
1005         }
1006 }
1007
1008 void DragBox_Think()
1009 {
1010         if(self.aiment && self.enemy)
1011         {
1012                 self.origin_x = (self.aiment.origin_x + self.enemy.origin_x) * 0.5;
1013                 self.origin_y = (self.aiment.origin_y + self.enemy.origin_y) * 0.5;
1014                 self.origin_z = (self.aiment.origin_z + self.enemy.origin_z) * 0.5;
1015                 self.maxs_x = fabs(self.aiment.origin_x - self.enemy.origin_x) * 0.5;
1016                 self.maxs_y = fabs(self.aiment.origin_y - self.enemy.origin_y) * 0.5;
1017                 self.maxs_z = fabs(self.aiment.origin_z - self.enemy.origin_z) * 0.5;
1018                 self.mins = -1 * self.maxs;
1019                 setorigin(self, self.origin); setsize(self, self.mins, self.maxs); // link edict
1020         }
1021
1022         if(self.cnt == -1) // actually race_place -1
1023         {
1024                 // show "10 10" for qualifying spawns
1025                 setmodel(self.killindicator, "models/sprites/10.spr32");
1026                 setmodel(self.killindicator.killindicator, "models/sprites/10.spr32");
1027         }
1028         else if(self.cnt == -2) // actually race_place 0
1029         {
1030                 // show "10 0" for loser spawns
1031                 setmodel(self.killindicator, "models/sprites/10.spr32");
1032                 setmodel(self.killindicator.killindicator, "models/sprites/0.spr32");
1033         }
1034         else
1035         {
1036                 setmodel(self.killindicator, strcat("models/sprites/", ftos(mod(self.cnt, 10)), ".spr32"));
1037                 setmodel(self.killindicator.killindicator, strcat("models/sprites/", ftos(floor(self.cnt / 10)), ".spr32"));
1038         }
1039
1040         self.nextthink = time;
1041 }
1042
1043 #endif