qcsrc/server/cheats.qc

   1 #include "cheats.qh"
   2
   3 #include "g_damage.qh"
   4 #include "race.qh"
   5 #include "../common/triggers/teleporters.qh"
   6
   7 #include "mutators/all.qh"
   8
   9 #include "weapons/tracing.qh"
  10
  11 #include "../common/constants.qh"
  12 #include "../common/deathtypes/all.qh"
  13 #include "../common/util.qh"
  14
  15 #include <common/physics/player.qh>
  16
  17 #include "../common/monsters/all.qh"
  18
  19 #include "../common/weapons/all.qh"
  20
  21 #include "../common/triggers/subs.qh"
  22
  23 #include "../common/triggers/func/breakable.qh"
  24
  25 #include "../lib/csqcmodel/sv_model.qh"
  26
  27 #include "../lib/warpzone/anglestransform.qh"
  28 #include "../lib/warpzone/util_server.qh"
  29
  30 void CopyBody(entity this, float keepvelocity);
  31
  32 #ifdef NOCHEATS
  33
  34 float CheatImpulse(int imp) { return 0; }
  35 float CheatCommand(float argc) { return 0; }
  36 float CheatFrame() { return 0; }
  37 void CheatInit() { cheatcount_total = world.cheatcount; }
  38 void CheatShutdown() { }
  39 void CheatShutdownClient() { }
  40 void Drag_MoveDrag(entity from, entity to) { }
  41
  42 #else
  43
  44 .float maycheat;
  45 float gamestart_sv_cheats;
  46
  47
  48
  49 void CheatInit()
  50 {
  51         gamestart_sv_cheats = autocvar_sv_cheats;
  52 }
  53
  54 void CheatShutdown()
  55 {
  56 }
  57
  58 void CheatShutdownClient()
  59 {
  60 }
  61
  62 float CheatsAllowed(float i, float argc, float fr) // the cheat gets passed as argument for possible future ACL checking
  63 {SELFPARAM();
  64         // dead people cannot cheat
  65         if(IS_DEAD(self))
  66                 return 0;
  67         if(gamestart_sv_cheats < 2 && !IS_PLAYER(self))
  68                 return 0;
  69
  70         // sv_clones
  71         if(i == CHIMPULSE_CLONE_MOVING.impulse || i == CHIMPULSE_CLONE_STANDING.impulse)
  72                 if(self.lip < sv_clones)
  73                         return 1;
  74
  75         // haha
  76         if(self.maycheat)
  77                 return 1;
  78
  79         // sv_cheats
  80         if(gamestart_sv_cheats && autocvar_sv_cheats)
  81                 return 1;
  82
  83         // if we get here, player is not allowed to cheat. Log it.
  84         if(i)
  85                 bprintf("Player %s^7 tried to use cheat 'impulse %d'\n", self.netname, i);
  86         else if(argc)
  87                 bprintf("Player %s^7 tried to use cheat '%s'\n", self.netname, argv(0));
  88         else if(fr)
  89                 bprintf("Player %s^7 tried to use cheat frame %d\n", self.netname, fr);
  90         else
  91                 bprintf("Player %s^7 tried to use an unknown cheat\n", self.netname);
  92
  93         return 0;
  94 }
  95
  96 #define BEGIN_CHEAT_FUNCTION() \
  97         float cheating, attempting; \
  98         cheating = 0; attempting = 0
  99 #define DID_CHEAT() \
 100         ++cheating
 101 #define ADD_CHEATS(e,n) \
 102         cheatcount_total += n; \
 103         e.cheatcount += n
 104 #define END_CHEAT_FUNCTION() \
 105         ADD_CHEATS(self,cheating); \
 106         return attempting
 107 #define IS_CHEAT(i,argc,fr) \
 108         if((++attempting, !CheatsAllowed(i,argc,fr))) \
 109                 break
 110
 111 float num_autoscreenshot;
 112 void info_autoscreenshot_findtarget()
 113 {SELFPARAM();
 114         entity e;
 115         e = find(world, targetname, self.target);
 116         if(!e)
 117         {
 118                 objerror("Missing target. FAIL!");
 119                 return;
 120         }
 121         vector a = vectoangles(e.origin - self.origin);
 122         a.x = -a.x; // don't ask
 123         self.angles_x = a.x;
 124         self.angles_y = a.y;
 125         // we leave Rick Roll alone
 126 }
 127 spawnfunc(info_autoscreenshot)
 128 {
 129         if(++num_autoscreenshot > autocvar_g_max_info_autoscreenshot)
 130         {
 131                 objerror("Too many info_autoscreenshot entitites. FAIL!");
 132                 return;
 133         }
 134         if(self.target != "")
 135                 InitializeEntity(self, info_autoscreenshot_findtarget, INITPRIO_FINDTARGET);
 136         // this one just has to exist
 137 }
 138
 139 float CheatImpulse(int imp)
 140 {SELFPARAM();
 141         BEGIN_CHEAT_FUNCTION();
 142         switch(imp)
 143         {
 144                 entity e, e2;
 145
 146                 case CHIMPULSE_SPEEDRUN_INIT.impulse: // deploy personal waypoint
 147                         // shared with regular waypoint init, so this is not a cheat by itself
 148                         if(!self.personal)
 149                         {
 150                                 self.personal = new(personal_wp);
 151                         }
 152                         self.personal.origin = self.origin;
 153                         self.personal.v_angle = self.v_angle;
 154                         self.personal.velocity = self.velocity;
 155                         self.personal.ammo_rockets = self.ammo_rockets;
 156                         self.personal.ammo_nails = self.ammo_nails;
 157                         self.personal.ammo_cells = self.ammo_cells;
 158                         self.personal.ammo_plasma = self.ammo_plasma;
 159                         self.personal.ammo_shells = self.ammo_shells;
 160                         self.personal.ammo_fuel = self.ammo_fuel;
 161                         self.personal.health = self.health;
 162                         self.personal.armorvalue = self.armorvalue;
 163                         self.personal.weapons = self.weapons;
 164                         self.personal.items = self.items;
 165                         self.personal.pauserotarmor_finished = self.pauserotarmor_finished;
 166                         self.personal.pauserothealth_finished = self.pauserothealth_finished;
 167                         self.personal.pauserotfuel_finished = self.pauserotfuel_finished;
 168                         self.personal.pauseregen_finished = self.pauseregen_finished;
 169                         self.personal.strength_finished = self.strength_finished;
 170                         self.personal.invincible_finished = self.invincible_finished;
 171                         self.personal.teleport_time = time;
 172                         break; // this part itself doesn't cheat, so let's not count this
 173                 case CHIMPULSE_CLONE_MOVING.impulse:
 174                         IS_CHEAT(imp, 0, 0);
 175                         makevectors (self.v_angle);
 176                         self.velocity = self.velocity + v_forward * 300;
 177                         CopyBody(self, 1);
 178                         self.lip += 1;
 179                         self.velocity = self.velocity - v_forward * 300;
 180                         DID_CHEAT();
 181                         break;
 182                 case CHIMPULSE_CLONE_STANDING.impulse:
 183                         IS_CHEAT(imp, 0, 0);
 184                         CopyBody(self, 0);
 185                         self.lip += 1;
 186                         DID_CHEAT();
 187                         break;
 188                 case CHIMPULSE_GIVE_ALL.impulse:
 189                         IS_CHEAT(imp, 0, 0);
 190                         CheatCommand(tokenize_console("give all"));
 191                         break; // already counted as cheat
 192                 case CHIMPULSE_SPEEDRUN.impulse:
 193                         IS_CHEAT(imp, 0, 0);
 194                         if(self.personal)
 195                         {
 196                                 self.speedrunning = true;
 197                                 tracebox(self.personal.origin, self.mins, self.maxs, self.personal.origin, MOVE_WORLDONLY, self);
 198                                 if(trace_startsolid)
 199                                 {
 200                                         sprint(self, "Cannot move there, cheater - only waypoints set using g_waypointsprite_personal work\n");
 201                                 }
 202                                 else
 203                                 {
 204                                         // Abort speedrun, teleport back
 205                                         setorigin(self, self.personal.origin);
 206                                         self.oldvelocity = self.velocity = self.personal.velocity;
 207                                         self.angles = self.personal.v_angle;
 208                                         self.fixangle = true;
 209
 210                                         MUTATOR_CALLHOOK(AbortSpeedrun, self);
 211                                 }
 212
 213                                 self.ammo_rockets = self.personal.ammo_rockets;
 214                                 self.ammo_nails = self.personal.ammo_nails;
 215                                 self.ammo_cells = self.personal.ammo_cells;
 216                                 self.ammo_plasma = self.personal.ammo_plasma;
 217                                 self.ammo_shells = self.personal.ammo_shells;
 218                                 self.ammo_fuel = self.personal.ammo_fuel;
 219                                 self.health = self.personal.health;
 220                                 self.armorvalue = self.personal.armorvalue;
 221                                 self.weapons = self.personal.weapons;
 222                                 self.items = self.personal.items;
 223                                 self.pauserotarmor_finished = time + self.personal.pauserotarmor_finished - self.personal.teleport_time;
 224                                 self.pauserothealth_finished = time + self.personal.pauserothealth_finished - self.personal.teleport_time;
 225                                 self.pauserotfuel_finished = time + self.personal.pauserotfuel_finished - self.personal.teleport_time;
 226                                 self.pauseregen_finished = time + self.personal.pauseregen_finished - self.personal.teleport_time;
 227                                 self.strength_finished = time + self.personal.strength_finished - self.personal.teleport_time;
 228                                 self.invincible_finished = time + self.personal.invincible_finished - self.personal.teleport_time;
 229
 230                                 DID_CHEAT();
 231                                 break;
 232                         }
 233                         if(IS_DEAD(self))
 234                                 sprint(self, "UR DEAD AHAHAH))\n");
 235                         else
 236                                 sprint(self, "No waypoint set, cheater (use g_waypointsprite_personal to set one)\n");
 237                         break;
 238                 case CHIMPULSE_TELEPORT.impulse:
 239                         IS_CHEAT(imp, 0, 0);
 240                         if(self.movetype == MOVETYPE_NOCLIP)
 241                         {
 242                                 e = find(world, classname, "info_autoscreenshot");
 243                                 if(e)
 244                                 {
 245                                         sprint(self, "Emergency teleport used info_autoscreenshot location\n");
 246                                         setorigin(self, e.origin);
 247                                         self.angles = e.angles;
 248                                         remove(e);
 249                                         // should we? self.angles_x = -self.angles_x;
 250                                         self.fixangle = true;
 251                                         self.velocity = '0 0 0';
 252                                         DID_CHEAT();
 253                                         break;
 254                                 }
 255                         }
 256                         if(MoveToRandomMapLocation(self, DPCONTENTS_SOLID | DPCONTENTS_CORPSE | DPCONTENTS_PLAYERCLIP, DPCONTENTS_SLIME | DPCONTENTS_LAVA | DPCONTENTS_SKY | DPCONTENTS_BODY | DPCONTENTS_DONOTENTER, Q3SURFACEFLAG_SKY, ((gamestart_sv_cheats < 2) ? 100 : 100000), 384, 384))
 257                         {
 258                                 sprint(self, "Emergency teleport used random location\n");
 259                                 self.angles_x = -self.angles.x;
 260                                 self.fixangle = true;
 261                                 self.velocity = '0 0 0';
 262                                 DID_CHEAT();
 263                                 break;
 264                         }
 265                         sprint(self, "Emergency teleport could not find a good location, forget it!\n");
 266                         break;
 267                 case CHIMPULSE_R00T.impulse:
 268                         IS_CHEAT(imp, 0, 0);
 269                         RandomSelection_Init();
 270                         FOREACH_CLIENT(IS_PLAYER(it) && !IS_DEAD(it) && DIFF_TEAM(it, self), LAMBDA(RandomSelection_Add(it, 0, string_null, 1, 1)));
 271                         if(RandomSelection_chosen_ent)
 272                                 e = RandomSelection_chosen_ent;
 273                         else
 274                                 e = self;
 275
 276                         Send_Effect(EFFECT_ROCKET_EXPLODE, e.origin, '0 0 0', 1);
 277                         sound(e, CH_SHOTS, SND_ROCKET_IMPACT, VOL_BASE, ATTEN_NORM);
 278
 279                         e2 = spawn();
 280                         setorigin(e2, e.origin);
 281                         RadiusDamage(e2, self, 1000, 0, 128, world, world, 500, DEATH_CHEAT.m_id, e);
 282                         remove(e2);
 283
 284                         LOG_INFO("404 Sportsmanship not found.\n");
 285                         DID_CHEAT();
 286                         break;
 287         }
 288
 289         END_CHEAT_FUNCTION();
 290 }
 291
 292 void DragBox_Think();
 293 float drag_lastcnt;
 294 float CheatCommand(float argc)
 295 {SELFPARAM();
 296         BEGIN_CHEAT_FUNCTION();
 297         string cmd;
 298         cmd = argv(0);
 299         switch(cmd)
 300         {
 301                 float effectnum, f;
 302                 vector start, end;
 303                 entity oldself;
 304
 305                 case "pointparticles":
 306                         IS_CHEAT(0, argc, 0);
 307                         if(argc == 5)
 308                         {
 309                                 // arguments:
 310                                 //   effectname
 311                                 //   origin (0..1, on crosshair line)
 312                                 //   velocity
 313                                 //   howmany
 314                                 f = stof(argv(2));
 315                                 crosshair_trace(self);
 316                                 start = (1-f) * self.origin + f * trace_endpos;
 317                                 end = stov(argv(3));
 318                                 f = stof(argv(4));
 319                                 Send_Effect_(argv(1), start, end, f);
 320                                 DID_CHEAT();
 321                                 break;
 322                         }
 323                         sprint(self, "Usage: sv_cheats 1; restart; cmd pointparticles effectname position(0..1) velocityvector multiplier\n");
 324                         break;
 325                 case "trailparticles":
 326                         IS_CHEAT(0, argc, 0);
 327                         if(argc == 2)
 328                         {
 329                                 // arguments:
 330                                 //   effectname
 331                                 effectnum = _particleeffectnum(argv(1));
 332                                 W_SetupShot(self, false, false, "", CH_WEAPON_A, 0);
 333                                 traceline(w_shotorg, w_shotorg + w_shotdir * MAX_SHOT_DISTANCE, MOVE_NORMAL, self);
 334                                 __trailparticles(self, effectnum, w_shotorg, trace_endpos);
 335                                 DID_CHEAT();
 336                                 break;
 337                         }
 338                         sprint(self, "Usage: sv_cheats 1; restart; cmd trailparticles effectname\n");
 339                         break;
 340                 case "make":
 341                         IS_CHEAT(0, argc, 0);
 342                         if(argc == 3)
 343                         {
 344                                 // arguments:
 345                                 //   modelname mode
 346                                 f = stof(argv(2));
 347                                 W_SetupShot(self, false, false, "", CH_WEAPON_A, 0);
 348                                 traceline(w_shotorg, w_shotorg + w_shotdir * 2048, MOVE_NORMAL, self);
 349                                 if((trace_dphitq3surfaceflags & Q3SURFACEFLAG_NOIMPACT) || trace_fraction == 1)
 350                                 {
 351                                         sprint(self, "cannot make stuff there (bad surface)\n");
 352                                 }
 353                                 else
 354                                 {
 355                                         entity e = spawn();
 356                                         e.model = strzone(argv(1));
 357                                         e.mdl = "rocket_explode";
 358                                         e.health = 1000;
 359                                         setorigin(e, trace_endpos);
 360                                         e.effects = EF_NOMODELFLAGS;
 361                                         if(f == 1)
 362                                         {
 363                                                 e.angles = fixedvectoangles2(trace_plane_normal, v_forward);
 364                                                 e.angles = AnglesTransform_ApplyToAngles(e.angles, '-90 0 0'); // so unrotated models work
 365                                         }
 366                                         WITH(entity, self, e, spawnfunc_func_breakable(e));
 367                                         // now, is it valid?
 368                                         if(f == 0)
 369                                         {
 370                                                 tracebox(e.origin, e.mins, e.maxs, e.origin, MOVE_NORMAL, e);
 371                                                 if(trace_startsolid)
 372                                                 {
 373                                                         remove(e);
 374                                                         sprint(self, "cannot make stuff there (no space)\n");
 375                                                 }
 376                                                 else
 377                                                         DID_CHEAT();
 378                                         }
 379                                         else
 380                                                 DID_CHEAT();
 381                                 }
 382                         }
 383                         else
 384                                 sprint(self, "Usage: sv_cheats 1; restart; cmd make models/... 0/1/2\n");
 385                         break;
 386                 case "penalty":
 387                         IS_CHEAT(0, argc, 0);
 388                         if(argc == 3)
 389                         {
 390                                 race_ImposePenaltyTime(self, stof(argv(1)), argv(2));
 391                                 DID_CHEAT();
 392                                 break;
 393                         }
 394                         sprint(self, "Usage: sv_cheats 1; restart; cmd penalty 5.0 AHAHAHAHAHAHAH))\n");
 395                         break;
 396                 case "dragbox_spawn": {
 397                         IS_CHEAT(0, argc, 0);
 398                         entity e = new(dragbox_box);
 399                         e.think = DragBox_Think;
 400                         e.nextthink = time;
 401                         e.solid = -1; // black
 402                         setmodel(e, MDL_Null); // network it
 403                         if(argc == 4)
 404                                 e.cnt = stof(argv(1));
 405                         else
 406                                 e.cnt = max(0, drag_lastcnt);
 407
 408                         e.aiment = new(dragbox_corner_1);
 409                         e.aiment.owner = e;
 410                         setmodel(e.aiment, MDL_MARKER);
 411                         e.aiment.skin = 0;
 412                         setsize(e.aiment, '0 0 0', '0 0 0');
 413                         if(argc == 4)
 414                                 setorigin(e.aiment, stov(argv(2)));
 415                         else
 416                         {
 417                                 crosshair_trace(self);
 418                                 setorigin(e.aiment, trace_endpos);
 419                         }
 420
 421                         e.enemy = new(dragbox_corner_2);
 422                         e.enemy.owner = e;
 423                         setmodel(e.enemy, MDL_MARKER);
 424                         e.enemy.skin = 1;
 425                         setsize(e.enemy, '0 0 0', '0 0 0');
 426                         end = normalize(self.origin + self.view_ofs - e.aiment.origin);
 427                         end.x = (end.x > 0) * 2 - 1;
 428                         end.y = (end.y > 0) * 2 - 1;
 429                         end.z = (end.z > 0) * 2 - 1;
 430                         if(argc == 4)
 431                                 setorigin(e.enemy, stov(argv(3)));
 432                         else
 433                                 setorigin(e.enemy, e.aiment.origin + 32 * end);
 434
 435                         e.killindicator = new(drag_digit);
 436                         e.killindicator.owner = e;
 437                         setattachment(e.killindicator, e, "");
 438                         setorigin(e.killindicator, '0 0 -8');
 439                         e.killindicator.killindicator = new(drag_digit);
 440                         e.killindicator.killindicator.owner = e;
 441                         setattachment(e.killindicator.killindicator, e, "");
 442                         setorigin(e.killindicator.killindicator, '0 0 8');
 443                         DID_CHEAT();
 444                         break;
 445                 }
 446                 case "dragpoint_spawn": {
 447                         IS_CHEAT(0, argc, 0);
 448                         entity e = new(dragpoint);
 449                         e.think = DragBox_Think;
 450                         e.nextthink = time;
 451                         e.solid = 0; // nothing special
 452                         setmodel(e, MDL_MARKER);
 453                         setsize(e, STAT(PL_MIN, NULL), STAT(PL_MAX, NULL));
 454                         e.skin = 2;
 455                         if(argc == 3)
 456                                 e.cnt = stof(argv(1));
 457                         else
 458                                 e.cnt = drag_lastcnt;
 459                         if(argc == 3)
 460                                 setorigin(e, stov(argv(2)));
 461                         else
 462                         {
 463                                 crosshair_trace(self);
 464                                 setorigin(e, trace_endpos + normalize(self.origin + self.view_ofs - trace_endpos));
 465                                 move_out_of_solid(e);
 466                         }
 467
 468                         e.killindicator = new(drag_digit);
 469                         e.killindicator.owner = e;
 470                         setattachment(e.killindicator, e, "");
 471                         setorigin(e.killindicator, '0 0 40');
 472                         e.killindicator.killindicator = new(drag_digit);
 473                         e.killindicator.killindicator.owner = e;
 474                         setattachment(e.killindicator.killindicator, e, "");
 475                         setorigin(e.killindicator.killindicator, '0 0 56');
 476                         DID_CHEAT();
 477                         break;
 478                 }
 479                 case "drag_remove":
 480                         IS_CHEAT(0, argc, 0);
 481                         RandomSelection_Init();
 482                         crosshair_trace(self);
 483                         for(entity e = world; (e = find(e, classname, "dragbox_box")); )
 484                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 485                         for(entity e = world; (e = find(e, classname, "dragpoint")); )
 486                                 RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 487                         if(RandomSelection_chosen_ent)
 488                         {
 489                                 remove(RandomSelection_chosen_ent.killindicator.killindicator);
 490                                 remove(RandomSelection_chosen_ent.killindicator);
 491                                 if(RandomSelection_chosen_ent.aiment)
 492                                         remove(RandomSelection_chosen_ent.aiment);
 493                                 if(RandomSelection_chosen_ent.enemy)
 494                                         remove(RandomSelection_chosen_ent.enemy);
 495                                 remove(RandomSelection_chosen_ent);
 496                         }
 497                         DID_CHEAT();
 498                         break;
 499                 case "drag_setcnt":
 500                         IS_CHEAT(0, argc, 0);
 501                         if(argc == 2)
 502                         {
 503                                 RandomSelection_Init();
 504                                 crosshair_trace(self);
 505                                 for(entity e = world; (e = find(e, classname, "dragbox_box")); )
 506                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 507                                 for(entity e = world; (e = find(e, classname, "dragpoint")); )
 508                                         RandomSelection_Add(e, 0, string_null, 1, 1 / vlen(e.origin + (e.mins + e.maxs) * 0.5 - trace_endpos));
 509                                 if(RandomSelection_chosen_ent)
 510                                 {
 511                                         if(substring(argv(1), 0, 1) == "*")
 512                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = RandomSelection_chosen_ent.cnt + stof(substring(argv(1), 1, -1));
 513                                         else
 514                                                 RandomSelection_chosen_ent.cnt = drag_lastcnt = stof(argv(1));
 515                                 }
 516                                 DID_CHEAT();
 517                                 break;
 518                         }
 519                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_setcnt cnt\n");
 520                         break;
 521                 case "drag_save":
 522                         IS_CHEAT(0, argc, 0);
 523                         if(argc == 2)
 524                         {
 525                                 f = fopen(argv(1), FILE_WRITE);
 526                                 fputs(f, "cmd drag_clear\n");
 527                                 for(entity e = world; (e = find(e, classname, "dragbox_box")); )
 528                                 {
 529                                         fputs(f, strcat("cmd dragbox_spawn ", ftos(e.cnt), " \"", vtos(e.aiment.origin), "\" \"", vtos(e.enemy.origin), "\"\n"));
 530                                 }
 531                                 for(entity e = world; (e = find(e, classname, "dragpoint")); )
 532                                 {
 533                                         fputs(f, strcat("cmd dragpoint_spawn ", ftos(e.cnt), " \"", vtos(e.origin), "\"\n"));
 534                                 }
 535                                 fclose(f);
 536                                 DID_CHEAT();
 537                                 break;
 538                         }
 539                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 540                         break;
 541                 case "drag_saveraceent":
 542                         IS_CHEAT(0, argc, 0);
 543                         if(argc == 2)
 544                         {
 545                                 f = fopen(argv(1), FILE_WRITE);
 546                                 for(entity e = world; (e = find(e, classname, "dragbox_box")); )
 547                                 {
 548                                         fputs(f, "{\n");
 549                                         fputs(f, "\"classname\" \"trigger_race_checkpoint\"\n");
 550                                         fputs(f, strcat("\"origin\" \"", ftos(e.absmin.x), " ", ftos(e.absmin.y), " ", ftos(e.absmin.z), "\"\n"));
 551                                         fputs(f, strcat("\"maxs\" \"", ftos(e.absmax.x - e.absmin.x), " ", ftos(e.absmax.y - e.absmin.y), " ", ftos(e.absmax.z - e.absmin.z), "\"\n"));
 552                                         fputs(f, strcat("\"cnt\" \"", ftos(e.cnt), "\"\n"));
 553                                         fputs(f, strcat("\"targetname\" \"checkpoint", ftos(e.cnt), "\"\n"));
 554                                         fputs(f, "}\n");
 555                                 }
 556                                 for(entity e = world; (e = find(e, classname, "dragpoint")); )
 557                                 {
 558                                         start = '0 0 0';
 559                                         effectnum = 0;
 560                                         for(oldself = world; (oldself = find(oldself, classname, "dragbox_box")); )
 561                                         {
 562                                                 if(e.cnt <= 0 && oldself.cnt == 0 || e.cnt == oldself.cnt)
 563                                                 {
 564                                                         start = start + oldself.origin;
 565                                                         ++effectnum;
 566                                                 }
 567                                         }
 568                                         start *= 1 / effectnum;
 569                                         fputs(f, "{\n");
 570                                         fputs(f, "\"classname\" \"info_player_race\"\n");
 571                                         fputs(f, strcat("\"angle\" \"", ftos(vectoyaw(start - e.origin)), "\"\n"));
 572                                         fputs(f, strcat("\"origin\" \"", ftos(e.origin.x), " ", ftos(e.origin.y), " ", ftos(e.origin.z), "\"\n"));
 573                                         if(e.cnt == -2)
 574                                         {
 575                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 576                                                 fputs(f, "\"race_place\" \"0\"\n");
 577                                         }
 578                                         else if(e.cnt == -1)
 579                                         {
 580                                                 fputs(f, "\"target\" \"checkpoint0\"\n");
 581                                                 fputs(f, "\"race_place\" \"-1\"\n");
 582                                         }
 583                                         else
 584                                         {
 585                                                 fputs(f, strcat("\"target\" \"checkpoint", ftos(e.cnt), "\"\n"));
 586                                                 if(e.cnt == 0)
 587                                                 {
 588                                                         // these need race_place
 589                                                         // counting...
 590                                                         effectnum = 1;
 591                                                         for(oldself = world; (oldself = find(oldself, classname, "dragpoint")); )
 592                                                         if(oldself.cnt == 0)
 593                                                         {
 594                                                                 if(vlen(oldself.origin - start) < vlen(e.origin - start))
 595                                                                         ++effectnum;
 596                                                                 else if(vlen(oldself.origin - start) == vlen(e.origin - start) && etof(oldself) < etof(e))
 597                                                                         ++effectnum;
 598                                                         }
 599                                                         fputs(f, strcat("\"race_place\" \"", ftos(effectnum), "\"\n"));
 600                                                 }
 601                                         }
 602                                         fputs(f, "}\n");
 603                                 }
 604                                 fclose(f);
 605                                 DID_CHEAT();
 606                                 break;
 607                         }
 608                         sprint(self, "Usage: sv_cheats 1; restart; cmd dragbox_save filename\n");
 609                         break;
 610                 case "drag_clear":
 611                         IS_CHEAT(0, argc, 0);
 612                         for(entity e = world; (e = find(e, classname, "dragbox_box")); )
 613                                 remove(e);
 614                         for(entity e = world; (e = find(e, classname, "dragbox_corner_1")); )
 615                                 remove(e);
 616                         for(entity e = world; (e = find(e, classname, "dragbox_corner_2")); )
 617                                 remove(e);
 618                         for(entity e = world; (e = find(e, classname, "dragpoint")); )
 619                                 remove(e);
 620                         for(entity e = world; (e = find(e, classname, "drag_digit")); )
 621                                 remove(e);
 622                         DID_CHEAT();
 623                         break;
 624                 case "god":
 625                         IS_CHEAT(0, argc, 0);
 626                         BITXOR_ASSIGN(self.flags, FL_GODMODE);
 627                         if(self.flags & FL_GODMODE)
 628                         {
 629                                 sprint(self, "godmode ON\n");
 630                                 DID_CHEAT();
 631                         }
 632                         else
 633                                 sprint(self, "godmode OFF\n");
 634                         break;
 635                 case "notarget":
 636                         IS_CHEAT(0, argc, 0);
 637                         BITXOR_ASSIGN(self.flags, FL_NOTARGET);
 638                         if(self.flags & FL_NOTARGET)
 639                         {
 640                                 sprint(self, "notarget ON\n");
 641                                 DID_CHEAT();
 642                         }
 643                         else
 644                                 sprint(self, "notarget OFF\n");
 645                         break;
 646                 case "noclip":
 647                         IS_CHEAT(0, argc, 0);
 648                         if(self.movetype != MOVETYPE_NOCLIP)
 649                         {
 650                                 self.movetype = MOVETYPE_NOCLIP;
 651                                 sprint(self, "noclip ON\n");
 652                                 DID_CHEAT();
 653                         }
 654                         else
 655                         {
 656                                 self.movetype = MOVETYPE_WALK;
 657                                 sprint(self, "noclip OFF\n");
 658                         }
 659                         break;
 660                 case "fly":
 661                         IS_CHEAT(0, argc, 0);
 662                         if(self.movetype != MOVETYPE_FLY)
 663                         {
 664                                 self.movetype = MOVETYPE_FLY;
 665                                 sprint(self, "flymode ON\n");
 666                                 DID_CHEAT();
 667                         }
 668                         else
 669                         {
 670                                 self.movetype = MOVETYPE_WALK;
 671                                 sprint(self, "flymode OFF\n");
 672                         }
 673                         break;
 674                 case "give":
 675                         IS_CHEAT(0, argc, 0);
 676                         if(GiveItems(self, 1, argc))
 677                                 DID_CHEAT();
 678                         break;
 679                 case "usetarget":
 680                         IS_CHEAT(0, argc, 0);
 681                         setself(spawn());
 682                         self.target = argv(1);
 683                         activator = this;
 684                         SUB_UseTargets();
 685                         remove(self);
 686                         setself(this);
 687                         DID_CHEAT();
 688                         break;
 689                 case "killtarget":
 690                         IS_CHEAT(0, argc, 0);
 691                         setself(spawn());
 692                         self.killtarget = argv(1);
 693                         activator = this;
 694                         SUB_UseTargets();
 695                         remove(self);
 696                         setself(this);
 697                         DID_CHEAT();
 698                         break;
 699                 case "teleporttotarget":
 700                         IS_CHEAT(0, argc, 0);
 701                         setself(new(cheattriggerteleport));
 702                         setorigin(self, self.origin);
 703                         self.target = argv(1);
 704                         teleport_findtarget();
 705                         if(!wasfreed(self))
 706                         {
 707                                 Simple_TeleportPlayer(self, this);
 708                                 remove(self);
 709                                 DID_CHEAT();
 710                         }
 711                         setself(this);
 712                         break;
 713         }
 714
 715         END_CHEAT_FUNCTION();
 716 }
 717
 718 float Drag(float force_allow_pick, float ischeat);
 719 void Drag_Begin(entity dragger, entity draggee, vector touchpoint);
 720 void Drag_Finish(entity dragger);
 721 float Drag_IsDraggable(entity draggee);
 722 float Drag_MayChangeAngles(entity draggee);
 723 void Drag_MoveForward(entity dragger);
 724 void Drag_SetSpeed(entity dragger, float s);
 725 void Drag_MoveBackward(entity dragger);
 726 void Drag_Update(entity dragger);
 727 float Drag_CanDrag(entity dragger);
 728 float Drag_IsDragging(entity dragger);
 729 void Drag_MoveDrag(entity from, entity to);
 730 .entity dragentity;
 731
 732 float CheatFrame()
 733 {SELFPARAM();
 734         BEGIN_CHEAT_FUNCTION();
 735
 736         // Dragging can be used as either a cheat, or a function for some objects. If sv_cheats is active,
 737         // the cheat dragging is used (unlimited pickup range and any entity can be carried). If sv_cheats
 738         // is disabled, normal dragging is used (limited pickup range and only dragable objects can be carried),
 739         // grabbing itself no longer being accounted as cheating.
 740
 741         switch(0)
 742         {
 743                 default:
 744                         if(self.maycheat || (gamestart_sv_cheats && autocvar_sv_cheats))
 745                         {
 746                                 // use cheat dragging if cheats are enabled
 747                                 crosshair_trace_plusvisibletriggers(self);
 748                                 Drag(true, true);
 749                         }
 750                         else
 751                         {
 752                                 Drag(false, false); // execute dragging
 753                         }
 754                         break;
 755         }
 756
 757         END_CHEAT_FUNCTION();
 758 }
 759
 760
 761
 762
 763
 764 // ENTITY DRAGGING
 765
 766 // on dragger:
 767 .float draggravity;
 768 .float dragspeed; // speed of mouse wheel action
 769 .float dragdistance; // distance of dragentity's draglocalvector from view_ofs
 770 .vector draglocalvector; // local attachment vector of the dragentity
 771 .float draglocalangle;
 772 // on draggee:
 773 .entity draggedby;
 774 .float dragmovetype;
 775
 776 float Drag(float force_allow_pick, float ischeat)
 777 {SELFPARAM();
 778         BEGIN_CHEAT_FUNCTION();
 779
 780         // returns true when an entity has been picked up
 781         // If pick is true, the object can also be picked up if it's not being held already
 782         // If pick is false, only keep dragging the object if it's already being held
 783
 784         switch(0)
 785         {
 786                 default:
 787                         if(Drag_IsDragging(self))
 788                         {
 789                                 if(PHYS_INPUT_BUTTON_DRAG(self))
 790                                 {
 791                                         if(self.impulse == 10 || self.impulse == 15 || self.impulse == 18)
 792                                         {
 793                                                 Drag_MoveForward(self);
 794                                                 self.impulse = 0;
 795                                         }
 796                                         else if(self.impulse == 12 || self.impulse == 16 || self.impulse == 19)
 797                                         {
 798                                                 Drag_MoveBackward(self);
 799                                                 self.impulse = 0;
 800                                         }
 801                                         else if(self.impulse >= 1 && self.impulse <= 9)
 802                                         {
 803                                                 Drag_SetSpeed(self, self.impulse - 1);
 804                                         }
 805                                         else if(self.impulse == 14)
 806                                         {
 807                                                 Drag_SetSpeed(self, 9);
 808                                         }
 809
 810                                         if(frametime)
 811                                                 Drag_Update(self);
 812                                 }
 813                                 else
 814                                 {
 815                                         Drag_Finish(self);
 816                                 }
 817                         }
 818                         else
 819                         {
 820                                 if(Drag_CanDrag(self))
 821                                         if(PHYS_INPUT_BUTTON_DRAG(self))
 822                                         {
 823                                                 crosshair_trace_plusvisibletriggers(self);
 824                                                 entity e = trace_ent;
 825                                                 float pick = force_allow_pick;
 826                                                 if (e && !pick)
 827                                                 {
 828                                                         // pick is true if the object can be picked up. While an object is being carried, the Drag() function
 829                                                         // must execute for it either way, otherwise it would cause bugs if it went out of the player's trace.
 830                                                         // This also makes sure that an object can only pe picked up if in range, but does not get dropped if
 831                                                         // it goes out of range while slinging it around.
 832
 833                                                         if(vlen(self.origin - e.origin) <= autocvar_g_grab_range)
 834                                                         {
 835                                                                 switch(e.grab)
 836                                                                 {
 837                                                                         case 0: // can't grab
 838                                                                                 break;
 839                                                                         case 1: // owner can grab
 840                                                                                 if(e.owner == self || e.realowner == self)
 841                                                                                         pick = true;
 842                                                                                 break;
 843                                                                         case 2: // owner and team mates can grab
 844                                                                                 if(SAME_TEAM(e.owner, self) || SAME_TEAM(e.realowner, self) || e.team == self.team)
 845                                                                                         pick = true;
 846                                                                                 break;
 847                                                                         case 3: // anyone can grab
 848                                                                                 pick = true;
 849                                                                                 break;
 850                                                                         default:
 851                                                                                 break;
 852                                                                 }
 853                                                         }
 854                                                 }
 855                                                 // Find e and pick
 856                                                 if(e && pick)
 857                                                         if(Drag_IsDraggable(e))
 858                                                         {
 859                                                                 if(ischeat)
 860                                                                         IS_CHEAT(0, 0, CHRAME_DRAG);
 861                                                                 if(e.draggedby)
 862                                                                         Drag_Finish(e.draggedby);
 863                                                                 if(e.tag_entity)
 864                                                                         detach_sameorigin(e);
 865                                                                 Drag_Begin(self, e, trace_endpos);
 866                                                                 if(ischeat)
 867                                                                         DID_CHEAT();
 868                                                                 return true;
 869                                                         }
 870                                         }
 871                         }
 872                         break;
 873         }
 874         return false;
 875 }
 876
 877 void Drag_Begin(entity dragger, entity draggee, vector touchpoint)
 878 {
 879         float tagscale;
 880
 881         draggee.dragmovetype = draggee.movetype;
 882         draggee.draggravity = draggee.gravity;
 883         draggee.movetype = MOVETYPE_WALK;
 884         draggee.gravity = 0.00001;
 885         UNSET_ONGROUND(draggee);
 886         draggee.draggedby = dragger;
 887
 888         dragger.dragentity = draggee;
 889
 890         dragger.dragdistance = vlen(touchpoint - dragger.origin - dragger.view_ofs);
 891         dragger.draglocalangle = draggee.angles.y - dragger.v_angle.y;
 892         touchpoint = touchpoint - gettaginfo(draggee, 0);
 893         tagscale = pow(vlen(v_forward), -2);
 894         dragger.draglocalvector_x = touchpoint * v_forward * tagscale;
 895         dragger.draglocalvector_y = touchpoint * v_right * tagscale;
 896         dragger.draglocalvector_z = touchpoint * v_up * tagscale;
 897
 898         dragger.dragspeed = 64;
 899 }
 900
 901 void Drag_Finish(entity dragger)
 902 {
 903         entity draggee;
 904         draggee = dragger.dragentity;
 905         if(dragger)
 906                 dragger.dragentity = world;
 907         draggee.draggedby = world;
 908         draggee.movetype = draggee.dragmovetype;
 909         draggee.gravity = draggee.draggravity;
 910
 911         switch(draggee.movetype)
 912         {
 913                 case MOVETYPE_TOSS:
 914                 case MOVETYPE_WALK:
 915                 case MOVETYPE_STEP:
 916                 case MOVETYPE_FLYMISSILE:
 917                 case MOVETYPE_BOUNCE:
 918                 case MOVETYPE_BOUNCEMISSILE:
 919                 case MOVETYPE_PHYSICS:
 920                         break;
 921                 default:
 922                         draggee.velocity = '0 0 0';
 923                         break;
 924         }
 925
 926         if((draggee.flags & FL_ITEM) && (vlen(draggee.velocity) < 32))
 927         {
 928                 draggee.velocity = '0 0 0';
 929                 SET_ONGROUND(draggee); // floating items are FUN
 930         }
 931 }
 932
 933 float Drag_IsDraggable(entity draggee)
 934 {
 935         // TODO add more checks for bad stuff here
 936         if(draggee == world)
 937                 return false;
 938         if(draggee.classname == "func_bobbing")
 939                 return false;
 940         if(draggee.classname == "door") // FIXME find out why these must be excluded, or work around the problem (trying to drag these causes like 4 fps)
 941                 return false;
 942         if(draggee.classname == "plat")
 943                 return false;
 944         if(draggee.classname == "func_button")
 945                 return false;
 946 //      if(draggee.model == "")
 947 //              return false;
 948         if(IS_SPEC(draggee))
 949                 return false;
 950         if(IS_OBSERVER(draggee))
 951                 return false;
 952         if(draggee.classname == "exteriorweaponentity")
 953                 return false;
 954         if(draggee.classname == "weaponentity")
 955                 return false;
 956
 957         return true;
 958 }
 959
 960 float Drag_MayChangeAngles(entity draggee)
 961 {
 962         // TODO add more checks for bad stuff here
 963         if(substring(draggee.model, 0, 1) == "*")
 964                 return false;
 965         return true;
 966 }
 967
 968 void Drag_MoveForward(entity dragger)
 969 {
 970         dragger.dragdistance += dragger.dragspeed;
 971 }
 972
 973 void Drag_SetSpeed(entity dragger, float s)
 974 {
 975         dragger.dragspeed = pow(2, s);
 976 }
 977
 978 void Drag_MoveBackward(entity dragger)
 979 {
 980         dragger.dragdistance = max(0, dragger.dragdistance - dragger.dragspeed);
 981 }
 982
 983 void Drag_Update(entity dragger)
 984 {
 985         vector curorigin, neworigin, goodvelocity;
 986         float f;
 987         entity draggee;
 988
 989         draggee = dragger.dragentity;
 990         UNSET_ONGROUND(draggee);
 991
 992         curorigin = gettaginfo(draggee, 0);
 993         curorigin = curorigin + v_forward * dragger.draglocalvector.x + v_right * dragger.draglocalvector.y + v_up * dragger.draglocalvector.z;
 994         makevectors(dragger.v_angle);
 995         neworigin = dragger.origin + dragger.view_ofs + v_forward * dragger.dragdistance;
 996         goodvelocity = (neworigin - curorigin) * (1 / frametime);
 997
 998         while(draggee.angles.y - dragger.v_angle.y - dragger.draglocalangle > 180)
 999                 dragger.draglocalangle += 360;
1000         while(draggee.angles.y - dragger.v_angle.y - dragger.draglocalangle <= -180)
1001                 dragger.draglocalangle -= 360;
1002
1003         f = min(frametime * 10, 1);
1004         draggee.velocity = draggee.velocity * (1 - f) + goodvelocity * f;
1005
1006         if(Drag_MayChangeAngles(draggee))
1007                 draggee.angles_y = draggee.angles.y * (1 - f) + (dragger.v_angle.y + dragger.draglocalangle) * f;
1008
1009         draggee.ltime = max(servertime + serverframetime, draggee.ltime); // fixes func_train breakage
1010
1011         vector vecs = '0 0 0';
1012         .entity weaponentity = weaponentities[0]; // TODO: unhardcode
1013         if(dragger.(weaponentity).movedir.x > 0)
1014                 vecs = dragger.(weaponentity).movedir;
1015
1016         vector dv = v_right * -vecs_y + v_up * vecs_z;
1017
1018         te_lightning1(draggee, dragger.origin + dragger.view_ofs + dv, curorigin);
1019 }
1020
1021 float Drag_CanDrag(entity dragger)
1022 {
1023         return (!IS_DEAD(dragger)) || (IS_PLAYER(dragger));
1024 }
1025
1026 float Drag_IsDragging(entity dragger)
1027 {
1028         if(!dragger.dragentity)
1029                 return false;
1030         if(wasfreed(dragger.dragentity) || dragger.dragentity.draggedby != dragger)
1031         {
1032                 dragger.dragentity = world;
1033                 return false;
1034         }
1035         if(!Drag_CanDrag(dragger) || !Drag_IsDraggable(dragger.dragentity))
1036         {
1037                 Drag_Finish(dragger);
1038                 return false;
1039         }
1040         return true;
1041 }
1042
1043 void Drag_MoveDrag(entity from, entity to)
1044 {
1045         if(from.draggedby)
1046         {
1047                 to.draggedby = from.draggedby;
1048                 to.draggedby.dragentity = to;
1049                 from.draggedby = world;
1050         }
1051 }
1052
1053 void DragBox_Think()
1054 {SELFPARAM();
1055         if(self.aiment && self.enemy)
1056         {
1057                 self.origin_x = (self.aiment.origin.x + self.enemy.origin.x) * 0.5;
1058                 self.origin_y = (self.aiment.origin.y + self.enemy.origin.y) * 0.5;
1059                 self.origin_z = (self.aiment.origin.z + self.enemy.origin.z) * 0.5;
1060                 self.maxs_x = fabs(self.aiment.origin.x - self.enemy.origin.x) * 0.5;
1061                 self.maxs_y = fabs(self.aiment.origin.y - self.enemy.origin.y) * 0.5;
1062                 self.maxs_z = fabs(self.aiment.origin.z - self.enemy.origin.z) * 0.5;
1063                 self.mins = -1 * self.maxs;
1064                 setorigin(self, self.origin);
1065                 setsize(self, self.mins, self.maxs); // link edict
1066         }
1067
1068         if(self.cnt == -1) // actually race_place -1
1069         {
1070                 // show "10 10" for qualifying spawns
1071                 setmodel(self.killindicator, MDL_NUM(10));
1072                 setmodel(self.killindicator.killindicator, MDL_NUM(10));
1073         }
1074         else if(self.cnt == -2) // actually race_place 0
1075         {
1076                 // show "10 0" for loser spawns
1077                 setmodel(self.killindicator, MDL_NUM(10));
1078                 setmodel(self.killindicator.killindicator, MDL_NUM(0));
1079         }
1080         else
1081         {
1082                 setmodel(self.killindicator, MDL_NUM(self.cnt % 10));
1083                 setmodel(self.killindicator.killindicator, MDL_NUM(floor(self.cnt / 10)));
1084         }
1085
1086         self.nextthink = time;
1087 }
1088
1089 #endif